src/HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
author wenzelm
Tue Sep 03 01:12:40 2013 +0200 (2013-09-03)
changeset 53374 a14d2a854c02
parent 52803 bcaa5bbf7e6b
child 54220 0e6645622f22
permissions -rw-r--r--
tuned proofs -- clarified flow of facts wrt. calculation;
     1 (*  Title:      HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
     2     Author:     Amine Chaieb
     3 *)
     4 
     5 header {* Implementation and verification of multivariate polynomials *}
     6 
     7 theory Reflected_Multivariate_Polynomial
     8 imports Complex_Main "~~/src/HOL/Library/Abstract_Rat" Polynomial_List
     9 begin
    10 
    11 subsection{* Datatype of polynomial expressions *}
    12 
    13 datatype poly = C Num| Bound nat| Add poly poly|Sub poly poly
    14   | Mul poly poly| Neg poly| Pw poly nat| CN poly nat poly
    15 
    16 abbreviation poly_0 :: "poly" ("0\<^sub>p") where "0\<^sub>p \<equiv> C (0\<^sub>N)"
    17 abbreviation poly_p :: "int \<Rightarrow> poly" ("'((_)')\<^sub>p") where "(i)\<^sub>p \<equiv> C (i)\<^sub>N"
    18 
    19 
    20 subsection{* Boundedness, substitution and all that *}
    21 
    22 primrec polysize:: "poly \<Rightarrow> nat"
    23 where
    24   "polysize (C c) = 1"
    25 | "polysize (Bound n) = 1"
    26 | "polysize (Neg p) = 1 + polysize p"
    27 | "polysize (Add p q) = 1 + polysize p + polysize q"
    28 | "polysize (Sub p q) = 1 + polysize p + polysize q"
    29 | "polysize (Mul p q) = 1 + polysize p + polysize q"
    30 | "polysize (Pw p n) = 1 + polysize p"
    31 | "polysize (CN c n p) = 4 + polysize c + polysize p"
    32 
    33 primrec polybound0:: "poly \<Rightarrow> bool" -- {* a poly is INDEPENDENT of Bound 0 *}
    34 where
    35   "polybound0 (C c) = True"
    36 | "polybound0 (Bound n) = (n>0)"
    37 | "polybound0 (Neg a) = polybound0 a"
    38 | "polybound0 (Add a b) = (polybound0 a \<and> polybound0 b)"
    39 | "polybound0 (Sub a b) = (polybound0 a \<and> polybound0 b)"
    40 | "polybound0 (Mul a b) = (polybound0 a \<and> polybound0 b)"
    41 | "polybound0 (Pw p n) = (polybound0 p)"
    42 | "polybound0 (CN c n p) = (n \<noteq> 0 \<and> polybound0 c \<and> polybound0 p)"
    43 
    44 primrec polysubst0:: "poly \<Rightarrow> poly \<Rightarrow> poly" -- {* substitute a poly into a poly for Bound 0 *}
    45 where
    46   "polysubst0 t (C c) = (C c)"
    47 | "polysubst0 t (Bound n) = (if n=0 then t else Bound n)"
    48 | "polysubst0 t (Neg a) = Neg (polysubst0 t a)"
    49 | "polysubst0 t (Add a b) = Add (polysubst0 t a) (polysubst0 t b)"
    50 | "polysubst0 t (Sub a b) = Sub (polysubst0 t a) (polysubst0 t b)"
    51 | "polysubst0 t (Mul a b) = Mul (polysubst0 t a) (polysubst0 t b)"
    52 | "polysubst0 t (Pw p n) = Pw (polysubst0 t p) n"
    53 | "polysubst0 t (CN c n p) = (if n=0 then Add (polysubst0 t c) (Mul t (polysubst0 t p))
    54                              else CN (polysubst0 t c) n (polysubst0 t p))"
    55 
    56 fun decrpoly:: "poly \<Rightarrow> poly"
    57 where
    58   "decrpoly (Bound n) = Bound (n - 1)"
    59 | "decrpoly (Neg a) = Neg (decrpoly a)"
    60 | "decrpoly (Add a b) = Add (decrpoly a) (decrpoly b)"
    61 | "decrpoly (Sub a b) = Sub (decrpoly a) (decrpoly b)"
    62 | "decrpoly (Mul a b) = Mul (decrpoly a) (decrpoly b)"
    63 | "decrpoly (Pw p n) = Pw (decrpoly p) n"
    64 | "decrpoly (CN c n p) = CN (decrpoly c) (n - 1) (decrpoly p)"
    65 | "decrpoly a = a"
    66 
    67 
    68 subsection{* Degrees and heads and coefficients *}
    69 
    70 fun degree:: "poly \<Rightarrow> nat"
    71 where
    72   "degree (CN c 0 p) = 1 + degree p"
    73 | "degree p = 0"
    74 
    75 fun head:: "poly \<Rightarrow> poly"
    76 where
    77   "head (CN c 0 p) = head p"
    78 | "head p = p"
    79 
    80 (* More general notions of degree and head *)
    81 fun degreen:: "poly \<Rightarrow> nat \<Rightarrow> nat"
    82 where
    83   "degreen (CN c n p) = (\<lambda>m. if n=m then 1 + degreen p n else 0)"
    84  |"degreen p = (\<lambda>m. 0)"
    85 
    86 fun headn:: "poly \<Rightarrow> nat \<Rightarrow> poly"
    87 where
    88   "headn (CN c n p) = (\<lambda>m. if n \<le> m then headn p m else CN c n p)"
    89 | "headn p = (\<lambda>m. p)"
    90 
    91 fun coefficients:: "poly \<Rightarrow> poly list"
    92 where
    93   "coefficients (CN c 0 p) = c#(coefficients p)"
    94 | "coefficients p = [p]"
    95 
    96 fun isconstant:: "poly \<Rightarrow> bool"
    97 where
    98   "isconstant (CN c 0 p) = False"
    99 | "isconstant p = True"
   100 
   101 fun behead:: "poly \<Rightarrow> poly"
   102 where
   103   "behead (CN c 0 p) = (let p' = behead p in if p' = 0\<^sub>p then c else CN c 0 p')"
   104 | "behead p = 0\<^sub>p"
   105 
   106 fun headconst:: "poly \<Rightarrow> Num"
   107 where
   108   "headconst (CN c n p) = headconst p"
   109 | "headconst (C n) = n"
   110 
   111 
   112 subsection{* Operations for normalization *}
   113 
   114 declare if_cong[fundef_cong del]
   115 declare let_cong[fundef_cong del]
   116 
   117 fun polyadd :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "+\<^sub>p" 60)
   118 where
   119   "polyadd (C c) (C c') = C (c+\<^sub>Nc')"
   120 | "polyadd (C c) (CN c' n' p') = CN (polyadd (C c) c') n' p'"
   121 | "polyadd (CN c n p) (C c') = CN (polyadd c (C c')) n p"
   122 | "polyadd (CN c n p) (CN c' n' p') =
   123     (if n < n' then CN (polyadd c (CN c' n' p')) n p
   124      else if n'<n then CN (polyadd (CN c n p) c') n' p'
   125      else (let cc' = polyadd c c' ;
   126                pp' = polyadd p p'
   127            in (if pp' = 0\<^sub>p then cc' else CN cc' n pp')))"
   128 | "polyadd a b = Add a b"
   129 
   130 
   131 fun polyneg :: "poly \<Rightarrow> poly" ("~\<^sub>p")
   132 where
   133   "polyneg (C c) = C (~\<^sub>N c)"
   134 | "polyneg (CN c n p) = CN (polyneg c) n (polyneg p)"
   135 | "polyneg a = Neg a"
   136 
   137 definition polysub :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "-\<^sub>p" 60)
   138   where "p -\<^sub>p q = polyadd p (polyneg q)"
   139 
   140 fun polymul :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "*\<^sub>p" 60)
   141 where
   142   "polymul (C c) (C c') = C (c*\<^sub>Nc')"
   143 | "polymul (C c) (CN c' n' p') =
   144       (if c = 0\<^sub>N then 0\<^sub>p else CN (polymul (C c) c') n' (polymul (C c) p'))"
   145 | "polymul (CN c n p) (C c') =
   146       (if c' = 0\<^sub>N  then 0\<^sub>p else CN (polymul c (C c')) n (polymul p (C c')))"
   147 | "polymul (CN c n p) (CN c' n' p') =
   148   (if n<n' then CN (polymul c (CN c' n' p')) n (polymul p (CN c' n' p'))
   149   else if n' < n
   150   then CN (polymul (CN c n p) c') n' (polymul (CN c n p) p')
   151   else polyadd (polymul (CN c n p) c') (CN 0\<^sub>p n' (polymul (CN c n p) p')))"
   152 | "polymul a b = Mul a b"
   153 
   154 declare if_cong[fundef_cong]
   155 declare let_cong[fundef_cong]
   156 
   157 fun polypow :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   158 where
   159   "polypow 0 = (\<lambda>p. (1)\<^sub>p)"
   160 | "polypow n = (\<lambda>p. let q = polypow (n div 2) p ; d = polymul q q in
   161                     if even n then d else polymul p d)"
   162 
   163 abbreviation poly_pow :: "poly \<Rightarrow> nat \<Rightarrow> poly" (infixl "^\<^sub>p" 60)
   164   where "a ^\<^sub>p k \<equiv> polypow k a"
   165 
   166 function polynate :: "poly \<Rightarrow> poly"
   167 where
   168   "polynate (Bound n) = CN 0\<^sub>p n (1)\<^sub>p"
   169 | "polynate (Add p q) = (polynate p +\<^sub>p polynate q)"
   170 | "polynate (Sub p q) = (polynate p -\<^sub>p polynate q)"
   171 | "polynate (Mul p q) = (polynate p *\<^sub>p polynate q)"
   172 | "polynate (Neg p) = (~\<^sub>p (polynate p))"
   173 | "polynate (Pw p n) = ((polynate p) ^\<^sub>p n)"
   174 | "polynate (CN c n p) = polynate (Add c (Mul (Bound n) p))"
   175 | "polynate (C c) = C (normNum c)"
   176 by pat_completeness auto
   177 termination by (relation "measure polysize") auto
   178 
   179 fun poly_cmul :: "Num \<Rightarrow> poly \<Rightarrow> poly"
   180 where
   181   "poly_cmul y (C x) = C (y *\<^sub>N x)"
   182 | "poly_cmul y (CN c n p) = CN (poly_cmul y c) n (poly_cmul y p)"
   183 | "poly_cmul y p = C y *\<^sub>p p"
   184 
   185 definition monic :: "poly \<Rightarrow> (poly \<times> bool)" where
   186   "monic p \<equiv> (let h = headconst p in if h = 0\<^sub>N then (p,False) else ((C (Ninv h)) *\<^sub>p p, 0>\<^sub>N h))"
   187 
   188 
   189 subsection{* Pseudo-division *}
   190 
   191 definition shift1 :: "poly \<Rightarrow> poly"
   192   where "shift1 p \<equiv> CN 0\<^sub>p 0 p"
   193 
   194 abbreviation funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
   195   where "funpow \<equiv> compow"
   196 
   197 partial_function (tailrec) polydivide_aux :: "poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   198 where
   199   "polydivide_aux a n p k s =
   200     (if s = 0\<^sub>p then (k,s)
   201      else
   202       (let b = head s; m = degree s in
   203         (if m < n then (k,s)
   204          else
   205           (let p'= funpow (m - n) shift1 p in
   206             (if a = b then polydivide_aux a n p k (s -\<^sub>p p')
   207              else polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (b *\<^sub>p p')))))))"
   208 
   209 definition polydivide :: "poly \<Rightarrow> poly \<Rightarrow> (nat \<times> poly)"
   210   where "polydivide s p \<equiv> polydivide_aux (head p) (degree p) p 0 s"
   211 
   212 fun poly_deriv_aux :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   213 where
   214   "poly_deriv_aux n (CN c 0 p) = CN (poly_cmul ((int n)\<^sub>N) c) 0 (poly_deriv_aux (n + 1) p)"
   215 | "poly_deriv_aux n p = poly_cmul ((int n)\<^sub>N) p"
   216 
   217 fun poly_deriv :: "poly \<Rightarrow> poly"
   218 where
   219   "poly_deriv (CN c 0 p) = poly_deriv_aux 1 p"
   220 | "poly_deriv p = 0\<^sub>p"
   221 
   222 
   223 subsection{* Semantics of the polynomial representation *}
   224 
   225 primrec Ipoly :: "'a list \<Rightarrow> poly \<Rightarrow> 'a::{field_char_0, field_inverse_zero, power}" where
   226   "Ipoly bs (C c) = INum c"
   227 | "Ipoly bs (Bound n) = bs!n"
   228 | "Ipoly bs (Neg a) = - Ipoly bs a"
   229 | "Ipoly bs (Add a b) = Ipoly bs a + Ipoly bs b"
   230 | "Ipoly bs (Sub a b) = Ipoly bs a - Ipoly bs b"
   231 | "Ipoly bs (Mul a b) = Ipoly bs a * Ipoly bs b"
   232 | "Ipoly bs (Pw t n) = (Ipoly bs t) ^ n"
   233 | "Ipoly bs (CN c n p) = (Ipoly bs c) + (bs!n)*(Ipoly bs p)"
   234 
   235 abbreviation
   236   Ipoly_syntax :: "poly \<Rightarrow> 'a list \<Rightarrow>'a::{field_char_0, field_inverse_zero, power}" ("\<lparr>_\<rparr>\<^sub>p\<^bsup>_\<^esup>")
   237   where "\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<equiv> Ipoly bs p"
   238 
   239 lemma Ipoly_CInt: "Ipoly bs (C (i,1)) = of_int i"
   240   by (simp add: INum_def)
   241 lemma Ipoly_CRat: "Ipoly bs (C (i, j)) = of_int i / of_int j"
   242   by (simp  add: INum_def)
   243 
   244 lemmas RIpoly_eqs = Ipoly.simps(2-7) Ipoly_CInt Ipoly_CRat
   245 
   246 
   247 subsection {* Normal form and normalization *}
   248 
   249 fun isnpolyh:: "poly \<Rightarrow> nat \<Rightarrow> bool"
   250 where
   251   "isnpolyh (C c) = (\<lambda>k. isnormNum c)"
   252 | "isnpolyh (CN c n p) = (\<lambda>k. n \<ge> k \<and> (isnpolyh c (Suc n)) \<and> (isnpolyh p n) \<and> (p \<noteq> 0\<^sub>p))"
   253 | "isnpolyh p = (\<lambda>k. False)"
   254 
   255 lemma isnpolyh_mono: "\<lbrakk>n' \<le> n ; isnpolyh p n\<rbrakk> \<Longrightarrow> isnpolyh p n'"
   256   by (induct p rule: isnpolyh.induct) auto
   257 
   258 definition isnpoly :: "poly \<Rightarrow> bool"
   259   where "isnpoly p \<equiv> isnpolyh p 0"
   260 
   261 text{* polyadd preserves normal forms *}
   262 
   263 lemma polyadd_normh: "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1\<rbrakk>
   264       \<Longrightarrow> isnpolyh (polyadd p q) (min n0 n1)"
   265 proof (induct p q arbitrary: n0 n1 rule: polyadd.induct)
   266   case (2 ab c' n' p' n0 n1)
   267   from 2 have  th1: "isnpolyh (C ab) (Suc n')" by simp
   268   from 2(3) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1" by simp_all
   269   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')" by simp
   270   with 2(1)[OF th1 th2] have th3:"isnpolyh (C ab +\<^sub>p c') (Suc n')" by simp
   271   from nplen1 have n01len1: "min n0 n1 \<le> n'" by simp
   272   thus ?case using 2 th3 by simp
   273 next
   274   case (3 c' n' p' ab n1 n0)
   275   from 3 have  th1: "isnpolyh (C ab) (Suc n')" by simp
   276   from 3(2) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1" by simp_all
   277   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')" by simp
   278   with 3(1)[OF th2 th1] have th3:"isnpolyh (c' +\<^sub>p C ab) (Suc n')" by simp
   279   from nplen1 have n01len1: "min n0 n1 \<le> n'" by simp
   280   thus ?case using 3 th3 by simp
   281 next
   282   case (4 c n p c' n' p' n0 n1)
   283   hence nc: "isnpolyh c (Suc n)" and np: "isnpolyh p n" by simp_all
   284   from 4 have nc': "isnpolyh c' (Suc n')" and np': "isnpolyh p' n'" by simp_all
   285   from 4 have ngen0: "n \<ge> n0" by simp
   286   from 4 have n'gen1: "n' \<ge> n1" by simp
   287   have "n < n' \<or> n' < n \<or> n = n'" by auto
   288   moreover {
   289     assume eq: "n = n'"
   290     with "4.hyps"(3)[OF nc nc']
   291     have ncc':"isnpolyh (c +\<^sub>p c') (Suc n)" by auto
   292     hence ncc'n01: "isnpolyh (c +\<^sub>p c') (min n0 n1)"
   293       using isnpolyh_mono[where n'="min n0 n1" and n="Suc n"] ngen0 n'gen1 by auto
   294     from eq "4.hyps"(4)[OF np np'] have npp': "isnpolyh (p +\<^sub>p p') n" by simp
   295     have minle: "min n0 n1 \<le> n'" using ngen0 n'gen1 eq by simp
   296     from minle npp' ncc'n01 4 eq ngen0 n'gen1 ncc' have ?case by (simp add: Let_def) }
   297   moreover {
   298     assume lt: "n < n'"
   299     have "min n0 n1 \<le> n0" by simp
   300     with 4 lt have th1:"min n0 n1 \<le> n" by auto
   301     from 4 have th21: "isnpolyh c (Suc n)" by simp
   302     from 4 have th22: "isnpolyh (CN c' n' p') n'" by simp
   303     from lt have th23: "min (Suc n) n' = Suc n" by arith
   304     from "4.hyps"(1)[OF th21 th22]
   305     have "isnpolyh (polyadd c (CN c' n' p')) (Suc n)" using th23 by simp
   306     with 4 lt th1 have ?case by simp }
   307   moreover {
   308     assume gt: "n' < n" hence gt': "n' < n \<and> \<not> n < n'" by simp
   309     have "min n0 n1 \<le> n1"  by simp
   310     with 4 gt have th1:"min n0 n1 \<le> n'" by auto
   311     from 4 have th21: "isnpolyh c' (Suc n')" by simp_all
   312     from 4 have th22: "isnpolyh (CN c n p) n" by simp
   313     from gt have th23: "min n (Suc n') = Suc n'" by arith
   314     from "4.hyps"(2)[OF th22 th21]
   315     have "isnpolyh (polyadd (CN c n p) c') (Suc n')" using th23 by simp
   316     with 4 gt th1 have ?case by simp }
   317   ultimately show ?case by blast
   318 qed auto
   319 
   320 lemma polyadd[simp]: "Ipoly bs (polyadd p q) = Ipoly bs p + Ipoly bs q"
   321   by (induct p q rule: polyadd.induct)
   322     (auto simp add: Let_def field_simps distrib_left[symmetric] simp del: distrib_left)
   323 
   324 lemma polyadd_norm: "\<lbrakk> isnpoly p ; isnpoly q\<rbrakk> \<Longrightarrow> isnpoly (polyadd p q)"
   325   using polyadd_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   326 
   327 text{* The degree of addition and other general lemmas needed for the normal form of polymul *}
   328 
   329 lemma polyadd_different_degreen:
   330   "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1; degreen p m \<noteq> degreen q m ; m \<le> min n0 n1\<rbrakk> \<Longrightarrow>
   331   degreen (polyadd p q) m = max (degreen p m) (degreen q m)"
   332 proof (induct p q arbitrary: m n0 n1 rule: polyadd.induct)
   333   case (4 c n p c' n' p' m n0 n1)
   334   have "n' = n \<or> n < n' \<or> n' < n" by arith
   335   thus ?case
   336   proof (elim disjE)
   337     assume [simp]: "n' = n"
   338     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   339     show ?thesis by (auto simp: Let_def)
   340   next
   341     assume "n < n'"
   342     with 4 show ?thesis by auto
   343   next
   344     assume "n' < n"
   345     with 4 show ?thesis by auto
   346   qed
   347 qed auto
   348 
   349 lemma headnz[simp]: "\<lbrakk>isnpolyh p n ; p \<noteq> 0\<^sub>p\<rbrakk> \<Longrightarrow> headn p m \<noteq> 0\<^sub>p"
   350   by (induct p arbitrary: n rule: headn.induct) auto
   351 lemma degree_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> degree p = 0"
   352   by (induct p arbitrary: n rule: degree.induct) auto
   353 lemma degreen_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> degreen p m = 0"
   354   by (induct p arbitrary: n rule: degreen.induct) auto
   355 
   356 lemma degree_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> degree p = 0"
   357   by (induct p arbitrary: n rule: degree.induct) auto
   358 
   359 lemma degree_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degree c = 0"
   360   using degree_isnpolyh_Suc by auto
   361 lemma degreen_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degreen c n = 0"
   362   using degreen_0 by auto
   363 
   364 
   365 lemma degreen_polyadd:
   366   assumes np: "isnpolyh p n0" and nq: "isnpolyh q n1" and m: "m \<le> max n0 n1"
   367   shows "degreen (p +\<^sub>p q) m \<le> max (degreen p m) (degreen q m)"
   368   using np nq m
   369 proof (induct p q arbitrary: n0 n1 m rule: polyadd.induct)
   370   case (2 c c' n' p' n0 n1)
   371   thus ?case  by (cases n') simp_all
   372 next
   373   case (3 c n p c' n0 n1)
   374   thus ?case by (cases n) auto
   375 next
   376   case (4 c n p c' n' p' n0 n1 m)
   377   have "n' = n \<or> n < n' \<or> n' < n" by arith
   378   thus ?case
   379   proof (elim disjE)
   380     assume [simp]: "n' = n"
   381     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   382     show ?thesis by (auto simp: Let_def)
   383   qed simp_all
   384 qed auto
   385 
   386 lemma polyadd_eq_const_degreen: "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1 ; polyadd p q = C c\<rbrakk>
   387   \<Longrightarrow> degreen p m = degreen q m"
   388 proof (induct p q arbitrary: m n0 n1 c rule: polyadd.induct)
   389   case (4 c n p c' n' p' m n0 n1 x)
   390   { assume nn': "n' < n" hence ?case using 4 by simp }
   391   moreover
   392   { assume nn':"\<not> n' < n" hence "n < n' \<or> n = n'" by arith
   393     moreover { assume "n < n'" with 4 have ?case by simp }
   394     moreover { assume eq: "n = n'" hence ?case using 4
   395         apply (cases "p +\<^sub>p p' = 0\<^sub>p")
   396         apply (auto simp add: Let_def)
   397         apply blast
   398         done
   399     }
   400     ultimately have ?case by blast }
   401   ultimately show ?case by blast
   402 qed simp_all
   403 
   404 lemma polymul_properties:
   405   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   406     and np: "isnpolyh p n0"
   407     and nq: "isnpolyh q n1"
   408     and m: "m \<le> min n0 n1"
   409   shows "isnpolyh (p *\<^sub>p q) (min n0 n1)"
   410     and "(p *\<^sub>p q = 0\<^sub>p) = (p = 0\<^sub>p \<or> q = 0\<^sub>p)"
   411     and "degreen (p *\<^sub>p q) m = (if (p = 0\<^sub>p \<or> q = 0\<^sub>p) then 0 else degreen p m + degreen q m)"
   412   using np nq m
   413 proof (induct p q arbitrary: n0 n1 m rule: polymul.induct)
   414   case (2 c c' n' p')
   415   { case (1 n0 n1)
   416     with "2.hyps"(4-6)[of n' n' n']
   417       and "2.hyps"(1-3)[of "Suc n'" "Suc n'" n']
   418     show ?case by (auto simp add: min_def)
   419   next
   420     case (2 n0 n1) thus ?case by auto
   421   next
   422     case (3 n0 n1) thus ?case  using "2.hyps" by auto }
   423 next
   424   case (3 c n p c')
   425   { case (1 n0 n1)
   426     with "3.hyps"(4-6)[of n n n]
   427       "3.hyps"(1-3)[of "Suc n" "Suc n" n]
   428     show ?case by (auto simp add: min_def)
   429   next
   430     case (2 n0 n1) thus ?case by auto
   431   next
   432     case (3 n0 n1) thus ?case  using "3.hyps" by auto }
   433 next
   434   case (4 c n p c' n' p')
   435   let ?cnp = "CN c n p" let ?cnp' = "CN c' n' p'"
   436     {
   437       case (1 n0 n1)
   438       hence cnp: "isnpolyh ?cnp n" and cnp': "isnpolyh ?cnp' n'"
   439         and np: "isnpolyh p n" and nc: "isnpolyh c (Suc n)"
   440         and np': "isnpolyh p' n'" and nc': "isnpolyh c' (Suc n')"
   441         and nn0: "n \<ge> n0" and nn1:"n' \<ge> n1"
   442         by simp_all
   443       { assume "n < n'"
   444         with "4.hyps"(4-5)[OF np cnp', of n]
   445           "4.hyps"(1)[OF nc cnp', of n] nn0 cnp
   446         have ?case by (simp add: min_def)
   447       } moreover {
   448         assume "n' < n"
   449         with "4.hyps"(16-17)[OF cnp np', of "n'"]
   450           "4.hyps"(13)[OF cnp nc', of "Suc n'"] nn1 cnp'
   451         have ?case
   452           by (cases "Suc n' = n") (simp_all add: min_def)
   453       } moreover {
   454         assume "n' = n"
   455         with "4.hyps"(16-17)[OF cnp np', of n]
   456           "4.hyps"(13)[OF cnp nc', of n] cnp cnp' nn1 nn0
   457         have ?case
   458           apply (auto intro!: polyadd_normh)
   459           apply (simp_all add: min_def isnpolyh_mono[OF nn0])
   460           done
   461       }
   462       ultimately show ?case by arith
   463     next
   464       fix n0 n1 m
   465       assume np: "isnpolyh ?cnp n0" and np':"isnpolyh ?cnp' n1"
   466       and m: "m \<le> min n0 n1"
   467       let ?d = "degreen (?cnp *\<^sub>p ?cnp') m"
   468       let ?d1 = "degreen ?cnp m"
   469       let ?d2 = "degreen ?cnp' m"
   470       let ?eq = "?d = (if ?cnp = 0\<^sub>p \<or> ?cnp' = 0\<^sub>p then 0  else ?d1 + ?d2)"
   471       have "n'<n \<or> n < n' \<or> n' = n" by auto
   472       moreover
   473       {assume "n' < n \<or> n < n'"
   474         with "4.hyps"(3,6,18) np np' m
   475         have ?eq by auto }
   476       moreover
   477       { assume nn': "n' = n"
   478         hence nn: "\<not> n' < n \<and> \<not> n < n'" by arith
   479         from "4.hyps"(16,18)[of n n' n]
   480           "4.hyps"(13,14)[of n "Suc n'" n]
   481           np np' nn'
   482         have norm: "isnpolyh ?cnp n" "isnpolyh c' (Suc n)" "isnpolyh (?cnp *\<^sub>p c') n"
   483           "isnpolyh p' n" "isnpolyh (?cnp *\<^sub>p p') n" "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   484           "(?cnp *\<^sub>p c' = 0\<^sub>p) = (c' = 0\<^sub>p)"
   485           "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p" by (auto simp add: min_def)
   486         { assume mn: "m = n"
   487           from "4.hyps"(17,18)[OF norm(1,4), of n]
   488             "4.hyps"(13,15)[OF norm(1,2), of n] norm nn' mn
   489           have degs:  "degreen (?cnp *\<^sub>p c') n =
   490             (if c'=0\<^sub>p then 0 else ?d1 + degreen c' n)"
   491             "degreen (?cnp *\<^sub>p p') n = ?d1  + degreen p' n" by (simp_all add: min_def)
   492           from degs norm
   493           have th1: "degreen(?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n" by simp
   494           hence neq: "degreen (?cnp *\<^sub>p c') n \<noteq> degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   495             by simp
   496           have nmin: "n \<le> min n n" by (simp add: min_def)
   497           from polyadd_different_degreen[OF norm(3,6) neq nmin] th1
   498           have deg: "degreen (CN c n p *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n = degreen (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp
   499           from "4.hyps"(16-18)[OF norm(1,4), of n]
   500             "4.hyps"(13-15)[OF norm(1,2), of n]
   501             mn norm m nn' deg
   502           have ?eq by simp }
   503         moreover
   504         { assume mn: "m \<noteq> n" hence mn': "m < n" using m np by auto
   505           from nn' m np have max1: "m \<le> max n n"  by simp
   506           hence min1: "m \<le> min n n" by simp
   507           hence min2: "m \<le> min n (Suc n)" by simp
   508           from "4.hyps"(16-18)[OF norm(1,4) min1]
   509             "4.hyps"(13-15)[OF norm(1,2) min2]
   510             degreen_polyadd[OF norm(3,6) max1]
   511 
   512           have "degreen (?cnp *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (?cnp *\<^sub>p p')) m
   513             \<le> max (degreen (?cnp *\<^sub>p c') m) (degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) m)"
   514             using mn nn' np np' by simp
   515           with "4.hyps"(16-18)[OF norm(1,4) min1]
   516             "4.hyps"(13-15)[OF norm(1,2) min2]
   517             degreen_0[OF norm(3) mn']
   518           have ?eq using nn' mn np np' by clarsimp }
   519         ultimately have ?eq by blast }
   520       ultimately show ?eq by blast }
   521     { case (2 n0 n1)
   522       hence np: "isnpolyh ?cnp n0" and np': "isnpolyh ?cnp' n1"
   523         and m: "m \<le> min n0 n1" by simp_all
   524       hence mn: "m \<le> n" by simp
   525       let ?c0p = "CN 0\<^sub>p n (?cnp *\<^sub>p p')"
   526       {assume C: "?cnp *\<^sub>p c' +\<^sub>p ?c0p = 0\<^sub>p" "n' = n"
   527         hence nn: "\<not>n' < n \<and> \<not> n<n'" by simp
   528         from "4.hyps"(16-18) [of n n n]
   529           "4.hyps"(13-15)[of n "Suc n" n]
   530           np np' C(2) mn
   531         have norm: "isnpolyh ?cnp n" "isnpolyh c' (Suc n)" "isnpolyh (?cnp *\<^sub>p c') n"
   532           "isnpolyh p' n" "isnpolyh (?cnp *\<^sub>p p') n" "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   533           "(?cnp *\<^sub>p c' = 0\<^sub>p) = (c' = 0\<^sub>p)"
   534           "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p"
   535           "degreen (?cnp *\<^sub>p c') n = (if c'=0\<^sub>p then 0 else degreen ?cnp n + degreen c' n)"
   536             "degreen (?cnp *\<^sub>p p') n = degreen ?cnp n + degreen p' n"
   537           by (simp_all add: min_def)
   538 
   539           from norm have cn: "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp
   540           have degneq: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   541             using norm by simp
   542         from polyadd_eq_const_degreen[OF norm(3) cn C(1), where m="n"]  degneq
   543         have "False" by simp }
   544       thus ?case using "4.hyps" by clarsimp }
   545 qed auto
   546 
   547 lemma polymul[simp]: "Ipoly bs (p *\<^sub>p q) = (Ipoly bs p) * (Ipoly bs q)"
   548   by (induct p q rule: polymul.induct) (auto simp add: field_simps)
   549 
   550 lemma polymul_normh:
   551   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   552   shows "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1\<rbrakk> \<Longrightarrow> isnpolyh (p *\<^sub>p q) (min n0 n1)"
   553   using polymul_properties(1) by blast
   554 
   555 lemma polymul_eq0_iff:
   556   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   557   shows "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1\<rbrakk> \<Longrightarrow> (p *\<^sub>p q = 0\<^sub>p) = (p = 0\<^sub>p \<or> q = 0\<^sub>p) "
   558   using polymul_properties(2) by blast
   559 
   560 lemma polymul_degreen:  (* FIXME duplicate? *)
   561   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   562   shows "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1 ; m \<le> min n0 n1\<rbrakk> \<Longrightarrow>
   563     degreen (p *\<^sub>p q) m = (if (p = 0\<^sub>p \<or> q = 0\<^sub>p) then 0 else degreen p m + degreen q m)"
   564   using polymul_properties(3) by blast
   565 
   566 lemma polymul_norm:
   567   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   568   shows "\<lbrakk> isnpoly p; isnpoly q\<rbrakk> \<Longrightarrow> isnpoly (polymul p q)"
   569   using polymul_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   570 
   571 lemma headconst_zero: "isnpolyh p n0 \<Longrightarrow> headconst p = 0\<^sub>N \<longleftrightarrow> p = 0\<^sub>p"
   572   by (induct p arbitrary: n0 rule: headconst.induct) auto
   573 
   574 lemma headconst_isnormNum: "isnpolyh p n0 \<Longrightarrow> isnormNum (headconst p)"
   575   by (induct p arbitrary: n0) auto
   576 
   577 lemma monic_eqI:
   578   assumes np: "isnpolyh p n0"
   579   shows "INum (headconst p) * Ipoly bs (fst (monic p)) =
   580     (Ipoly bs p ::'a::{field_char_0, field_inverse_zero, power})"
   581   unfolding monic_def Let_def
   582 proof (cases "headconst p = 0\<^sub>N", simp_all add: headconst_zero[OF np])
   583   let ?h = "headconst p"
   584   assume pz: "p \<noteq> 0\<^sub>p"
   585   { assume hz: "INum ?h = (0::'a)"
   586     from headconst_isnormNum[OF np] have norm: "isnormNum ?h" "isnormNum 0\<^sub>N" by simp_all
   587     from isnormNum_unique[where ?'a = 'a, OF norm] hz have "?h = 0\<^sub>N" by simp
   588     with headconst_zero[OF np] have "p =0\<^sub>p" by blast with pz have "False" by blast}
   589   thus "INum (headconst p) = (0::'a) \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0" by blast
   590 qed
   591 
   592 
   593 text{* polyneg is a negation and preserves normal forms *}
   594 
   595 lemma polyneg[simp]: "Ipoly bs (polyneg p) = - Ipoly bs p"
   596   by (induct p rule: polyneg.induct) auto
   597 
   598 lemma polyneg0: "isnpolyh p n \<Longrightarrow> ((~\<^sub>p p) = 0\<^sub>p) = (p = 0\<^sub>p)"
   599   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: Nneg_def)
   600 lemma polyneg_polyneg: "isnpolyh p n0 \<Longrightarrow> ~\<^sub>p (~\<^sub>p p) = p"
   601   by (induct p arbitrary: n0 rule: polyneg.induct) auto
   602 lemma polyneg_normh: "\<And>n. isnpolyh p n \<Longrightarrow> isnpolyh (polyneg p) n "
   603   by (induct p rule: polyneg.induct) (auto simp add: polyneg0)
   604 
   605 lemma polyneg_norm: "isnpoly p \<Longrightarrow> isnpoly (polyneg p)"
   606   using isnpoly_def polyneg_normh by simp
   607 
   608 
   609 text{* polysub is a substraction and preserves normal forms *}
   610 
   611 lemma polysub[simp]: "Ipoly bs (polysub p q) = (Ipoly bs p) - (Ipoly bs q)"
   612   by (simp add: polysub_def)
   613 lemma polysub_normh:
   614   "\<And>n0 n1. \<lbrakk> isnpolyh p n0 ; isnpolyh q n1\<rbrakk> \<Longrightarrow> isnpolyh (polysub p q) (min n0 n1)"
   615   by (simp add: polysub_def polyneg_normh polyadd_normh)
   616 
   617 lemma polysub_norm: "\<lbrakk> isnpoly p; isnpoly q\<rbrakk> \<Longrightarrow> isnpoly (polysub p q)"
   618   using polyadd_norm polyneg_norm by (simp add: polysub_def)
   619 lemma polysub_same_0[simp]:
   620   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   621   shows "isnpolyh p n0 \<Longrightarrow> polysub p p = 0\<^sub>p"
   622   unfolding polysub_def split_def fst_conv snd_conv
   623   by (induct p arbitrary: n0) (auto simp add: Let_def Nsub0[simplified Nsub_def])
   624 
   625 lemma polysub_0:
   626   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   627   shows "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1\<rbrakk> \<Longrightarrow> (p -\<^sub>p q = 0\<^sub>p) = (p = q)"
   628   unfolding polysub_def split_def fst_conv snd_conv
   629   by (induct p q arbitrary: n0 n1 rule:polyadd.induct)
   630     (auto simp: Nsub0[simplified Nsub_def] Let_def)
   631 
   632 text{* polypow is a power function and preserves normal forms *}
   633 
   634 lemma polypow[simp]: "Ipoly bs (polypow n p) = ((Ipoly bs p :: 'a::{field_char_0, field_inverse_zero})) ^ n"
   635 proof (induct n rule: polypow.induct)
   636   case 1
   637   thus ?case by simp
   638 next
   639   case (2 n)
   640   let ?q = "polypow ((Suc n) div 2) p"
   641   let ?d = "polymul ?q ?q"
   642   have "odd (Suc n) \<or> even (Suc n)" by simp
   643   moreover
   644   { assume odd: "odd (Suc n)"
   645     have th: "(Suc (Suc (Suc (0\<Colon>nat)) * (Suc n div Suc (Suc (0\<Colon>nat))))) = Suc n div 2 + Suc n div 2 + 1"
   646       by arith
   647     from odd have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs (polymul p ?d)" by (simp add: Let_def)
   648     also have "\<dots> = (Ipoly bs p) * (Ipoly bs p)^(Suc n div 2)*(Ipoly bs p)^(Suc n div 2)"
   649       using "2.hyps" by simp
   650     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2 + 1)"
   651       by (simp only: power_add power_one_right) simp
   652     also have "\<dots> = (Ipoly bs p) ^ (Suc (Suc (Suc (0\<Colon>nat)) * (Suc n div Suc (Suc (0\<Colon>nat)))))"
   653       by (simp only: th)
   654     finally have ?case
   655     using odd_nat_div_two_times_two_plus_one[OF odd, symmetric] by simp  }
   656   moreover
   657   { assume even: "even (Suc n)"
   658     have th: "(Suc (Suc (0\<Colon>nat))) * (Suc n div Suc (Suc (0\<Colon>nat))) = Suc n div 2 + Suc n div 2"
   659       by arith
   660     from even have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs ?d" by (simp add: Let_def)
   661     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2)"
   662       using "2.hyps" apply (simp only: power_add) by simp
   663     finally have ?case using even_nat_div_two_times_two[OF even] by (simp only: th)}
   664   ultimately show ?case by blast
   665 qed
   666 
   667 lemma polypow_normh:
   668   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   669   shows "isnpolyh p n \<Longrightarrow> isnpolyh (polypow k p) n"
   670 proof (induct k arbitrary: n rule: polypow.induct)
   671   case (2 k n)
   672   let ?q = "polypow (Suc k div 2) p"
   673   let ?d = "polymul ?q ?q"
   674   from 2 have th1:"isnpolyh ?q n" and th2: "isnpolyh p n" by blast+
   675   from polymul_normh[OF th1 th1] have dn: "isnpolyh ?d n" by simp
   676   from polymul_normh[OF th2 dn] have on: "isnpolyh (polymul p ?d) n" by simp
   677   from dn on show ?case by (simp add: Let_def)
   678 qed auto
   679 
   680 lemma polypow_norm:
   681   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   682   shows "isnpoly p \<Longrightarrow> isnpoly (polypow k p)"
   683   by (simp add: polypow_normh isnpoly_def)
   684 
   685 text{* Finally the whole normalization *}
   686 
   687 lemma polynate [simp]:
   688   "Ipoly bs (polynate p) = (Ipoly bs p :: 'a ::{field_char_0, field_inverse_zero})"
   689   by (induct p rule:polynate.induct) auto
   690 
   691 lemma polynate_norm[simp]:
   692   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   693   shows "isnpoly (polynate p)"
   694   by (induct p rule: polynate.induct)
   695      (simp_all add: polyadd_norm polymul_norm polysub_norm polyneg_norm polypow_norm,
   696       simp_all add: isnpoly_def)
   697 
   698 text{* shift1 *}
   699 
   700 
   701 lemma shift1: "Ipoly bs (shift1 p) = Ipoly bs (Mul (Bound 0) p)"
   702   by (simp add: shift1_def)
   703 
   704 lemma shift1_isnpoly:
   705   assumes pn: "isnpoly p"
   706     and pnz: "p \<noteq> 0\<^sub>p"
   707   shows "isnpoly (shift1 p) "
   708   using pn pnz by (simp add: shift1_def isnpoly_def)
   709 
   710 lemma shift1_nz[simp]:"shift1 p \<noteq> 0\<^sub>p"
   711   by (simp add: shift1_def)
   712 lemma funpow_shift1_isnpoly:
   713   "\<lbrakk> isnpoly p ; p \<noteq> 0\<^sub>p\<rbrakk> \<Longrightarrow> isnpoly (funpow n shift1 p)"
   714   by (induct n arbitrary: p) (auto simp add: shift1_isnpoly funpow_swap1)
   715 
   716 lemma funpow_isnpolyh:
   717   assumes f: "\<And> p. isnpolyh p n \<Longrightarrow> isnpolyh (f p) n"
   718     and np: "isnpolyh p n"
   719   shows "isnpolyh (funpow k f p) n"
   720   using f np by (induct k arbitrary: p) auto
   721 
   722 lemma funpow_shift1:
   723   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0, field_inverse_zero}) =
   724     Ipoly bs (Mul (Pw (Bound 0) n) p)"
   725   by (induct n arbitrary: p) (simp_all add: shift1_isnpoly shift1)
   726 
   727 lemma shift1_isnpolyh: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> isnpolyh (shift1 p) 0"
   728   using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by (simp add: shift1_def)
   729 
   730 lemma funpow_shift1_1:
   731   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0, field_inverse_zero}) =
   732     Ipoly bs (funpow n shift1 (1)\<^sub>p *\<^sub>p p)"
   733   by (simp add: funpow_shift1)
   734 
   735 lemma poly_cmul[simp]: "Ipoly bs (poly_cmul c p) = Ipoly bs (Mul (C c) p)"
   736   by (induct p rule: poly_cmul.induct) (auto simp add: field_simps)
   737 
   738 lemma behead:
   739   assumes np: "isnpolyh p n"
   740   shows "Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) =
   741     (Ipoly bs p :: 'a :: {field_char_0, field_inverse_zero})"
   742   using np
   743 proof (induct p arbitrary: n rule: behead.induct)
   744   case (1 c p n) hence pn: "isnpolyh p n" by simp
   745   from 1(1)[OF pn]
   746   have th:"Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) = Ipoly bs p" .
   747   then show ?case using "1.hyps"
   748     apply (simp add: Let_def,cases "behead p = 0\<^sub>p")
   749     apply (simp_all add: th[symmetric] field_simps)
   750     done
   751 qed (auto simp add: Let_def)
   752 
   753 lemma behead_isnpolyh:
   754   assumes np: "isnpolyh p n"
   755   shows "isnpolyh (behead p) n"
   756   using np by (induct p rule: behead.induct) (auto simp add: Let_def isnpolyh_mono)
   757 
   758 
   759 subsection{* Miscellaneous lemmas about indexes, decrementation, substitution  etc ... *}
   760 
   761 lemma isnpolyh_polybound0: "isnpolyh p (Suc n) \<Longrightarrow> polybound0 p"
   762 proof (induct p arbitrary: n rule: poly.induct, auto)
   763   case (goal1 c n p n')
   764   hence "n = Suc (n - 1)" by simp
   765   hence "isnpolyh p (Suc (n - 1))"  using `isnpolyh p n` by simp
   766   with goal1(2) show ?case by simp
   767 qed
   768 
   769 lemma isconstant_polybound0: "isnpolyh p n0 \<Longrightarrow> isconstant p \<longleftrightarrow> polybound0 p"
   770   by (induct p arbitrary: n0 rule: isconstant.induct) (auto simp add: isnpolyh_polybound0)
   771 
   772 lemma decrpoly_zero[simp]: "decrpoly p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   773   by (induct p) auto
   774 
   775 lemma decrpoly_normh: "isnpolyh p n0 \<Longrightarrow> polybound0 p \<Longrightarrow> isnpolyh (decrpoly p) (n0 - 1)"
   776   apply (induct p arbitrary: n0)
   777   apply auto
   778   apply (atomize)
   779   apply (erule_tac x = "Suc nat" in allE)
   780   apply auto
   781   done
   782 
   783 lemma head_polybound0: "isnpolyh p n0 \<Longrightarrow> polybound0 (head p)"
   784   by (induct p  arbitrary: n0 rule: head.induct) (auto intro: isnpolyh_polybound0)
   785 
   786 lemma polybound0_I:
   787   assumes nb: "polybound0 a"
   788   shows "Ipoly (b#bs) a = Ipoly (b'#bs) a"
   789   using nb
   790   by (induct a rule: poly.induct) auto
   791 
   792 lemma polysubst0_I: "Ipoly (b#bs) (polysubst0 a t) = Ipoly ((Ipoly (b#bs) a)#bs) t"
   793   by (induct t) simp_all
   794 
   795 lemma polysubst0_I':
   796   assumes nb: "polybound0 a"
   797   shows "Ipoly (b#bs) (polysubst0 a t) = Ipoly ((Ipoly (b'#bs) a)#bs) t"
   798   by (induct t) (simp_all add: polybound0_I[OF nb, where b="b" and b'="b'"])
   799 
   800 lemma decrpoly:
   801   assumes nb: "polybound0 t"
   802   shows "Ipoly (x#bs) t = Ipoly bs (decrpoly t)"
   803   using nb by (induct t rule: decrpoly.induct) simp_all
   804 
   805 lemma polysubst0_polybound0:
   806   assumes nb: "polybound0 t"
   807   shows "polybound0 (polysubst0 t a)"
   808   using nb by (induct a rule: poly.induct) auto
   809 
   810 lemma degree0_polybound0: "isnpolyh p n \<Longrightarrow> degree p = 0 \<Longrightarrow> polybound0 p"
   811   by (induct p arbitrary: n rule: degree.induct) (auto simp add: isnpolyh_polybound0)
   812 
   813 primrec maxindex :: "poly \<Rightarrow> nat" where
   814   "maxindex (Bound n) = n + 1"
   815 | "maxindex (CN c n p) = max  (n + 1) (max (maxindex c) (maxindex p))"
   816 | "maxindex (Add p q) = max (maxindex p) (maxindex q)"
   817 | "maxindex (Sub p q) = max (maxindex p) (maxindex q)"
   818 | "maxindex (Mul p q) = max (maxindex p) (maxindex q)"
   819 | "maxindex (Neg p) = maxindex p"
   820 | "maxindex (Pw p n) = maxindex p"
   821 | "maxindex (C x) = 0"
   822 
   823 definition wf_bs :: "'a list \<Rightarrow> poly \<Rightarrow> bool"
   824   where "wf_bs bs p = (length bs \<ge> maxindex p)"
   825 
   826 lemma wf_bs_coefficients: "wf_bs bs p \<Longrightarrow> \<forall> c \<in> set (coefficients p). wf_bs bs c"
   827 proof (induct p rule: coefficients.induct)
   828   case (1 c p)
   829   show ?case
   830   proof
   831     fix x assume xc: "x \<in> set (coefficients (CN c 0 p))"
   832     hence "x = c \<or> x \<in> set (coefficients p)" by simp
   833     moreover
   834     {assume "x = c" hence "wf_bs bs x" using "1.prems"  unfolding wf_bs_def by simp}
   835     moreover
   836     {assume H: "x \<in> set (coefficients p)"
   837       from "1.prems" have "wf_bs bs p" unfolding wf_bs_def by simp
   838       with "1.hyps" H have "wf_bs bs x" by blast }
   839     ultimately  show "wf_bs bs x" by blast
   840   qed
   841 qed simp_all
   842 
   843 lemma maxindex_coefficients: " \<forall>c\<in> set (coefficients p). maxindex c \<le> maxindex p"
   844   by (induct p rule: coefficients.induct) auto
   845 
   846 lemma wf_bs_I: "wf_bs bs p ==> Ipoly (bs@bs') p = Ipoly bs p"
   847   unfolding wf_bs_def by (induct p) (auto simp add: nth_append)
   848 
   849 lemma take_maxindex_wf:
   850   assumes wf: "wf_bs bs p"
   851   shows "Ipoly (take (maxindex p) bs) p = Ipoly bs p"
   852 proof-
   853   let ?ip = "maxindex p"
   854   let ?tbs = "take ?ip bs"
   855   from wf have "length ?tbs = ?ip" unfolding wf_bs_def by simp
   856   hence wf': "wf_bs ?tbs p" unfolding wf_bs_def by  simp
   857   have eq: "bs = ?tbs @ (drop ?ip bs)" by simp
   858   from wf_bs_I[OF wf', of "drop ?ip bs"] show ?thesis using eq by simp
   859 qed
   860 
   861 lemma decr_maxindex: "polybound0 p \<Longrightarrow> maxindex (decrpoly p) = maxindex p - 1"
   862   by (induct p) auto
   863 
   864 lemma wf_bs_insensitive: "length bs = length bs' \<Longrightarrow> wf_bs bs p = wf_bs bs' p"
   865   unfolding wf_bs_def by simp
   866 
   867 lemma wf_bs_insensitive': "wf_bs (x#bs) p = wf_bs (y#bs) p"
   868   unfolding wf_bs_def by simp
   869 
   870 
   871 
   872 lemma wf_bs_coefficients': "\<forall>c \<in> set (coefficients p). wf_bs bs c \<Longrightarrow> wf_bs (x#bs) p"
   873   by (induct p rule: coefficients.induct) (auto simp add: wf_bs_def)
   874 lemma coefficients_Nil[simp]: "coefficients p \<noteq> []"
   875   by (induct p rule: coefficients.induct) simp_all
   876 
   877 
   878 lemma coefficients_head: "last (coefficients p) = head p"
   879   by (induct p rule: coefficients.induct) auto
   880 
   881 lemma wf_bs_decrpoly: "wf_bs bs (decrpoly p) \<Longrightarrow> wf_bs (x#bs) p"
   882   unfolding wf_bs_def by (induct p rule: decrpoly.induct) auto
   883 
   884 lemma length_le_list_ex: "length xs \<le> n \<Longrightarrow> \<exists> ys. length (xs @ ys) = n"
   885   apply (rule exI[where x="replicate (n - length xs) z"])
   886   apply simp
   887   done
   888 
   889 lemma isnpolyh_Suc_const:"isnpolyh p (Suc n) \<Longrightarrow> isconstant p"
   890   apply (cases p)
   891   apply auto
   892   apply (case_tac "nat")
   893   apply simp_all
   894   done
   895 
   896 lemma wf_bs_polyadd: "wf_bs bs p \<and> wf_bs bs q \<longrightarrow> wf_bs bs (p +\<^sub>p q)"
   897   unfolding wf_bs_def
   898   apply (induct p q rule: polyadd.induct)
   899   apply (auto simp add: Let_def)
   900   done
   901 
   902 lemma wf_bs_polyul: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p *\<^sub>p q)"
   903   unfolding wf_bs_def
   904   apply (induct p q arbitrary: bs rule: polymul.induct)
   905   apply (simp_all add: wf_bs_polyadd)
   906   apply clarsimp
   907   apply (rule wf_bs_polyadd[unfolded wf_bs_def, rule_format])
   908   apply auto
   909   done
   910 
   911 lemma wf_bs_polyneg: "wf_bs bs p \<Longrightarrow> wf_bs bs (~\<^sub>p p)"
   912   unfolding wf_bs_def by (induct p rule: polyneg.induct) auto
   913 
   914 lemma wf_bs_polysub: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p -\<^sub>p q)"
   915   unfolding polysub_def split_def fst_conv snd_conv using wf_bs_polyadd wf_bs_polyneg by blast
   916 
   917 
   918 subsection{* Canonicity of polynomial representation, see lemma isnpolyh_unique*}
   919 
   920 definition "polypoly bs p = map (Ipoly bs) (coefficients p)"
   921 definition "polypoly' bs p = map ((Ipoly bs o decrpoly)) (coefficients p)"
   922 definition "poly_nate bs p = map ((Ipoly bs o decrpoly)) (coefficients (polynate p))"
   923 
   924 lemma coefficients_normh: "isnpolyh p n0 \<Longrightarrow> \<forall> q \<in> set (coefficients p). isnpolyh q n0"
   925 proof (induct p arbitrary: n0 rule: coefficients.induct)
   926   case (1 c p n0)
   927   have cp: "isnpolyh (CN c 0 p) n0" by fact
   928   hence norm: "isnpolyh c 0" "isnpolyh p 0" "p \<noteq> 0\<^sub>p" "n0 = 0"
   929     by (auto simp add: isnpolyh_mono[where n'=0])
   930   from "1.hyps"[OF norm(2)] norm(1) norm(4)  show ?case by simp
   931 qed auto
   932 
   933 lemma coefficients_isconst:
   934   "isnpolyh p n \<Longrightarrow> \<forall>q\<in>set (coefficients p). isconstant q"
   935   by (induct p arbitrary: n rule: coefficients.induct)
   936     (auto simp add: isnpolyh_Suc_const)
   937 
   938 lemma polypoly_polypoly':
   939   assumes np: "isnpolyh p n0"
   940   shows "polypoly (x#bs) p = polypoly' bs p"
   941 proof-
   942   let ?cf = "set (coefficients p)"
   943   from coefficients_normh[OF np] have cn_norm: "\<forall> q\<in> ?cf. isnpolyh q n0" .
   944   {fix q assume q: "q \<in> ?cf"
   945     from q cn_norm have th: "isnpolyh q n0" by blast
   946     from coefficients_isconst[OF np] q have "isconstant q" by blast
   947     with isconstant_polybound0[OF th] have "polybound0 q" by blast}
   948   hence "\<forall>q \<in> ?cf. polybound0 q" ..
   949   hence "\<forall>q \<in> ?cf. Ipoly (x#bs) q = Ipoly bs (decrpoly q)"
   950     using polybound0_I[where b=x and bs=bs and b'=y] decrpoly[where x=x and bs=bs]
   951     by auto
   952 
   953   thus ?thesis unfolding polypoly_def polypoly'_def by simp
   954 qed
   955 
   956 lemma polypoly_poly:
   957   assumes np: "isnpolyh p n0"
   958   shows "Ipoly (x#bs) p = poly (polypoly (x#bs) p) x"
   959   using np
   960   by (induct p arbitrary: n0 bs rule: coefficients.induct) (auto simp add: polypoly_def)
   961 
   962 lemma polypoly'_poly:
   963   assumes np: "isnpolyh p n0"
   964   shows "\<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup> = poly (polypoly' bs p) x"
   965   using polypoly_poly[OF np, simplified polypoly_polypoly'[OF np]] .
   966 
   967 
   968 lemma polypoly_poly_polybound0:
   969   assumes np: "isnpolyh p n0" and nb: "polybound0 p"
   970   shows "polypoly bs p = [Ipoly bs p]"
   971   using np nb unfolding polypoly_def
   972   apply (cases p)
   973   apply auto
   974   apply (case_tac nat)
   975   apply auto
   976   done
   977 
   978 lemma head_isnpolyh: "isnpolyh p n0 \<Longrightarrow> isnpolyh (head p) n0"
   979   by (induct p rule: head.induct) auto
   980 
   981 lemma headn_nz[simp]: "isnpolyh p n0 \<Longrightarrow> (headn p m = 0\<^sub>p) = (p = 0\<^sub>p)"
   982   by (cases p) auto
   983 
   984 lemma head_eq_headn0: "head p = headn p 0"
   985   by (induct p rule: head.induct) simp_all
   986 
   987 lemma head_nz[simp]: "isnpolyh p n0 \<Longrightarrow> (head p = 0\<^sub>p) = (p = 0\<^sub>p)"
   988   by (simp add: head_eq_headn0)
   989 
   990 lemma isnpolyh_zero_iff:
   991   assumes nq: "isnpolyh p n0"
   992     and eq :"\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a::{field_char_0, field_inverse_zero, power})"
   993   shows "p = 0\<^sub>p"
   994   using nq eq
   995 proof (induct "maxindex p" arbitrary: p n0 rule: less_induct)
   996   case less
   997   note np = `isnpolyh p n0` and zp = `\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)`
   998   {assume nz: "maxindex p = 0"
   999     then obtain c where "p = C c" using np by (cases p) auto
  1000     with zp np have "p = 0\<^sub>p" unfolding wf_bs_def by simp}
  1001   moreover
  1002   {assume nz: "maxindex p \<noteq> 0"
  1003     let ?h = "head p"
  1004     let ?hd = "decrpoly ?h"
  1005     let ?ihd = "maxindex ?hd"
  1006     from head_isnpolyh[OF np] head_polybound0[OF np] have h:"isnpolyh ?h n0" "polybound0 ?h"
  1007       by simp_all
  1008     hence nhd: "isnpolyh ?hd (n0 - 1)" using decrpoly_normh by blast
  1009 
  1010     from maxindex_coefficients[of p] coefficients_head[of p, symmetric]
  1011     have mihn: "maxindex ?h \<le> maxindex p" by auto
  1012     with decr_maxindex[OF h(2)] nz  have ihd_lt_n: "?ihd < maxindex p" by auto
  1013     {fix bs:: "'a list"  assume bs: "wf_bs bs ?hd"
  1014       let ?ts = "take ?ihd bs"
  1015       let ?rs = "drop ?ihd bs"
  1016       have ts: "wf_bs ?ts ?hd" using bs unfolding wf_bs_def by simp
  1017       have bs_ts_eq: "?ts@ ?rs = bs" by simp
  1018       from wf_bs_decrpoly[OF ts] have tsh: " \<forall>x. wf_bs (x#?ts) ?h" by simp
  1019       from ihd_lt_n have "ALL x. length (x#?ts) \<le> maxindex p" by simp
  1020       with length_le_list_ex obtain xs where xs:"length ((x#?ts) @ xs) = maxindex p" by blast
  1021       hence "\<forall> x. wf_bs ((x#?ts) @ xs) p" unfolding wf_bs_def by simp
  1022       with zp have "\<forall> x. Ipoly ((x#?ts) @ xs) p = 0" by blast
  1023       hence "\<forall> x. Ipoly (x#(?ts @ xs)) p = 0" by simp
  1024       with polypoly_poly[OF np, where ?'a = 'a] polypoly_polypoly'[OF np, where ?'a = 'a]
  1025       have "\<forall>x. poly (polypoly' (?ts @ xs) p) x = poly [] x"  by simp
  1026       hence "poly (polypoly' (?ts @ xs) p) = poly []" by auto
  1027       hence "\<forall> c \<in> set (coefficients p). Ipoly (?ts @ xs) (decrpoly c) = 0"
  1028         using poly_zero[where ?'a='a] by (simp add: polypoly'_def list_all_iff)
  1029       with coefficients_head[of p, symmetric]
  1030       have th0: "Ipoly (?ts @ xs) ?hd = 0" by simp
  1031       from bs have wf'': "wf_bs ?ts ?hd" unfolding wf_bs_def by simp
  1032       with th0 wf_bs_I[of ?ts ?hd xs] have "Ipoly ?ts ?hd = 0" by simp
  1033       with wf'' wf_bs_I[of ?ts ?hd ?rs] bs_ts_eq have "\<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0" by simp }
  1034     then have hdz: "\<forall>bs. wf_bs bs ?hd \<longrightarrow> \<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)" by blast
  1035 
  1036     from less(1)[OF ihd_lt_n nhd] hdz have "?hd = 0\<^sub>p" by blast
  1037     hence "?h = 0\<^sub>p" by simp
  1038     with head_nz[OF np] have "p = 0\<^sub>p" by simp}
  1039   ultimately show "p = 0\<^sub>p" by blast
  1040 qed
  1041 
  1042 lemma isnpolyh_unique:
  1043   assumes np:"isnpolyh p n0"
  1044     and nq: "isnpolyh q n1"
  1045   shows "(\<forall>bs. \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (\<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup> :: 'a::{field_char_0, field_inverse_zero, power})) \<longleftrightarrow>  p = q"
  1046 proof(auto)
  1047   assume H: "\<forall>bs. (\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> ::'a)= \<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup>"
  1048   hence "\<forall>bs.\<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup>= (0::'a)" by simp
  1049   hence "\<forall>bs. wf_bs bs (p -\<^sub>p q) \<longrightarrow> \<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1050     using wf_bs_polysub[where p=p and q=q] by auto
  1051   with isnpolyh_zero_iff[OF polysub_normh[OF np nq]] polysub_0[OF np nq]
  1052   show "p = q" by blast
  1053 qed
  1054 
  1055 
  1056 text{* consequences of unicity on the algorithms for polynomial normalization *}
  1057 
  1058 lemma polyadd_commute:
  1059   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1060     and np: "isnpolyh p n0"
  1061     and nq: "isnpolyh q n1"
  1062   shows "p +\<^sub>p q = q +\<^sub>p p"
  1063   using isnpolyh_unique[OF polyadd_normh[OF np nq] polyadd_normh[OF nq np]] by simp
  1064 
  1065 lemma zero_normh: "isnpolyh 0\<^sub>p n" by simp
  1066 lemma one_normh: "isnpolyh (1)\<^sub>p n" by simp
  1067 
  1068 lemma polyadd_0[simp]:
  1069   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1070     and np: "isnpolyh p n0"
  1071   shows "p +\<^sub>p 0\<^sub>p = p" and "0\<^sub>p +\<^sub>p p = p"
  1072   using isnpolyh_unique[OF polyadd_normh[OF np zero_normh] np]
  1073     isnpolyh_unique[OF polyadd_normh[OF zero_normh np] np] by simp_all
  1074 
  1075 lemma polymul_1[simp]:
  1076   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1077     and np: "isnpolyh p n0"
  1078   shows "p *\<^sub>p (1)\<^sub>p = p" and "(1)\<^sub>p *\<^sub>p p = p"
  1079   using isnpolyh_unique[OF polymul_normh[OF np one_normh] np]
  1080     isnpolyh_unique[OF polymul_normh[OF one_normh np] np] by simp_all
  1081 
  1082 lemma polymul_0[simp]:
  1083   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1084     and np: "isnpolyh p n0"
  1085   shows "p *\<^sub>p 0\<^sub>p = 0\<^sub>p" and "0\<^sub>p *\<^sub>p p = 0\<^sub>p"
  1086   using isnpolyh_unique[OF polymul_normh[OF np zero_normh] zero_normh]
  1087     isnpolyh_unique[OF polymul_normh[OF zero_normh np] zero_normh] by simp_all
  1088 
  1089 lemma polymul_commute:
  1090   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1091     and np:"isnpolyh p n0"
  1092     and nq: "isnpolyh q n1"
  1093   shows "p *\<^sub>p q = q *\<^sub>p p"
  1094   using isnpolyh_unique[OF polymul_normh[OF np nq] polymul_normh[OF nq np], where ?'a = "'a\<Colon>{field_char_0, field_inverse_zero, power}"]
  1095   by simp
  1096 
  1097 declare polyneg_polyneg [simp]
  1098 
  1099 lemma isnpolyh_polynate_id [simp]:
  1100   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1101     and np:"isnpolyh p n0"
  1102   shows "polynate p = p"
  1103   using isnpolyh_unique[where ?'a= "'a::{field_char_0, field_inverse_zero}", OF polynate_norm[of p, unfolded isnpoly_def] np] polynate[where ?'a = "'a::{field_char_0, field_inverse_zero}"]
  1104   by simp
  1105 
  1106 lemma polynate_idempotent[simp]:
  1107   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1108   shows "polynate (polynate p) = polynate p"
  1109   using isnpolyh_polynate_id[OF polynate_norm[of p, unfolded isnpoly_def]] .
  1110 
  1111 lemma poly_nate_polypoly': "poly_nate bs p = polypoly' bs (polynate p)"
  1112   unfolding poly_nate_def polypoly'_def ..
  1113 
  1114 lemma poly_nate_poly:
  1115   "poly (poly_nate bs p) = (\<lambda>x:: 'a ::{field_char_0, field_inverse_zero}. \<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup>)"
  1116   using polypoly'_poly[OF polynate_norm[unfolded isnpoly_def], symmetric, of bs p]
  1117   unfolding poly_nate_polypoly' by auto
  1118 
  1119 
  1120 subsection{* heads, degrees and all that *}
  1121 
  1122 lemma degree_eq_degreen0: "degree p = degreen p 0"
  1123   by (induct p rule: degree.induct) simp_all
  1124 
  1125 lemma degree_polyneg:
  1126   assumes n: "isnpolyh p n"
  1127   shows "degree (polyneg p) = degree p"
  1128   apply (induct p arbitrary: n rule: polyneg.induct)
  1129   using n apply simp_all
  1130   apply (case_tac na)
  1131   apply auto
  1132   done
  1133 
  1134 lemma degree_polyadd:
  1135   assumes np: "isnpolyh p n0" and nq: "isnpolyh q n1"
  1136   shows "degree (p +\<^sub>p q) \<le> max (degree p) (degree q)"
  1137   using degreen_polyadd[OF np nq, where m= "0"] degree_eq_degreen0 by simp
  1138 
  1139 
  1140 lemma degree_polysub:
  1141   assumes np: "isnpolyh p n0"
  1142     and nq: "isnpolyh q n1"
  1143   shows "degree (p -\<^sub>p q) \<le> max (degree p) (degree q)"
  1144 proof-
  1145   from nq have nq': "isnpolyh (~\<^sub>p q) n1" using polyneg_normh by simp
  1146   from degree_polyadd[OF np nq'] show ?thesis by (simp add: polysub_def degree_polyneg[OF nq])
  1147 qed
  1148 
  1149 lemma degree_polysub_samehead:
  1150   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1151     and np: "isnpolyh p n0" and nq: "isnpolyh q n1" and h: "head p = head q"
  1152     and d: "degree p = degree q"
  1153   shows "degree (p -\<^sub>p q) < degree p \<or> (p -\<^sub>p q = 0\<^sub>p)"
  1154   unfolding polysub_def split_def fst_conv snd_conv
  1155   using np nq h d
  1156 proof (induct p q rule: polyadd.induct)
  1157   case (1 c c')
  1158   thus ?case by (simp add: Nsub_def Nsub0[simplified Nsub_def])
  1159 next
  1160   case (2 c c' n' p')
  1161   from 2 have "degree (C c) = degree (CN c' n' p')" by simp
  1162   hence nz:"n' > 0" by (cases n') auto
  1163   hence "head (CN c' n' p') = CN c' n' p'" by (cases n') auto
  1164   with 2 show ?case by simp
  1165 next
  1166   case (3 c n p c')
  1167   hence "degree (C c') = degree (CN c n p)" by simp
  1168   hence nz:"n > 0" by (cases n) auto
  1169   hence "head (CN c n p) = CN c n p" by (cases n) auto
  1170   with 3 show ?case by simp
  1171 next
  1172   case (4 c n p c' n' p')
  1173   hence H: "isnpolyh (CN c n p) n0" "isnpolyh (CN c' n' p') n1"
  1174     "head (CN c n p) = head (CN c' n' p')" "degree (CN c n p) = degree (CN c' n' p')" by simp+
  1175   hence degc: "degree c = 0" and degc': "degree c' = 0" by simp_all
  1176   hence degnc: "degree (~\<^sub>p c) = 0" and degnc': "degree (~\<^sub>p c') = 0"
  1177     using H(1-2) degree_polyneg by auto
  1178   from H have cnh: "isnpolyh c (Suc n)" and c'nh: "isnpolyh c' (Suc n')"  by simp+
  1179   from degree_polysub[OF cnh c'nh, simplified polysub_def] degc degc' have degcmc': "degree (c +\<^sub>p  ~\<^sub>pc') = 0"  by simp
  1180   from H have pnh: "isnpolyh p n" and p'nh: "isnpolyh p' n'" by auto
  1181   have "n = n' \<or> n < n' \<or> n > n'" by arith
  1182   moreover
  1183   {assume nn': "n = n'"
  1184     have "n = 0 \<or> n >0" by arith
  1185     moreover {assume nz: "n = 0" hence ?case using 4 nn' by (auto simp add: Let_def degcmc')}
  1186     moreover {assume nz: "n > 0"
  1187       with nn' H(3) have  cc':"c = c'" and pp': "p = p'" by (cases n, auto)+
  1188       hence ?case
  1189         using polysub_same_0[OF p'nh, simplified polysub_def split_def fst_conv snd_conv] polysub_same_0[OF c'nh, simplified polysub_def]
  1190         using nn' 4 by (simp add: Let_def) }
  1191     ultimately have ?case by blast}
  1192   moreover
  1193   {assume nn': "n < n'" hence n'p: "n' > 0" by simp
  1194     hence headcnp':"head (CN c' n' p') = CN c' n' p'"  by (cases n') simp_all
  1195     have degcnp': "degree (CN c' n' p') = 0" and degcnpeq: "degree (CN c n p) = degree (CN c' n' p')"
  1196       using 4 nn' by (cases n', simp_all)
  1197     hence "n > 0" by (cases n) simp_all
  1198     hence headcnp: "head (CN c n p) = CN c n p" by (cases n) auto
  1199     from H(3) headcnp headcnp' nn' have ?case by auto}
  1200   moreover
  1201   {assume nn': "n > n'"  hence np: "n > 0" by simp
  1202     hence headcnp:"head (CN c n p) = CN c n p"  by (cases n) simp_all
  1203     from 4 have degcnpeq: "degree (CN c' n' p') = degree (CN c n p)" by simp
  1204     from np have degcnp: "degree (CN c n p) = 0" by (cases n) simp_all
  1205     with degcnpeq have "n' > 0" by (cases n') simp_all
  1206     hence headcnp': "head (CN c' n' p') = CN c' n' p'" by (cases n') auto
  1207     from H(3) headcnp headcnp' nn' have ?case by auto}
  1208   ultimately show ?case  by blast
  1209 qed auto
  1210 
  1211 lemma shift1_head : "isnpolyh p n0 \<Longrightarrow> head (shift1 p) = head p"
  1212   by (induct p arbitrary: n0 rule: head.induct) (simp_all add: shift1_def)
  1213 
  1214 lemma funpow_shift1_head: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> head (funpow k shift1 p) = head p"
  1215 proof (induct k arbitrary: n0 p)
  1216   case 0
  1217   thus ?case by auto
  1218 next
  1219   case (Suc k n0 p)
  1220   hence "isnpolyh (shift1 p) 0" by (simp add: shift1_isnpolyh)
  1221   with Suc have "head (funpow k shift1 (shift1 p)) = head (shift1 p)"
  1222     and "head (shift1 p) = head p" by (simp_all add: shift1_head)
  1223   thus ?case by (simp add: funpow_swap1)
  1224 qed
  1225 
  1226 lemma shift1_degree: "degree (shift1 p) = 1 + degree p"
  1227   by (simp add: shift1_def)
  1228 lemma funpow_shift1_degree: "degree (funpow k shift1 p) = k + degree p "
  1229   by (induct k arbitrary: p) (auto simp add: shift1_degree)
  1230 
  1231 lemma funpow_shift1_nz: "p \<noteq> 0\<^sub>p \<Longrightarrow> funpow n shift1 p \<noteq> 0\<^sub>p"
  1232   by (induct n arbitrary: p) simp_all
  1233 
  1234 lemma head_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> head p = p"
  1235   by (induct p arbitrary: n rule: degree.induct) auto
  1236 lemma headn_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> headn p m = p"
  1237   by (induct p arbitrary: n rule: degreen.induct) auto
  1238 lemma head_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> head p = p"
  1239   by (induct p arbitrary: n rule: degree.induct) auto
  1240 lemma head_head[simp]: "isnpolyh p n0 \<Longrightarrow> head (head p) = head p"
  1241   by (induct p rule: head.induct) auto
  1242 
  1243 lemma polyadd_eq_const_degree:
  1244   "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> polyadd p q = C c \<Longrightarrow> degree p = degree q"
  1245   using polyadd_eq_const_degreen degree_eq_degreen0 by simp
  1246 
  1247 lemma polyadd_head:
  1248   assumes np: "isnpolyh p n0"
  1249     and nq: "isnpolyh q n1"
  1250     and deg: "degree p \<noteq> degree q"
  1251   shows "head (p +\<^sub>p q) = (if degree p < degree q then head q else head p)"
  1252   using np nq deg
  1253   apply (induct p q arbitrary: n0 n1 rule: polyadd.induct)
  1254   using np
  1255   apply simp_all
  1256   apply (case_tac n', simp, simp)
  1257   apply (case_tac n, simp, simp)
  1258   apply (case_tac n, case_tac n', simp add: Let_def)
  1259   apply (case_tac "pa +\<^sub>p p' = 0\<^sub>p")
  1260   apply (auto simp add: polyadd_eq_const_degree)
  1261   apply (metis head_nz)
  1262   apply (metis head_nz)
  1263   apply (metis degree.simps(9) gr0_conv_Suc head.simps(1) less_Suc0 not_less_eq)
  1264   apply (metis degree.simps(9) gr0_conv_Suc nat_less_le order_le_less_trans)
  1265   done
  1266 
  1267 lemma polymul_head_polyeq:
  1268   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1269   shows "\<lbrakk>isnpolyh p n0; isnpolyh q n1 ; p \<noteq> 0\<^sub>p ; q \<noteq> 0\<^sub>p \<rbrakk> \<Longrightarrow> head (p *\<^sub>p q) = head p *\<^sub>p head q"
  1270 proof (induct p q arbitrary: n0 n1 rule: polymul.induct)
  1271   case (2 c c' n' p' n0 n1)
  1272   hence "isnpolyh (head (CN c' n' p')) n1" "isnormNum c"  by (simp_all add: head_isnpolyh)
  1273   thus ?case using 2 by (cases n') auto
  1274 next
  1275   case (3 c n p c' n0 n1)
  1276   hence "isnpolyh (head (CN c n p)) n0" "isnormNum c'"  by (simp_all add: head_isnpolyh)
  1277   thus ?case using 3 by (cases n) auto
  1278 next
  1279   case (4 c n p c' n' p' n0 n1)
  1280   hence norm: "isnpolyh p n" "isnpolyh c (Suc n)" "isnpolyh p' n'" "isnpolyh c' (Suc n')"
  1281     "isnpolyh (CN c n p) n" "isnpolyh (CN c' n' p') n'"
  1282     by simp_all
  1283   have "n < n' \<or> n' < n \<or> n = n'" by arith
  1284   moreover
  1285   {assume nn': "n < n'" hence ?case
  1286       using norm "4.hyps"(2)[OF norm(1,6)] "4.hyps"(1)[OF norm(2,6)]
  1287       apply simp
  1288       apply (cases n)
  1289       apply simp
  1290       apply (cases n')
  1291       apply simp_all
  1292       done }
  1293   moreover {assume nn': "n'< n"
  1294     hence ?case
  1295       using norm "4.hyps"(6) [OF norm(5,3)] "4.hyps"(5)[OF norm(5,4)]
  1296       apply simp
  1297       apply (cases n')
  1298       apply simp
  1299       apply (cases n)
  1300       apply auto
  1301       done }
  1302   moreover {assume nn': "n' = n"
  1303     from nn' polymul_normh[OF norm(5,4)]
  1304     have ncnpc':"isnpolyh (CN c n p *\<^sub>p c') n" by (simp add: min_def)
  1305     from nn' polymul_normh[OF norm(5,3)] norm
  1306     have ncnpp':"isnpolyh (CN c n p *\<^sub>p p') n" by simp
  1307     from nn' ncnpp' polymul_eq0_iff[OF norm(5,3)] norm(6)
  1308     have ncnpp0':"isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp
  1309     from polyadd_normh[OF ncnpc' ncnpp0']
  1310     have nth: "isnpolyh ((CN c n p *\<^sub>p c') +\<^sub>p (CN 0\<^sub>p n (CN c n p *\<^sub>p p'))) n"
  1311       by (simp add: min_def)
  1312     {assume np: "n > 0"
  1313       with nn' head_isnpolyh_Suc'[OF np nth]
  1314         head_isnpolyh_Suc'[OF np norm(5)] head_isnpolyh_Suc'[OF np norm(6)[simplified nn']]
  1315       have ?case by simp}
  1316     moreover
  1317     { assume nz: "n = 0"
  1318       from polymul_degreen[OF norm(5,4), where m="0"]
  1319         polymul_degreen[OF norm(5,3), where m="0"] nn' nz degree_eq_degreen0
  1320       norm(5,6) degree_npolyhCN[OF norm(6)]
  1321     have dth:"degree (CN c 0 p *\<^sub>p c') < degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))" by simp
  1322     hence dth':"degree (CN c 0 p *\<^sub>p c') \<noteq> degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))" by simp
  1323     from polyadd_head[OF ncnpc'[simplified nz] ncnpp0'[simplified nz] dth'] dth
  1324     have ?case   using norm "4.hyps"(6)[OF norm(5,3)]
  1325         "4.hyps"(5)[OF norm(5,4)] nn' nz by simp }
  1326     ultimately have ?case by (cases n) auto}
  1327   ultimately show ?case by blast
  1328 qed simp_all
  1329 
  1330 lemma degree_coefficients: "degree p = length (coefficients p) - 1"
  1331   by (induct p rule: degree.induct) auto
  1332 
  1333 lemma degree_head[simp]: "degree (head p) = 0"
  1334   by (induct p rule: head.induct) auto
  1335 
  1336 lemma degree_CN: "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<le> 1 + degree p"
  1337   by (cases n) simp_all
  1338 lemma degree_CN': "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<ge>  degree p"
  1339   by (cases n) simp_all
  1340 
  1341 lemma polyadd_different_degree:
  1342   "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1; degree p \<noteq> degree q\<rbrakk> \<Longrightarrow>
  1343     degree (polyadd p q) = max (degree p) (degree q)"
  1344   using polyadd_different_degreen degree_eq_degreen0 by simp
  1345 
  1346 lemma degreen_polyneg: "isnpolyh p n0 \<Longrightarrow> degreen (~\<^sub>p p) m = degreen p m"
  1347   by (induct p arbitrary: n0 rule: polyneg.induct) auto
  1348 
  1349 lemma degree_polymul:
  1350   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1351     and np: "isnpolyh p n0"
  1352     and nq: "isnpolyh q n1"
  1353   shows "degree (p *\<^sub>p q) \<le> degree p + degree q"
  1354   using polymul_degreen[OF np nq, where m="0"]  degree_eq_degreen0 by simp
  1355 
  1356 lemma polyneg_degree: "isnpolyh p n \<Longrightarrow> degree (polyneg p) = degree p"
  1357   by (induct p arbitrary: n rule: degree.induct) auto
  1358 
  1359 lemma polyneg_head: "isnpolyh p n \<Longrightarrow> head(polyneg p) = polyneg (head p)"
  1360   by (induct p arbitrary: n rule: degree.induct) auto
  1361 
  1362 
  1363 subsection {* Correctness of polynomial pseudo division *}
  1364 
  1365 lemma polydivide_aux_properties:
  1366   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1367     and np: "isnpolyh p n0"
  1368     and ns: "isnpolyh s n1"
  1369     and ap: "head p = a"
  1370     and ndp: "degree p = n" and pnz: "p \<noteq> 0\<^sub>p"
  1371   shows "(polydivide_aux a n p k s = (k',r) \<longrightarrow> (k' \<ge> k) \<and> (degree r = 0 \<or> degree r < degree p)
  1372           \<and> (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> ((polypow (k' - k) a) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)))"
  1373   using ns
  1374 proof (induct "degree s" arbitrary: s k k' r n1 rule: less_induct)
  1375   case less
  1376   let ?qths = "\<exists>q n1. isnpolyh q n1 \<and> (a ^\<^sub>p (k' - k) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1377   let ?ths = "polydivide_aux a n p k s = (k', r) \<longrightarrow>  k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p)
  1378     \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1379   let ?b = "head s"
  1380   let ?p' = "funpow (degree s - n) shift1 p"
  1381   let ?xdn = "funpow (degree s - n) shift1 (1)\<^sub>p"
  1382   let ?akk' = "a ^\<^sub>p (k' - k)"
  1383   note ns = `isnpolyh s n1`
  1384   from np have np0: "isnpolyh p 0"
  1385     using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by simp
  1386   have np': "isnpolyh ?p' 0"
  1387     using funpow_shift1_isnpoly[OF np0[simplified isnpoly_def[symmetric]] pnz, where n="degree s - n"] isnpoly_def
  1388     by simp
  1389   have headp': "head ?p' = head p"
  1390     using funpow_shift1_head[OF np pnz] by simp
  1391   from funpow_shift1_isnpoly[where p="(1)\<^sub>p"] have nxdn: "isnpolyh ?xdn 0"
  1392     by (simp add: isnpoly_def)
  1393   from polypow_normh [OF head_isnpolyh[OF np0], where k="k' - k"] ap
  1394   have nakk':"isnpolyh ?akk' 0" by blast
  1395   { assume sz: "s = 0\<^sub>p"
  1396     hence ?ths using np polydivide_aux.simps
  1397       apply clarsimp
  1398       apply (rule exI[where x="0\<^sub>p"])
  1399       apply simp
  1400       done }
  1401   moreover
  1402   { assume sz: "s \<noteq> 0\<^sub>p"
  1403     { assume dn: "degree s < n"
  1404       hence "?ths" using ns ndp np polydivide_aux.simps
  1405         apply auto
  1406         apply (rule exI[where x="0\<^sub>p"])
  1407         apply simp
  1408         done }
  1409     moreover
  1410     { assume dn': "\<not> degree s < n" hence dn: "degree s \<ge> n" by arith
  1411       have degsp': "degree s = degree ?p'"
  1412         using dn ndp funpow_shift1_degree[where k = "degree s - n" and p="p"] by simp
  1413       { assume ba: "?b = a"
  1414         hence headsp': "head s = head ?p'"
  1415           using ap headp' by simp
  1416         have nr: "isnpolyh (s -\<^sub>p ?p') 0"
  1417           using polysub_normh[OF ns np'] by simp
  1418         from degree_polysub_samehead[OF ns np' headsp' degsp']
  1419         have "degree (s -\<^sub>p ?p') < degree s \<or> s -\<^sub>p ?p' = 0\<^sub>p" by simp
  1420         moreover
  1421         { assume deglt:"degree (s -\<^sub>p ?p') < degree s"
  1422           from polydivide_aux.simps sz dn' ba
  1423           have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1424             by (simp add: Let_def)
  1425           { assume h1: "polydivide_aux a n p k s = (k', r)"
  1426             from less(1)[OF deglt nr, of k k' r] trans[OF eq[symmetric] h1]
  1427             have kk': "k \<le> k'"
  1428               and nr:"\<exists>nr. isnpolyh r nr"
  1429               and dr: "degree r = 0 \<or> degree r < degree p"
  1430               and q1: "\<exists>q nq. isnpolyh q nq \<and> (a ^\<^sub>p k' - k *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r)"
  1431               by auto
  1432             from q1 obtain q n1 where nq: "isnpolyh q n1"
  1433               and asp:"a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r" by blast
  1434             from nr obtain nr where nr': "isnpolyh r nr" by blast
  1435             from polymul_normh[OF nakk' ns] have nakks': "isnpolyh (a ^\<^sub>p (k' - k) *\<^sub>p s) 0"
  1436               by simp
  1437             from polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]
  1438             have nq': "isnpolyh (?akk' *\<^sub>p ?xdn +\<^sub>p q) 0" by simp
  1439             from polyadd_normh[OF polymul_normh[OF np
  1440               polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]] nr']
  1441             have nqr': "isnpolyh (p *\<^sub>p (?akk' *\<^sub>p ?xdn +\<^sub>p q) +\<^sub>p r) 0"
  1442               by simp
  1443             from asp have "\<forall> (bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p')) =
  1444               Ipoly bs (p *\<^sub>p q +\<^sub>p r)" by simp
  1445             hence " \<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a^\<^sub>p (k' - k)*\<^sub>p s) =
  1446               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs ?p' + Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1447               by (simp add: field_simps)
  1448             hence " \<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1449               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p *\<^sub>p p) +
  1450               Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1451               by (auto simp only: funpow_shift1_1)
  1452             hence "\<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1453               Ipoly bs p * (Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p) +
  1454               Ipoly bs q) + Ipoly bs r"
  1455               by (simp add: field_simps)
  1456             hence "\<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1457               Ipoly bs (p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r)"
  1458               by simp
  1459             with isnpolyh_unique[OF nakks' nqr']
  1460             have "a ^\<^sub>p (k' - k) *\<^sub>p s =
  1461               p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r"
  1462               by blast
  1463             hence ?qths using nq'
  1464               apply (rule_tac x="(a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q" in exI)
  1465               apply (rule_tac x="0" in exI)
  1466               apply simp
  1467               done
  1468             with kk' nr dr have "k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p) \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1469               by blast
  1470           }
  1471           hence ?ths by blast
  1472         }
  1473         moreover
  1474         { assume spz:"s -\<^sub>p ?p' = 0\<^sub>p"
  1475           from spz isnpolyh_unique[OF polysub_normh[OF ns np'], where q="0\<^sub>p", symmetric, where ?'a = "'a::{field_char_0, field_inverse_zero}"]
  1476           have " \<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs s = Ipoly bs ?p'"
  1477             by simp
  1478           hence "\<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs s = Ipoly bs (?xdn *\<^sub>p p)"
  1479             using np nxdn
  1480             apply simp
  1481             apply (simp only: funpow_shift1_1)
  1482             apply simp
  1483             done
  1484           hence sp': "s = ?xdn *\<^sub>p p" using isnpolyh_unique[OF ns polymul_normh[OF nxdn np]]
  1485             by blast
  1486           { assume h1: "polydivide_aux a n p k s = (k',r)"
  1487             from polydivide_aux.simps sz dn' ba
  1488             have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1489               by (simp add: Let_def)
  1490             also have "\<dots> = (k,0\<^sub>p)"
  1491               using polydivide_aux.simps spz by simp
  1492             finally have "(k',r) = (k,0\<^sub>p)" using h1 by simp
  1493             with sp'[symmetric] ns np nxdn polyadd_0(1)[OF polymul_normh[OF np nxdn]]
  1494               polyadd_0(2)[OF polymul_normh[OF np nxdn]] have ?ths
  1495               apply auto
  1496               apply (rule exI[where x="?xdn"])
  1497               apply (auto simp add: polymul_commute[of p])
  1498               done
  1499           }
  1500         }
  1501         ultimately have ?ths by blast
  1502       }
  1503       moreover
  1504       { assume ba: "?b \<noteq> a"
  1505         from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns]
  1506           polymul_normh[OF head_isnpolyh[OF ns] np']]
  1507         have nth: "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1508           by (simp add: min_def)
  1509         have nzths: "a *\<^sub>p s \<noteq> 0\<^sub>p" "?b *\<^sub>p ?p' \<noteq> 0\<^sub>p"
  1510           using polymul_eq0_iff[OF head_isnpolyh[OF np0, simplified ap] ns]
  1511             polymul_eq0_iff[OF head_isnpolyh[OF ns] np']head_nz[OF np0] ap pnz sz head_nz[OF ns]
  1512             funpow_shift1_nz[OF pnz]
  1513           by simp_all
  1514         from polymul_head_polyeq[OF head_isnpolyh[OF np] ns] head_nz[OF np] sz ap head_head[OF np] pnz
  1515           polymul_head_polyeq[OF head_isnpolyh[OF ns] np'] head_nz [OF ns] sz funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1516         have hdth: "head (a *\<^sub>p s) = head (?b *\<^sub>p ?p')"
  1517           using head_head[OF ns] funpow_shift1_head[OF np pnz]
  1518             polymul_commute[OF head_isnpolyh[OF np] head_isnpolyh[OF ns]]
  1519           by (simp add: ap)
  1520         from polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1521           head_nz[OF np] pnz sz ap[symmetric]
  1522           funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1523           polymul_degreen[OF head_isnpolyh[OF ns] np', where m="0"] head_nz[OF ns]
  1524           ndp dn
  1525         have degth: "degree (a *\<^sub>p s) = degree (?b *\<^sub>p ?p')"
  1526           by (simp add: degree_eq_degreen0[symmetric] funpow_shift1_degree)
  1527         { assume dth: "degree ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) < degree s"
  1528           from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1529             polymul_normh[OF head_isnpolyh[OF ns]np']] ap
  1530           have nasbp': "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1531             by simp
  1532           { assume h1:"polydivide_aux a n p k s = (k', r)"
  1533             from h1 polydivide_aux.simps sz dn' ba
  1534             have eq:"polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = (k',r)"
  1535               by (simp add: Let_def)
  1536             with less(1)[OF dth nasbp', of "Suc k" k' r]
  1537             obtain q nq nr where kk': "Suc k \<le> k'"
  1538               and nr: "isnpolyh r nr"
  1539               and nq: "isnpolyh q nq"
  1540               and dr: "degree r = 0 \<or> degree r < degree p"
  1541               and qr: "a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = p *\<^sub>p q +\<^sub>p r"
  1542               by auto
  1543             from kk' have kk'':"Suc (k' - Suc k) = k' - k" by arith
  1544             {
  1545               fix bs:: "'a::{field_char_0, field_inverse_zero} list"
  1546               from qr isnpolyh_unique[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k", simplified ap] nasbp', symmetric]
  1547               have "Ipoly bs (a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p'))) = Ipoly bs (p *\<^sub>p q +\<^sub>p r)"
  1548                 by simp
  1549               hence "Ipoly bs a ^ (Suc (k' - Suc k)) * Ipoly bs s =
  1550                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?p' + Ipoly bs r"
  1551                 by (simp add: field_simps)
  1552               hence "Ipoly bs a ^ (k' - k)  * Ipoly bs s =
  1553                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn * Ipoly bs p + Ipoly bs r"
  1554                 by (simp add: kk'' funpow_shift1_1[where n="degree s - n" and p="p"])
  1555               hence "Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1556                 Ipoly bs p * (Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn) + Ipoly bs r"
  1557                 by (simp add: field_simps)
  1558             }
  1559             hence ieq:"\<forall>(bs :: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1560               Ipoly bs (p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r)"
  1561               by auto
  1562             let ?q = "q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)"
  1563             from polyadd_normh[OF nq polymul_normh[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k"] head_isnpolyh[OF ns], simplified ap ] nxdn]]
  1564             have nqw: "isnpolyh ?q 0"
  1565               by simp
  1566             from ieq isnpolyh_unique[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - k"] ns, simplified ap] polyadd_normh[OF polymul_normh[OF np nqw] nr]]
  1567             have asth: "(a ^\<^sub>p (k' - k) *\<^sub>p s) = p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r"
  1568               by blast
  1569             from dr kk' nr h1 asth nqw have ?ths
  1570               apply simp
  1571               apply (rule conjI)
  1572               apply (rule exI[where x="nr"], simp)
  1573               apply (rule exI[where x="(q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn))"], simp)
  1574               apply (rule exI[where x="0"], simp)
  1575               done
  1576           }
  1577           hence ?ths by blast
  1578         }
  1579         moreover
  1580         { assume spz: "a *\<^sub>p s -\<^sub>p (?b *\<^sub>p ?p') = 0\<^sub>p"
  1581           {
  1582             fix bs :: "'a::{field_char_0, field_inverse_zero} list"
  1583             from isnpolyh_unique[OF nth, where ?'a="'a" and q="0\<^sub>p",simplified,symmetric] spz
  1584             have "Ipoly bs (a*\<^sub>p s) = Ipoly bs ?b * Ipoly bs ?p'"
  1585               by simp
  1586             hence "Ipoly bs (a*\<^sub>p s) = Ipoly bs (?b *\<^sub>p ?xdn) * Ipoly bs p"
  1587               by (simp add: funpow_shift1_1[where n="degree s - n" and p="p"])
  1588             hence "Ipoly bs (a*\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))"
  1589               by simp
  1590           }
  1591           hence hth: "\<forall> (bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a*\<^sub>p s) =
  1592             Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))" ..
  1593           from hth have asq: "a *\<^sub>p s = p *\<^sub>p (?b *\<^sub>p ?xdn)"
  1594             using isnpolyh_unique[where ?'a = "'a::{field_char_0, field_inverse_zero}", OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1595                     polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]],
  1596               simplified ap] by simp
  1597           { assume h1: "polydivide_aux a n p k s = (k', r)"
  1598             from h1 sz ba dn' spz polydivide_aux.simps polydivide_aux.simps
  1599             have "(k',r) = (Suc k, 0\<^sub>p)" by (simp add: Let_def)
  1600             with h1 np head_isnpolyh[OF np, simplified ap] ns polymul_normh[OF head_isnpolyh[OF ns] nxdn]
  1601               polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]] asq
  1602             have ?ths
  1603               apply (clarsimp simp add: Let_def)
  1604               apply (rule exI[where x="?b *\<^sub>p ?xdn"])
  1605               apply simp
  1606               apply (rule exI[where x="0"], simp)
  1607               done
  1608           }
  1609           hence ?ths by blast
  1610         }
  1611         ultimately have ?ths
  1612           using  degree_polysub_samehead[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns] polymul_normh[OF head_isnpolyh[OF ns] np'] hdth degth] polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1613             head_nz[OF np] pnz sz ap[symmetric]
  1614           by (simp add: degree_eq_degreen0[symmetric]) blast
  1615       }
  1616       ultimately have ?ths by blast
  1617     }
  1618     ultimately have ?ths by blast
  1619   }
  1620   ultimately show ?ths by blast
  1621 qed
  1622 
  1623 lemma polydivide_properties:
  1624   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1625     and np: "isnpolyh p n0" and ns: "isnpolyh s n1" and pnz: "p \<noteq> 0\<^sub>p"
  1626   shows "\<exists>k r. polydivide s p = (k,r) \<and>
  1627     (\<exists>nr. isnpolyh r nr) \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1628     (\<exists>q n1. isnpolyh q n1 \<and> ((polypow k (head p)) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r))"
  1629 proof -
  1630   have trv: "head p = head p" "degree p = degree p"
  1631     by simp_all
  1632   from polydivide_def[where s="s" and p="p"] have ex: "\<exists> k r. polydivide s p = (k,r)"
  1633     by auto
  1634   then obtain k r where kr: "polydivide s p = (k,r)"
  1635     by blast
  1636   from trans[OF meta_eq_to_obj_eq[OF polydivide_def[where s="s"and p="p"], symmetric] kr]
  1637     polydivide_aux_properties[OF np ns trv pnz, where k="0" and k'="k" and r="r"]
  1638   have "(degree r = 0 \<or> degree r < degree p) \<and>
  1639     (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> head p ^\<^sub>p k - 0 *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1640     by blast
  1641   with kr show ?thesis
  1642     apply -
  1643     apply (rule exI[where x="k"])
  1644     apply (rule exI[where x="r"])
  1645     apply simp
  1646     done
  1647 qed
  1648 
  1649 
  1650 subsection{* More about polypoly and pnormal etc *}
  1651 
  1652 definition "isnonconstant p = (\<not> isconstant p)"
  1653 
  1654 lemma isnonconstant_pnormal_iff:
  1655   assumes nc: "isnonconstant p"
  1656   shows "pnormal (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1657 proof
  1658   let ?p = "polypoly bs p"
  1659   assume H: "pnormal ?p"
  1660   have csz: "coefficients p \<noteq> []" using nc by (cases p) auto
  1661 
  1662   from coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]
  1663     pnormal_last_nonzero[OF H]
  1664   show "Ipoly bs (head p) \<noteq> 0" by (simp add: polypoly_def)
  1665 next
  1666   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1667   let ?p = "polypoly bs p"
  1668   have csz: "coefficients p \<noteq> []" using nc by (cases p) auto
  1669   hence pz: "?p \<noteq> []" by (simp add: polypoly_def)
  1670   hence lg: "length ?p > 0" by simp
  1671   from h coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]
  1672   have lz: "last ?p \<noteq> 0" by (simp add: polypoly_def)
  1673   from pnormal_last_length[OF lg lz] show "pnormal ?p" .
  1674 qed
  1675 
  1676 lemma isnonconstant_coefficients_length: "isnonconstant p \<Longrightarrow> length (coefficients p) > 1"
  1677   unfolding isnonconstant_def
  1678   apply (cases p)
  1679   apply simp_all
  1680   apply (case_tac nat)
  1681   apply auto
  1682   done
  1683 
  1684 lemma isnonconstant_nonconstant:
  1685   assumes inc: "isnonconstant p"
  1686   shows "nonconstant (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1687 proof
  1688   let ?p = "polypoly bs p"
  1689   assume nc: "nonconstant ?p"
  1690   from isnonconstant_pnormal_iff[OF inc, of bs] nc
  1691   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0" unfolding nonconstant_def by blast
  1692 next
  1693   let ?p = "polypoly bs p"
  1694   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1695   from isnonconstant_pnormal_iff[OF inc, of bs] h
  1696   have pn: "pnormal ?p" by blast
  1697   { fix x assume H: "?p = [x]"
  1698     from H have "length (coefficients p) = 1" unfolding polypoly_def by auto
  1699     with isnonconstant_coefficients_length[OF inc] have False by arith }
  1700   thus "nonconstant ?p" using pn unfolding nonconstant_def by blast
  1701 qed
  1702 
  1703 lemma pnormal_length: "p\<noteq>[] \<Longrightarrow> pnormal p \<longleftrightarrow> length (pnormalize p) = length p"
  1704   apply (induct p)
  1705   apply (simp_all add: pnormal_def)
  1706   apply (case_tac "p = []")
  1707   apply simp_all
  1708   done
  1709 
  1710 lemma degree_degree:
  1711   assumes inc: "isnonconstant p"
  1712   shows "degree p = Polynomial_List.degree (polypoly bs p) \<longleftrightarrow> \<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1713 proof
  1714   let ?p = "polypoly bs p"
  1715   assume H: "degree p = Polynomial_List.degree ?p"
  1716   from isnonconstant_coefficients_length[OF inc] have pz: "?p \<noteq> []"
  1717     unfolding polypoly_def by auto
  1718   from H degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  1719   have lg:"length (pnormalize ?p) = length ?p"
  1720     unfolding Polynomial_List.degree_def polypoly_def by simp
  1721   hence "pnormal ?p" using pnormal_length[OF pz] by blast
  1722   with isnonconstant_pnormal_iff[OF inc]
  1723   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0" by blast
  1724 next
  1725   let  ?p = "polypoly bs p"
  1726   assume H: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1727   with isnonconstant_pnormal_iff[OF inc] have "pnormal ?p" by blast
  1728   with degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  1729   show "degree p = Polynomial_List.degree ?p"
  1730     unfolding polypoly_def pnormal_def Polynomial_List.degree_def by auto
  1731 qed
  1732 
  1733 
  1734 section {* Swaps ; Division by a certain variable *}
  1735 
  1736 primrec swap :: "nat \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> poly" where
  1737   "swap n m (C x) = C x"
  1738 | "swap n m (Bound k) = Bound (if k = n then m else if k=m then n else k)"
  1739 | "swap n m (Neg t) = Neg (swap n m t)"
  1740 | "swap n m (Add s t) = Add (swap n m s) (swap n m t)"
  1741 | "swap n m (Sub s t) = Sub (swap n m s) (swap n m t)"
  1742 | "swap n m (Mul s t) = Mul (swap n m s) (swap n m t)"
  1743 | "swap n m (Pw t k) = Pw (swap n m t) k"
  1744 | "swap n m (CN c k p) =
  1745     CN (swap n m c) (if k = n then m else if k=m then n else k) (swap n m p)"
  1746 
  1747 lemma swap:
  1748   assumes nbs: "n < length bs"
  1749     and mbs: "m < length bs"
  1750   shows "Ipoly bs (swap n m t) = Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  1751 proof (induct t)
  1752   case (Bound k)
  1753   thus ?case using nbs mbs by simp
  1754 next
  1755   case (CN c k p)
  1756   thus ?case using nbs mbs by simp
  1757 qed simp_all
  1758 
  1759 lemma swap_swap_id [simp]: "swap n m (swap m n t) = t"
  1760   by (induct t) simp_all
  1761 
  1762 lemma swap_commute: "swap n m p = swap m n p"
  1763   by (induct p) simp_all
  1764 
  1765 lemma swap_same_id[simp]: "swap n n t = t"
  1766   by (induct t) simp_all
  1767 
  1768 definition "swapnorm n m t = polynate (swap n m t)"
  1769 
  1770 lemma swapnorm:
  1771   assumes nbs: "n < length bs"
  1772     and mbs: "m < length bs"
  1773   shows "((Ipoly bs (swapnorm n m t) :: 'a\<Colon>{field_char_0, field_inverse_zero})) =
  1774     Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  1775   using swap[OF assms] swapnorm_def by simp
  1776 
  1777 lemma swapnorm_isnpoly [simp]:
  1778   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1779   shows "isnpoly (swapnorm n m p)"
  1780   unfolding swapnorm_def by simp
  1781 
  1782 definition "polydivideby n s p =
  1783   (let ss = swapnorm 0 n s ; sp = swapnorm 0 n p ; h = head sp; (k,r) = polydivide ss sp
  1784    in (k, swapnorm 0 n h,swapnorm 0 n r))"
  1785 
  1786 lemma swap_nz [simp]: " (swap n m p = 0\<^sub>p) = (p = 0\<^sub>p)"
  1787   by (induct p) simp_all
  1788 
  1789 fun isweaknpoly :: "poly \<Rightarrow> bool"
  1790 where
  1791   "isweaknpoly (C c) = True"
  1792 | "isweaknpoly (CN c n p) \<longleftrightarrow> isweaknpoly c \<and> isweaknpoly p"
  1793 | "isweaknpoly p = False"
  1794 
  1795 lemma isnpolyh_isweaknpoly: "isnpolyh p n0 \<Longrightarrow> isweaknpoly p"
  1796   by (induct p arbitrary: n0) auto
  1797 
  1798 lemma swap_isweanpoly: "isweaknpoly p \<Longrightarrow> isweaknpoly (swap n m p)"
  1799   by (induct p) auto
  1800 
  1801 end