src/Pure/Isar/element.ML
author wenzelm
Sun Mar 07 12:19:47 2010 +0100 (2010-03-07)
changeset 35625 9c818cab0dd0
parent 35624 c4e29a0bb8c1
child 35767 086504a943af
permissions -rw-r--r--
modernized structure Object_Logic;
     1 (*  Title:      Pure/Isar/element.ML
     2     Author:     Makarius
     3 
     4 Explicit data structures for some Isar language elements, with derived
     5 logical operations.
     6 *)
     7 
     8 signature ELEMENT =
     9 sig
    10   datatype ('typ, 'term) stmt =
    11     Shows of (Attrib.binding * ('term * 'term list) list) list |
    12     Obtains of (binding * ((binding * 'typ option) list * 'term list)) list
    13   type statement = (string, string) stmt
    14   type statement_i = (typ, term) stmt
    15   datatype ('typ, 'term, 'fact) ctxt =
    16     Fixes of (binding * 'typ option * mixfix) list |
    17     Constrains of (string * 'typ) list |
    18     Assumes of (Attrib.binding * ('term * 'term list) list) list |
    19     Defines of (Attrib.binding * ('term * 'term list)) list |
    20     Notes of string * (Attrib.binding * ('fact * Attrib.src list) list) list
    21   type context = (string, string, Facts.ref) ctxt
    22   type context_i = (typ, term, thm list) ctxt
    23   val facts_map: (('typ, 'term, 'fact) ctxt -> ('a, 'b, 'c) ctxt) ->
    24    (Attrib.binding * ('fact * Attrib.src list) list) list ->
    25    (Attrib.binding * ('c * Attrib.src list) list) list
    26   val map_ctxt: {binding: binding -> binding, typ: 'typ -> 'a, term: 'term -> 'b,
    27     pattern: 'term -> 'b, fact: 'fact -> 'c, attrib: Attrib.src -> Attrib.src} ->
    28     ('typ, 'term, 'fact) ctxt -> ('a, 'b, 'c) ctxt
    29   val map_ctxt_attrib: (Attrib.src -> Attrib.src) ->
    30     ('typ, 'term, 'fact) ctxt -> ('typ, 'term, 'fact) ctxt
    31   val morph_ctxt: morphism -> context_i -> context_i
    32   val pretty_stmt: Proof.context -> statement_i -> Pretty.T list
    33   val pretty_ctxt: Proof.context -> context_i -> Pretty.T list
    34   val pretty_statement: Proof.context -> string -> thm -> Pretty.T
    35   type witness
    36   val prove_witness: Proof.context -> term -> tactic -> witness
    37   val witness_proof: (witness list list -> Proof.context -> Proof.context) ->
    38     term list list -> Proof.context -> Proof.state
    39   val witness_proof_eqs: (witness list list -> thm list -> Proof.context -> Proof.context) ->
    40     term list list -> term list -> Proof.context -> Proof.state
    41   val witness_local_proof: (witness list list -> Proof.state -> Proof.state) ->
    42     string -> term list list -> Proof.context -> bool -> Proof.state -> Proof.state
    43   val morph_witness: morphism -> witness -> witness
    44   val conclude_witness: witness -> thm
    45   val pretty_witness: Proof.context -> witness -> Pretty.T
    46   val instT_type: typ Symtab.table -> typ -> typ
    47   val instT_term: typ Symtab.table -> term -> term
    48   val instT_thm: theory -> typ Symtab.table -> thm -> thm
    49   val instT_morphism: theory -> typ Symtab.table -> morphism
    50   val inst_term: typ Symtab.table * term Symtab.table -> term -> term
    51   val inst_thm: theory -> typ Symtab.table * term Symtab.table -> thm -> thm
    52   val inst_morphism: theory -> typ Symtab.table * term Symtab.table -> morphism
    53   val satisfy_thm: witness list -> thm -> thm
    54   val satisfy_morphism: witness list -> morphism
    55   val satisfy_facts: witness list ->
    56     (Attrib.binding * (thm list * Attrib.src list) list) list ->
    57     (Attrib.binding * (thm list * Attrib.src list) list) list
    58   val generalize_facts: Proof.context -> Proof.context ->
    59     (Attrib.binding * (thm list * Attrib.src list) list) list ->
    60     (Attrib.binding * (thm list * Attrib.src list) list) list
    61   val eq_morphism: theory -> thm list -> morphism
    62   val transfer_morphism: theory -> morphism
    63   val init: context_i -> Context.generic -> Context.generic
    64   val activate_i: context_i -> Proof.context -> context_i * Proof.context
    65   val activate: (typ, term, Facts.ref) ctxt -> Proof.context -> context_i * Proof.context
    66 end;
    67 
    68 structure Element: ELEMENT =
    69 struct
    70 
    71 (** language elements **)
    72 
    73 (* statement *)
    74 
    75 datatype ('typ, 'term) stmt =
    76   Shows of (Attrib.binding * ('term * 'term list) list) list |
    77   Obtains of (binding * ((binding * 'typ option) list * 'term list)) list;
    78 
    79 type statement = (string, string) stmt;
    80 type statement_i = (typ, term) stmt;
    81 
    82 
    83 (* context *)
    84 
    85 datatype ('typ, 'term, 'fact) ctxt =
    86   Fixes of (binding * 'typ option * mixfix) list |
    87   Constrains of (string * 'typ) list |
    88   Assumes of (Attrib.binding * ('term * 'term list) list) list |
    89   Defines of (Attrib.binding * ('term * 'term list)) list |
    90   Notes of string * (Attrib.binding * ('fact * Attrib.src list) list) list;
    91 
    92 type context = (string, string, Facts.ref) ctxt;
    93 type context_i = (typ, term, thm list) ctxt;
    94 
    95 fun facts_map f facts = Notes ("", facts) |> f |> (fn Notes (_, facts') => facts');
    96 
    97 fun map_ctxt {binding, typ, term, pattern, fact, attrib} =
    98   fn Fixes fixes => Fixes (fixes |> map (fn (x, T, mx) => (binding x, Option.map typ T, mx)))
    99    | Constrains xs => Constrains (xs |> map (fn (x, T) =>
   100       (Name.of_binding (binding (Binding.name x)), typ T)))
   101    | Assumes asms => Assumes (asms |> map (fn ((a, atts), propps) =>
   102       ((binding a, map attrib atts), propps |> map (fn (t, ps) => (term t, map pattern ps)))))
   103    | Defines defs => Defines (defs |> map (fn ((a, atts), (t, ps)) =>
   104       ((binding a, map attrib atts), (term t, map pattern ps))))
   105    | Notes (kind, facts) => Notes (kind, facts |> map (fn ((a, atts), bs) =>
   106       ((binding a, map attrib atts), bs |> map (fn (ths, btts) => (fact ths, map attrib btts)))));
   107 
   108 fun map_ctxt_attrib attrib =
   109   map_ctxt {binding = I, typ = I, term = I, pattern = I, fact = I, attrib = attrib};
   110 
   111 fun morph_ctxt phi = map_ctxt
   112  {binding = Morphism.binding phi,
   113   typ = Morphism.typ phi,
   114   term = Morphism.term phi,
   115   pattern = Morphism.term phi,
   116   fact = Morphism.fact phi,
   117   attrib = Args.morph_values phi};
   118 
   119 
   120 
   121 (** pretty printing **)
   122 
   123 fun pretty_items _ _ [] = []
   124   | pretty_items keyword sep (x :: ys) =
   125       Pretty.block [Pretty.keyword keyword, Pretty.brk 1, x] ::
   126         map (fn y => Pretty.block [Pretty.str "  ", Pretty.keyword sep, Pretty.brk 1, y]) ys;
   127 
   128 fun pretty_name_atts ctxt (b, atts) sep =
   129   if Binding.is_empty b andalso null atts then []
   130   else [Pretty.block (Pretty.breaks
   131     (Pretty.str (Binding.str_of b) :: Attrib.pretty_attribs ctxt atts @ [Pretty.str sep]))];
   132 
   133 
   134 (* pretty_stmt *)
   135 
   136 fun pretty_stmt ctxt =
   137   let
   138     val prt_typ = Pretty.quote o Syntax.pretty_typ ctxt;
   139     val prt_term = Pretty.quote o Syntax.pretty_term ctxt;
   140     val prt_terms = separate (Pretty.keyword "and") o map prt_term;
   141     val prt_name_atts = pretty_name_atts ctxt;
   142 
   143     fun prt_show (a, ts) =
   144       Pretty.block (Pretty.breaks (prt_name_atts a ":" @ prt_terms (map fst ts)));
   145 
   146     fun prt_var (x, SOME T) = Pretty.block
   147           [Pretty.str (Binding.name_of x ^ " ::"), Pretty.brk 1, prt_typ T]
   148       | prt_var (x, NONE) = Pretty.str (Binding.name_of x);
   149     val prt_vars = separate (Pretty.keyword "and") o map prt_var;
   150 
   151     fun prt_obtain (_, ([], ts)) = Pretty.block (Pretty.breaks (prt_terms ts))
   152       | prt_obtain (_, (xs, ts)) = Pretty.block (Pretty.breaks
   153           (prt_vars xs @ [Pretty.keyword "where"] @ prt_terms ts));
   154   in
   155     fn Shows shows => pretty_items "shows" "and" (map prt_show shows)
   156      | Obtains obtains => pretty_items "obtains" "|" (map prt_obtain obtains)
   157   end;
   158 
   159 
   160 (* pretty_ctxt *)
   161 
   162 fun pretty_ctxt ctxt =
   163   let
   164     val prt_typ = Pretty.quote o Syntax.pretty_typ ctxt;
   165     val prt_term = Pretty.quote o Syntax.pretty_term ctxt;
   166     val prt_thm = Pretty.backquote o Display.pretty_thm ctxt;
   167     val prt_name_atts = pretty_name_atts ctxt;
   168 
   169     fun prt_mixfix NoSyn = []
   170       | prt_mixfix mx = [Pretty.brk 2, Syntax.pretty_mixfix mx];
   171 
   172     fun prt_fix (x, SOME T, mx) = Pretty.block (Pretty.str (Binding.name_of x ^ " ::") ::
   173           Pretty.brk 1 :: prt_typ T :: Pretty.brk 1 :: prt_mixfix mx)
   174       | prt_fix (x, NONE, mx) = Pretty.block (Pretty.str (Binding.name_of x) ::
   175           Pretty.brk 1 :: prt_mixfix mx);
   176     fun prt_constrain (x, T) = prt_fix (Binding.name x, SOME T, NoSyn);
   177 
   178     fun prt_asm (a, ts) =
   179       Pretty.block (Pretty.breaks (prt_name_atts a ":" @ map (prt_term o fst) ts));
   180     fun prt_def (a, (t, _)) =
   181       Pretty.block (Pretty.breaks (prt_name_atts a ":" @ [prt_term t]));
   182 
   183     fun prt_fact (ths, []) = map prt_thm ths
   184       | prt_fact (ths, atts) = Pretty.enclose "(" ")"
   185           (Pretty.breaks (map prt_thm ths)) :: Attrib.pretty_attribs ctxt atts;
   186     fun prt_note (a, ths) =
   187       Pretty.block (Pretty.breaks (flat (prt_name_atts a "=" :: map prt_fact ths)));
   188   in
   189     fn Fixes fixes => pretty_items "fixes" "and" (map prt_fix fixes)
   190      | Constrains xs => pretty_items "constrains" "and" (map prt_constrain xs)
   191      | Assumes asms => pretty_items "assumes" "and" (map prt_asm asms)
   192      | Defines defs => pretty_items "defines" "and" (map prt_def defs)
   193      | Notes ("", facts) => pretty_items "notes" "and" (map prt_note facts)
   194      | Notes (kind, facts) => pretty_items ("notes " ^ kind) "and" (map prt_note facts)
   195   end;
   196 
   197 
   198 (* pretty_statement *)
   199 
   200 local
   201 
   202 fun thm_name kind th prts =
   203   let val head =
   204     if Thm.has_name_hint th then
   205       Pretty.block [Pretty.command kind,
   206         Pretty.brk 1, Pretty.str (Long_Name.base_name (Thm.get_name_hint th) ^ ":")]
   207     else Pretty.command kind
   208   in Pretty.block (Pretty.fbreaks (head :: prts)) end;
   209 
   210 fun fix (x, T) = (Binding.name x, SOME T);
   211 
   212 fun obtain prop ctxt =
   213   let
   214     val ((xs, prop'), ctxt') = Variable.focus prop ctxt;
   215     val As = Logic.strip_imp_prems (Thm.term_of prop');
   216   in ((Binding.empty, (map (fix o Term.dest_Free o Thm.term_of o #2) xs, As)), ctxt') end;
   217 
   218 in
   219 
   220 fun pretty_statement ctxt kind raw_th =
   221   let
   222     val thy = ProofContext.theory_of ctxt;
   223     val cert = Thm.cterm_of thy;
   224 
   225     val th = MetaSimplifier.norm_hhf raw_th;
   226     val is_elim = Object_Logic.is_elim th;
   227 
   228     val ((_, [th']), ctxt') = Variable.import true [th] (Variable.set_body false ctxt);
   229     val prop = Thm.prop_of th';
   230     val (prems, concl) = Logic.strip_horn prop;
   231     val concl_term = Object_Logic.drop_judgment thy concl;
   232 
   233     val fixes = fold_aterms (fn v as Free (x, T) =>
   234         if Variable.newly_fixed ctxt' ctxt x andalso not (v aconv concl_term)
   235         then insert (op =) (x, T) else I | _ => I) prop [] |> rev;
   236     val (assumes, cases) = take_suffix (fn prem =>
   237       is_elim andalso concl aconv Logic.strip_assums_concl prem) prems;
   238   in
   239     pretty_ctxt ctxt' (Fixes (map (fn (x, T) => (Binding.name x, SOME T, NoSyn)) fixes)) @
   240     pretty_ctxt ctxt' (Assumes (map (fn t => (Attrib.empty_binding, [(t, [])])) assumes)) @
   241      (if null cases then pretty_stmt ctxt' (Shows [(Attrib.empty_binding, [(concl, [])])])
   242       else
   243         let val (clauses, ctxt'') = fold_map (obtain o cert) cases ctxt'
   244         in pretty_stmt ctxt'' (Obtains clauses) end)
   245   end |> thm_name kind raw_th;
   246 
   247 end;
   248 
   249 
   250 
   251 (** logical operations **)
   252 
   253 (* witnesses -- hypotheses as protected facts *)
   254 
   255 datatype witness = Witness of term * thm;
   256 
   257 val mark_witness = Logic.protect;
   258 fun witness_prop (Witness (t, _)) = t;
   259 fun witness_hyps (Witness (_, th)) = #hyps (Thm.rep_thm th);
   260 fun map_witness f (Witness witn) = Witness (f witn);
   261 
   262 fun morph_witness phi = map_witness (fn (t, th) => (Morphism.term phi t, Morphism.thm phi th));
   263 
   264 fun prove_witness ctxt t tac =
   265   Witness (t, Thm.close_derivation (Goal.prove ctxt [] [] (mark_witness t) (fn _ =>
   266     Tactic.rtac Drule.protectI 1 THEN tac)));
   267 
   268 
   269 local
   270 
   271 val refine_witness =
   272   Proof.refine (Method.Basic (K (RAW_METHOD
   273     (K (ALLGOALS
   274       (CONJUNCTS (ALLGOALS
   275         (CONJUNCTS (TRYALL (Tactic.rtac Drule.protectI))))))))));
   276 
   277 fun gen_witness_proof proof after_qed wit_propss eq_props =
   278   let
   279     val propss = (map o map) (fn prop => (mark_witness prop, [])) wit_propss
   280       @ [map (rpair []) eq_props];
   281     fun after_qed' thmss =
   282       let val (wits, eqs) = split_last ((map o map) Thm.close_derivation thmss);
   283       in after_qed ((map2 o map2) (curry Witness) wit_propss wits) eqs end;
   284   in proof after_qed' propss #> refine_witness #> Seq.hd end;
   285 
   286 in
   287 
   288 fun witness_proof after_qed wit_propss =
   289   gen_witness_proof (Proof.theorem_i NONE) (fn wits => fn _ => after_qed wits)
   290     wit_propss [];
   291 
   292 val witness_proof_eqs = gen_witness_proof (Proof.theorem_i NONE);
   293 
   294 fun witness_local_proof after_qed cmd wit_propss goal_ctxt int =
   295   gen_witness_proof (fn after_qed' => fn propss =>
   296     Proof.map_context (K goal_ctxt)
   297     #> Proof.local_goal (Proof_Display.print_results int) (K I) ProofContext.bind_propp_i
   298       cmd NONE after_qed' (map (pair Thm.empty_binding) propss))
   299     (fn wits => fn _ => after_qed wits) wit_propss [];
   300 
   301 end;
   302 
   303 
   304 fun compose_witness (Witness (_, th)) r =
   305   let
   306     val th' = Goal.conclude th;
   307     val A = Thm.cprem_of r 1;
   308   in
   309     Thm.implies_elim
   310       (Conv.gconv_rule Drule.beta_eta_conversion 1 r)
   311       (Conv.fconv_rule Drule.beta_eta_conversion
   312         (Thm.instantiate (Thm.match (Thm.cprop_of th', A)) th'))
   313   end;
   314 
   315 fun conclude_witness (Witness (_, th)) =
   316   Thm.close_derivation (MetaSimplifier.norm_hhf_protect (Goal.conclude th));
   317 
   318 fun pretty_witness ctxt witn =
   319   let val prt_term = Pretty.quote o Syntax.pretty_term ctxt in
   320     Pretty.block (prt_term (witness_prop witn) ::
   321       (if ! show_hyps then [Pretty.brk 2, Pretty.list "[" "]"
   322          (map prt_term (witness_hyps witn))] else []))
   323   end;
   324 
   325 
   326 (* derived rules *)
   327 
   328 fun instantiate_tfrees thy subst th =
   329   let
   330     val certT = Thm.ctyp_of thy;
   331     val idx = Thm.maxidx_of th + 1;
   332     fun cert_inst (a, (S, T)) = (certT (TVar ((a, idx), S)), certT T);
   333 
   334     fun add_inst (a, S) insts =
   335       if AList.defined (op =) insts a then insts
   336       else (case AList.lookup (op =) subst a of NONE => insts | SOME T => (a, (S, T)) :: insts);
   337     val insts =
   338       Term.fold_types (Term.fold_atyps (fn TFree v => add_inst v | _ => I))
   339         (Thm.full_prop_of th) [];
   340   in
   341     th
   342     |> Thm.generalize (map fst insts, []) idx
   343     |> Thm.instantiate (map cert_inst insts, [])
   344   end;
   345 
   346 fun instantiate_frees thy subst =
   347   let val cert = Thm.cterm_of thy in
   348     Drule.forall_intr_list (map (cert o Free o fst) subst) #>
   349     Drule.forall_elim_list (map (cert o snd) subst)
   350   end;
   351 
   352 fun hyps_rule rule th =
   353   let val {hyps, ...} = Thm.crep_thm th in
   354     Drule.implies_elim_list
   355       (rule (Drule.implies_intr_list hyps th))
   356       (map (Thm.assume o Drule.cterm_rule rule) hyps)
   357   end;
   358 
   359 
   360 (* instantiate types *)
   361 
   362 fun instT_type env =
   363   if Symtab.is_empty env then I
   364   else Term.map_type_tfree (fn (x, S) => the_default (TFree (x, S)) (Symtab.lookup env x));
   365 
   366 fun instT_term env =
   367   if Symtab.is_empty env then I
   368   else Term.map_types (instT_type env);
   369 
   370 fun instT_subst env th = (Thm.fold_terms o Term.fold_types o Term.fold_atyps)
   371   (fn T as TFree (a, _) =>
   372     let val T' = the_default T (Symtab.lookup env a)
   373     in if T = T' then I else insert (op =) (a, T') end
   374   | _ => I) th [];
   375 
   376 fun instT_thm thy env th =
   377   if Symtab.is_empty env then th
   378   else
   379     let val subst = instT_subst env th
   380     in if null subst then th else th |> hyps_rule (instantiate_tfrees thy subst) end;
   381 
   382 fun instT_morphism thy env =
   383   let val thy_ref = Theory.check_thy thy in
   384     Morphism.morphism
   385      {binding = I,
   386       typ = instT_type env,
   387       term = instT_term env,
   388       fact = map (fn th => instT_thm (Theory.deref thy_ref) env th)}
   389   end;
   390 
   391 
   392 (* instantiate types and terms *)
   393 
   394 fun inst_term (envT, env) =
   395   if Symtab.is_empty env then instT_term envT
   396   else
   397     let
   398       val instT = instT_type envT;
   399       fun inst (Const (x, T)) = Const (x, instT T)
   400         | inst (Free (x, T)) =
   401             (case Symtab.lookup env x of
   402               NONE => Free (x, instT T)
   403             | SOME t => t)
   404         | inst (Var (xi, T)) = Var (xi, instT T)
   405         | inst (b as Bound _) = b
   406         | inst (Abs (x, T, t)) = Abs (x, instT T, inst t)
   407         | inst (t $ u) = inst t $ inst u;
   408     in Envir.beta_norm o inst end;
   409 
   410 fun inst_thm thy (envT, env) th =
   411   if Symtab.is_empty env then instT_thm thy envT th
   412   else
   413     let
   414       val substT = instT_subst envT th;
   415       val subst = (Thm.fold_terms o Term.fold_aterms)
   416        (fn Free (x, T) =>
   417           let
   418             val T' = instT_type envT T;
   419             val t = Free (x, T');
   420             val t' = the_default t (Symtab.lookup env x);
   421           in if t aconv t' then I else insert (eq_fst (op =)) ((x, T'), t') end
   422        | _ => I) th [];
   423     in
   424       if null substT andalso null subst then th
   425       else th |> hyps_rule
   426        (instantiate_tfrees thy substT #>
   427         instantiate_frees thy subst #>
   428         Conv.fconv_rule (Thm.beta_conversion true))
   429     end;
   430 
   431 fun inst_morphism thy envs =
   432   let val thy_ref = Theory.check_thy thy in
   433     Morphism.morphism
   434      {binding = I,
   435       typ = instT_type (#1 envs),
   436       term = inst_term envs,
   437       fact = map (fn th => inst_thm (Theory.deref thy_ref) envs th)}
   438   end;
   439 
   440 
   441 (* satisfy hypotheses *)
   442 
   443 fun satisfy_thm witns thm = thm |> fold (fn hyp =>
   444     (case find_first (fn Witness (t, _) => Thm.term_of hyp aconv t) witns of
   445       NONE => I
   446     | SOME w => Thm.implies_intr hyp #> compose_witness w)) (#hyps (Thm.crep_thm thm));
   447 
   448 val satisfy_morphism = Morphism.thm_morphism o satisfy_thm;
   449 val satisfy_facts = facts_map o morph_ctxt o satisfy_morphism;
   450 
   451 
   452 (* rewriting with equalities *)
   453 
   454 fun eq_morphism thy thms = Morphism.morphism
   455  {binding = I,
   456   typ = I,
   457   term = MetaSimplifier.rewrite_term thy thms [],
   458   fact = map (MetaSimplifier.rewrite_rule thms)};
   459 
   460 
   461 (* generalize type/term parameters *)
   462 
   463 val maxidx_atts = fold Args.maxidx_values;
   464 
   465 fun generalize_facts inner outer facts =
   466   let
   467     val thy = ProofContext.theory_of inner;
   468     val maxidx =
   469       fold (fn ((_, atts), bs) => maxidx_atts atts #> fold (maxidx_atts o #2) bs) facts ~1;
   470     val exp_fact = map (Thm.adjust_maxidx_thm maxidx) #> Variable.export inner outer;
   471     val exp_term = Drule.term_rule thy (singleton exp_fact);
   472     val exp_typ = Logic.type_map exp_term;
   473     val morphism = Morphism.morphism {binding = I, typ = exp_typ, term = exp_term, fact = exp_fact};
   474   in facts_map (morph_ctxt morphism) facts end;
   475 
   476 
   477 (* transfer to theory using closure *)
   478 
   479 fun transfer_morphism thy =
   480   let val thy_ref = Theory.check_thy thy
   481   in Morphism.thm_morphism (fn th => transfer (Theory.deref thy_ref) th) end;
   482 
   483 
   484 
   485 (** activate in context **)
   486 
   487 (* init *)
   488 
   489 fun init (Fixes fixes) = Context.map_proof (ProofContext.add_fixes fixes #> #2)
   490   | init (Constrains _) = I
   491   | init (Assumes asms) = Context.map_proof (fn ctxt =>
   492       let
   493         val asms' = Attrib.map_specs (Attrib.attribute_i (ProofContext.theory_of ctxt)) asms;
   494         val (_, ctxt') = ctxt
   495           |> fold Variable.auto_fixes (maps (map #1 o #2) asms')
   496           |> ProofContext.add_assms_i Assumption.assume_export asms';
   497       in ctxt' end)
   498   | init (Defines defs) = Context.map_proof (fn ctxt =>
   499       let
   500         val defs' = Attrib.map_specs (Attrib.attribute_i (ProofContext.theory_of ctxt)) defs;
   501         val asms = defs' |> map (fn ((name, atts), (t, ps)) =>
   502             let val ((c, _), t') = Local_Defs.cert_def ctxt t  (* FIXME adapt ps? *)
   503             in (t', ((Thm.def_binding_optional (Binding.name c) name, atts), [(t', ps)])) end);
   504         val (_, ctxt') = ctxt
   505           |> fold Variable.auto_fixes (map #1 asms)
   506           |> ProofContext.add_assms_i Local_Defs.def_export (map #2 asms);
   507       in ctxt' end)
   508   | init (Notes (kind, facts)) = (fn context =>
   509       let
   510         val facts' = Attrib.map_facts (Attrib.attribute_i (Context.theory_of context)) facts;
   511         val context' = context |> Context.mapping
   512           (PureThy.note_thmss kind facts' #> #2)
   513           (ProofContext.note_thmss kind facts' #> #2);
   514       in context' end);
   515 
   516 
   517 (* activate *)
   518 
   519 fun activate_i elem ctxt =
   520   let
   521     val elem' = map_ctxt_attrib Args.assignable elem;
   522     val ctxt' = Context.proof_map (init elem') ctxt;
   523   in (map_ctxt_attrib Args.closure elem', ctxt') end;
   524 
   525 fun activate raw_elem ctxt =
   526   let val elem = raw_elem |> map_ctxt
   527    {binding = tap Name.of_binding,
   528     typ = I,
   529     term = I,
   530     pattern = I,
   531     fact = ProofContext.get_fact ctxt,
   532     attrib = Attrib.intern_src (ProofContext.theory_of ctxt)}
   533   in activate_i elem ctxt end;
   534 
   535 end;