src/HOL/Set.thy
author haftmann
Mon Jul 12 10:48:37 2010 +0200 (2010-07-12)
changeset 37767 a2b7a20d6ea3
parent 37677 c5a8b612e571
child 38648 52ea97d95e4b
permissions -rw-r--r--
dropped superfluous [code del]s
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel *)
     2 
     3 header {* Set theory for higher-order logic *}
     4 
     5 theory Set
     6 imports Lattices
     7 begin
     8 
     9 subsection {* Sets as predicates *}
    10 
    11 types 'a set = "'a \<Rightarrow> bool"
    12 
    13 definition Collect :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set" where -- "comprehension"
    14   "Collect P = P"
    15 
    16 definition member :: "'a \<Rightarrow> 'a set \<Rightarrow> bool" where -- "membership"
    17   mem_def: "member x A = A x"
    18 
    19 notation
    20   member  ("op :") and
    21   member  ("(_/ : _)" [50, 51] 50)
    22 
    23 abbreviation not_member where
    24   "not_member x A \<equiv> ~ (x : A)" -- "non-membership"
    25 
    26 notation
    27   not_member  ("op ~:") and
    28   not_member  ("(_/ ~: _)" [50, 51] 50)
    29 
    30 notation (xsymbols)
    31   member      ("op \<in>") and
    32   member      ("(_/ \<in> _)" [50, 51] 50) and
    33   not_member  ("op \<notin>") and
    34   not_member  ("(_/ \<notin> _)" [50, 51] 50)
    35 
    36 notation (HTML output)
    37   member      ("op \<in>") and
    38   member      ("(_/ \<in> _)" [50, 51] 50) and
    39   not_member  ("op \<notin>") and
    40   not_member  ("(_/ \<notin> _)" [50, 51] 50)
    41 
    42 text {* Set comprehensions *}
    43 
    44 syntax
    45   "_Coll" :: "pttrn => bool => 'a set"    ("(1{_./ _})")
    46 translations
    47   "{x. P}" == "CONST Collect (%x. P)"
    48 
    49 syntax
    50   "_Collect" :: "idt => 'a set => bool => 'a set"    ("(1{_ :/ _./ _})")
    51 syntax (xsymbols)
    52   "_Collect" :: "idt => 'a set => bool => 'a set"    ("(1{_ \<in>/ _./ _})")
    53 translations
    54   "{x:A. P}" => "{x. x:A & P}"
    55 
    56 lemma mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
    57   by (simp add: Collect_def mem_def)
    58 
    59 lemma Collect_mem_eq [simp]: "{x. x:A} = A"
    60   by (simp add: Collect_def mem_def)
    61 
    62 lemma CollectI: "P(a) ==> a : {x. P(x)}"
    63   by simp
    64 
    65 lemma CollectD: "a : {x. P(x)} ==> P(a)"
    66   by simp
    67 
    68 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
    69   by simp
    70 
    71 text {*
    72 Simproc for pulling @{text "x=t"} in @{text "{x. \<dots> & x=t & \<dots>}"}
    73 to the front (and similarly for @{text "t=x"}):
    74 *}
    75 
    76 setup {*
    77 let
    78   val Coll_perm_tac = rtac @{thm Collect_cong} 1 THEN rtac @{thm iffI} 1 THEN
    79     ALLGOALS(EVERY'[REPEAT_DETERM o (etac @{thm conjE}),
    80                     DEPTH_SOLVE_1 o (ares_tac [@{thm conjI}])])
    81   val defColl_regroup = Simplifier.simproc @{theory}
    82     "defined Collect" ["{x. P x & Q x}"]
    83     (Quantifier1.rearrange_Coll Coll_perm_tac)
    84 in
    85   Simplifier.map_simpset (fn ss => ss addsimprocs [defColl_regroup])
    86 end
    87 *}
    88 
    89 lemmas CollectE = CollectD [elim_format]
    90 
    91 text {* Set enumerations *}
    92 
    93 abbreviation empty :: "'a set" ("{}") where
    94   "{} \<equiv> bot"
    95 
    96 definition insert :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a set" where
    97   insert_compr: "insert a B = {x. x = a \<or> x \<in> B}"
    98 
    99 syntax
   100   "_Finset" :: "args => 'a set"    ("{(_)}")
   101 translations
   102   "{x, xs}" == "CONST insert x {xs}"
   103   "{x}" == "CONST insert x {}"
   104 
   105 
   106 subsection {* Subsets and bounded quantifiers *}
   107 
   108 abbreviation
   109   subset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   110   "subset \<equiv> less"
   111 
   112 abbreviation
   113   subset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   114   "subset_eq \<equiv> less_eq"
   115 
   116 notation (output)
   117   subset  ("op <") and
   118   subset  ("(_/ < _)" [50, 51] 50) and
   119   subset_eq  ("op <=") and
   120   subset_eq  ("(_/ <= _)" [50, 51] 50)
   121 
   122 notation (xsymbols)
   123   subset  ("op \<subset>") and
   124   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   125   subset_eq  ("op \<subseteq>") and
   126   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   127 
   128 notation (HTML output)
   129   subset  ("op \<subset>") and
   130   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   131   subset_eq  ("op \<subseteq>") and
   132   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   133 
   134 abbreviation (input)
   135   supset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   136   "supset \<equiv> greater"
   137 
   138 abbreviation (input)
   139   supset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   140   "supset_eq \<equiv> greater_eq"
   141 
   142 notation (xsymbols)
   143   supset  ("op \<supset>") and
   144   supset  ("(_/ \<supset> _)" [50, 51] 50) and
   145   supset_eq  ("op \<supseteq>") and
   146   supset_eq  ("(_/ \<supseteq> _)" [50, 51] 50)
   147 
   148 definition Ball :: "'a set \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   149   "Ball A P \<longleftrightarrow> (\<forall>x. x \<in> A \<longrightarrow> P x)"   -- "bounded universal quantifiers"
   150 
   151 definition Bex :: "'a set \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   152   "Bex A P \<longleftrightarrow> (\<exists>x. x \<in> A \<and> P x)"   -- "bounded existential quantifiers"
   153 
   154 syntax
   155   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
   156   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
   157   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3EX! _:_./ _)" [0, 0, 10] 10)
   158   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST _:_./ _)" [0, 0, 10] 10)
   159 
   160 syntax (HOL)
   161   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
   162   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
   163   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3?! _:_./ _)" [0, 0, 10] 10)
   164 
   165 syntax (xsymbols)
   166   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   167   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   168   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   169   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST_\<in>_./ _)" [0, 0, 10] 10)
   170 
   171 syntax (HTML output)
   172   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   173   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   174   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   175 
   176 translations
   177   "ALL x:A. P" == "CONST Ball A (%x. P)"
   178   "EX x:A. P" == "CONST Bex A (%x. P)"
   179   "EX! x:A. P" => "EX! x. x:A & P"
   180   "LEAST x:A. P" => "LEAST x. x:A & P"
   181 
   182 syntax (output)
   183   "_setlessAll" :: "[idt, 'a, bool] => bool"  ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   184   "_setlessEx"  :: "[idt, 'a, bool] => bool"  ("(3EX _<_./ _)"  [0, 0, 10] 10)
   185   "_setleAll"   :: "[idt, 'a, bool] => bool"  ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   186   "_setleEx"    :: "[idt, 'a, bool] => bool"  ("(3EX _<=_./ _)" [0, 0, 10] 10)
   187   "_setleEx1"   :: "[idt, 'a, bool] => bool"  ("(3EX! _<=_./ _)" [0, 0, 10] 10)
   188 
   189 syntax (xsymbols)
   190   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   191   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   192   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   193   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   194   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   195 
   196 syntax (HOL output)
   197   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   198   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   199   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   200   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   201   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3?! _<=_./ _)" [0, 0, 10] 10)
   202 
   203 syntax (HTML output)
   204   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   205   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   206   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   207   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   208   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   209 
   210 translations
   211  "\<forall>A\<subset>B. P"   =>  "ALL A. A \<subset> B --> P"
   212  "\<exists>A\<subset>B. P"   =>  "EX A. A \<subset> B & P"
   213  "\<forall>A\<subseteq>B. P"   =>  "ALL A. A \<subseteq> B --> P"
   214  "\<exists>A\<subseteq>B. P"   =>  "EX A. A \<subseteq> B & P"
   215  "\<exists>!A\<subseteq>B. P"  =>  "EX! A. A \<subseteq> B & P"
   216 
   217 print_translation {*
   218 let
   219   val Type (set_type, _) = @{typ "'a set"};   (* FIXME 'a => bool (!?!) *)
   220   val All_binder = Syntax.binder_name @{const_syntax All};
   221   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   222   val impl = @{const_syntax "op -->"};
   223   val conj = @{const_syntax "op &"};
   224   val sbset = @{const_syntax subset};
   225   val sbset_eq = @{const_syntax subset_eq};
   226 
   227   val trans =
   228    [((All_binder, impl, sbset), @{syntax_const "_setlessAll"}),
   229     ((All_binder, impl, sbset_eq), @{syntax_const "_setleAll"}),
   230     ((Ex_binder, conj, sbset), @{syntax_const "_setlessEx"}),
   231     ((Ex_binder, conj, sbset_eq), @{syntax_const "_setleEx"})];
   232 
   233   fun mk v v' c n P =
   234     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   235     then Syntax.const c $ Syntax.mark_bound v' $ n $ P else raise Match;
   236 
   237   fun tr' q = (q,
   238         fn [Const (@{syntax_const "_bound"}, _) $ Free (v, Type (T, _)),
   239             Const (c, _) $
   240               (Const (d, _) $ (Const (@{syntax_const "_bound"}, _) $ Free (v', _)) $ n) $ P] =>
   241             if T = set_type then
   242               (case AList.lookup (op =) trans (q, c, d) of
   243                 NONE => raise Match
   244               | SOME l => mk v v' l n P)
   245             else raise Match
   246          | _ => raise Match);
   247 in
   248   [tr' All_binder, tr' Ex_binder]
   249 end
   250 *}
   251 
   252 
   253 text {*
   254   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   255   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   256   only translated if @{text "[0..n] subset bvs(e)"}.
   257 *}
   258 
   259 syntax
   260   "_Setcompr" :: "'a => idts => bool => 'a set"    ("(1{_ |/_./ _})")
   261 
   262 parse_translation {*
   263   let
   264     val ex_tr = snd (mk_binder_tr ("EX ", @{const_syntax Ex}));
   265 
   266     fun nvars (Const (@{syntax_const "_idts"}, _) $ _ $ idts) = nvars idts + 1
   267       | nvars _ = 1;
   268 
   269     fun setcompr_tr [e, idts, b] =
   270       let
   271         val eq = Syntax.const @{const_syntax "op ="} $ Bound (nvars idts) $ e;
   272         val P = Syntax.const @{const_syntax "op &"} $ eq $ b;
   273         val exP = ex_tr [idts, P];
   274       in Syntax.const @{const_syntax Collect} $ Term.absdummy (dummyT, exP) end;
   275 
   276   in [(@{syntax_const "_Setcompr"}, setcompr_tr)] end;
   277 *}
   278 
   279 print_translation {*
   280  [Syntax.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   281   Syntax.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"}]
   282 *} -- {* to avoid eta-contraction of body *}
   283 
   284 print_translation {*
   285 let
   286   val ex_tr' = snd (mk_binder_tr' (@{const_syntax Ex}, "DUMMY"));
   287 
   288   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   289     let
   290       fun check (Const (@{const_syntax Ex}, _) $ Abs (_, _, P), n) = check (P, n + 1)
   291         | check (Const (@{const_syntax "op &"}, _) $
   292               (Const (@{const_syntax "op ="}, _) $ Bound m $ e) $ P, n) =
   293             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   294             subset (op =) (0 upto (n - 1), add_loose_bnos (e, 0, []))
   295         | check _ = false;
   296 
   297         fun tr' (_ $ abs) =
   298           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   299           in Syntax.const @{syntax_const "_Setcompr"} $ e $ idts $ Q end;
   300     in
   301       if check (P, 0) then tr' P
   302       else
   303         let
   304           val (x as _ $ Free(xN, _), t) = atomic_abs_tr' abs;
   305           val M = Syntax.const @{syntax_const "_Coll"} $ x $ t;
   306         in
   307           case t of
   308             Const (@{const_syntax "op &"}, _) $
   309               (Const (@{const_syntax Set.member}, _) $
   310                 (Const (@{syntax_const "_bound"}, _) $ Free (yN, _)) $ A) $ P =>
   311             if xN = yN then Syntax.const @{syntax_const "_Collect"} $ x $ A $ P else M
   312           | _ => M
   313         end
   314     end;
   315   in [(@{const_syntax Collect}, setcompr_tr')] end;
   316 *}
   317 
   318 setup {*
   319 let
   320   val unfold_bex_tac = unfold_tac @{thms "Bex_def"};
   321   fun prove_bex_tac ss = unfold_bex_tac ss THEN Quantifier1.prove_one_point_ex_tac;
   322   val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   323   val unfold_ball_tac = unfold_tac @{thms "Ball_def"};
   324   fun prove_ball_tac ss = unfold_ball_tac ss THEN Quantifier1.prove_one_point_all_tac;
   325   val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   326   val defBEX_regroup = Simplifier.simproc @{theory}
   327     "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   328   val defBALL_regroup = Simplifier.simproc @{theory}
   329     "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   330 in
   331   Simplifier.map_simpset (fn ss => ss addsimprocs [defBALL_regroup, defBEX_regroup])
   332 end
   333 *}
   334 
   335 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   336   by (simp add: Ball_def)
   337 
   338 lemmas strip = impI allI ballI
   339 
   340 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   341   by (simp add: Ball_def)
   342 
   343 text {*
   344   Gives better instantiation for bound:
   345 *}
   346 
   347 declaration {* fn _ =>
   348   Classical.map_cs (fn cs => cs addbefore ("bspec", datac @{thm bspec} 1))
   349 *}
   350 
   351 ML {*
   352 structure Simpdata =
   353 struct
   354 
   355 open Simpdata;
   356 
   357 val mksimps_pairs = [(@{const_name Ball}, @{thms bspec})] @ mksimps_pairs;
   358 
   359 end;
   360 
   361 open Simpdata;
   362 *}
   363 
   364 declaration {* fn _ =>
   365   Simplifier.map_ss (fn ss => ss setmksimps (mksimps mksimps_pairs))
   366 *}
   367 
   368 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   369   by (unfold Ball_def) blast
   370 
   371 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   372   -- {* Normally the best argument order: @{prop "P x"} constrains the
   373     choice of @{prop "x:A"}. *}
   374   by (unfold Bex_def) blast
   375 
   376 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   377   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   378   by (unfold Bex_def) blast
   379 
   380 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   381   by (unfold Bex_def) blast
   382 
   383 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   384   by (unfold Bex_def) blast
   385 
   386 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   387   -- {* Trival rewrite rule. *}
   388   by (simp add: Ball_def)
   389 
   390 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   391   -- {* Dual form for existentials. *}
   392   by (simp add: Bex_def)
   393 
   394 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   395   by blast
   396 
   397 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   398   by blast
   399 
   400 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   401   by blast
   402 
   403 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   404   by blast
   405 
   406 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   407   by blast
   408 
   409 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   410   by blast
   411 
   412 
   413 text {* Congruence rules *}
   414 
   415 lemma ball_cong:
   416   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   417     (ALL x:A. P x) = (ALL x:B. Q x)"
   418   by (simp add: Ball_def)
   419 
   420 lemma strong_ball_cong [cong]:
   421   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   422     (ALL x:A. P x) = (ALL x:B. Q x)"
   423   by (simp add: simp_implies_def Ball_def)
   424 
   425 lemma bex_cong:
   426   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   427     (EX x:A. P x) = (EX x:B. Q x)"
   428   by (simp add: Bex_def cong: conj_cong)
   429 
   430 lemma strong_bex_cong [cong]:
   431   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   432     (EX x:A. P x) = (EX x:B. Q x)"
   433   by (simp add: simp_implies_def Bex_def cong: conj_cong)
   434 
   435 
   436 subsection {* Basic operations *}
   437 
   438 subsubsection {* Subsets *}
   439 
   440 lemma subsetI [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> x \<in> B) \<Longrightarrow> A \<subseteq> B"
   441   unfolding mem_def by (rule le_funI, rule le_boolI)
   442 
   443 text {*
   444   \medskip Map the type @{text "'a set => anything"} to just @{typ
   445   'a}; for overloading constants whose first argument has type @{typ
   446   "'a set"}.
   447 *}
   448 
   449 lemma subsetD [elim, intro?]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   450   unfolding mem_def by (erule le_funE, erule le_boolE)
   451   -- {* Rule in Modus Ponens style. *}
   452 
   453 lemma rev_subsetD [no_atp,intro?]: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   454   -- {* The same, with reversed premises for use with @{text erule} --
   455       cf @{text rev_mp}. *}
   456   by (rule subsetD)
   457 
   458 text {*
   459   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   460 *}
   461 
   462 lemma subsetCE [no_atp,elim]: "A \<subseteq> B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   463   -- {* Classical elimination rule. *}
   464   unfolding mem_def by (blast dest: le_funE le_boolE)
   465 
   466 lemma subset_eq [no_atp]: "A \<le> B = (\<forall>x\<in>A. x \<in> B)" by blast
   467 
   468 lemma contra_subsetD [no_atp]: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   469   by blast
   470 
   471 lemma subset_refl [simp]: "A \<subseteq> A"
   472   by (fact order_refl)
   473 
   474 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   475   by (fact order_trans)
   476 
   477 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
   478   by (rule subsetD)
   479 
   480 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
   481   by (rule subsetD)
   482 
   483 lemma eq_mem_trans: "a=b ==> b \<in> A ==> a \<in> A"
   484   by simp
   485 
   486 lemmas basic_trans_rules [trans] =
   487   order_trans_rules set_rev_mp set_mp eq_mem_trans
   488 
   489 
   490 subsubsection {* Equality *}
   491 
   492 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   493   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   494    apply (rule Collect_mem_eq)
   495   apply (rule Collect_mem_eq)
   496   done
   497 
   498 lemma expand_set_eq: "(A = B) = (ALL x. (x:A) = (x:B))"
   499 by(auto intro:set_ext)
   500 
   501 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   502   -- {* Anti-symmetry of the subset relation. *}
   503   by (iprover intro: set_ext subsetD)
   504 
   505 text {*
   506   \medskip Equality rules from ZF set theory -- are they appropriate
   507   here?
   508 *}
   509 
   510 lemma equalityD1: "A = B ==> A \<subseteq> B"
   511   by simp
   512 
   513 lemma equalityD2: "A = B ==> B \<subseteq> A"
   514   by simp
   515 
   516 text {*
   517   \medskip Be careful when adding this to the claset as @{text
   518   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   519   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   520 *}
   521 
   522 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   523   by simp
   524 
   525 lemma equalityCE [elim]:
   526     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   527   by blast
   528 
   529 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   530   by simp
   531 
   532 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   533   by simp
   534 
   535 
   536 subsubsection {* The universal set -- UNIV *}
   537 
   538 abbreviation UNIV :: "'a set" where
   539   "UNIV \<equiv> top"
   540 
   541 lemma UNIV_def:
   542   "UNIV = {x. True}"
   543   by (simp add: top_fun_eq top_bool_eq Collect_def)
   544 
   545 lemma UNIV_I [simp]: "x : UNIV"
   546   by (simp add: UNIV_def)
   547 
   548 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   549 
   550 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   551   by simp
   552 
   553 lemma subset_UNIV [simp]: "A \<subseteq> UNIV"
   554   by (rule subsetI) (rule UNIV_I)
   555 
   556 text {*
   557   \medskip Eta-contracting these two rules (to remove @{text P})
   558   causes them to be ignored because of their interaction with
   559   congruence rules.
   560 *}
   561 
   562 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   563   by (simp add: Ball_def)
   564 
   565 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   566   by (simp add: Bex_def)
   567 
   568 lemma UNIV_eq_I: "(\<And>x. x \<in> A) \<Longrightarrow> UNIV = A"
   569   by auto
   570 
   571 
   572 subsubsection {* The empty set *}
   573 
   574 lemma empty_def:
   575   "{} = {x. False}"
   576   by (simp add: bot_fun_eq bot_bool_eq Collect_def)
   577 
   578 lemma empty_iff [simp]: "(c : {}) = False"
   579   by (simp add: empty_def)
   580 
   581 lemma emptyE [elim!]: "a : {} ==> P"
   582   by simp
   583 
   584 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   585     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   586   by blast
   587 
   588 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   589   by blast
   590 
   591 lemma equals0D: "A = {} ==> a \<notin> A"
   592     -- {* Use for reasoning about disjointness: @{text "A Int B = {}"} *}
   593   by blast
   594 
   595 lemma ball_empty [simp]: "Ball {} P = True"
   596   by (simp add: Ball_def)
   597 
   598 lemma bex_empty [simp]: "Bex {} P = False"
   599   by (simp add: Bex_def)
   600 
   601 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   602   by (blast elim: equalityE)
   603 
   604 
   605 subsubsection {* The Powerset operator -- Pow *}
   606 
   607 definition Pow :: "'a set => 'a set set" where
   608   Pow_def: "Pow A = {B. B \<le> A}"
   609 
   610 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   611   by (simp add: Pow_def)
   612 
   613 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   614   by (simp add: Pow_def)
   615 
   616 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   617   by (simp add: Pow_def)
   618 
   619 lemma Pow_bottom: "{} \<in> Pow B"
   620   by simp
   621 
   622 lemma Pow_top: "A \<in> Pow A"
   623   by simp
   624 
   625 
   626 subsubsection {* Set complement *}
   627 
   628 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   629   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   630 
   631 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   632   by (unfold mem_def fun_Compl_def bool_Compl_def) blast
   633 
   634 text {*
   635   \medskip This form, with negated conclusion, works well with the
   636   Classical prover.  Negated assumptions behave like formulae on the
   637   right side of the notional turnstile ... *}
   638 
   639 lemma ComplD [dest!]: "c : -A ==> c~:A"
   640   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   641 
   642 lemmas ComplE = ComplD [elim_format]
   643 
   644 lemma Compl_eq: "- A = {x. ~ x : A}" by blast
   645 
   646 
   647 subsubsection {* Binary union -- Un *}
   648 
   649 abbreviation union :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Un" 65) where
   650   "op Un \<equiv> sup"
   651 
   652 notation (xsymbols)
   653   union  (infixl "\<union>" 65)
   654 
   655 notation (HTML output)
   656   union  (infixl "\<union>" 65)
   657 
   658 lemma Un_def:
   659   "A \<union> B = {x. x \<in> A \<or> x \<in> B}"
   660   by (simp add: sup_fun_eq sup_bool_eq Collect_def mem_def)
   661 
   662 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   663   by (unfold Un_def) blast
   664 
   665 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   666   by simp
   667 
   668 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   669   by simp
   670 
   671 text {*
   672   \medskip Classical introduction rule: no commitment to @{prop A} vs
   673   @{prop B}.
   674 *}
   675 
   676 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   677   by auto
   678 
   679 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   680   by (unfold Un_def) blast
   681 
   682 lemma insert_def: "insert a B = {x. x = a} \<union> B"
   683   by (simp add: Collect_def mem_def insert_compr Un_def)
   684 
   685 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
   686   by (fact mono_sup)
   687 
   688 
   689 subsubsection {* Binary intersection -- Int *}
   690 
   691 abbreviation inter :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Int" 70) where
   692   "op Int \<equiv> inf"
   693 
   694 notation (xsymbols)
   695   inter  (infixl "\<inter>" 70)
   696 
   697 notation (HTML output)
   698   inter  (infixl "\<inter>" 70)
   699 
   700 lemma Int_def:
   701   "A \<inter> B = {x. x \<in> A \<and> x \<in> B}"
   702   by (simp add: inf_fun_eq inf_bool_eq Collect_def mem_def)
   703 
   704 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   705   by (unfold Int_def) blast
   706 
   707 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   708   by simp
   709 
   710 lemma IntD1: "c : A Int B ==> c:A"
   711   by simp
   712 
   713 lemma IntD2: "c : A Int B ==> c:B"
   714   by simp
   715 
   716 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   717   by simp
   718 
   719 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
   720   by (fact mono_inf)
   721 
   722 
   723 subsubsection {* Set difference *}
   724 
   725 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   726   by (simp add: mem_def fun_diff_def bool_diff_def)
   727 
   728 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   729   by simp
   730 
   731 lemma DiffD1: "c : A - B ==> c : A"
   732   by simp
   733 
   734 lemma DiffD2: "c : A - B ==> c : B ==> P"
   735   by simp
   736 
   737 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   738   by simp
   739 
   740 lemma set_diff_eq: "A - B = {x. x : A & ~ x : B}" by blast
   741 
   742 lemma Compl_eq_Diff_UNIV: "-A = (UNIV - A)"
   743 by blast
   744 
   745 
   746 subsubsection {* Augmenting a set -- @{const insert} *}
   747 
   748 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   749   by (unfold insert_def) blast
   750 
   751 lemma insertI1: "a : insert a B"
   752   by simp
   753 
   754 lemma insertI2: "a : B ==> a : insert b B"
   755   by simp
   756 
   757 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   758   by (unfold insert_def) blast
   759 
   760 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   761   -- {* Classical introduction rule. *}
   762   by auto
   763 
   764 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   765   by auto
   766 
   767 lemma set_insert:
   768   assumes "x \<in> A"
   769   obtains B where "A = insert x B" and "x \<notin> B"
   770 proof
   771   from assms show "A = insert x (A - {x})" by blast
   772 next
   773   show "x \<notin> A - {x}" by blast
   774 qed
   775 
   776 lemma insert_ident: "x ~: A ==> x ~: B ==> (insert x A = insert x B) = (A = B)"
   777 by auto
   778 
   779 subsubsection {* Singletons, using insert *}
   780 
   781 lemma singletonI [intro!,no_atp]: "a : {a}"
   782     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   783   by (rule insertI1)
   784 
   785 lemma singletonD [dest!,no_atp]: "b : {a} ==> b = a"
   786   by blast
   787 
   788 lemmas singletonE = singletonD [elim_format]
   789 
   790 lemma singleton_iff: "(b : {a}) = (b = a)"
   791   by blast
   792 
   793 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   794   by blast
   795 
   796 lemma singleton_insert_inj_eq [iff,no_atp]:
   797      "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   798   by blast
   799 
   800 lemma singleton_insert_inj_eq' [iff,no_atp]:
   801      "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   802   by blast
   803 
   804 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   805   by fast
   806 
   807 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   808   by blast
   809 
   810 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   811   by blast
   812 
   813 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   814   by blast
   815 
   816 lemma doubleton_eq_iff: "({a,b} = {c,d}) = (a=c & b=d | a=d & b=c)"
   817   by (blast elim: equalityE)
   818 
   819 
   820 subsubsection {* Image of a set under a function *}
   821 
   822 text {*
   823   Frequently @{term b} does not have the syntactic form of @{term "f x"}.
   824 *}
   825 
   826 definition image :: "('a => 'b) => 'a set => 'b set" (infixr "`" 90) where
   827   image_def [no_atp]: "f ` A = {y. EX x:A. y = f(x)}"
   828 
   829 abbreviation
   830   range :: "('a => 'b) => 'b set" where -- "of function"
   831   "range f == f ` UNIV"
   832 
   833 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   834   by (unfold image_def) blast
   835 
   836 lemma imageI: "x : A ==> f x : f ` A"
   837   by (rule image_eqI) (rule refl)
   838 
   839 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   840   -- {* This version's more effective when we already have the
   841     required @{term x}. *}
   842   by (unfold image_def) blast
   843 
   844 lemma imageE [elim!]:
   845   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   846   -- {* The eta-expansion gives variable-name preservation. *}
   847   by (unfold image_def) blast
   848 
   849 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   850   by blast
   851 
   852 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   853   by blast
   854 
   855 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   856   -- {* This rewrite rule would confuse users if made default. *}
   857   by blast
   858 
   859 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   860   apply safe
   861    prefer 2 apply fast
   862   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
   863   done
   864 
   865 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   866   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   867     @{text hypsubst}, but breaks too many existing proofs. *}
   868   by blast
   869 
   870 text {*
   871   \medskip Range of a function -- just a translation for image!
   872 *}
   873 
   874 lemma range_eqI: "b = f x ==> b \<in> range f"
   875   by simp
   876 
   877 lemma rangeI: "f x \<in> range f"
   878   by simp
   879 
   880 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   881   by blast
   882 
   883 
   884 subsubsection {* Some rules with @{text "if"} *}
   885 
   886 text{* Elimination of @{text"{x. \<dots> & x=t & \<dots>}"}. *}
   887 
   888 lemma Collect_conv_if: "{x. x=a & P x} = (if P a then {a} else {})"
   889   by auto
   890 
   891 lemma Collect_conv_if2: "{x. a=x & P x} = (if P a then {a} else {})"
   892   by auto
   893 
   894 text {*
   895   Rewrite rules for boolean case-splitting: faster than @{text
   896   "split_if [split]"}.
   897 *}
   898 
   899 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   900   by (rule split_if)
   901 
   902 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   903   by (rule split_if)
   904 
   905 text {*
   906   Split ifs on either side of the membership relation.  Not for @{text
   907   "[simp]"} -- can cause goals to blow up!
   908 *}
   909 
   910 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   911   by (rule split_if)
   912 
   913 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   914   by (rule split_if [where P="%S. a : S"])
   915 
   916 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   917 
   918 (*Would like to add these, but the existing code only searches for the
   919   outer-level constant, which in this case is just Set.member; we instead need
   920   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   921   apply, then the formula should be kept.
   922   [("uminus", Compl_iff RS iffD1), ("minus", [Diff_iff RS iffD1]),
   923    ("Int", [IntD1,IntD2]),
   924    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   925  *)
   926 
   927 
   928 subsection {* Further operations and lemmas *}
   929 
   930 subsubsection {* The ``proper subset'' relation *}
   931 
   932 lemma psubsetI [intro!,no_atp]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
   933   by (unfold less_le) blast
   934 
   935 lemma psubsetE [elim!,no_atp]: 
   936     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
   937   by (unfold less_le) blast
   938 
   939 lemma psubset_insert_iff:
   940   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
   941   by (auto simp add: less_le subset_insert_iff)
   942 
   943 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
   944   by (simp only: less_le)
   945 
   946 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
   947   by (simp add: psubset_eq)
   948 
   949 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
   950 apply (unfold less_le)
   951 apply (auto dest: subset_antisym)
   952 done
   953 
   954 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
   955 apply (unfold less_le)
   956 apply (auto dest: subsetD)
   957 done
   958 
   959 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
   960   by (auto simp add: psubset_eq)
   961 
   962 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
   963   by (auto simp add: psubset_eq)
   964 
   965 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
   966   by (unfold less_le) blast
   967 
   968 lemma atomize_ball:
   969     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
   970   by (simp only: Ball_def atomize_all atomize_imp)
   971 
   972 lemmas [symmetric, rulify] = atomize_ball
   973   and [symmetric, defn] = atomize_ball
   974 
   975 subsubsection {* Derived rules involving subsets. *}
   976 
   977 text {* @{text insert}. *}
   978 
   979 lemma subset_insertI: "B \<subseteq> insert a B"
   980   by (rule subsetI) (erule insertI2)
   981 
   982 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
   983   by blast
   984 
   985 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
   986   by blast
   987 
   988 
   989 text {* \medskip Finite Union -- the least upper bound of two sets. *}
   990 
   991 lemma Un_upper1: "A \<subseteq> A \<union> B"
   992   by (fact sup_ge1)
   993 
   994 lemma Un_upper2: "B \<subseteq> A \<union> B"
   995   by (fact sup_ge2)
   996 
   997 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
   998   by (fact sup_least)
   999 
  1000 
  1001 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
  1002 
  1003 lemma Int_lower1: "A \<inter> B \<subseteq> A"
  1004   by (fact inf_le1)
  1005 
  1006 lemma Int_lower2: "A \<inter> B \<subseteq> B"
  1007   by (fact inf_le2)
  1008 
  1009 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
  1010   by (fact inf_greatest)
  1011 
  1012 
  1013 text {* \medskip Set difference. *}
  1014 
  1015 lemma Diff_subset: "A - B \<subseteq> A"
  1016   by blast
  1017 
  1018 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
  1019 by blast
  1020 
  1021 
  1022 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1023 
  1024 text {* @{text "{}"}. *}
  1025 
  1026 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1027   -- {* supersedes @{text "Collect_False_empty"} *}
  1028   by auto
  1029 
  1030 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1031   by blast
  1032 
  1033 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1034   by (unfold less_le) blast
  1035 
  1036 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1037 by blast
  1038 
  1039 lemma empty_Collect_eq [simp]: "({} = Collect P) = (\<forall>x. \<not> P x)"
  1040 by blast
  1041 
  1042 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1043   by blast
  1044 
  1045 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1046   by blast
  1047 
  1048 lemma Collect_imp_eq: "{x. P x --> Q x} = -{x. P x} \<union> {x. Q x}"
  1049   by blast
  1050 
  1051 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1052   by blast
  1053 
  1054 
  1055 text {* \medskip @{text insert}. *}
  1056 
  1057 lemma insert_is_Un: "insert a A = {a} Un A"
  1058   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1059   by blast
  1060 
  1061 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1062   by blast
  1063 
  1064 lemmas empty_not_insert = insert_not_empty [symmetric, standard]
  1065 declare empty_not_insert [simp]
  1066 
  1067 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1068   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1069   -- {* with \emph{quadratic} running time *}
  1070   by blast
  1071 
  1072 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1073   by blast
  1074 
  1075 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1076   by blast
  1077 
  1078 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1079   by blast
  1080 
  1081 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1082   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1083   apply (rule_tac x = "A - {a}" in exI, blast)
  1084   done
  1085 
  1086 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1087   by auto
  1088 
  1089 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1090   by blast
  1091 
  1092 lemma insert_disjoint [simp,no_atp]:
  1093  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1094  "({} = insert a A \<inter> B) = (a \<notin> B \<and> {} = A \<inter> B)"
  1095   by auto
  1096 
  1097 lemma disjoint_insert [simp,no_atp]:
  1098  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1099  "({} = A \<inter> insert b B) = (b \<notin> A \<and> {} = A \<inter> B)"
  1100   by auto
  1101 
  1102 text {* \medskip @{text image}. *}
  1103 
  1104 lemma image_empty [simp]: "f`{} = {}"
  1105   by blast
  1106 
  1107 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1108   by blast
  1109 
  1110 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1111   by auto
  1112 
  1113 lemma image_constant_conv: "(%x. c) ` A = (if A = {} then {} else {c})"
  1114 by auto
  1115 
  1116 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1117 by blast
  1118 
  1119 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1120 by blast
  1121 
  1122 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1123 by blast
  1124 
  1125 lemma empty_is_image[iff]: "({} = f ` A) = (A = {})"
  1126 by blast
  1127 
  1128 
  1129 lemma image_Collect [no_atp]: "f ` {x. P x} = {f x | x. P x}"
  1130   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS,
  1131       with its implicit quantifier and conjunction.  Also image enjoys better
  1132       equational properties than does the RHS. *}
  1133   by blast
  1134 
  1135 lemma if_image_distrib [simp]:
  1136   "(\<lambda>x. if P x then f x else g x) ` S
  1137     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1138   by (auto simp add: image_def)
  1139 
  1140 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1141   by (simp add: image_def)
  1142 
  1143 
  1144 text {* \medskip @{text range}. *}
  1145 
  1146 lemma full_SetCompr_eq [no_atp]: "{u. \<exists>x. u = f x} = range f"
  1147   by auto
  1148 
  1149 lemma range_composition: "range (\<lambda>x. f (g x)) = f`range g"
  1150 by (subst image_image, simp)
  1151 
  1152 
  1153 text {* \medskip @{text Int} *}
  1154 
  1155 lemma Int_absorb [simp]: "A \<inter> A = A"
  1156   by (fact inf_idem)
  1157 
  1158 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1159   by (fact inf_left_idem)
  1160 
  1161 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1162   by (fact inf_commute)
  1163 
  1164 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1165   by (fact inf_left_commute)
  1166 
  1167 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1168   by (fact inf_assoc)
  1169 
  1170 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1171   -- {* Intersection is an AC-operator *}
  1172 
  1173 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1174   by (fact inf_absorb2)
  1175 
  1176 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1177   by (fact inf_absorb1)
  1178 
  1179 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1180   by (fact inf_bot_left)
  1181 
  1182 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1183   by (fact inf_bot_right)
  1184 
  1185 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1186   by blast
  1187 
  1188 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1189   by blast
  1190 
  1191 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1192   by (fact inf_top_left)
  1193 
  1194 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1195   by (fact inf_top_right)
  1196 
  1197 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1198   by (fact inf_sup_distrib1)
  1199 
  1200 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1201   by (fact inf_sup_distrib2)
  1202 
  1203 lemma Int_UNIV [simp,no_atp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1204   by (fact inf_eq_top_iff)
  1205 
  1206 lemma Int_subset_iff [simp]: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1207   by (fact le_inf_iff)
  1208 
  1209 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1210   by blast
  1211 
  1212 
  1213 text {* \medskip @{text Un}. *}
  1214 
  1215 lemma Un_absorb [simp]: "A \<union> A = A"
  1216   by (fact sup_idem)
  1217 
  1218 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1219   by (fact sup_left_idem)
  1220 
  1221 lemma Un_commute: "A \<union> B = B \<union> A"
  1222   by (fact sup_commute)
  1223 
  1224 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1225   by (fact sup_left_commute)
  1226 
  1227 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1228   by (fact sup_assoc)
  1229 
  1230 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1231   -- {* Union is an AC-operator *}
  1232 
  1233 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1234   by (fact sup_absorb2)
  1235 
  1236 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1237   by (fact sup_absorb1)
  1238 
  1239 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1240   by (fact sup_bot_left)
  1241 
  1242 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1243   by (fact sup_bot_right)
  1244 
  1245 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1246   by (fact sup_top_left)
  1247 
  1248 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1249   by (fact sup_top_right)
  1250 
  1251 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1252   by blast
  1253 
  1254 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1255   by blast
  1256 
  1257 lemma Int_insert_left:
  1258     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1259   by auto
  1260 
  1261 lemma Int_insert_left_if0[simp]:
  1262     "a \<notin> C \<Longrightarrow> (insert a B) Int C = B \<inter> C"
  1263   by auto
  1264 
  1265 lemma Int_insert_left_if1[simp]:
  1266     "a \<in> C \<Longrightarrow> (insert a B) Int C = insert a (B Int C)"
  1267   by auto
  1268 
  1269 lemma Int_insert_right:
  1270     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1271   by auto
  1272 
  1273 lemma Int_insert_right_if0[simp]:
  1274     "a \<notin> A \<Longrightarrow> A Int (insert a B) = A Int B"
  1275   by auto
  1276 
  1277 lemma Int_insert_right_if1[simp]:
  1278     "a \<in> A \<Longrightarrow> A Int (insert a B) = insert a (A Int B)"
  1279   by auto
  1280 
  1281 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1282   by (fact sup_inf_distrib1)
  1283 
  1284 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1285   by (fact sup_inf_distrib2)
  1286 
  1287 lemma Un_Int_crazy:
  1288     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1289   by blast
  1290 
  1291 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1292   by (fact le_iff_sup)
  1293 
  1294 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1295   by (fact sup_eq_bot_iff)
  1296 
  1297 lemma Un_subset_iff [simp]: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1298   by (fact le_sup_iff)
  1299 
  1300 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1301   by blast
  1302 
  1303 lemma Diff_Int2: "A \<inter> C - B \<inter> C = A \<inter> C - B"
  1304   by blast
  1305 
  1306 
  1307 text {* \medskip Set complement *}
  1308 
  1309 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1310   by (fact inf_compl_bot)
  1311 
  1312 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1313   by (fact compl_inf_bot)
  1314 
  1315 lemma Compl_partition: "A \<union> -A = UNIV"
  1316   by (fact sup_compl_top)
  1317 
  1318 lemma Compl_partition2: "-A \<union> A = UNIV"
  1319   by (fact compl_sup_top)
  1320 
  1321 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1322   by (fact double_compl)
  1323 
  1324 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1325   by (fact compl_sup)
  1326 
  1327 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1328   by (fact compl_inf)
  1329 
  1330 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1331   by blast
  1332 
  1333 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1334   -- {* Halmos, Naive Set Theory, page 16. *}
  1335   by blast
  1336 
  1337 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1338   by (fact compl_top_eq)
  1339 
  1340 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1341   by (fact compl_bot_eq)
  1342 
  1343 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1344   by (fact compl_le_compl_iff)
  1345 
  1346 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1347   by (fact compl_eq_compl_iff)
  1348 
  1349 text {* \medskip Bounded quantifiers.
  1350 
  1351   The following are not added to the default simpset because
  1352   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1353 
  1354 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1355   by blast
  1356 
  1357 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1358   by blast
  1359 
  1360 
  1361 text {* \medskip Set difference. *}
  1362 
  1363 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1364   by blast
  1365 
  1366 lemma Diff_eq_empty_iff [simp,no_atp]: "(A - B = {}) = (A \<subseteq> B)"
  1367   by blast
  1368 
  1369 lemma Diff_cancel [simp]: "A - A = {}"
  1370   by blast
  1371 
  1372 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1373 by blast
  1374 
  1375 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1376   by (blast elim: equalityE)
  1377 
  1378 lemma empty_Diff [simp]: "{} - A = {}"
  1379   by blast
  1380 
  1381 lemma Diff_empty [simp]: "A - {} = A"
  1382   by blast
  1383 
  1384 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1385   by blast
  1386 
  1387 lemma Diff_insert0 [simp,no_atp]: "x \<notin> A ==> A - insert x B = A - B"
  1388   by blast
  1389 
  1390 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1391   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1392   by blast
  1393 
  1394 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1395   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1396   by blast
  1397 
  1398 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1399   by auto
  1400 
  1401 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1402   by blast
  1403 
  1404 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1405 by blast
  1406 
  1407 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1408   by blast
  1409 
  1410 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1411   by auto
  1412 
  1413 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1414   by blast
  1415 
  1416 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1417   by blast
  1418 
  1419 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1420   by blast
  1421 
  1422 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1423   by blast
  1424 
  1425 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1426   by blast
  1427 
  1428 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1429   by blast
  1430 
  1431 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1432   by blast
  1433 
  1434 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1435   by blast
  1436 
  1437 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1438   by blast
  1439 
  1440 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1441   by blast
  1442 
  1443 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1444   by blast
  1445 
  1446 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1447   by auto
  1448 
  1449 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1450   by blast
  1451 
  1452 
  1453 text {* \medskip Quantification over type @{typ bool}. *}
  1454 
  1455 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1456   by (cases x) auto
  1457 
  1458 lemma all_bool_eq: "(\<forall>b. P b) \<longleftrightarrow> P True \<and> P False"
  1459   by (auto intro: bool_induct)
  1460 
  1461 lemma bool_contrapos: "P x \<Longrightarrow> \<not> P False \<Longrightarrow> P True"
  1462   by (cases x) auto
  1463 
  1464 lemma ex_bool_eq: "(\<exists>b. P b) \<longleftrightarrow> P True \<or> P False"
  1465   by (auto intro: bool_contrapos)
  1466 
  1467 text {* \medskip @{text Pow} *}
  1468 
  1469 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1470   by (auto simp add: Pow_def)
  1471 
  1472 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1473   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1474 
  1475 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1476   by (blast intro: exI [where ?x = "- u", standard])
  1477 
  1478 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1479   by blast
  1480 
  1481 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1482   by blast
  1483 
  1484 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1485   by blast
  1486 
  1487 
  1488 text {* \medskip Miscellany. *}
  1489 
  1490 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1491   by blast
  1492 
  1493 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1494   by blast
  1495 
  1496 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1497   by (unfold less_le) blast
  1498 
  1499 lemma all_not_in_conv [simp]: "(\<forall>x. x \<notin> A) = (A = {})"
  1500   by blast
  1501 
  1502 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1503   by blast
  1504 
  1505 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1506   by iprover
  1507 
  1508 
  1509 subsubsection {* Monotonicity of various operations *}
  1510 
  1511 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1512   by blast
  1513 
  1514 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1515   by blast
  1516 
  1517 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1518   by blast
  1519 
  1520 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1521   by (fact sup_mono)
  1522 
  1523 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1524   by (fact inf_mono)
  1525 
  1526 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1527   by blast
  1528 
  1529 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1530   by (fact compl_mono)
  1531 
  1532 text {* \medskip Monotonicity of implications. *}
  1533 
  1534 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1535   apply (rule impI)
  1536   apply (erule subsetD, assumption)
  1537   done
  1538 
  1539 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1540   by iprover
  1541 
  1542 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1543   by iprover
  1544 
  1545 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1546   by iprover
  1547 
  1548 lemma imp_refl: "P --> P" ..
  1549 
  1550 lemma not_mono: "Q --> P ==> ~ P --> ~ Q"
  1551   by iprover
  1552 
  1553 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1554   by iprover
  1555 
  1556 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1557   by iprover
  1558 
  1559 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  1560   by blast
  1561 
  1562 lemma Int_Collect_mono:
  1563     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  1564   by blast
  1565 
  1566 lemmas basic_monos =
  1567   subset_refl imp_refl disj_mono conj_mono
  1568   ex_mono Collect_mono in_mono
  1569 
  1570 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  1571   by iprover
  1572 
  1573 
  1574 subsubsection {* Inverse image of a function *}
  1575 
  1576 definition vimage :: "('a => 'b) => 'b set => 'a set" (infixr "-`" 90) where
  1577   "f -` B == {x. f x : B}"
  1578 
  1579 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  1580   by (unfold vimage_def) blast
  1581 
  1582 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  1583   by simp
  1584 
  1585 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  1586   by (unfold vimage_def) blast
  1587 
  1588 lemma vimageI2: "f a : A ==> a : f -` A"
  1589   by (unfold vimage_def) fast
  1590 
  1591 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  1592   by (unfold vimage_def) blast
  1593 
  1594 lemma vimageD: "a : f -` A ==> f a : A"
  1595   by (unfold vimage_def) fast
  1596 
  1597 lemma vimage_empty [simp]: "f -` {} = {}"
  1598   by blast
  1599 
  1600 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  1601   by blast
  1602 
  1603 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  1604   by blast
  1605 
  1606 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  1607   by fast
  1608 
  1609 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  1610   by blast
  1611 
  1612 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  1613   by blast
  1614 
  1615 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  1616   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  1617   by blast
  1618 
  1619 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  1620   by blast
  1621 
  1622 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  1623   by blast
  1624 
  1625 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  1626   -- {* monotonicity *}
  1627   by blast
  1628 
  1629 lemma vimage_image_eq [no_atp]: "f -` (f ` A) = {y. EX x:A. f x = f y}"
  1630 by (blast intro: sym)
  1631 
  1632 lemma image_vimage_subset: "f ` (f -` A) <= A"
  1633 by blast
  1634 
  1635 lemma image_vimage_eq [simp]: "f ` (f -` A) = A Int range f"
  1636 by blast
  1637 
  1638 lemma vimage_const [simp]: "((\<lambda>x. c) -` A) = (if c \<in> A then UNIV else {})"
  1639   by auto
  1640 
  1641 lemma vimage_if [simp]: "((\<lambda>x. if x \<in> B then c else d) -` A) = 
  1642    (if c \<in> A then (if d \<in> A then UNIV else B)
  1643     else if d \<in> A then -B else {})"  
  1644   by (auto simp add: vimage_def) 
  1645 
  1646 lemma vimage_inter_cong:
  1647   "(\<And> w. w \<in> S \<Longrightarrow> f w = g w) \<Longrightarrow> f -` y \<inter> S = g -` y \<inter> S"
  1648   by auto
  1649 
  1650 lemma image_Int_subset: "f`(A Int B) <= f`A Int f`B"
  1651 by blast
  1652 
  1653 lemma image_diff_subset: "f`A - f`B <= f`(A - B)"
  1654 by blast
  1655 
  1656 
  1657 subsubsection {* Getting the Contents of a Singleton Set *}
  1658 
  1659 definition contents :: "'a set \<Rightarrow> 'a" where
  1660   "contents X = (THE x. X = {x})"
  1661 
  1662 lemma contents_eq [simp]: "contents {x} = x"
  1663   by (simp add: contents_def)
  1664 
  1665 
  1666 subsubsection {* Least value operator *}
  1667 
  1668 lemma Least_mono:
  1669   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1670     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1671     -- {* Courtesy of Stephan Merz *}
  1672   apply clarify
  1673   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  1674   apply (rule LeastI2_order)
  1675   apply (auto elim: monoD intro!: order_antisym)
  1676   done
  1677 
  1678 subsection {* Misc *}
  1679 
  1680 text {* Rudimentary code generation *}
  1681 
  1682 lemma insert_code [code]: "insert y A x \<longleftrightarrow> y = x \<or> A x"
  1683   by (auto simp add: insert_compr Collect_def mem_def)
  1684 
  1685 lemma vimage_code [code]: "(f -` A) x = A (f x)"
  1686   by (simp add: vimage_def Collect_def mem_def)
  1687 
  1688 hide_const (open) member
  1689 
  1690 text {* Misc theorem and ML bindings *}
  1691 
  1692 lemmas equalityI = subset_antisym
  1693 
  1694 ML {*
  1695 val Ball_def = @{thm Ball_def}
  1696 val Bex_def = @{thm Bex_def}
  1697 val CollectD = @{thm CollectD}
  1698 val CollectE = @{thm CollectE}
  1699 val CollectI = @{thm CollectI}
  1700 val Collect_conj_eq = @{thm Collect_conj_eq}
  1701 val Collect_mem_eq = @{thm Collect_mem_eq}
  1702 val IntD1 = @{thm IntD1}
  1703 val IntD2 = @{thm IntD2}
  1704 val IntE = @{thm IntE}
  1705 val IntI = @{thm IntI}
  1706 val Int_Collect = @{thm Int_Collect}
  1707 val UNIV_I = @{thm UNIV_I}
  1708 val UNIV_witness = @{thm UNIV_witness}
  1709 val UnE = @{thm UnE}
  1710 val UnI1 = @{thm UnI1}
  1711 val UnI2 = @{thm UnI2}
  1712 val ballE = @{thm ballE}
  1713 val ballI = @{thm ballI}
  1714 val bexCI = @{thm bexCI}
  1715 val bexE = @{thm bexE}
  1716 val bexI = @{thm bexI}
  1717 val bex_triv = @{thm bex_triv}
  1718 val bspec = @{thm bspec}
  1719 val contra_subsetD = @{thm contra_subsetD}
  1720 val distinct_lemma = @{thm distinct_lemma}
  1721 val eq_to_mono = @{thm eq_to_mono}
  1722 val equalityCE = @{thm equalityCE}
  1723 val equalityD1 = @{thm equalityD1}
  1724 val equalityD2 = @{thm equalityD2}
  1725 val equalityE = @{thm equalityE}
  1726 val equalityI = @{thm equalityI}
  1727 val imageE = @{thm imageE}
  1728 val imageI = @{thm imageI}
  1729 val image_Un = @{thm image_Un}
  1730 val image_insert = @{thm image_insert}
  1731 val insert_commute = @{thm insert_commute}
  1732 val insert_iff = @{thm insert_iff}
  1733 val mem_Collect_eq = @{thm mem_Collect_eq}
  1734 val rangeE = @{thm rangeE}
  1735 val rangeI = @{thm rangeI}
  1736 val range_eqI = @{thm range_eqI}
  1737 val subsetCE = @{thm subsetCE}
  1738 val subsetD = @{thm subsetD}
  1739 val subsetI = @{thm subsetI}
  1740 val subset_refl = @{thm subset_refl}
  1741 val subset_trans = @{thm subset_trans}
  1742 val vimageD = @{thm vimageD}
  1743 val vimageE = @{thm vimageE}
  1744 val vimageI = @{thm vimageI}
  1745 val vimageI2 = @{thm vimageI2}
  1746 val vimage_Collect = @{thm vimage_Collect}
  1747 val vimage_Int = @{thm vimage_Int}
  1748 val vimage_Un = @{thm vimage_Un}
  1749 *}
  1750 
  1751 end