src/HOL/Library/FuncSet.thy
author hoelzl
Tue Oct 07 10:34:24 2014 +0200 (2014-10-07)
changeset 58606 9c66f7c541fb
parent 56777 9c3f0ae99532
child 58783 c6348a062131
permissions -rw-r--r--
add Giry monad
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B \<equiv> Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" \<rightleftharpoons> "CONST Pi A (%x. B)"
    45   "%x:A. f" \<rightleftharpoons> "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    67   unfolding Pi_def by auto
    68 
    69 lemma PiE [elim]:
    70   "f : Pi A B ==> (f x : B x ==> Q) ==> (x ~: A ==> Q) ==> Q"
    71 by(auto simp: Pi_def)
    72 
    73 lemma Pi_cong:
    74   "(\<And> w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    75   by (auto simp: Pi_def)
    76 
    77 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    78   by auto
    79 
    80 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    81   by (simp add: Pi_def)
    82 
    83 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    84   by auto
    85 
    86 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    87   by auto
    88 
    89 lemma Pi_eq_empty[simp]: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B x = {})"
    90 apply (simp add: Pi_def, auto)
    91 txt{*Converse direction requires Axiom of Choice to exhibit a function
    92 picking an element from each non-empty @{term "B x"}*}
    93 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    94 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    95 done
    96 
    97 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    98 by (simp add: Pi_def)
    99 
   100 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
   101   by auto
   102 
   103 lemma Pi_UN:
   104   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
   105   assumes "finite I" and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
   106   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
   107 proof (intro set_eqI iffI)
   108   fix f assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
   109   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i" by auto
   110   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)" by auto
   111   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   112     using `finite I` finite_nat_set_iff_bounded_le[of "n`I"] by auto
   113   have "f \<in> Pi I (A k)"
   114   proof (intro Pi_I)
   115     fix i assume "i \<in> I"
   116     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   117     show "f i \<in> A k i" by auto
   118   qed
   119   then show "f \<in> (\<Union>n. Pi I (A n))" by auto
   120 qed auto
   121 
   122 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
   123 by (simp add: Pi_def)
   124 
   125 text{*Covariance of Pi-sets in their second argument*}
   126 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
   127 by auto
   128 
   129 text{*Contravariance of Pi-sets in their first argument*}
   130 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
   131 by auto
   132 
   133 lemma prod_final:
   134   assumes 1: "fst \<circ> f \<in> Pi A B" and 2: "snd \<circ> f \<in> Pi A C"
   135   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   136 proof (rule Pi_I) 
   137   fix z
   138   assume z: "z \<in> A" 
   139   have "f z = (fst (f z), snd (f z))" 
   140     by simp
   141   also have "...  \<in> B z \<times> C z"
   142     by (metis SigmaI PiE o_apply 1 2 z) 
   143   finally show "f z \<in> B z \<times> C z" .
   144 qed
   145 
   146 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   147   by (auto simp: Pi_def)
   148 
   149 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   150   by (auto simp: Pi_def)
   151 
   152 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   153   by (auto simp: Pi_def)
   154 
   155 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   156   by (auto simp: Pi_def)
   157 
   158 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   159   apply auto
   160   apply (drule_tac x=x in Pi_mem)
   161   apply (simp_all split: split_if_asm)
   162   apply (drule_tac x=i in Pi_mem)
   163   apply (auto dest!: Pi_mem)
   164   done
   165 
   166 subsection{*Composition With a Restricted Domain: @{term compose}*}
   167 
   168 lemma funcset_compose:
   169   "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   170 by (simp add: Pi_def compose_def restrict_def)
   171 
   172 lemma compose_assoc:
   173     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   174       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   175 by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   176 
   177 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   178 by (simp add: compose_def restrict_def)
   179 
   180 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   181   by (auto simp add: image_def compose_eq)
   182 
   183 
   184 subsection{*Bounded Abstraction: @{term restrict}*}
   185 
   186 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   187   by (simp add: Pi_def restrict_def)
   188 
   189 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   190   by (simp add: Pi_def restrict_def)
   191 
   192 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   193   by (simp add: restrict_def)
   194 
   195 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   196   by simp
   197 
   198 lemma restrict_ext:
   199     "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   200   by (simp add: fun_eq_iff Pi_def restrict_def)
   201 
   202 lemma restrict_UNIV: "restrict f UNIV = f"
   203   by (simp add: restrict_def)
   204 
   205 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   206   by (simp add: inj_on_def restrict_def)
   207 
   208 lemma Id_compose:
   209     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   210   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   211 
   212 lemma compose_Id:
   213     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   214   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   215 
   216 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   217   by (auto simp add: restrict_def)
   218 
   219 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   220   unfolding restrict_def by (simp add: fun_eq_iff)
   221 
   222 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   223   by (auto simp: restrict_def)
   224 
   225 lemma restrict_upd[simp]:
   226   "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   227   by (auto simp: fun_eq_iff)
   228 
   229 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   230   by (auto simp: restrict_def Pi_def)
   231 
   232 
   233 subsection{*Bijections Between Sets*}
   234 
   235 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   236 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   237 
   238 lemma bij_betwI:
   239 assumes "f \<in> A \<rightarrow> B" and "g \<in> B \<rightarrow> A"
   240     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x" and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   241 shows "bij_betw f A B"
   242 unfolding bij_betw_def
   243 proof
   244   show "inj_on f A" by (metis g_f inj_on_def)
   245 next
   246   have "f ` A \<subseteq> B" using `f \<in> A \<rightarrow> B` by auto
   247   moreover
   248   have "B \<subseteq> f ` A" by auto (metis Pi_mem `g \<in> B \<rightarrow> A` f_g image_iff)
   249   ultimately show "f ` A = B" by blast
   250 qed
   251 
   252 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   253 by (auto simp add: bij_betw_def)
   254 
   255 lemma inj_on_compose:
   256   "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   257 by (auto simp add: bij_betw_def inj_on_def compose_eq)
   258 
   259 lemma bij_betw_compose:
   260   "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   261 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   262 apply (auto simp add: compose_def image_def)
   263 done
   264 
   265 lemma bij_betw_restrict_eq [simp]:
   266   "bij_betw (restrict f A) A B = bij_betw f A B"
   267 by (simp add: bij_betw_def)
   268 
   269 
   270 subsection{*Extensionality*}
   271 
   272 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   273   unfolding extensional_def by auto
   274 
   275 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   276 by (simp add: extensional_def)
   277 
   278 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   279 by (simp add: restrict_def extensional_def)
   280 
   281 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   282 by (simp add: compose_def)
   283 
   284 lemma extensionalityI:
   285   "[| f \<in> extensional A; g \<in> extensional A;
   286       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   287 by (force simp add: fun_eq_iff extensional_def)
   288 
   289 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   290 by(rule extensionalityI[OF restrict_extensional]) auto
   291 
   292 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   293   unfolding extensional_def by auto
   294 
   295 lemma inv_into_funcset: "f ` A = B ==> (\<lambda>x\<in>B. inv_into A f x) : B -> A"
   296 by (unfold inv_into_def) (fast intro: someI2)
   297 
   298 lemma compose_inv_into_id:
   299   "bij_betw f A B ==> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   300 apply (simp add: bij_betw_def compose_def)
   301 apply (rule restrict_ext, auto)
   302 done
   303 
   304 lemma compose_id_inv_into:
   305   "f ` A = B ==> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   306 apply (simp add: compose_def)
   307 apply (rule restrict_ext)
   308 apply (simp add: f_inv_into_f)
   309 done
   310 
   311 lemma extensional_insert[intro, simp]:
   312   assumes "a \<in> extensional (insert i I)"
   313   shows "a(i := b) \<in> extensional (insert i I)"
   314   using assms unfolding extensional_def by auto
   315 
   316 lemma extensional_Int[simp]:
   317   "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   318   unfolding extensional_def by auto
   319 
   320 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   321   by (auto simp: extensional_def)
   322 
   323 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   324   unfolding restrict_def extensional_def by auto
   325 
   326 lemma extensional_insert_undefined[intro, simp]:
   327   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   328   unfolding extensional_def by auto
   329 
   330 lemma extensional_insert_cancel[intro, simp]:
   331   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   332   unfolding extensional_def by auto
   333 
   334 
   335 subsection{*Cardinality*}
   336 
   337 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   338 by (rule card_inj_on_le) auto
   339 
   340 lemma card_bij:
   341   "[|f \<in> A\<rightarrow>B; inj_on f A;
   342      g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   343 by (blast intro: card_inj order_antisym)
   344 
   345 subsection {* Extensional Function Spaces *} 
   346 
   347 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set" where
   348   "PiE S T = Pi S T \<inter> extensional S"
   349 
   350 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   351 
   352 syntax "_PiE"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PIE _:_./ _)" 10)
   353 
   354 syntax (xsymbols) "_PiE" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   355 
   356 syntax (HTML output) "_PiE" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   357 
   358 translations "PIE x:A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (%x. B)"
   359 
   360 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "->\<^sub>E" 60) where
   361   "A ->\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   362 
   363 notation (xsymbols)
   364   extensional_funcset  (infixr "\<rightarrow>\<^sub>E" 60)
   365 
   366 lemma extensional_funcset_def: "extensional_funcset S T = (S -> T) \<inter> extensional S"
   367   by (simp add: PiE_def)
   368 
   369 lemma PiE_empty_domain[simp]: "PiE {} T = {%x. undefined}"
   370   unfolding PiE_def by simp
   371 
   372 lemma PiE_UNIV_domain: "PiE UNIV T = Pi UNIV T"
   373   unfolding PiE_def by simp
   374 
   375 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (PIE i:I. F i) = {}"
   376   unfolding PiE_def by auto
   377 
   378 lemma PiE_eq_empty_iff:
   379   "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   380 proof
   381   assume "Pi\<^sub>E I F = {}"
   382   show "\<exists>i\<in>I. F i = {}"
   383   proof (rule ccontr)
   384     assume "\<not> ?thesis"
   385     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)" by auto
   386     from choice[OF this]
   387     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   388     then have "f \<in> Pi\<^sub>E I F" by (auto simp: extensional_def PiE_def)
   389     with `Pi\<^sub>E I F = {}` show False by auto
   390   qed
   391 qed (auto simp: PiE_def)
   392 
   393 lemma PiE_arb: "f \<in> PiE S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   394   unfolding PiE_def by auto (auto dest!: extensional_arb)
   395 
   396 lemma PiE_mem: "f \<in> PiE S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   397   unfolding PiE_def by auto
   398 
   399 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> PiE S T \<Longrightarrow> f(x := y) \<in> PiE (insert x S) T"
   400   unfolding PiE_def extensional_def by auto
   401 
   402 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> PiE (insert x S) T \<Longrightarrow> f(x := undefined) \<in> PiE S T"
   403   unfolding PiE_def extensional_def by auto
   404 
   405 lemma PiE_insert_eq:
   406   assumes "x \<notin> S"
   407   shows "PiE (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   408 proof -
   409   {
   410     fix f assume "f \<in> PiE (insert x S) T"
   411     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   412       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   413   }
   414   then show ?thesis using assms by (auto intro: PiE_fun_upd)
   415 qed
   416 
   417 lemma PiE_Int: "(Pi\<^sub>E I A) \<inter> (Pi\<^sub>E I B) = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   418   by (auto simp: PiE_def)
   419 
   420 lemma PiE_cong:
   421   "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   422   unfolding PiE_def by (auto simp: Pi_cong)
   423 
   424 lemma PiE_E [elim]:
   425   "f \<in> PiE A B \<Longrightarrow> (x \<in> A \<Longrightarrow> f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> f x = undefined \<Longrightarrow> Q) \<Longrightarrow> Q"
   426 by(auto simp: Pi_def PiE_def extensional_def)
   427 
   428 lemma PiE_I[intro!]: "(\<And>x. x \<in> A ==> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> PiE A B"
   429   by (simp add: PiE_def extensional_def)
   430 
   431 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> PiE A B \<subseteq> PiE A C"
   432   by auto
   433 
   434 lemma PiE_iff: "f \<in> PiE I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   435   by (simp add: PiE_def Pi_iff)
   436 
   437 lemma PiE_restrict[simp]:  "f \<in> PiE A B \<Longrightarrow> restrict f A = f"
   438   by (simp add: extensional_restrict PiE_def)
   439 
   440 lemma restrict_PiE[simp]: "restrict f I \<in> PiE I S \<longleftrightarrow> f \<in> Pi I S"
   441   by (auto simp: PiE_iff)
   442 
   443 lemma PiE_eq_subset:
   444   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   445   assumes eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'" and "i \<in> I"
   446   shows "F i \<subseteq> F' i"
   447 proof
   448   fix x assume "x \<in> F i"
   449   with ne have "\<forall>j. \<exists>y. ((j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined))"
   450     by auto
   451   from choice[OF this] obtain f
   452     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   453   then have "f \<in> Pi\<^sub>E I F" by (auto simp: extensional_def PiE_def)
   454   then have "f \<in> Pi\<^sub>E I F'" using assms by simp
   455   then show "x \<in> F' i" using f `i \<in> I` by (auto simp: PiE_def)
   456 qed
   457 
   458 lemma PiE_eq_iff_not_empty:
   459   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   460   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   461 proof (intro iffI ballI)
   462   fix i assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'" and i: "i \<in> I"
   463   show "F i = F' i"
   464     using PiE_eq_subset[of I F F', OF ne eq i]
   465     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   466     by auto
   467 qed (auto simp: PiE_def)
   468 
   469 lemma PiE_eq_iff:
   470   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   471 proof (intro iffI disjCI)
   472   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   473   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   474   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   475     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   476   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i" by auto
   477 next
   478   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   479   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   480     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   481 qed
   482 
   483 lemma extensional_funcset_fun_upd_restricts_rangeI: 
   484   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f : (insert x S) \<rightarrow>\<^sub>E T ==> f(x := undefined) : S \<rightarrow>\<^sub>E (T - {f x})"
   485   unfolding extensional_funcset_def extensional_def
   486   apply auto
   487   apply (case_tac "x = xa")
   488   apply auto
   489   done
   490 
   491 lemma extensional_funcset_fun_upd_extends_rangeI:
   492   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   493   shows "f(x := a) \<in> (insert x S) \<rightarrow>\<^sub>E  T"
   494   using assms unfolding extensional_funcset_def extensional_def by auto
   495 
   496 subsubsection {* Injective Extensional Function Spaces *}
   497 
   498 lemma extensional_funcset_fun_upd_inj_onI:
   499   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})" "inj_on f S"
   500   shows "inj_on (f(x := a)) S"
   501   using assms unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   502 
   503 lemma extensional_funcset_extend_domain_inj_on_eq:
   504   assumes "x \<notin> S"
   505   shows"{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   506     (%(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   507 proof -
   508   from assms show ?thesis
   509     apply (auto del: PiE_I PiE_E)
   510     apply (auto intro: extensional_funcset_fun_upd_inj_onI extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   511     apply (auto simp add: image_iff inj_on_def)
   512     apply (rule_tac x="xa x" in exI)
   513     apply (auto intro: PiE_mem del: PiE_I PiE_E)
   514     apply (rule_tac x="xa(x := undefined)" in exI)
   515     apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   516     apply (auto dest!: PiE_mem split: split_if_asm)
   517     done
   518 qed
   519 
   520 lemma extensional_funcset_extend_domain_inj_onI:
   521   assumes "x \<notin> S"
   522   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   523 proof -
   524   from assms show ?thesis
   525     apply (auto intro!: inj_onI)
   526     apply (metis fun_upd_same)
   527     by (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   528 qed
   529   
   530 
   531 subsubsection {* Cardinality *}
   532 
   533 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (PIE i : S. T i)"
   534   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   535 
   536 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   537 proof (safe intro!: inj_onI ext)
   538   fix f y g z assume "x \<notin> S" and fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   539   assume "f(x := y) = g(x := z)"
   540   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   541     unfolding fun_eq_iff by auto
   542   from this[of x] show "y = z" by simp
   543   fix i from *[of i] `x \<notin> S` fg show "f i = g i"
   544     by (auto split: split_if_asm simp: PiE_def extensional_def)
   545 qed
   546 
   547 lemma card_PiE:
   548   "finite S \<Longrightarrow> card (PIE i : S. T i) = (\<Prod> i\<in>S. card (T i))"
   549 proof (induct rule: finite_induct)
   550   case empty then show ?case by auto
   551 next
   552   case (insert x S) then show ?case
   553     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   554 qed
   555 
   556 end