src/Provers/Arith/cancel_numerals.ML
author wenzelm
Sun Mar 07 12:19:47 2010 +0100 (2010-03-07)
changeset 35625 9c818cab0dd0
parent 24630 351a308ab58d
child 35762 af3ff2ba4c54
permissions -rw-r--r--
modernized structure Object_Logic;
     1 (*  Title:      Provers/Arith/cancel_numerals.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   2000  University of Cambridge
     5 
     6 Cancel common coefficients in balanced expressions:
     7 
     8      i + #m*u + j ~~ i' + #m'*u + j'  ==  #(m-m')*u + i + j ~~ i' + j'
     9 
    10 where ~~ is an appropriate balancing operation (e.g. =, <=, <, -).
    11 
    12 It works by (a) massaging both sides to bring the selected term to the front:
    13 
    14      #m*u + (i + j) ~~ #m'*u + (i' + j')
    15 
    16 (b) then using bal_add1 or bal_add2 to reach
    17 
    18      #(m-m')*u + i + j ~~ i' + j'       (if m'<=m)
    19 
    20 or
    21 
    22      i + j ~~ #(m'-m)*u + i' + j'       (otherwise)
    23 *)
    24 
    25 signature CANCEL_NUMERALS_DATA =
    26 sig
    27   (*abstract syntax*)
    28   val mk_sum: typ -> term list -> term
    29   val dest_sum: term -> term list
    30   val mk_bal: term * term -> term
    31   val dest_bal: term -> term * term
    32   val mk_coeff: int * term -> term
    33   val dest_coeff: term -> int * term
    34   val find_first_coeff: term -> term list -> int * term list
    35   (*rules*)
    36   val bal_add1: thm
    37   val bal_add2: thm
    38   (*proof tools*)
    39   val prove_conv: tactic list -> Proof.context -> thm list -> term * term -> thm option
    40   val trans_tac: simpset -> thm option -> tactic (*applies the initial lemma*)
    41   val norm_tac: simpset -> tactic                (*proves the initial lemma*)
    42   val numeral_simp_tac: simpset -> tactic        (*proves the final theorem*)
    43   val simplify_meta_eq: simpset -> thm -> thm    (*simplifies the final theorem*)
    44 end;
    45 
    46 
    47 functor CancelNumeralsFun(Data: CANCEL_NUMERALS_DATA):
    48   sig
    49   val proc: simpset -> term -> thm option
    50   end
    51 =
    52 struct
    53 
    54 (*For t = #n*u then put u in the table*)
    55 fun update_by_coeff t =
    56   Termtab.update (#2 (Data.dest_coeff t), ());
    57 
    58 (*a left-to-right scan of terms1, seeking a term of the form #n*u, where
    59   #m*u is in terms2 for some m*)
    60 fun find_common (terms1,terms2) =
    61   let val tab2 = fold update_by_coeff terms2 Termtab.empty
    62       fun seek [] = raise TERM("find_common", [])
    63         | seek (t::terms) =
    64               let val (_,u) = Data.dest_coeff t
    65               in if Termtab.defined tab2 u then u else seek terms end
    66   in  seek terms1 end;
    67 
    68 (*the simplification procedure*)
    69 fun proc ss t =
    70   let
    71     val ctxt = Simplifier.the_context ss
    72     val prems = prems_of_ss ss
    73     val ([t'], ctxt') = Variable.import_terms true [t] ctxt
    74     val export = singleton (Variable.export ctxt' ctxt)
    75 
    76     val (t1,t2) = Data.dest_bal t'
    77     val terms1 = Data.dest_sum t1
    78     and terms2 = Data.dest_sum t2
    79 
    80     val u = find_common (terms1, terms2)
    81     val (n1, terms1') = Data.find_first_coeff u terms1
    82     and (n2, terms2') = Data.find_first_coeff u terms2
    83     and T = Term.fastype_of u
    84 
    85     fun newshape (i,terms) = Data.mk_sum T (Data.mk_coeff(i,u)::terms)
    86     val reshape =  (*Move i*u to the front and put j*u into standard form
    87                        i + #m + j + k == #m + i + (j + k) *)
    88         if n1=0 orelse n2=0 then   (*trivial, so do nothing*)
    89           raise TERM("cancel_numerals", [])
    90         else Data.prove_conv [Data.norm_tac ss] ctxt prems
    91           (t', Data.mk_bal (newshape(n1,terms1'), newshape(n2,terms2')))
    92   in
    93     Option.map (export o Data.simplify_meta_eq ss)
    94       (if n2 <= n1 then
    95          Data.prove_conv
    96            [Data.trans_tac ss reshape, rtac Data.bal_add1 1,
    97             Data.numeral_simp_tac ss] ctxt prems
    98            (t', Data.mk_bal (newshape(n1-n2,terms1'), Data.mk_sum T terms2'))
    99        else
   100          Data.prove_conv
   101            [Data.trans_tac ss reshape, rtac Data.bal_add2 1,
   102             Data.numeral_simp_tac ss] ctxt prems
   103            (t', Data.mk_bal (Data.mk_sum T terms1', newshape(n2-n1,terms2'))))
   104   end
   105   (* FIXME avoid handling of generic exceptions *)
   106   handle TERM _ => NONE
   107        | TYPE _ => NONE;   (*Typically (if thy doesn't include Numeral)
   108                              Undeclared type constructor "Numeral.bin"*)
   109 
   110 end;