src/HOL/Tools/prop_logic.ML
author paulson
Fri Nov 24 16:38:42 2006 +0100 (2006-11-24)
changeset 21513 9e9fff87dc6c
parent 20442 04621ea9440e
child 22441 7da872d34ace
permissions -rw-r--r--
Conversion of "equal" to "=" for TSTP format; big tidy-up
     1 (*  Title:      HOL/Tools/prop_logic.ML
     2     ID:         $Id$
     3     Author:     Tjark Weber
     4     Copyright   2004-2005
     5 
     6 Formulas of propositional logic.
     7 *)
     8 
     9 signature PROP_LOGIC =
    10 sig
    11 	datatype prop_formula =
    12 		  True
    13 		| False
    14 		| BoolVar of int  (* NOTE: only use indices >= 1 *)
    15 		| Not of prop_formula
    16 		| Or of prop_formula * prop_formula
    17 		| And of prop_formula * prop_formula
    18 
    19 	val SNot     : prop_formula -> prop_formula
    20 	val SOr      : prop_formula * prop_formula -> prop_formula
    21 	val SAnd     : prop_formula * prop_formula -> prop_formula
    22 	val simplify : prop_formula -> prop_formula  (* eliminates True/False and double-negation *)
    23 
    24 	val indices : prop_formula -> int list  (* set of all variable indices *)
    25 	val maxidx  : prop_formula -> int       (* maximal variable index *)
    26 
    27 	val exists      : prop_formula list -> prop_formula  (* finite disjunction *)
    28 	val all         : prop_formula list -> prop_formula  (* finite conjunction *)
    29 	val dot_product : prop_formula list * prop_formula list -> prop_formula
    30 
    31 	val nnf    : prop_formula -> prop_formula  (* negation normal form *)
    32 	val cnf    : prop_formula -> prop_formula  (* conjunctive normal form *)
    33 	val auxcnf : prop_formula -> prop_formula  (* cnf with auxiliary variables *)
    34 	val defcnf : prop_formula -> prop_formula  (* definitional cnf *)
    35 
    36 	val eval : (int -> bool) -> prop_formula -> bool  (* semantics *)
    37 
    38 	(* propositional representation of HOL terms *)
    39 	val prop_formula_of_term : Term.term -> int Termtab.table -> prop_formula * int Termtab.table
    40 	(* HOL term representation of propositional formulae *)
    41 	val term_of_prop_formula : prop_formula -> Term.term
    42 end;
    43 
    44 structure PropLogic : PROP_LOGIC =
    45 struct
    46 
    47 (* ------------------------------------------------------------------------- *)
    48 (* prop_formula: formulas of propositional logic, built from Boolean         *)
    49 (*               variables (referred to by index) and True/False using       *)
    50 (*               not/or/and                                                  *)
    51 (* ------------------------------------------------------------------------- *)
    52 
    53 	datatype prop_formula =
    54 		  True
    55 		| False
    56 		| BoolVar of int  (* NOTE: only use indices >= 1 *)
    57 		| Not of prop_formula
    58 		| Or of prop_formula * prop_formula
    59 		| And of prop_formula * prop_formula;
    60 
    61 (* ------------------------------------------------------------------------- *)
    62 (* The following constructor functions make sure that True and False do not  *)
    63 (* occur within any of the other connectives (i.e. Not, Or, And), and        *)
    64 (* perform double-negation elimination.                                      *)
    65 (* ------------------------------------------------------------------------- *)
    66 
    67 	(* prop_formula -> prop_formula *)
    68 
    69 	fun SNot True     = False
    70 	  | SNot False    = True
    71 	  | SNot (Not fm) = fm
    72 	  | SNot fm       = Not fm;
    73 
    74 	(* prop_formula * prop_formula -> prop_formula *)
    75 
    76 	fun SOr (True, _)   = True
    77 	  | SOr (_, True)   = True
    78 	  | SOr (False, fm) = fm
    79 	  | SOr (fm, False) = fm
    80 	  | SOr (fm1, fm2)  = Or (fm1, fm2);
    81 
    82 	(* prop_formula * prop_formula -> prop_formula *)
    83 
    84 	fun SAnd (True, fm) = fm
    85 	  | SAnd (fm, True) = fm
    86 	  | SAnd (False, _) = False
    87 	  | SAnd (_, False) = False
    88 	  | SAnd (fm1, fm2) = And (fm1, fm2);
    89 
    90 (* ------------------------------------------------------------------------- *)
    91 (* simplify: eliminates True/False below other connectives, and double-      *)
    92 (*      negation                                                             *)
    93 (* ------------------------------------------------------------------------- *)
    94 
    95 	(* prop_formula -> prop_formula *)
    96 
    97 	fun simplify (Not fm)         = SNot (simplify fm)
    98 	  | simplify (Or (fm1, fm2))  = SOr (simplify fm1, simplify fm2)
    99 	  | simplify (And (fm1, fm2)) = SAnd (simplify fm1, simplify fm2)
   100 	  | simplify fm               = fm;
   101 
   102 (* ------------------------------------------------------------------------- *)
   103 (* indices: collects all indices of Boolean variables that occur in a        *)
   104 (*      propositional formula 'fm'; no duplicates                            *)
   105 (* ------------------------------------------------------------------------- *)
   106 
   107 	(* prop_formula -> int list *)
   108 
   109 	fun indices True             = []
   110 	  | indices False            = []
   111 	  | indices (BoolVar i)      = [i]
   112 	  | indices (Not fm)         = indices fm
   113 	  | indices (Or (fm1, fm2))  = (indices fm1) union_int (indices fm2)
   114 	  | indices (And (fm1, fm2)) = (indices fm1) union_int (indices fm2);
   115 
   116 (* ------------------------------------------------------------------------- *)
   117 (* maxidx: computes the maximal variable index occuring in a formula of      *)
   118 (*      propositional logic 'fm'; 0 if 'fm' contains no variable             *)
   119 (* ------------------------------------------------------------------------- *)
   120 
   121 	(* prop_formula -> int *)
   122 
   123 	fun maxidx True             = 0
   124 	  | maxidx False            = 0
   125 	  | maxidx (BoolVar i)      = i
   126 	  | maxidx (Not fm)         = maxidx fm
   127 	  | maxidx (Or (fm1, fm2))  = Int.max (maxidx fm1, maxidx fm2)
   128 	  | maxidx (And (fm1, fm2)) = Int.max (maxidx fm1, maxidx fm2);
   129 
   130 (* ------------------------------------------------------------------------- *)
   131 (* exists: computes the disjunction over a list 'xs' of propositional        *)
   132 (*      formulas                                                             *)
   133 (* ------------------------------------------------------------------------- *)
   134 
   135 	(* prop_formula list -> prop_formula *)
   136 
   137 	fun exists xs = Library.foldl SOr (False, xs);
   138 
   139 (* ------------------------------------------------------------------------- *)
   140 (* all: computes the conjunction over a list 'xs' of propositional formulas  *)
   141 (* ------------------------------------------------------------------------- *)
   142 
   143 	(* prop_formula list -> prop_formula *)
   144 
   145 	fun all xs = Library.foldl SAnd (True, xs);
   146 
   147 (* ------------------------------------------------------------------------- *)
   148 (* dot_product: ([x1,...,xn], [y1,...,yn]) -> x1*y1+...+xn*yn                *)
   149 (* ------------------------------------------------------------------------- *)
   150 
   151 	(* prop_formula list * prop_formula list -> prop_formula *)
   152 
   153 	fun dot_product (xs,ys) = exists (map SAnd (xs~~ys));
   154 
   155 (* ------------------------------------------------------------------------- *)
   156 (* nnf: computes the negation normal form of a formula 'fm' of propositional *)
   157 (*      logic (i.e. only variables may be negated, but not subformulas).     *)
   158 (*      Simplification (c.f. 'simplify') is performed as well.               *)
   159 (* ------------------------------------------------------------------------- *)
   160 
   161 	(* prop_formula -> prop_formula *)
   162 
   163 	fun
   164 	(* constants *)
   165 	    nnf True                   = True
   166 	  | nnf False                  = False
   167 	(* variables *)
   168 	  | nnf (BoolVar i)            = (BoolVar i)
   169 	(* 'or' and 'and' as outermost connectives are left untouched *)
   170 	  | nnf (Or  (fm1, fm2))       = SOr  (nnf fm1, nnf fm2)
   171 	  | nnf (And (fm1, fm2))       = SAnd (nnf fm1, nnf fm2)
   172 	(* 'not' + constant *)
   173 	  | nnf (Not True)             = False
   174 	  | nnf (Not False)            = True
   175 	(* 'not' + variable *)
   176 	  | nnf (Not (BoolVar i))      = Not (BoolVar i)
   177 	(* pushing 'not' inside of 'or'/'and' using de Morgan's laws *)
   178 	  | nnf (Not (Or  (fm1, fm2))) = SAnd (nnf (SNot fm1), nnf (SNot fm2))
   179 	  | nnf (Not (And (fm1, fm2))) = SOr  (nnf (SNot fm1), nnf (SNot fm2))
   180 	(* double-negation elimination *)
   181 	  | nnf (Not (Not fm))         = nnf fm;
   182 
   183 (* ------------------------------------------------------------------------- *)
   184 (* cnf: computes the conjunctive normal form (i.e. a conjunction of          *)
   185 (*      disjunctions) of a formula 'fm' of propositional logic.  The result  *)
   186 (*      formula may be exponentially longer than 'fm'.                       *)
   187 (* ------------------------------------------------------------------------- *)
   188 
   189 	(* prop_formula -> prop_formula *)
   190 
   191 	fun cnf fm =
   192 	let
   193 		fun
   194 		(* constants *)
   195 		    cnf_from_nnf True             = True
   196 		  | cnf_from_nnf False            = False
   197 		(* literals *)
   198 		  | cnf_from_nnf (BoolVar i)      = BoolVar i
   199 		  | cnf_from_nnf (Not fm1)        = Not fm1  (* 'fm1' must be a variable since the formula is in NNF *)
   200 		(* pushing 'or' inside of 'and' using distributive laws *)
   201 		  | cnf_from_nnf (Or (fm1, fm2))  =
   202 			let
   203 				fun cnf_or (And (fm11, fm12), fm2) =
   204 					And (cnf_or (fm11, fm2), cnf_or (fm12, fm2))
   205 				  | cnf_or (fm1, And (fm21, fm22)) =
   206 					And (cnf_or (fm1, fm21), cnf_or (fm1, fm22))
   207 				(* neither subformula contains 'and' *)
   208 				  | cnf_or (fm1, fm2) =
   209 					Or (fm1, fm2)
   210 			in
   211 				cnf_or (cnf_from_nnf fm1, cnf_from_nnf fm2)
   212 			end
   213 		(* 'and' as outermost connective is left untouched *)
   214 		  | cnf_from_nnf (And (fm1, fm2)) = And (cnf_from_nnf fm1, cnf_from_nnf fm2)
   215 	in
   216 		(cnf_from_nnf o nnf) fm
   217 	end;
   218 
   219 (* ------------------------------------------------------------------------- *)
   220 (* auxcnf: computes the definitional conjunctive normal form of a formula    *)
   221 (*      'fm' of propositional logic, introducing auxiliary variables if      *)
   222 (*      necessary to avoid an exponential blowup of the formula.  The result *)
   223 (*      formula is satisfiable if and only if 'fm' is satisfiable.           *)
   224 (*      Auxiliary variables are introduced as switches for OR-nodes, based   *)
   225 (*      on the observation that e.g. "fm1 OR (fm21 AND fm22)" is             *)
   226 (*      equisatisfiable with "(fm1 OR ~aux) AND (fm21 OR aux) AND (fm22 OR   *)
   227 (*      aux)".                                                               *)
   228 (* ------------------------------------------------------------------------- *)
   229 
   230 (* ------------------------------------------------------------------------- *)
   231 (* Note: 'auxcnf' tends to use fewer variables and fewer clauses than        *)
   232 (*      'defcnf' below, but sometimes generates much larger SAT problems     *)
   233 (*      overall (hence it must sometimes generate longer clauses than        *)
   234 (*      'defcnf' does).  It is currently not quite clear to me if one of the *)
   235 (*      algorithms is clearly superior to the other, but I suggest using     *)
   236 (*      'defcnf' instead.                                                    *)
   237 (* ------------------------------------------------------------------------- *)
   238 
   239 	(* prop_formula -> prop_formula *)
   240 
   241 	fun auxcnf fm =
   242 	let
   243 		(* convert formula to NNF first *)
   244 		val fm' = nnf fm
   245 		(* 'new' specifies the next index that is available to introduce an auxiliary variable *)
   246 		(* int ref *)
   247 		val new = ref (maxidx fm' + 1)
   248 		(* unit -> int *)
   249 		fun new_idx () = let val idx = !new in new := idx+1; idx end
   250 		(* prop_formula -> prop_formula *)
   251 		fun
   252 		(* constants *)
   253 		    auxcnf_from_nnf True  = True
   254 		  | auxcnf_from_nnf False = False
   255 		(* literals *)
   256 		  | auxcnf_from_nnf (BoolVar i) = BoolVar i
   257 		  | auxcnf_from_nnf (Not fm1)   = Not fm1  (* 'fm1' must be a variable since the formula is in NNF *)
   258 		(* pushing 'or' inside of 'and' using auxiliary variables *)
   259 		  | auxcnf_from_nnf (Or (fm1, fm2)) =
   260 			let
   261 				val fm1' = auxcnf_from_nnf fm1
   262 				val fm2' = auxcnf_from_nnf fm2
   263 				(* prop_formula * prop_formula -> prop_formula *)
   264 				fun auxcnf_or (And (fm11, fm12), fm2) =
   265 					(case fm2 of
   266 					(* do not introduce an auxiliary variable for literals *)
   267 					  BoolVar _ =>
   268 							And (auxcnf_or (fm11, fm2), auxcnf_or (fm12, fm2))
   269 					| Not _ =>
   270 							And (auxcnf_or (fm11, fm2), auxcnf_or (fm12, fm2))
   271 					| _ =>
   272 						let
   273 							val aux = BoolVar (new_idx ())
   274 						in
   275 							And (And (auxcnf_or (fm11, aux), auxcnf_or (fm12, aux)), auxcnf_or (fm2, Not aux))
   276 						end)
   277 				  | auxcnf_or (fm1, And (fm21, fm22)) =
   278 					(case fm1 of
   279 					(* do not introduce an auxiliary variable for literals *)
   280 					  BoolVar _ =>
   281 							And (auxcnf_or (fm1, fm21), auxcnf_or (fm1, fm22))
   282 					| Not _ =>
   283 							And (auxcnf_or (fm1, fm21), auxcnf_or (fm1, fm22))
   284 					| _ =>
   285 						let
   286 							val aux = BoolVar (new_idx ())
   287 						in
   288 							And (auxcnf_or (fm1, Not aux), And (auxcnf_or (fm21, aux), auxcnf_or (fm22, aux)))
   289 						end)
   290 				(* neither subformula contains 'and' *)
   291 				  | auxcnf_or (fm1, fm2) =
   292 					Or (fm1, fm2)
   293 			in
   294 				auxcnf_or (fm1', fm2')
   295 			end
   296 		(* 'and' as outermost connective is left untouched *)
   297 		  | auxcnf_from_nnf (And (fm1, fm2)) =
   298 				And (auxcnf_from_nnf fm1, auxcnf_from_nnf fm2)
   299 	in
   300 		auxcnf_from_nnf fm'
   301 	end;
   302 
   303 (* ------------------------------------------------------------------------- *)
   304 (* defcnf: computes the definitional conjunctive normal form of a formula    *)
   305 (*      'fm' of propositional logic, introducing auxiliary variables to      *)
   306 (*      avoid an exponential blowup of the formula.  The result formula is   *)
   307 (*      satisfiable if and only if 'fm' is satisfiable.  Auxiliary variables *)
   308 (*      are introduced as abbreviations for AND-, OR-, and NOT-nodes, based  *)
   309 (*      on the following equisatisfiabilities (+/- indicates polarity):      *)
   310 (*      LITERAL+       == LITERAL                                            *)
   311 (*      LITERAL-       == NOT LITERAL                                        *)
   312 (*      (NOT fm1)+     == aux AND (NOT aux OR fm1-)                          *)
   313 (*      (fm1 OR fm2)+  == aux AND (NOT aux OR fm1+ OR fm2+)                  *)
   314 (*      (fm1 AND fm2)+ == aux AND (NOT aux OR fm1+) AND (NOT aux OR fm2+)    *)
   315 (*      (NOT fm1)-     == aux AND (NOT aux OR fm1+)                          *)
   316 (*      (fm1 OR fm2)-  == aux AND (NOT aux OR fm1-) AND (NOT aux OR fm2-)    *)
   317 (*      (fm1 AND fm2)- == aux AND (NOT aux OR fm1- OR fm2-)                  *)
   318 (*      Example:                                                             *)
   319 (*      NOT (a AND b) == aux1 AND (NOT aux1 OR aux2)                         *)
   320 (*                            AND (NOT aux2 OR NOT a OR NOT b)               *)
   321 (* ------------------------------------------------------------------------- *)
   322 
   323 	(* prop_formula -> prop_formula *)
   324 
   325 	fun defcnf fm =
   326 	let
   327 		(* simplify formula first *)
   328 		val fm' = simplify fm
   329 		(* 'new' specifies the next index that is available to introduce an auxiliary variable *)
   330 		(* int ref *)
   331 		val new = ref (maxidx fm' + 1)
   332 		(* unit -> int *)
   333 		fun new_idx () = let val idx = !new in new := idx+1; idx end
   334 		(* optimization for n-ary disjunction/conjunction *)
   335 		(* prop_formula -> prop_formula list *)
   336 		fun disjuncts (Or (fm1, fm2)) = (disjuncts fm1) @ (disjuncts fm2)
   337 		  | disjuncts fm1             = [fm1]
   338 		(* prop_formula -> prop_formula list *)
   339 		fun conjuncts (And (fm1, fm2)) = (conjuncts fm1) @ (conjuncts fm2)
   340 		  | conjuncts fm1              = [fm1]
   341 		(* polarity -> formula -> (defining clauses, literal) *)
   342 		(* bool -> prop_formula -> prop_formula * prop_formula *)
   343 		fun
   344 		(* constants *)
   345 		    defcnf' true  True  = (True, True)
   346 		  | defcnf' false True  = (*(True, False)*) error "formula is not simplified, True occurs with negative polarity"
   347 		  | defcnf' true  False = (True, False)
   348 		  | defcnf' false False = (*(True, True)*) error "formula is not simplified, False occurs with negative polarity"
   349 		(* literals *)
   350 		  | defcnf' true  (BoolVar i)       = (True, BoolVar i)
   351 		  | defcnf' false (BoolVar i)       = (True, Not (BoolVar i))
   352 		  | defcnf' true  (Not (BoolVar i)) = (True, Not (BoolVar i))
   353 		  | defcnf' false (Not (BoolVar i)) = (True, BoolVar i)
   354 		(* 'not' *)
   355 		  | defcnf' polarity (Not fm1) =
   356 			let
   357 				val (def1, aux1) = defcnf' (not polarity) fm1
   358 				val aux          = BoolVar (new_idx ())
   359 				val def          = Or (Not aux, aux1)
   360 			in
   361 				(SAnd (def1, def), aux)
   362 			end
   363 		(* 'or' *)
   364 		  | defcnf' polarity (Or (fm1, fm2)) =
   365 			let
   366 				val fms          = disjuncts (Or (fm1, fm2))
   367 				val (defs, auxs) = split_list (map (defcnf' polarity) fms)
   368 				val aux          = BoolVar (new_idx ())
   369 				val def          = if polarity then Or (Not aux, exists auxs) else all (map (fn a => Or (Not aux, a)) auxs)
   370 			in
   371 				(SAnd (all defs, def), aux)
   372 			end
   373 		(* 'and' *)
   374 		  | defcnf' polarity (And (fm1, fm2)) =
   375 			let
   376 				val fms          = conjuncts (And (fm1, fm2))
   377 				val (defs, auxs) = split_list (map (defcnf' polarity) fms)
   378 				val aux          = BoolVar (new_idx ())
   379 				val def          = if not polarity then Or (Not aux, exists auxs) else all (map (fn a => Or (Not aux, a)) auxs)
   380 			in
   381 				(SAnd (all defs, def), aux)
   382 			end
   383 		(* optimization: do not introduce auxiliary variables for parts of the formula that are in CNF already *)
   384 		(* prop_formula -> prop_formula * prop_formula *)
   385 		fun defcnf_or (Or (fm1, fm2)) =
   386 			let
   387 				val (def1, aux1) = defcnf_or fm1
   388 				val (def2, aux2) = defcnf_or fm2
   389 			in
   390 				(SAnd (def1, def2), Or (aux1, aux2))
   391 			end
   392 		  | defcnf_or fm =
   393 			defcnf' true fm
   394 		(* prop_formula -> prop_formula * prop_formula *)
   395 		fun defcnf_and (And (fm1, fm2)) =
   396 			let
   397 				val (def1, aux1) = defcnf_and fm1
   398 				val (def2, aux2) = defcnf_and fm2
   399 			in
   400 				(SAnd (def1, def2), And (aux1, aux2))
   401 			end
   402 		  | defcnf_and (Or (fm1, fm2)) =
   403 			let
   404 				val (def1, aux1) = defcnf_or fm1
   405 				val (def2, aux2) = defcnf_or fm2
   406 			in
   407 				(SAnd (def1, def2), Or (aux1, aux2))
   408 			end
   409 		  | defcnf_and fm =
   410 			defcnf' true fm
   411 	in
   412 		SAnd (defcnf_and fm')
   413 	end;
   414 
   415 (* ------------------------------------------------------------------------- *)
   416 (* eval: given an assignment 'a' of Boolean values to variable indices, the  *)
   417 (*      truth value of a propositional formula 'fm' is computed              *)
   418 (* ------------------------------------------------------------------------- *)
   419 
   420 	(* (int -> bool) -> prop_formula -> bool *)
   421 
   422 	fun eval a True            = true
   423 	  | eval a False           = false
   424 	  | eval a (BoolVar i)     = (a i)
   425 	  | eval a (Not fm)        = not (eval a fm)
   426 	  | eval a (Or (fm1,fm2))  = (eval a fm1) orelse (eval a fm2)
   427 	  | eval a (And (fm1,fm2)) = (eval a fm1) andalso (eval a fm2);
   428 
   429 (* ------------------------------------------------------------------------- *)
   430 (* prop_formula_of_term: returns the propositional structure of a HOL term,  *)
   431 (*      with subterms replaced by Boolean variables.  Also returns a table   *)
   432 (*      of terms and corresponding variables that extends the table that was *)
   433 (*      given as an argument.  Usually, you'll just want to use              *)
   434 (*      'Termtab.empty' as value for 'table'.                                *)
   435 (* ------------------------------------------------------------------------- *)
   436 
   437 (* Note: The implementation is somewhat optimized; the next index to be used *)
   438 (*       is computed only when it is actually needed.  However, when         *)
   439 (*       'prop_formula_of_term' is invoked many times, it might be more      *)
   440 (*       efficient to pass and return this value as an additional parameter, *)
   441 (*       so that it does not have to be recomputed (by folding over the      *)
   442 (*       table) for each invocation.                                         *)
   443 
   444 	(* Term.term -> int Termtab.table -> prop_formula * int Termtab.table *)
   445 	fun prop_formula_of_term t table =
   446 	let
   447 		val next_idx_is_valid = ref false
   448 		val next_idx          = ref 0
   449 		fun get_next_idx () =
   450 			if !next_idx_is_valid then
   451 				inc next_idx
   452 			else (
   453 				next_idx          := Termtab.fold (curry Int.max o snd) table 0;
   454 				next_idx_is_valid := true;
   455 				inc next_idx
   456 			)
   457 		fun aux (Const ("True", _))         table =
   458 			(True, table)
   459 		  | aux (Const ("False", _))        table =
   460 			(False, table)
   461 		  | aux (Const ("Not", _) $ x)      table =
   462 			apfst Not (aux x table)
   463 		  | aux (Const ("op |", _) $ x $ y) table =
   464 			let
   465 				val (fm1, table1) = aux x table
   466 				val (fm2, table2) = aux y table1
   467 			in
   468 				(Or (fm1, fm2), table2)
   469 			end
   470 		  | aux (Const ("op &", _) $ x $ y) table =
   471 			let
   472 				val (fm1, table1) = aux x table
   473 				val (fm2, table2) = aux y table1
   474 			in
   475 				(And (fm1, fm2), table2)
   476 			end
   477 		  | aux x                           table =
   478 			(case Termtab.lookup table x of
   479 			  SOME i =>
   480 				(BoolVar i, table)
   481 			| NONE   =>
   482 				let
   483 					val i = get_next_idx ()
   484 				in
   485 					(BoolVar i, Termtab.update (x, i) table)
   486 				end)
   487 	in
   488 		aux t table
   489 	end;
   490 
   491 (* ------------------------------------------------------------------------- *)
   492 (* term_of_prop_formula: returns a HOL term that corresponds to a            *)
   493 (*      propositional formula, with Boolean variables replaced by Free's     *)
   494 (* ------------------------------------------------------------------------- *)
   495 
   496 (* Note: A more generic implementation should take another argument of type  *)
   497 (*       Term.term Inttab.table (or so) that specifies HOL terms for some    *)
   498 (*       Boolean variables in the formula, similar to 'prop_formula_of_term' *)
   499 (*       (but the other way round).                                          *)
   500 
   501 	(* prop_formula -> Term.term *)
   502 	fun term_of_prop_formula True             =
   503 			HOLogic.true_const
   504 		| term_of_prop_formula False            =
   505 			HOLogic.false_const
   506 		| term_of_prop_formula (BoolVar i)      =
   507 			Free ("v" ^ Int.toString i, HOLogic.boolT)
   508 		| term_of_prop_formula (Not fm)         =
   509 			HOLogic.mk_not (term_of_prop_formula fm)
   510 		| term_of_prop_formula (Or (fm1, fm2))  =
   511 			HOLogic.mk_disj (term_of_prop_formula fm1, term_of_prop_formula fm2)
   512 		| term_of_prop_formula (And (fm1, fm2)) =
   513 			HOLogic.mk_conj (term_of_prop_formula fm1, term_of_prop_formula fm2);
   514 
   515 end;