src/Pure/sign.ML
author wenzelm
Sat Oct 24 21:30:33 2009 +0200 (2009-10-24)
changeset 33097 9d501e11084a
parent 33095 bbd52d2f8696
child 33157 56f836b9414f
permissions -rw-r--r--
maintain position of formal entities via name space;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val naming_of: theory -> Name_Space.naming
    16   val full_name: theory -> binding -> string
    17   val full_name_path: theory -> string -> binding -> string
    18   val full_bname: theory -> bstring -> string
    19   val full_bname_path: theory -> string -> bstring -> string
    20   val syn_of: theory -> Syntax.syntax
    21   val tsig_of: theory -> Type.tsig
    22   val classes_of: theory -> Sorts.algebra
    23   val all_classes: theory -> class list
    24   val super_classes: theory -> class -> class list
    25   val minimize_sort: theory -> sort -> sort
    26   val complete_sort: theory -> sort -> sort
    27   val defaultS: theory -> sort
    28   val subsort: theory -> sort * sort -> bool
    29   val of_sort: theory -> typ * sort -> bool
    30   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    31   val is_logtype: theory -> string -> bool
    32   val typ_instance: theory -> typ * typ -> bool
    33   val typ_equiv: theory -> typ * typ -> bool
    34   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    35   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    36   val consts_of: theory -> Consts.T
    37   val the_const_constraint: theory -> string -> typ
    38   val const_type: theory -> string -> typ option
    39   val the_const_type: theory -> string -> typ
    40   val declared_tyname: theory -> string -> bool
    41   val declared_const: theory -> string -> bool
    42   val const_monomorphic: theory -> string -> bool
    43   val const_syntax_name: theory -> string -> string
    44   val const_typargs: theory -> string * typ -> typ list
    45   val const_instance: theory -> string * typ list -> typ
    46   val mk_const: theory -> string * typ list -> term
    47   val class_space: theory -> Name_Space.T
    48   val type_space: theory -> Name_Space.T
    49   val const_space: theory -> Name_Space.T
    50   val intern_class: theory -> xstring -> string
    51   val extern_class: theory -> string -> xstring
    52   val intern_type: theory -> xstring -> string
    53   val extern_type: theory -> string -> xstring
    54   val intern_const: theory -> xstring -> string
    55   val extern_const: theory -> string -> xstring
    56   val intern_sort: theory -> sort -> sort
    57   val extern_sort: theory -> sort -> sort
    58   val intern_typ: theory -> typ -> typ
    59   val extern_typ: theory -> typ -> typ
    60   val intern_term: theory -> term -> term
    61   val extern_term: (string -> xstring) -> theory -> term -> term
    62   val intern_tycons: theory -> typ -> typ
    63   val arity_number: theory -> string -> int
    64   val arity_sorts: theory -> string -> sort -> sort list
    65   val certify_class: theory -> class -> class
    66   val certify_sort: theory -> sort -> sort
    67   val certify_typ: theory -> typ -> typ
    68   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    69   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    70   val certify_term: theory -> term -> term * typ * int
    71   val cert_term: theory -> term -> term
    72   val cert_prop: theory -> term -> term
    73   val no_frees: Pretty.pp -> term -> term
    74   val no_vars: Pretty.pp -> term -> term
    75   val cert_def: Proof.context -> term -> (string * typ) * term
    76   val read_class: theory -> xstring -> class
    77   val read_arity: theory -> xstring * string list * string -> arity
    78   val cert_arity: theory -> arity -> arity
    79   val add_defsort: string -> theory -> theory
    80   val add_defsort_i: sort -> theory -> theory
    81   val add_types: (binding * int * mixfix) list -> theory -> theory
    82   val add_nonterminals: binding list -> theory -> theory
    83   val add_tyabbrs: (binding * string list * string * mixfix) list -> theory -> theory
    84   val add_tyabbrs_i: (binding * string list * typ * mixfix) list -> theory -> theory
    85   val add_syntax: (string * string * mixfix) list -> theory -> theory
    86   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    87   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    88   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    89   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    90   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    91   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    92   val declare_const: Properties.T -> (binding * typ) * mixfix -> theory -> term * theory
    93   val add_consts: (binding * string * mixfix) list -> theory -> theory
    94   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    95   val add_abbrev: string -> Properties.T -> binding * term -> theory -> (term * term) * theory
    96   val revert_abbrev: string -> string -> theory -> theory
    97   val add_const_constraint: string * typ option -> theory -> theory
    98   val primitive_class: binding * class list -> theory -> theory
    99   val primitive_classrel: class * class -> theory -> theory
   100   val primitive_arity: arity -> theory -> theory
   101   val add_trfuns:
   102     (string * (ast list -> ast)) list *
   103     (string * (term list -> term)) list *
   104     (string * (term list -> term)) list *
   105     (string * (ast list -> ast)) list -> theory -> theory
   106   val add_trfunsT:
   107     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   108   val add_advanced_trfuns:
   109     (string * (Proof.context -> ast list -> ast)) list *
   110     (string * (Proof.context -> term list -> term)) list *
   111     (string * (Proof.context -> term list -> term)) list *
   112     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   113   val add_advanced_trfunsT:
   114     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   115   val add_tokentrfuns:
   116     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   117   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   118     -> theory -> theory
   119   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   120   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   121   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   122   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   123   val add_path: string -> theory -> theory
   124   val root_path: theory -> theory
   125   val parent_path: theory -> theory
   126   val mandatory_path: string -> theory -> theory
   127   val local_path: theory -> theory
   128   val restore_naming: theory -> theory -> theory
   129   val hide_class: bool -> string -> theory -> theory
   130   val hide_type: bool -> string -> theory -> theory
   131   val hide_const: bool -> string -> theory -> theory
   132 end
   133 
   134 structure Sign: SIGN =
   135 struct
   136 
   137 (** datatype sign **)
   138 
   139 datatype sign = Sign of
   140  {naming: Name_Space.naming,    (*common naming conventions*)
   141   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   142   tsig: Type.tsig,              (*order-sorted signature of types*)
   143   consts: Consts.T};            (*polymorphic constants*)
   144 
   145 fun make_sign (naming, syn, tsig, consts) =
   146   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   147 
   148 structure SignData = TheoryDataFun
   149 (
   150   type T = sign;
   151   val copy = I;
   152   fun extend (Sign {syn, tsig, consts, ...}) =
   153     make_sign (Name_Space.default_naming, syn, tsig, consts);
   154 
   155   val empty =
   156     make_sign (Name_Space.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   157 
   158   fun merge pp (sign1, sign2) =
   159     let
   160       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   161       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   162 
   163       val naming = Name_Space.default_naming;
   164       val syn = Syntax.merge_syntaxes syn1 syn2;
   165       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   166       val consts = Consts.merge (consts1, consts2);
   167     in make_sign (naming, syn, tsig, consts) end;
   168 );
   169 
   170 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   171 
   172 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   173   make_sign (f (naming, syn, tsig, consts)));
   174 
   175 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   176 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   177 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   178 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   179 
   180 
   181 (* naming *)
   182 
   183 val naming_of = #naming o rep_sg;
   184 
   185 val full_name = Name_Space.full_name o naming_of;
   186 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   187 
   188 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   189 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   190 
   191 
   192 (* syntax *)
   193 
   194 val syn_of = #syn o rep_sg;
   195 
   196 
   197 (* type signature *)
   198 
   199 val tsig_of = #tsig o rep_sg;
   200 
   201 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   202 val all_classes = Sorts.all_classes o classes_of;
   203 val super_classes = Sorts.super_classes o classes_of;
   204 val minimize_sort = Sorts.minimize_sort o classes_of;
   205 val complete_sort = Sorts.complete_sort o classes_of;
   206 
   207 val defaultS = Type.defaultS o tsig_of;
   208 val subsort = Type.subsort o tsig_of;
   209 val of_sort = Type.of_sort o tsig_of;
   210 val witness_sorts = Type.witness_sorts o tsig_of;
   211 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   212 
   213 val typ_instance = Type.typ_instance o tsig_of;
   214 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   215 val typ_match = Type.typ_match o tsig_of;
   216 val typ_unify = Type.unify o tsig_of;
   217 
   218 
   219 (* polymorphic constants *)
   220 
   221 val consts_of = #consts o rep_sg;
   222 val the_const_constraint = Consts.the_constraint o consts_of;
   223 val the_const_type = Consts.the_type o consts_of;
   224 val const_type = try o the_const_type;
   225 val const_monomorphic = Consts.is_monomorphic o consts_of;
   226 val const_syntax_name = Consts.syntax_name o consts_of;
   227 val const_typargs = Consts.typargs o consts_of;
   228 val const_instance = Consts.instance o consts_of;
   229 
   230 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   231 
   232 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   233 val declared_const = can o the_const_constraint;
   234 
   235 
   236 
   237 (** intern / extern names **)
   238 
   239 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   240 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   241 val const_space = Consts.space_of o consts_of;
   242 
   243 val intern_class = Name_Space.intern o class_space;
   244 val extern_class = Name_Space.extern o class_space;
   245 val intern_type = Name_Space.intern o type_space;
   246 val extern_type = Name_Space.extern o type_space;
   247 val intern_const = Name_Space.intern o const_space;
   248 val extern_const = Name_Space.extern o const_space;
   249 
   250 val intern_sort = map o intern_class;
   251 val extern_sort = map o extern_class;
   252 
   253 local
   254 
   255 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   256   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   257   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   258 
   259 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   260   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   261   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   262   | map_term _ _ _ (t as Bound _) = t
   263   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   264   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   265 
   266 val add_classesT = Term.fold_atyps
   267   (fn TFree (_, S) => fold (insert (op =)) S
   268     | TVar (_, S) => fold (insert (op =)) S
   269     | _ => I);
   270 
   271 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   272   | add_tyconsT _ = I;
   273 
   274 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   275 
   276 fun mapping add_names f t =
   277   let
   278     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   279     val tab = map_filter f' (add_names t []);
   280     fun get x = the_default x (AList.lookup (op =) tab x);
   281   in get end;
   282 
   283 fun typ_mapping f g thy T =
   284   T |> map_typ
   285     (mapping add_classesT (f thy) T)
   286     (mapping add_tyconsT (g thy) T);
   287 
   288 fun term_mapping f g h thy t =
   289   t |> map_term
   290     (mapping (Term.fold_types add_classesT) (f thy) t)
   291     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   292     (mapping add_consts (h thy) t);
   293 
   294 in
   295 
   296 val intern_typ = typ_mapping intern_class intern_type;
   297 val extern_typ = typ_mapping extern_class extern_type;
   298 val intern_term = term_mapping intern_class intern_type intern_const;
   299 fun extern_term h = term_mapping extern_class extern_type (K h);
   300 val intern_tycons = typ_mapping (K I) intern_type;
   301 
   302 end;
   303 
   304 
   305 
   306 (** certify entities **)    (*exception TYPE*)
   307 
   308 (* certify wrt. type signature *)
   309 
   310 val arity_number = Type.arity_number o tsig_of;
   311 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   312 
   313 val certify_class         = Type.cert_class o tsig_of;
   314 val certify_sort          = Type.cert_sort o tsig_of;
   315 val certify_typ           = Type.cert_typ o tsig_of;
   316 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   317 
   318 
   319 (* certify term/prop *)
   320 
   321 local
   322 
   323 fun type_check pp tm =
   324   let
   325     fun err_appl why bs t T u U =
   326       let
   327         val xs = map Free bs;           (*we do not rename here*)
   328         val t' = subst_bounds (xs, t);
   329         val u' = subst_bounds (xs, u);
   330         val msg = cat_lines
   331           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   332       in raise TYPE (msg, [T, U], [t', u']) end;
   333 
   334     fun typ_of (_, Const (_, T)) = T
   335       | typ_of (_, Free  (_, T)) = T
   336       | typ_of (_, Var (_, T)) = T
   337       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   338           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   339       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   340       | typ_of (bs, t $ u) =
   341           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   342             (case T of
   343               Type ("fun", [T1, T2]) =>
   344                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   345             | _ => err_appl "Operator not of function type" bs t T u U)
   346           end;
   347   in typ_of ([], tm) end;
   348 
   349 fun err msg = raise TYPE (msg, [], []);
   350 
   351 fun check_vars (t $ u) = (check_vars t; check_vars u)
   352   | check_vars (Abs (_, _, t)) = check_vars t
   353   | check_vars (Free (x, _)) =
   354       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   355   | check_vars (Var (xi as (_, i), _)) =
   356       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   357   | check_vars _ = ();
   358 
   359 in
   360 
   361 fun certify' prop pp do_expand consts thy tm =
   362   let
   363     val _ = check_vars tm;
   364     val tm' = Term.map_types (certify_typ thy) tm;
   365     val T = type_check pp tm';
   366     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   367     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   368   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   369 
   370 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   371 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   372 val cert_term = #1 oo certify_term;
   373 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   374 
   375 end;
   376 
   377 
   378 (* specifications *)
   379 
   380 fun no_variables kind add addT mk mkT pp tm =
   381   (case (add tm [], addT tm []) of
   382     ([], []) => tm
   383   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   384       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   385        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   386 
   387 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   388 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   389 
   390 fun cert_def ctxt tm =
   391   let val ((lhs, rhs), _) = tm
   392     |> no_vars (Syntax.pp ctxt)
   393     |> Logic.strip_imp_concl
   394     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   395   in (Term.dest_Const (Term.head_of lhs), rhs) end
   396   handle TERM (msg, _) => error msg;
   397 
   398 
   399 
   400 (** read and certify entities **)    (*exception ERROR*)
   401 
   402 (* classes *)
   403 
   404 fun read_class thy c = certify_class thy (intern_class thy c)
   405   handle TYPE (msg, _, _) => error msg;
   406 
   407 
   408 (* type arities *)
   409 
   410 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   411   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   412   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   413 
   414 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   415 val cert_arity = prep_arity (K I) certify_sort;
   416 
   417 
   418 
   419 (** signature extension functions **)  (*exception ERROR/TYPE*)
   420 
   421 (* add default sort *)
   422 
   423 fun gen_add_defsort prep_sort s thy =
   424   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   425 
   426 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   427 val add_defsort_i = gen_add_defsort certify_sort;
   428 
   429 
   430 (* add type constructors *)
   431 
   432 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   433   let
   434     val syn' = Syntax.update_type_gram (map (fn (a, n, mx) => (Name.of_binding a, n, mx)) types) syn;
   435     val decls = map (fn (a, n, mx) => (Binding.map_name (Syntax.type_name mx) a, n)) types;
   436     val tags = [(Markup.theory_nameN, Context.theory_name thy)];
   437     val tsig' = fold (Type.add_type naming tags) decls tsig;
   438   in (naming, syn', tsig', consts) end);
   439 
   440 
   441 (* add nonterminals *)
   442 
   443 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   444   let
   445     val syn' = Syntax.update_consts (map Name.of_binding ns) syn;
   446     val tsig' = fold (Type.add_nonterminal naming []) ns tsig;
   447   in (naming, syn', tsig', consts) end);
   448 
   449 
   450 (* add type abbreviations *)
   451 
   452 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   453   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   454     let
   455       val ctxt = ProofContext.init thy;
   456       val syn' = Syntax.update_type_gram [(Name.of_binding a, length vs, mx)] syn;
   457       val b = Binding.map_name (Syntax.type_name mx) a;
   458       val abbr = (b, vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   459         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote (Binding.str_of b));
   460       val tsig' = Type.add_abbrev naming [] abbr tsig;
   461     in (naming, syn', tsig', consts) end);
   462 
   463 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   464 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   465 
   466 
   467 (* modify syntax *)
   468 
   469 fun gen_syntax change_gram parse_typ mode args thy =
   470   let
   471     val ctxt = ProofContext.init thy;
   472     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   473       handle ERROR msg =>
   474         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name mx c));
   475   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   476 
   477 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   478 
   479 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   480 val add_modesyntax_i = gen_add_syntax (K I);
   481 val add_syntax = add_modesyntax Syntax.mode_default;
   482 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   483 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   484 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   485 
   486 fun notation add mode args thy =
   487   let
   488     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   489     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   490       | const_syntax _ = NONE;
   491   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   492 
   493 
   494 (* add constants *)
   495 
   496 local
   497 
   498 fun gen_add_consts parse_typ authentic tags raw_args thy =
   499   let
   500     val ctxt = ProofContext.init thy;
   501     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   502     fun prep (raw_b, raw_T, raw_mx) =
   503       let
   504         val (mx_name, mx) = Syntax.const_mixfix (Name.of_binding raw_b) raw_mx;
   505         val b = Binding.map_name (K mx_name) raw_b;
   506         val c = full_name thy b;
   507         val c_syn = if authentic then Syntax.constN ^ c else Name.of_binding b;
   508         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   509           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   510         val T' = Logic.varifyT T;
   511       in ((b, T'), (c_syn, T', mx), Const (c, T)) end;
   512     val args = map prep raw_args;
   513     val tags' = tags |> Properties.put (Markup.theory_nameN, Context.theory_name thy);
   514   in
   515     thy
   516     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   517     |> add_syntax_i (map #2 args)
   518     |> pair (map #3 args)
   519   end;
   520 
   521 in
   522 
   523 fun add_consts args = snd o gen_add_consts Syntax.parse_typ false [] args;
   524 fun add_consts_i args = snd o gen_add_consts (K I) false [] args;
   525 
   526 fun declare_const tags ((b, T), mx) thy =
   527   let
   528     val pos = Binding.pos_of b;
   529     val ([const as Const (c, _)], thy') = gen_add_consts (K I) true tags [(b, T, mx)] thy;
   530     val _ = Position.report (Markup.const_decl c) pos;
   531   in (const, thy') end;
   532 
   533 end;
   534 
   535 
   536 (* abbreviations *)
   537 
   538 fun add_abbrev mode tags (b, raw_t) thy =
   539   let
   540     val pp = Syntax.pp_global thy;
   541     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   542     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   543       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   544     val (res, consts') = consts_of thy
   545       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (b, t);
   546   in (res, thy |> map_consts (K consts')) end;
   547 
   548 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   549 
   550 
   551 (* add constraints *)
   552 
   553 fun add_const_constraint (c, opt_T) thy =
   554   let
   555     fun prepT raw_T =
   556       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   557       in cert_term thy (Const (c, T)); T end
   558       handle TYPE (msg, _, _) => error msg;
   559   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   560 
   561 
   562 (* primitive classes and arities *)
   563 
   564 fun primitive_class (bclass, classes) thy =
   565   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   566     let
   567       val syn' = Syntax.update_consts [Name.of_binding bclass] syn;
   568       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   569     in (naming, syn', tsig', consts) end)
   570   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   571 
   572 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   573 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   574 
   575 
   576 (* add translation functions *)
   577 
   578 local
   579 
   580 fun mk trs = map Syntax.mk_trfun trs;
   581 
   582 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   583   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   584 
   585 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   586 
   587 in
   588 
   589 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   590 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   591 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   592 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   593 
   594 end;
   595 
   596 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   597 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   598 
   599 
   600 (* translation rules *)
   601 
   602 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   603   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   604   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   605 
   606 val add_trrules = gen_trrules Syntax.update_trrules;
   607 val del_trrules = gen_trrules Syntax.remove_trrules;
   608 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   609 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   610 
   611 
   612 (* naming *)
   613 
   614 val add_path = map_naming o Name_Space.add_path;
   615 val root_path = map_naming Name_Space.root_path;
   616 val parent_path = map_naming Name_Space.parent_path;
   617 val mandatory_path = map_naming o Name_Space.mandatory_path;
   618 
   619 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   620 
   621 val restore_naming = map_naming o K o naming_of;
   622 
   623 
   624 (* hide names *)
   625 
   626 val hide_class = map_tsig oo Type.hide_class;
   627 val hide_type = map_tsig oo Type.hide_type;
   628 val hide_const = map_consts oo Consts.hide;
   629 
   630 end;