src/HOL/Analysis/Cartesian_Euclidean_Space.thy
author nipkow
Thu Dec 07 15:48:50 2017 +0100 (7 months ago)
changeset 67155 9e5b05d54f9d
parent 66804 3f9bb52082c4
child 67399 eab6ce8368fa
permissions -rw-r--r--
canonical name
     1 section \<open>Instantiates the finite Cartesian product of Euclidean spaces as a Euclidean space.\<close>
     2 
     3 theory Cartesian_Euclidean_Space
     4 imports Finite_Cartesian_Product Derivative 
     5 begin
     6 
     7 lemma subspace_special_hyperplane: "subspace {x. x $ k = 0}"
     8   by (simp add: subspace_def)
     9 
    10 lemma delta_mult_idempotent:
    11   "(if k=a then 1 else (0::'a::semiring_1)) * (if k=a then 1 else 0) = (if k=a then 1 else 0)"
    12   by simp
    13 
    14 (*move up?*)
    15 lemma sum_UNIV_sum:
    16   fixes g :: "'a::finite + 'b::finite \<Rightarrow> _"
    17   shows "(\<Sum>x\<in>UNIV. g x) = (\<Sum>x\<in>UNIV. g (Inl x)) + (\<Sum>x\<in>UNIV. g (Inr x))"
    18   apply (subst UNIV_Plus_UNIV [symmetric])
    19   apply (subst sum.Plus)
    20   apply simp_all
    21   done
    22 
    23 lemma sum_mult_product:
    24   "sum h {..<A * B :: nat} = (\<Sum>i\<in>{..<A}. \<Sum>j\<in>{..<B}. h (j + i * B))"
    25   unfolding sum_nat_group[of h B A, unfolded atLeast0LessThan, symmetric]
    26 proof (rule sum.cong, simp, rule sum.reindex_cong)
    27   fix i
    28   show "inj_on (\<lambda>j. j + i * B) {..<B}" by (auto intro!: inj_onI)
    29   show "{i * B..<i * B + B} = (\<lambda>j. j + i * B) ` {..<B}"
    30   proof safe
    31     fix j assume "j \<in> {i * B..<i * B + B}"
    32     then show "j \<in> (\<lambda>j. j + i * B) ` {..<B}"
    33       by (auto intro!: image_eqI[of _ _ "j - i * B"])
    34   qed simp
    35 qed simp
    36 
    37 subsection\<open>Basic componentwise operations on vectors.\<close>
    38 
    39 instantiation vec :: (times, finite) times
    40 begin
    41 
    42 definition "op * \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) * (y$i)))"
    43 instance ..
    44 
    45 end
    46 
    47 instantiation vec :: (one, finite) one
    48 begin
    49 
    50 definition "1 \<equiv> (\<chi> i. 1)"
    51 instance ..
    52 
    53 end
    54 
    55 instantiation vec :: (ord, finite) ord
    56 begin
    57 
    58 definition "x \<le> y \<longleftrightarrow> (\<forall>i. x$i \<le> y$i)"
    59 definition "x < (y::'a^'b) \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
    60 instance ..
    61 
    62 end
    63 
    64 text\<open>The ordering on one-dimensional vectors is linear.\<close>
    65 
    66 class cart_one =
    67   assumes UNIV_one: "card (UNIV :: 'a set) = Suc 0"
    68 begin
    69 
    70 subclass finite
    71 proof
    72   from UNIV_one show "finite (UNIV :: 'a set)"
    73     by (auto intro!: card_ge_0_finite)
    74 qed
    75 
    76 end
    77 
    78 instance vec:: (order, finite) order
    79   by standard (auto simp: less_eq_vec_def less_vec_def vec_eq_iff
    80       intro: order.trans order.antisym order.strict_implies_order)
    81 
    82 instance vec :: (linorder, cart_one) linorder
    83 proof
    84   obtain a :: 'b where all: "\<And>P. (\<forall>i. P i) \<longleftrightarrow> P a"
    85   proof -
    86     have "card (UNIV :: 'b set) = Suc 0" by (rule UNIV_one)
    87     then obtain b :: 'b where "UNIV = {b}" by (auto iff: card_Suc_eq)
    88     then have "\<And>P. (\<forall>i\<in>UNIV. P i) \<longleftrightarrow> P b" by auto
    89     then show thesis by (auto intro: that)
    90   qed
    91   fix x y :: "'a^'b::cart_one"
    92   note [simp] = less_eq_vec_def less_vec_def all vec_eq_iff field_simps
    93   show "x \<le> y \<or> y \<le> x" by auto
    94 qed
    95 
    96 text\<open>Constant Vectors\<close>
    97 
    98 definition "vec x = (\<chi> i. x)"
    99 
   100 lemma interval_cbox_cart: "{a::real^'n..b} = cbox a b"
   101   by (auto simp add: less_eq_vec_def mem_box Basis_vec_def inner_axis)
   102 
   103 text\<open>Also the scalar-vector multiplication.\<close>
   104 
   105 definition vector_scalar_mult:: "'a::times \<Rightarrow> 'a ^ 'n \<Rightarrow> 'a ^ 'n" (infixl "*s" 70)
   106   where "c *s x = (\<chi> i. c * (x$i))"
   107 
   108 
   109 subsection \<open>A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space.\<close>
   110 
   111 lemma sum_cong_aux:
   112   "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> sum f A = sum g A"
   113   by (auto intro: sum.cong)
   114 
   115 hide_fact (open) sum_cong_aux
   116 
   117 method_setup vector = \<open>
   118 let
   119   val ss1 =
   120     simpset_of (put_simpset HOL_basic_ss @{context}
   121       addsimps [@{thm sum.distrib} RS sym,
   122       @{thm sum_subtractf} RS sym, @{thm sum_distrib_left},
   123       @{thm sum_distrib_right}, @{thm sum_negf} RS sym])
   124   val ss2 =
   125     simpset_of (@{context} addsimps
   126              [@{thm plus_vec_def}, @{thm times_vec_def},
   127               @{thm minus_vec_def}, @{thm uminus_vec_def},
   128               @{thm one_vec_def}, @{thm zero_vec_def}, @{thm vec_def},
   129               @{thm scaleR_vec_def},
   130               @{thm vec_lambda_beta}, @{thm vector_scalar_mult_def}])
   131   fun vector_arith_tac ctxt ths =
   132     simp_tac (put_simpset ss1 ctxt)
   133     THEN' (fn i => resolve_tac ctxt @{thms Cartesian_Euclidean_Space.sum_cong_aux} i
   134          ORELSE resolve_tac ctxt @{thms sum.neutral} i
   135          ORELSE simp_tac (put_simpset HOL_basic_ss ctxt addsimps [@{thm vec_eq_iff}]) i)
   136     (* THEN' TRY o clarify_tac HOL_cs  THEN' (TRY o rtac @{thm iffI}) *)
   137     THEN' asm_full_simp_tac (put_simpset ss2 ctxt addsimps ths)
   138 in
   139   Attrib.thms >> (fn ths => fn ctxt => SIMPLE_METHOD' (vector_arith_tac ctxt ths))
   140 end
   141 \<close> "lift trivial vector statements to real arith statements"
   142 
   143 lemma vec_0[simp]: "vec 0 = 0" by vector
   144 lemma vec_1[simp]: "vec 1 = 1" by vector
   145 
   146 lemma vec_inj[simp]: "vec x = vec y \<longleftrightarrow> x = y" by vector
   147 
   148 lemma vec_in_image_vec: "vec x \<in> (vec ` S) \<longleftrightarrow> x \<in> S" by auto
   149 
   150 lemma vec_add: "vec(x + y) = vec x + vec y"  by vector
   151 lemma vec_sub: "vec(x - y) = vec x - vec y" by vector
   152 lemma vec_cmul: "vec(c * x) = c *s vec x " by vector
   153 lemma vec_neg: "vec(- x) = - vec x " by vector
   154 
   155 lemma vec_sum:
   156   assumes "finite S"
   157   shows "vec(sum f S) = sum (vec \<circ> f) S"
   158   using assms
   159 proof induct
   160   case empty
   161   then show ?case by simp
   162 next
   163   case insert
   164   then show ?case by (auto simp add: vec_add)
   165 qed
   166 
   167 text\<open>Obvious "component-pushing".\<close>
   168 
   169 lemma vec_component [simp]: "vec x $ i = x"
   170   by vector
   171 
   172 lemma vector_mult_component [simp]: "(x * y)$i = x$i * y$i"
   173   by vector
   174 
   175 lemma vector_smult_component [simp]: "(c *s y)$i = c * (y$i)"
   176   by vector
   177 
   178 lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector
   179 
   180 lemmas vector_component =
   181   vec_component vector_add_component vector_mult_component
   182   vector_smult_component vector_minus_component vector_uminus_component
   183   vector_scaleR_component cond_component
   184 
   185 
   186 subsection \<open>Some frequently useful arithmetic lemmas over vectors.\<close>
   187 
   188 instance vec :: (semigroup_mult, finite) semigroup_mult
   189   by standard (vector mult.assoc)
   190 
   191 instance vec :: (monoid_mult, finite) monoid_mult
   192   by standard vector+
   193 
   194 instance vec :: (ab_semigroup_mult, finite) ab_semigroup_mult
   195   by standard (vector mult.commute)
   196 
   197 instance vec :: (comm_monoid_mult, finite) comm_monoid_mult
   198   by standard vector
   199 
   200 instance vec :: (semiring, finite) semiring
   201   by standard (vector field_simps)+
   202 
   203 instance vec :: (semiring_0, finite) semiring_0
   204   by standard (vector field_simps)+
   205 instance vec :: (semiring_1, finite) semiring_1
   206   by standard vector
   207 instance vec :: (comm_semiring, finite) comm_semiring
   208   by standard (vector field_simps)+
   209 
   210 instance vec :: (comm_semiring_0, finite) comm_semiring_0 ..
   211 instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
   212 instance vec :: (semiring_0_cancel, finite) semiring_0_cancel ..
   213 instance vec :: (comm_semiring_0_cancel, finite) comm_semiring_0_cancel ..
   214 instance vec :: (ring, finite) ring ..
   215 instance vec :: (semiring_1_cancel, finite) semiring_1_cancel ..
   216 instance vec :: (comm_semiring_1, finite) comm_semiring_1 ..
   217 
   218 instance vec :: (ring_1, finite) ring_1 ..
   219 
   220 instance vec :: (real_algebra, finite) real_algebra
   221   by standard (simp_all add: vec_eq_iff)
   222 
   223 instance vec :: (real_algebra_1, finite) real_algebra_1 ..
   224 
   225 lemma of_nat_index: "(of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
   226 proof (induct n)
   227   case 0
   228   then show ?case by vector
   229 next
   230   case Suc
   231   then show ?case by vector
   232 qed
   233 
   234 lemma one_index [simp]: "(1 :: 'a :: one ^ 'n) $ i = 1"
   235   by vector
   236 
   237 lemma neg_one_index [simp]: "(- 1 :: 'a :: {one, uminus} ^ 'n) $ i = - 1"
   238   by vector
   239 
   240 instance vec :: (semiring_char_0, finite) semiring_char_0
   241 proof
   242   fix m n :: nat
   243   show "inj (of_nat :: nat \<Rightarrow> 'a ^ 'b)"
   244     by (auto intro!: injI simp add: vec_eq_iff of_nat_index)
   245 qed
   246 
   247 instance vec :: (numeral, finite) numeral ..
   248 instance vec :: (semiring_numeral, finite) semiring_numeral ..
   249 
   250 lemma numeral_index [simp]: "numeral w $ i = numeral w"
   251   by (induct w) (simp_all only: numeral.simps vector_add_component one_index)
   252 
   253 lemma neg_numeral_index [simp]: "- numeral w $ i = - numeral w"
   254   by (simp only: vector_uminus_component numeral_index)
   255 
   256 instance vec :: (comm_ring_1, finite) comm_ring_1 ..
   257 instance vec :: (ring_char_0, finite) ring_char_0 ..
   258 
   259 lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"
   260   by (vector mult.assoc)
   261 lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x"
   262   by (vector field_simps)
   263 lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y"
   264   by (vector field_simps)
   265 lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
   266 lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
   267 lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y"
   268   by (vector field_simps)
   269 lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
   270 lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
   271 lemma vector_sneg_minus1: "-x = (-1::'a::ring_1) *s x" by vector
   272 lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
   273 lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x"
   274   by (vector field_simps)
   275 
   276 lemma vec_eq[simp]: "(vec m = vec n) \<longleftrightarrow> (m = n)"
   277   by (simp add: vec_eq_iff)
   278 
   279 lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n)" by (metis norm_eq_zero)
   280 lemma vector_mul_eq_0[simp]: "(a *s x = 0) \<longleftrightarrow> a = (0::'a::idom) \<or> x = 0"
   281   by vector
   282 lemma vector_mul_lcancel[simp]: "a *s x = a *s y \<longleftrightarrow> a = (0::real) \<or> x = y"
   283   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
   284 lemma vector_mul_rcancel[simp]: "a *s x = b *s x \<longleftrightarrow> (a::real) = b \<or> x = 0"
   285   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
   286 lemma vector_mul_lcancel_imp: "a \<noteq> (0::real) ==>  a *s x = a *s y ==> (x = y)"
   287   by (metis vector_mul_lcancel)
   288 lemma vector_mul_rcancel_imp: "x \<noteq> 0 \<Longrightarrow> (a::real) *s x = b *s x ==> a = b"
   289   by (metis vector_mul_rcancel)
   290 
   291 lemma component_le_norm_cart: "\<bar>x$i\<bar> <= norm x"
   292   apply (simp add: norm_vec_def)
   293   apply (rule member_le_L2_set, simp_all)
   294   done
   295 
   296 lemma norm_bound_component_le_cart: "norm x <= e ==> \<bar>x$i\<bar> <= e"
   297   by (metis component_le_norm_cart order_trans)
   298 
   299 lemma norm_bound_component_lt_cart: "norm x < e ==> \<bar>x$i\<bar> < e"
   300   by (metis component_le_norm_cart le_less_trans)
   301 
   302 lemma norm_le_l1_cart: "norm x <= sum(\<lambda>i. \<bar>x$i\<bar>) UNIV"
   303   by (simp add: norm_vec_def L2_set_le_sum)
   304 
   305 lemma scalar_mult_eq_scaleR: "c *s x = c *\<^sub>R x"
   306   unfolding scaleR_vec_def vector_scalar_mult_def by simp
   307 
   308 lemma dist_mul[simp]: "dist (c *s x) (c *s y) = \<bar>c\<bar> * dist x y"
   309   unfolding dist_norm scalar_mult_eq_scaleR
   310   unfolding scaleR_right_diff_distrib[symmetric] by simp
   311 
   312 lemma sum_component [simp]:
   313   fixes f:: " 'a \<Rightarrow> ('b::comm_monoid_add) ^'n"
   314   shows "(sum f S)$i = sum (\<lambda>x. (f x)$i) S"
   315 proof (cases "finite S")
   316   case True
   317   then show ?thesis by induct simp_all
   318 next
   319   case False
   320   then show ?thesis by simp
   321 qed
   322 
   323 lemma sum_eq: "sum f S = (\<chi> i. sum (\<lambda>x. (f x)$i ) S)"
   324   by (simp add: vec_eq_iff)
   325 
   326 lemma sum_cmul:
   327   fixes f:: "'c \<Rightarrow> ('a::semiring_1)^'n"
   328   shows "sum (\<lambda>x. c *s f x) S = c *s sum f S"
   329   by (simp add: vec_eq_iff sum_distrib_left)
   330 
   331 lemma sum_norm_allsubsets_bound_cart:
   332   fixes f:: "'a \<Rightarrow> real ^'n"
   333   assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (sum f Q) \<le> e"
   334   shows "sum (\<lambda>x. norm (f x)) P \<le> 2 * real CARD('n) *  e"
   335   using sum_norm_allsubsets_bound[OF assms]
   336   by simp
   337 
   338 subsection\<open>Closures and interiors of halfspaces\<close>
   339 
   340 lemma interior_halfspace_le [simp]:
   341   assumes "a \<noteq> 0"
   342     shows "interior {x. a \<bullet> x \<le> b} = {x. a \<bullet> x < b}"
   343 proof -
   344   have *: "a \<bullet> x < b" if x: "x \<in> S" and S: "S \<subseteq> {x. a \<bullet> x \<le> b}" and "open S" for S x
   345   proof -
   346     obtain e where "e>0" and e: "cball x e \<subseteq> S"
   347       using \<open>open S\<close> open_contains_cball x by blast
   348     then have "x + (e / norm a) *\<^sub>R a \<in> cball x e"
   349       by (simp add: dist_norm)
   350     then have "x + (e / norm a) *\<^sub>R a \<in> S"
   351       using e by blast
   352     then have "x + (e / norm a) *\<^sub>R a \<in> {x. a \<bullet> x \<le> b}"
   353       using S by blast
   354     moreover have "e * (a \<bullet> a) / norm a > 0"
   355       by (simp add: \<open>0 < e\<close> assms)
   356     ultimately show ?thesis
   357       by (simp add: algebra_simps)
   358   qed
   359   show ?thesis
   360     by (rule interior_unique) (auto simp: open_halfspace_lt *)
   361 qed
   362 
   363 lemma interior_halfspace_ge [simp]:
   364    "a \<noteq> 0 \<Longrightarrow> interior {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x > b}"
   365 using interior_halfspace_le [of "-a" "-b"] by simp
   366 
   367 lemma interior_halfspace_component_le [simp]:
   368      "interior {x. x$k \<le> a} = {x :: (real,'n::finite) vec. x$k < a}" (is "?LE")
   369   and interior_halfspace_component_ge [simp]:
   370      "interior {x. x$k \<ge> a} = {x :: (real,'n::finite) vec. x$k > a}" (is "?GE")
   371 proof -
   372   have "axis k (1::real) \<noteq> 0"
   373     by (simp add: axis_def vec_eq_iff)
   374   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   375     by (simp add: cart_eq_inner_axis inner_commute)
   376   ultimately show ?LE ?GE
   377     using interior_halfspace_le [of "axis k (1::real)" a]
   378           interior_halfspace_ge [of "axis k (1::real)" a] by auto
   379 qed
   380 
   381 lemma closure_halfspace_lt [simp]:
   382   assumes "a \<noteq> 0"
   383     shows "closure {x. a \<bullet> x < b} = {x. a \<bullet> x \<le> b}"
   384 proof -
   385   have [simp]: "-{x. a \<bullet> x < b} = {x. a \<bullet> x \<ge> b}"
   386     by (force simp:)
   387   then show ?thesis
   388     using interior_halfspace_ge [of a b] assms
   389     by (force simp: closure_interior)
   390 qed
   391 
   392 lemma closure_halfspace_gt [simp]:
   393    "a \<noteq> 0 \<Longrightarrow> closure {x. a \<bullet> x > b} = {x. a \<bullet> x \<ge> b}"
   394 using closure_halfspace_lt [of "-a" "-b"] by simp
   395 
   396 lemma closure_halfspace_component_lt [simp]:
   397      "closure {x. x$k < a} = {x :: (real,'n::finite) vec. x$k \<le> a}" (is "?LE")
   398   and closure_halfspace_component_gt [simp]:
   399      "closure {x. x$k > a} = {x :: (real,'n::finite) vec. x$k \<ge> a}" (is "?GE")
   400 proof -
   401   have "axis k (1::real) \<noteq> 0"
   402     by (simp add: axis_def vec_eq_iff)
   403   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   404     by (simp add: cart_eq_inner_axis inner_commute)
   405   ultimately show ?LE ?GE
   406     using closure_halfspace_lt [of "axis k (1::real)" a]
   407           closure_halfspace_gt [of "axis k (1::real)" a] by auto
   408 qed
   409 
   410 lemma interior_hyperplane [simp]:
   411   assumes "a \<noteq> 0"
   412     shows "interior {x. a \<bullet> x = b} = {}"
   413 proof -
   414   have [simp]: "{x. a \<bullet> x = b} = {x. a \<bullet> x \<le> b} \<inter> {x. a \<bullet> x \<ge> b}"
   415     by (force simp:)
   416   then show ?thesis
   417     by (auto simp: assms)
   418 qed
   419 
   420 lemma frontier_halfspace_le:
   421   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   422     shows "frontier {x. a \<bullet> x \<le> b} = {x. a \<bullet> x = b}"
   423 proof (cases "a = 0")
   424   case True with assms show ?thesis by simp
   425 next
   426   case False then show ?thesis
   427     by (force simp: frontier_def closed_halfspace_le)
   428 qed
   429 
   430 lemma frontier_halfspace_ge:
   431   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   432     shows "frontier {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x = b}"
   433 proof (cases "a = 0")
   434   case True with assms show ?thesis by simp
   435 next
   436   case False then show ?thesis
   437     by (force simp: frontier_def closed_halfspace_ge)
   438 qed
   439 
   440 lemma frontier_halfspace_lt:
   441   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   442     shows "frontier {x. a \<bullet> x < b} = {x. a \<bullet> x = b}"
   443 proof (cases "a = 0")
   444   case True with assms show ?thesis by simp
   445 next
   446   case False then show ?thesis
   447     by (force simp: frontier_def interior_open open_halfspace_lt)
   448 qed
   449 
   450 lemma frontier_halfspace_gt:
   451   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   452     shows "frontier {x. a \<bullet> x > b} = {x. a \<bullet> x = b}"
   453 proof (cases "a = 0")
   454   case True with assms show ?thesis by simp
   455 next
   456   case False then show ?thesis
   457     by (force simp: frontier_def interior_open open_halfspace_gt)
   458 qed
   459 
   460 lemma interior_standard_hyperplane:
   461    "interior {x :: (real,'n::finite) vec. x$k = a} = {}"
   462 proof -
   463   have "axis k (1::real) \<noteq> 0"
   464     by (simp add: axis_def vec_eq_iff)
   465   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   466     by (simp add: cart_eq_inner_axis inner_commute)
   467   ultimately show ?thesis
   468     using interior_hyperplane [of "axis k (1::real)" a]
   469     by force
   470 qed
   471 
   472 subsection \<open>Matrix operations\<close>
   473 
   474 text\<open>Matrix notation. NB: an MxN matrix is of type @{typ "'a^'n^'m"}, not @{typ "'a^'m^'n"}\<close>
   475 
   476 definition matrix_matrix_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'p^'n \<Rightarrow> 'a ^ 'p ^'m"
   477     (infixl "**" 70)
   478   where "m ** m' == (\<chi> i j. sum (\<lambda>k. ((m$i)$k) * ((m'$k)$j)) (UNIV :: 'n set)) ::'a ^ 'p ^'m"
   479 
   480 definition matrix_vector_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'm"
   481     (infixl "*v" 70)
   482   where "m *v x \<equiv> (\<chi> i. sum (\<lambda>j. ((m$i)$j) * (x$j)) (UNIV ::'n set)) :: 'a^'m"
   483 
   484 definition vector_matrix_mult :: "'a ^ 'm \<Rightarrow> ('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n "
   485     (infixl "v*" 70)
   486   where "v v* m == (\<chi> j. sum (\<lambda>i. ((m$i)$j) * (v$i)) (UNIV :: 'm set)) :: 'a^'n"
   487 
   488 definition "(mat::'a::zero => 'a ^'n^'n) k = (\<chi> i j. if i = j then k else 0)"
   489 definition transpose where
   490   "(transpose::'a^'n^'m \<Rightarrow> 'a^'m^'n) A = (\<chi> i j. ((A$j)$i))"
   491 definition "(row::'m => 'a ^'n^'m \<Rightarrow> 'a ^'n) i A = (\<chi> j. ((A$i)$j))"
   492 definition "(column::'n =>'a^'n^'m =>'a^'m) j A = (\<chi> i. ((A$i)$j))"
   493 definition "rows(A::'a^'n^'m) = { row i A | i. i \<in> (UNIV :: 'm set)}"
   494 definition "columns(A::'a^'n^'m) = { column i A | i. i \<in> (UNIV :: 'n set)}"
   495 
   496 lemma mat_0[simp]: "mat 0 = 0" by (vector mat_def)
   497 lemma matrix_add_ldistrib: "(A ** (B + C)) = (A ** B) + (A ** C)"
   498   by (vector matrix_matrix_mult_def sum.distrib[symmetric] field_simps)
   499 
   500 lemma matrix_mul_lid:
   501   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   502   shows "mat 1 ** A = A"
   503   apply (simp add: matrix_matrix_mult_def mat_def)
   504   apply vector
   505   apply (auto simp only: if_distrib cond_application_beta sum.delta'[OF finite]
   506     mult_1_left mult_zero_left if_True UNIV_I)
   507   done
   508 
   509 
   510 lemma matrix_mul_rid:
   511   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   512   shows "A ** mat 1 = A"
   513   apply (simp add: matrix_matrix_mult_def mat_def)
   514   apply vector
   515   apply (auto simp only: if_distrib cond_application_beta sum.delta[OF finite]
   516     mult_1_right mult_zero_right if_True UNIV_I cong: if_cong)
   517   done
   518 
   519 lemma matrix_mul_assoc: "A ** (B ** C) = (A ** B) ** C"
   520   apply (vector matrix_matrix_mult_def sum_distrib_left sum_distrib_right mult.assoc)
   521   apply (subst sum.swap)
   522   apply simp
   523   done
   524 
   525 lemma matrix_vector_mul_assoc: "A *v (B *v x) = (A ** B) *v x"
   526   apply (vector matrix_matrix_mult_def matrix_vector_mult_def
   527     sum_distrib_left sum_distrib_right mult.assoc)
   528   apply (subst sum.swap)
   529   apply simp
   530   done
   531 
   532 lemma matrix_vector_mul_lid: "mat 1 *v x = (x::'a::semiring_1 ^ 'n)"
   533   apply (vector matrix_vector_mult_def mat_def)
   534   apply (simp add: if_distrib cond_application_beta sum.delta' cong del: if_weak_cong)
   535   done
   536 
   537 lemma matrix_transpose_mul:
   538     "transpose(A ** B) = transpose B ** transpose (A::'a::comm_semiring_1^_^_)"
   539   by (simp add: matrix_matrix_mult_def transpose_def vec_eq_iff mult.commute)
   540 
   541 lemma matrix_eq:
   542   fixes A B :: "'a::semiring_1 ^ 'n ^ 'm"
   543   shows "A = B \<longleftrightarrow>  (\<forall>x. A *v x = B *v x)" (is "?lhs \<longleftrightarrow> ?rhs")
   544   apply auto
   545   apply (subst vec_eq_iff)
   546   apply clarify
   547   apply (clarsimp simp add: matrix_vector_mult_def if_distrib cond_application_beta vec_eq_iff cong del: if_weak_cong)
   548   apply (erule_tac x="axis ia 1" in allE)
   549   apply (erule_tac x="i" in allE)
   550   apply (auto simp add: if_distrib cond_application_beta axis_def
   551     sum.delta[OF finite] cong del: if_weak_cong)
   552   done
   553 
   554 lemma matrix_vector_mul_component: "((A::real^_^_) *v x)$k = (A$k) \<bullet> x"
   555   by (simp add: matrix_vector_mult_def inner_vec_def)
   556 
   557 lemma dot_lmul_matrix: "((x::real ^_) v* A) \<bullet> y = x \<bullet> (A *v y)"
   558   apply (simp add: inner_vec_def matrix_vector_mult_def vector_matrix_mult_def sum_distrib_right sum_distrib_left ac_simps)
   559   apply (subst sum.swap)
   560   apply simp
   561   done
   562 
   563 lemma transpose_mat: "transpose (mat n) = mat n"
   564   by (vector transpose_def mat_def)
   565 
   566 lemma transpose_transpose: "transpose(transpose A) = A"
   567   by (vector transpose_def)
   568 
   569 lemma row_transpose:
   570   fixes A:: "'a::semiring_1^_^_"
   571   shows "row i (transpose A) = column i A"
   572   by (simp add: row_def column_def transpose_def vec_eq_iff)
   573 
   574 lemma column_transpose:
   575   fixes A:: "'a::semiring_1^_^_"
   576   shows "column i (transpose A) = row i A"
   577   by (simp add: row_def column_def transpose_def vec_eq_iff)
   578 
   579 lemma rows_transpose: "rows(transpose (A::'a::semiring_1^_^_)) = columns A"
   580   by (auto simp add: rows_def columns_def row_transpose intro: set_eqI)
   581 
   582 lemma columns_transpose: "columns(transpose (A::'a::semiring_1^_^_)) = rows A"
   583   by (metis transpose_transpose rows_transpose)
   584 
   585 text\<open>Two sometimes fruitful ways of looking at matrix-vector multiplication.\<close>
   586 
   587 lemma matrix_mult_dot: "A *v x = (\<chi> i. A$i \<bullet> x)"
   588   by (simp add: matrix_vector_mult_def inner_vec_def)
   589 
   590 lemma matrix_mult_vsum:
   591   "(A::'a::comm_semiring_1^'n^'m) *v x = sum (\<lambda>i. (x$i) *s column i A) (UNIV:: 'n set)"
   592   by (simp add: matrix_vector_mult_def vec_eq_iff column_def mult.commute)
   593 
   594 lemma vector_componentwise:
   595   "(x::'a::ring_1^'n) = (\<chi> j. \<Sum>i\<in>UNIV. (x$i) * (axis i 1 :: 'a^'n) $ j)"
   596   by (simp add: axis_def if_distrib sum.If_cases vec_eq_iff)
   597 
   598 lemma basis_expansion: "sum (\<lambda>i. (x$i) *s axis i 1) UNIV = (x::('a::ring_1) ^'n)"
   599   by (auto simp add: axis_def vec_eq_iff if_distrib sum.If_cases cong del: if_weak_cong)
   600 
   601 lemma linear_componentwise_expansion:
   602   fixes f:: "real ^'m \<Rightarrow> real ^ _"
   603   assumes lf: "linear f"
   604   shows "(f x)$j = sum (\<lambda>i. (x$i) * (f (axis i 1)$j)) (UNIV :: 'm set)" (is "?lhs = ?rhs")
   605 proof -
   606   let ?M = "(UNIV :: 'm set)"
   607   let ?N = "(UNIV :: 'n set)"
   608   have "?rhs = (sum (\<lambda>i.(x$i) *\<^sub>R f (axis i 1) ) ?M)$j"
   609     unfolding sum_component by simp
   610   then show ?thesis
   611     unfolding linear_sum_mul[OF lf, symmetric]
   612     unfolding scalar_mult_eq_scaleR[symmetric]
   613     unfolding basis_expansion
   614     by simp
   615 qed
   616 
   617 text\<open>Inverse matrices  (not necessarily square)\<close>
   618 
   619 definition
   620   "invertible(A::'a::semiring_1^'n^'m) \<longleftrightarrow> (\<exists>A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   621 
   622 definition
   623   "matrix_inv(A:: 'a::semiring_1^'n^'m) =
   624     (SOME A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   625 
   626 text\<open>Correspondence between matrices and linear operators.\<close>
   627 
   628 definition matrix :: "('a::{plus,times, one, zero}^'m \<Rightarrow> 'a ^ 'n) \<Rightarrow> 'a^'m^'n"
   629   where "matrix f = (\<chi> i j. (f(axis j 1))$i)"
   630 
   631 lemma matrix_vector_mul_linear: "linear(\<lambda>x. A *v (x::real ^ _))"
   632   by (simp add: linear_iff matrix_vector_mult_def vec_eq_iff
   633       field_simps sum_distrib_left sum.distrib)
   634 
   635 lemma matrix_works:
   636   assumes lf: "linear f"
   637   shows "matrix f *v x = f (x::real ^ 'n)"
   638   apply (simp add: matrix_def matrix_vector_mult_def vec_eq_iff mult.commute)
   639   by (simp add: linear_componentwise_expansion lf)
   640 
   641 lemma matrix_vector_mul: "linear f ==> f = (\<lambda>x. matrix f *v (x::real ^ 'n))"
   642   by (simp add: ext matrix_works)
   643 
   644 lemma matrix_of_matrix_vector_mul: "matrix(\<lambda>x. A *v (x :: real ^ 'n)) = A"
   645   by (simp add: matrix_eq matrix_vector_mul_linear matrix_works)
   646 
   647 lemma matrix_compose:
   648   assumes lf: "linear (f::real^'n \<Rightarrow> real^'m)"
   649     and lg: "linear (g::real^'m \<Rightarrow> real^_)"
   650   shows "matrix (g \<circ> f) = matrix g ** matrix f"
   651   using lf lg linear_compose[OF lf lg] matrix_works[OF linear_compose[OF lf lg]]
   652   by (simp add: matrix_eq matrix_works matrix_vector_mul_assoc[symmetric] o_def)
   653 
   654 lemma matrix_vector_column:
   655   "(A::'a::comm_semiring_1^'n^_) *v x = sum (\<lambda>i. (x$i) *s ((transpose A)$i)) (UNIV:: 'n set)"
   656   by (simp add: matrix_vector_mult_def transpose_def vec_eq_iff mult.commute)
   657 
   658 lemma adjoint_matrix: "adjoint(\<lambda>x. (A::real^'n^'m) *v x) = (\<lambda>x. transpose A *v x)"
   659   apply (rule adjoint_unique)
   660   apply (simp add: transpose_def inner_vec_def matrix_vector_mult_def
   661     sum_distrib_right sum_distrib_left)
   662   apply (subst sum.swap)
   663   apply (auto simp add: ac_simps)
   664   done
   665 
   666 lemma matrix_adjoint: assumes lf: "linear (f :: real^'n \<Rightarrow> real ^'m)"
   667   shows "matrix(adjoint f) = transpose(matrix f)"
   668   apply (subst matrix_vector_mul[OF lf])
   669   unfolding adjoint_matrix matrix_of_matrix_vector_mul
   670   apply rule
   671   done
   672 
   673 
   674 subsection \<open>lambda skolemization on cartesian products\<close>
   675 
   676 (* FIXME: rename do choice_cart *)
   677 
   678 lemma lambda_skolem: "(\<forall>i. \<exists>x. P i x) \<longleftrightarrow>
   679    (\<exists>x::'a ^ 'n. \<forall>i. P i (x $ i))" (is "?lhs \<longleftrightarrow> ?rhs")
   680 proof -
   681   let ?S = "(UNIV :: 'n set)"
   682   { assume H: "?rhs"
   683     then have ?lhs by auto }
   684   moreover
   685   { assume H: "?lhs"
   686     then obtain f where f:"\<forall>i. P i (f i)" unfolding choice_iff by metis
   687     let ?x = "(\<chi> i. (f i)) :: 'a ^ 'n"
   688     { fix i
   689       from f have "P i (f i)" by metis
   690       then have "P i (?x $ i)" by auto
   691     }
   692     hence "\<forall>i. P i (?x$i)" by metis
   693     hence ?rhs by metis }
   694   ultimately show ?thesis by metis
   695 qed
   696 
   697 lemma vector_sub_project_orthogonal_cart: "(b::real^'n) \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *s b) = 0"
   698   unfolding inner_simps scalar_mult_eq_scaleR by auto
   699 
   700 lemma left_invertible_transpose:
   701   "(\<exists>(B). B ** transpose (A) = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). A ** B = mat 1)"
   702   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   703 
   704 lemma right_invertible_transpose:
   705   "(\<exists>(B). transpose (A) ** B = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). B ** A = mat 1)"
   706   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   707 
   708 lemma matrix_left_invertible_injective:
   709   "(\<exists>B. (B::real^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x y. A *v x = A *v y \<longrightarrow> x = y)"
   710 proof -
   711   { fix B:: "real^'m^'n" and x y assume B: "B ** A = mat 1" and xy: "A *v x = A*v y"
   712     from xy have "B*v (A *v x) = B *v (A*v y)" by simp
   713     hence "x = y"
   714       unfolding matrix_vector_mul_assoc B matrix_vector_mul_lid . }
   715   moreover
   716   { assume A: "\<forall>x y. A *v x = A *v y \<longrightarrow> x = y"
   717     hence i: "inj (op *v A)" unfolding inj_on_def by auto
   718     from linear_injective_left_inverse[OF matrix_vector_mul_linear i]
   719     obtain g where g: "linear g" "g \<circ> op *v A = id" by blast
   720     have "matrix g ** A = mat 1"
   721       unfolding matrix_eq matrix_vector_mul_lid matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   722       using g(2) by (simp add: fun_eq_iff)
   723     then have "\<exists>B. (B::real ^'m^'n) ** A = mat 1" by blast }
   724   ultimately show ?thesis by blast
   725 qed
   726 
   727 lemma matrix_left_invertible_ker:
   728   "(\<exists>B. (B::real ^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x. A *v x = 0 \<longrightarrow> x = 0)"
   729   unfolding matrix_left_invertible_injective
   730   using linear_injective_0[OF matrix_vector_mul_linear, of A]
   731   by (simp add: inj_on_def)
   732 
   733 lemma matrix_right_invertible_surjective:
   734   "(\<exists>B. (A::real^'n^'m) ** (B::real^'m^'n) = mat 1) \<longleftrightarrow> surj (\<lambda>x. A *v x)"
   735 proof -
   736   { fix B :: "real ^'m^'n"
   737     assume AB: "A ** B = mat 1"
   738     { fix x :: "real ^ 'm"
   739       have "A *v (B *v x) = x"
   740         by (simp add: matrix_vector_mul_lid matrix_vector_mul_assoc AB) }
   741     hence "surj (op *v A)" unfolding surj_def by metis }
   742   moreover
   743   { assume sf: "surj (op *v A)"
   744     from linear_surjective_right_inverse[OF matrix_vector_mul_linear sf]
   745     obtain g:: "real ^'m \<Rightarrow> real ^'n" where g: "linear g" "op *v A \<circ> g = id"
   746       by blast
   747 
   748     have "A ** (matrix g) = mat 1"
   749       unfolding matrix_eq  matrix_vector_mul_lid
   750         matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   751       using g(2) unfolding o_def fun_eq_iff id_def
   752       .
   753     hence "\<exists>B. A ** (B::real^'m^'n) = mat 1" by blast
   754   }
   755   ultimately show ?thesis unfolding surj_def by blast
   756 qed
   757 
   758 lemma matrix_left_invertible_independent_columns:
   759   fixes A :: "real^'n^'m"
   760   shows "(\<exists>(B::real ^'m^'n). B ** A = mat 1) \<longleftrightarrow>
   761       (\<forall>c. sum (\<lambda>i. c i *s column i A) (UNIV :: 'n set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   762     (is "?lhs \<longleftrightarrow> ?rhs")
   763 proof -
   764   let ?U = "UNIV :: 'n set"
   765   { assume k: "\<forall>x. A *v x = 0 \<longrightarrow> x = 0"
   766     { fix c i
   767       assume c: "sum (\<lambda>i. c i *s column i A) ?U = 0" and i: "i \<in> ?U"
   768       let ?x = "\<chi> i. c i"
   769       have th0:"A *v ?x = 0"
   770         using c
   771         unfolding matrix_mult_vsum vec_eq_iff
   772         by auto
   773       from k[rule_format, OF th0] i
   774       have "c i = 0" by (vector vec_eq_iff)}
   775     hence ?rhs by blast }
   776   moreover
   777   { assume H: ?rhs
   778     { fix x assume x: "A *v x = 0"
   779       let ?c = "\<lambda>i. ((x$i ):: real)"
   780       from H[rule_format, of ?c, unfolded matrix_mult_vsum[symmetric], OF x]
   781       have "x = 0" by vector }
   782   }
   783   ultimately show ?thesis unfolding matrix_left_invertible_ker by blast
   784 qed
   785 
   786 lemma matrix_right_invertible_independent_rows:
   787   fixes A :: "real^'n^'m"
   788   shows "(\<exists>(B::real^'m^'n). A ** B = mat 1) \<longleftrightarrow>
   789     (\<forall>c. sum (\<lambda>i. c i *s row i A) (UNIV :: 'm set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   790   unfolding left_invertible_transpose[symmetric]
   791     matrix_left_invertible_independent_columns
   792   by (simp add: column_transpose)
   793 
   794 lemma matrix_right_invertible_span_columns:
   795   "(\<exists>(B::real ^'n^'m). (A::real ^'m^'n) ** B = mat 1) \<longleftrightarrow>
   796     span (columns A) = UNIV" (is "?lhs = ?rhs")
   797 proof -
   798   let ?U = "UNIV :: 'm set"
   799   have fU: "finite ?U" by simp
   800   have lhseq: "?lhs \<longleftrightarrow> (\<forall>y. \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y)"
   801     unfolding matrix_right_invertible_surjective matrix_mult_vsum surj_def
   802     apply (subst eq_commute)
   803     apply rule
   804     done
   805   have rhseq: "?rhs \<longleftrightarrow> (\<forall>x. x \<in> span (columns A))" by blast
   806   { assume h: ?lhs
   807     { fix x:: "real ^'n"
   808       from h[unfolded lhseq, rule_format, of x] obtain y :: "real ^'m"
   809         where y: "sum (\<lambda>i. (y$i) *s column i A) ?U = x" by blast
   810       have "x \<in> span (columns A)"
   811         unfolding y[symmetric]
   812         apply (rule span_sum)
   813         unfolding scalar_mult_eq_scaleR
   814         apply (rule span_mul)
   815         apply (rule span_superset)
   816         unfolding columns_def
   817         apply blast
   818         done
   819     }
   820     then have ?rhs unfolding rhseq by blast }
   821   moreover
   822   { assume h:?rhs
   823     let ?P = "\<lambda>(y::real ^'n). \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y"
   824     { fix y
   825       have "?P y"
   826       proof (rule span_induct_alt[of ?P "columns A", folded scalar_mult_eq_scaleR])
   827         show "\<exists>x::real ^ 'm. sum (\<lambda>i. (x$i) *s column i A) ?U = 0"
   828           by (rule exI[where x=0], simp)
   829       next
   830         fix c y1 y2
   831         assume y1: "y1 \<in> columns A" and y2: "?P y2"
   832         from y1 obtain i where i: "i \<in> ?U" "y1 = column i A"
   833           unfolding columns_def by blast
   834         from y2 obtain x:: "real ^'m" where
   835           x: "sum (\<lambda>i. (x$i) *s column i A) ?U = y2" by blast
   836         let ?x = "(\<chi> j. if j = i then c + (x$i) else (x$j))::real^'m"
   837         show "?P (c*s y1 + y2)"
   838         proof (rule exI[where x= "?x"], vector, auto simp add: i x[symmetric] if_distrib distrib_left cond_application_beta cong del: if_weak_cong)
   839           fix j
   840           have th: "\<forall>xa \<in> ?U. (if xa = i then (c + (x$i)) * ((column xa A)$j)
   841               else (x$xa) * ((column xa A$j))) = (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))"
   842             using i(1) by (simp add: field_simps)
   843           have "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
   844               else (x$xa) * ((column xa A$j))) ?U = sum (\<lambda>xa. (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))) ?U"
   845             apply (rule sum.cong[OF refl])
   846             using th apply blast
   847             done
   848           also have "\<dots> = sum (\<lambda>xa. if xa = i then c * ((column i A)$j) else 0) ?U + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
   849             by (simp add: sum.distrib)
   850           also have "\<dots> = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
   851             unfolding sum.delta[OF fU]
   852             using i(1) by simp
   853           finally show "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
   854             else (x$xa) * ((column xa A$j))) ?U = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U" .
   855         qed
   856       next
   857         show "y \<in> span (columns A)"
   858           unfolding h by blast
   859       qed
   860     }
   861     then have ?lhs unfolding lhseq ..
   862   }
   863   ultimately show ?thesis by blast
   864 qed
   865 
   866 lemma matrix_left_invertible_span_rows:
   867   "(\<exists>(B::real^'m^'n). B ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> span (rows A) = UNIV"
   868   unfolding right_invertible_transpose[symmetric]
   869   unfolding columns_transpose[symmetric]
   870   unfolding matrix_right_invertible_span_columns
   871   ..
   872 
   873 text \<open>The same result in terms of square matrices.\<close>
   874 
   875 lemma matrix_left_right_inverse:
   876   fixes A A' :: "real ^'n^'n"
   877   shows "A ** A' = mat 1 \<longleftrightarrow> A' ** A = mat 1"
   878 proof -
   879   { fix A A' :: "real ^'n^'n"
   880     assume AA': "A ** A' = mat 1"
   881     have sA: "surj (op *v A)"
   882       unfolding surj_def
   883       apply clarify
   884       apply (rule_tac x="(A' *v y)" in exI)
   885       apply (simp add: matrix_vector_mul_assoc AA' matrix_vector_mul_lid)
   886       done
   887     from linear_surjective_isomorphism[OF matrix_vector_mul_linear sA]
   888     obtain f' :: "real ^'n \<Rightarrow> real ^'n"
   889       where f': "linear f'" "\<forall>x. f' (A *v x) = x" "\<forall>x. A *v f' x = x" by blast
   890     have th: "matrix f' ** A = mat 1"
   891       by (simp add: matrix_eq matrix_works[OF f'(1)]
   892           matrix_vector_mul_assoc[symmetric] matrix_vector_mul_lid f'(2)[rule_format])
   893     hence "(matrix f' ** A) ** A' = mat 1 ** A'" by simp
   894     hence "matrix f' = A'"
   895       by (simp add: matrix_mul_assoc[symmetric] AA' matrix_mul_rid matrix_mul_lid)
   896     hence "matrix f' ** A = A' ** A" by simp
   897     hence "A' ** A = mat 1" by (simp add: th)
   898   }
   899   then show ?thesis by blast
   900 qed
   901 
   902 text \<open>Considering an n-element vector as an n-by-1 or 1-by-n matrix.\<close>
   903 
   904 definition "rowvector v = (\<chi> i j. (v$j))"
   905 
   906 definition "columnvector v = (\<chi> i j. (v$i))"
   907 
   908 lemma transpose_columnvector: "transpose(columnvector v) = rowvector v"
   909   by (simp add: transpose_def rowvector_def columnvector_def vec_eq_iff)
   910 
   911 lemma transpose_rowvector: "transpose(rowvector v) = columnvector v"
   912   by (simp add: transpose_def columnvector_def rowvector_def vec_eq_iff)
   913 
   914 lemma dot_rowvector_columnvector: "columnvector (A *v v) = A ** columnvector v"
   915   by (vector columnvector_def matrix_matrix_mult_def matrix_vector_mult_def)
   916 
   917 lemma dot_matrix_product:
   918   "(x::real^'n) \<bullet> y = (((rowvector x ::real^'n^1) ** (columnvector y :: real^1^'n))$1)$1"
   919   by (vector matrix_matrix_mult_def rowvector_def columnvector_def inner_vec_def)
   920 
   921 lemma dot_matrix_vector_mul:
   922   fixes A B :: "real ^'n ^'n" and x y :: "real ^'n"
   923   shows "(A *v x) \<bullet> (B *v y) =
   924       (((rowvector x :: real^'n^1) ** ((transpose A ** B) ** (columnvector y :: real ^1^'n)))$1)$1"
   925   unfolding dot_matrix_product transpose_columnvector[symmetric]
   926     dot_rowvector_columnvector matrix_transpose_mul matrix_mul_assoc ..
   927 
   928 lemma infnorm_cart:"infnorm (x::real^'n) = Sup {\<bar>x$i\<bar> |i. i\<in>UNIV}"
   929   by (simp add: infnorm_def inner_axis Basis_vec_def) (metis (lifting) inner_axis real_inner_1_right)
   930 
   931 lemma component_le_infnorm_cart: "\<bar>x$i\<bar> \<le> infnorm (x::real^'n)"
   932   using Basis_le_infnorm[of "axis i 1" x]
   933   by (simp add: Basis_vec_def axis_eq_axis inner_axis)
   934 
   935 lemma continuous_component[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x $ i)"
   936   unfolding continuous_def by (rule tendsto_vec_nth)
   937 
   938 lemma continuous_on_component[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x $ i)"
   939   unfolding continuous_on_def by (fast intro: tendsto_vec_nth)
   940 
   941 lemma continuous_on_vec_lambda[continuous_intros]:
   942   "(\<And>i. continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<chi> i. f i x)"
   943   unfolding continuous_on_def by (auto intro: tendsto_vec_lambda)
   944 
   945 lemma closed_positive_orthant: "closed {x::real^'n. \<forall>i. 0 \<le>x$i}"
   946   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
   947 
   948 lemma bounded_component_cart: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $ i) ` s)"
   949   unfolding bounded_def
   950   apply clarify
   951   apply (rule_tac x="x $ i" in exI)
   952   apply (rule_tac x="e" in exI)
   953   apply clarify
   954   apply (rule order_trans [OF dist_vec_nth_le], simp)
   955   done
   956 
   957 lemma compact_lemma_cart:
   958   fixes f :: "nat \<Rightarrow> 'a::heine_borel ^ 'n"
   959   assumes f: "bounded (range f)"
   960   shows "\<exists>l r. strict_mono r \<and>
   961         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $ i) (l $ i) < e) sequentially)"
   962     (is "?th d")
   963 proof -
   964   have "\<forall>d' \<subseteq> d. ?th d'"
   965     by (rule compact_lemma_general[where unproj=vec_lambda])
   966       (auto intro!: f bounded_component_cart simp: vec_lambda_eta)
   967   then show "?th d" by simp
   968 qed
   969 
   970 instance vec :: (heine_borel, finite) heine_borel
   971 proof
   972   fix f :: "nat \<Rightarrow> 'a ^ 'b"
   973   assume f: "bounded (range f)"
   974   then obtain l r where r: "strict_mono r"
   975       and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $ i) (l $ i) < e) sequentially"
   976     using compact_lemma_cart [OF f] by blast
   977   let ?d = "UNIV::'b set"
   978   { fix e::real assume "e>0"
   979     hence "0 < e / (real_of_nat (card ?d))"
   980       using zero_less_card_finite divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
   981     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))) sequentially"
   982       by simp
   983     moreover
   984     { fix n
   985       assume n: "\<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))"
   986       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $ i) (l $ i))"
   987         unfolding dist_vec_def using zero_le_dist by (rule L2_set_le_sum)
   988       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
   989         by (rule sum_strict_mono) (simp_all add: n)
   990       finally have "dist (f (r n)) l < e" by simp
   991     }
   992     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
   993       by (rule eventually_mono)
   994   }
   995   hence "((f \<circ> r) \<longlongrightarrow> l) sequentially" unfolding o_def tendsto_iff by simp
   996   with r show "\<exists>l r. strict_mono r \<and> ((f \<circ> r) \<longlongrightarrow> l) sequentially" by auto
   997 qed
   998 
   999 lemma interval_cart:
  1000   fixes a :: "real^'n"
  1001   shows "box a b = {x::real^'n. \<forall>i. a$i < x$i \<and> x$i < b$i}"
  1002     and "cbox a b = {x::real^'n. \<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i}"
  1003   by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def mem_box Basis_vec_def inner_axis)
  1004 
  1005 lemma mem_interval_cart:
  1006   fixes a :: "real^'n"
  1007   shows "x \<in> box a b \<longleftrightarrow> (\<forall>i. a$i < x$i \<and> x$i < b$i)"
  1008     and "x \<in> cbox a b \<longleftrightarrow> (\<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i)"
  1009   using interval_cart[of a b] by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def)
  1010 
  1011 lemma interval_eq_empty_cart:
  1012   fixes a :: "real^'n"
  1013   shows "(box a b = {} \<longleftrightarrow> (\<exists>i. b$i \<le> a$i))" (is ?th1)
  1014     and "(cbox a b = {} \<longleftrightarrow> (\<exists>i. b$i < a$i))" (is ?th2)
  1015 proof -
  1016   { fix i x assume as:"b$i \<le> a$i" and x:"x\<in>box a b"
  1017     hence "a $ i < x $ i \<and> x $ i < b $ i" unfolding mem_interval_cart by auto
  1018     hence "a$i < b$i" by auto
  1019     hence False using as by auto }
  1020   moreover
  1021   { assume as:"\<forall>i. \<not> (b$i \<le> a$i)"
  1022     let ?x = "(1/2) *\<^sub>R (a + b)"
  1023     { fix i
  1024       have "a$i < b$i" using as[THEN spec[where x=i]] by auto
  1025       hence "a$i < ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i < b$i"
  1026         unfolding vector_smult_component and vector_add_component
  1027         by auto }
  1028     hence "box a b \<noteq> {}" using mem_interval_cart(1)[of "?x" a b] by auto }
  1029   ultimately show ?th1 by blast
  1030 
  1031   { fix i x assume as:"b$i < a$i" and x:"x\<in>cbox a b"
  1032     hence "a $ i \<le> x $ i \<and> x $ i \<le> b $ i" unfolding mem_interval_cart by auto
  1033     hence "a$i \<le> b$i" by auto
  1034     hence False using as by auto }
  1035   moreover
  1036   { assume as:"\<forall>i. \<not> (b$i < a$i)"
  1037     let ?x = "(1/2) *\<^sub>R (a + b)"
  1038     { fix i
  1039       have "a$i \<le> b$i" using as[THEN spec[where x=i]] by auto
  1040       hence "a$i \<le> ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i \<le> b$i"
  1041         unfolding vector_smult_component and vector_add_component
  1042         by auto }
  1043     hence "cbox a b \<noteq> {}" using mem_interval_cart(2)[of "?x" a b] by auto  }
  1044   ultimately show ?th2 by blast
  1045 qed
  1046 
  1047 lemma interval_ne_empty_cart:
  1048   fixes a :: "real^'n"
  1049   shows "cbox a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i \<le> b$i)"
  1050     and "box a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i < b$i)"
  1051   unfolding interval_eq_empty_cart[of a b] by (auto simp add: not_less not_le)
  1052     (* BH: Why doesn't just "auto" work here? *)
  1053 
  1054 lemma subset_interval_imp_cart:
  1055   fixes a :: "real^'n"
  1056   shows "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> cbox c d \<subseteq> cbox a b"
  1057     and "(\<forall>i. a$i < c$i \<and> d$i < b$i) \<Longrightarrow> cbox c d \<subseteq> box a b"
  1058     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> cbox a b"
  1059     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> box a b"
  1060   unfolding subset_eq[unfolded Ball_def] unfolding mem_interval_cart
  1061   by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)
  1062 
  1063 lemma interval_sing:
  1064   fixes a :: "'a::linorder^'n"
  1065   shows "{a .. a} = {a} \<and> {a<..<a} = {}"
  1066   apply (auto simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
  1067   done
  1068 
  1069 lemma subset_interval_cart:
  1070   fixes a :: "real^'n"
  1071   shows "cbox c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th1)
  1072     and "cbox c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i < c$i \<and> d$i < b$i)" (is ?th2)
  1073     and "box c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th3)
  1074     and "box c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th4)
  1075   using subset_box[of c d a b] by (simp_all add: Basis_vec_def inner_axis)
  1076 
  1077 lemma disjoint_interval_cart:
  1078   fixes a::"real^'n"
  1079   shows "cbox a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i < c$i \<or> b$i < c$i \<or> d$i < a$i))" (is ?th1)
  1080     and "cbox a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th2)
  1081     and "box a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i < c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th3)
  1082     and "box a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th4)
  1083   using disjoint_interval[of a b c d] by (simp_all add: Basis_vec_def inner_axis)
  1084 
  1085 lemma inter_interval_cart:
  1086   fixes a :: "real^'n"
  1087   shows "cbox a b \<inter> cbox c d =  {(\<chi> i. max (a$i) (c$i)) .. (\<chi> i. min (b$i) (d$i))}"
  1088   unfolding Int_interval
  1089   by (auto simp: mem_box less_eq_vec_def)
  1090     (auto simp: Basis_vec_def inner_axis)
  1091 
  1092 lemma closed_interval_left_cart:
  1093   fixes b :: "real^'n"
  1094   shows "closed {x::real^'n. \<forall>i. x$i \<le> b$i}"
  1095   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1096 
  1097 lemma closed_interval_right_cart:
  1098   fixes a::"real^'n"
  1099   shows "closed {x::real^'n. \<forall>i. a$i \<le> x$i}"
  1100   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1101 
  1102 lemma is_interval_cart:
  1103   "is_interval (s::(real^'n) set) \<longleftrightarrow>
  1104     (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i. ((a$i \<le> x$i \<and> x$i \<le> b$i) \<or> (b$i \<le> x$i \<and> x$i \<le> a$i))) \<longrightarrow> x \<in> s)"
  1105   by (simp add: is_interval_def Ball_def Basis_vec_def inner_axis imp_ex)
  1106 
  1107 lemma closed_halfspace_component_le_cart: "closed {x::real^'n. x$i \<le> a}"
  1108   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1109 
  1110 lemma closed_halfspace_component_ge_cart: "closed {x::real^'n. x$i \<ge> a}"
  1111   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1112 
  1113 lemma open_halfspace_component_lt_cart: "open {x::real^'n. x$i < a}"
  1114   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1115 
  1116 lemma open_halfspace_component_gt_cart: "open {x::real^'n. x$i  > a}"
  1117   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1118 
  1119 lemma Lim_component_le_cart:
  1120   fixes f :: "'a \<Rightarrow> real^'n"
  1121   assumes "(f \<longlongrightarrow> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f x $i \<le> b) net"
  1122   shows "l$i \<le> b"
  1123   by (rule tendsto_le[OF assms(2) tendsto_const tendsto_vec_nth, OF assms(1, 3)])
  1124 
  1125 lemma Lim_component_ge_cart:
  1126   fixes f :: "'a \<Rightarrow> real^'n"
  1127   assumes "(f \<longlongrightarrow> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$i) net"
  1128   shows "b \<le> l$i"
  1129   by (rule tendsto_le[OF assms(2) tendsto_vec_nth tendsto_const, OF assms(1, 3)])
  1130 
  1131 lemma Lim_component_eq_cart:
  1132   fixes f :: "'a \<Rightarrow> real^'n"
  1133   assumes net: "(f \<longlongrightarrow> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$i = b) net"
  1134   shows "l$i = b"
  1135   using ev[unfolded order_eq_iff eventually_conj_iff] and
  1136     Lim_component_ge_cart[OF net, of b i] and
  1137     Lim_component_le_cart[OF net, of i b] by auto
  1138 
  1139 lemma connected_ivt_component_cart:
  1140   fixes x :: "real^'n"
  1141   shows "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$k \<le> a \<Longrightarrow> a \<le> y$k \<Longrightarrow> (\<exists>z\<in>s.  z$k = a)"
  1142   using connected_ivt_hyperplane[of s x y "axis k 1" a]
  1143   by (auto simp add: inner_axis inner_commute)
  1144 
  1145 lemma subspace_substandard_cart: "subspace {x::real^_. (\<forall>i. P i \<longrightarrow> x$i = 0)}"
  1146   unfolding subspace_def by auto
  1147 
  1148 lemma closed_substandard_cart:
  1149   "closed {x::'a::real_normed_vector ^ 'n. \<forall>i. P i \<longrightarrow> x$i = 0}"
  1150 proof -
  1151   { fix i::'n
  1152     have "closed {x::'a ^ 'n. P i \<longrightarrow> x$i = 0}"
  1153       by (cases "P i") (simp_all add: closed_Collect_eq continuous_on_const continuous_on_id continuous_on_component) }
  1154   thus ?thesis
  1155     unfolding Collect_all_eq by (simp add: closed_INT)
  1156 qed
  1157 
  1158 lemma dim_substandard_cart: "dim {x::real^'n. \<forall>i. i \<notin> d \<longrightarrow> x$i = 0} = card d"
  1159   (is "dim ?A = _")
  1160 proof -
  1161   let ?a = "\<lambda>x. axis x 1 :: real^'n"
  1162   have *: "{x. \<forall>i\<in>Basis. i \<notin> ?a ` d \<longrightarrow> x \<bullet> i = 0} = ?A"
  1163     by (auto simp: image_iff Basis_vec_def axis_eq_axis inner_axis)
  1164   have "?a ` d \<subseteq> Basis"
  1165     by (auto simp: Basis_vec_def)
  1166   thus ?thesis
  1167     using dim_substandard[of "?a ` d"] card_image[of ?a d]
  1168     by (auto simp: axis_eq_axis inj_on_def *)
  1169 qed
  1170 
  1171 lemma affinity_inverses:
  1172   assumes m0: "m \<noteq> (0::'a::field)"
  1173   shows "(\<lambda>x. m *s x + c) \<circ> (\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) = id"
  1174   "(\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) \<circ> (\<lambda>x. m *s x + c) = id"
  1175   using m0
  1176   apply (auto simp add: fun_eq_iff vector_add_ldistrib diff_conv_add_uminus simp del: add_uminus_conv_diff)
  1177   apply (simp_all add: vector_smult_lneg[symmetric] vector_smult_assoc vector_sneg_minus1 [symmetric])
  1178   done
  1179 
  1180 lemma vector_affinity_eq:
  1181   assumes m0: "(m::'a::field) \<noteq> 0"
  1182   shows "m *s x + c = y \<longleftrightarrow> x = inverse m *s y + -(inverse m *s c)"
  1183 proof
  1184   assume h: "m *s x + c = y"
  1185   hence "m *s x = y - c" by (simp add: field_simps)
  1186   hence "inverse m *s (m *s x) = inverse m *s (y - c)" by simp
  1187   then show "x = inverse m *s y + - (inverse m *s c)"
  1188     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1189 next
  1190   assume h: "x = inverse m *s y + - (inverse m *s c)"
  1191   show "m *s x + c = y" unfolding h
  1192     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1193 qed
  1194 
  1195 lemma vector_eq_affinity:
  1196     "(m::'a::field) \<noteq> 0 ==> (y = m *s x + c \<longleftrightarrow> inverse(m) *s y + -(inverse(m) *s c) = x)"
  1197   using vector_affinity_eq[where m=m and x=x and y=y and c=c]
  1198   by metis
  1199 
  1200 lemma vector_cart:
  1201   fixes f :: "real^'n \<Rightarrow> real"
  1202   shows "(\<chi> i. f (axis i 1)) = (\<Sum>i\<in>Basis. f i *\<^sub>R i)"
  1203   unfolding euclidean_eq_iff[where 'a="real^'n"]
  1204   by simp (simp add: Basis_vec_def inner_axis)
  1205 
  1206 lemma const_vector_cart:"((\<chi> i. d)::real^'n) = (\<Sum>i\<in>Basis. d *\<^sub>R i)"
  1207   by (rule vector_cart)
  1208 
  1209 subsection "Convex Euclidean Space"
  1210 
  1211 lemma Cart_1:"(1::real^'n) = \<Sum>Basis"
  1212   using const_vector_cart[of 1] by (simp add: one_vec_def)
  1213 
  1214 declare vector_add_ldistrib[simp] vector_ssub_ldistrib[simp] vector_smult_assoc[simp] vector_smult_rneg[simp]
  1215 declare vector_sadd_rdistrib[simp] vector_sub_rdistrib[simp]
  1216 
  1217 lemmas vector_component_simps = vector_minus_component vector_smult_component vector_add_component less_eq_vec_def vec_lambda_beta vector_uminus_component
  1218 
  1219 lemma convex_box_cart:
  1220   assumes "\<And>i. convex {x. P i x}"
  1221   shows "convex {x. \<forall>i. P i (x$i)}"
  1222   using assms unfolding convex_def by auto
  1223 
  1224 lemma convex_positive_orthant_cart: "convex {x::real^'n. (\<forall>i. 0 \<le> x$i)}"
  1225   by (rule convex_box_cart) (simp add: atLeast_def[symmetric])
  1226 
  1227 lemma unit_interval_convex_hull_cart:
  1228   "cbox (0::real^'n) 1 = convex hull {x. \<forall>i. (x$i = 0) \<or> (x$i = 1)}"
  1229   unfolding Cart_1 unit_interval_convex_hull[where 'a="real^'n"] box_real[symmetric]
  1230   by (rule arg_cong[where f="\<lambda>x. convex hull x"]) (simp add: Basis_vec_def inner_axis)
  1231 
  1232 lemma cube_convex_hull_cart:
  1233   assumes "0 < d"
  1234   obtains s::"(real^'n) set"
  1235     where "finite s" "cbox (x - (\<chi> i. d)) (x + (\<chi> i. d)) = convex hull s"
  1236 proof -
  1237   from assms obtain s where "finite s"
  1238     and "cbox (x - sum (op *\<^sub>R d) Basis) (x + sum (op *\<^sub>R d) Basis) = convex hull s"
  1239     by (rule cube_convex_hull)
  1240   with that[of s] show thesis
  1241     by (simp add: const_vector_cart)
  1242 qed
  1243 
  1244 
  1245 subsection "Derivative"
  1246 
  1247 definition "jacobian f net = matrix(frechet_derivative f net)"
  1248 
  1249 lemma jacobian_works:
  1250   "(f::(real^'a) \<Rightarrow> (real^'b)) differentiable net \<longleftrightarrow>
  1251     (f has_derivative (\<lambda>h. (jacobian f net) *v h)) net"
  1252   apply rule
  1253   unfolding jacobian_def
  1254   apply (simp only: matrix_works[OF linear_frechet_derivative]) defer
  1255   apply (rule differentiableI)
  1256   apply assumption
  1257   unfolding frechet_derivative_works
  1258   apply assumption
  1259   done
  1260 
  1261 
  1262 subsection \<open>Component of the differential must be zero if it exists at a local
  1263   maximum or minimum for that corresponding component.\<close>
  1264 
  1265 lemma differential_zero_maxmin_cart:
  1266   fixes f::"real^'a \<Rightarrow> real^'b"
  1267   assumes "0 < e" "((\<forall>y \<in> ball x e. (f y)$k \<le> (f x)$k) \<or> (\<forall>y\<in>ball x e. (f x)$k \<le> (f y)$k))"
  1268     "f differentiable (at x)"
  1269   shows "jacobian f (at x) $ k = 0"
  1270   using differential_zero_maxmin_component[of "axis k 1" e x f] assms
  1271     vector_cart[of "\<lambda>j. frechet_derivative f (at x) j $ k"]
  1272   by (simp add: Basis_vec_def axis_eq_axis inner_axis jacobian_def matrix_def)
  1273 
  1274 subsection \<open>Lemmas for working on @{typ "real^1"}\<close>
  1275 
  1276 lemma forall_1[simp]: "(\<forall>i::1. P i) \<longleftrightarrow> P 1"
  1277   by (metis (full_types) num1_eq_iff)
  1278 
  1279 lemma ex_1[simp]: "(\<exists>x::1. P x) \<longleftrightarrow> P 1"
  1280   by auto (metis (full_types) num1_eq_iff)
  1281 
  1282 lemma exhaust_2:
  1283   fixes x :: 2
  1284   shows "x = 1 \<or> x = 2"
  1285 proof (induct x)
  1286   case (of_int z)
  1287   then have "0 <= z" and "z < 2" by simp_all
  1288   then have "z = 0 | z = 1" by arith
  1289   then show ?case by auto
  1290 qed
  1291 
  1292 lemma forall_2: "(\<forall>i::2. P i) \<longleftrightarrow> P 1 \<and> P 2"
  1293   by (metis exhaust_2)
  1294 
  1295 lemma exhaust_3:
  1296   fixes x :: 3
  1297   shows "x = 1 \<or> x = 2 \<or> x = 3"
  1298 proof (induct x)
  1299   case (of_int z)
  1300   then have "0 <= z" and "z < 3" by simp_all
  1301   then have "z = 0 \<or> z = 1 \<or> z = 2" by arith
  1302   then show ?case by auto
  1303 qed
  1304 
  1305 lemma forall_3: "(\<forall>i::3. P i) \<longleftrightarrow> P 1 \<and> P 2 \<and> P 3"
  1306   by (metis exhaust_3)
  1307 
  1308 lemma UNIV_1 [simp]: "UNIV = {1::1}"
  1309   by (auto simp add: num1_eq_iff)
  1310 
  1311 lemma UNIV_2: "UNIV = {1::2, 2::2}"
  1312   using exhaust_2 by auto
  1313 
  1314 lemma UNIV_3: "UNIV = {1::3, 2::3, 3::3}"
  1315   using exhaust_3 by auto
  1316 
  1317 lemma sum_1: "sum f (UNIV::1 set) = f 1"
  1318   unfolding UNIV_1 by simp
  1319 
  1320 lemma sum_2: "sum f (UNIV::2 set) = f 1 + f 2"
  1321   unfolding UNIV_2 by simp
  1322 
  1323 lemma sum_3: "sum f (UNIV::3 set) = f 1 + f 2 + f 3"
  1324   unfolding UNIV_3 by (simp add: ac_simps)
  1325 
  1326 instantiation num1 :: cart_one
  1327 begin
  1328 
  1329 instance
  1330 proof
  1331   show "CARD(1) = Suc 0" by auto
  1332 qed
  1333 
  1334 end
  1335 
  1336 subsection\<open>The collapse of the general concepts to dimension one.\<close>
  1337 
  1338 lemma vector_one: "(x::'a ^1) = (\<chi> i. (x$1))"
  1339   by (simp add: vec_eq_iff)
  1340 
  1341 lemma forall_one: "(\<forall>(x::'a ^1). P x) \<longleftrightarrow> (\<forall>x. P(\<chi> i. x))"
  1342   apply auto
  1343   apply (erule_tac x= "x$1" in allE)
  1344   apply (simp only: vector_one[symmetric])
  1345   done
  1346 
  1347 lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
  1348   by (simp add: norm_vec_def)
  1349 
  1350 lemma norm_real: "norm(x::real ^ 1) = \<bar>x$1\<bar>"
  1351   by (simp add: norm_vector_1)
  1352 
  1353 lemma dist_real: "dist(x::real ^ 1) y = \<bar>(x$1) - (y$1)\<bar>"
  1354   by (auto simp add: norm_real dist_norm)
  1355 
  1356 
  1357 subsection\<open>Explicit vector construction from lists.\<close>
  1358 
  1359 definition "vector l = (\<chi> i. foldr (\<lambda>x f n. fun_upd (f (n+1)) n x) l (\<lambda>n x. 0) 1 i)"
  1360 
  1361 lemma vector_1: "(vector[x]) $1 = x"
  1362   unfolding vector_def by simp
  1363 
  1364 lemma vector_2:
  1365  "(vector[x,y]) $1 = x"
  1366  "(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
  1367   unfolding vector_def by simp_all
  1368 
  1369 lemma vector_3:
  1370  "(vector [x,y,z] ::('a::zero)^3)$1 = x"
  1371  "(vector [x,y,z] ::('a::zero)^3)$2 = y"
  1372  "(vector [x,y,z] ::('a::zero)^3)$3 = z"
  1373   unfolding vector_def by simp_all
  1374 
  1375 lemma forall_vector_1: "(\<forall>v::'a::zero^1. P v) \<longleftrightarrow> (\<forall>x. P(vector[x]))"
  1376   apply auto
  1377   apply (erule_tac x="v$1" in allE)
  1378   apply (subgoal_tac "vector [v$1] = v")
  1379   apply simp
  1380   apply (vector vector_def)
  1381   apply simp
  1382   done
  1383 
  1384 lemma forall_vector_2: "(\<forall>v::'a::zero^2. P v) \<longleftrightarrow> (\<forall>x y. P(vector[x, y]))"
  1385   apply auto
  1386   apply (erule_tac x="v$1" in allE)
  1387   apply (erule_tac x="v$2" in allE)
  1388   apply (subgoal_tac "vector [v$1, v$2] = v")
  1389   apply simp
  1390   apply (vector vector_def)
  1391   apply (simp add: forall_2)
  1392   done
  1393 
  1394 lemma forall_vector_3: "(\<forall>v::'a::zero^3. P v) \<longleftrightarrow> (\<forall>x y z. P(vector[x, y, z]))"
  1395   apply auto
  1396   apply (erule_tac x="v$1" in allE)
  1397   apply (erule_tac x="v$2" in allE)
  1398   apply (erule_tac x="v$3" in allE)
  1399   apply (subgoal_tac "vector [v$1, v$2, v$3] = v")
  1400   apply simp
  1401   apply (vector vector_def)
  1402   apply (simp add: forall_3)
  1403   done
  1404 
  1405 lemma bounded_linear_component_cart[intro]: "bounded_linear (\<lambda>x::real^'n. x $ k)"
  1406   apply (rule bounded_linearI[where K=1])
  1407   using component_le_norm_cart[of _ k] unfolding real_norm_def by auto
  1408 
  1409 lemma interval_split_cart:
  1410   "{a..b::real^'n} \<inter> {x. x$k \<le> c} = {a .. (\<chi> i. if i = k then min (b$k) c else b$i)}"
  1411   "cbox a b \<inter> {x. x$k \<ge> c} = {(\<chi> i. if i = k then max (a$k) c else a$i) .. b}"
  1412   apply (rule_tac[!] set_eqI)
  1413   unfolding Int_iff mem_interval_cart mem_Collect_eq interval_cbox_cart
  1414   unfolding vec_lambda_beta
  1415   by auto
  1416 
  1417 end