src/HOL/Library/FuncSet.thy
author wenzelm
Mon Apr 28 17:50:03 2014 +0200 (2014-04-28)
changeset 56777 9c3f0ae99532
parent 54417 dbb8ecfe1337
child 58606 9c66f7c541fb
permissions -rw-r--r--
tuned;
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B \<equiv> Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" \<rightleftharpoons> "CONST Pi A (%x. B)"
    45   "%x:A. f" \<rightleftharpoons> "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    67   unfolding Pi_def by auto
    68 
    69 lemma PiE [elim]:
    70   "f : Pi A B ==> (f x : B x ==> Q) ==> (x ~: A ==> Q) ==> Q"
    71 by(auto simp: Pi_def)
    72 
    73 lemma Pi_cong:
    74   "(\<And> w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    75   by (auto simp: Pi_def)
    76 
    77 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    78   by auto
    79 
    80 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    81   by (simp add: Pi_def)
    82 
    83 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    84   by auto
    85 
    86 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    87   by auto
    88 
    89 lemma Pi_eq_empty[simp]: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B x = {})"
    90 apply (simp add: Pi_def, auto)
    91 txt{*Converse direction requires Axiom of Choice to exhibit a function
    92 picking an element from each non-empty @{term "B x"}*}
    93 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    94 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    95 done
    96 
    97 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    98 by (simp add: Pi_def)
    99 
   100 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
   101   by auto
   102 
   103 lemma Pi_UN:
   104   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
   105   assumes "finite I" and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
   106   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
   107 proof (intro set_eqI iffI)
   108   fix f assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
   109   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i" by auto
   110   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)" by auto
   111   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   112     using `finite I` finite_nat_set_iff_bounded_le[of "n`I"] by auto
   113   have "f \<in> Pi I (A k)"
   114   proof (intro Pi_I)
   115     fix i assume "i \<in> I"
   116     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   117     show "f i \<in> A k i" by auto
   118   qed
   119   then show "f \<in> (\<Union>n. Pi I (A n))" by auto
   120 qed auto
   121 
   122 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
   123 by (simp add: Pi_def)
   124 
   125 text{*Covariance of Pi-sets in their second argument*}
   126 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
   127 by auto
   128 
   129 text{*Contravariance of Pi-sets in their first argument*}
   130 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
   131 by auto
   132 
   133 lemma prod_final:
   134   assumes 1: "fst \<circ> f \<in> Pi A B" and 2: "snd \<circ> f \<in> Pi A C"
   135   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   136 proof (rule Pi_I) 
   137   fix z
   138   assume z: "z \<in> A" 
   139   have "f z = (fst (f z), snd (f z))" 
   140     by simp
   141   also have "...  \<in> B z \<times> C z"
   142     by (metis SigmaI PiE o_apply 1 2 z) 
   143   finally show "f z \<in> B z \<times> C z" .
   144 qed
   145 
   146 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   147   by (auto simp: Pi_def)
   148 
   149 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   150   by (auto simp: Pi_def)
   151 
   152 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   153   by (auto simp: Pi_def)
   154 
   155 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   156   by (auto simp: Pi_def)
   157 
   158 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   159   apply auto
   160   apply (drule_tac x=x in Pi_mem)
   161   apply (simp_all split: split_if_asm)
   162   apply (drule_tac x=i in Pi_mem)
   163   apply (auto dest!: Pi_mem)
   164   done
   165 
   166 subsection{*Composition With a Restricted Domain: @{term compose}*}
   167 
   168 lemma funcset_compose:
   169   "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   170 by (simp add: Pi_def compose_def restrict_def)
   171 
   172 lemma compose_assoc:
   173     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   174       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   175 by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   176 
   177 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   178 by (simp add: compose_def restrict_def)
   179 
   180 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   181   by (auto simp add: image_def compose_eq)
   182 
   183 
   184 subsection{*Bounded Abstraction: @{term restrict}*}
   185 
   186 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   187   by (simp add: Pi_def restrict_def)
   188 
   189 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   190   by (simp add: Pi_def restrict_def)
   191 
   192 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   193   by (simp add: restrict_def)
   194 
   195 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   196   by simp
   197 
   198 lemma restrict_ext:
   199     "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   200   by (simp add: fun_eq_iff Pi_def restrict_def)
   201 
   202 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   203   by (simp add: inj_on_def restrict_def)
   204 
   205 lemma Id_compose:
   206     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   207   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   208 
   209 lemma compose_Id:
   210     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   211   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   212 
   213 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   214   by (auto simp add: restrict_def)
   215 
   216 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   217   unfolding restrict_def by (simp add: fun_eq_iff)
   218 
   219 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   220   by (auto simp: restrict_def)
   221 
   222 lemma restrict_upd[simp]:
   223   "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   224   by (auto simp: fun_eq_iff)
   225 
   226 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   227   by (auto simp: restrict_def Pi_def)
   228 
   229 
   230 subsection{*Bijections Between Sets*}
   231 
   232 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   233 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   234 
   235 lemma bij_betwI:
   236 assumes "f \<in> A \<rightarrow> B" and "g \<in> B \<rightarrow> A"
   237     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x" and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   238 shows "bij_betw f A B"
   239 unfolding bij_betw_def
   240 proof
   241   show "inj_on f A" by (metis g_f inj_on_def)
   242 next
   243   have "f ` A \<subseteq> B" using `f \<in> A \<rightarrow> B` by auto
   244   moreover
   245   have "B \<subseteq> f ` A" by auto (metis Pi_mem `g \<in> B \<rightarrow> A` f_g image_iff)
   246   ultimately show "f ` A = B" by blast
   247 qed
   248 
   249 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   250 by (auto simp add: bij_betw_def)
   251 
   252 lemma inj_on_compose:
   253   "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   254 by (auto simp add: bij_betw_def inj_on_def compose_eq)
   255 
   256 lemma bij_betw_compose:
   257   "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   258 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   259 apply (auto simp add: compose_def image_def)
   260 done
   261 
   262 lemma bij_betw_restrict_eq [simp]:
   263   "bij_betw (restrict f A) A B = bij_betw f A B"
   264 by (simp add: bij_betw_def)
   265 
   266 
   267 subsection{*Extensionality*}
   268 
   269 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   270   unfolding extensional_def by auto
   271 
   272 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   273 by (simp add: extensional_def)
   274 
   275 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   276 by (simp add: restrict_def extensional_def)
   277 
   278 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   279 by (simp add: compose_def)
   280 
   281 lemma extensionalityI:
   282   "[| f \<in> extensional A; g \<in> extensional A;
   283       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   284 by (force simp add: fun_eq_iff extensional_def)
   285 
   286 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   287 by(rule extensionalityI[OF restrict_extensional]) auto
   288 
   289 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   290   unfolding extensional_def by auto
   291 
   292 lemma inv_into_funcset: "f ` A = B ==> (\<lambda>x\<in>B. inv_into A f x) : B -> A"
   293 by (unfold inv_into_def) (fast intro: someI2)
   294 
   295 lemma compose_inv_into_id:
   296   "bij_betw f A B ==> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   297 apply (simp add: bij_betw_def compose_def)
   298 apply (rule restrict_ext, auto)
   299 done
   300 
   301 lemma compose_id_inv_into:
   302   "f ` A = B ==> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   303 apply (simp add: compose_def)
   304 apply (rule restrict_ext)
   305 apply (simp add: f_inv_into_f)
   306 done
   307 
   308 lemma extensional_insert[intro, simp]:
   309   assumes "a \<in> extensional (insert i I)"
   310   shows "a(i := b) \<in> extensional (insert i I)"
   311   using assms unfolding extensional_def by auto
   312 
   313 lemma extensional_Int[simp]:
   314   "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   315   unfolding extensional_def by auto
   316 
   317 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   318   by (auto simp: extensional_def)
   319 
   320 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   321   unfolding restrict_def extensional_def by auto
   322 
   323 lemma extensional_insert_undefined[intro, simp]:
   324   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   325   unfolding extensional_def by auto
   326 
   327 lemma extensional_insert_cancel[intro, simp]:
   328   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   329   unfolding extensional_def by auto
   330 
   331 
   332 subsection{*Cardinality*}
   333 
   334 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   335 by (rule card_inj_on_le) auto
   336 
   337 lemma card_bij:
   338   "[|f \<in> A\<rightarrow>B; inj_on f A;
   339      g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   340 by (blast intro: card_inj order_antisym)
   341 
   342 subsection {* Extensional Function Spaces *} 
   343 
   344 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set" where
   345   "PiE S T = Pi S T \<inter> extensional S"
   346 
   347 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   348 
   349 syntax "_PiE"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PIE _:_./ _)" 10)
   350 
   351 syntax (xsymbols) "_PiE" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   352 
   353 syntax (HTML output) "_PiE" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   354 
   355 translations "PIE x:A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (%x. B)"
   356 
   357 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "->\<^sub>E" 60) where
   358   "A ->\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   359 
   360 notation (xsymbols)
   361   extensional_funcset  (infixr "\<rightarrow>\<^sub>E" 60)
   362 
   363 lemma extensional_funcset_def: "extensional_funcset S T = (S -> T) \<inter> extensional S"
   364   by (simp add: PiE_def)
   365 
   366 lemma PiE_empty_domain[simp]: "PiE {} T = {%x. undefined}"
   367   unfolding PiE_def by simp
   368 
   369 lemma PiE_UNIV_domain: "PiE UNIV T = Pi UNIV T"
   370   unfolding PiE_def by simp
   371 
   372 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (PIE i:I. F i) = {}"
   373   unfolding PiE_def by auto
   374 
   375 lemma PiE_eq_empty_iff:
   376   "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   377 proof
   378   assume "Pi\<^sub>E I F = {}"
   379   show "\<exists>i\<in>I. F i = {}"
   380   proof (rule ccontr)
   381     assume "\<not> ?thesis"
   382     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)" by auto
   383     from choice[OF this]
   384     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   385     then have "f \<in> Pi\<^sub>E I F" by (auto simp: extensional_def PiE_def)
   386     with `Pi\<^sub>E I F = {}` show False by auto
   387   qed
   388 qed (auto simp: PiE_def)
   389 
   390 lemma PiE_arb: "f \<in> PiE S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   391   unfolding PiE_def by auto (auto dest!: extensional_arb)
   392 
   393 lemma PiE_mem: "f \<in> PiE S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   394   unfolding PiE_def by auto
   395 
   396 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> PiE S T \<Longrightarrow> f(x := y) \<in> PiE (insert x S) T"
   397   unfolding PiE_def extensional_def by auto
   398 
   399 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> PiE (insert x S) T \<Longrightarrow> f(x := undefined) \<in> PiE S T"
   400   unfolding PiE_def extensional_def by auto
   401 
   402 lemma PiE_insert_eq:
   403   assumes "x \<notin> S"
   404   shows "PiE (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   405 proof -
   406   {
   407     fix f assume "f \<in> PiE (insert x S) T"
   408     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   409       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   410   }
   411   then show ?thesis using assms by (auto intro: PiE_fun_upd)
   412 qed
   413 
   414 lemma PiE_Int: "(Pi\<^sub>E I A) \<inter> (Pi\<^sub>E I B) = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   415   by (auto simp: PiE_def)
   416 
   417 lemma PiE_cong:
   418   "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   419   unfolding PiE_def by (auto simp: Pi_cong)
   420 
   421 lemma PiE_E [elim]:
   422   "f \<in> PiE A B \<Longrightarrow> (x \<in> A \<Longrightarrow> f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> f x = undefined \<Longrightarrow> Q) \<Longrightarrow> Q"
   423 by(auto simp: Pi_def PiE_def extensional_def)
   424 
   425 lemma PiE_I[intro!]: "(\<And>x. x \<in> A ==> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> PiE A B"
   426   by (simp add: PiE_def extensional_def)
   427 
   428 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> PiE A B \<subseteq> PiE A C"
   429   by auto
   430 
   431 lemma PiE_iff: "f \<in> PiE I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   432   by (simp add: PiE_def Pi_iff)
   433 
   434 lemma PiE_restrict[simp]:  "f \<in> PiE A B \<Longrightarrow> restrict f A = f"
   435   by (simp add: extensional_restrict PiE_def)
   436 
   437 lemma restrict_PiE[simp]: "restrict f I \<in> PiE I S \<longleftrightarrow> f \<in> Pi I S"
   438   by (auto simp: PiE_iff)
   439 
   440 lemma PiE_eq_subset:
   441   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   442   assumes eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'" and "i \<in> I"
   443   shows "F i \<subseteq> F' i"
   444 proof
   445   fix x assume "x \<in> F i"
   446   with ne have "\<forall>j. \<exists>y. ((j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined))"
   447     by auto
   448   from choice[OF this] obtain f
   449     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   450   then have "f \<in> Pi\<^sub>E I F" by (auto simp: extensional_def PiE_def)
   451   then have "f \<in> Pi\<^sub>E I F'" using assms by simp
   452   then show "x \<in> F' i" using f `i \<in> I` by (auto simp: PiE_def)
   453 qed
   454 
   455 lemma PiE_eq_iff_not_empty:
   456   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   457   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   458 proof (intro iffI ballI)
   459   fix i assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'" and i: "i \<in> I"
   460   show "F i = F' i"
   461     using PiE_eq_subset[of I F F', OF ne eq i]
   462     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   463     by auto
   464 qed (auto simp: PiE_def)
   465 
   466 lemma PiE_eq_iff:
   467   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   468 proof (intro iffI disjCI)
   469   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   470   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   471   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   472     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   473   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i" by auto
   474 next
   475   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   476   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   477     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   478 qed
   479 
   480 lemma extensional_funcset_fun_upd_restricts_rangeI: 
   481   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f : (insert x S) \<rightarrow>\<^sub>E T ==> f(x := undefined) : S \<rightarrow>\<^sub>E (T - {f x})"
   482   unfolding extensional_funcset_def extensional_def
   483   apply auto
   484   apply (case_tac "x = xa")
   485   apply auto
   486   done
   487 
   488 lemma extensional_funcset_fun_upd_extends_rangeI:
   489   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   490   shows "f(x := a) \<in> (insert x S) \<rightarrow>\<^sub>E  T"
   491   using assms unfolding extensional_funcset_def extensional_def by auto
   492 
   493 subsubsection {* Injective Extensional Function Spaces *}
   494 
   495 lemma extensional_funcset_fun_upd_inj_onI:
   496   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})" "inj_on f S"
   497   shows "inj_on (f(x := a)) S"
   498   using assms unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   499 
   500 lemma extensional_funcset_extend_domain_inj_on_eq:
   501   assumes "x \<notin> S"
   502   shows"{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   503     (%(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   504 proof -
   505   from assms show ?thesis
   506     apply (auto del: PiE_I PiE_E)
   507     apply (auto intro: extensional_funcset_fun_upd_inj_onI extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   508     apply (auto simp add: image_iff inj_on_def)
   509     apply (rule_tac x="xa x" in exI)
   510     apply (auto intro: PiE_mem del: PiE_I PiE_E)
   511     apply (rule_tac x="xa(x := undefined)" in exI)
   512     apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   513     apply (auto dest!: PiE_mem split: split_if_asm)
   514     done
   515 qed
   516 
   517 lemma extensional_funcset_extend_domain_inj_onI:
   518   assumes "x \<notin> S"
   519   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   520 proof -
   521   from assms show ?thesis
   522     apply (auto intro!: inj_onI)
   523     apply (metis fun_upd_same)
   524     by (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   525 qed
   526   
   527 
   528 subsubsection {* Cardinality *}
   529 
   530 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (PIE i : S. T i)"
   531   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   532 
   533 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   534 proof (safe intro!: inj_onI ext)
   535   fix f y g z assume "x \<notin> S" and fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   536   assume "f(x := y) = g(x := z)"
   537   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   538     unfolding fun_eq_iff by auto
   539   from this[of x] show "y = z" by simp
   540   fix i from *[of i] `x \<notin> S` fg show "f i = g i"
   541     by (auto split: split_if_asm simp: PiE_def extensional_def)
   542 qed
   543 
   544 lemma card_PiE:
   545   "finite S \<Longrightarrow> card (PIE i : S. T i) = (\<Prod> i\<in>S. card (T i))"
   546 proof (induct rule: finite_induct)
   547   case empty then show ?case by auto
   548 next
   549   case (insert x S) then show ?case
   550     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   551 qed
   552 
   553 end