src/HOL/Complex.thy
author blanchet
Sun May 04 18:14:58 2014 +0200 (2014-05-04)
changeset 56846 9df717fef2bb
parent 56541 0e3abadbef39
child 56889 48a745e1bde7
permissions -rw-r--r--
renamed 'xxx_size' to 'size_xxx' for old datatype package
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec Re :: "complex \<Rightarrow> real"
    16   where Re: "Re (Complex x y) = x"
    17 
    18 primrec Im :: "complex \<Rightarrow> real"
    19   where Im: "Im (Complex x y) = y"
    20 
    21 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    22   by (induct z) simp
    23 
    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    25   by (induct x, induct y) simp
    26 
    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    28   by (induct x, induct y) simp
    29 
    30 
    31 subsection {* Addition and Subtraction *}
    32 
    33 instantiation complex :: ab_group_add
    34 begin
    35 
    36 definition complex_zero_def:
    37   "0 = Complex 0 0"
    38 
    39 definition complex_add_def:
    40   "x + y = Complex (Re x + Re y) (Im x + Im y)"
    41 
    42 definition complex_minus_def:
    43   "- x = Complex (- Re x) (- Im x)"
    44 
    45 definition complex_diff_def:
    46   "x - (y\<Colon>complex) = x + - y"
    47 
    48 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    49   by (simp add: complex_zero_def)
    50 
    51 lemma complex_Re_zero [simp]: "Re 0 = 0"
    52   by (simp add: complex_zero_def)
    53 
    54 lemma complex_Im_zero [simp]: "Im 0 = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_add [simp]:
    58   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    59   by (simp add: complex_add_def)
    60 
    61 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    62   by (simp add: complex_add_def)
    63 
    64 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_minus [simp]:
    68   "- (Complex a b) = Complex (- a) (- b)"
    69   by (simp add: complex_minus_def)
    70 
    71 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    72   by (simp add: complex_minus_def)
    73 
    74 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_diff [simp]:
    78   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    79   by (simp add: complex_diff_def)
    80 
    81 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    82   by (simp add: complex_diff_def)
    83 
    84 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    85   by (simp add: complex_diff_def)
    86 
    87 instance
    88   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    89 
    90 end
    91 
    92 
    93 subsection {* Multiplication and Division *}
    94 
    95 instantiation complex :: field_inverse_zero
    96 begin
    97 
    98 definition complex_one_def:
    99   "1 = Complex 1 0"
   100 
   101 definition complex_mult_def:
   102   "x * y = Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   103 
   104 definition complex_inverse_def:
   105   "inverse x =
   106     Complex (Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)) (- Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2))"
   107 
   108 definition complex_divide_def:
   109   "x / (y\<Colon>complex) = x * inverse y"
   110 
   111 lemma Complex_eq_1 [simp]:
   112   "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"
   113   by (simp add: complex_one_def)
   114 
   115 lemma Complex_eq_neg_1 [simp]:
   116   "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"
   117   by (simp add: complex_one_def)
   118 
   119 lemma complex_Re_one [simp]: "Re 1 = 1"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Im_one [simp]: "Im 1 = 0"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_mult [simp]:
   126   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   127   by (simp add: complex_mult_def)
   128 
   129 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_inverse [simp]:
   136   "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"
   137   by (simp add: complex_inverse_def)
   138 
   139 lemma complex_Re_inverse:
   140   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
   141   by (simp add: complex_inverse_def)
   142 
   143 lemma complex_Im_inverse:
   144   "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
   145   by (simp add: complex_inverse_def)
   146 
   147 instance
   148   by intro_classes (simp_all add: complex_mult_def
   149     distrib_left distrib_right right_diff_distrib left_diff_distrib
   150     complex_inverse_def complex_divide_def
   151     power2_eq_square add_divide_distrib [symmetric]
   152     complex_eq_iff)
   153 
   154 end
   155 
   156 
   157 subsection {* Numerals and Arithmetic *}
   158 
   159 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   160   by (induct n) simp_all
   161 
   162 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   163   by (induct n) simp_all
   164 
   165 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   166   by (cases z rule: int_diff_cases) simp
   167 
   168 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   169   by (cases z rule: int_diff_cases) simp
   170 
   171 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
   172   using complex_Re_of_int [of "numeral v"] by simp
   173 
   174 lemma complex_Re_neg_numeral [simp]: "Re (- numeral v) = - numeral v"
   175   using complex_Re_of_int [of "- numeral v"] by simp
   176 
   177 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
   178   using complex_Im_of_int [of "numeral v"] by simp
   179 
   180 lemma complex_Im_neg_numeral [simp]: "Im (- numeral v) = 0"
   181   using complex_Im_of_int [of "- numeral v"] by simp
   182 
   183 lemma Complex_eq_numeral [simp]:
   184   "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"
   185   by (simp add: complex_eq_iff)
   186 
   187 lemma Complex_eq_neg_numeral [simp]:
   188   "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"
   189   by (simp add: complex_eq_iff)
   190 
   191 
   192 subsection {* Scalar Multiplication *}
   193 
   194 instantiation complex :: real_field
   195 begin
   196 
   197 definition complex_scaleR_def:
   198   "scaleR r x = Complex (r * Re x) (r * Im x)"
   199 
   200 lemma complex_scaleR [simp]:
   201   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   202   unfolding complex_scaleR_def by simp
   203 
   204 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   205   unfolding complex_scaleR_def by simp
   206 
   207 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   208   unfolding complex_scaleR_def by simp
   209 
   210 instance
   211 proof
   212   fix a b :: real and x y :: complex
   213   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   214     by (simp add: complex_eq_iff distrib_left)
   215   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   216     by (simp add: complex_eq_iff distrib_right)
   217   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   218     by (simp add: complex_eq_iff mult_assoc)
   219   show "scaleR 1 x = x"
   220     by (simp add: complex_eq_iff)
   221   show "scaleR a x * y = scaleR a (x * y)"
   222     by (simp add: complex_eq_iff algebra_simps)
   223   show "x * scaleR a y = scaleR a (x * y)"
   224     by (simp add: complex_eq_iff algebra_simps)
   225 qed
   226 
   227 end
   228 
   229 
   230 subsection{* Properties of Embedding from Reals *}
   231 
   232 abbreviation complex_of_real :: "real \<Rightarrow> complex"
   233   where "complex_of_real \<equiv> of_real"
   234 
   235 declare [[coercion complex_of_real]]
   236 
   237 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   238   by (simp add: of_real_def complex_scaleR_def)
   239 
   240 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   241   by (simp add: complex_of_real_def)
   242 
   243 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   244   by (simp add: complex_of_real_def)
   245 
   246 lemma Complex_add_complex_of_real [simp]:
   247   shows "Complex x y + complex_of_real r = Complex (x+r) y"
   248   by (simp add: complex_of_real_def)
   249 
   250 lemma complex_of_real_add_Complex [simp]:
   251   shows "complex_of_real r + Complex x y = Complex (r+x) y"
   252   by (simp add: complex_of_real_def)
   253 
   254 lemma Complex_mult_complex_of_real:
   255   shows "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   256   by (simp add: complex_of_real_def)
   257 
   258 lemma complex_of_real_mult_Complex:
   259   shows "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   260   by (simp add: complex_of_real_def)
   261 
   262 lemma complex_eq_cancel_iff2 [simp]:
   263   shows "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   264   by (simp add: complex_of_real_def)
   265 
   266 lemma complex_split_polar:
   267      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   268   by (simp add: complex_eq_iff polar_Ex)
   269 
   270 
   271 subsection {* Vector Norm *}
   272 
   273 instantiation complex :: real_normed_field
   274 begin
   275 
   276 definition complex_norm_def:
   277   "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   278 
   279 abbreviation cmod :: "complex \<Rightarrow> real"
   280   where "cmod \<equiv> norm"
   281 
   282 definition complex_sgn_def:
   283   "sgn x = x /\<^sub>R cmod x"
   284 
   285 definition dist_complex_def:
   286   "dist x y = cmod (x - y)"
   287 
   288 definition open_complex_def:
   289   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   290 
   291 lemmas cmod_def = complex_norm_def
   292 
   293 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"
   294   by (simp add: complex_norm_def)
   295 
   296 instance proof
   297   fix r :: real and x y :: complex and S :: "complex set"
   298   show "(norm x = 0) = (x = 0)"
   299     by (induct x) simp
   300   show "norm (x + y) \<le> norm x + norm y"
   301     by (induct x, induct y)
   302        (simp add: real_sqrt_sum_squares_triangle_ineq)
   303   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   304     by (induct x)
   305        (simp add: power_mult_distrib distrib_left [symmetric] real_sqrt_mult)
   306   show "norm (x * y) = norm x * norm y"
   307     by (induct x, induct y)
   308        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   309   show "sgn x = x /\<^sub>R cmod x"
   310     by (rule complex_sgn_def)
   311   show "dist x y = cmod (x - y)"
   312     by (rule dist_complex_def)
   313   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   314     by (rule open_complex_def)
   315 qed
   316 
   317 end
   318 
   319 lemma cmod_unit_one: "cmod (Complex (cos a) (sin a)) = 1"
   320   by simp
   321 
   322 lemma cmod_complex_polar:
   323   "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   324   by (simp add: norm_mult)
   325 
   326 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   327   unfolding complex_norm_def
   328   by (rule real_sqrt_sum_squares_ge1)
   329 
   330 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
   331   by (rule order_trans [OF _ norm_ge_zero], simp)
   332 
   333 lemma complex_mod_triangle_ineq2: "cmod(b + a) - cmod b \<le> cmod a"
   334   by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   335 
   336 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   337   by (cases x) simp
   338 
   339 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   340   by (cases x) simp
   341 
   342 
   343 lemma abs_sqrt_wlog:
   344   fixes x::"'a::linordered_idom"
   345   assumes "\<And>x::'a. x \<ge> 0 \<Longrightarrow> P x (x\<^sup>2)" shows "P \<bar>x\<bar> (x\<^sup>2)"
   346 by (metis abs_ge_zero assms power2_abs)
   347 
   348 lemma complex_abs_le_norm: "\<bar>Re z\<bar> + \<bar>Im z\<bar> \<le> sqrt 2 * norm z"
   349   unfolding complex_norm_def
   350   apply (rule abs_sqrt_wlog [where x="Re z"])
   351   apply (rule abs_sqrt_wlog [where x="Im z"])
   352   apply (rule power2_le_imp_le)
   353   apply (simp_all add: power2_sum add_commute sum_squares_bound real_sqrt_mult [symmetric])
   354   done
   355 
   356 
   357 text {* Properties of complex signum. *}
   358 
   359 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   360   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult_commute)
   361 
   362 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   363   by (simp add: complex_sgn_def divide_inverse)
   364 
   365 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   366   by (simp add: complex_sgn_def divide_inverse)
   367 
   368 
   369 subsection {* Completeness of the Complexes *}
   370 
   371 lemma bounded_linear_Re: "bounded_linear Re"
   372   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
   373 
   374 lemma bounded_linear_Im: "bounded_linear Im"
   375   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
   376 
   377 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
   378 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
   379 lemmas tendsto_Re [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Re]
   380 lemmas tendsto_Im [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Im]
   381 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
   382 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
   383 lemmas continuous_Re [simp] = bounded_linear.continuous [OF bounded_linear_Re]
   384 lemmas continuous_Im [simp] = bounded_linear.continuous [OF bounded_linear_Im]
   385 lemmas continuous_on_Re [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Re]
   386 lemmas continuous_on_Im [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Im]
   387 lemmas has_derivative_Re [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Re]
   388 lemmas has_derivative_Im [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Im]
   389 lemmas sums_Re = bounded_linear.sums [OF bounded_linear_Re]
   390 lemmas sums_Im = bounded_linear.sums [OF bounded_linear_Im]
   391 
   392 lemma tendsto_Complex [tendsto_intros]:
   393   assumes "(f ---> a) F" and "(g ---> b) F"
   394   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"
   395 proof (rule tendstoI)
   396   fix r :: real assume "0 < r"
   397   hence "0 < r / sqrt 2" by simp
   398   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) F"
   399     using `(f ---> a) F` and `0 < r / sqrt 2` by (rule tendstoD)
   400   moreover
   401   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) F"
   402     using `(g ---> b) F` and `0 < r / sqrt 2` by (rule tendstoD)
   403   ultimately
   404   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) F"
   405     by (rule eventually_elim2)
   406        (simp add: dist_norm real_sqrt_sum_squares_less)
   407 qed
   408 
   409 
   410 lemma tendsto_complex_iff:
   411   "(f ---> x) F \<longleftrightarrow> (((\<lambda>x. Re (f x)) ---> Re x) F \<and> ((\<lambda>x. Im (f x)) ---> Im x) F)"
   412 proof -
   413   have f: "f = (\<lambda>x. Complex (Re (f x)) (Im (f x)))" and x: "x = Complex (Re x) (Im x)"
   414     by simp_all
   415   show ?thesis
   416     apply (subst f)
   417     apply (subst x)
   418     apply (intro iffI tendsto_Complex conjI)
   419     apply (simp_all add: tendsto_Re tendsto_Im)
   420     done
   421 qed
   422 
   423 instance complex :: banach
   424 proof
   425   fix X :: "nat \<Rightarrow> complex"
   426   assume X: "Cauchy X"
   427   from Cauchy_Re [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   428     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   429   from Cauchy_Im [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   430     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   431   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   432     using tendsto_Complex [OF 1 2] by simp
   433   thus "convergent X"
   434     by (rule convergentI)
   435 qed
   436 
   437 declare
   438   DERIV_power[where 'a=complex, unfolded of_nat_def[symmetric], derivative_intros]
   439 
   440 
   441 subsection {* The Complex Number $i$ *}
   442 
   443 definition "ii" :: complex  ("\<i>")
   444   where i_def: "ii \<equiv> Complex 0 1"
   445 
   446 lemma complex_Re_i [simp]: "Re ii = 0"
   447   by (simp add: i_def)
   448 
   449 lemma complex_Im_i [simp]: "Im ii = 1"
   450   by (simp add: i_def)
   451 
   452 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   453   by (simp add: i_def)
   454 
   455 lemma norm_ii [simp]: "norm ii = 1"
   456   by (simp add: i_def)
   457 
   458 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   459   by (simp add: complex_eq_iff)
   460 
   461 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   462   by (simp add: complex_eq_iff)
   463 
   464 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"
   465   by (simp add: complex_eq_iff)
   466 
   467 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"
   468   by (simp add: complex_eq_iff)
   469 
   470 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   471   by (simp add: complex_eq_iff)
   472 
   473 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   474   by (simp add: complex_eq_iff)
   475 
   476 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   477   by (simp add: i_def complex_of_real_def)
   478 
   479 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   480   by (simp add: i_def complex_of_real_def)
   481 
   482 lemma i_squared [simp]: "ii * ii = -1"
   483   by (simp add: i_def)
   484 
   485 lemma power2_i [simp]: "ii\<^sup>2 = -1"
   486   by (simp add: power2_eq_square)
   487 
   488 lemma inverse_i [simp]: "inverse ii = - ii"
   489   by (rule inverse_unique, simp)
   490 
   491 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   492   by (simp add: mult_assoc [symmetric])
   493 
   494 
   495 subsection {* Complex Conjugation *}
   496 
   497 definition cnj :: "complex \<Rightarrow> complex" where
   498   "cnj z = Complex (Re z) (- Im z)"
   499 
   500 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   501   by (simp add: cnj_def)
   502 
   503 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   504   by (simp add: cnj_def)
   505 
   506 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   507   by (simp add: cnj_def)
   508 
   509 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   510   by (simp add: complex_eq_iff)
   511 
   512 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   513   by (simp add: cnj_def)
   514 
   515 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   516   by (simp add: complex_eq_iff)
   517 
   518 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   519   by (simp add: complex_eq_iff)
   520 
   521 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   522   by (simp add: complex_eq_iff)
   523 
   524 lemma cnj_setsum: "cnj (setsum f s) = (\<Sum>x\<in>s. cnj (f x))"
   525   by (induct s rule: infinite_finite_induct) (auto simp: complex_cnj_add)
   526 
   527 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   528   by (simp add: complex_eq_iff)
   529 
   530 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   531   by (simp add: complex_eq_iff)
   532 
   533 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   534   by (simp add: complex_eq_iff)
   535 
   536 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   537   by (simp add: complex_eq_iff)
   538 
   539 lemma cnj_setprod: "cnj (setprod f s) = (\<Prod>x\<in>s. cnj (f x))"
   540   by (induct s rule: infinite_finite_induct) (auto simp: complex_cnj_mult)
   541 
   542 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   543   by (simp add: complex_inverse_def)
   544 
   545 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   546   by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   547 
   548 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   549   by (induct n, simp_all add: complex_cnj_mult)
   550 
   551 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   552   by (simp add: complex_eq_iff)
   553 
   554 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   555   by (simp add: complex_eq_iff)
   556 
   557 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
   558   by (simp add: complex_eq_iff)
   559 
   560 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"
   561   by (simp add: complex_eq_iff)
   562 
   563 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   564   by (simp add: complex_eq_iff)
   565 
   566 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   567   by (simp add: complex_norm_def)
   568 
   569 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   570   by (simp add: complex_eq_iff)
   571 
   572 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   573   by (simp add: complex_eq_iff)
   574 
   575 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   576   by (simp add: complex_eq_iff)
   577 
   578 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   579   by (simp add: complex_eq_iff)
   580 
   581 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   582   by (simp add: complex_eq_iff power2_eq_square)
   583 
   584 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"
   585   by (simp add: norm_mult power2_eq_square)
   586 
   587 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   588   by (simp add: cmod_def power2_eq_square)
   589 
   590 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   591   by simp
   592 
   593 lemma bounded_linear_cnj: "bounded_linear cnj"
   594   using complex_cnj_add complex_cnj_scaleR
   595   by (rule bounded_linear_intro [where K=1], simp)
   596 
   597 lemmas tendsto_cnj [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_cnj]
   598 lemmas isCont_cnj [simp] = bounded_linear.isCont [OF bounded_linear_cnj]
   599 lemmas continuous_cnj [simp, continuous_intros] = bounded_linear.continuous [OF bounded_linear_cnj]
   600 lemmas continuous_on_cnj [simp, continuous_intros] = bounded_linear.continuous_on [OF bounded_linear_cnj]
   601 lemmas has_derivative_cnj [simp, derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_cnj]
   602 
   603 lemma lim_cnj: "((\<lambda>x. cnj(f x)) ---> cnj l) F \<longleftrightarrow> (f ---> l) F"
   604   by (simp add: tendsto_iff dist_complex_def Complex.complex_cnj_diff [symmetric])
   605 
   606 lemma sums_cnj: "((\<lambda>x. cnj(f x)) sums cnj l) \<longleftrightarrow> (f sums l)"
   607   by (simp add: sums_def lim_cnj cnj_setsum [symmetric])
   608 
   609 
   610 subsection{*Basic Lemmas*}
   611 
   612 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"
   613   by (metis complex_Im_zero complex_Re_zero complex_eqI sum_power2_eq_zero_iff)
   614 
   615 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"
   616 by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)
   617 
   618 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"
   619 apply (cases z, auto)
   620 by (metis complex_of_real_def of_real_add of_real_power power2_eq_square)
   621 
   622 lemma complex_div_eq_0: 
   623     "(Re(a / b) = 0 \<longleftrightarrow> Re(a * cnj b) = 0) & (Im(a / b) = 0 \<longleftrightarrow> Im(a * cnj b) = 0)"
   624 proof (cases "b=0")
   625   case True then show ?thesis by auto
   626 next
   627   case False
   628   show ?thesis
   629   proof (cases b)
   630     case (Complex x y)
   631     then have "x\<^sup>2 + y\<^sup>2 > 0"
   632       by (metis Complex_eq_0 False sum_power2_gt_zero_iff)
   633     then have "!!u v. u / (x\<^sup>2 + y\<^sup>2) + v / (x\<^sup>2 + y\<^sup>2) = (u + v) / (x\<^sup>2 + y\<^sup>2)"
   634       by (metis add_divide_distrib)
   635     with Complex False show ?thesis
   636       by (auto simp: complex_divide_def)
   637   qed
   638 qed
   639 
   640 lemma re_complex_div_eq_0: "Re(a / b) = 0 \<longleftrightarrow> Re(a * cnj b) = 0"
   641   and im_complex_div_eq_0: "Im(a / b) = 0 \<longleftrightarrow> Im(a * cnj b) = 0"
   642 using complex_div_eq_0 by auto
   643 
   644 
   645 lemma complex_div_gt_0: 
   646     "(Re(a / b) > 0 \<longleftrightarrow> Re(a * cnj b) > 0) & (Im(a / b) > 0 \<longleftrightarrow> Im(a * cnj b) > 0)"
   647 proof (cases "b=0")
   648   case True then show ?thesis by auto
   649 next
   650   case False
   651   show ?thesis
   652   proof (cases b)
   653     case (Complex x y)
   654     then have "x\<^sup>2 + y\<^sup>2 > 0"
   655       by (metis Complex_eq_0 False sum_power2_gt_zero_iff)
   656     moreover have "!!u v. u / (x\<^sup>2 + y\<^sup>2) + v / (x\<^sup>2 + y\<^sup>2) = (u + v) / (x\<^sup>2 + y\<^sup>2)"
   657       by (metis add_divide_distrib)
   658     ultimately show ?thesis using Complex False `0 < x\<^sup>2 + y\<^sup>2`
   659       apply (simp add: complex_divide_def  zero_less_divide_iff less_divide_eq)
   660       apply (metis less_divide_eq mult_zero_left diff_conv_add_uminus minus_divide_left)
   661       done
   662   qed
   663 qed
   664 
   665 lemma re_complex_div_gt_0: "Re(a / b) > 0 \<longleftrightarrow> Re(a * cnj b) > 0"
   666   and im_complex_div_gt_0: "Im(a / b) > 0 \<longleftrightarrow> Im(a * cnj b) > 0"
   667 using complex_div_gt_0 by auto
   668 
   669 lemma re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"
   670   by (metis le_less re_complex_div_eq_0 re_complex_div_gt_0)
   671 
   672 lemma im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"
   673   by (metis im_complex_div_eq_0 im_complex_div_gt_0 le_less)
   674 
   675 lemma re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"
   676   by (metis less_asym neq_iff re_complex_div_eq_0 re_complex_div_gt_0)
   677 
   678 lemma im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"
   679   by (metis im_complex_div_eq_0 im_complex_div_gt_0 less_asym neq_iff)
   680 
   681 lemma re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"
   682   by (metis not_le re_complex_div_gt_0)
   683 
   684 lemma im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"
   685   by (metis im_complex_div_gt_0 not_le)
   686 
   687 lemma Re_setsum: "Re(setsum f s) = setsum (%x. Re(f x)) s"
   688   by (induct s rule: infinite_finite_induct) auto
   689 
   690 lemma Im_setsum: "Im(setsum f s) = setsum (%x. Im(f x)) s"
   691   by (induct s rule: infinite_finite_induct) auto
   692 
   693 lemma sums_complex_iff: "f sums x \<longleftrightarrow> ((\<lambda>x. Re (f x)) sums Re x) \<and> ((\<lambda>x. Im (f x)) sums Im x)"
   694   unfolding sums_def tendsto_complex_iff Im_setsum Re_setsum ..
   695   
   696 lemma summable_complex_iff: "summable f \<longleftrightarrow> summable (\<lambda>x. Re (f x)) \<and>  summable (\<lambda>x. Im (f x))"
   697   unfolding summable_def sums_complex_iff[abs_def] by (metis Im.simps Re.simps)
   698 
   699 lemma summable_complex_of_real [simp]: "summable (\<lambda>n. complex_of_real (f n)) \<longleftrightarrow> summable f"
   700   unfolding summable_complex_iff by simp
   701 
   702 lemma summable_Re: "summable f \<Longrightarrow> summable (\<lambda>x. Re (f x))"
   703   unfolding summable_complex_iff by blast
   704 
   705 lemma summable_Im: "summable f \<Longrightarrow> summable (\<lambda>x. Im (f x))"
   706   unfolding summable_complex_iff by blast
   707 
   708 lemma Complex_setsum': "setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"
   709   by (induct s rule: infinite_finite_induct) auto
   710 
   711 lemma Complex_setsum: "Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"
   712   by (metis Complex_setsum')
   713 
   714 lemma of_real_setsum: "of_real (setsum f s) = setsum (%x. of_real(f x)) s"
   715   by (induct s rule: infinite_finite_induct) auto
   716 
   717 lemma of_real_setprod: "of_real (setprod f s) = setprod (%x. of_real(f x)) s"
   718   by (induct s rule: infinite_finite_induct) auto
   719 
   720 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"
   721 by (metis Reals_cases Reals_of_real complex.exhaust complex.inject complex_cnj 
   722           complex_of_real_def equal_neg_zero)
   723 
   724 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"
   725   by (metis Reals_of_real complex_of_real_def)
   726 
   727 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm(z) = abs(Re z)"
   728   by (metis Re_complex_of_real Reals_cases norm_of_real)
   729 
   730 lemma complex_is_Real_iff: "z \<in> \<real> \<longleftrightarrow> Im z = 0"
   731   by (metis Complex_in_Reals Im_complex_of_real Reals_cases complex_surj)
   732 
   733 lemma series_comparison_complex:
   734   fixes f:: "nat \<Rightarrow> 'a::banach"
   735   assumes sg: "summable g"
   736      and "\<And>n. g n \<in> \<real>" "\<And>n. Re (g n) \<ge> 0"
   737      and fg: "\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> norm(g n)"
   738   shows "summable f"
   739 proof -
   740   have g: "\<And>n. cmod (g n) = Re (g n)" using assms
   741     by (metis abs_of_nonneg in_Reals_norm)
   742   show ?thesis
   743     apply (rule summable_comparison_test' [where g = "\<lambda>n. norm (g n)" and N=N])
   744     using sg
   745     apply (auto simp: summable_def)
   746     apply (rule_tac x="Re s" in exI)
   747     apply (auto simp: g sums_Re)
   748     apply (metis fg g)
   749     done
   750 qed
   751 
   752 subsection{*Finally! Polar Form for Complex Numbers*}
   753 
   754 subsubsection {* $\cos \theta + i \sin \theta$ *}
   755 
   756 definition cis :: "real \<Rightarrow> complex" where
   757   "cis a = Complex (cos a) (sin a)"
   758 
   759 lemma Re_cis [simp]: "Re (cis a) = cos a"
   760   by (simp add: cis_def)
   761 
   762 lemma Im_cis [simp]: "Im (cis a) = sin a"
   763   by (simp add: cis_def)
   764 
   765 lemma cis_zero [simp]: "cis 0 = 1"
   766   by (simp add: cis_def)
   767 
   768 lemma norm_cis [simp]: "norm (cis a) = 1"
   769   by (simp add: cis_def)
   770 
   771 lemma sgn_cis [simp]: "sgn (cis a) = cis a"
   772   by (simp add: sgn_div_norm)
   773 
   774 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
   775   by (metis norm_cis norm_zero zero_neq_one)
   776 
   777 lemma cis_mult: "cis a * cis b = cis (a + b)"
   778   by (simp add: cis_def cos_add sin_add)
   779 
   780 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   781   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)
   782 
   783 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   784   by (simp add: cis_def)
   785 
   786 lemma cis_divide: "cis a / cis b = cis (a - b)"
   787   by (simp add: complex_divide_def cis_mult)
   788 
   789 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   790   by (auto simp add: DeMoivre)
   791 
   792 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   793   by (auto simp add: DeMoivre)
   794 
   795 subsubsection {* $r(\cos \theta + i \sin \theta)$ *}
   796 
   797 definition rcis :: "[real, real] \<Rightarrow> complex" where
   798   "rcis r a = complex_of_real r * cis a"
   799 
   800 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   801   by (simp add: rcis_def)
   802 
   803 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   804   by (simp add: rcis_def)
   805 
   806 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   807   by (simp add: complex_eq_iff polar_Ex)
   808 
   809 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   810   by (simp add: rcis_def norm_mult)
   811 
   812 lemma cis_rcis_eq: "cis a = rcis 1 a"
   813   by (simp add: rcis_def)
   814 
   815 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   816   by (simp add: rcis_def cis_mult)
   817 
   818 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   819   by (simp add: rcis_def)
   820 
   821 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   822   by (simp add: rcis_def)
   823 
   824 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
   825   by (simp add: rcis_def)
   826 
   827 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   828   by (simp add: rcis_def power_mult_distrib DeMoivre)
   829 
   830 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   831   by (simp add: divide_inverse rcis_def)
   832 
   833 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   834   by (simp add: rcis_def cis_divide [symmetric])
   835 
   836 subsubsection {* Complex exponential *}
   837 
   838 abbreviation expi :: "complex \<Rightarrow> complex"
   839   where "expi \<equiv> exp"
   840 
   841 lemma cis_conv_exp: "cis b = exp (Complex 0 b)"
   842 proof (rule complex_eqI)
   843   { fix n have "Complex 0 b ^ n =
   844     real (fact n) *\<^sub>R Complex (cos_coeff n * b ^ n) (sin_coeff n * b ^ n)"
   845       apply (induct n)
   846       apply (simp add: cos_coeff_def sin_coeff_def)
   847       apply (simp add: sin_coeff_Suc cos_coeff_Suc del: mult_Suc)
   848       done } note * = this
   849   show "Re (cis b) = Re (exp (Complex 0 b))"
   850     unfolding exp_def cis_def cos_def
   851     by (subst bounded_linear.suminf[OF bounded_linear_Re summable_exp_generic],
   852       simp add: * mult_assoc [symmetric])
   853   show "Im (cis b) = Im (exp (Complex 0 b))"
   854     unfolding exp_def cis_def sin_def
   855     by (subst bounded_linear.suminf[OF bounded_linear_Im summable_exp_generic],
   856       simp add: * mult_assoc [symmetric])
   857 qed
   858 
   859 lemma expi_def: "expi z = complex_of_real (exp (Re z)) * cis (Im z)"
   860   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by simp
   861 
   862 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
   863   unfolding expi_def by simp
   864 
   865 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
   866   unfolding expi_def by simp
   867 
   868 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   869 apply (insert rcis_Ex [of z])
   870 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   871 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   872 done
   873 
   874 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   875   by (simp add: expi_def cis_def)
   876 
   877 subsubsection {* Complex argument *}
   878 
   879 definition arg :: "complex \<Rightarrow> real" where
   880   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"
   881 
   882 lemma arg_zero: "arg 0 = 0"
   883   by (simp add: arg_def)
   884 
   885 lemma of_nat_less_of_int_iff: (* TODO: move *)
   886   "(of_nat n :: 'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"
   887   by (metis of_int_of_nat_eq of_int_less_iff)
   888 
   889 lemma real_of_nat_less_numeral_iff [simp]: (* TODO: move *)
   890   "real (n::nat) < numeral w \<longleftrightarrow> n < numeral w"
   891   using of_nat_less_of_int_iff [of n "numeral w", where 'a=real]
   892   by (simp add: real_of_nat_def zless_nat_eq_int_zless [symmetric])
   893 
   894 lemma arg_unique:
   895   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
   896   shows "arg z = x"
   897 proof -
   898   from assms have "z \<noteq> 0" by auto
   899   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
   900   proof
   901     fix a def d \<equiv> "a - x"
   902     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
   903     from a assms have "- (2*pi) < d \<and> d < 2*pi"
   904       unfolding d_def by simp
   905     moreover from a assms have "cos a = cos x" and "sin a = sin x"
   906       by (simp_all add: complex_eq_iff)
   907     hence cos: "cos d = 1" unfolding d_def cos_diff by simp
   908     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)
   909     ultimately have "d = 0"
   910       unfolding sin_zero_iff even_mult_two_ex
   911       by (auto simp add: numeral_2_eq_2 less_Suc_eq)
   912     thus "a = x" unfolding d_def by simp
   913   qed (simp add: assms del: Re_sgn Im_sgn)
   914   with `z \<noteq> 0` show "arg z = x"
   915     unfolding arg_def by simp
   916 qed
   917 
   918 lemma arg_correct:
   919   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
   920 proof (simp add: arg_def assms, rule someI_ex)
   921   obtain r a where z: "z = rcis r a" using rcis_Ex by fast
   922   with assms have "r \<noteq> 0" by auto
   923   def b \<equiv> "if 0 < r then a else a + pi"
   924   have b: "sgn z = cis b"
   925     unfolding z b_def rcis_def using `r \<noteq> 0`
   926     by (simp add: of_real_def sgn_scaleR sgn_if, simp add: cis_def)
   927   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"
   928     by (induct_tac n, simp_all add: distrib_left cis_mult [symmetric],
   929       simp add: cis_def)
   930   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"
   931     by (case_tac x rule: int_diff_cases,
   932       simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
   933   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"
   934   have "sgn z = cis c"
   935     unfolding b c_def
   936     by (simp add: cis_divide [symmetric] cis_2pi_int)
   937   moreover have "- pi < c \<and> c \<le> pi"
   938     using ceiling_correct [of "(b - pi) / (2*pi)"]
   939     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)
   940   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast
   941 qed
   942 
   943 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
   944   by (cases "z = 0", simp_all add: arg_zero arg_correct)
   945 
   946 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
   947   by (simp add: arg_correct)
   948 
   949 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
   950   by (cases "z = 0", simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
   951 
   952 lemma cos_arg_i_mult_zero [simp]:
   953      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   954   using cis_arg [of "Complex 0 y"] by (simp add: complex_eq_iff)
   955 
   956 text {* Legacy theorem names *}
   957 
   958 lemmas expand_complex_eq = complex_eq_iff
   959 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
   960 lemmas complex_equality = complex_eqI
   961 
   962 end