src/HOL/Real_Vector_Spaces.thy
author wenzelm
Tue Sep 03 01:12:40 2013 +0200 (2013-09-03)
changeset 53374 a14d2a854c02
parent 52381 63eec9cea2c7
child 53381 355a4cac5440
permissions -rw-r--r--
tuned proofs -- clarified flow of facts wrt. calculation;
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Vector Spaces and Algebras over the Reals *}
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection {* Locale for additive functions *}
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34 by (simp add: add minus diff_minus)
    35 
    36 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    37 apply (cases "finite A")
    38 apply (induct set: finite)
    39 apply (simp add: zero)
    40 apply (simp add: add)
    41 apply (simp add: zero)
    42 done
    43 
    44 end
    45 
    46 subsection {* Vector spaces *}
    47 
    48 locale vector_space =
    49   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    50   assumes scale_right_distrib [algebra_simps]:
    51     "scale a (x + y) = scale a x + scale a y"
    52   and scale_left_distrib [algebra_simps]:
    53     "scale (a + b) x = scale a x + scale b x"
    54   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    55   and scale_one [simp]: "scale 1 x = x"
    56 begin
    57 
    58 lemma scale_left_commute:
    59   "scale a (scale b x) = scale b (scale a x)"
    60 by (simp add: mult_commute)
    61 
    62 lemma scale_zero_left [simp]: "scale 0 x = 0"
    63   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    64   and scale_left_diff_distrib [algebra_simps]:
    65         "scale (a - b) x = scale a x - scale b x"
    66   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    67 proof -
    68   interpret s: additive "\<lambda>a. scale a x"
    69     proof qed (rule scale_left_distrib)
    70   show "scale 0 x = 0" by (rule s.zero)
    71   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    72   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    73   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    74 qed
    75 
    76 lemma scale_zero_right [simp]: "scale a 0 = 0"
    77   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    78   and scale_right_diff_distrib [algebra_simps]:
    79         "scale a (x - y) = scale a x - scale a y"
    80   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    81 proof -
    82   interpret s: additive "\<lambda>x. scale a x"
    83     proof qed (rule scale_right_distrib)
    84   show "scale a 0 = 0" by (rule s.zero)
    85   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    86   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    87   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    88 qed
    89 
    90 lemma scale_eq_0_iff [simp]:
    91   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    92 proof cases
    93   assume "a = 0" thus ?thesis by simp
    94 next
    95   assume anz [simp]: "a \<noteq> 0"
    96   { assume "scale a x = 0"
    97     hence "scale (inverse a) (scale a x) = 0" by simp
    98     hence "x = 0" by simp }
    99   thus ?thesis by force
   100 qed
   101 
   102 lemma scale_left_imp_eq:
   103   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   104 proof -
   105   assume nonzero: "a \<noteq> 0"
   106   assume "scale a x = scale a y"
   107   hence "scale a (x - y) = 0"
   108      by (simp add: scale_right_diff_distrib)
   109   hence "x - y = 0" by (simp add: nonzero)
   110   thus "x = y" by (simp only: right_minus_eq)
   111 qed
   112 
   113 lemma scale_right_imp_eq:
   114   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   115 proof -
   116   assume nonzero: "x \<noteq> 0"
   117   assume "scale a x = scale b x"
   118   hence "scale (a - b) x = 0"
   119      by (simp add: scale_left_diff_distrib)
   120   hence "a - b = 0" by (simp add: nonzero)
   121   thus "a = b" by (simp only: right_minus_eq)
   122 qed
   123 
   124 lemma scale_cancel_left [simp]:
   125   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   126 by (auto intro: scale_left_imp_eq)
   127 
   128 lemma scale_cancel_right [simp]:
   129   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   130 by (auto intro: scale_right_imp_eq)
   131 
   132 end
   133 
   134 subsection {* Real vector spaces *}
   135 
   136 class scaleR =
   137   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   138 begin
   139 
   140 abbreviation
   141   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   142 where
   143   "x /\<^sub>R r == scaleR (inverse r) x"
   144 
   145 end
   146 
   147 class real_vector = scaleR + ab_group_add +
   148   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   149   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   150   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   151   and scaleR_one: "scaleR 1 x = x"
   152 
   153 interpretation real_vector:
   154   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   155 apply unfold_locales
   156 apply (rule scaleR_add_right)
   157 apply (rule scaleR_add_left)
   158 apply (rule scaleR_scaleR)
   159 apply (rule scaleR_one)
   160 done
   161 
   162 text {* Recover original theorem names *}
   163 
   164 lemmas scaleR_left_commute = real_vector.scale_left_commute
   165 lemmas scaleR_zero_left = real_vector.scale_zero_left
   166 lemmas scaleR_minus_left = real_vector.scale_minus_left
   167 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   168 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   169 lemmas scaleR_zero_right = real_vector.scale_zero_right
   170 lemmas scaleR_minus_right = real_vector.scale_minus_right
   171 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   172 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   173 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   174 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   175 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   176 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   177 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   178 
   179 text {* Legacy names *}
   180 
   181 lemmas scaleR_left_distrib = scaleR_add_left
   182 lemmas scaleR_right_distrib = scaleR_add_right
   183 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   184 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   185 
   186 lemma scaleR_minus1_left [simp]:
   187   fixes x :: "'a::real_vector"
   188   shows "scaleR (-1) x = - x"
   189   using scaleR_minus_left [of 1 x] by simp
   190 
   191 class real_algebra = real_vector + ring +
   192   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   193   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   194 
   195 class real_algebra_1 = real_algebra + ring_1
   196 
   197 class real_div_algebra = real_algebra_1 + division_ring
   198 
   199 class real_field = real_div_algebra + field
   200 
   201 instantiation real :: real_field
   202 begin
   203 
   204 definition
   205   real_scaleR_def [simp]: "scaleR a x = a * x"
   206 
   207 instance proof
   208 qed (simp_all add: algebra_simps)
   209 
   210 end
   211 
   212 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   213 proof qed (rule scaleR_left_distrib)
   214 
   215 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   216 proof qed (rule scaleR_right_distrib)
   217 
   218 lemma nonzero_inverse_scaleR_distrib:
   219   fixes x :: "'a::real_div_algebra" shows
   220   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   221 by (rule inverse_unique, simp)
   222 
   223 lemma inverse_scaleR_distrib:
   224   fixes x :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   225   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226 apply (case_tac "a = 0", simp)
   227 apply (case_tac "x = 0", simp)
   228 apply (erule (1) nonzero_inverse_scaleR_distrib)
   229 done
   230 
   231 
   232 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   233 @{term of_real} *}
   234 
   235 definition
   236   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   237   "of_real r = scaleR r 1"
   238 
   239 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   240 by (simp add: of_real_def)
   241 
   242 lemma of_real_0 [simp]: "of_real 0 = 0"
   243 by (simp add: of_real_def)
   244 
   245 lemma of_real_1 [simp]: "of_real 1 = 1"
   246 by (simp add: of_real_def)
   247 
   248 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   249 by (simp add: of_real_def scaleR_left_distrib)
   250 
   251 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   252 by (simp add: of_real_def)
   253 
   254 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   255 by (simp add: of_real_def scaleR_left_diff_distrib)
   256 
   257 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   258 by (simp add: of_real_def mult_commute)
   259 
   260 lemma nonzero_of_real_inverse:
   261   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   262    inverse (of_real x :: 'a::real_div_algebra)"
   263 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   264 
   265 lemma of_real_inverse [simp]:
   266   "of_real (inverse x) =
   267    inverse (of_real x :: 'a::{real_div_algebra, division_ring_inverse_zero})"
   268 by (simp add: of_real_def inverse_scaleR_distrib)
   269 
   270 lemma nonzero_of_real_divide:
   271   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   272    (of_real x / of_real y :: 'a::real_field)"
   273 by (simp add: divide_inverse nonzero_of_real_inverse)
   274 
   275 lemma of_real_divide [simp]:
   276   "of_real (x / y) =
   277    (of_real x / of_real y :: 'a::{real_field, field_inverse_zero})"
   278 by (simp add: divide_inverse)
   279 
   280 lemma of_real_power [simp]:
   281   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   282 by (induct n) simp_all
   283 
   284 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   285 by (simp add: of_real_def)
   286 
   287 lemma inj_of_real:
   288   "inj of_real"
   289   by (auto intro: injI)
   290 
   291 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   292 
   293 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   294 proof
   295   fix r
   296   show "of_real r = id r"
   297     by (simp add: of_real_def)
   298 qed
   299 
   300 text{*Collapse nested embeddings*}
   301 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   302 by (induct n) auto
   303 
   304 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   305 by (cases z rule: int_diff_cases, simp)
   306 
   307 lemma of_real_numeral: "of_real (numeral w) = numeral w"
   308 using of_real_of_int_eq [of "numeral w"] by simp
   309 
   310 lemma of_real_neg_numeral: "of_real (neg_numeral w) = neg_numeral w"
   311 using of_real_of_int_eq [of "neg_numeral w"] by simp
   312 
   313 text{*Every real algebra has characteristic zero*}
   314 
   315 instance real_algebra_1 < ring_char_0
   316 proof
   317   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   318   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   319 qed
   320 
   321 instance real_field < field_char_0 ..
   322 
   323 
   324 subsection {* The Set of Real Numbers *}
   325 
   326 definition Reals :: "'a::real_algebra_1 set" where
   327   "Reals = range of_real"
   328 
   329 notation (xsymbols)
   330   Reals  ("\<real>")
   331 
   332 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   333 by (simp add: Reals_def)
   334 
   335 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   336 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   337 
   338 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   339 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   340 
   341 lemma Reals_numeral [simp]: "numeral w \<in> Reals"
   342 by (subst of_real_numeral [symmetric], rule Reals_of_real)
   343 
   344 lemma Reals_neg_numeral [simp]: "neg_numeral w \<in> Reals"
   345 by (subst of_real_neg_numeral [symmetric], rule Reals_of_real)
   346 
   347 lemma Reals_0 [simp]: "0 \<in> Reals"
   348 apply (unfold Reals_def)
   349 apply (rule range_eqI)
   350 apply (rule of_real_0 [symmetric])
   351 done
   352 
   353 lemma Reals_1 [simp]: "1 \<in> Reals"
   354 apply (unfold Reals_def)
   355 apply (rule range_eqI)
   356 apply (rule of_real_1 [symmetric])
   357 done
   358 
   359 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   360 apply (auto simp add: Reals_def)
   361 apply (rule range_eqI)
   362 apply (rule of_real_add [symmetric])
   363 done
   364 
   365 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   366 apply (auto simp add: Reals_def)
   367 apply (rule range_eqI)
   368 apply (rule of_real_minus [symmetric])
   369 done
   370 
   371 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   372 apply (auto simp add: Reals_def)
   373 apply (rule range_eqI)
   374 apply (rule of_real_diff [symmetric])
   375 done
   376 
   377 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   378 apply (auto simp add: Reals_def)
   379 apply (rule range_eqI)
   380 apply (rule of_real_mult [symmetric])
   381 done
   382 
   383 lemma nonzero_Reals_inverse:
   384   fixes a :: "'a::real_div_algebra"
   385   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   386 apply (auto simp add: Reals_def)
   387 apply (rule range_eqI)
   388 apply (erule nonzero_of_real_inverse [symmetric])
   389 done
   390 
   391 lemma Reals_inverse [simp]:
   392   fixes a :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   393   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   394 apply (auto simp add: Reals_def)
   395 apply (rule range_eqI)
   396 apply (rule of_real_inverse [symmetric])
   397 done
   398 
   399 lemma nonzero_Reals_divide:
   400   fixes a b :: "'a::real_field"
   401   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   402 apply (auto simp add: Reals_def)
   403 apply (rule range_eqI)
   404 apply (erule nonzero_of_real_divide [symmetric])
   405 done
   406 
   407 lemma Reals_divide [simp]:
   408   fixes a b :: "'a::{real_field, field_inverse_zero}"
   409   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   410 apply (auto simp add: Reals_def)
   411 apply (rule range_eqI)
   412 apply (rule of_real_divide [symmetric])
   413 done
   414 
   415 lemma Reals_power [simp]:
   416   fixes a :: "'a::{real_algebra_1}"
   417   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   418 apply (auto simp add: Reals_def)
   419 apply (rule range_eqI)
   420 apply (rule of_real_power [symmetric])
   421 done
   422 
   423 lemma Reals_cases [cases set: Reals]:
   424   assumes "q \<in> \<real>"
   425   obtains (of_real) r where "q = of_real r"
   426   unfolding Reals_def
   427 proof -
   428   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   429   then obtain r where "q = of_real r" ..
   430   then show thesis ..
   431 qed
   432 
   433 lemma Reals_induct [case_names of_real, induct set: Reals]:
   434   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   435   by (rule Reals_cases) auto
   436 
   437 
   438 subsection {* Real normed vector spaces *}
   439 
   440 class dist =
   441   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   442 
   443 class norm =
   444   fixes norm :: "'a \<Rightarrow> real"
   445 
   446 class sgn_div_norm = scaleR + norm + sgn +
   447   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   448 
   449 class dist_norm = dist + norm + minus +
   450   assumes dist_norm: "dist x y = norm (x - y)"
   451 
   452 class open_dist = "open" + dist +
   453   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   454 
   455 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   456   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   457   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   458   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   459 begin
   460 
   461 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   462 proof -
   463   have "0 = norm (x + -1 *\<^sub>R x)" 
   464     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   465   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   466   finally show ?thesis by simp
   467 qed
   468 
   469 end
   470 
   471 class real_normed_algebra = real_algebra + real_normed_vector +
   472   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   473 
   474 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   475   assumes norm_one [simp]: "norm 1 = 1"
   476 
   477 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   478   assumes norm_mult: "norm (x * y) = norm x * norm y"
   479 
   480 class real_normed_field = real_field + real_normed_div_algebra
   481 
   482 instance real_normed_div_algebra < real_normed_algebra_1
   483 proof
   484   fix x y :: 'a
   485   show "norm (x * y) \<le> norm x * norm y"
   486     by (simp add: norm_mult)
   487 next
   488   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   489     by (rule norm_mult)
   490   thus "norm (1::'a) = 1" by simp
   491 qed
   492 
   493 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   494 by simp
   495 
   496 lemma zero_less_norm_iff [simp]:
   497   fixes x :: "'a::real_normed_vector"
   498   shows "(0 < norm x) = (x \<noteq> 0)"
   499 by (simp add: order_less_le)
   500 
   501 lemma norm_not_less_zero [simp]:
   502   fixes x :: "'a::real_normed_vector"
   503   shows "\<not> norm x < 0"
   504 by (simp add: linorder_not_less)
   505 
   506 lemma norm_le_zero_iff [simp]:
   507   fixes x :: "'a::real_normed_vector"
   508   shows "(norm x \<le> 0) = (x = 0)"
   509 by (simp add: order_le_less)
   510 
   511 lemma norm_minus_cancel [simp]:
   512   fixes x :: "'a::real_normed_vector"
   513   shows "norm (- x) = norm x"
   514 proof -
   515   have "norm (- x) = norm (scaleR (- 1) x)"
   516     by (simp only: scaleR_minus_left scaleR_one)
   517   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   518     by (rule norm_scaleR)
   519   finally show ?thesis by simp
   520 qed
   521 
   522 lemma norm_minus_commute:
   523   fixes a b :: "'a::real_normed_vector"
   524   shows "norm (a - b) = norm (b - a)"
   525 proof -
   526   have "norm (- (b - a)) = norm (b - a)"
   527     by (rule norm_minus_cancel)
   528   thus ?thesis by simp
   529 qed
   530 
   531 lemma norm_triangle_ineq2:
   532   fixes a b :: "'a::real_normed_vector"
   533   shows "norm a - norm b \<le> norm (a - b)"
   534 proof -
   535   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   536     by (rule norm_triangle_ineq)
   537   thus ?thesis by simp
   538 qed
   539 
   540 lemma norm_triangle_ineq3:
   541   fixes a b :: "'a::real_normed_vector"
   542   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   543 apply (subst abs_le_iff)
   544 apply auto
   545 apply (rule norm_triangle_ineq2)
   546 apply (subst norm_minus_commute)
   547 apply (rule norm_triangle_ineq2)
   548 done
   549 
   550 lemma norm_triangle_ineq4:
   551   fixes a b :: "'a::real_normed_vector"
   552   shows "norm (a - b) \<le> norm a + norm b"
   553 proof -
   554   have "norm (a + - b) \<le> norm a + norm (- b)"
   555     by (rule norm_triangle_ineq)
   556   thus ?thesis
   557     by (simp only: diff_minus norm_minus_cancel)
   558 qed
   559 
   560 lemma norm_diff_ineq:
   561   fixes a b :: "'a::real_normed_vector"
   562   shows "norm a - norm b \<le> norm (a + b)"
   563 proof -
   564   have "norm a - norm (- b) \<le> norm (a - - b)"
   565     by (rule norm_triangle_ineq2)
   566   thus ?thesis by simp
   567 qed
   568 
   569 lemma norm_diff_triangle_ineq:
   570   fixes a b c d :: "'a::real_normed_vector"
   571   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   572 proof -
   573   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   574     by (simp add: diff_minus add_ac)
   575   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   576     by (rule norm_triangle_ineq)
   577   finally show ?thesis .
   578 qed
   579 
   580 lemma abs_norm_cancel [simp]:
   581   fixes a :: "'a::real_normed_vector"
   582   shows "\<bar>norm a\<bar> = norm a"
   583 by (rule abs_of_nonneg [OF norm_ge_zero])
   584 
   585 lemma norm_add_less:
   586   fixes x y :: "'a::real_normed_vector"
   587   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   588 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   589 
   590 lemma norm_mult_less:
   591   fixes x y :: "'a::real_normed_algebra"
   592   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   593 apply (rule order_le_less_trans [OF norm_mult_ineq])
   594 apply (simp add: mult_strict_mono')
   595 done
   596 
   597 lemma norm_of_real [simp]:
   598   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   599 unfolding of_real_def by simp
   600 
   601 lemma norm_numeral [simp]:
   602   "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   603 by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   604 
   605 lemma norm_neg_numeral [simp]:
   606   "norm (neg_numeral w::'a::real_normed_algebra_1) = numeral w"
   607 by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   608 
   609 lemma norm_of_int [simp]:
   610   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   611 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   612 
   613 lemma norm_of_nat [simp]:
   614   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   615 apply (subst of_real_of_nat_eq [symmetric])
   616 apply (subst norm_of_real, simp)
   617 done
   618 
   619 lemma nonzero_norm_inverse:
   620   fixes a :: "'a::real_normed_div_algebra"
   621   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   622 apply (rule inverse_unique [symmetric])
   623 apply (simp add: norm_mult [symmetric])
   624 done
   625 
   626 lemma norm_inverse:
   627   fixes a :: "'a::{real_normed_div_algebra, division_ring_inverse_zero}"
   628   shows "norm (inverse a) = inverse (norm a)"
   629 apply (case_tac "a = 0", simp)
   630 apply (erule nonzero_norm_inverse)
   631 done
   632 
   633 lemma nonzero_norm_divide:
   634   fixes a b :: "'a::real_normed_field"
   635   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   636 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   637 
   638 lemma norm_divide:
   639   fixes a b :: "'a::{real_normed_field, field_inverse_zero}"
   640   shows "norm (a / b) = norm a / norm b"
   641 by (simp add: divide_inverse norm_mult norm_inverse)
   642 
   643 lemma norm_power_ineq:
   644   fixes x :: "'a::{real_normed_algebra_1}"
   645   shows "norm (x ^ n) \<le> norm x ^ n"
   646 proof (induct n)
   647   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   648 next
   649   case (Suc n)
   650   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   651     by (rule norm_mult_ineq)
   652   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   653     using norm_ge_zero by (rule mult_left_mono)
   654   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   655     by simp
   656 qed
   657 
   658 lemma norm_power:
   659   fixes x :: "'a::{real_normed_div_algebra}"
   660   shows "norm (x ^ n) = norm x ^ n"
   661 by (induct n) (simp_all add: norm_mult)
   662 
   663 
   664 subsection {* Metric spaces *}
   665 
   666 class metric_space = open_dist +
   667   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   668   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   669 begin
   670 
   671 lemma dist_self [simp]: "dist x x = 0"
   672 by simp
   673 
   674 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   675 using dist_triangle2 [of x x y] by simp
   676 
   677 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   678 by (simp add: less_le)
   679 
   680 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   681 by (simp add: not_less)
   682 
   683 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   684 by (simp add: le_less)
   685 
   686 lemma dist_commute: "dist x y = dist y x"
   687 proof (rule order_antisym)
   688   show "dist x y \<le> dist y x"
   689     using dist_triangle2 [of x y x] by simp
   690   show "dist y x \<le> dist x y"
   691     using dist_triangle2 [of y x y] by simp
   692 qed
   693 
   694 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   695 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   696 
   697 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   698 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   699 
   700 lemma dist_triangle_alt:
   701   shows "dist y z <= dist x y + dist x z"
   702 by (rule dist_triangle3)
   703 
   704 lemma dist_pos_lt:
   705   shows "x \<noteq> y ==> 0 < dist x y"
   706 by (simp add: zero_less_dist_iff)
   707 
   708 lemma dist_nz:
   709   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   710 by (simp add: zero_less_dist_iff)
   711 
   712 lemma dist_triangle_le:
   713   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   714 by (rule order_trans [OF dist_triangle2])
   715 
   716 lemma dist_triangle_lt:
   717   shows "dist x z + dist y z < e ==> dist x y < e"
   718 by (rule le_less_trans [OF dist_triangle2])
   719 
   720 lemma dist_triangle_half_l:
   721   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
   722 by (rule dist_triangle_lt [where z=y], simp)
   723 
   724 lemma dist_triangle_half_r:
   725   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
   726 by (rule dist_triangle_half_l, simp_all add: dist_commute)
   727 
   728 subclass topological_space
   729 proof
   730   have "\<exists>e::real. 0 < e"
   731     by (fast intro: zero_less_one)
   732   then show "open UNIV"
   733     unfolding open_dist by simp
   734 next
   735   fix S T assume "open S" "open T"
   736   then show "open (S \<inter> T)"
   737     unfolding open_dist
   738     apply clarify
   739     apply (drule (1) bspec)+
   740     apply (clarify, rename_tac r s)
   741     apply (rule_tac x="min r s" in exI, simp)
   742     done
   743 next
   744   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   745     unfolding open_dist by fast
   746 qed
   747 
   748 lemma open_ball: "open {y. dist x y < d}"
   749 proof (unfold open_dist, intro ballI)
   750   fix y assume *: "y \<in> {y. dist x y < d}"
   751   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
   752     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
   753 qed
   754 
   755 subclass first_countable_topology
   756 proof
   757   fix x 
   758   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   759   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
   760     fix S assume "open S" "x \<in> S"
   761     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
   762       by (auto simp: open_dist subset_eq dist_commute)
   763     moreover
   764     from e obtain i where "inverse (Suc i) < e"
   765       by (auto dest!: reals_Archimedean)
   766     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
   767       by auto
   768     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
   769       by blast
   770   qed (auto intro: open_ball)
   771 qed
   772 
   773 end
   774 
   775 instance metric_space \<subseteq> t2_space
   776 proof
   777   fix x y :: "'a::metric_space"
   778   assume xy: "x \<noteq> y"
   779   let ?U = "{y'. dist x y' < dist x y / 2}"
   780   let ?V = "{x'. dist y x' < dist x y / 2}"
   781   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
   782                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
   783   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
   784     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
   785     using open_ball[of _ "dist x y / 2"] by auto
   786   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   787     by blast
   788 qed
   789 
   790 text {* Every normed vector space is a metric space. *}
   791 
   792 instance real_normed_vector < metric_space
   793 proof
   794   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
   795     unfolding dist_norm by simp
   796 next
   797   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
   798     unfolding dist_norm
   799     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
   800 qed
   801 
   802 subsection {* Class instances for real numbers *}
   803 
   804 instantiation real :: real_normed_field
   805 begin
   806 
   807 definition dist_real_def:
   808   "dist x y = \<bar>x - y\<bar>"
   809 
   810 definition open_real_def [code del]:
   811   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   812 
   813 definition real_norm_def [simp]:
   814   "norm r = \<bar>r\<bar>"
   815 
   816 instance
   817 apply (intro_classes, unfold real_norm_def real_scaleR_def)
   818 apply (rule dist_real_def)
   819 apply (rule open_real_def)
   820 apply (simp add: sgn_real_def)
   821 apply (rule abs_eq_0)
   822 apply (rule abs_triangle_ineq)
   823 apply (rule abs_mult)
   824 apply (rule abs_mult)
   825 done
   826 
   827 end
   828 
   829 code_abort "open :: real set \<Rightarrow> bool"
   830 
   831 instance real :: linorder_topology
   832 proof
   833   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
   834   proof (rule ext, safe)
   835     fix S :: "real set" assume "open S"
   836     then guess f unfolding open_real_def bchoice_iff ..
   837     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
   838       by (fastforce simp: dist_real_def)
   839     show "generate_topology (range lessThan \<union> range greaterThan) S"
   840       apply (subst *)
   841       apply (intro generate_topology_Union generate_topology.Int)
   842       apply (auto intro: generate_topology.Basis)
   843       done
   844   next
   845     fix S :: "real set" assume "generate_topology (range lessThan \<union> range greaterThan) S"
   846     moreover have "\<And>a::real. open {..<a}"
   847       unfolding open_real_def dist_real_def
   848     proof clarify
   849       fix x a :: real assume "x < a"
   850       hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
   851       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
   852     qed
   853     moreover have "\<And>a::real. open {a <..}"
   854       unfolding open_real_def dist_real_def
   855     proof clarify
   856       fix x a :: real assume "a < x"
   857       hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
   858       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
   859     qed
   860     ultimately show "open S"
   861       by induct auto
   862   qed
   863 qed
   864 
   865 instance real :: linear_continuum_topology ..
   866 
   867 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
   868 lemmas open_real_lessThan = open_lessThan[where 'a=real]
   869 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
   870 lemmas closed_real_atMost = closed_atMost[where 'a=real]
   871 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
   872 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
   873 
   874 subsection {* Extra type constraints *}
   875 
   876 text {* Only allow @{term "open"} in class @{text topological_space}. *}
   877 
   878 setup {* Sign.add_const_constraint
   879   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
   880 
   881 text {* Only allow @{term dist} in class @{text metric_space}. *}
   882 
   883 setup {* Sign.add_const_constraint
   884   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
   885 
   886 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
   887 
   888 setup {* Sign.add_const_constraint
   889   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
   890 
   891 subsection {* Sign function *}
   892 
   893 lemma norm_sgn:
   894   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
   895 by (simp add: sgn_div_norm)
   896 
   897 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
   898 by (simp add: sgn_div_norm)
   899 
   900 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
   901 by (simp add: sgn_div_norm)
   902 
   903 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
   904 by (simp add: sgn_div_norm)
   905 
   906 lemma sgn_scaleR:
   907   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
   908 by (simp add: sgn_div_norm mult_ac)
   909 
   910 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
   911 by (simp add: sgn_div_norm)
   912 
   913 lemma sgn_of_real:
   914   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
   915 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
   916 
   917 lemma sgn_mult:
   918   fixes x y :: "'a::real_normed_div_algebra"
   919   shows "sgn (x * y) = sgn x * sgn y"
   920 by (simp add: sgn_div_norm norm_mult mult_commute)
   921 
   922 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
   923 by (simp add: sgn_div_norm divide_inverse)
   924 
   925 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
   926 unfolding real_sgn_eq by simp
   927 
   928 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
   929 unfolding real_sgn_eq by simp
   930 
   931 lemma norm_conv_dist: "norm x = dist x 0"
   932   unfolding dist_norm by simp
   933 
   934 subsection {* Bounded Linear and Bilinear Operators *}
   935 
   936 locale bounded_linear = additive f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
   937   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
   938   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
   939 begin
   940 
   941 lemma pos_bounded:
   942   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
   943 proof -
   944   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
   945     using bounded by fast
   946   show ?thesis
   947   proof (intro exI impI conjI allI)
   948     show "0 < max 1 K"
   949       by (rule order_less_le_trans [OF zero_less_one le_maxI1])
   950   next
   951     fix x
   952     have "norm (f x) \<le> norm x * K" using K .
   953     also have "\<dots> \<le> norm x * max 1 K"
   954       by (rule mult_left_mono [OF le_maxI2 norm_ge_zero])
   955     finally show "norm (f x) \<le> norm x * max 1 K" .
   956   qed
   957 qed
   958 
   959 lemma nonneg_bounded:
   960   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
   961 proof -
   962   from pos_bounded
   963   show ?thesis by (auto intro: order_less_imp_le)
   964 qed
   965 
   966 end
   967 
   968 lemma bounded_linear_intro:
   969   assumes "\<And>x y. f (x + y) = f x + f y"
   970   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
   971   assumes "\<And>x. norm (f x) \<le> norm x * K"
   972   shows "bounded_linear f"
   973   by default (fast intro: assms)+
   974 
   975 locale bounded_bilinear =
   976   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
   977                  \<Rightarrow> 'c::real_normed_vector"
   978     (infixl "**" 70)
   979   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
   980   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
   981   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
   982   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
   983   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
   984 begin
   985 
   986 lemma pos_bounded:
   987   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
   988 apply (cut_tac bounded, erule exE)
   989 apply (rule_tac x="max 1 K" in exI, safe)
   990 apply (rule order_less_le_trans [OF zero_less_one le_maxI1])
   991 apply (drule spec, drule spec, erule order_trans)
   992 apply (rule mult_left_mono [OF le_maxI2])
   993 apply (intro mult_nonneg_nonneg norm_ge_zero)
   994 done
   995 
   996 lemma nonneg_bounded:
   997   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
   998 proof -
   999   from pos_bounded
  1000   show ?thesis by (auto intro: order_less_imp_le)
  1001 qed
  1002 
  1003 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1004 by (rule additive.intro, rule add_right)
  1005 
  1006 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1007 by (rule additive.intro, rule add_left)
  1008 
  1009 lemma zero_left: "prod 0 b = 0"
  1010 by (rule additive.zero [OF additive_left])
  1011 
  1012 lemma zero_right: "prod a 0 = 0"
  1013 by (rule additive.zero [OF additive_right])
  1014 
  1015 lemma minus_left: "prod (- a) b = - prod a b"
  1016 by (rule additive.minus [OF additive_left])
  1017 
  1018 lemma minus_right: "prod a (- b) = - prod a b"
  1019 by (rule additive.minus [OF additive_right])
  1020 
  1021 lemma diff_left:
  1022   "prod (a - a') b = prod a b - prod a' b"
  1023 by (rule additive.diff [OF additive_left])
  1024 
  1025 lemma diff_right:
  1026   "prod a (b - b') = prod a b - prod a b'"
  1027 by (rule additive.diff [OF additive_right])
  1028 
  1029 lemma bounded_linear_left:
  1030   "bounded_linear (\<lambda>a. a ** b)"
  1031 apply (cut_tac bounded, safe)
  1032 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1033 apply (rule add_left)
  1034 apply (rule scaleR_left)
  1035 apply (simp add: mult_ac)
  1036 done
  1037 
  1038 lemma bounded_linear_right:
  1039   "bounded_linear (\<lambda>b. a ** b)"
  1040 apply (cut_tac bounded, safe)
  1041 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1042 apply (rule add_right)
  1043 apply (rule scaleR_right)
  1044 apply (simp add: mult_ac)
  1045 done
  1046 
  1047 lemma prod_diff_prod:
  1048   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1049 by (simp add: diff_left diff_right)
  1050 
  1051 end
  1052 
  1053 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1054   by default (auto intro!: exI[of _ 1])
  1055 
  1056 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1057   by default (auto intro!: exI[of _ 1])
  1058 
  1059 lemma bounded_linear_add:
  1060   assumes "bounded_linear f"
  1061   assumes "bounded_linear g"
  1062   shows "bounded_linear (\<lambda>x. f x + g x)"
  1063 proof -
  1064   interpret f: bounded_linear f by fact
  1065   interpret g: bounded_linear g by fact
  1066   show ?thesis
  1067   proof
  1068     from f.bounded obtain Kf where Kf: "\<And>x. norm (f x) \<le> norm x * Kf" by blast
  1069     from g.bounded obtain Kg where Kg: "\<And>x. norm (g x) \<le> norm x * Kg" by blast
  1070     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1071       using add_mono[OF Kf Kg]
  1072       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1073   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1074 qed
  1075 
  1076 lemma bounded_linear_minus:
  1077   assumes "bounded_linear f"
  1078   shows "bounded_linear (\<lambda>x. - f x)"
  1079 proof -
  1080   interpret f: bounded_linear f by fact
  1081   show ?thesis apply (unfold_locales)
  1082     apply (simp add: f.add)
  1083     apply (simp add: f.scaleR)
  1084     apply (simp add: f.bounded)
  1085     done
  1086 qed
  1087 
  1088 lemma bounded_linear_compose:
  1089   assumes "bounded_linear f"
  1090   assumes "bounded_linear g"
  1091   shows "bounded_linear (\<lambda>x. f (g x))"
  1092 proof -
  1093   interpret f: bounded_linear f by fact
  1094   interpret g: bounded_linear g by fact
  1095   show ?thesis proof (unfold_locales)
  1096     fix x y show "f (g (x + y)) = f (g x) + f (g y)"
  1097       by (simp only: f.add g.add)
  1098   next
  1099     fix r x show "f (g (scaleR r x)) = scaleR r (f (g x))"
  1100       by (simp only: f.scaleR g.scaleR)
  1101   next
  1102     from f.pos_bounded
  1103     obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf" by fast
  1104     from g.pos_bounded
  1105     obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg" by fast
  1106     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1107     proof (intro exI allI)
  1108       fix x
  1109       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1110         using f .
  1111       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1112         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1113       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1114         by (rule mult_assoc)
  1115       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1116     qed
  1117   qed
  1118 qed
  1119 
  1120 lemma bounded_bilinear_mult:
  1121   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1122 apply (rule bounded_bilinear.intro)
  1123 apply (rule distrib_right)
  1124 apply (rule distrib_left)
  1125 apply (rule mult_scaleR_left)
  1126 apply (rule mult_scaleR_right)
  1127 apply (rule_tac x="1" in exI)
  1128 apply (simp add: norm_mult_ineq)
  1129 done
  1130 
  1131 lemma bounded_linear_mult_left:
  1132   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1133   using bounded_bilinear_mult
  1134   by (rule bounded_bilinear.bounded_linear_left)
  1135 
  1136 lemma bounded_linear_mult_right:
  1137   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1138   using bounded_bilinear_mult
  1139   by (rule bounded_bilinear.bounded_linear_right)
  1140 
  1141 lemmas bounded_linear_mult_const =
  1142   bounded_linear_mult_left [THEN bounded_linear_compose]
  1143 
  1144 lemmas bounded_linear_const_mult =
  1145   bounded_linear_mult_right [THEN bounded_linear_compose]
  1146 
  1147 lemma bounded_linear_divide:
  1148   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1149   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1150 
  1151 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1152 apply (rule bounded_bilinear.intro)
  1153 apply (rule scaleR_left_distrib)
  1154 apply (rule scaleR_right_distrib)
  1155 apply simp
  1156 apply (rule scaleR_left_commute)
  1157 apply (rule_tac x="1" in exI, simp)
  1158 done
  1159 
  1160 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1161   using bounded_bilinear_scaleR
  1162   by (rule bounded_bilinear.bounded_linear_left)
  1163 
  1164 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1165   using bounded_bilinear_scaleR
  1166   by (rule bounded_bilinear.bounded_linear_right)
  1167 
  1168 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1169   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1170 
  1171 lemma real_bounded_linear:
  1172   fixes f :: "real \<Rightarrow> real"
  1173   shows "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1174 proof -
  1175   { fix x assume "bounded_linear f"
  1176     then interpret bounded_linear f .
  1177     from scaleR[of x 1] have "f x = x * f 1"
  1178       by simp }
  1179   then show ?thesis
  1180     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1181 qed
  1182 
  1183 instance real_normed_algebra_1 \<subseteq> perfect_space
  1184 proof
  1185   fix x::'a
  1186   show "\<not> open {x}"
  1187     unfolding open_dist dist_norm
  1188     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1189 qed
  1190 
  1191 subsection {* Filters and Limits on Metric Space *}
  1192 
  1193 lemma eventually_nhds_metric:
  1194   fixes a :: "'a :: metric_space"
  1195   shows "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1196 unfolding eventually_nhds open_dist
  1197 apply safe
  1198 apply fast
  1199 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
  1200 apply clarsimp
  1201 apply (rule_tac x="d - dist x a" in exI, clarsimp)
  1202 apply (simp only: less_diff_eq)
  1203 apply (erule le_less_trans [OF dist_triangle])
  1204 done
  1205 
  1206 lemma eventually_at:
  1207   fixes a :: "'a :: metric_space"
  1208   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1209   unfolding eventually_at_filter eventually_nhds_metric by (auto simp: dist_nz)
  1210 
  1211 lemma eventually_at_le:
  1212   fixes a :: "'a::metric_space"
  1213   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1214   unfolding eventually_at_filter eventually_nhds_metric
  1215   apply auto
  1216   apply (rule_tac x="d / 2" in exI)
  1217   apply auto
  1218   done
  1219 
  1220 lemma tendstoI:
  1221   fixes l :: "'a :: metric_space"
  1222   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1223   shows "(f ---> l) F"
  1224   apply (rule topological_tendstoI)
  1225   apply (simp add: open_dist)
  1226   apply (drule (1) bspec, clarify)
  1227   apply (drule assms)
  1228   apply (erule eventually_elim1, simp)
  1229   done
  1230 
  1231 lemma tendstoD:
  1232   fixes l :: "'a :: metric_space"
  1233   shows "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1234   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
  1235   apply (clarsimp simp add: open_dist)
  1236   apply (rule_tac x="e - dist x l" in exI, clarsimp)
  1237   apply (simp only: less_diff_eq)
  1238   apply (erule le_less_trans [OF dist_triangle])
  1239   apply simp
  1240   apply simp
  1241   done
  1242 
  1243 lemma tendsto_iff:
  1244   fixes l :: "'a :: metric_space"
  1245   shows "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1246   using tendstoI tendstoD by fast
  1247 
  1248 lemma metric_tendsto_imp_tendsto:
  1249   fixes a :: "'a :: metric_space" and b :: "'b :: metric_space"
  1250   assumes f: "(f ---> a) F"
  1251   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1252   shows "(g ---> b) F"
  1253 proof (rule tendstoI)
  1254   fix e :: real assume "0 < e"
  1255   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1256   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1257     using le_less_trans by (rule eventually_elim2)
  1258 qed
  1259 
  1260 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1261   unfolding filterlim_at_top
  1262   apply (intro allI)
  1263   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1264   apply (auto simp: natceiling_le_eq)
  1265   done
  1266 
  1267 subsubsection {* Limits of Sequences *}
  1268 
  1269 lemma LIMSEQ_def: "X ----> (L::'a::metric_space) \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1270   unfolding tendsto_iff eventually_sequentially ..
  1271 
  1272 lemma LIMSEQ_iff_nz: "X ----> (L::'a::metric_space) = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1273   unfolding LIMSEQ_def by (metis Suc_leD zero_less_Suc)
  1274 
  1275 lemma metric_LIMSEQ_I:
  1276   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> (L::'a::metric_space)"
  1277 by (simp add: LIMSEQ_def)
  1278 
  1279 lemma metric_LIMSEQ_D:
  1280   "\<lbrakk>X ----> (L::'a::metric_space); 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1281 by (simp add: LIMSEQ_def)
  1282 
  1283 
  1284 subsubsection {* Limits of Functions *}
  1285 
  1286 lemma LIM_def: "f -- (a::'a::metric_space) --> (L::'b::metric_space) =
  1287      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
  1288         --> dist (f x) L < r)"
  1289   unfolding tendsto_iff eventually_at by simp
  1290 
  1291 lemma metric_LIM_I:
  1292   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
  1293     \<Longrightarrow> f -- (a::'a::metric_space) --> (L::'b::metric_space)"
  1294 by (simp add: LIM_def)
  1295 
  1296 lemma metric_LIM_D:
  1297   "\<lbrakk>f -- (a::'a::metric_space) --> (L::'b::metric_space); 0 < r\<rbrakk>
  1298     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1299 by (simp add: LIM_def)
  1300 
  1301 lemma metric_LIM_imp_LIM:
  1302   assumes f: "f -- a --> (l::'a::metric_space)"
  1303   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1304   shows "g -- a --> (m::'b::metric_space)"
  1305   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1306 
  1307 lemma metric_LIM_equal2:
  1308   assumes 1: "0 < R"
  1309   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
  1310   shows "g -- a --> l \<Longrightarrow> f -- (a::'a::metric_space) --> l"
  1311 apply (rule topological_tendstoI)
  1312 apply (drule (2) topological_tendstoD)
  1313 apply (simp add: eventually_at, safe)
  1314 apply (rule_tac x="min d R" in exI, safe)
  1315 apply (simp add: 1)
  1316 apply (simp add: 2)
  1317 done
  1318 
  1319 lemma metric_LIM_compose2:
  1320   assumes f: "f -- (a::'a::metric_space) --> b"
  1321   assumes g: "g -- b --> c"
  1322   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1323   shows "(\<lambda>x. g (f x)) -- a --> c"
  1324   using inj
  1325   by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1326 
  1327 lemma metric_isCont_LIM_compose2:
  1328   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1329   assumes f [unfolded isCont_def]: "isCont f a"
  1330   assumes g: "g -- f a --> l"
  1331   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1332   shows "(\<lambda>x. g (f x)) -- a --> l"
  1333 by (rule metric_LIM_compose2 [OF f g inj])
  1334 
  1335 subsection {* Complete metric spaces *}
  1336 
  1337 subsection {* Cauchy sequences *}
  1338 
  1339 definition (in metric_space) Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1340   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
  1341 
  1342 subsection {* Cauchy Sequences *}
  1343 
  1344 lemma metric_CauchyI:
  1345   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1346   by (simp add: Cauchy_def)
  1347 
  1348 lemma metric_CauchyD:
  1349   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1350   by (simp add: Cauchy_def)
  1351 
  1352 lemma metric_Cauchy_iff2:
  1353   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1354 apply (simp add: Cauchy_def, auto)
  1355 apply (drule reals_Archimedean, safe)
  1356 apply (drule_tac x = n in spec, auto)
  1357 apply (rule_tac x = M in exI, auto)
  1358 apply (drule_tac x = m in spec, simp)
  1359 apply (drule_tac x = na in spec, auto)
  1360 done
  1361 
  1362 lemma Cauchy_iff2:
  1363   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1364   unfolding metric_Cauchy_iff2 dist_real_def ..
  1365 
  1366 lemma Cauchy_subseq_Cauchy:
  1367   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1368 apply (auto simp add: Cauchy_def)
  1369 apply (drule_tac x=e in spec, clarify)
  1370 apply (rule_tac x=M in exI, clarify)
  1371 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1372 done
  1373 
  1374 theorem LIMSEQ_imp_Cauchy:
  1375   assumes X: "X ----> a" shows "Cauchy X"
  1376 proof (rule metric_CauchyI)
  1377   fix e::real assume "0 < e"
  1378   hence "0 < e/2" by simp
  1379   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1380   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1381   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1382   proof (intro exI allI impI)
  1383     fix m assume "N \<le> m"
  1384     hence m: "dist (X m) a < e/2" using N by fast
  1385     fix n assume "N \<le> n"
  1386     hence n: "dist (X n) a < e/2" using N by fast
  1387     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1388       by (rule dist_triangle2)
  1389     also from m n have "\<dots> < e" by simp
  1390     finally show "dist (X m) (X n) < e" .
  1391   qed
  1392 qed
  1393 
  1394 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1395 unfolding convergent_def
  1396 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1397 
  1398 subsubsection {* Cauchy Sequences are Convergent *}
  1399 
  1400 class complete_space = metric_space +
  1401   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1402 
  1403 lemma Cauchy_convergent_iff:
  1404   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1405   shows "Cauchy X = convergent X"
  1406 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1407 
  1408 subsection {* The set of real numbers is a complete metric space *}
  1409 
  1410 text {*
  1411 Proof that Cauchy sequences converge based on the one from
  1412 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1413 *}
  1414 
  1415 text {*
  1416   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1417   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1418 *}
  1419 
  1420 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1421 by (simp add: isUbI setleI)
  1422 
  1423 lemma increasing_LIMSEQ:
  1424   fixes f :: "nat \<Rightarrow> real"
  1425   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  1426       and bdd: "\<And>n. f n \<le> l"
  1427       and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  1428   shows "f ----> l"
  1429 proof (rule increasing_tendsto)
  1430   fix x assume "x < l"
  1431   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  1432     by auto
  1433   from en[OF `0 < e`] obtain n where "l - e \<le> f n"
  1434     by (auto simp: field_simps)
  1435   with `e < l - x` `0 < e` have "x < f n" by simp
  1436   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  1437     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  1438 qed (insert bdd, auto)
  1439 
  1440 lemma real_Cauchy_convergent:
  1441   fixes X :: "nat \<Rightarrow> real"
  1442   assumes X: "Cauchy X"
  1443   shows "convergent X"
  1444 proof -
  1445   def S \<equiv> "{x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1446   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S" by auto
  1447 
  1448   { fix N x assume N: "\<forall>n\<ge>N. X n < x"
  1449   have "isUb UNIV S x"
  1450   proof (rule isUb_UNIV_I)
  1451   fix y::real assume "y \<in> S"
  1452   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1453     by (simp add: S_def)
  1454   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1455   hence "y < X (max M N)" by simp
  1456   also have "\<dots> < x" using N by simp
  1457   finally show "y \<le> x"
  1458     by (rule order_less_imp_le)
  1459   qed }
  1460   note bound_isUb = this 
  1461 
  1462   have "\<exists>u. isLub UNIV S u"
  1463   proof (rule reals_complete)
  1464   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  1465     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  1466   hence N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  1467   show "\<exists>x. x \<in> S"
  1468   proof
  1469     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1470       by (simp add: abs_diff_less_iff dist_real_def)
  1471     thus "X N - 1 \<in> S" by (rule mem_S)
  1472   qed
  1473   show "\<exists>u. isUb UNIV S u"
  1474   proof
  1475     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1476       by (simp add: abs_diff_less_iff dist_real_def)
  1477     thus "isUb UNIV S (X N + 1)"
  1478       by (rule bound_isUb)
  1479   qed
  1480   qed
  1481   then obtain x where x: "isLub UNIV S x" ..
  1482   have "X ----> x"
  1483   proof (rule metric_LIMSEQ_I)
  1484   fix r::real assume "0 < r"
  1485   hence r: "0 < r/2" by simp
  1486   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  1487     using metric_CauchyD [OF X r] by auto
  1488   hence "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  1489   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1490     by (simp only: dist_real_def abs_diff_less_iff)
  1491 
  1492   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1493   hence "X N - r/2 \<in> S" by (rule mem_S)
  1494   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1495 
  1496   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1497   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1498   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1499 
  1500   show "\<exists>N. \<forall>n\<ge>N. dist (X n) x < r"
  1501   proof (intro exI allI impI)
  1502     fix n assume n: "N \<le> n"
  1503     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1504     thus "dist (X n) x < r" using 1 2
  1505       by (simp add: abs_diff_less_iff dist_real_def)
  1506   qed
  1507   qed
  1508   then show ?thesis unfolding convergent_def by auto
  1509 qed
  1510 
  1511 instance real :: complete_space
  1512   by intro_classes (rule real_Cauchy_convergent)
  1513 
  1514 class banach = real_normed_vector + complete_space
  1515 
  1516 instance real :: banach by default
  1517 
  1518 lemma tendsto_at_topI_sequentially:
  1519   fixes f :: "real \<Rightarrow> real"
  1520   assumes mono: "mono f"
  1521   assumes limseq: "(\<lambda>n. f (real n)) ----> y"
  1522   shows "(f ---> y) at_top"
  1523 proof (rule tendstoI)
  1524   fix e :: real assume "0 < e"
  1525   with limseq obtain N :: nat where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e"
  1526     by (auto simp: LIMSEQ_def dist_real_def)
  1527   { fix x :: real
  1528     from ex_le_of_nat[of x] guess n ..
  1529     note monoD[OF mono this]
  1530     also have "f (real_of_nat n) \<le> y"
  1531       by (rule LIMSEQ_le_const[OF limseq])
  1532          (auto intro: exI[of _ n] monoD[OF mono] simp: real_eq_of_nat[symmetric])
  1533     finally have "f x \<le> y" . }
  1534   note le = this
  1535   have "eventually (\<lambda>x. real N \<le> x) at_top"
  1536     by (rule eventually_ge_at_top)
  1537   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  1538   proof eventually_elim
  1539     fix x assume N': "real N \<le> x"
  1540     with N[of N] le have "y - f (real N) < e" by auto
  1541     moreover note monoD[OF mono N']
  1542     ultimately show "dist (f x) y < e"
  1543       using le[of x] by (auto simp: dist_real_def field_simps)
  1544   qed
  1545 qed
  1546 
  1547 end
  1548