src/HOL/Analysis/Finite_Cartesian_Product.thy
author nipkow
Thu Dec 07 15:48:50 2017 +0100 (10 months ago)
changeset 67155 9e5b05d54f9d
parent 66453 cc19f7ca2ed6
child 67399 eab6ce8368fa
permissions -rw-r--r--
canonical name
     1 (*  Title:      HOL/Analysis/Finite_Cartesian_Product.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 section \<open>Definition of finite Cartesian product types.\<close>
     6 
     7 theory Finite_Cartesian_Product
     8 imports
     9   Euclidean_Space
    10   L2_Norm
    11   "HOL-Library.Numeral_Type"
    12   "HOL-Library.Countable_Set"
    13   "HOL-Library.FuncSet"
    14 begin
    15 
    16 subsection \<open>Finite Cartesian products, with indexing and lambdas.\<close>
    17 
    18 typedef ('a, 'b) vec = "UNIV :: (('b::finite) \<Rightarrow> 'a) set"
    19   morphisms vec_nth vec_lambda ..
    20 
    21 notation
    22   vec_nth (infixl "$" 90) and
    23   vec_lambda (binder "\<chi>" 10)
    24 
    25 (*
    26   Translate "'b ^ 'n" into "'b ^ ('n :: finite)". When 'n has already more than
    27   the finite type class write "vec 'b 'n"
    28 *)
    29 
    30 syntax "_finite_vec" :: "type \<Rightarrow> type \<Rightarrow> type" ("(_ ^/ _)" [15, 16] 15)
    31 
    32 parse_translation \<open>
    33   let
    34     fun vec t u = Syntax.const @{type_syntax vec} $ t $ u;
    35     fun finite_vec_tr [t, u] =
    36       (case Term_Position.strip_positions u of
    37         v as Free (x, _) =>
    38           if Lexicon.is_tid x then
    39             vec t (Syntax.const @{syntax_const "_ofsort"} $ v $
    40               Syntax.const @{class_syntax finite})
    41           else vec t u
    42       | _ => vec t u)
    43   in
    44     [(@{syntax_const "_finite_vec"}, K finite_vec_tr)]
    45   end
    46 \<close>
    47 
    48 lemma vec_eq_iff: "(x = y) \<longleftrightarrow> (\<forall>i. x$i = y$i)"
    49   by (simp add: vec_nth_inject [symmetric] fun_eq_iff)
    50 
    51 lemma vec_lambda_beta [simp]: "vec_lambda g $ i = g i"
    52   by (simp add: vec_lambda_inverse)
    53 
    54 lemma vec_lambda_unique: "(\<forall>i. f$i = g i) \<longleftrightarrow> vec_lambda g = f"
    55   by (auto simp add: vec_eq_iff)
    56 
    57 lemma vec_lambda_eta: "(\<chi> i. (g$i)) = g"
    58   by (simp add: vec_eq_iff)
    59 
    60 subsection \<open>Cardinality of vectors\<close>
    61 
    62 instance vec :: (finite, finite) finite
    63 proof
    64   show "finite (UNIV :: ('a, 'b) vec set)"
    65   proof (subst bij_betw_finite)
    66     show "bij_betw vec_nth UNIV (Pi (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))"
    67       by (intro bij_betwI[of _ _ _ vec_lambda]) (auto simp: vec_eq_iff)
    68     have "finite (PiE (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))"
    69       by (intro finite_PiE) auto
    70     also have "(PiE (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set)) = Pi UNIV (\<lambda>_. UNIV)"
    71       by auto
    72     finally show "finite \<dots>" .
    73   qed
    74 qed
    75 
    76 lemma countable_PiE:
    77   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> countable (F i)) \<Longrightarrow> countable (Pi\<^sub>E I F)"
    78   by (induct I arbitrary: F rule: finite_induct) (auto simp: PiE_insert_eq)
    79 
    80 instance vec :: (countable, finite) countable
    81 proof
    82   have "countable (UNIV :: ('a, 'b) vec set)"
    83   proof (rule countableI_bij2)
    84     show "bij_betw vec_nth UNIV (Pi (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))"
    85       by (intro bij_betwI[of _ _ _ vec_lambda]) (auto simp: vec_eq_iff)
    86     have "countable (PiE (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))"
    87       by (intro countable_PiE) auto
    88     also have "(PiE (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set)) = Pi UNIV (\<lambda>_. UNIV)"
    89       by auto
    90     finally show "countable \<dots>" .
    91   qed
    92   thus "\<exists>t::('a, 'b) vec \<Rightarrow> nat. inj t"
    93     by (auto elim!: countableE)
    94 qed
    95 
    96 lemma infinite_UNIV_vec:
    97   assumes "infinite (UNIV :: 'a set)"
    98   shows   "infinite (UNIV :: ('a, 'b :: finite) vec set)"
    99 proof (subst bij_betw_finite)
   100   show "bij_betw vec_nth UNIV (Pi (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))"
   101     by (intro bij_betwI[of _ _ _ vec_lambda]) (auto simp: vec_eq_iff)
   102   have "infinite (PiE (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))" (is "infinite ?A")
   103   proof
   104     assume "finite ?A"
   105     hence "finite ((\<lambda>f. f undefined) ` ?A)"
   106       by (rule finite_imageI)
   107     also have "(\<lambda>f. f undefined) ` ?A = UNIV"
   108       by auto
   109     finally show False 
   110       using \<open>infinite (UNIV :: 'a set)\<close> by contradiction
   111   qed
   112   also have "?A = Pi UNIV (\<lambda>_. UNIV)" 
   113     by auto
   114   finally show "infinite (Pi (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))" .
   115 qed
   116 
   117 lemma CARD_vec [simp]:
   118   "CARD(('a,'b::finite) vec) = CARD('a) ^ CARD('b)"
   119 proof (cases "finite (UNIV :: 'a set)")
   120   case True
   121   show ?thesis
   122   proof (subst bij_betw_same_card)
   123     show "bij_betw vec_nth UNIV (Pi (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))"
   124       by (intro bij_betwI[of _ _ _ vec_lambda]) (auto simp: vec_eq_iff)
   125     have "CARD('a) ^ CARD('b) = card (PiE (UNIV :: 'b set) (\<lambda>_. UNIV :: 'a set))"
   126       (is "_ = card ?A")
   127       by (subst card_PiE) (auto simp: prod_constant)
   128     
   129     also have "?A = Pi UNIV (\<lambda>_. UNIV)" 
   130       by auto
   131     finally show "card \<dots> = CARD('a) ^ CARD('b)" ..
   132   qed
   133 qed (simp_all add: infinite_UNIV_vec)
   134 
   135 subsection \<open>Group operations and class instances\<close>
   136 
   137 instantiation vec :: (zero, finite) zero
   138 begin
   139   definition "0 \<equiv> (\<chi> i. 0)"
   140   instance ..
   141 end
   142 
   143 instantiation vec :: (plus, finite) plus
   144 begin
   145   definition "op + \<equiv> (\<lambda> x y. (\<chi> i. x$i + y$i))"
   146   instance ..
   147 end
   148 
   149 instantiation vec :: (minus, finite) minus
   150 begin
   151   definition "op - \<equiv> (\<lambda> x y. (\<chi> i. x$i - y$i))"
   152   instance ..
   153 end
   154 
   155 instantiation vec :: (uminus, finite) uminus
   156 begin
   157   definition "uminus \<equiv> (\<lambda> x. (\<chi> i. - (x$i)))"
   158   instance ..
   159 end
   160 
   161 lemma zero_index [simp]: "0 $ i = 0"
   162   unfolding zero_vec_def by simp
   163 
   164 lemma vector_add_component [simp]: "(x + y)$i = x$i + y$i"
   165   unfolding plus_vec_def by simp
   166 
   167 lemma vector_minus_component [simp]: "(x - y)$i = x$i - y$i"
   168   unfolding minus_vec_def by simp
   169 
   170 lemma vector_uminus_component [simp]: "(- x)$i = - (x$i)"
   171   unfolding uminus_vec_def by simp
   172 
   173 instance vec :: (semigroup_add, finite) semigroup_add
   174   by standard (simp add: vec_eq_iff add.assoc)
   175 
   176 instance vec :: (ab_semigroup_add, finite) ab_semigroup_add
   177   by standard (simp add: vec_eq_iff add.commute)
   178 
   179 instance vec :: (monoid_add, finite) monoid_add
   180   by standard (simp_all add: vec_eq_iff)
   181 
   182 instance vec :: (comm_monoid_add, finite) comm_monoid_add
   183   by standard (simp add: vec_eq_iff)
   184 
   185 instance vec :: (cancel_semigroup_add, finite) cancel_semigroup_add
   186   by standard (simp_all add: vec_eq_iff)
   187 
   188 instance vec :: (cancel_ab_semigroup_add, finite) cancel_ab_semigroup_add
   189   by standard (simp_all add: vec_eq_iff diff_diff_eq)
   190 
   191 instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
   192 
   193 instance vec :: (group_add, finite) group_add
   194   by standard (simp_all add: vec_eq_iff)
   195 
   196 instance vec :: (ab_group_add, finite) ab_group_add
   197   by standard (simp_all add: vec_eq_iff)
   198 
   199 
   200 subsection \<open>Real vector space\<close>
   201 
   202 instantiation vec :: (real_vector, finite) real_vector
   203 begin
   204 
   205 definition "scaleR \<equiv> (\<lambda> r x. (\<chi> i. scaleR r (x$i)))"
   206 
   207 lemma vector_scaleR_component [simp]: "(scaleR r x)$i = scaleR r (x$i)"
   208   unfolding scaleR_vec_def by simp
   209 
   210 instance
   211   by standard (simp_all add: vec_eq_iff scaleR_left_distrib scaleR_right_distrib)
   212 
   213 end
   214 
   215 
   216 subsection \<open>Topological space\<close>
   217 
   218 instantiation vec :: (topological_space, finite) topological_space
   219 begin
   220 
   221 definition [code del]:
   222   "open (S :: ('a ^ 'b) set) \<longleftrightarrow>
   223     (\<forall>x\<in>S. \<exists>A. (\<forall>i. open (A i) \<and> x$i \<in> A i) \<and>
   224       (\<forall>y. (\<forall>i. y$i \<in> A i) \<longrightarrow> y \<in> S))"
   225 
   226 instance proof
   227   show "open (UNIV :: ('a ^ 'b) set)"
   228     unfolding open_vec_def by auto
   229 next
   230   fix S T :: "('a ^ 'b) set"
   231   assume "open S" "open T" thus "open (S \<inter> T)"
   232     unfolding open_vec_def
   233     apply clarify
   234     apply (drule (1) bspec)+
   235     apply (clarify, rename_tac Sa Ta)
   236     apply (rule_tac x="\<lambda>i. Sa i \<inter> Ta i" in exI)
   237     apply (simp add: open_Int)
   238     done
   239 next
   240   fix K :: "('a ^ 'b) set set"
   241   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   242     unfolding open_vec_def
   243     apply clarify
   244     apply (drule (1) bspec)
   245     apply (drule (1) bspec)
   246     apply clarify
   247     apply (rule_tac x=A in exI)
   248     apply fast
   249     done
   250 qed
   251 
   252 end
   253 
   254 lemma open_vector_box: "\<forall>i. open (S i) \<Longrightarrow> open {x. \<forall>i. x $ i \<in> S i}"
   255   unfolding open_vec_def by auto
   256 
   257 lemma open_vimage_vec_nth: "open S \<Longrightarrow> open ((\<lambda>x. x $ i) -` S)"
   258   unfolding open_vec_def
   259   apply clarify
   260   apply (rule_tac x="\<lambda>k. if k = i then S else UNIV" in exI, simp)
   261   done
   262 
   263 lemma closed_vimage_vec_nth: "closed S \<Longrightarrow> closed ((\<lambda>x. x $ i) -` S)"
   264   unfolding closed_open vimage_Compl [symmetric]
   265   by (rule open_vimage_vec_nth)
   266 
   267 lemma closed_vector_box: "\<forall>i. closed (S i) \<Longrightarrow> closed {x. \<forall>i. x $ i \<in> S i}"
   268 proof -
   269   have "{x. \<forall>i. x $ i \<in> S i} = (\<Inter>i. (\<lambda>x. x $ i) -` S i)" by auto
   270   thus "\<forall>i. closed (S i) \<Longrightarrow> closed {x. \<forall>i. x $ i \<in> S i}"
   271     by (simp add: closed_INT closed_vimage_vec_nth)
   272 qed
   273 
   274 lemma tendsto_vec_nth [tendsto_intros]:
   275   assumes "((\<lambda>x. f x) \<longlongrightarrow> a) net"
   276   shows "((\<lambda>x. f x $ i) \<longlongrightarrow> a $ i) net"
   277 proof (rule topological_tendstoI)
   278   fix S assume "open S" "a $ i \<in> S"
   279   then have "open ((\<lambda>y. y $ i) -` S)" "a \<in> ((\<lambda>y. y $ i) -` S)"
   280     by (simp_all add: open_vimage_vec_nth)
   281   with assms have "eventually (\<lambda>x. f x \<in> (\<lambda>y. y $ i) -` S) net"
   282     by (rule topological_tendstoD)
   283   then show "eventually (\<lambda>x. f x $ i \<in> S) net"
   284     by simp
   285 qed
   286 
   287 lemma isCont_vec_nth [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x $ i) a"
   288   unfolding isCont_def by (rule tendsto_vec_nth)
   289 
   290 lemma vec_tendstoI:
   291   assumes "\<And>i. ((\<lambda>x. f x $ i) \<longlongrightarrow> a $ i) net"
   292   shows "((\<lambda>x. f x) \<longlongrightarrow> a) net"
   293 proof (rule topological_tendstoI)
   294   fix S assume "open S" and "a \<in> S"
   295   then obtain A where A: "\<And>i. open (A i)" "\<And>i. a $ i \<in> A i"
   296     and S: "\<And>y. \<forall>i. y $ i \<in> A i \<Longrightarrow> y \<in> S"
   297     unfolding open_vec_def by metis
   298   have "\<And>i. eventually (\<lambda>x. f x $ i \<in> A i) net"
   299     using assms A by (rule topological_tendstoD)
   300   hence "eventually (\<lambda>x. \<forall>i. f x $ i \<in> A i) net"
   301     by (rule eventually_all_finite)
   302   thus "eventually (\<lambda>x. f x \<in> S) net"
   303     by (rule eventually_mono, simp add: S)
   304 qed
   305 
   306 lemma tendsto_vec_lambda [tendsto_intros]:
   307   assumes "\<And>i. ((\<lambda>x. f x i) \<longlongrightarrow> a i) net"
   308   shows "((\<lambda>x. \<chi> i. f x i) \<longlongrightarrow> (\<chi> i. a i)) net"
   309   using assms by (simp add: vec_tendstoI)
   310 
   311 lemma open_image_vec_nth: assumes "open S" shows "open ((\<lambda>x. x $ i) ` S)"
   312 proof (rule openI)
   313   fix a assume "a \<in> (\<lambda>x. x $ i) ` S"
   314   then obtain z where "a = z $ i" and "z \<in> S" ..
   315   then obtain A where A: "\<forall>i. open (A i) \<and> z $ i \<in> A i"
   316     and S: "\<forall>y. (\<forall>i. y $ i \<in> A i) \<longrightarrow> y \<in> S"
   317     using \<open>open S\<close> unfolding open_vec_def by auto
   318   hence "A i \<subseteq> (\<lambda>x. x $ i) ` S"
   319     by (clarsimp, rule_tac x="\<chi> j. if j = i then x else z $ j" in image_eqI,
   320       simp_all)
   321   hence "open (A i) \<and> a \<in> A i \<and> A i \<subseteq> (\<lambda>x. x $ i) ` S"
   322     using A \<open>a = z $ i\<close> by simp
   323   then show "\<exists>T. open T \<and> a \<in> T \<and> T \<subseteq> (\<lambda>x. x $ i) ` S" by - (rule exI)
   324 qed
   325 
   326 instance vec :: (perfect_space, finite) perfect_space
   327 proof
   328   fix x :: "'a ^ 'b" show "\<not> open {x}"
   329   proof
   330     assume "open {x}"
   331     hence "\<forall>i. open ((\<lambda>x. x $ i) ` {x})" by (fast intro: open_image_vec_nth)
   332     hence "\<forall>i. open {x $ i}" by simp
   333     thus "False" by (simp add: not_open_singleton)
   334   qed
   335 qed
   336 
   337 
   338 subsection \<open>Metric space\<close>
   339 (* TODO: Product of uniform spaces and compatibility with metric_spaces! *)
   340 
   341 instantiation vec :: (metric_space, finite) dist
   342 begin
   343 
   344 definition
   345   "dist x y = L2_set (\<lambda>i. dist (x$i) (y$i)) UNIV"
   346 
   347 instance ..
   348 end
   349 
   350 instantiation vec :: (metric_space, finite) uniformity_dist
   351 begin
   352 
   353 definition [code del]:
   354   "(uniformity :: (('a, 'b) vec \<times> ('a, 'b) vec) filter) =
   355     (INF e:{0 <..}. principal {(x, y). dist x y < e})"
   356 
   357 instance
   358   by standard (rule uniformity_vec_def)
   359 end
   360 
   361 declare uniformity_Abort[where 'a="'a :: metric_space ^ 'b :: finite", code]
   362 
   363 instantiation vec :: (metric_space, finite) metric_space
   364 begin
   365 
   366 lemma dist_vec_nth_le: "dist (x $ i) (y $ i) \<le> dist x y"
   367   unfolding dist_vec_def by (rule member_le_L2_set) simp_all
   368 
   369 instance proof
   370   fix x y :: "'a ^ 'b"
   371   show "dist x y = 0 \<longleftrightarrow> x = y"
   372     unfolding dist_vec_def
   373     by (simp add: L2_set_eq_0_iff vec_eq_iff)
   374 next
   375   fix x y z :: "'a ^ 'b"
   376   show "dist x y \<le> dist x z + dist y z"
   377     unfolding dist_vec_def
   378     apply (rule order_trans [OF _ L2_set_triangle_ineq])
   379     apply (simp add: L2_set_mono dist_triangle2)
   380     done
   381 next
   382   fix S :: "('a ^ 'b) set"
   383   have *: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   384   proof
   385     assume "open S" show "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   386     proof
   387       fix x assume "x \<in> S"
   388       obtain A where A: "\<forall>i. open (A i)" "\<forall>i. x $ i \<in> A i"
   389         and S: "\<forall>y. (\<forall>i. y $ i \<in> A i) \<longrightarrow> y \<in> S"
   390         using \<open>open S\<close> and \<open>x \<in> S\<close> unfolding open_vec_def by metis
   391       have "\<forall>i\<in>UNIV. \<exists>r>0. \<forall>y. dist y (x $ i) < r \<longrightarrow> y \<in> A i"
   392         using A unfolding open_dist by simp
   393       hence "\<exists>r. \<forall>i\<in>UNIV. 0 < r i \<and> (\<forall>y. dist y (x $ i) < r i \<longrightarrow> y \<in> A i)"
   394         by (rule finite_set_choice [OF finite])
   395       then obtain r where r1: "\<forall>i. 0 < r i"
   396         and r2: "\<forall>i y. dist y (x $ i) < r i \<longrightarrow> y \<in> A i" by fast
   397       have "0 < Min (range r) \<and> (\<forall>y. dist y x < Min (range r) \<longrightarrow> y \<in> S)"
   398         by (simp add: r1 r2 S le_less_trans [OF dist_vec_nth_le])
   399       thus "\<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" ..
   400     qed
   401   next
   402     assume *: "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" show "open S"
   403     proof (unfold open_vec_def, rule)
   404       fix x assume "x \<in> S"
   405       then obtain e where "0 < e" and S: "\<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   406         using * by fast
   407       define r where [abs_def]: "r i = e / sqrt (of_nat CARD('b))" for i :: 'b
   408       from \<open>0 < e\<close> have r: "\<forall>i. 0 < r i"
   409         unfolding r_def by simp_all
   410       from \<open>0 < e\<close> have e: "e = L2_set r UNIV"
   411         unfolding r_def by (simp add: L2_set_constant)
   412       define A where "A i = {y. dist (x $ i) y < r i}" for i
   413       have "\<forall>i. open (A i) \<and> x $ i \<in> A i"
   414         unfolding A_def by (simp add: open_ball r)
   415       moreover have "\<forall>y. (\<forall>i. y $ i \<in> A i) \<longrightarrow> y \<in> S"
   416         by (simp add: A_def S dist_vec_def e L2_set_strict_mono dist_commute)
   417       ultimately show "\<exists>A. (\<forall>i. open (A i) \<and> x $ i \<in> A i) \<and>
   418         (\<forall>y. (\<forall>i. y $ i \<in> A i) \<longrightarrow> y \<in> S)" by metis
   419     qed
   420   qed
   421   show "open S = (\<forall>x\<in>S. \<forall>\<^sub>F (x', y) in uniformity. x' = x \<longrightarrow> y \<in> S)"
   422     unfolding * eventually_uniformity_metric
   423     by (simp del: split_paired_All add: dist_vec_def dist_commute)
   424 qed
   425 
   426 end
   427 
   428 lemma Cauchy_vec_nth:
   429   "Cauchy (\<lambda>n. X n) \<Longrightarrow> Cauchy (\<lambda>n. X n $ i)"
   430   unfolding Cauchy_def by (fast intro: le_less_trans [OF dist_vec_nth_le])
   431 
   432 lemma vec_CauchyI:
   433   fixes X :: "nat \<Rightarrow> 'a::metric_space ^ 'n"
   434   assumes X: "\<And>i. Cauchy (\<lambda>n. X n $ i)"
   435   shows "Cauchy (\<lambda>n. X n)"
   436 proof (rule metric_CauchyI)
   437   fix r :: real assume "0 < r"
   438   hence "0 < r / of_nat CARD('n)" (is "0 < ?s") by simp
   439   define N where "N i = (LEAST N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m $ i) (X n $ i) < ?s)" for i
   440   define M where "M = Max (range N)"
   441   have "\<And>i. \<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m $ i) (X n $ i) < ?s"
   442     using X \<open>0 < ?s\<close> by (rule metric_CauchyD)
   443   hence "\<And>i. \<forall>m\<ge>N i. \<forall>n\<ge>N i. dist (X m $ i) (X n $ i) < ?s"
   444     unfolding N_def by (rule LeastI_ex)
   445   hence M: "\<And>i. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m $ i) (X n $ i) < ?s"
   446     unfolding M_def by simp
   447   {
   448     fix m n :: nat
   449     assume "M \<le> m" "M \<le> n"
   450     have "dist (X m) (X n) = L2_set (\<lambda>i. dist (X m $ i) (X n $ i)) UNIV"
   451       unfolding dist_vec_def ..
   452     also have "\<dots> \<le> sum (\<lambda>i. dist (X m $ i) (X n $ i)) UNIV"
   453       by (rule L2_set_le_sum [OF zero_le_dist])
   454     also have "\<dots> < sum (\<lambda>i::'n. ?s) UNIV"
   455       by (rule sum_strict_mono, simp_all add: M \<open>M \<le> m\<close> \<open>M \<le> n\<close>)
   456     also have "\<dots> = r"
   457       by simp
   458     finally have "dist (X m) (X n) < r" .
   459   }
   460   hence "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < r"
   461     by simp
   462   then show "\<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < r" ..
   463 qed
   464 
   465 instance vec :: (complete_space, finite) complete_space
   466 proof
   467   fix X :: "nat \<Rightarrow> 'a ^ 'b" assume "Cauchy X"
   468   have "\<And>i. (\<lambda>n. X n $ i) \<longlonglongrightarrow> lim (\<lambda>n. X n $ i)"
   469     using Cauchy_vec_nth [OF \<open>Cauchy X\<close>]
   470     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   471   hence "X \<longlonglongrightarrow> vec_lambda (\<lambda>i. lim (\<lambda>n. X n $ i))"
   472     by (simp add: vec_tendstoI)
   473   then show "convergent X"
   474     by (rule convergentI)
   475 qed
   476 
   477 
   478 subsection \<open>Normed vector space\<close>
   479 
   480 instantiation vec :: (real_normed_vector, finite) real_normed_vector
   481 begin
   482 
   483 definition "norm x = L2_set (\<lambda>i. norm (x$i)) UNIV"
   484 
   485 definition "sgn (x::'a^'b) = scaleR (inverse (norm x)) x"
   486 
   487 instance proof
   488   fix a :: real and x y :: "'a ^ 'b"
   489   show "norm x = 0 \<longleftrightarrow> x = 0"
   490     unfolding norm_vec_def
   491     by (simp add: L2_set_eq_0_iff vec_eq_iff)
   492   show "norm (x + y) \<le> norm x + norm y"
   493     unfolding norm_vec_def
   494     apply (rule order_trans [OF _ L2_set_triangle_ineq])
   495     apply (simp add: L2_set_mono norm_triangle_ineq)
   496     done
   497   show "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   498     unfolding norm_vec_def
   499     by (simp add: L2_set_right_distrib)
   500   show "sgn x = scaleR (inverse (norm x)) x"
   501     by (rule sgn_vec_def)
   502   show "dist x y = norm (x - y)"
   503     unfolding dist_vec_def norm_vec_def
   504     by (simp add: dist_norm)
   505 qed
   506 
   507 end
   508 
   509 lemma norm_nth_le: "norm (x $ i) \<le> norm x"
   510 unfolding norm_vec_def
   511 by (rule member_le_L2_set) simp_all
   512 
   513 lemma bounded_linear_vec_nth: "bounded_linear (\<lambda>x. x $ i)"
   514 apply standard
   515 apply (rule vector_add_component)
   516 apply (rule vector_scaleR_component)
   517 apply (rule_tac x="1" in exI, simp add: norm_nth_le)
   518 done
   519 
   520 instance vec :: (banach, finite) banach ..
   521 
   522 
   523 subsection \<open>Inner product space\<close>
   524 
   525 instantiation vec :: (real_inner, finite) real_inner
   526 begin
   527 
   528 definition "inner x y = sum (\<lambda>i. inner (x$i) (y$i)) UNIV"
   529 
   530 instance proof
   531   fix r :: real and x y z :: "'a ^ 'b"
   532   show "inner x y = inner y x"
   533     unfolding inner_vec_def
   534     by (simp add: inner_commute)
   535   show "inner (x + y) z = inner x z + inner y z"
   536     unfolding inner_vec_def
   537     by (simp add: inner_add_left sum.distrib)
   538   show "inner (scaleR r x) y = r * inner x y"
   539     unfolding inner_vec_def
   540     by (simp add: sum_distrib_left)
   541   show "0 \<le> inner x x"
   542     unfolding inner_vec_def
   543     by (simp add: sum_nonneg)
   544   show "inner x x = 0 \<longleftrightarrow> x = 0"
   545     unfolding inner_vec_def
   546     by (simp add: vec_eq_iff sum_nonneg_eq_0_iff)
   547   show "norm x = sqrt (inner x x)"
   548     unfolding inner_vec_def norm_vec_def L2_set_def
   549     by (simp add: power2_norm_eq_inner)
   550 qed
   551 
   552 end
   553 
   554 
   555 subsection \<open>Euclidean space\<close>
   556 
   557 text \<open>Vectors pointing along a single axis.\<close>
   558 
   559 definition "axis k x = (\<chi> i. if i = k then x else 0)"
   560 
   561 lemma axis_nth [simp]: "axis i x $ i = x"
   562   unfolding axis_def by simp
   563 
   564 lemma axis_eq_axis: "axis i x = axis j y \<longleftrightarrow> x = y \<and> i = j \<or> x = 0 \<and> y = 0"
   565   unfolding axis_def vec_eq_iff by auto
   566 
   567 lemma inner_axis_axis:
   568   "inner (axis i x) (axis j y) = (if i = j then inner x y else 0)"
   569   unfolding inner_vec_def
   570   apply (cases "i = j")
   571   apply clarsimp
   572   apply (subst sum.remove [of _ j], simp_all)
   573   apply (rule sum.neutral, simp add: axis_def)
   574   apply (rule sum.neutral, simp add: axis_def)
   575   done
   576 
   577 lemma sum_single:
   578   assumes "finite A" and "k \<in> A" and "f k = y"
   579   assumes "\<And>i. i \<in> A \<Longrightarrow> i \<noteq> k \<Longrightarrow> f i = 0"
   580   shows "(\<Sum>i\<in>A. f i) = y"
   581   apply (subst sum.remove [OF assms(1,2)])
   582   apply (simp add: sum.neutral assms(3,4))
   583   done
   584 
   585 lemma inner_axis: "inner x (axis i y) = inner (x $ i) y"
   586   unfolding inner_vec_def
   587   apply (rule_tac k=i in sum_single)
   588   apply simp_all
   589   apply (simp add: axis_def)
   590   done
   591 
   592 instantiation vec :: (euclidean_space, finite) euclidean_space
   593 begin
   594 
   595 definition "Basis = (\<Union>i. \<Union>u\<in>Basis. {axis i u})"
   596 
   597 instance proof
   598   show "(Basis :: ('a ^ 'b) set) \<noteq> {}"
   599     unfolding Basis_vec_def by simp
   600 next
   601   show "finite (Basis :: ('a ^ 'b) set)"
   602     unfolding Basis_vec_def by simp
   603 next
   604   fix u v :: "'a ^ 'b"
   605   assume "u \<in> Basis" and "v \<in> Basis"
   606   thus "inner u v = (if u = v then 1 else 0)"
   607     unfolding Basis_vec_def
   608     by (auto simp add: inner_axis_axis axis_eq_axis inner_Basis)
   609 next
   610   fix x :: "'a ^ 'b"
   611   show "(\<forall>u\<in>Basis. inner x u = 0) \<longleftrightarrow> x = 0"
   612     unfolding Basis_vec_def
   613     by (simp add: inner_axis euclidean_all_zero_iff vec_eq_iff)
   614 qed
   615 
   616 lemma DIM_cart[simp]: "DIM('a^'b) = CARD('b) * DIM('a)"
   617   apply (simp add: Basis_vec_def)
   618   apply (subst card_UN_disjoint)
   619      apply simp
   620     apply simp
   621    apply (auto simp: axis_eq_axis) [1]
   622   apply (subst card_UN_disjoint)
   623      apply (auto simp: axis_eq_axis)
   624   done
   625 
   626 end
   627 
   628 lemma cart_eq_inner_axis: "a $ i = inner a (axis i 1)"
   629   by (simp add: inner_axis)
   630 
   631 lemma axis_in_Basis: "a \<in> Basis \<Longrightarrow> axis i a \<in> Basis"
   632   by (auto simp add: Basis_vec_def axis_eq_axis)
   633 
   634 end