src/HOL/Product_Type.thy
author wenzelm
Thu Apr 18 17:07:01 2013 +0200 (2013-04-18)
changeset 51717 9e7d1c139569
parent 51703 f2e92fc0c8aa
child 52143 36ffe23b25f8
permissions -rw-r--r--
simplifier uses proper Proof.context instead of historic type simpset;
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 keywords "inductive_set" "coinductive_set" :: thy_decl
    11 begin
    12 
    13 subsection {* @{typ bool} is a datatype *}
    14 
    15 rep_datatype True False by (auto intro: bool_induct)
    16 
    17 declare case_split [cases type: bool]
    18   -- "prefer plain propositional version"
    19 
    20 lemma
    21   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    22     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    23     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P"
    24     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    25     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    26   by (simp_all add: equal)
    27 
    28 lemma If_case_cert:
    29   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    30   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    31   using assms by simp_all
    32 
    33 setup {*
    34   Code.add_case @{thm If_case_cert}
    35 *}
    36 
    37 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    38   (Haskell infix 4 "==")
    39 
    40 code_instance bool :: equal
    41   (Haskell -)
    42 
    43 
    44 subsection {* The @{text unit} type *}
    45 
    46 typedef unit = "{True}"
    47   by auto
    48 
    49 definition Unity :: unit  ("'(')")
    50   where "() = Abs_unit True"
    51 
    52 lemma unit_eq [no_atp]: "u = ()"
    53   by (induct u) (simp add: Unity_def)
    54 
    55 text {*
    56   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    57   this rule directly --- it loops!
    58 *}
    59 
    60 simproc_setup unit_eq ("x::unit") = {*
    61   fn _ => fn _ => fn ct =>
    62     if HOLogic.is_unit (term_of ct) then NONE
    63     else SOME (mk_meta_eq @{thm unit_eq})
    64 *}
    65 
    66 rep_datatype "()" by simp
    67 
    68 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    69   by simp
    70 
    71 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    72   by (rule triv_forall_equality)
    73 
    74 text {*
    75   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    76   [source] "%u::unit. f u"}, replacing it by @{term [source]
    77   f} rather than by @{term [source] "%u. f ()"}.
    78 *}
    79 
    80 lemma unit_abs_eta_conv [simp, no_atp]: "(%u::unit. f ()) = f"
    81   by (rule ext) simp
    82 
    83 lemma UNIV_unit [no_atp]:
    84   "UNIV = {()}" by auto
    85 
    86 instantiation unit :: default
    87 begin
    88 
    89 definition "default = ()"
    90 
    91 instance ..
    92 
    93 end
    94 
    95 lemma [code]:
    96   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
    97 
    98 code_type unit
    99   (SML "unit")
   100   (OCaml "unit")
   101   (Haskell "()")
   102   (Scala "Unit")
   103 
   104 code_const Unity
   105   (SML "()")
   106   (OCaml "()")
   107   (Haskell "()")
   108   (Scala "()")
   109 
   110 code_instance unit :: equal
   111   (Haskell -)
   112 
   113 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   114   (Haskell infix 4 "==")
   115 
   116 code_reserved SML
   117   unit
   118 
   119 code_reserved OCaml
   120   unit
   121 
   122 code_reserved Scala
   123   Unit
   124 
   125 
   126 subsection {* The product type *}
   127 
   128 subsubsection {* Type definition *}
   129 
   130 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   131   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   132 
   133 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   134 
   135 typedef ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   136   unfolding prod_def by auto
   137 
   138 type_notation (xsymbols)
   139   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   140 type_notation (HTML output)
   141   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   142 
   143 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   144   "Pair a b = Abs_prod (Pair_Rep a b)"
   145 
   146 rep_datatype Pair proof -
   147   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   148   assume "\<And>a b. P (Pair a b)"
   149   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   150 next
   151   fix a c :: 'a and b d :: 'b
   152   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   153     by (auto simp add: Pair_Rep_def fun_eq_iff)
   154   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   155     by (auto simp add: prod_def)
   156   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   157     by (simp add: Pair_def Abs_prod_inject)
   158 qed
   159 
   160 declare prod.simps(2) [nitpick_simp del]
   161 
   162 declare prod.weak_case_cong [cong del]
   163 
   164 
   165 subsubsection {* Tuple syntax *}
   166 
   167 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   168   "split \<equiv> prod_case"
   169 
   170 text {*
   171   Patterns -- extends pre-defined type @{typ pttrn} used in
   172   abstractions.
   173 *}
   174 
   175 nonterminal tuple_args and patterns
   176 
   177 syntax
   178   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   179   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   180   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   181   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   182   ""            :: "pttrn => patterns"                  ("_")
   183   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   184 
   185 translations
   186   "(x, y)" == "CONST Pair x y"
   187   "_pattern x y" => "CONST Pair x y"
   188   "_patterns x y" => "CONST Pair x y"
   189   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   190   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   191   "%(x, y). b" == "CONST prod_case (%x y. b)"
   192   "_abs (CONST Pair x y) t" => "%(x, y). t"
   193   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   194      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   195 
   196 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   197   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   198 print_translation {*
   199 let
   200   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   201         (* split (%x y. t) => %(x,y) t *)
   202         let
   203           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   204           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   205         in
   206           Syntax.const @{syntax_const "_abs"} $
   207             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   208         end
   209     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   210         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   211         let
   212           val Const (@{syntax_const "_abs"}, _) $
   213             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   214           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   215         in
   216           Syntax.const @{syntax_const "_abs"} $
   217             (Syntax.const @{syntax_const "_pattern"} $ x' $
   218               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   219         end
   220     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   221         (* split (split (%x y z. t)) => %((x, y), z). t *)
   222         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   223     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   224         (* split (%pttrn z. t) => %(pttrn,z). t *)
   225         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   226           Syntax.const @{syntax_const "_abs"} $
   227             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   228         end
   229     | split_tr' _ = raise Match;
   230 in [(@{const_syntax prod_case}, split_tr')] end
   231 *}
   232 
   233 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   234 typed_print_translation {*
   235 let
   236   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   237     | split_guess_names_tr' T [Abs (x, xT, t)] =
   238         (case (head_of t) of
   239           Const (@{const_syntax prod_case}, _) => raise Match
   240         | _ =>
   241           let 
   242             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   243             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   244             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   245           in
   246             Syntax.const @{syntax_const "_abs"} $
   247               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   248           end)
   249     | split_guess_names_tr' T [t] =
   250         (case head_of t of
   251           Const (@{const_syntax prod_case}, _) => raise Match
   252         | _ =>
   253           let
   254             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   255             val (y, t') =
   256               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   257             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   258           in
   259             Syntax.const @{syntax_const "_abs"} $
   260               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   261           end)
   262     | split_guess_names_tr' _ _ = raise Match;
   263 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   264 *}
   265 
   266 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   267    where Q is some bounded quantifier or set operator.
   268    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   269    whereas we want "Q (x,y):A. P x y".
   270    Otherwise prevent eta-contraction.
   271 *)
   272 print_translation {*
   273 let
   274   fun contract Q f ts =
   275     case ts of
   276       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   277       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   278     | _ => f ts;
   279   fun contract2 (Q,f) = (Q, contract Q f);
   280   val pairs =
   281     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   282      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   283      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   284      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   285 in map contract2 pairs end
   286 *}
   287 
   288 subsubsection {* Code generator setup *}
   289 
   290 code_type prod
   291   (SML infix 2 "*")
   292   (OCaml infix 2 "*")
   293   (Haskell "!((_),/ (_))")
   294   (Scala "((_),/ (_))")
   295 
   296 code_const Pair
   297   (SML "!((_),/ (_))")
   298   (OCaml "!((_),/ (_))")
   299   (Haskell "!((_),/ (_))")
   300   (Scala "!((_),/ (_))")
   301 
   302 code_instance prod :: equal
   303   (Haskell -)
   304 
   305 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   306   (Haskell infix 4 "==")
   307 
   308 
   309 subsubsection {* Fundamental operations and properties *}
   310 
   311 lemma Pair_inject:
   312   assumes "(a, b) = (a', b')"
   313     and "a = a' ==> b = b' ==> R"
   314   shows R
   315   using assms by simp
   316 
   317 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   318   by (cases p) simp
   319 
   320 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   321   "fst p = (case p of (a, b) \<Rightarrow> a)"
   322 
   323 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   324   "snd p = (case p of (a, b) \<Rightarrow> b)"
   325 
   326 lemma fst_conv [simp, code]: "fst (a, b) = a"
   327   unfolding fst_def by simp
   328 
   329 lemma snd_conv [simp, code]: "snd (a, b) = b"
   330   unfolding snd_def by simp
   331 
   332 code_const fst and snd
   333   (Haskell "fst" and "snd")
   334 
   335 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   336   by (simp add: fun_eq_iff split: prod.split)
   337 
   338 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   339   by simp
   340 
   341 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   342   by simp
   343 
   344 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   345   by (cases p) simp
   346 
   347 lemmas surjective_pairing = pair_collapse [symmetric]
   348 
   349 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   350   by (cases s, cases t) simp
   351 
   352 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   353   by (simp add: prod_eq_iff)
   354 
   355 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   356   by (fact prod.cases)
   357 
   358 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   359   by (rule split_conv [THEN iffD2])
   360 
   361 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   362   by (rule split_conv [THEN iffD1])
   363 
   364 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   365   by (simp add: fun_eq_iff split: prod.split)
   366 
   367 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   368   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   369   by (simp add: fun_eq_iff split: prod.split)
   370 
   371 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   372   by (cases x) simp
   373 
   374 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   375   by (cases p) simp
   376 
   377 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   378   by (simp add: prod_case_unfold)
   379 
   380 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   381   -- {* Prevents simplification of @{term c}: much faster *}
   382   by (fact prod.weak_case_cong)
   383 
   384 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   385   by (simp add: split_eta)
   386 
   387 lemma split_paired_all [no_atp]: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   388 proof
   389   fix a b
   390   assume "!!x. PROP P x"
   391   then show "PROP P (a, b)" .
   392 next
   393   fix x
   394   assume "!!a b. PROP P (a, b)"
   395   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   396 qed
   397 
   398 lemma case_prod_distrib: "f (case x of (x, y) \<Rightarrow> g x y) = (case x of (x, y) \<Rightarrow> f (g x y))"
   399   by (cases x) simp
   400 
   401 text {*
   402   The rule @{thm [source] split_paired_all} does not work with the
   403   Simplifier because it also affects premises in congrence rules,
   404   where this can lead to premises of the form @{text "!!a b. ... =
   405   ?P(a, b)"} which cannot be solved by reflexivity.
   406 *}
   407 
   408 lemmas split_tupled_all = split_paired_all unit_all_eq2
   409 
   410 ML {*
   411   (* replace parameters of product type by individual component parameters *)
   412   local (* filtering with exists_paired_all is an essential optimization *)
   413     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   414           can HOLogic.dest_prodT T orelse exists_paired_all t
   415       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   416       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   417       | exists_paired_all _ = false;
   418     val ss =
   419       simpset_of
   420        (put_simpset HOL_basic_ss @{context}
   421         addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   422         addsimprocs [@{simproc unit_eq}]);
   423   in
   424     fun split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   425       if exists_paired_all t then safe_full_simp_tac (put_simpset ss ctxt) i else no_tac);
   426 
   427     fun unsafe_split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   428       if exists_paired_all t then full_simp_tac (put_simpset ss ctxt) i else no_tac);
   429 
   430     fun split_all ctxt th =
   431       if exists_paired_all (Thm.prop_of th)
   432       then full_simplify (put_simpset ss ctxt) th else th;
   433   end;
   434 *}
   435 
   436 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_all_tac", split_all_tac)) *}
   437 
   438 lemma split_paired_All [simp, no_atp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   439   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   440   by fast
   441 
   442 lemma split_paired_Ex [simp, no_atp]: "(EX x. P x) = (EX a b. P (a, b))"
   443   by fast
   444 
   445 lemma split_paired_The [no_atp]: "(THE x. P x) = (THE (a, b). P (a, b))"
   446   -- {* Can't be added to simpset: loops! *}
   447   by (simp add: split_eta)
   448 
   449 text {*
   450   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   451   @{thm [source] split_eta} as a rewrite rule is not general enough,
   452   and using @{thm [source] cond_split_eta} directly would render some
   453   existing proofs very inefficient; similarly for @{text
   454   split_beta}.
   455 *}
   456 
   457 ML {*
   458 local
   459   val cond_split_eta_ss =
   460     simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms cond_split_eta});
   461   fun Pair_pat k 0 (Bound m) = (m = k)
   462     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   463         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   464     | Pair_pat _ _ _ = false;
   465   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   466     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   467     | no_args k i (Bound m) = m < k orelse m > k + i
   468     | no_args _ _ _ = true;
   469   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   470     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   471     | split_pat tp i _ = NONE;
   472   fun metaeq ctxt lhs rhs = mk_meta_eq (Goal.prove ctxt [] []
   473         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   474         (K (simp_tac (put_simpset cond_split_eta_ss ctxt) 1)));
   475 
   476   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   477     | beta_term_pat k i (t $ u) =
   478         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   479     | beta_term_pat k i t = no_args k i t;
   480   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   481     | eta_term_pat _ _ _ = false;
   482   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   483     | subst arg k i (t $ u) =
   484         if Pair_pat k i (t $ u) then incr_boundvars k arg
   485         else (subst arg k i t $ subst arg k i u)
   486     | subst arg k i t = t;
   487 in
   488   fun beta_proc ctxt (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   489         (case split_pat beta_term_pat 1 t of
   490           SOME (i, f) => SOME (metaeq ctxt s (subst arg 0 i f))
   491         | NONE => NONE)
   492     | beta_proc _ _ = NONE;
   493   fun eta_proc ctxt (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   494         (case split_pat eta_term_pat 1 t of
   495           SOME (_, ft) => SOME (metaeq ctxt s (let val (f $ arg) = ft in f end))
   496         | NONE => NONE)
   497     | eta_proc _ _ = NONE;
   498 end;
   499 *}
   500 simproc_setup split_beta ("split f z") = {* fn _ => fn ctxt => fn ct => beta_proc ctxt (term_of ct) *}
   501 simproc_setup split_eta ("split f") = {* fn _ => fn ctxt => fn ct => eta_proc ctxt (term_of ct) *}
   502 
   503 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   504   by (subst surjective_pairing, rule split_conv)
   505 
   506 lemma split_beta': "(\<lambda>(x,y). f x y) = (\<lambda>x. f (fst x) (snd x))"
   507   by (auto simp: fun_eq_iff)
   508 
   509 
   510 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   511   -- {* For use with @{text split} and the Simplifier. *}
   512   by (insert surj_pair [of p], clarify, simp)
   513 
   514 text {*
   515   @{thm [source] split_split} could be declared as @{text "[split]"}
   516   done after the Splitter has been speeded up significantly;
   517   precompute the constants involved and don't do anything unless the
   518   current goal contains one of those constants.
   519 *}
   520 
   521 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   522 by (subst split_split, simp)
   523 
   524 text {*
   525   \medskip @{term split} used as a logical connective or set former.
   526 
   527   \medskip These rules are for use with @{text blast}; could instead
   528   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   529 
   530 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   531   apply (simp only: split_tupled_all)
   532   apply (simp (no_asm_simp))
   533   done
   534 
   535 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   536   apply (simp only: split_tupled_all)
   537   apply (simp (no_asm_simp))
   538   done
   539 
   540 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   541   by (induct p) auto
   542 
   543 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   544   by (induct p) auto
   545 
   546 lemma splitE2:
   547   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   548 proof -
   549   assume q: "Q (split P z)"
   550   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   551   show R
   552     apply (rule r surjective_pairing)+
   553     apply (rule split_beta [THEN subst], rule q)
   554     done
   555 qed
   556 
   557 lemma splitD': "split R (a,b) c ==> R a b c"
   558   by simp
   559 
   560 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   561   by simp
   562 
   563 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   564 by (simp only: split_tupled_all, simp)
   565 
   566 lemma mem_splitE:
   567   assumes major: "z \<in> split c p"
   568     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   569   shows Q
   570   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   571 
   572 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   573 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   574 
   575 ML {*
   576 local (* filtering with exists_p_split is an essential optimization *)
   577   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   578     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   579     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   580     | exists_p_split _ = false;
   581 in
   582 fun split_conv_tac ctxt = SUBGOAL (fn (t, i) =>
   583   if exists_p_split t
   584   then safe_full_simp_tac (put_simpset HOL_basic_ss ctxt addsimps @{thms split_conv}) i
   585   else no_tac);
   586 end;
   587 *}
   588 
   589 (* This prevents applications of splitE for already splitted arguments leading
   590    to quite time-consuming computations (in particular for nested tuples) *)
   591 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_conv_tac", split_conv_tac)) *}
   592 
   593 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   594   by (rule ext) fast
   595 
   596 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   597   by (rule ext) fast
   598 
   599 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   600   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   601   by (rule ext) blast
   602 
   603 (* Do NOT make this a simp rule as it
   604    a) only helps in special situations
   605    b) can lead to nontermination in the presence of split_def
   606 *)
   607 lemma split_comp_eq: 
   608   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   609   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   610   by (rule ext) auto
   611 
   612 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   613   apply (rule_tac x = "(a, b)" in image_eqI)
   614    apply auto
   615   done
   616 
   617 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   618   by blast
   619 
   620 (*
   621 the following  would be slightly more general,
   622 but cannot be used as rewrite rule:
   623 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   624 ### ?y = .x
   625 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   626 by (rtac some_equality 1)
   627 by ( Simp_tac 1)
   628 by (split_all_tac 1)
   629 by (Asm_full_simp_tac 1)
   630 qed "The_split_eq";
   631 *)
   632 
   633 text {*
   634   Setup of internal @{text split_rule}.
   635 *}
   636 
   637 lemmas prod_caseI = prod.cases [THEN iffD2]
   638 
   639 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   640   by (fact splitI2)
   641 
   642 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   643   by (fact splitI2')
   644 
   645 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   646   by (fact splitE)
   647 
   648 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   649   by (fact splitE')
   650 
   651 declare prod_caseI [intro!]
   652 
   653 lemma prod_case_beta:
   654   "prod_case f p = f (fst p) (snd p)"
   655   by (fact split_beta)
   656 
   657 lemma prod_cases3 [cases type]:
   658   obtains (fields) a b c where "y = (a, b, c)"
   659   by (cases y, case_tac b) blast
   660 
   661 lemma prod_induct3 [case_names fields, induct type]:
   662     "(!!a b c. P (a, b, c)) ==> P x"
   663   by (cases x) blast
   664 
   665 lemma prod_cases4 [cases type]:
   666   obtains (fields) a b c d where "y = (a, b, c, d)"
   667   by (cases y, case_tac c) blast
   668 
   669 lemma prod_induct4 [case_names fields, induct type]:
   670     "(!!a b c d. P (a, b, c, d)) ==> P x"
   671   by (cases x) blast
   672 
   673 lemma prod_cases5 [cases type]:
   674   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   675   by (cases y, case_tac d) blast
   676 
   677 lemma prod_induct5 [case_names fields, induct type]:
   678     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   679   by (cases x) blast
   680 
   681 lemma prod_cases6 [cases type]:
   682   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   683   by (cases y, case_tac e) blast
   684 
   685 lemma prod_induct6 [case_names fields, induct type]:
   686     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   687   by (cases x) blast
   688 
   689 lemma prod_cases7 [cases type]:
   690   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   691   by (cases y, case_tac f) blast
   692 
   693 lemma prod_induct7 [case_names fields, induct type]:
   694     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   695   by (cases x) blast
   696 
   697 lemma split_def:
   698   "split = (\<lambda>c p. c (fst p) (snd p))"
   699   by (fact prod_case_unfold)
   700 
   701 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   702   "internal_split == split"
   703 
   704 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   705   by (simp only: internal_split_def split_conv)
   706 
   707 ML_file "Tools/split_rule.ML"
   708 setup Split_Rule.setup
   709 
   710 hide_const internal_split
   711 
   712 
   713 subsubsection {* Derived operations *}
   714 
   715 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   716   "curry = (\<lambda>c x y. c (x, y))"
   717 
   718 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   719   by (simp add: curry_def)
   720 
   721 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   722   by (simp add: curry_def)
   723 
   724 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   725   by (simp add: curry_def)
   726 
   727 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   728   by (simp add: curry_def)
   729 
   730 lemma curry_split [simp]: "curry (split f) = f"
   731   by (simp add: curry_def split_def)
   732 
   733 lemma split_curry [simp]: "split (curry f) = f"
   734   by (simp add: curry_def split_def)
   735 
   736 text {*
   737   The composition-uncurry combinator.
   738 *}
   739 
   740 notation fcomp (infixl "\<circ>>" 60)
   741 
   742 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   743   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   744 
   745 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   746   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   747 
   748 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   749   by (simp add: scomp_unfold prod_case_unfold)
   750 
   751 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   752   by (simp add: fun_eq_iff)
   753 
   754 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   755   by (simp add: fun_eq_iff)
   756 
   757 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   758   by (simp add: fun_eq_iff scomp_unfold)
   759 
   760 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   761   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   762 
   763 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   764   by (simp add: fun_eq_iff scomp_unfold)
   765 
   766 code_const scomp
   767   (Eval infixl 3 "#->")
   768 
   769 no_notation fcomp (infixl "\<circ>>" 60)
   770 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   771 
   772 text {*
   773   @{term map_pair} --- action of the product functor upon
   774   functions.
   775 *}
   776 
   777 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   778   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   779 
   780 lemma map_pair_simp [simp, code]:
   781   "map_pair f g (a, b) = (f a, g b)"
   782   by (simp add: map_pair_def)
   783 
   784 enriched_type map_pair: map_pair
   785   by (auto simp add: split_paired_all)
   786 
   787 lemma fst_map_pair [simp]:
   788   "fst (map_pair f g x) = f (fst x)"
   789   by (cases x) simp_all
   790 
   791 lemma snd_prod_fun [simp]:
   792   "snd (map_pair f g x) = g (snd x)"
   793   by (cases x) simp_all
   794 
   795 lemma fst_comp_map_pair [simp]:
   796   "fst \<circ> map_pair f g = f \<circ> fst"
   797   by (rule ext) simp_all
   798 
   799 lemma snd_comp_map_pair [simp]:
   800   "snd \<circ> map_pair f g = g \<circ> snd"
   801   by (rule ext) simp_all
   802 
   803 lemma map_pair_compose:
   804   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   805   by (rule ext) (simp add: map_pair.compositionality comp_def)
   806 
   807 lemma map_pair_ident [simp]:
   808   "map_pair (%x. x) (%y. y) = (%z. z)"
   809   by (rule ext) (simp add: map_pair.identity)
   810 
   811 lemma map_pair_imageI [intro]:
   812   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   813   by (rule image_eqI) simp_all
   814 
   815 lemma prod_fun_imageE [elim!]:
   816   assumes major: "c \<in> map_pair f g ` R"
   817     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   818   shows P
   819   apply (rule major [THEN imageE])
   820   apply (case_tac x)
   821   apply (rule cases)
   822   apply simp_all
   823   done
   824 
   825 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   826   "apfst f = map_pair f id"
   827 
   828 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   829   "apsnd f = map_pair id f"
   830 
   831 lemma apfst_conv [simp, code]:
   832   "apfst f (x, y) = (f x, y)" 
   833   by (simp add: apfst_def)
   834 
   835 lemma apsnd_conv [simp, code]:
   836   "apsnd f (x, y) = (x, f y)" 
   837   by (simp add: apsnd_def)
   838 
   839 lemma fst_apfst [simp]:
   840   "fst (apfst f x) = f (fst x)"
   841   by (cases x) simp
   842 
   843 lemma fst_comp_apfst [simp]:
   844   "fst \<circ> apfst f = f \<circ> fst"
   845   by (simp add: fun_eq_iff)
   846 
   847 lemma fst_apsnd [simp]:
   848   "fst (apsnd f x) = fst x"
   849   by (cases x) simp
   850 
   851 lemma fst_comp_apsnd [simp]:
   852   "fst \<circ> apsnd f = fst"
   853   by (simp add: fun_eq_iff)
   854 
   855 lemma snd_apfst [simp]:
   856   "snd (apfst f x) = snd x"
   857   by (cases x) simp
   858 
   859 lemma snd_comp_apfst [simp]:
   860   "snd \<circ> apfst f = snd"
   861   by (simp add: fun_eq_iff)
   862 
   863 lemma snd_apsnd [simp]:
   864   "snd (apsnd f x) = f (snd x)"
   865   by (cases x) simp
   866 
   867 lemma snd_comp_apsnd [simp]:
   868   "snd \<circ> apsnd f = f \<circ> snd"
   869   by (simp add: fun_eq_iff)
   870 
   871 lemma apfst_compose:
   872   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   873   by (cases x) simp
   874 
   875 lemma apsnd_compose:
   876   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   877   by (cases x) simp
   878 
   879 lemma apfst_apsnd [simp]:
   880   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   881   by (cases x) simp
   882 
   883 lemma apsnd_apfst [simp]:
   884   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   885   by (cases x) simp
   886 
   887 lemma apfst_id [simp] :
   888   "apfst id = id"
   889   by (simp add: fun_eq_iff)
   890 
   891 lemma apsnd_id [simp] :
   892   "apsnd id = id"
   893   by (simp add: fun_eq_iff)
   894 
   895 lemma apfst_eq_conv [simp]:
   896   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   897   by (cases x) simp
   898 
   899 lemma apsnd_eq_conv [simp]:
   900   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   901   by (cases x) simp
   902 
   903 lemma apsnd_apfst_commute:
   904   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   905   by simp
   906 
   907 text {*
   908   Disjoint union of a family of sets -- Sigma.
   909 *}
   910 
   911 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
   912   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   913 
   914 abbreviation
   915   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
   916     (infixr "<*>" 80) where
   917   "A <*> B == Sigma A (%_. B)"
   918 
   919 notation (xsymbols)
   920   Times  (infixr "\<times>" 80)
   921 
   922 notation (HTML output)
   923   Times  (infixr "\<times>" 80)
   924 
   925 hide_const (open) Times
   926 
   927 syntax
   928   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   929 translations
   930   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   931 
   932 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   933   by (unfold Sigma_def) blast
   934 
   935 lemma SigmaE [elim!]:
   936     "[| c: Sigma A B;
   937         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   938      |] ==> P"
   939   -- {* The general elimination rule. *}
   940   by (unfold Sigma_def) blast
   941 
   942 text {*
   943   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   944   eigenvariables.
   945 *}
   946 
   947 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   948   by blast
   949 
   950 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   951   by blast
   952 
   953 lemma SigmaE2:
   954     "[| (a, b) : Sigma A B;
   955         [| a:A;  b:B(a) |] ==> P
   956      |] ==> P"
   957   by blast
   958 
   959 lemma Sigma_cong:
   960      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   961       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   962   by auto
   963 
   964 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   965   by blast
   966 
   967 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   968   by blast
   969 
   970 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   971   by blast
   972 
   973 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   974   by auto
   975 
   976 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   977   by auto
   978 
   979 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   980   by auto
   981 
   982 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   983   by blast
   984 
   985 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   986   by blast
   987 
   988 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   989   by (blast elim: equalityE)
   990 
   991 lemma SetCompr_Sigma_eq:
   992     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   993   by blast
   994 
   995 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   996   by blast
   997 
   998 lemma UN_Times_distrib:
   999   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1000   -- {* Suggested by Pierre Chartier *}
  1001   by blast
  1002 
  1003 lemma split_paired_Ball_Sigma [simp, no_atp]:
  1004     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1005   by blast
  1006 
  1007 lemma split_paired_Bex_Sigma [simp, no_atp]:
  1008     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1009   by blast
  1010 
  1011 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1012   by blast
  1013 
  1014 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1015   by blast
  1016 
  1017 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1018   by blast
  1019 
  1020 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1021   by blast
  1022 
  1023 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1024   by blast
  1025 
  1026 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1027   by blast
  1028 
  1029 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1030   by blast
  1031 
  1032 text {*
  1033   Non-dependent versions are needed to avoid the need for higher-order
  1034   matching, especially when the rules are re-oriented.
  1035 *}
  1036 
  1037 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1038 by blast
  1039 
  1040 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1041 by blast
  1042 
  1043 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1044 by blast
  1045 
  1046 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1047   by auto
  1048 
  1049 lemma times_eq_iff: "A \<times> B = C \<times> D \<longleftrightarrow> A = C \<and> B = D \<or> ((A = {} \<or> B = {}) \<and> (C = {} \<or> D = {}))"
  1050   by auto
  1051 
  1052 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1053   by force
  1054 
  1055 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1056   by force
  1057 
  1058 lemma insert_times_insert[simp]:
  1059   "insert a A \<times> insert b B =
  1060    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1061 by blast
  1062 
  1063 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1064   apply auto
  1065   apply (case_tac "f x")
  1066   apply auto
  1067   done
  1068 
  1069 lemma times_Int_times: "A \<times> B \<inter> C \<times> D = (A \<inter> C) \<times> (B \<inter> D)"
  1070   by auto
  1071 
  1072 lemma swap_inj_on:
  1073   "inj_on (\<lambda>(i, j). (j, i)) A"
  1074   by (auto intro!: inj_onI)
  1075 
  1076 lemma swap_product:
  1077   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1078   by (simp add: split_def image_def) blast
  1079 
  1080 lemma image_split_eq_Sigma:
  1081   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1082 proof (safe intro!: imageI)
  1083   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1084   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1085     using * eq[symmetric] by auto
  1086 qed simp_all
  1087 
  1088 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1089   [code_abbrev]: "product A B = A \<times> B"
  1090 
  1091 hide_const (open) product
  1092 
  1093 lemma member_product:
  1094   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1095   by (simp add: product_def)
  1096 
  1097 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1098 
  1099 lemma map_pair_inj_on:
  1100   assumes "inj_on f A" and "inj_on g B"
  1101   shows "inj_on (map_pair f g) (A \<times> B)"
  1102 proof (rule inj_onI)
  1103   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1104   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1105   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1106   assume "map_pair f g x = map_pair f g y"
  1107   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1108   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1109   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1110   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1111   moreover from `map_pair f g x = map_pair f g y`
  1112   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1113   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1114   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1115   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1116   ultimately show "x = y" by(rule prod_eqI)
  1117 qed
  1118 
  1119 lemma map_pair_surj:
  1120   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1121   assumes "surj f" and "surj g"
  1122   shows "surj (map_pair f g)"
  1123 unfolding surj_def
  1124 proof
  1125   fix y :: "'b \<times> 'd"
  1126   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1127   moreover
  1128   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1129   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1130   thus "\<exists>x. y = map_pair f g x" by auto
  1131 qed
  1132 
  1133 lemma map_pair_surj_on:
  1134   assumes "f ` A = A'" and "g ` B = B'"
  1135   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1136 unfolding image_def
  1137 proof(rule set_eqI,rule iffI)
  1138   fix x :: "'a \<times> 'c"
  1139   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1140   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1141   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1142   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1143   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1144   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1145 next
  1146   fix x :: "'a \<times> 'c"
  1147   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1148   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1149   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1150   moreover from `image g B = B'` and `snd x \<in> B'`
  1151   obtain b where "b \<in> B" and "snd x = g b" by auto
  1152   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1153   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1154   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1155   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1156 qed
  1157 
  1158 
  1159 subsection {* Simproc for rewriting a set comprehension into a pointfree expression *}
  1160 
  1161 ML_file "Tools/set_comprehension_pointfree.ML"
  1162 
  1163 setup {*
  1164   Code_Preproc.map_pre (fn ctxt => ctxt addsimprocs
  1165     [Raw_Simplifier.make_simproc {name = "set comprehension", lhss = [@{cpat "Collect ?P"}],
  1166     proc = K Set_Comprehension_Pointfree.code_simproc, identifier = []}])
  1167 *}
  1168 
  1169 
  1170 subsection {* Inductively defined sets *}
  1171 
  1172 ML_file "Tools/inductive_set.ML"
  1173 setup Inductive_Set.setup
  1174 
  1175 
  1176 subsection {* Legacy theorem bindings and duplicates *}
  1177 
  1178 lemma PairE:
  1179   obtains x y where "p = (x, y)"
  1180   by (fact prod.exhaust)
  1181 
  1182 lemmas Pair_eq = prod.inject
  1183 
  1184 lemmas split = split_conv  -- {* for backwards compatibility *}
  1185 
  1186 lemmas Pair_fst_snd_eq = prod_eq_iff
  1187 
  1188 hide_const (open) prod
  1189 
  1190 end