src/Pure/Isar/attrib.ML
author wenzelm
Tue Sep 02 16:55:33 2008 +0200 (2008-09-02)
changeset 28084 a05ca48ef263
parent 28083 103d9282a946
child 28965 1de908189869
permissions -rw-r--r--
type Attrib.binding abbreviates Name.binding without attributes;
Attrib.no_binding refers to Name.no_binding;
     1 (*  Title:      Pure/Isar/attrib.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Symbolic representation of attributes -- with name and syntax.
     6 *)
     7 
     8 signature ATTRIB =
     9 sig
    10   type src = Args.src
    11   type binding = Name.binding * src list
    12   val no_binding: binding
    13   val print_attributes: theory -> unit
    14   val intern: theory -> xstring -> string
    15   val intern_src: theory -> src -> src
    16   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    17   val defined: theory -> string -> bool
    18   val attribute: theory -> src -> attribute
    19   val attribute_i: theory -> src -> attribute
    20   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    21   val map_specs: ('a -> 'att) ->
    22     (('c * 'a list) * 'd) list -> (('c * 'att list) * 'd) list
    23   val map_facts: ('a -> 'att) ->
    24     (('c * 'a list) * ('d * 'a list) list) list ->
    25     (('c * 'att list) * ('d * 'att list) list) list
    26   val crude_closure: Proof.context -> src -> src
    27   val add_attributes: (bstring * (src -> attribute) * string) list -> theory -> theory
    28   val syntax: (Context.generic * Args.T list ->
    29     attribute * (Context.generic * Args.T list)) -> src -> attribute
    30   val no_args: attribute -> src -> attribute
    31   val add_del_args: attribute -> attribute -> src -> attribute
    32   val thm_sel: Args.T list -> Facts.interval list * Args.T list
    33   val thm: Context.generic * Args.T list -> thm * (Context.generic * Args.T list)
    34   val thms: Context.generic * Args.T list -> thm list * (Context.generic * Args.T list)
    35   val multi_thm: Context.generic * Args.T list -> thm list * (Context.generic * Args.T list)
    36   val print_configs: Proof.context -> unit
    37   val internal: (morphism -> attribute) -> src
    38   val register_config: Config.value Config.T -> theory -> theory
    39   val config_bool: bstring -> bool -> bool Config.T * (theory -> theory)
    40   val config_int: bstring -> int -> int Config.T * (theory -> theory)
    41   val config_string: bstring -> string -> string Config.T * (theory -> theory)
    42   val config_bool_global: bstring -> bool -> bool Config.T * (theory -> theory)
    43   val config_int_global: bstring -> int -> int Config.T * (theory -> theory)
    44   val config_string_global: bstring -> string -> string Config.T * (theory -> theory)
    45 end;
    46 
    47 structure Attrib: ATTRIB =
    48 struct
    49 
    50 structure T = OuterLex;
    51 structure P = OuterParse;
    52 
    53 
    54 (* source and bindings *)
    55 
    56 type src = Args.src;
    57 
    58 type binding = Name.binding * src list;
    59 val no_binding: binding = (Name.no_binding, []);
    60 
    61 
    62 
    63 (** named attributes **)
    64 
    65 (* theory data *)
    66 
    67 structure Attributes = TheoryDataFun
    68 (
    69   type T = (((src -> attribute) * string) * stamp) NameSpace.table;
    70   val empty = NameSpace.empty_table;
    71   val copy = I;
    72   val extend = I;
    73   fun merge _ tables : T = NameSpace.merge_tables (eq_snd (op =)) tables handle Symtab.DUP dup =>
    74     error ("Attempt to merge different versions of attribute " ^ quote dup);
    75 );
    76 
    77 fun print_attributes thy =
    78   let
    79     val attribs = Attributes.get thy;
    80     fun prt_attr (name, ((_, comment), _)) = Pretty.block
    81       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    82   in
    83     [Pretty.big_list "attributes:" (map prt_attr (NameSpace.extern_table attribs))]
    84     |> Pretty.chunks |> Pretty.writeln
    85   end;
    86 
    87 
    88 (* name space *)
    89 
    90 val intern = NameSpace.intern o #1 o Attributes.get;
    91 val intern_src = Args.map_name o intern;
    92 
    93 val extern = NameSpace.extern o #1 o Attributes.get o ProofContext.theory_of;
    94 
    95 
    96 (* pretty printing *)
    97 
    98 fun pretty_attribs _ [] = []
    99   | pretty_attribs ctxt srcs =
   100       [Pretty.enclose "[" "]"
   101         (Pretty.commas (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs))];
   102 
   103 
   104 (* get attributes *)
   105 
   106 val defined = Symtab.defined o #2 o Attributes.get;
   107 
   108 fun attribute_i thy =
   109   let
   110     val attrs = #2 (Attributes.get thy);
   111     fun attr src =
   112       let val ((name, _), pos) = Args.dest_src src in
   113         (case Symtab.lookup attrs name of
   114           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   115         | SOME ((att, _), _) => (Position.report (Markup.attribute name) pos; att src))
   116       end;
   117   in attr end;
   118 
   119 fun attribute thy = attribute_i thy o intern_src thy;
   120 
   121 fun eval_thms ctxt args = ProofContext.note_thmss Thm.theoremK
   122     [((Name.no_binding, []),
   123       map (apsnd (map (attribute (ProofContext.theory_of ctxt)))) args)] ctxt
   124   |> fst |> maps snd;
   125 
   126 
   127 (* attributed declarations *)
   128 
   129 fun map_specs f = map (apfst (apsnd (map f)));
   130 fun map_facts f = map (apfst (apsnd (map f)) o apsnd (map (apsnd (map f))));
   131 
   132 
   133 (* crude_closure *)
   134 
   135 (*Produce closure without knowing facts in advance! The following
   136   works reasonably well for attribute parsers that do not peek at the
   137   thm structure.*)
   138 
   139 fun crude_closure ctxt src =
   140  (try (fn () => attribute_i (ProofContext.theory_of ctxt) src
   141     (Context.Proof ctxt, Drule.asm_rl)) ();
   142   Args.closure src);
   143 
   144 
   145 (* add_attributes *)
   146 
   147 fun add_attributes raw_attrs thy =
   148   let
   149     val new_attrs =
   150       raw_attrs |> map (fn (name, att, comment) => (name, ((att, comment), stamp ())));
   151     fun add attrs = NameSpace.extend_table (Sign.naming_of thy) new_attrs attrs
   152       handle Symtab.DUP dup => error ("Duplicate declaration of attributes " ^ quote dup);
   153   in Attributes.map add thy end;
   154 
   155 
   156 (* attribute syntax *)
   157 
   158 fun syntax scan src (st, th) =
   159   let val (f: attribute, st') = Args.syntax "attribute" scan src st
   160   in f (st', th) end;
   161 
   162 fun no_args x = syntax (Scan.succeed x);
   163 
   164 fun add_del_args add del = syntax
   165   (Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add));
   166 
   167 
   168 
   169 (** parsing attributed theorems **)
   170 
   171 val thm_sel = P.$$$ "(" |-- P.list1
   172  (P.nat --| P.minus -- P.nat >> Facts.FromTo ||
   173   P.nat --| P.minus >> Facts.From ||
   174   P.nat >> Facts.Single) --| P.$$$ ")";
   175 
   176 local
   177 
   178 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   179 
   180 fun gen_thm pick = Scan.depend (fn context =>
   181   let
   182     val thy = Context.theory_of context;
   183     val get = Context.cases (PureThy.get_fact context) ProofContext.get_fact context;
   184     val get_fact = get o Facts.Fact;
   185     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   186   in
   187     P.$$$ "[" |-- Args.attribs (intern thy) --| P.$$$ "]" >> (fn srcs =>
   188       let
   189         val atts = map (attribute_i thy) srcs;
   190         val (context', th') = Library.apply atts (context, Drule.dummy_thm);
   191       in (context', pick "" [th']) end)
   192     ||
   193     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   194       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   195      Scan.ahead (P.position fact_name) :|-- (fn (name, pos) =>
   196       Args.named_fact (get_named pos) -- Scan.option thm_sel
   197         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   198     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   199       let
   200         val ths = Facts.select thmref fact;
   201         val atts = map (attribute_i thy) srcs;
   202         val (context', ths') = foldl_map (Library.apply atts) (context, ths);
   203       in (context', pick name ths') end)
   204   end);
   205 
   206 in
   207 
   208 val thm = gen_thm Facts.the_single;
   209 val multi_thm = gen_thm (K I);
   210 val thms = Scan.repeat multi_thm >> flat;
   211 
   212 end;
   213 
   214 
   215 
   216 (** basic attributes **)
   217 
   218 (* internal *)
   219 
   220 fun internal att = Args.src (("Pure.attribute", [T.mk_attribute att]), Position.none);
   221 
   222 val internal_att =
   223   syntax (Scan.lift Args.internal_attribute >> Morphism.form);
   224 
   225 
   226 (* tags *)
   227 
   228 val tagged = syntax (Scan.lift (Args.name -- Args.name) >> Thm.tag);
   229 val untagged = syntax (Scan.lift Args.name >> Thm.untag);
   230 
   231 val kind = syntax (Scan.lift Args.name >> Thm.kind);
   232 
   233 
   234 (* rule composition *)
   235 
   236 val COMP_att =
   237   syntax (Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   238     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B))));
   239 
   240 val THEN_att =
   241   syntax (Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   242     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B))));
   243 
   244 val OF_att =
   245   syntax (thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A)));
   246 
   247 
   248 (* rename_abs *)
   249 
   250 val rename_abs = syntax
   251   (Scan.lift (Scan.repeat (Args.maybe Args.name) >> (apsnd o Drule.rename_bvars')));
   252 
   253 
   254 (* unfold / fold definitions *)
   255 
   256 fun unfolded_syntax rule =
   257   syntax (thms >>
   258     (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths)));
   259 
   260 val unfolded = unfolded_syntax LocalDefs.unfold;
   261 val folded = unfolded_syntax LocalDefs.fold;
   262 
   263 
   264 (* rule cases *)
   265 
   266 val consumes = syntax (Scan.lift (Scan.optional P.nat 1) >> RuleCases.consumes);
   267 val case_names = syntax (Scan.lift (Scan.repeat1 Args.name) >> RuleCases.case_names);
   268 val case_conclusion =
   269   syntax (Scan.lift (Args.name -- Scan.repeat Args.name) >> RuleCases.case_conclusion);
   270 val params = syntax (Scan.lift (P.and_list1 (Scan.repeat Args.name)) >> RuleCases.params);
   271 
   272 
   273 (* rule format *)
   274 
   275 val rule_format = syntax (Args.mode "no_asm"
   276   >> (fn true => ObjectLogic.rule_format_no_asm | false => ObjectLogic.rule_format));
   277 
   278 val elim_format = no_args (Thm.rule_attribute (K Tactic.make_elim));
   279 
   280 
   281 (* misc rules *)
   282 
   283 val standard = no_args (Thm.rule_attribute (K Drule.standard));
   284 
   285 val no_vars = no_args (Thm.rule_attribute (fn context => fn th =>
   286   let
   287     val ctxt = Variable.set_body false (Context.proof_of context);
   288     val ((_, [th']), _) = Variable.import_thms true [th] ctxt;
   289   in th' end));
   290 
   291 val eta_long =
   292   no_args (Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion)));
   293 
   294 val rotated = syntax
   295   (Scan.lift (Scan.optional P.int 1) >> (fn n => Thm.rule_attribute (K (rotate_prems n))));
   296 
   297 
   298 (* theory setup *)
   299 
   300 val _ = Context.>> (Context.map_theory
   301  (add_attributes
   302    [("attribute", internal_att, "internal attribute"),
   303     ("tagged", tagged, "tagged theorem"),
   304     ("untagged", untagged, "untagged theorem"),
   305     ("kind", kind, "theorem kind"),
   306     ("COMP", COMP_att, "direct composition with rules (no lifting)"),
   307     ("THEN", THEN_att, "resolution with rule"),
   308     ("OF", OF_att, "rule applied to facts"),
   309     ("rename_abs", rename_abs, "rename bound variables in abstractions"),
   310     ("unfolded", unfolded, "unfolded definitions"),
   311     ("folded", folded, "folded definitions"),
   312     ("standard", standard, "result put into standard form"),
   313     ("elim_format", elim_format, "destruct rule turned into elimination rule format"),
   314     ("no_vars", no_vars, "frozen schematic vars"),
   315     ("eta_long", eta_long, "put theorem into eta long beta normal form"),
   316     ("consumes", consumes, "number of consumed facts"),
   317     ("case_names", case_names, "named rule cases"),
   318     ("case_conclusion", case_conclusion, "named conclusion of rule cases"),
   319     ("params", params, "named rule parameters"),
   320     ("atomize", no_args ObjectLogic.declare_atomize, "declaration of atomize rule"),
   321     ("rulify", no_args ObjectLogic.declare_rulify, "declaration of rulify rule"),
   322     ("rule_format", rule_format, "result put into standard rule format"),
   323     ("rotated", rotated, "rotated theorem premises"),
   324     ("defn", add_del_args LocalDefs.defn_add LocalDefs.defn_del,
   325       "declaration of definitional transformations")]));
   326 
   327 
   328 
   329 (** configuration options **)
   330 
   331 (* naming *)
   332 
   333 structure Configs = TheoryDataFun
   334 (
   335   type T = Config.value Config.T Symtab.table;
   336   val empty = Symtab.empty;
   337   val copy = I;
   338   val extend = I;
   339   fun merge _ = Symtab.merge (K true);
   340 );
   341 
   342 fun print_configs ctxt =
   343   let
   344     val thy = ProofContext.theory_of ctxt;
   345     fun prt (name, config) =
   346       let val value = Config.get ctxt config in
   347         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   348           Pretty.str (Config.print_value value)]
   349       end;
   350     val configs = NameSpace.extern_table (#1 (Attributes.get thy), Configs.get thy);
   351   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   352 
   353 
   354 (* concrete syntax *)
   355 
   356 local
   357 
   358 val equals = P.$$$ "=";
   359 
   360 fun scan_value (Config.Bool _) =
   361       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   362       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   363       Scan.succeed (Config.Bool true)
   364   | scan_value (Config.Int _) = equals |-- P.int >> Config.Int
   365   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   366 
   367 fun scan_config thy config =
   368   let val config_type = Config.get_thy thy config
   369   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   370 
   371 in
   372 
   373 fun register_config config thy =
   374   let
   375     val bname = Config.name_of config;
   376     val name = Sign.full_name thy bname;
   377   in
   378     thy
   379     |> add_attributes [(bname, syntax (Scan.lift (scan_config thy config) >> Morphism.form),
   380       "configuration option")]
   381     |> Configs.map (Symtab.update (name, config))
   382   end;
   383 
   384 fun declare_config make coerce global name default =
   385   let
   386     val config_value = Config.declare global name (make default);
   387     val config = coerce config_value;
   388   in (config, register_config config_value) end;
   389 
   390 val config_bool   = declare_config Config.Bool Config.bool false;
   391 val config_int    = declare_config Config.Int Config.int false;
   392 val config_string = declare_config Config.String Config.string false;
   393 
   394 val config_bool_global   = declare_config Config.Bool Config.bool true;
   395 val config_int_global    = declare_config Config.Int Config.int true;
   396 val config_string_global = declare_config Config.String Config.string true;
   397 
   398 end;
   399 
   400 
   401 (* theory setup *)
   402 
   403 val _ = Context.>> (Context.map_theory
   404  (register_config Unify.trace_bound_value #>
   405   register_config Unify.search_bound_value #>
   406   register_config Unify.trace_simp_value #>
   407   register_config Unify.trace_types_value #>
   408   register_config MetaSimplifier.simp_depth_limit_value));
   409 
   410 end;