src/HOL/Nat.thy
author haftmann
Thu Dec 29 10:47:55 2011 +0100 (2011-12-29)
changeset 46028 9f113cdf3d66
parent 45965 2af982715e5c
child 46350 a49c89df7c92
permissions -rw-r--r--
attribute code_abbrev superseedes code_unfold_post
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 uses
    13   "~~/src/Tools/rat.ML"
    14   "~~/src/Provers/Arith/cancel_sums.ML"
    15   "Tools/arith_data.ML"
    16   ("Tools/nat_arith.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    26   -- {* the axiom of infinity in 2 parts *}
    27   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    28   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    29 
    30 subsection {* Type nat *}
    31 
    32 text {* Type definition *}
    33 
    34 inductive Nat :: "ind \<Rightarrow> bool" where
    35   Zero_RepI: "Nat Zero_Rep"
    36 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    37 
    38 typedef (open) nat = "{n. Nat n}"
    39   morphisms Rep_Nat Abs_Nat
    40   using Nat.Zero_RepI by auto
    41 
    42 lemma Nat_Rep_Nat:
    43   "Nat (Rep_Nat n)"
    44   using Rep_Nat by simp
    45 
    46 lemma Nat_Abs_Nat_inverse:
    47   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    48   using Abs_Nat_inverse by simp
    49 
    50 lemma Nat_Abs_Nat_inject:
    51   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    52   using Abs_Nat_inject by simp
    53 
    54 instantiation nat :: zero
    55 begin
    56 
    57 definition Zero_nat_def:
    58   "0 = Abs_Nat Zero_Rep"
    59 
    60 instance ..
    61 
    62 end
    63 
    64 definition Suc :: "nat \<Rightarrow> nat" where
    65   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    66 
    67 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    68   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    74   by (rule iffI, rule Suc_Rep_inject) simp_all
    75 
    76 rep_datatype "0 \<Colon> nat" Suc
    77   apply (unfold Zero_nat_def Suc_def)
    78   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    79    apply (erule Nat_Rep_Nat [THEN Nat.induct])
    80    apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    81     apply (simp_all add: Nat_Abs_Nat_inject Nat_Rep_Nat
    82       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep
    83       Suc_Rep_not_Zero_Rep [symmetric]
    84       Suc_Rep_inject' Rep_Nat_inject)
    85   done
    86 
    87 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    88   -- {* for backward compatibility -- names of variables differ *}
    89   fixes n
    90   assumes "P 0"
    91     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    92   shows "P n"
    93   using assms by (rule nat.induct)
    94 
    95 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    96 
    97 lemmas nat_rec_0 = nat.recs(1)
    98   and nat_rec_Suc = nat.recs(2)
    99 
   100 lemmas nat_case_0 = nat.cases(1)
   101   and nat_case_Suc = nat.cases(2)
   102    
   103 
   104 text {* Injectiveness and distinctness lemmas *}
   105 
   106 lemma inj_Suc[simp]: "inj_on Suc N"
   107   by (simp add: inj_on_def)
   108 
   109 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   110 by (rule notE, rule Suc_not_Zero)
   111 
   112 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   113 by (rule Suc_neq_Zero, erule sym)
   114 
   115 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   116 by (rule inj_Suc [THEN injD])
   117 
   118 lemma n_not_Suc_n: "n \<noteq> Suc n"
   119 by (induct n) simp_all
   120 
   121 lemma Suc_n_not_n: "Suc n \<noteq> n"
   122 by (rule not_sym, rule n_not_Suc_n)
   123 
   124 text {* A special form of induction for reasoning
   125   about @{term "m < n"} and @{term "m - n"} *}
   126 
   127 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   128     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   129   apply (rule_tac x = m in spec)
   130   apply (induct n)
   131   prefer 2
   132   apply (rule allI)
   133   apply (induct_tac x, iprover+)
   134   done
   135 
   136 
   137 subsection {* Arithmetic operators *}
   138 
   139 instantiation nat :: "{minus, comm_monoid_add}"
   140 begin
   141 
   142 primrec plus_nat where
   143   add_0:      "0 + n = (n\<Colon>nat)"
   144 | add_Suc:  "Suc m + n = Suc (m + n)"
   145 
   146 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   147   by (induct m) simp_all
   148 
   149 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   150   by (induct m) simp_all
   151 
   152 declare add_0 [code]
   153 
   154 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   155   by simp
   156 
   157 primrec minus_nat where
   158   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   159 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   160 
   161 declare diff_Suc [simp del]
   162 
   163 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   164   by (induct n) (simp_all add: diff_Suc)
   165 
   166 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   167   by (induct n) (simp_all add: diff_Suc)
   168 
   169 instance proof
   170   fix n m q :: nat
   171   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   172   show "n + m = m + n" by (induct n) simp_all
   173   show "0 + n = n" by simp
   174 qed
   175 
   176 end
   177 
   178 hide_fact (open) add_0 add_0_right diff_0
   179 
   180 instantiation nat :: comm_semiring_1_cancel
   181 begin
   182 
   183 definition
   184   One_nat_def [simp, code_post]: "1 = Suc 0"
   185 
   186 primrec times_nat where
   187   mult_0:     "0 * n = (0\<Colon>nat)"
   188 | mult_Suc: "Suc m * n = n + (m * n)"
   189 
   190 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   191   by (induct m) simp_all
   192 
   193 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   194   by (induct m) (simp_all add: add_left_commute)
   195 
   196 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   197   by (induct m) (simp_all add: add_assoc)
   198 
   199 instance proof
   200   fix n m q :: nat
   201   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   202   show "1 * n = n" unfolding One_nat_def by simp
   203   show "n * m = m * n" by (induct n) simp_all
   204   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   205   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   206   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   207 qed
   208 
   209 end
   210 
   211 subsubsection {* Addition *}
   212 
   213 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   214   by (rule add_assoc)
   215 
   216 lemma nat_add_commute: "m + n = n + (m::nat)"
   217   by (rule add_commute)
   218 
   219 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   220   by (rule add_left_commute)
   221 
   222 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   223   by (rule add_left_cancel)
   224 
   225 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   226   by (rule add_right_cancel)
   227 
   228 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   229 
   230 lemma add_is_0 [iff]:
   231   fixes m n :: nat
   232   shows "(m + n = 0) = (m = 0 & n = 0)"
   233   by (cases m) simp_all
   234 
   235 lemma add_is_1:
   236   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   237   by (cases m) simp_all
   238 
   239 lemma one_is_add:
   240   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   241   by (rule trans, rule eq_commute, rule add_is_1)
   242 
   243 lemma add_eq_self_zero:
   244   fixes m n :: nat
   245   shows "m + n = m \<Longrightarrow> n = 0"
   246   by (induct m) simp_all
   247 
   248 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   249   apply (induct k)
   250    apply simp
   251   apply(drule comp_inj_on[OF _ inj_Suc])
   252   apply (simp add:o_def)
   253   done
   254 
   255 
   256 subsubsection {* Difference *}
   257 
   258 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   259   by (induct m) simp_all
   260 
   261 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   262   by (induct i j rule: diff_induct) simp_all
   263 
   264 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   265   by (simp add: diff_diff_left)
   266 
   267 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   268   by (simp add: diff_diff_left add_commute)
   269 
   270 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   271   by (induct n) simp_all
   272 
   273 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   274   by (simp add: diff_add_inverse add_commute [of m n])
   275 
   276 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   277   by (induct k) simp_all
   278 
   279 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   280   by (simp add: diff_cancel add_commute)
   281 
   282 lemma diff_add_0: "n - (n + m) = (0::nat)"
   283   by (induct n) simp_all
   284 
   285 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   286   unfolding One_nat_def by simp
   287 
   288 text {* Difference distributes over multiplication *}
   289 
   290 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   291 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   292 
   293 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   294 by (simp add: diff_mult_distrib mult_commute [of k])
   295   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   296 
   297 
   298 subsubsection {* Multiplication *}
   299 
   300 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   301   by (rule mult_assoc)
   302 
   303 lemma nat_mult_commute: "m * n = n * (m::nat)"
   304   by (rule mult_commute)
   305 
   306 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   307   by (rule right_distrib)
   308 
   309 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   310   by (induct m) auto
   311 
   312 lemmas nat_distrib =
   313   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   314 
   315 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   316   apply (induct m)
   317    apply simp
   318   apply (induct n)
   319    apply auto
   320   done
   321 
   322 lemma one_eq_mult_iff [simp,no_atp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   323   apply (rule trans)
   324   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   325   done
   326 
   327 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   328   unfolding One_nat_def by (rule mult_eq_1_iff)
   329 
   330 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   331   unfolding One_nat_def by (rule one_eq_mult_iff)
   332 
   333 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   334 proof -
   335   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   336   proof (induct n arbitrary: m)
   337     case 0 then show "m = 0" by simp
   338   next
   339     case (Suc n) then show "m = Suc n"
   340       by (cases m) (simp_all add: eq_commute [of "0"])
   341   qed
   342   then show ?thesis by auto
   343 qed
   344 
   345 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   346   by (simp add: mult_commute)
   347 
   348 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   349   by (subst mult_cancel1) simp
   350 
   351 
   352 subsection {* Orders on @{typ nat} *}
   353 
   354 subsubsection {* Operation definition *}
   355 
   356 instantiation nat :: linorder
   357 begin
   358 
   359 primrec less_eq_nat where
   360   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   361 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   362 
   363 declare less_eq_nat.simps [simp del]
   364 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   365 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   366 
   367 definition less_nat where
   368   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   369 
   370 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   371   by (simp add: less_eq_nat.simps(2))
   372 
   373 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   374   unfolding less_eq_Suc_le ..
   375 
   376 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   377   by (induct n) (simp_all add: less_eq_nat.simps(2))
   378 
   379 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   380   by (simp add: less_eq_Suc_le)
   381 
   382 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   383   by simp
   384 
   385 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   386   by (simp add: less_eq_Suc_le)
   387 
   388 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   389   by (simp add: less_eq_Suc_le)
   390 
   391 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   392   by (induct m arbitrary: n)
   393     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   394 
   395 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   396   by (cases n) (auto intro: le_SucI)
   397 
   398 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   399   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   400 
   401 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   402   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   403 
   404 instance
   405 proof
   406   fix n m :: nat
   407   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   408   proof (induct n arbitrary: m)
   409     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   410   next
   411     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   412   qed
   413 next
   414   fix n :: nat show "n \<le> n" by (induct n) simp_all
   415 next
   416   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   417   then show "n = m"
   418     by (induct n arbitrary: m)
   419       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   420 next
   421   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   422   then show "n \<le> q"
   423   proof (induct n arbitrary: m q)
   424     case 0 show ?case by simp
   425   next
   426     case (Suc n) then show ?case
   427       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   428         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   429         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   430   qed
   431 next
   432   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   433     by (induct n arbitrary: m)
   434       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   435 qed
   436 
   437 end
   438 
   439 instantiation nat :: bot
   440 begin
   441 
   442 definition bot_nat :: nat where
   443   "bot_nat = 0"
   444 
   445 instance proof
   446 qed (simp add: bot_nat_def)
   447 
   448 end
   449 
   450 subsubsection {* Introduction properties *}
   451 
   452 lemma lessI [iff]: "n < Suc n"
   453   by (simp add: less_Suc_eq_le)
   454 
   455 lemma zero_less_Suc [iff]: "0 < Suc n"
   456   by (simp add: less_Suc_eq_le)
   457 
   458 
   459 subsubsection {* Elimination properties *}
   460 
   461 lemma less_not_refl: "~ n < (n::nat)"
   462   by (rule order_less_irrefl)
   463 
   464 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   465   by (rule not_sym) (rule less_imp_neq) 
   466 
   467 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   468   by (rule less_imp_neq)
   469 
   470 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   471   by (rule notE, rule less_not_refl)
   472 
   473 lemma less_zeroE: "(n::nat) < 0 ==> R"
   474   by (rule notE) (rule not_less0)
   475 
   476 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   477   unfolding less_Suc_eq_le le_less ..
   478 
   479 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   480   by (simp add: less_Suc_eq)
   481 
   482 lemma less_one [iff, no_atp]: "(n < (1::nat)) = (n = 0)"
   483   unfolding One_nat_def by (rule less_Suc0)
   484 
   485 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   486   by simp
   487 
   488 text {* "Less than" is antisymmetric, sort of *}
   489 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   490   unfolding not_less less_Suc_eq_le by (rule antisym)
   491 
   492 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   493   by (rule linorder_neq_iff)
   494 
   495 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   496   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   497   shows "P n m"
   498   apply (rule less_linear [THEN disjE])
   499   apply (erule_tac [2] disjE)
   500   apply (erule lessCase)
   501   apply (erule sym [THEN eqCase])
   502   apply (erule major)
   503   done
   504 
   505 
   506 subsubsection {* Inductive (?) properties *}
   507 
   508 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   509   unfolding less_eq_Suc_le [of m] le_less by simp 
   510 
   511 lemma lessE:
   512   assumes major: "i < k"
   513   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   514   shows P
   515 proof -
   516   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   517     unfolding less_eq_Suc_le by (induct k) simp_all
   518   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   519     by (clarsimp simp add: less_le)
   520   with p1 p2 show P by auto
   521 qed
   522 
   523 lemma less_SucE: assumes major: "m < Suc n"
   524   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   525   apply (rule major [THEN lessE])
   526   apply (rule eq, blast)
   527   apply (rule less, blast)
   528   done
   529 
   530 lemma Suc_lessE: assumes major: "Suc i < k"
   531   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   532   apply (rule major [THEN lessE])
   533   apply (erule lessI [THEN minor])
   534   apply (erule Suc_lessD [THEN minor], assumption)
   535   done
   536 
   537 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   538   by simp
   539 
   540 lemma less_trans_Suc:
   541   assumes le: "i < j" shows "j < k ==> Suc i < k"
   542   apply (induct k, simp_all)
   543   apply (insert le)
   544   apply (simp add: less_Suc_eq)
   545   apply (blast dest: Suc_lessD)
   546   done
   547 
   548 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   549 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   550   unfolding not_less less_Suc_eq_le ..
   551 
   552 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   553   unfolding not_le Suc_le_eq ..
   554 
   555 text {* Properties of "less than or equal" *}
   556 
   557 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   558   unfolding less_Suc_eq_le .
   559 
   560 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   561   unfolding not_le less_Suc_eq_le ..
   562 
   563 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   564   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   565 
   566 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   567   by (drule le_Suc_eq [THEN iffD1], iprover+)
   568 
   569 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   570   unfolding Suc_le_eq .
   571 
   572 text {* Stronger version of @{text Suc_leD} *}
   573 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   574   unfolding Suc_le_eq .
   575 
   576 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   577   unfolding less_eq_Suc_le by (rule Suc_leD)
   578 
   579 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   580 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   581 
   582 
   583 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   584 
   585 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   586   unfolding le_less .
   587 
   588 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   589   by (rule le_less)
   590 
   591 text {* Useful with @{text blast}. *}
   592 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   593   by auto
   594 
   595 lemma le_refl: "n \<le> (n::nat)"
   596   by simp
   597 
   598 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   599   by (rule order_trans)
   600 
   601 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   602   by (rule antisym)
   603 
   604 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   605   by (rule less_le)
   606 
   607 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   608   unfolding less_le ..
   609 
   610 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   611   by (rule linear)
   612 
   613 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   614 
   615 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   616   unfolding less_Suc_eq_le by auto
   617 
   618 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   619   unfolding not_less by (rule le_less_Suc_eq)
   620 
   621 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   622 
   623 text {* These two rules ease the use of primitive recursion.
   624 NOTE USE OF @{text "=="} *}
   625 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   626 by simp
   627 
   628 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   629 by simp
   630 
   631 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   632 by (cases n) simp_all
   633 
   634 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   635 by (cases n) simp_all
   636 
   637 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   638 by (cases n) simp_all
   639 
   640 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   641 by (cases n) simp_all
   642 
   643 text {* This theorem is useful with @{text blast} *}
   644 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   645 by (rule neq0_conv[THEN iffD1], iprover)
   646 
   647 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   648 by (fast intro: not0_implies_Suc)
   649 
   650 lemma not_gr0 [iff,no_atp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   651 using neq0_conv by blast
   652 
   653 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   654 by (induct m') simp_all
   655 
   656 text {* Useful in certain inductive arguments *}
   657 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   658 by (cases m) simp_all
   659 
   660 
   661 subsubsection {* Monotonicity of Addition *}
   662 
   663 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   664 by (simp add: diff_Suc split: nat.split)
   665 
   666 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   667 unfolding One_nat_def by (rule Suc_pred)
   668 
   669 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   670 by (induct k) simp_all
   671 
   672 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   673 by (induct k) simp_all
   674 
   675 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   676 by(auto dest:gr0_implies_Suc)
   677 
   678 text {* strict, in 1st argument *}
   679 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   680 by (induct k) simp_all
   681 
   682 text {* strict, in both arguments *}
   683 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   684   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   685   apply (induct j, simp_all)
   686   done
   687 
   688 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   689 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   690   apply (induct n)
   691   apply (simp_all add: order_le_less)
   692   apply (blast elim!: less_SucE
   693                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   694   done
   695 
   696 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   697 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   698 apply(auto simp: gr0_conv_Suc)
   699 apply (induct_tac m)
   700 apply (simp_all add: add_less_mono)
   701 done
   702 
   703 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   704 instance nat :: linordered_semidom
   705 proof
   706   fix i j k :: nat
   707   show "0 < (1::nat)" by simp
   708   show "i \<le> j ==> k + i \<le> k + j" by simp
   709   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   710 qed
   711 
   712 instance nat :: no_zero_divisors
   713 proof
   714   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   715 qed
   716 
   717 
   718 subsubsection {* @{term min} and @{term max} *}
   719 
   720 lemma mono_Suc: "mono Suc"
   721 by (rule monoI) simp
   722 
   723 lemma min_0L [simp]: "min 0 n = (0::nat)"
   724 by (rule min_absorb1) simp
   725 
   726 lemma min_0R [simp]: "min n 0 = (0::nat)"
   727 by (rule min_absorb2) simp
   728 
   729 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   730 by (simp add: mono_Suc min_of_mono)
   731 
   732 lemma min_Suc1:
   733    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   734 by (simp split: nat.split)
   735 
   736 lemma min_Suc2:
   737    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   738 by (simp split: nat.split)
   739 
   740 lemma max_0L [simp]: "max 0 n = (n::nat)"
   741 by (rule max_absorb2) simp
   742 
   743 lemma max_0R [simp]: "max n 0 = (n::nat)"
   744 by (rule max_absorb1) simp
   745 
   746 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   747 by (simp add: mono_Suc max_of_mono)
   748 
   749 lemma max_Suc1:
   750    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   751 by (simp split: nat.split)
   752 
   753 lemma max_Suc2:
   754    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   755 by (simp split: nat.split)
   756 
   757 lemma nat_mult_min_left:
   758   fixes m n q :: nat
   759   shows "min m n * q = min (m * q) (n * q)"
   760   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   761 
   762 lemma nat_mult_min_right:
   763   fixes m n q :: nat
   764   shows "m * min n q = min (m * n) (m * q)"
   765   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   766 
   767 lemma nat_add_max_left:
   768   fixes m n q :: nat
   769   shows "max m n + q = max (m + q) (n + q)"
   770   by (simp add: max_def)
   771 
   772 lemma nat_add_max_right:
   773   fixes m n q :: nat
   774   shows "m + max n q = max (m + n) (m + q)"
   775   by (simp add: max_def)
   776 
   777 lemma nat_mult_max_left:
   778   fixes m n q :: nat
   779   shows "max m n * q = max (m * q) (n * q)"
   780   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   781 
   782 lemma nat_mult_max_right:
   783   fixes m n q :: nat
   784   shows "m * max n q = max (m * n) (m * q)"
   785   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   786 
   787 
   788 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   789 
   790 text {* Complete induction, aka course-of-values induction *}
   791 
   792 instance nat :: wellorder proof
   793   fix P and n :: nat
   794   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   795   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   796   proof (induct n)
   797     case (0 n)
   798     have "P 0" by (rule step) auto
   799     thus ?case using 0 by auto
   800   next
   801     case (Suc m n)
   802     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   803     thus ?case
   804     proof
   805       assume "n \<le> m" thus "P n" by (rule Suc(1))
   806     next
   807       assume n: "n = Suc m"
   808       show "P n"
   809         by (rule step) (rule Suc(1), simp add: n le_simps)
   810     qed
   811   qed
   812   then show "P n" by auto
   813 qed
   814 
   815 lemma Least_Suc:
   816      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   817   apply (case_tac "n", auto)
   818   apply (frule LeastI)
   819   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   820   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   821   apply (erule_tac [2] Least_le)
   822   apply (case_tac "LEAST x. P x", auto)
   823   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   824   apply (blast intro: order_antisym)
   825   done
   826 
   827 lemma Least_Suc2:
   828    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   829   apply (erule (1) Least_Suc [THEN ssubst])
   830   apply simp
   831   done
   832 
   833 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   834   apply (cases n)
   835    apply blast
   836   apply (rule_tac x="LEAST k. P(k)" in exI)
   837   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   838   done
   839 
   840 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   841   unfolding One_nat_def
   842   apply (cases n)
   843    apply blast
   844   apply (frule (1) ex_least_nat_le)
   845   apply (erule exE)
   846   apply (case_tac k)
   847    apply simp
   848   apply (rename_tac k1)
   849   apply (rule_tac x=k1 in exI)
   850   apply (auto simp add: less_eq_Suc_le)
   851   done
   852 
   853 lemma nat_less_induct:
   854   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   855   using assms less_induct by blast
   856 
   857 lemma measure_induct_rule [case_names less]:
   858   fixes f :: "'a \<Rightarrow> nat"
   859   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   860   shows "P a"
   861 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   862 
   863 text {* old style induction rules: *}
   864 lemma measure_induct:
   865   fixes f :: "'a \<Rightarrow> nat"
   866   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   867   by (rule measure_induct_rule [of f P a]) iprover
   868 
   869 lemma full_nat_induct:
   870   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   871   shows "P n"
   872   by (rule less_induct) (auto intro: step simp:le_simps)
   873 
   874 text{*An induction rule for estabilishing binary relations*}
   875 lemma less_Suc_induct:
   876   assumes less:  "i < j"
   877      and  step:  "!!i. P i (Suc i)"
   878      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   879   shows "P i j"
   880 proof -
   881   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   882   have "P i (Suc (i + k))"
   883   proof (induct k)
   884     case 0
   885     show ?case by (simp add: step)
   886   next
   887     case (Suc k)
   888     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   889     hence "i < Suc (i + k)" by (simp add: add_commute)
   890     from trans[OF this lessI Suc step]
   891     show ?case by simp
   892   qed
   893   thus "P i j" by (simp add: j)
   894 qed
   895 
   896 text {* The method of infinite descent, frequently used in number theory.
   897 Provided by Roelof Oosterhuis.
   898 $P(n)$ is true for all $n\in\mathbb{N}$ if
   899 \begin{itemize}
   900   \item case ``0'': given $n=0$ prove $P(n)$,
   901   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   902         a smaller integer $m$ such that $\neg P(m)$.
   903 \end{itemize} *}
   904 
   905 text{* A compact version without explicit base case: *}
   906 lemma infinite_descent:
   907   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   908 by (induct n rule: less_induct, auto)
   909 
   910 lemma infinite_descent0[case_names 0 smaller]: 
   911   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   912 by (rule infinite_descent) (case_tac "n>0", auto)
   913 
   914 text {*
   915 Infinite descent using a mapping to $\mathbb{N}$:
   916 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   917 \begin{itemize}
   918 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   919 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   920 \end{itemize}
   921 NB: the proof also shows how to use the previous lemma. *}
   922 
   923 corollary infinite_descent0_measure [case_names 0 smaller]:
   924   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   925     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   926   shows "P x"
   927 proof -
   928   obtain n where "n = V x" by auto
   929   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   930   proof (induct n rule: infinite_descent0)
   931     case 0 -- "i.e. $V(x) = 0$"
   932     with A0 show "P x" by auto
   933   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   934     case (smaller n)
   935     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   936     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   937     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   938     then show ?case by auto
   939   qed
   940   ultimately show "P x" by auto
   941 qed
   942 
   943 text{* Again, without explicit base case: *}
   944 lemma infinite_descent_measure:
   945 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   946 proof -
   947   from assms obtain n where "n = V x" by auto
   948   moreover have "!!x. V x = n \<Longrightarrow> P x"
   949   proof (induct n rule: infinite_descent, auto)
   950     fix x assume "\<not> P x"
   951     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   952   qed
   953   ultimately show "P x" by auto
   954 qed
   955 
   956 text {* A [clumsy] way of lifting @{text "<"}
   957   monotonicity to @{text "\<le>"} monotonicity *}
   958 lemma less_mono_imp_le_mono:
   959   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   960 by (simp add: order_le_less) (blast)
   961 
   962 
   963 text {* non-strict, in 1st argument *}
   964 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   965 by (rule add_right_mono)
   966 
   967 text {* non-strict, in both arguments *}
   968 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   969 by (rule add_mono)
   970 
   971 lemma le_add2: "n \<le> ((m + n)::nat)"
   972 by (insert add_right_mono [of 0 m n], simp)
   973 
   974 lemma le_add1: "n \<le> ((n + m)::nat)"
   975 by (simp add: add_commute, rule le_add2)
   976 
   977 lemma less_add_Suc1: "i < Suc (i + m)"
   978 by (rule le_less_trans, rule le_add1, rule lessI)
   979 
   980 lemma less_add_Suc2: "i < Suc (m + i)"
   981 by (rule le_less_trans, rule le_add2, rule lessI)
   982 
   983 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   984 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   985 
   986 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   987 by (rule le_trans, assumption, rule le_add1)
   988 
   989 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   990 by (rule le_trans, assumption, rule le_add2)
   991 
   992 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   993 by (rule less_le_trans, assumption, rule le_add1)
   994 
   995 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   996 by (rule less_le_trans, assumption, rule le_add2)
   997 
   998 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   999 apply (rule le_less_trans [of _ "i+j"])
  1000 apply (simp_all add: le_add1)
  1001 done
  1002 
  1003 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1004 apply (rule notI)
  1005 apply (drule add_lessD1)
  1006 apply (erule less_irrefl [THEN notE])
  1007 done
  1008 
  1009 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1010 by (simp add: add_commute)
  1011 
  1012 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1013 apply (rule order_trans [of _ "m+k"])
  1014 apply (simp_all add: le_add1)
  1015 done
  1016 
  1017 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1018 apply (simp add: add_commute)
  1019 apply (erule add_leD1)
  1020 done
  1021 
  1022 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1023 by (blast dest: add_leD1 add_leD2)
  1024 
  1025 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1026 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1027 by (force simp del: add_Suc_right
  1028     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1029 
  1030 
  1031 subsubsection {* More results about difference *}
  1032 
  1033 text {* Addition is the inverse of subtraction:
  1034   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1035 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1036 by (induct m n rule: diff_induct) simp_all
  1037 
  1038 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1039 by (simp add: add_diff_inverse linorder_not_less)
  1040 
  1041 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1042 by (simp add: add_commute)
  1043 
  1044 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1045 by (induct m n rule: diff_induct) simp_all
  1046 
  1047 lemma diff_less_Suc: "m - n < Suc m"
  1048 apply (induct m n rule: diff_induct)
  1049 apply (erule_tac [3] less_SucE)
  1050 apply (simp_all add: less_Suc_eq)
  1051 done
  1052 
  1053 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1054 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1055 
  1056 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1057   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1058 
  1059 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1060 by (rule le_less_trans, rule diff_le_self)
  1061 
  1062 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1063 by (cases n) (auto simp add: le_simps)
  1064 
  1065 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1066 by (induct j k rule: diff_induct) simp_all
  1067 
  1068 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1069 by (simp add: add_commute diff_add_assoc)
  1070 
  1071 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1072 by (auto simp add: diff_add_inverse2)
  1073 
  1074 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1075 by (induct m n rule: diff_induct) simp_all
  1076 
  1077 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1078 by (rule iffD2, rule diff_is_0_eq)
  1079 
  1080 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1081 by (induct m n rule: diff_induct) simp_all
  1082 
  1083 lemma less_imp_add_positive:
  1084   assumes "i < j"
  1085   shows "\<exists>k::nat. 0 < k & i + k = j"
  1086 proof
  1087   from assms show "0 < j - i & i + (j - i) = j"
  1088     by (simp add: order_less_imp_le)
  1089 qed
  1090 
  1091 text {* a nice rewrite for bounded subtraction *}
  1092 lemma nat_minus_add_max:
  1093   fixes n m :: nat
  1094   shows "n - m + m = max n m"
  1095     by (simp add: max_def not_le order_less_imp_le)
  1096 
  1097 lemma nat_diff_split:
  1098   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1099     -- {* elimination of @{text -} on @{text nat} *}
  1100 by (cases "a < b")
  1101   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1102     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1103 
  1104 lemma nat_diff_split_asm:
  1105   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1106     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1107 by (auto split: nat_diff_split)
  1108 
  1109 
  1110 subsubsection {* Monotonicity of Multiplication *}
  1111 
  1112 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1113 by (simp add: mult_right_mono)
  1114 
  1115 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1116 by (simp add: mult_left_mono)
  1117 
  1118 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1119 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1120 by (simp add: mult_mono)
  1121 
  1122 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1123 by (simp add: mult_strict_right_mono)
  1124 
  1125 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1126       there are no negative numbers.*}
  1127 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1128   apply (induct m)
  1129    apply simp
  1130   apply (case_tac n)
  1131    apply simp_all
  1132   done
  1133 
  1134 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1135   apply (induct m)
  1136    apply simp
  1137   apply (case_tac n)
  1138    apply simp_all
  1139   done
  1140 
  1141 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1142   apply (safe intro!: mult_less_mono1)
  1143   apply (case_tac k, auto)
  1144   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1145   apply (blast intro: mult_le_mono1)
  1146   done
  1147 
  1148 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1149 by (simp add: mult_commute [of k])
  1150 
  1151 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1152 by (simp add: linorder_not_less [symmetric], auto)
  1153 
  1154 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1155 by (simp add: linorder_not_less [symmetric], auto)
  1156 
  1157 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1158 by (subst mult_less_cancel1) simp
  1159 
  1160 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1161 by (subst mult_le_cancel1) simp
  1162 
  1163 lemma le_square: "m \<le> m * (m::nat)"
  1164   by (cases m) (auto intro: le_add1)
  1165 
  1166 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1167   by (cases m) (auto intro: le_add1)
  1168 
  1169 text {* Lemma for @{text gcd} *}
  1170 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1171   apply (drule sym)
  1172   apply (rule disjCI)
  1173   apply (rule nat_less_cases, erule_tac [2] _)
  1174    apply (drule_tac [2] mult_less_mono2)
  1175     apply (auto)
  1176   done
  1177 
  1178 text {* the lattice order on @{typ nat} *}
  1179 
  1180 instantiation nat :: distrib_lattice
  1181 begin
  1182 
  1183 definition
  1184   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1185 
  1186 definition
  1187   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1188 
  1189 instance by intro_classes
  1190   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1191     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1192 
  1193 end
  1194 
  1195 
  1196 subsection {* Natural operation of natural numbers on functions *}
  1197 
  1198 text {*
  1199   We use the same logical constant for the power operations on
  1200   functions and relations, in order to share the same syntax.
  1201 *}
  1202 
  1203 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1204 
  1205 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1206   "f ^^ n \<equiv> compow n f"
  1207 
  1208 notation (latex output)
  1209   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1210 
  1211 notation (HTML output)
  1212   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1213 
  1214 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1215 
  1216 overloading
  1217   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1218 begin
  1219 
  1220 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1221   "funpow 0 f = id"
  1222 | "funpow (Suc n) f = f o funpow n f"
  1223 
  1224 end
  1225 
  1226 text {* for code generation *}
  1227 
  1228 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1229   funpow_code_def [code_abbrev]: "funpow = compow"
  1230 
  1231 lemma [code]:
  1232   "funpow (Suc n) f = f o funpow n f"
  1233   "funpow 0 f = id"
  1234   by (simp_all add: funpow_code_def)
  1235 
  1236 hide_const (open) funpow
  1237 
  1238 lemma funpow_add:
  1239   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1240   by (induct m) simp_all
  1241 
  1242 lemma funpow_mult:
  1243   fixes f :: "'a \<Rightarrow> 'a"
  1244   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1245   by (induct n) (simp_all add: funpow_add)
  1246 
  1247 lemma funpow_swap1:
  1248   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1249 proof -
  1250   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1251   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1252   also have "\<dots> = (f ^^ n) (f x)" by simp
  1253   finally show ?thesis .
  1254 qed
  1255 
  1256 lemma comp_funpow:
  1257   fixes f :: "'a \<Rightarrow> 'a"
  1258   shows "comp f ^^ n = comp (f ^^ n)"
  1259   by (induct n) simp_all
  1260 
  1261 
  1262 subsection {* Kleene iteration *}
  1263 
  1264 lemma Kleene_iter_lpfp: assumes "mono f" and "f p \<le> p" shows "(f^^k) bot \<le> p"
  1265 proof(induction k)
  1266   case 0 show ?case by simp
  1267 next
  1268   case Suc
  1269   from monoD[OF assms(1) Suc] assms(2)
  1270   show ?case by simp
  1271 qed
  1272 
  1273 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1274 shows "lfp f = (f^^k) bot"
  1275 proof(rule antisym)
  1276   show "lfp f \<le> (f^^k) bot"
  1277   proof(rule lfp_lowerbound)
  1278     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1279   qed
  1280 next
  1281   show "(f^^k) bot \<le> lfp f"
  1282     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1283 qed
  1284 
  1285 
  1286 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1287 
  1288 context semiring_1
  1289 begin
  1290 
  1291 definition of_nat :: "nat \<Rightarrow> 'a" where
  1292   "of_nat n = (plus 1 ^^ n) 0"
  1293 
  1294 lemma of_nat_simps [simp]:
  1295   shows of_nat_0: "of_nat 0 = 0"
  1296     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1297   by (simp_all add: of_nat_def)
  1298 
  1299 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1300   by (simp add: of_nat_def)
  1301 
  1302 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1303   by (induct m) (simp_all add: add_ac)
  1304 
  1305 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1306   by (induct m) (simp_all add: add_ac left_distrib)
  1307 
  1308 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1309   "of_nat_aux inc 0 i = i"
  1310 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1311 
  1312 lemma of_nat_code:
  1313   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1314 proof (induct n)
  1315   case 0 then show ?case by simp
  1316 next
  1317   case (Suc n)
  1318   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1319     by (induct n) simp_all
  1320   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1321     by simp
  1322   with Suc show ?case by (simp add: add_commute)
  1323 qed
  1324 
  1325 end
  1326 
  1327 declare of_nat_code [code]
  1328 
  1329 text{*Class for unital semirings with characteristic zero.
  1330  Includes non-ordered rings like the complex numbers.*}
  1331 
  1332 class semiring_char_0 = semiring_1 +
  1333   assumes inj_of_nat: "inj of_nat"
  1334 begin
  1335 
  1336 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1337   by (auto intro: inj_of_nat injD)
  1338 
  1339 text{*Special cases where either operand is zero*}
  1340 
  1341 lemma of_nat_0_eq_iff [simp, no_atp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1342   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1343 
  1344 lemma of_nat_eq_0_iff [simp, no_atp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1345   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1346 
  1347 end
  1348 
  1349 context linordered_semidom
  1350 begin
  1351 
  1352 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1353   by (induct m) simp_all
  1354 
  1355 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1356   apply (induct m n rule: diff_induct, simp_all)
  1357   apply (rule add_pos_nonneg [OF zero_less_one zero_le_imp_of_nat])
  1358   done
  1359 
  1360 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1361   apply (induct m n rule: diff_induct, simp_all)
  1362   apply (insert zero_le_imp_of_nat)
  1363   apply (force simp add: not_less [symmetric])
  1364   done
  1365 
  1366 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1367   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1368 
  1369 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1370   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1371 
  1372 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1373 
  1374 subclass semiring_char_0 proof
  1375 qed (auto intro!: injI simp add: eq_iff)
  1376 
  1377 text{*Special cases where either operand is zero*}
  1378 
  1379 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1380   by (rule of_nat_le_iff [of 0, simplified])
  1381 
  1382 lemma of_nat_le_0_iff [simp, no_atp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1383   by (rule of_nat_le_iff [of _ 0, simplified])
  1384 
  1385 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1386   by (rule of_nat_less_iff [of 0, simplified])
  1387 
  1388 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1389   by (rule of_nat_less_iff [of _ 0, simplified])
  1390 
  1391 end
  1392 
  1393 context ring_1
  1394 begin
  1395 
  1396 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1397 by (simp add: algebra_simps of_nat_add [symmetric])
  1398 
  1399 end
  1400 
  1401 context linordered_idom
  1402 begin
  1403 
  1404 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1405   unfolding abs_if by auto
  1406 
  1407 end
  1408 
  1409 lemma of_nat_id [simp]: "of_nat n = n"
  1410   by (induct n) simp_all
  1411 
  1412 lemma of_nat_eq_id [simp]: "of_nat = id"
  1413   by (auto simp add: fun_eq_iff)
  1414 
  1415 
  1416 subsection {* The Set of Natural Numbers *}
  1417 
  1418 context semiring_1
  1419 begin
  1420 
  1421 definition Nats  :: "'a set" where
  1422   "Nats = range of_nat"
  1423 
  1424 notation (xsymbols)
  1425   Nats  ("\<nat>")
  1426 
  1427 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1428   by (simp add: Nats_def)
  1429 
  1430 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1431 apply (simp add: Nats_def)
  1432 apply (rule range_eqI)
  1433 apply (rule of_nat_0 [symmetric])
  1434 done
  1435 
  1436 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1437 apply (simp add: Nats_def)
  1438 apply (rule range_eqI)
  1439 apply (rule of_nat_1 [symmetric])
  1440 done
  1441 
  1442 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1443 apply (auto simp add: Nats_def)
  1444 apply (rule range_eqI)
  1445 apply (rule of_nat_add [symmetric])
  1446 done
  1447 
  1448 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1449 apply (auto simp add: Nats_def)
  1450 apply (rule range_eqI)
  1451 apply (rule of_nat_mult [symmetric])
  1452 done
  1453 
  1454 lemma Nats_cases [cases set: Nats]:
  1455   assumes "x \<in> \<nat>"
  1456   obtains (of_nat) n where "x = of_nat n"
  1457   unfolding Nats_def
  1458 proof -
  1459   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1460   then obtain n where "x = of_nat n" ..
  1461   then show thesis ..
  1462 qed
  1463 
  1464 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1465   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1466   by (rule Nats_cases) auto
  1467 
  1468 end
  1469 
  1470 
  1471 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1472 
  1473 lemma subst_equals:
  1474   assumes 1: "t = s" and 2: "u = t"
  1475   shows "u = s"
  1476   using 2 1 by (rule trans)
  1477 
  1478 setup Arith_Data.setup
  1479 
  1480 use "Tools/nat_arith.ML"
  1481 declaration {* K Nat_Arith.setup *}
  1482 
  1483 use "Tools/lin_arith.ML"
  1484 setup {* Lin_Arith.global_setup *}
  1485 declaration {* K Lin_Arith.setup *}
  1486 
  1487 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1488   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1489 (* Because of this simproc, the arithmetic solver is really only
  1490 useful to detect inconsistencies among the premises for subgoals which are
  1491 *not* themselves (in)equalities, because the latter activate
  1492 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1493 solver all the time rather than add the additional check. *)
  1494 
  1495 
  1496 lemmas [arith_split] = nat_diff_split split_min split_max
  1497 
  1498 context order
  1499 begin
  1500 
  1501 lemma lift_Suc_mono_le:
  1502   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1503   shows "f n \<le> f n'"
  1504 proof (cases "n < n'")
  1505   case True
  1506   thus ?thesis
  1507     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1508 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1509 
  1510 lemma lift_Suc_mono_less:
  1511   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1512   shows "f n < f n'"
  1513 using `n < n'`
  1514 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1515 
  1516 lemma lift_Suc_mono_less_iff:
  1517   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1518 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1519          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1520 
  1521 end
  1522 
  1523 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1524   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1525 
  1526 lemma mono_nat_linear_lb:
  1527   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1528 apply(induct_tac k)
  1529  apply simp
  1530 apply(erule_tac x="m+n" in meta_allE)
  1531 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1532 apply simp
  1533 done
  1534 
  1535 
  1536 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1537 
  1538 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1539 by arith
  1540 
  1541 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1542 by arith
  1543 
  1544 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1545 by arith
  1546 
  1547 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1548 by arith
  1549 
  1550 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1551 by arith
  1552 
  1553 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1554 by arith
  1555 
  1556 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1557   second premise n\<le>m*)
  1558 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1559 by arith
  1560 
  1561 text {* Simplification of relational expressions involving subtraction *}
  1562 
  1563 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1564 by (simp split add: nat_diff_split)
  1565 
  1566 hide_fact (open) diff_diff_eq
  1567 
  1568 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1569 by (auto split add: nat_diff_split)
  1570 
  1571 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1572 by (auto split add: nat_diff_split)
  1573 
  1574 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1575 by (auto split add: nat_diff_split)
  1576 
  1577 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1578 
  1579 (* Monotonicity of subtraction in first argument *)
  1580 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1581 by (simp split add: nat_diff_split)
  1582 
  1583 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1584 by (simp split add: nat_diff_split)
  1585 
  1586 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1587 by (simp split add: nat_diff_split)
  1588 
  1589 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1590 by (simp split add: nat_diff_split)
  1591 
  1592 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1593 by auto
  1594 
  1595 lemma inj_on_diff_nat: 
  1596   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1597   shows "inj_on (\<lambda>n. n - k) N"
  1598 proof (rule inj_onI)
  1599   fix x y
  1600   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1601   with k_le_n have "x - k + k = y - k + k" by auto
  1602   with a k_le_n show "x = y" by auto
  1603 qed
  1604 
  1605 text{*Rewriting to pull differences out*}
  1606 
  1607 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1608 by arith
  1609 
  1610 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1611 by arith
  1612 
  1613 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1614 by arith
  1615 
  1616 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1617 by simp
  1618 
  1619 text{*Lemmas for ex/Factorization*}
  1620 
  1621 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1622 by (cases m) auto
  1623 
  1624 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1625 by (cases m) auto
  1626 
  1627 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1628 by (cases m) auto
  1629 
  1630 text {* Specialized induction principles that work "backwards": *}
  1631 
  1632 lemma inc_induct[consumes 1, case_names base step]:
  1633   assumes less: "i <= j"
  1634   assumes base: "P j"
  1635   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1636   shows "P i"
  1637   using less
  1638 proof (induct d=="j - i" arbitrary: i)
  1639   case (0 i)
  1640   hence "i = j" by simp
  1641   with base show ?case by simp
  1642 next
  1643   case (Suc d i)
  1644   hence "i < j" "P (Suc i)"
  1645     by simp_all
  1646   thus "P i" by (rule step)
  1647 qed
  1648 
  1649 lemma strict_inc_induct[consumes 1, case_names base step]:
  1650   assumes less: "i < j"
  1651   assumes base: "!!i. j = Suc i ==> P i"
  1652   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1653   shows "P i"
  1654   using less
  1655 proof (induct d=="j - i - 1" arbitrary: i)
  1656   case (0 i)
  1657   with `i < j` have "j = Suc i" by simp
  1658   with base show ?case by simp
  1659 next
  1660   case (Suc d i)
  1661   hence "i < j" "P (Suc i)"
  1662     by simp_all
  1663   thus "P i" by (rule step)
  1664 qed
  1665 
  1666 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1667   using inc_induct[of "k - i" k P, simplified] by blast
  1668 
  1669 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1670   using inc_induct[of 0 k P] by blast
  1671 
  1672 (*The others are
  1673       i - j - k = i - (j + k),
  1674       k \<le> j ==> j - k + i = j + i - k,
  1675       k \<le> j ==> i + (j - k) = i + j - k *)
  1676 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1677 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1678 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1679 
  1680 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1681 Least_Suc}, since there appears to be no need.*}
  1682 
  1683 
  1684 subsection {* The divides relation on @{typ nat} *}
  1685 
  1686 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1687 unfolding dvd_def by simp
  1688 
  1689 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1690 by (simp add: dvd_def)
  1691 
  1692 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1693 by (simp add: dvd_def)
  1694 
  1695 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1696   unfolding dvd_def
  1697   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1698 
  1699 text {* @{term "op dvd"} is a partial order *}
  1700 
  1701 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1702   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1703 
  1704 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1705 unfolding dvd_def
  1706 by (blast intro: diff_mult_distrib2 [symmetric])
  1707 
  1708 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1709   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1710   apply (blast intro: dvd_add)
  1711   done
  1712 
  1713 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1714 by (drule_tac m = m in dvd_diff_nat, auto)
  1715 
  1716 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1717   apply (rule iffI)
  1718    apply (erule_tac [2] dvd_add)
  1719    apply (rule_tac [2] dvd_refl)
  1720   apply (subgoal_tac "n = (n+k) -k")
  1721    prefer 2 apply simp
  1722   apply (erule ssubst)
  1723   apply (erule dvd_diff_nat)
  1724   apply (rule dvd_refl)
  1725   done
  1726 
  1727 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1728   unfolding dvd_def
  1729   apply (erule exE)
  1730   apply (simp add: mult_ac)
  1731   done
  1732 
  1733 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1734   apply auto
  1735    apply (subgoal_tac "m*n dvd m*1")
  1736    apply (drule dvd_mult_cancel, auto)
  1737   done
  1738 
  1739 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1740   apply (subst mult_commute)
  1741   apply (erule dvd_mult_cancel1)
  1742   done
  1743 
  1744 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1745 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1746 
  1747 lemma nat_dvd_not_less:
  1748   fixes m n :: nat
  1749   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1750 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1751 
  1752 
  1753 subsection {* aliasses *}
  1754 
  1755 lemma nat_mult_1: "(1::nat) * n = n"
  1756   by simp
  1757  
  1758 lemma nat_mult_1_right: "n * (1::nat) = n"
  1759   by simp
  1760 
  1761 
  1762 subsection {* size of a datatype value *}
  1763 
  1764 class size =
  1765   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1766 
  1767 
  1768 subsection {* code module namespace *}
  1769 
  1770 code_modulename SML
  1771   Nat Arith
  1772 
  1773 code_modulename OCaml
  1774   Nat Arith
  1775 
  1776 code_modulename Haskell
  1777   Nat Arith
  1778 
  1779 end