src/Tools/quickcheck.ML
author wenzelm
Sun Mar 07 12:19:47 2010 +0100 (2010-03-07)
changeset 35625 9c818cab0dd0
parent 35380 6ac5b81a763d
child 36610 bafd82950e24
permissions -rw-r--r--
modernized structure Object_Logic;
     1 (*  Title:      Tools/quickcheck.ML
     2     Author:     Stefan Berghofer, Florian Haftmann, TU Muenchen
     3 
     4 Generic counterexample search engine.
     5 *)
     6 
     7 signature QUICKCHECK =
     8 sig
     9   val auto: bool Unsynchronized.ref
    10   val timing : bool Unsynchronized.ref
    11   datatype report = Report of
    12     { iterations : int, raised_match_errors : int,
    13       satisfied_assms : int list, positive_concl_tests : int }
    14   val gen_test_term: Proof.context -> bool -> bool -> string option -> int -> int -> term ->
    15     (string * term) list option * ((string * int) list * ((int * report list) list) option)
    16   val test_term: Proof.context -> bool -> string option -> int -> int -> term ->
    17     (string * term) list option
    18   val add_generator:
    19     string * (Proof.context -> bool -> term -> int -> term list option * (bool list * bool))
    20       -> theory -> theory
    21   val setup: theory -> theory
    22   val quickcheck: (string * string) list -> int -> Proof.state -> (string * term) list option
    23 end;
    24 
    25 structure Quickcheck : QUICKCHECK =
    26 struct
    27 
    28 (* preferences *)
    29 
    30 val auto = Unsynchronized.ref false;
    31 
    32 val timing = Unsynchronized.ref false;
    33 
    34 val _ =
    35   ProofGeneralPgip.add_preference Preferences.category_tracing
    36   (setmp_CRITICAL auto true (fn () =>
    37     Preferences.bool_pref auto
    38       "auto-quickcheck"
    39       "Whether to run Quickcheck automatically.") ());
    40 
    41 (* quickcheck report *)
    42 
    43 datatype single_report = Run of bool list * bool | MatchExc
    44 
    45 datatype report = Report of
    46   { iterations : int, raised_match_errors : int,
    47     satisfied_assms : int list, positive_concl_tests : int }
    48 
    49 fun collect_single_report single_report
    50     (Report {iterations = iterations, raised_match_errors = raised_match_errors,
    51     satisfied_assms = satisfied_assms, positive_concl_tests = positive_concl_tests}) =
    52   case single_report
    53   of MatchExc =>
    54     Report {iterations = iterations + 1, raised_match_errors = raised_match_errors + 1,
    55       satisfied_assms = satisfied_assms, positive_concl_tests = positive_concl_tests}
    56    | Run (assms, concl) =>
    57     Report {iterations = iterations + 1, raised_match_errors = raised_match_errors,
    58       satisfied_assms =
    59         map2 (fn b => fn s => if b then s + 1 else s) assms
    60          (if null satisfied_assms then replicate (length assms) 0 else satisfied_assms),
    61       positive_concl_tests = if concl then positive_concl_tests + 1 else positive_concl_tests}
    62 
    63 (* quickcheck configuration -- default parameters, test generators *)
    64 
    65 datatype test_params = Test_Params of
    66   { size: int, iterations: int, default_type: typ option, no_assms: bool, report: bool, quiet : bool};
    67 
    68 fun dest_test_params (Test_Params { size, iterations, default_type, no_assms, report, quiet }) =
    69   ((size, iterations), ((default_type, no_assms), (report, quiet)));
    70 fun make_test_params ((size, iterations), ((default_type, no_assms), (report, quiet))) =
    71   Test_Params { size = size, iterations = iterations, default_type = default_type,
    72                 no_assms = no_assms, report = report, quiet = quiet };
    73 fun map_test_params f (Test_Params { size, iterations, default_type, no_assms, report, quiet }) =
    74   make_test_params (f ((size, iterations), ((default_type, no_assms), (report, quiet))));
    75 fun merge_test_params (Test_Params { size = size1, iterations = iterations1, default_type = default_type1,
    76                                      no_assms = no_assms1, report = report1, quiet = quiet1 },
    77   Test_Params { size = size2, iterations = iterations2, default_type = default_type2,
    78                 no_assms = no_assms2, report = report2, quiet = quiet2 }) =
    79   make_test_params ((Int.max (size1, size2), Int.max (iterations1, iterations2)),
    80     ((case default_type1 of NONE => default_type2 | _ => default_type1, no_assms1 orelse no_assms2),
    81     (report1 orelse report2, quiet1 orelse quiet2)));
    82 
    83 structure Data = Theory_Data
    84 (
    85   type T = (string * (Proof.context -> bool -> term -> int -> term list option * (bool list * bool))) list
    86     * test_params;
    87   val empty = ([], Test_Params
    88     { size = 10, iterations = 100, default_type = NONE, no_assms = false, report = false, quiet = false});
    89   val extend = I;
    90   fun merge ((generators1, params1), (generators2, params2)) : T =
    91     (AList.merge (op =) (K true) (generators1, generators2),
    92       merge_test_params (params1, params2));
    93 );
    94 
    95 val add_generator = Data.map o apfst o AList.update (op =);
    96 
    97 (* generating tests *)
    98 
    99 fun mk_tester_select name ctxt =
   100   case AList.lookup (op =) ((fst o Data.get o ProofContext.theory_of) ctxt) name
   101    of NONE => error ("No such quickcheck generator: " ^ name)
   102     | SOME generator => generator ctxt;
   103 
   104 fun mk_testers ctxt report t =
   105   (map snd o fst o Data.get o ProofContext.theory_of) ctxt
   106   |> map_filter (fn generator => try (generator ctxt report) t);
   107 
   108 fun mk_testers_strict ctxt report t =
   109   let
   110     val generators = ((map snd o fst o Data.get o ProofContext.theory_of) ctxt)
   111     val testers = map (fn generator => Exn.capture (generator ctxt report) t) generators;
   112   in if forall (is_none o Exn.get_result) testers
   113     then [(Exn.release o snd o split_last) testers]
   114     else map_filter Exn.get_result testers
   115   end;
   116 
   117 
   118 (* testing propositions *)
   119 
   120 fun prep_test_term t =
   121   let
   122     val _ = (null (Term.add_tvars t []) andalso null (Term.add_tfrees t [])) orelse
   123       error "Term to be tested contains type variables";
   124     val _ = null (Term.add_vars t []) orelse
   125       error "Term to be tested contains schematic variables";
   126     val frees = Term.add_frees t [];
   127   in (map fst frees, list_abs_free (frees, t)) end
   128 
   129 fun cpu_time description f =
   130   let
   131     val start = start_timing ()
   132     val result = Exn.capture f ()
   133     val time = Time.toMilliseconds (#cpu (end_timing start))
   134   in (Exn.release result, (description, time)) end
   135 
   136 fun gen_test_term ctxt quiet report generator_name size i t =
   137   let
   138     val (names, t') = prep_test_term t;
   139     val (testers, comp_time) = cpu_time "quickcheck compilation"
   140       (fn () => (case generator_name
   141        of NONE => if quiet then mk_testers ctxt report t' else mk_testers_strict ctxt report t'
   142         | SOME name => [mk_tester_select name ctxt report t']));
   143     fun iterate f 0 report = (NONE, report)
   144       | iterate f j report =
   145         let
   146           val (test_result, single_report) = apsnd Run (f ()) handle Match => (if quiet then ()
   147              else warning "Exception Match raised during quickcheck"; (NONE, MatchExc))
   148           val report = collect_single_report single_report report
   149         in
   150           case test_result of NONE => iterate f (j - 1) report | SOME q => (SOME q, report)
   151         end
   152     val empty_report = Report { iterations = 0, raised_match_errors = 0,
   153       satisfied_assms = [], positive_concl_tests = 0 }
   154     fun with_testers k [] = (NONE, [])
   155       | with_testers k (tester :: testers) =
   156           case iterate (fn () => tester (k - 1)) i empty_report
   157            of (NONE, report) => apsnd (cons report) (with_testers k testers)
   158             | (SOME q, report) => (SOME q, [report]);
   159     fun with_size k reports = if k > size then (NONE, reports)
   160       else (if quiet then () else priority ("Test data size: " ^ string_of_int k);
   161         let
   162           val (result, new_report) = with_testers k testers
   163           val reports = ((k, new_report) :: reports)
   164         in case result of NONE => with_size (k + 1) reports | SOME q => (SOME q, reports) end);
   165     val ((result, reports), exec_time) = cpu_time "quickcheck execution"
   166       (fn () => apfst
   167          (fn result => case result of NONE => NONE
   168         | SOME ts => SOME (names ~~ ts)) (with_size 1 []))
   169   in
   170     (result, ([exec_time, comp_time], if report then SOME reports else NONE))
   171   end;
   172 
   173 fun test_term ctxt quiet generator_name size i t =
   174   fst (gen_test_term ctxt quiet false generator_name size i t)
   175 
   176 fun monomorphic_term thy insts default_T = 
   177   let
   178     fun subst (T as TFree (v, S)) =
   179           let
   180             val T' = AList.lookup (op =) insts v
   181               |> the_default (the_default T default_T)
   182           in if Sign.of_sort thy (T, S) then T'
   183             else error ("Type " ^ Syntax.string_of_typ_global thy T ^
   184               " to be substituted for variable " ^
   185               Syntax.string_of_typ_global thy T ^ "\ndoes not have sort " ^
   186               Syntax.string_of_sort_global thy S)
   187           end
   188       | subst T = T;
   189   in (map_types o map_atyps) subst end;
   190 
   191 fun test_goal quiet report generator_name size iterations default_T no_assms insts i assms state =
   192   let
   193     val ctxt = Proof.context_of state;
   194     val thy = Proof.theory_of state;
   195     fun strip (Const ("all", _) $ Abs (_, _, t)) = strip t
   196       | strip t = t;
   197     val {goal = st, ...} = Proof.raw_goal state;
   198     val (gi, frees) = Logic.goal_params (prop_of st) i;
   199     val gi' = Logic.list_implies (if no_assms then [] else assms,
   200                                   subst_bounds (frees, strip gi))
   201       |> monomorphic_term thy insts default_T
   202       |> Object_Logic.atomize_term thy;
   203   in gen_test_term ctxt quiet report generator_name size iterations gi' end;
   204 
   205 fun pretty_counterex ctxt NONE = Pretty.str "Quickcheck found no counterexample."
   206   | pretty_counterex ctxt (SOME cex) =
   207       Pretty.chunks (Pretty.str "Quickcheck found a counterexample:\n" ::
   208         map (fn (s, t) =>
   209           Pretty.block [Pretty.str (s ^ " ="), Pretty.brk 1, Syntax.pretty_term ctxt t]) cex);
   210 
   211 fun pretty_report (Report {iterations = iterations, raised_match_errors = raised_match_errors,
   212     satisfied_assms = satisfied_assms, positive_concl_tests = positive_concl_tests}) =
   213   let
   214     fun pretty_stat s i = Pretty.block ([Pretty.str (s ^ ": " ^ string_of_int i)])
   215   in
   216      ([pretty_stat "iterations" iterations,
   217      pretty_stat "match exceptions" raised_match_errors]
   218      @ map_index (fn (i, n) => pretty_stat ("satisfied " ^ string_of_int (i + 1) ^ ". assumption") n)
   219        satisfied_assms
   220      @ [pretty_stat "positive conclusion tests" positive_concl_tests])
   221   end
   222 
   223 fun pretty_reports' [report] = [Pretty.chunks (pretty_report report)]
   224   | pretty_reports' reports =
   225   map_index (fn (i, report) =>
   226     Pretty.chunks (Pretty.str (string_of_int (i + 1) ^ ". generator:\n") :: pretty_report report))
   227     reports
   228 
   229 fun pretty_reports ctxt (SOME reports) =
   230   Pretty.chunks (Pretty.str "Quickcheck report:" ::
   231     maps (fn (size, reports) =>
   232       Pretty.str ("size " ^ string_of_int size ^ ":") :: pretty_reports' reports @ [Pretty.brk 1])
   233       (rev reports))
   234   | pretty_reports ctxt NONE = Pretty.str ""
   235 
   236 fun pretty_counterex_and_reports ctxt (cex, (timing, reports)) =
   237   Pretty.chunks [pretty_counterex ctxt cex, pretty_reports ctxt reports]
   238 
   239 (* automatic testing *)
   240 
   241 fun auto_quickcheck state =
   242   if not (!auto) then
   243     (false, state)
   244   else
   245     let
   246       val ctxt = Proof.context_of state;
   247       val assms = map term_of (Assumption.all_assms_of ctxt);
   248       val Test_Params { size, iterations, default_type, no_assms, report, quiet } =
   249         (snd o Data.get o Proof.theory_of) state;
   250       val res =
   251         try (test_goal true false NONE size iterations default_type no_assms [] 1 assms) state;
   252     in
   253       case res of
   254         NONE => (false, state)
   255       | SOME (NONE, report) => (false, state)
   256       | SOME (cex, report) => (true, Proof.goal_message (K (Pretty.chunks [Pretty.str "",
   257           Pretty.mark Markup.hilite (pretty_counterex ctxt cex)])) state)
   258     end
   259 
   260 val setup = Auto_Counterexample.register_tool ("quickcheck", auto_quickcheck)
   261 
   262 
   263 (* Isar commands *)
   264 
   265 fun read_nat s = case (Library.read_int o Symbol.explode) s
   266  of (k, []) => if k >= 0 then k
   267       else error ("Not a natural number: " ^ s)
   268   | (_, _ :: _) => error ("Not a natural number: " ^ s);
   269 fun read_bool "false" = false
   270   | read_bool "true" = true
   271   | read_bool s = error ("Not a Boolean value: " ^ s)
   272 
   273 fun parse_test_param ctxt ("size", arg) =
   274       (apfst o apfst o K) (read_nat arg)
   275   | parse_test_param ctxt ("iterations", arg) =
   276       (apfst o apsnd o K) (read_nat arg)
   277   | parse_test_param ctxt ("default_type", arg) =
   278       (apsnd o apfst o apfst o K o SOME) (ProofContext.read_typ ctxt arg)
   279   | parse_test_param ctxt ("no_assms", arg) =
   280       (apsnd o apfst o apsnd o K) (read_bool arg)
   281   | parse_test_param ctxt ("report", arg) =
   282       (apsnd o apsnd o apfst o K) (read_bool arg)
   283   | parse_test_param ctxt ("quiet", arg) =
   284       (apsnd o apsnd o apsnd o K) (read_bool arg)
   285   | parse_test_param ctxt (name, _) =
   286       error ("Unknown test parameter: " ^ name);
   287 
   288 fun parse_test_param_inst ctxt ("generator", arg) =
   289       (apsnd o apfst o K o SOME) arg
   290   | parse_test_param_inst ctxt (name, arg) =
   291       case try (ProofContext.read_typ ctxt) name
   292        of SOME (TFree (v, _)) => (apsnd o apsnd o AList.update (op =))
   293               (v, ProofContext.read_typ ctxt arg)
   294         | _ => (apfst o parse_test_param ctxt) (name, arg);
   295 
   296 fun quickcheck_params_cmd args thy =
   297   let
   298     val ctxt = ProofContext.init thy;
   299     val f = fold (parse_test_param ctxt) args;
   300   in
   301     thy
   302     |> (Data.map o apsnd o map_test_params) f
   303   end;
   304 
   305 fun gen_quickcheck args i state =
   306   let
   307     val thy = Proof.theory_of state;
   308     val ctxt = Proof.context_of state;
   309     val assms = map term_of (Assumption.all_assms_of ctxt);
   310     val default_params = (dest_test_params o snd o Data.get) thy;
   311     val f = fold (parse_test_param_inst ctxt) args;
   312     val (((size, iterations), ((default_type, no_assms), (report, quiet))), (generator_name, insts)) =
   313       f (default_params, (NONE, []));
   314   in
   315     test_goal quiet report generator_name size iterations default_type no_assms insts i assms state
   316   end;
   317 
   318 fun quickcheck args i state = fst (gen_quickcheck args i state)
   319 
   320 fun quickcheck_cmd args i state =
   321   gen_quickcheck args i (Toplevel.proof_of state)
   322   |> Pretty.writeln o pretty_counterex_and_reports (Toplevel.context_of state);
   323 
   324 local structure P = OuterParse and K = OuterKeyword in
   325 
   326 val parse_arg = P.name -- (Scan.optional (P.$$$ "=" |-- P.name) "true")
   327 
   328 val parse_args = P.$$$ "[" |-- P.list1 parse_arg --| P.$$$ "]"
   329   || Scan.succeed [];
   330 
   331 val _ = OuterSyntax.command "quickcheck_params" "set parameters for random testing" K.thy_decl
   332   (parse_args >> (fn args => Toplevel.theory (quickcheck_params_cmd args)));
   333 
   334 val _ = OuterSyntax.improper_command "quickcheck" "try to find counterexample for subgoal" K.diag
   335   (parse_args -- Scan.optional P.nat 1
   336     >> (fn (args, i) => Toplevel.no_timing o Toplevel.keep (quickcheck_cmd args i)));
   337 
   338 end; (*local*)
   339 
   340 end;
   341 
   342 
   343 val auto_quickcheck = Quickcheck.auto;