src/Pure/drule.ML
author berghofe
Fri Mar 10 14:57:06 2000 +0100 (2000-03-10)
changeset 8406 a217b0cd304d
parent 8365 affb2989d238
child 8496 7e4a466b18d5
permissions -rw-r--r--
Type.unify and Type.typ_match now use Vartab instead of association lists.
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val dest_implies      : cterm -> cterm * cterm
    14   val skip_flexpairs    : cterm -> cterm
    15   val strip_imp_prems   : cterm -> cterm list
    16   val cprems_of         : thm -> cterm list
    17   val read_insts        :
    18           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    19                   -> (indexname -> typ option) * (indexname -> sort option)
    20                   -> string list -> (string*string)list
    21                   -> (indexname*ctyp)list * (cterm*cterm)list
    22   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    23   val strip_shyps_warning : thm -> thm
    24   val forall_intr_list  : cterm list -> thm -> thm
    25   val forall_intr_frees : thm -> thm
    26   val forall_intr_vars  : thm -> thm
    27   val forall_elim_list  : cterm list -> thm -> thm
    28   val forall_elim_var   : int -> thm -> thm
    29   val forall_elim_vars  : int -> thm -> thm
    30   val freeze_thaw       : thm -> thm * (thm -> thm)
    31   val implies_elim_list : thm -> thm list -> thm
    32   val implies_intr_list : cterm list -> thm -> thm
    33   val instantiate       :
    34     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    35   val zero_var_indexes  : thm -> thm
    36   val standard          : thm -> thm
    37   val rotate_prems      : int -> thm -> thm
    38   val assume_ax         : theory -> string -> thm
    39   val RSN               : thm * (int * thm) -> thm
    40   val RS                : thm * thm -> thm
    41   val RLN               : thm list * (int * thm list) -> thm list
    42   val RL                : thm list * thm list -> thm list
    43   val MRS               : thm list * thm -> thm
    44   val MRL               : thm list list * thm list -> thm list
    45   val compose           : thm * int * thm -> thm list
    46   val COMP              : thm * thm -> thm
    47   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    48   val read_instantiate  : (string*string)list -> thm -> thm
    49   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    50   val weak_eq_thm       : thm * thm -> bool
    51   val eq_thm_sg         : thm * thm -> bool
    52   val size_of_thm       : thm -> int
    53   val reflexive_thm     : thm
    54   val symmetric_thm     : thm
    55   val transitive_thm    : thm
    56   val refl_implies      : thm
    57   val symmetric_fun     : thm -> thm
    58   val rewrite_rule_aux  : (meta_simpset -> thm -> thm option) -> thm list -> thm -> thm
    59   val rewrite_thm       : bool * bool * bool
    60                           -> (meta_simpset -> thm -> thm option)
    61                           -> meta_simpset -> thm -> thm
    62   val rewrite_cterm     : bool * bool * bool
    63                           -> (meta_simpset -> thm -> thm option)
    64                           -> meta_simpset -> cterm -> thm
    65   val rewrite_goals_rule_aux: (meta_simpset -> thm -> thm option) -> thm list -> thm -> thm
    66   val rewrite_goal_rule : bool* bool * bool
    67                           -> (meta_simpset -> thm -> thm option)
    68                           -> meta_simpset -> int -> thm -> thm
    69   val equal_abs_elim    : cterm  -> thm -> thm
    70   val equal_abs_elim_list: cterm list -> thm -> thm
    71   val flexpair_abs_elim_list: cterm list -> thm -> thm
    72   val asm_rl            : thm
    73   val cut_rl            : thm
    74   val revcut_rl         : thm
    75   val thin_rl           : thm
    76   val triv_forall_equality: thm
    77   val swap_prems_rl     : thm
    78   val equal_intr_rule   : thm
    79   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    80   val incr_indexes      : int -> thm -> thm
    81   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    82 end;
    83 
    84 signature DRULE =
    85 sig
    86   include BASIC_DRULE
    87   val compose_single    : thm * int * thm -> thm
    88   val triv_goal         : thm
    89   val rev_triv_goal     : thm
    90   val freeze_all        : thm -> thm
    91   val mk_triv_goal      : cterm -> thm
    92   val mk_cgoal          : cterm -> cterm
    93   val assume_goal       : cterm -> thm
    94   val tvars_of_terms    : term list -> (indexname * sort) list
    95   val vars_of_terms     : term list -> (indexname * typ) list
    96   val tvars_of          : thm -> (indexname * sort) list
    97   val vars_of           : thm -> (indexname * typ) list
    98   val unvarifyT         : thm -> thm
    99   val unvarify          : thm -> thm
   100   val rule_attribute    : ('a -> thm -> thm) -> 'a attribute
   101   val tag_rule          : tag -> thm -> thm
   102   val untag_rule        : tag -> thm -> thm
   103   val tag               : tag -> 'a attribute
   104   val untag             : tag -> 'a attribute
   105   val tag_lemma         : 'a attribute
   106   val tag_assumption    : 'a attribute
   107   val tag_internal      : 'a attribute
   108 end;
   109 
   110 structure Drule: DRULE =
   111 struct
   112 
   113 
   114 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   115 
   116 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   117 
   118 (*dest_implies for cterms. Note T=prop below*)
   119 fun dest_implies ct =
   120     case term_of ct of
   121         (Const("==>", _) $ _ $ _) =>
   122             let val (ct1,ct2) = dest_comb ct
   123             in  (#2 (dest_comb ct1), ct2)  end
   124       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   125 
   126 
   127 (*Discard flexflex pairs; return a cterm*)
   128 fun skip_flexpairs ct =
   129     case term_of ct of
   130         (Const("==>", _) $ (Const("=?=",_)$_$_) $ _) =>
   131             skip_flexpairs (#2 (dest_implies ct))
   132       | _ => ct;
   133 
   134 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   135 fun strip_imp_prems ct =
   136     let val (cA,cB) = dest_implies ct
   137     in  cA :: strip_imp_prems cB  end
   138     handle TERM _ => [];
   139 
   140 (* A1==>...An==>B  goes to B, where B is not an implication *)
   141 fun strip_imp_concl ct =
   142     case term_of ct of (Const("==>", _) $ _ $ _) =>
   143         strip_imp_concl (#2 (dest_comb ct))
   144   | _ => ct;
   145 
   146 (*The premises of a theorem, as a cterm list*)
   147 val cprems_of = strip_imp_prems o skip_flexpairs o cprop_of;
   148 
   149 
   150 (** reading of instantiations **)
   151 
   152 fun absent ixn =
   153   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   154 
   155 fun inst_failure ixn =
   156   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   157 
   158 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   159 let val {tsig,...} = Sign.rep_sg sign
   160     fun split([],tvs,vs) = (tvs,vs)
   161       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   162                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   163                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   164     val (tvs,vs) = split(insts,[],[]);
   165     fun readT((a,i),st) =
   166         let val ixn = ("'" ^ a,i);
   167             val S = case rsorts ixn of Some S => S | None => absent ixn;
   168             val T = Sign.read_typ (sign,sorts) st;
   169         in if Type.typ_instance(tsig,T,TVar(ixn,S)) then (ixn,T)
   170            else inst_failure ixn
   171         end
   172     val tye = map readT tvs;
   173     fun mkty(ixn,st) = (case rtypes ixn of
   174                           Some T => (ixn,(st,typ_subst_TVars tye T))
   175                         | None => absent ixn);
   176     val ixnsTs = map mkty vs;
   177     val ixns = map fst ixnsTs
   178     and sTs  = map snd ixnsTs
   179     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   180     fun mkcVar(ixn,T) =
   181         let val U = typ_subst_TVars tye2 T
   182         in cterm_of sign (Var(ixn,U)) end
   183     val ixnTs = ListPair.zip(ixns, map snd sTs)
   184 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   185     ListPair.zip(map mkcVar ixnTs,cts))
   186 end;
   187 
   188 
   189 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   190      Used for establishing default types (of variables) and sorts (of
   191      type variables) when reading another term.
   192      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   193 ***)
   194 
   195 fun types_sorts thm =
   196     let val {prop,hyps,...} = rep_thm thm;
   197         val big = list_comb(prop,hyps); (* bogus term! *)
   198         val vars = map dest_Var (term_vars big);
   199         val frees = map dest_Free (term_frees big);
   200         val tvars = term_tvars big;
   201         val tfrees = term_tfrees big;
   202         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   203         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   204     in (typ,sort) end;
   205 
   206 
   207 (** Standardization of rules **)
   208 
   209 (*Strip extraneous shyps as far as possible*)
   210 fun strip_shyps_warning thm =
   211   let
   212     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   213     val thm' = Thm.strip_shyps thm;
   214     val xshyps = Thm.extra_shyps thm';
   215   in
   216     if null xshyps then ()
   217     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   218     thm'
   219   end;
   220 
   221 (*Generalization over a list of variables, IGNORING bad ones*)
   222 fun forall_intr_list [] th = th
   223   | forall_intr_list (y::ys) th =
   224         let val gth = forall_intr_list ys th
   225         in  forall_intr y gth   handle THM _ =>  gth  end;
   226 
   227 (*Generalization over all suitable Free variables*)
   228 fun forall_intr_frees th =
   229     let val {prop,sign,...} = rep_thm th
   230     in  forall_intr_list
   231          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   232          th
   233     end;
   234 
   235 val forall_elim_var = PureThy.forall_elim_var;
   236 val forall_elim_vars = PureThy.forall_elim_vars;
   237 
   238 (*Specialization over a list of cterms*)
   239 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   240 
   241 (* maps [A1,...,An], B   to   [| A1;...;An |] ==> B  *)
   242 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   243 
   244 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   245 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   246 
   247 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   248 fun zero_var_indexes th =
   249     let val {prop,sign,...} = rep_thm th;
   250         val vars = term_vars prop
   251         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   252         val inrs = add_term_tvars(prop,[]);
   253         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   254         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   255                      (inrs, nms')
   256         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   257         fun varpairs([],[]) = []
   258           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   259                 let val T' = typ_subst_TVars tye T
   260                 in (cterm_of sign (Var(v,T')),
   261                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   262                 end
   263           | varpairs _ = raise TERM("varpairs", []);
   264     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   265 
   266 
   267 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   268     all generality expressed by Vars having index 0.*)
   269 fun standard th =
   270   let val {maxidx,...} = rep_thm th
   271   in
   272     th |> implies_intr_hyps
   273        |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   274        |> strip_shyps_warning
   275        |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   276   end;
   277 
   278 
   279 (*Convert all Vars in a theorem to Frees.  Also return a function for
   280   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   281   Similar code in type/freeze_thaw*)
   282 fun freeze_thaw th =
   283  let val fth = freezeT th
   284      val {prop,sign,...} = rep_thm fth
   285  in
   286    case term_vars prop of
   287        [] => (fth, fn x => x)
   288      | vars =>
   289          let fun newName (Var(ix,_), (pairs,used)) =
   290                    let val v = variant used (string_of_indexname ix)
   291                    in  ((ix,v)::pairs, v::used)  end;
   292              val (alist, _) = foldr newName
   293                                 (vars, ([], add_term_names (prop, [])))
   294              fun mk_inst (Var(v,T)) =
   295                  (cterm_of sign (Var(v,T)),
   296                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   297              val insts = map mk_inst vars
   298              fun thaw th' =
   299                  th' |> forall_intr_list (map #2 insts)
   300                      |> forall_elim_list (map #1 insts)
   301          in  (Thm.instantiate ([],insts) fth, thaw)  end
   302  end;
   303 
   304 
   305 (*Rotates a rule's premises to the left by k*)
   306 val rotate_prems = permute_prems 0;
   307 
   308 
   309 (*Assume a new formula, read following the same conventions as axioms.
   310   Generalizes over Free variables,
   311   creates the assumption, and then strips quantifiers.
   312   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   313              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   314 fun assume_ax thy sP =
   315     let val sign = Theory.sign_of thy
   316         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   317     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   318 
   319 (*Resolution: exactly one resolvent must be produced.*)
   320 fun tha RSN (i,thb) =
   321   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   322       ([th],_) => th
   323     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   324     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   325 
   326 (*resolution: P==>Q, Q==>R gives P==>R. *)
   327 fun tha RS thb = tha RSN (1,thb);
   328 
   329 (*For joining lists of rules*)
   330 fun thas RLN (i,thbs) =
   331   let val resolve = biresolution false (map (pair false) thas) i
   332       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   333   in  List.concat (map resb thbs)  end;
   334 
   335 fun thas RL thbs = thas RLN (1,thbs);
   336 
   337 (*Resolve a list of rules against bottom_rl from right to left;
   338   makes proof trees*)
   339 fun rls MRS bottom_rl =
   340   let fun rs_aux i [] = bottom_rl
   341         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   342   in  rs_aux 1 rls  end;
   343 
   344 (*As above, but for rule lists*)
   345 fun rlss MRL bottom_rls =
   346   let fun rs_aux i [] = bottom_rls
   347         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   348   in  rs_aux 1 rlss  end;
   349 
   350 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   351   with no lifting or renaming!  Q may contain ==> or meta-quants
   352   ALWAYS deletes premise i *)
   353 fun compose(tha,i,thb) =
   354     Seq.list_of (bicompose false (false,tha,0) i thb);
   355 
   356 fun compose_single (tha,i,thb) =
   357   (case compose (tha,i,thb) of
   358     [th] => th
   359   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   360 
   361 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   362 fun tha COMP thb =
   363     case compose(tha,1,thb) of
   364         [th] => th
   365       | _ =>   raise THM("COMP", 1, [tha,thb]);
   366 
   367 (** theorem equality **)
   368 
   369 (*Do the two theorems have the same signature?*)
   370 fun eq_thm_sg (th1,th2) = Sign.eq_sg(#sign(rep_thm th1), #sign(rep_thm th2));
   371 
   372 (*Useful "distance" function for BEST_FIRST*)
   373 val size_of_thm = size_of_term o #prop o rep_thm;
   374 
   375 
   376 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   377     (some) type variable renaming **)
   378 
   379  (* Can't use term_vars, because it sorts the resulting list of variable names.
   380     We instead need the unique list noramlised by the order of appearance
   381     in the term. *)
   382 fun term_vars' (t as Var(v,T)) = [t]
   383   | term_vars' (Abs(_,_,b)) = term_vars' b
   384   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   385   | term_vars' _ = [];
   386 
   387 fun forall_intr_vars th =
   388   let val {prop,sign,...} = rep_thm th;
   389       val vars = distinct (term_vars' prop);
   390   in forall_intr_list (map (cterm_of sign) vars) th end;
   391 
   392 fun weak_eq_thm (tha,thb) =
   393     eq_thm(forall_intr_vars (freezeT tha), forall_intr_vars (freezeT thb));
   394 
   395 
   396 
   397 (*** Meta-Rewriting Rules ***)
   398 
   399 val proto_sign = Theory.sign_of ProtoPure.thy;
   400 
   401 fun read_prop s = read_cterm proto_sign (s, propT);
   402 
   403 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [standard thm]));
   404 
   405 val reflexive_thm =
   406   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   407   in store_thm "reflexive" (Thm.reflexive cx) end;
   408 
   409 val symmetric_thm =
   410   let val xy = read_prop "x::'a::logic == y"
   411   in store_thm "symmetric"
   412       (Thm.implies_intr_hyps(Thm.symmetric(Thm.assume xy)))
   413    end;
   414 
   415 val transitive_thm =
   416   let val xy = read_prop "x::'a::logic == y"
   417       val yz = read_prop "y::'a::logic == z"
   418       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   419   in store_thm "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm))
   420   end;
   421 
   422 fun symmetric_fun thm = thm RS symmetric_thm;
   423 
   424 (** Below, a "conversion" has type cterm -> thm **)
   425 
   426 val refl_implies = reflexive (cterm_of proto_sign implies);
   427 
   428 (*In [A1,...,An]==>B, rewrite the selected A's only -- for rewrite_goals_tac*)
   429 (*Do not rewrite flex-flex pairs*)
   430 fun goals_conv pred cv =
   431   let fun gconv i ct =
   432         let val (A,B) = dest_implies ct
   433             val (thA,j) = case term_of A of
   434                   Const("=?=",_)$_$_ => (reflexive A, i)
   435                 | _ => (if pred i then cv A else reflexive A, i+1)
   436         in  combination (combination refl_implies thA) (gconv j B) end
   437         handle TERM _ => reflexive ct
   438   in gconv 1 end;
   439 
   440 (*Use a conversion to transform a theorem*)
   441 fun fconv_rule cv th = equal_elim (cv (cprop_of th)) th;
   442 
   443 (*rewriting conversion*)
   444 fun rew_conv mode prover mss = rewrite_cterm mode mss prover;
   445 
   446 (*Rewrite a theorem*)
   447 fun rewrite_rule_aux _ []   th = th
   448   | rewrite_rule_aux prover thms th =
   449       fconv_rule (rew_conv (true,false,false) prover (Thm.mss_of thms)) th;
   450 
   451 fun rewrite_thm mode prover mss = fconv_rule (rew_conv mode prover mss);
   452 fun rewrite_cterm mode prover mss = Thm.rewrite_cterm mode mss prover;
   453 
   454 (*Rewrite the subgoals of a proof state (represented by a theorem) *)
   455 fun rewrite_goals_rule_aux _ []   th = th
   456   | rewrite_goals_rule_aux prover thms th =
   457       fconv_rule (goals_conv (K true) (rew_conv (true, true, false) prover
   458         (Thm.mss_of thms))) th;
   459 
   460 (*Rewrite the subgoal of a proof state (represented by a theorem) *)
   461 fun rewrite_goal_rule mode prover mss i thm =
   462   if 0 < i  andalso  i <= nprems_of thm
   463   then fconv_rule (goals_conv (fn j => j=i) (rew_conv mode prover mss)) thm
   464   else raise THM("rewrite_goal_rule",i,[thm]);
   465 
   466 
   467 (*** Some useful meta-theorems ***)
   468 
   469 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   470 val asm_rl = store_thm "asm_rl" (trivial(read_prop "PROP ?psi"));
   471 val _ = store_thm "_" asm_rl;
   472 
   473 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   474 val cut_rl =
   475   store_thm "cut_rl"
   476     (trivial(read_prop "PROP ?psi ==> PROP ?theta"));
   477 
   478 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   479      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   480 val revcut_rl =
   481   let val V = read_prop "PROP V"
   482       and VW = read_prop "PROP V ==> PROP W";
   483   in
   484     store_thm "revcut_rl"
   485       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   486   end;
   487 
   488 (*for deleting an unwanted assumption*)
   489 val thin_rl =
   490   let val V = read_prop "PROP V"
   491       and W = read_prop "PROP W";
   492   in  store_thm "thin_rl" (implies_intr V (implies_intr W (assume W)))
   493   end;
   494 
   495 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   496 val triv_forall_equality =
   497   let val V  = read_prop "PROP V"
   498       and QV = read_prop "!!x::'a. PROP V"
   499       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   500   in
   501     store_thm "triv_forall_equality"
   502       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   503         (implies_intr V  (forall_intr x (assume V))))
   504   end;
   505 
   506 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   507    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   508    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   509 *)
   510 val swap_prems_rl =
   511   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   512       val major = assume cmajor;
   513       val cminor1 = read_prop "PROP PhiA";
   514       val minor1 = assume cminor1;
   515       val cminor2 = read_prop "PROP PhiB";
   516       val minor2 = assume cminor2;
   517   in store_thm "swap_prems_rl"
   518        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   519          (implies_elim (implies_elim major minor1) minor2))))
   520   end;
   521 
   522 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   523    ==> PROP ?phi == PROP ?psi
   524    Introduction rule for == as a meta-theorem.
   525 *)
   526 val equal_intr_rule =
   527   let val PQ = read_prop "PROP phi ==> PROP psi"
   528       and QP = read_prop "PROP psi ==> PROP phi"
   529   in
   530     store_thm "equal_intr_rule"
   531       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   532   end;
   533 
   534 
   535 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   536 
   537 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   538 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   539 
   540 fun read_instantiate_sg sg sinsts th =
   541     let val ts = types_sorts th;
   542         val used = add_term_tvarnames(#prop(rep_thm th),[]);
   543     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   544 
   545 (*Instantiate theorem th, reading instantiations under theory of th*)
   546 fun read_instantiate sinsts th =
   547     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   548 
   549 
   550 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   551   Instantiates distinct Vars by terms, inferring type instantiations. *)
   552 local
   553   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   554     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   555         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   556         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   557         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   558         val (tye',maxi') = Type.unify (#tsig(Sign.rep_sg sign')) maxi tye (T,U)
   559           handle Type.TUNIFY => raise TYPE("add_types", [T,U], [t,u])
   560     in  (sign', tye', maxi')  end;
   561 in
   562 fun cterm_instantiate ctpairs0 th =
   563   let val (sign,tye,_) = foldr add_types (ctpairs0, (#sign(rep_thm th), Vartab.empty, 0))
   564       val tsig = #tsig(Sign.rep_sg sign);
   565       fun instT(ct,cu) = let val inst = subst_TVars_Vartab tye
   566                          in (cterm_fun inst ct, cterm_fun inst cu) end
   567       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   568   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   569   handle TERM _ =>
   570            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   571        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   572 end;
   573 
   574 
   575 (** Derived rules mainly for METAHYPS **)
   576 
   577 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   578 fun equal_abs_elim ca eqth =
   579   let val {sign=signa, t=a, ...} = rep_cterm ca
   580       and combth = combination eqth (reflexive ca)
   581       val {sign,prop,...} = rep_thm eqth
   582       val (abst,absu) = Logic.dest_equals prop
   583       val cterm = cterm_of (Sign.merge (sign,signa))
   584   in  transitive (symmetric (beta_conversion (cterm (abst$a))))
   585            (transitive combth (beta_conversion (cterm (absu$a))))
   586   end
   587   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   588 
   589 (*Calling equal_abs_elim with multiple terms*)
   590 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   591 
   592 local
   593   val alpha = TVar(("'a",0), [])     (*  type ?'a::{}  *)
   594   fun err th = raise THM("flexpair_inst: ", 0, [th])
   595   fun flexpair_inst def th =
   596     let val {prop = Const _ $ t $ u,  sign,...} = rep_thm th
   597         val cterm = cterm_of sign
   598         fun cvar a = cterm(Var((a,0),alpha))
   599         val def' = cterm_instantiate [(cvar"t", cterm t), (cvar"u", cterm u)]
   600                    def
   601     in  equal_elim def' th
   602     end
   603     handle THM _ => err th | Bind => err th
   604 in
   605 val flexpair_intr = flexpair_inst (symmetric ProtoPure.flexpair_def)
   606 and flexpair_elim = flexpair_inst ProtoPure.flexpair_def
   607 end;
   608 
   609 (*Version for flexflex pairs -- this supports lifting.*)
   610 fun flexpair_abs_elim_list cts =
   611     flexpair_intr o equal_abs_elim_list cts o flexpair_elim;
   612 
   613 
   614 (*** GOAL (PROP A) <==> PROP A ***)
   615 
   616 local
   617   val A = read_prop "PROP A";
   618   val G = read_prop "GOAL (PROP A)";
   619   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   620 in
   621   val triv_goal = store_thm "triv_goal" (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume A));
   622   val rev_triv_goal = store_thm "rev_triv_goal" (Thm.equal_elim G_def (Thm.assume G));
   623 end;
   624 
   625 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign (Const ("Goal", propT --> propT)));
   626 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   627 
   628 
   629 
   630 (** variations on instantiate **)
   631 
   632 (* collect vars *)
   633 
   634 val add_tvarsT = foldl_atyps (fn (vs, TVar v) => v ins vs | (vs, _) => vs);
   635 val add_tvars = foldl_types add_tvarsT;
   636 val add_vars = foldl_aterms (fn (vs, Var v) => v ins vs | (vs, _) => vs);
   637 
   638 fun tvars_of_terms ts = rev (foldl add_tvars ([], ts));
   639 fun vars_of_terms ts = rev (foldl add_vars ([], ts));
   640 
   641 fun tvars_of thm = tvars_of_terms [#prop (Thm.rep_thm thm)];
   642 fun vars_of thm = vars_of_terms [#prop (Thm.rep_thm thm)];
   643 
   644 
   645 (* instantiate by left-to-right occurrence of variables *)
   646 
   647 fun instantiate' cTs cts thm =
   648   let
   649     fun err msg =
   650       raise TYPE ("instantiate': " ^ msg,
   651         mapfilter (apsome Thm.typ_of) cTs,
   652         mapfilter (apsome Thm.term_of) cts);
   653 
   654     fun inst_of (v, ct) =
   655       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   656         handle TYPE (msg, _, _) => err msg;
   657 
   658     fun zip_vars _ [] = []
   659       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   660       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   661       | zip_vars [] _ = err "more instantiations than variables in thm";
   662 
   663     (*instantiate types first!*)
   664     val thm' =
   665       if forall is_none cTs then thm
   666       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   667     in
   668       if forall is_none cts then thm'
   669       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   670     end;
   671 
   672 
   673 (* unvarify(T) *)
   674 
   675 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   676 
   677 fun unvarifyT thm =
   678   let
   679     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   680     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   681   in instantiate' tfrees [] thm end;
   682 
   683 fun unvarify raw_thm =
   684   let
   685     val thm = unvarifyT raw_thm;
   686     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   687     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   688   in instantiate' [] frees thm end;
   689 
   690 
   691 (* increment var indexes *)
   692 
   693 fun incr_indexes 0 thm = thm
   694   | incr_indexes inc thm =
   695       let
   696         val sign = Thm.sign_of_thm thm;
   697 
   698         fun inc_tvar ((x, i), S) = Some (Thm.ctyp_of sign (TVar ((x, i + inc), S)));
   699         fun inc_var ((x, i), T) = Some (Thm.cterm_of sign (Var ((x, i + inc), T)));
   700         val thm' = instantiate' (map inc_tvar (tvars_of thm)) [] thm;
   701         val thm'' = instantiate' [] (map inc_var (vars_of thm')) thm';
   702       in thm'' end;
   703 
   704 fun incr_indexes_wrt is cTs cts thms =
   705   let
   706     val maxidx =
   707       foldl Int.max (~1, is @
   708         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   709         map (#maxidx o Thm.rep_cterm) cts @
   710         map (#maxidx o Thm.rep_thm) thms);
   711   in incr_indexes (maxidx + 1) end;
   712 
   713 
   714 (* freeze_all *)
   715 
   716 (*freeze all (T)Vars; assumes thm in standard form*)
   717 
   718 fun freeze_all_TVars thm =
   719   (case tvars_of thm of
   720     [] => thm
   721   | tvars =>
   722       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   723       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   724 
   725 fun freeze_all_Vars thm =
   726   (case vars_of thm of
   727     [] => thm
   728   | vars =>
   729       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   730       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   731 
   732 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   733 
   734 
   735 (* mk_triv_goal *)
   736 
   737 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   738 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   739 
   740 
   741 
   742 (** basic attributes **)
   743 
   744 (* dependent rules *)
   745 
   746 fun rule_attribute f (x, thm) = (x, (f x thm));
   747 
   748 
   749 (* add / delete tags *)
   750 
   751 fun map_tags f thm =
   752   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   753 
   754 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   755 fun untag_rule tg = map_tags (fn tgs => tgs \ tg);
   756 
   757 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   758 fun untag tg x = rule_attribute (K (untag_rule tg)) x;
   759 
   760 fun simple_tag name x = tag (name, []) x;
   761 
   762 fun tag_lemma x = simple_tag "lemma" x;
   763 fun tag_assumption x = simple_tag "assumption" x;
   764 fun tag_internal x = simple_tag "internal" x;
   765 
   766 
   767 end;
   768 
   769 
   770 structure BasicDrule: BASIC_DRULE = Drule;
   771 open BasicDrule;