src/Pure/library.ML
author wenzelm
Wed Jul 13 20:13:27 2011 +0200 (2011-07-13)
changeset 43793 9c9a9b13c5da
parent 43652 dcd0b667f73d
child 44617 5db68864a967
permissions -rw-r--r--
low-level tuning;
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*user errors*)
    32   exception ERROR of string
    33   val error: string -> 'a
    34   val cat_error: string -> string -> 'a
    35   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    36 
    37   (*pairs*)
    38   val pair: 'a -> 'b -> 'a * 'b
    39   val rpair: 'a -> 'b -> 'b * 'a
    40   val fst: 'a * 'b -> 'a
    41   val snd: 'a * 'b -> 'b
    42   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    43   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    44   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val swap: 'a * 'b -> 'b * 'a
    46   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    47   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    48   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    49 
    50   (*booleans*)
    51   val equal: ''a -> ''a -> bool
    52   val not_equal: ''a -> ''a -> bool
    53   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    54   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    55   val exists: ('a -> bool) -> 'a list -> bool
    56   val forall: ('a -> bool) -> 'a list -> bool
    57   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    58   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    59 
    60   (*lists*)
    61   val single: 'a -> 'a list
    62   val the_single: 'a list -> 'a
    63   val singleton: ('a list -> 'b list) -> 'a -> 'b
    64   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    65   val apply: ('a -> 'a) list -> 'a -> 'a
    66   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    67   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    68   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    69   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    70   val flat: 'a list list -> 'a list
    71   val unflat: 'a list list -> 'b list -> 'b list list
    72   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    73   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    74   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    75   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    76   val maps: ('a -> 'b list) -> 'a list -> 'b list
    77   val filter: ('a -> bool) -> 'a list -> 'a list
    78   val filter_out: ('a -> bool) -> 'a list -> 'a list
    79   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    80   val take: int -> 'a list -> 'a list
    81   val drop: int -> 'a list -> 'a list
    82   val chop: int -> 'a list -> 'a list * 'a list
    83   val chop_while: ('a -> bool) -> 'a list -> 'a list * 'a list
    84   val nth: 'a list -> int -> 'a
    85   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    86   val nth_drop: int -> 'a list -> 'a list
    87   val nth_list: 'a list list -> int -> 'a list
    88   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    89   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val map_range: (int -> 'a) -> int -> 'a list
    91   val split_last: 'a list -> 'a list * 'a
    92   val find_index: ('a -> bool) -> 'a list -> int
    93   val find_first: ('a -> bool) -> 'a list -> 'a option
    94   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    95   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    96   val eq_list: ('a * 'a -> bool) -> 'a list * 'a list -> bool
    97   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    98   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
    99   val fold_rev2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   100   val forall2: ('a -> 'b -> bool) -> 'a list -> 'b list -> bool
   101   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   102   val ~~ : 'a list * 'b list -> ('a * 'b) list
   103   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   104   val split_list: ('a * 'b) list -> 'a list * 'b list
   105   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   106   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   107   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   108   val separate: 'a -> 'a list -> 'a list
   109   val surround: 'a -> 'a list -> 'a list
   110   val replicate: int -> 'a -> 'a list
   111   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   112   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   114   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val prefixes1: 'a list -> 'a list list
   116   val prefixes: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118   val suffixes: 'a list -> 'a list list
   119 
   120   (*integers*)
   121   val upto: int * int -> int list
   122   val downto: int * int -> int list
   123   val radixpand: int * int -> int list
   124   val radixstring: int * string * int -> string
   125   val string_of_int: int -> string
   126   val signed_string_of_int: int -> string
   127   val string_of_indexname: string * int -> string
   128   val read_radix_int: int -> string list -> int * string list
   129   val read_int: string list -> int * string list
   130   val oct_char: string -> string
   131 
   132   (*strings*)
   133   val nth_string: string -> int -> string
   134   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   135   val exists_string: (string -> bool) -> string -> bool
   136   val forall_string: (string -> bool) -> string -> bool
   137   val first_field: string -> string -> (string * string) option
   138   val enclose: string -> string -> string -> string
   139   val unenclose: string -> string
   140   val quote: string -> string
   141   val space_implode: string -> string list -> string
   142   val commas: string list -> string
   143   val commas_quote: string list -> string
   144   val cat_lines: string list -> string
   145   val space_explode: string -> string -> string list
   146   val split_lines: string -> string list
   147   val prefix_lines: string -> string -> string
   148   val prefix: string -> string -> string
   149   val suffix: string -> string -> string
   150   val unprefix: string -> string -> string
   151   val unsuffix: string -> string -> string
   152   val replicate_string: int -> string -> string
   153   val translate_string: (string -> string) -> string -> string
   154   val match_string: string -> string -> bool
   155 
   156   (*reals*)
   157   val string_of_real: real -> string
   158   val signed_string_of_real: real -> string
   159   val smart_string_of_real: real -> string
   160 
   161   (*lists as sets -- see also Pure/General/ord_list.ML*)
   162   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   163   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   164   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   165   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   166   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   167   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   168   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   169   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   170   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   171   val eq_set: ('a * 'a -> bool) -> 'a list * 'a list -> bool
   172   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   173   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   174   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   175 
   176   (*lists as multisets*)
   177   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   178   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   179   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   180 
   181   (*orders*)
   182   val is_equal: order -> bool
   183   val rev_order: order -> order
   184   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   185   val bool_ord: bool * bool -> order
   186   val int_ord: int * int -> order
   187   val string_ord: string * string -> order
   188   val fast_string_ord: string * string -> order
   189   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   190   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   191   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   192   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   193   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   194   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   195   val sort_strings: string list -> string list
   196   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   197   val tag_list: int -> 'a list -> (int * 'a) list
   198   val untag_list: (int * 'a) list -> 'a list
   199   val order_list: (int * 'a) list -> 'a list
   200 
   201   (*random numbers*)
   202   exception RANDOM
   203   val random: unit -> real
   204   val random_range: int -> int -> int
   205   val one_of: 'a list -> 'a
   206   val frequency: (int * 'a) list -> 'a
   207 
   208   (*misc*)
   209   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   210   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   211     'a -> 'b -> 'c * 'b
   212   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   213   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   214   val legacy_gensym: string -> string
   215   type stamp = unit Unsynchronized.ref
   216   val stamp: unit -> stamp
   217   type serial = int
   218   val serial: unit -> serial
   219   val serial_string: unit -> string
   220   structure Object: sig type T = exn end
   221   val cd: string -> unit
   222   val pwd: unit -> string
   223   val getenv: string -> string
   224   val getenv_strict: string -> string
   225 end;
   226 
   227 signature LIBRARY =
   228 sig
   229   include BASIC_LIBRARY
   230   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   231   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   232   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   233 end;
   234 
   235 structure Library: LIBRARY =
   236 struct
   237 
   238 (* functions *)
   239 
   240 fun undefined _ = raise Match;
   241 
   242 fun I x = x;
   243 fun K x = fn _ => x;
   244 fun curry f x y = f (x, y);
   245 fun uncurry f (x, y) = f x y;
   246 
   247 (*conditional application*)
   248 fun b ? f = fn x => if b then f x else x;
   249 
   250 (*composition with multiple args*)
   251 fun (f oo g) x y = f (g x y);
   252 fun (f ooo g) x y z = f (g x y z);
   253 fun (f oooo g) x y z w = f (g x y z w);
   254 
   255 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   256 fun funpow (0 : int) _ = I
   257   | funpow n f = f #> funpow (n - 1) f;
   258 
   259 fun funpow_yield (0 : int) _ x = ([], x)
   260   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   261 
   262 
   263 (* user errors *)
   264 
   265 exception ERROR of string;
   266 fun error msg = raise ERROR msg;
   267 
   268 fun cat_error "" msg = error msg
   269   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   270 
   271 fun assert_all pred list msg =
   272   let
   273     fun ass [] = ()
   274       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   275   in ass list end;
   276 
   277 
   278 (* pairs *)
   279 
   280 fun pair x y = (x, y);
   281 fun rpair x y = (y, x);
   282 
   283 fun fst (x, y) = x;
   284 fun snd (x, y) = y;
   285 
   286 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   287 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   288 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   289 
   290 fun swap (x, y) = (y, x);
   291 
   292 fun apfst f (x, y) = (f x, y);
   293 fun apsnd f (x, y) = (x, f y);
   294 fun pairself f (x, y) = (f x, f y);
   295 
   296 
   297 (* booleans *)
   298 
   299 (*polymorphic equality*)
   300 fun equal x y = x = y;
   301 fun not_equal x y = x <> y;
   302 
   303 (*combining predicates*)
   304 fun p orf q = fn x => p x orelse q x;
   305 fun p andf q = fn x => p x andalso q x;
   306 
   307 val exists = List.exists;
   308 val forall = List.all;
   309 
   310 
   311 (* flags *)
   312 
   313 fun setmp_CRITICAL flag value f x =
   314   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   315 
   316 fun setmp_thread_data tag orig_data data f x =
   317   uninterruptible (fn restore_attributes => fn () =>
   318     let
   319       val _ = Thread.setLocal (tag, data);
   320       val result = Exn.capture (restore_attributes f) x;
   321       val _ = Thread.setLocal (tag, orig_data);
   322     in Exn.release result end) ();
   323 
   324 
   325 
   326 (** lists **)
   327 
   328 fun single x = [x];
   329 
   330 fun the_single [x] = x
   331   | the_single _ = raise Empty;
   332 
   333 fun singleton f x = the_single (f [x]);
   334 
   335 fun yield_singleton f x = f [x] #>> the_single;
   336 
   337 fun apply [] x = x
   338   | apply (f :: fs) x = apply fs (f x);
   339 
   340 fun perhaps_apply funs arg =
   341   let
   342     fun app [] res = res
   343       | app (f :: fs) (changed, x) =
   344           (case f x of
   345             NONE => app fs (changed, x)
   346           | SOME x' => app fs (true, x'));
   347   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   348 
   349 fun perhaps_loop f arg =
   350   let
   351     fun loop (changed, x) =
   352       (case f x of
   353         NONE => (changed, x)
   354       | SOME x' => loop (true, x'));
   355   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   356 
   357 
   358 (* fold -- old versions *)
   359 
   360 (*the following versions of fold are designed to fit nicely with infixes*)
   361 
   362 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   363     for operators that associate to the left (TAIL RECURSIVE)*)
   364 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   365   let fun itl (e, [])  = e
   366         | itl (e, a::l) = itl (f(e, a), l)
   367   in  itl end;
   368 
   369 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   370     for operators that associate to the right (not tail recursive)*)
   371 fun foldr f (l, e) =
   372   let fun itr [] = e
   373         | itr (a::l) = f(a, itr l)
   374   in  itr l  end;
   375 
   376 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   377     for operators that associate to the left (TAIL RECURSIVE)*)
   378 fun foldl1 f [] = raise Empty
   379   | foldl1 f (x :: xs) = foldl f (x, xs);
   380 
   381 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   382     for n > 0, operators that associate to the right (not tail recursive)*)
   383 fun foldr1 f [] = raise Empty
   384   | foldr1 f l =
   385       let fun itr [x] = x
   386             | itr (x::l) = f(x, itr l)
   387       in  itr l  end;
   388 
   389 fun foldl_map f =
   390   let
   391     fun fold_aux (x, []) = (x, [])
   392       | fold_aux (x, y :: ys) =
   393           let
   394             val (x', y') = f (x, y);
   395             val (x'', ys') = fold_aux (x', ys);
   396           in (x'', y' :: ys') end;
   397   in fold_aux end;
   398 
   399 
   400 (* basic list functions *)
   401 
   402 fun eq_list eq (list1, list2) =
   403   pointer_eq (list1, list2) orelse
   404     let
   405       fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   406         | eq_lst _ = true;
   407     in length list1 = length list2 andalso eq_lst (list1, list2) end;
   408 
   409 fun maps f [] = []
   410   | maps f (x :: xs) = f x @ maps f xs;
   411 
   412 val filter = List.filter;
   413 fun filter_out f = filter (not o f);
   414 val map_filter = List.mapPartial;
   415 
   416 fun take (0: int) xs = []
   417   | take _ [] = []
   418   | take n (x :: xs) = x :: take (n - 1) xs;
   419 
   420 fun drop (0: int) xs = xs
   421   | drop _ [] = []
   422   | drop n (x :: xs) = drop (n - 1) xs;
   423 
   424 fun chop (0: int) xs = ([], xs)
   425   | chop _ [] = ([], [])
   426   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   427 
   428 fun chop_while P [] = ([], [])
   429   | chop_while P (ys as x :: xs) =
   430       if P x then chop_while P xs |>> cons x else ([], ys);
   431 
   432 (*return nth element of a list, where 0 designates the first element;
   433   raise Subscript if list too short*)
   434 fun nth xs i = List.nth (xs, i);
   435 
   436 fun nth_list xss i = nth xss i handle General.Subscript => [];
   437 
   438 fun nth_map 0 f (x :: xs) = f x :: xs
   439   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   440   | nth_map (_: int) _ [] = raise Subscript;
   441 
   442 fun nth_drop n xs =
   443   List.take (xs, n) @ List.drop (xs, n + 1);
   444 
   445 fun map_index f =
   446   let
   447     fun mapp (_: int) [] = []
   448       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   449   in mapp 0 end;
   450 
   451 fun fold_index f =
   452   let
   453     fun fold_aux (_: int) [] y = y
   454       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   455   in fold_aux 0 end;
   456 
   457 fun map_range f i =
   458   let
   459     fun mapp (k: int) =
   460       if k < i then f k :: mapp (k + 1) else [];
   461   in mapp 0 end;
   462 
   463 (*rear decomposition*)
   464 fun split_last [] = raise Empty
   465   | split_last [x] = ([], x)
   466   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   467 
   468 (*find position of first element satisfying a predicate*)
   469 fun find_index pred =
   470   let fun find (_: int) [] = ~1
   471         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   472   in find 0 end;
   473 
   474 (*find first element satisfying predicate*)
   475 val find_first = List.find;
   476 
   477 (*get first element by lookup function*)
   478 fun get_first _ [] = NONE
   479   | get_first f (x :: xs) =
   480       (case f x of
   481         NONE => get_first f xs
   482       | some => some);
   483 
   484 fun get_index f =
   485   let
   486     fun get (_: int) [] = NONE
   487       | get i (x :: xs) =
   488           case f x
   489            of NONE => get (i + 1) xs
   490             | SOME y => SOME (i, y)
   491   in get 0 end;
   492 
   493 val flat = List.concat;
   494 
   495 fun unflat (xs :: xss) ys =
   496       let val (ps, qs) = chop (length xs) ys
   497       in ps :: unflat xss qs end
   498   | unflat [] [] = []
   499   | unflat _ _ = raise ListPair.UnequalLengths;
   500 
   501 fun burrow f xss = unflat xss (f (flat xss));
   502 
   503 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   504 
   505 fun fold_burrow f xss s =
   506   apfst (unflat xss) (f (flat xss) s);
   507 
   508 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   509 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   510   | separate _ xs = xs;
   511 
   512 fun surround s (x :: xs) = s :: x :: surround s xs
   513   | surround s [] = [s];
   514 
   515 (*make the list [x, x, ..., x] of length n*)
   516 fun replicate (n: int) x =
   517   let fun rep (0, xs) = xs
   518         | rep (n, xs) = rep (n - 1, x :: xs)
   519   in
   520     if n < 0 then raise Subscript
   521     else rep (n, [])
   522   end;
   523 
   524 
   525 (* direct product *)
   526 
   527 fun map_product f _ [] = []
   528   | map_product f [] _ = []
   529   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   530 
   531 fun fold_product f _ [] z = z
   532   | fold_product f [] _ z = z
   533   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   534 
   535 
   536 (* lists of pairs *)
   537 
   538 fun map2 _ [] [] = []
   539   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   540   | map2 _ _ _ = raise ListPair.UnequalLengths;
   541 
   542 fun fold2 f [] [] z = z
   543   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   544   | fold2 f _ _ _ = raise ListPair.UnequalLengths;
   545 
   546 fun fold_rev2 f [] [] z = z
   547   | fold_rev2 f (x :: xs) (y :: ys) z = f x y (fold_rev2 f xs ys z)
   548   | fold_rev2 f _ _ _ = raise ListPair.UnequalLengths;
   549 
   550 fun forall2 P [] [] = true
   551   | forall2 P (x :: xs) (y :: ys) = P x y andalso forall2 P xs ys
   552   | forall2 P _ _ = raise ListPair.UnequalLengths;
   553 
   554 fun map_split f [] = ([], [])
   555   | map_split f (x :: xs) =
   556       let
   557         val (y, w) = f x;
   558         val (ys, ws) = map_split f xs;
   559       in (y :: ys, w :: ws) end;
   560 
   561 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   562   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   563   | zip_options _ [] = []
   564   | zip_options [] _ = raise ListPair.UnequalLengths;
   565 
   566 (*combine two lists forming a list of pairs:
   567   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   568 fun [] ~~ [] = []
   569   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   570   | _ ~~ _ = raise ListPair.UnequalLengths;
   571 
   572 (*inverse of ~~; the old 'split':
   573   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   574 val split_list = ListPair.unzip;
   575 
   576 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   577 
   578 
   579 (* prefixes, suffixes *)
   580 
   581 fun is_prefix _ [] _ = true
   582   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   583   | is_prefix eq _ _ = false;
   584 
   585 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   586    where xi is the first element that does not satisfy the predicate*)
   587 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   588   let fun take (rxs, []) = (rev rxs, [])
   589         | take (rxs, x :: xs) =
   590             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   591   in  take([], xs)  end;
   592 
   593 fun chop_prefix eq ([], ys) = ([], ([], ys))
   594   | chop_prefix eq (xs, []) = ([], (xs, []))
   595   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   596       if eq (x, y) then
   597         let val (ps', xys'') = chop_prefix eq (xs', ys')
   598         in (x :: ps', xys'') end
   599       else ([], (xs, ys));
   600 
   601 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   602    where xi is the last element that does not satisfy the predicate*)
   603 fun take_suffix _ [] = ([], [])
   604   | take_suffix pred (x :: xs) =
   605       (case take_suffix pred xs of
   606         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   607       | (prfx, sffx) => (x :: prfx, sffx));
   608 
   609 fun prefixes1 [] = []
   610   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   611 
   612 fun prefixes xs = [] :: prefixes1 xs;
   613 
   614 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   615 fun suffixes xs = [] :: suffixes1 xs;
   616 
   617 
   618 
   619 (** integers **)
   620 
   621 (* lists of integers *)
   622 
   623 (*make the list [from, from + 1, ..., to]*)
   624 fun ((i: int) upto j) =
   625   if i > j then [] else i :: (i + 1 upto j);
   626 
   627 (*make the list [from, from - 1, ..., to]*)
   628 fun ((i: int) downto j) =
   629   if i < j then [] else i :: (i - 1 downto j);
   630 
   631 
   632 (* convert integers to strings *)
   633 
   634 (*expand the number in the given base;
   635   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   636 fun radixpand (base, num) : int list =
   637   let
   638     fun radix (n, tail) =
   639       if n < base then n :: tail
   640       else radix (n div base, (n mod base) :: tail)
   641   in radix (num, []) end;
   642 
   643 (*expands a number into a string of characters starting from "zerochar";
   644   example: radixstring (2, "0", 8) gives "1000"*)
   645 fun radixstring (base, zerochar, num) =
   646   let val offset = ord zerochar;
   647       fun chrof n = chr (offset + n)
   648   in implode (map chrof (radixpand (base, num))) end;
   649 
   650 
   651 local
   652   val zero = ord "0";
   653   val small = 10000: int;
   654   val small_table = Vector.tabulate (small, Int.toString);
   655 in
   656 
   657 fun string_of_int i =
   658   if i < 0 then Int.toString i
   659   else if i < 10 then chr (zero + i)
   660   else if i < small then Vector.sub (small_table, i)
   661   else Int.toString i;
   662 
   663 end;
   664 
   665 fun signed_string_of_int i =
   666   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   667 
   668 fun string_of_indexname (a, 0) = a
   669   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   670 
   671 
   672 (* read integers *)
   673 
   674 fun read_radix_int radix cs =
   675   let
   676     val zero = ord "0";
   677     val limit = zero + radix;
   678     fun scan (num, []) = (num, [])
   679       | scan (num, c :: cs) =
   680         if zero <= ord c andalso ord c < limit then
   681           scan (radix * num + (ord c - zero), cs)
   682         else (num, c :: cs);
   683   in scan (0, cs) end;
   684 
   685 val read_int = read_radix_int 10;
   686 
   687 fun oct_char s = chr (#1 (read_radix_int 8 (raw_explode s)));
   688 
   689 
   690 
   691 (** strings **)
   692 
   693 (* functions tuned for strings, avoiding explode *)
   694 
   695 fun nth_string str i =
   696   (case try String.substring (str, i, 1) of
   697     SOME s => s
   698   | NONE => raise Subscript);
   699 
   700 fun fold_string f str x0 =
   701   let
   702     val n = size str;
   703     fun iter (x, i) =
   704       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   705   in iter (x0, 0) end;
   706 
   707 fun exists_string pred str =
   708   let
   709     val n = size str;
   710     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   711   in ex 0 end;
   712 
   713 fun forall_string pred = not o exists_string (not o pred);
   714 
   715 fun first_field sep str =
   716   let
   717     val n = size sep;
   718     val len = size str;
   719     fun find i =
   720       if i + n > len then NONE
   721       else if String.substring (str, i, n) = sep then SOME i
   722       else find (i + 1);
   723   in
   724     (case find 0 of
   725       NONE => NONE
   726     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   727   end;
   728 
   729 (*enclose in brackets*)
   730 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   731 fun unenclose str = String.substring (str, 1, size str - 2);
   732 
   733 (*simple quoting (does not escape special chars)*)
   734 val quote = enclose "\"" "\"";
   735 
   736 fun space_implode a bs = implode (separate a bs);
   737 
   738 val commas = space_implode ", ";
   739 val commas_quote = commas o map quote;
   740 
   741 val cat_lines = space_implode "\n";
   742 
   743 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   744 fun space_explode _ "" = []
   745   | space_explode sep s = String.fields (fn c => str c = sep) s;
   746 
   747 val split_lines = space_explode "\n";
   748 
   749 fun prefix_lines "" txt = txt
   750   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   751 
   752 fun prefix prfx s = prfx ^ s;
   753 fun suffix sffx s = s ^ sffx;
   754 
   755 fun unprefix prfx s =
   756   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   757   else raise Fail "unprefix";
   758 
   759 fun unsuffix sffx s =
   760   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   761   else raise Fail "unsuffix";
   762 
   763 fun replicate_string (0: int) _ = ""
   764   | replicate_string 1 a = a
   765   | replicate_string k a =
   766       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   767       else replicate_string (k div 2) (a ^ a) ^ a;
   768 
   769 fun translate_string f = String.translate (f o String.str);
   770 
   771 (*crude matching of str against simple glob pat*)
   772 fun match_string pat str =
   773   let
   774     fun match [] _ = true
   775       | match (p :: ps) s =
   776           size p <= size s andalso
   777             (case try (unprefix p) s of
   778               SOME s' => match ps s'
   779             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   780   in match (space_explode "*" pat) str end;
   781 
   782 
   783 (** reals **)
   784 
   785 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   786 
   787 fun signed_string_of_real x =
   788   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   789 
   790 fun smart_string_of_real x =
   791   let
   792     val s = signed_string_of_real x;
   793   in
   794     (case space_explode "." s of
   795       [a, b] => if forall_string (fn c => c = "0") b then a else s
   796     | _ => s)
   797   end;
   798 
   799 
   800 
   801 (** lists as sets -- see also Pure/General/ord_list.ML **)
   802 
   803 (* canonical operations *)
   804 
   805 fun member eq list x =
   806   let
   807     fun memb [] = false
   808       | memb (y :: ys) = eq (x, y) orelse memb ys;
   809   in memb list end;
   810 
   811 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   812 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   813 fun update eq x xs = cons x (remove eq x xs);
   814 
   815 fun inter eq xs = filter (member eq xs);
   816 
   817 fun union eq = fold (insert eq);
   818 fun subtract eq = fold (remove eq);
   819 
   820 fun merge eq (xs, ys) =
   821   if pointer_eq (xs, ys) then xs
   822   else if null xs then ys
   823   else fold_rev (insert eq) ys xs;
   824 
   825 
   826 (* subset and set equality *)
   827 
   828 fun subset eq (xs, ys) = forall (member eq ys) xs;
   829 
   830 fun eq_set eq (xs, ys) =
   831   eq_list eq (xs, ys) orelse
   832     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   833 
   834 
   835 (*makes a list of the distinct members of the input; preserves order, takes
   836   first of equal elements*)
   837 fun distinct eq lst =
   838   let
   839     fun dist (rev_seen, []) = rev rev_seen
   840       | dist (rev_seen, x :: xs) =
   841           if member eq rev_seen x then dist (rev_seen, xs)
   842           else dist (x :: rev_seen, xs);
   843   in dist ([], lst) end;
   844 
   845 (*returns a list containing all repeated elements exactly once; preserves
   846   order, takes first of equal elements*)
   847 fun duplicates eq lst =
   848   let
   849     fun dups (rev_dups, []) = rev rev_dups
   850       | dups (rev_dups, x :: xs) =
   851           if member eq rev_dups x orelse not (member eq xs x) then
   852             dups (rev_dups, xs)
   853           else dups (x :: rev_dups, xs);
   854   in dups ([], lst) end;
   855 
   856 fun has_duplicates eq =
   857   let
   858     fun dups [] = false
   859       | dups (x :: xs) = member eq xs x orelse dups xs;
   860   in dups end;
   861 
   862 
   863 (* matrices *)
   864 
   865 fun map_transpose f xss =
   866   let
   867     val n =
   868       (case distinct (op =) (map length xss) of
   869         [] => 0
   870       | [n] => n
   871       | _ => raise ListPair.UnequalLengths);
   872   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   873 
   874 
   875 
   876 (** lists as multisets **)
   877 
   878 fun remove1 eq x [] = []
   879   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   880 
   881 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   882 
   883 fun submultiset _ ([], _)  = true
   884   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   885 
   886 
   887 
   888 (** orders **)
   889 
   890 fun is_equal EQUAL = true
   891   | is_equal _ = false;
   892 
   893 fun rev_order LESS = GREATER
   894   | rev_order EQUAL = EQUAL
   895   | rev_order GREATER = LESS;
   896 
   897 (*assume rel is a linear strict order*)
   898 fun make_ord rel (x, y) =
   899   if rel (x, y) then LESS
   900   else if rel (y, x) then GREATER
   901   else EQUAL;
   902 
   903 fun bool_ord (false, true) = LESS
   904   | bool_ord (true, false) = GREATER
   905   | bool_ord _ = EQUAL;
   906 
   907 val int_ord = Int.compare;
   908 val string_ord = String.compare;
   909 
   910 fun fast_string_ord (s1, s2) =
   911   if pointer_eq (s1, s2) then EQUAL
   912   else (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   913 
   914 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   915   | option_ord _ (NONE, NONE) = EQUAL
   916   | option_ord _ (NONE, SOME _) = LESS
   917   | option_ord _ (SOME _, NONE) = GREATER;
   918 
   919 (*lexicographic product*)
   920 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   921   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   922 
   923 (*dictionary order -- in general NOT well-founded!*)
   924 fun dict_ord elem_ord (x :: xs, y :: ys) =
   925       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   926   | dict_ord _ ([], []) = EQUAL
   927   | dict_ord _ ([], _ :: _) = LESS
   928   | dict_ord _ (_ :: _, []) = GREATER;
   929 
   930 (*lexicographic product of lists*)
   931 fun list_ord elem_ord (xs, ys) =
   932   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   933 
   934 
   935 (* sorting *)
   936 
   937 (*quicksort -- stable, i.e. does not reorder equal elements*)
   938 fun quicksort unique ord =
   939   let
   940     fun qsort [] = []
   941       | qsort (xs as [_]) = xs
   942       | qsort (xs as [x, y]) =
   943           (case ord (x, y) of
   944             LESS => xs
   945           | EQUAL => if unique then [x] else xs
   946           | GREATER => [y, x])
   947       | qsort xs =
   948           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   949           in qsort lts @ eqs @ qsort gts end
   950     and part _ [] = ([], [], [])
   951       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   952     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   953       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   954       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   955       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   956   in qsort end;
   957 
   958 fun sort ord = quicksort false ord;
   959 fun sort_distinct ord = quicksort true ord;
   960 
   961 val sort_strings = sort string_ord;
   962 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   963 
   964 
   965 (* items tagged by integer index *)
   966 
   967 (*insert tags*)
   968 fun tag_list k [] = []
   969   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   970 
   971 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   972 fun untag_list [] = []
   973   | untag_list [(k: int, x)] = [x]
   974   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   975       if k = k' then untag_list rest
   976       else x :: untag_list rest;
   977 
   978 (*return list elements in original order*)
   979 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   980 
   981 
   982 
   983 (** random numbers **)
   984 
   985 exception RANDOM;
   986 
   987 fun rmod x y = x - y * Real.realFloor (x / y);
   988 
   989 local
   990   val a = 16807.0;
   991   val m = 2147483647.0;
   992   val random_seed = Unsynchronized.ref 1.0;
   993 in
   994 
   995 fun random () = CRITICAL (fn () =>
   996   let val r = rmod (a * ! random_seed) m
   997   in (random_seed := r; r) end);
   998 
   999 end;
  1000 
  1001 fun random_range l h =
  1002   if h < l orelse l < 0 then raise RANDOM
  1003   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1004 
  1005 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1006 
  1007 fun frequency xs =
  1008   let
  1009     val sum = foldl op + (0, map fst xs);
  1010     fun pick n ((k: int, x) :: xs) =
  1011       if n <= k then x else pick (n - k) xs
  1012   in pick (random_range 1 sum) xs end;
  1013 
  1014 
  1015 
  1016 (** misc **)
  1017 
  1018 fun divide_and_conquer decomp x =
  1019   let val (ys, recomb) = decomp x
  1020   in recomb (map (divide_and_conquer decomp) ys) end;
  1021 
  1022 fun divide_and_conquer' decomp x s =
  1023   let val ((ys, recomb), s') = decomp x s
  1024   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1025 
  1026 
  1027 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1028    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1029 fun partition_list p i j =
  1030   let
  1031     fun part (k: int) xs =
  1032       if k > j then
  1033         (case xs of
  1034           [] => []
  1035         | _ => raise Fail "partition_list")
  1036       else
  1037         let val (ns, rest) = List.partition (p k) xs
  1038         in ns :: part (k + 1) rest end;
  1039   in part (i: int) end;
  1040 
  1041 fun partition_eq (eq: 'a * 'a -> bool) =
  1042   let
  1043     fun part [] = []
  1044       | part (x :: ys) =
  1045           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1046           in (x :: xs) :: part xs' end;
  1047   in part end;
  1048 
  1049 
  1050 
  1051 (* generating identifiers -- often fresh *)
  1052 
  1053 local
  1054 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1055 fun gensym_char i =
  1056   if i<26 then chr (ord "A" + i)
  1057   else if i<52 then chr (ord "a" + i - 26)
  1058   else chr (ord "0" + i - 52);
  1059 
  1060 val char_vec = Vector.tabulate (62, gensym_char);
  1061 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1062 
  1063 val gensym_seed = Unsynchronized.ref (0: int);
  1064 
  1065 in
  1066   fun legacy_gensym pre =
  1067     pre ^ newid (NAMED_CRITICAL "legacy_gensym" (fn () => Unsynchronized.inc gensym_seed));
  1068 end;
  1069 
  1070 
  1071 (* stamps and serial numbers *)
  1072 
  1073 type stamp = unit Unsynchronized.ref;
  1074 val stamp: unit -> stamp = Unsynchronized.ref;
  1075 
  1076 type serial = int;
  1077 val serial = Multithreading.serial;
  1078 val serial_string = string_of_int o serial;
  1079 
  1080 
  1081 (* generic objects *)
  1082 
  1083 (*note that the builtin exception datatype may be extended by new
  1084   constructors at any time*)
  1085 structure Object = struct type T = exn end;
  1086 
  1087 
  1088 (* current directory *)
  1089 
  1090 val cd = OS.FileSys.chDir;
  1091 val pwd = OS.FileSys.getDir;
  1092 
  1093 
  1094 (* getenv *)
  1095 
  1096 fun getenv x =
  1097   (case OS.Process.getEnv x of
  1098     NONE => ""
  1099   | SOME y => y);
  1100 
  1101 fun getenv_strict x =
  1102   (case getenv x of
  1103     "" => error ("Undefined Isabelle environment variable: " ^ quote x)
  1104   | y => y);
  1105 
  1106 end;
  1107 
  1108 structure Basic_Library: BASIC_LIBRARY = Library;
  1109 open Basic_Library;
  1110 
  1111 datatype legacy = UnequalLengths;