src/HOL/Tools/hologic.ML
author wenzelm
Sat Mar 22 18:19:57 2014 +0100 (2014-03-22)
changeset 56254 a2dd9200854d
parent 55414 eab03e9cee8a
child 59058 a78612c67ec0
permissions -rw-r--r--
more antiquotations;
     1 (*  Title:      HOL/Tools/hologic.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Abstract syntax operations for HOL.
     5 *)
     6 
     7 signature HOLOGIC =
     8 sig
     9   val id_const: typ -> term
    10   val mk_comp: term * term -> term
    11   val boolN: string
    12   val boolT: typ
    13   val Trueprop: term
    14   val mk_Trueprop: term -> term
    15   val dest_Trueprop: term -> term
    16   val Trueprop_conv: conv -> conv
    17   val mk_induct_forall: typ -> term
    18   val mk_setT: typ -> typ
    19   val dest_setT: typ -> typ
    20   val Collect_const: typ -> term
    21   val mk_Collect: string * typ * term -> term
    22   val mk_mem: term * term -> term
    23   val dest_mem: term -> term * term
    24   val mk_set: typ -> term list -> term
    25   val dest_set: term -> term list
    26   val mk_UNIV: typ -> term
    27   val conj_intr: thm -> thm -> thm
    28   val conj_elim: thm -> thm * thm
    29   val conj_elims: thm -> thm list
    30   val conj: term
    31   val disj: term
    32   val imp: term
    33   val Not: term
    34   val mk_conj: term * term -> term
    35   val mk_disj: term * term -> term
    36   val mk_imp: term * term -> term
    37   val mk_not: term -> term
    38   val dest_conj: term -> term list
    39   val conjuncts: term -> term list
    40   val dest_disj: term -> term list
    41   val disjuncts: term -> term list
    42   val dest_imp: term -> term * term
    43   val dest_not: term -> term
    44   val conj_conv: conv -> conv -> conv
    45   val eq_const: typ -> term
    46   val mk_eq: term * term -> term
    47   val dest_eq: term -> term * term
    48   val eq_conv: conv -> conv -> conv
    49   val all_const: typ -> term
    50   val mk_all: string * typ * term -> term
    51   val list_all: (string * typ) list * term -> term
    52   val exists_const: typ -> term
    53   val mk_exists: string * typ * term -> term
    54   val choice_const: typ -> term
    55   val class_equal: string
    56   val mk_binop: string -> term * term -> term
    57   val mk_binrel: string -> term * term -> term
    58   val dest_bin: string -> typ -> term -> term * term
    59   val unitT: typ
    60   val is_unitT: typ -> bool
    61   val unit: term
    62   val is_unit: term -> bool
    63   val mk_prodT: typ * typ -> typ
    64   val dest_prodT: typ -> typ * typ
    65   val pair_const: typ -> typ -> term
    66   val mk_prod: term * term -> term
    67   val dest_prod: term -> term * term
    68   val mk_fst: term -> term
    69   val mk_snd: term -> term
    70   val split_const: typ * typ * typ -> term
    71   val mk_split: term -> term
    72   val flatten_tupleT: typ -> typ list
    73   val tupled_lambda: term -> term -> term
    74   val mk_tupleT: typ list -> typ
    75   val strip_tupleT: typ -> typ list
    76   val mk_tuple: term list -> term
    77   val strip_tuple: term -> term list
    78   val mk_ptupleT: int list list -> typ list -> typ
    79   val strip_ptupleT: int list list -> typ -> typ list
    80   val flat_tupleT_paths: typ -> int list list
    81   val mk_ptuple: int list list -> typ -> term list -> term
    82   val strip_ptuple: int list list -> term -> term list
    83   val flat_tuple_paths: term -> int list list
    84   val mk_psplits: int list list -> typ -> typ -> term -> term
    85   val strip_psplits: term -> term * typ list * int list list
    86   val natT: typ
    87   val zero: term
    88   val is_zero: term -> bool
    89   val mk_Suc: term -> term
    90   val dest_Suc: term -> term
    91   val Suc_zero: term
    92   val mk_nat: int -> term
    93   val dest_nat: term -> int
    94   val class_size: string
    95   val size_const: typ -> term
    96   val intT: typ
    97   val one_const: term
    98   val bit0_const: term
    99   val bit1_const: term
   100   val mk_bit: int -> term
   101   val dest_bit: term -> int
   102   val mk_numeral: int -> term
   103   val dest_num: term -> int
   104   val numeral_const: typ -> term
   105   val add_numerals: term -> (term * typ) list -> (term * typ) list
   106   val mk_number: typ -> int -> term
   107   val dest_number: term -> typ * int
   108   val code_integerT: typ
   109   val code_naturalT: typ
   110   val realT: typ
   111   val nibbleT: typ
   112   val mk_nibble: int -> term
   113   val dest_nibble: term -> int
   114   val charT: typ
   115   val mk_char: int -> term
   116   val dest_char: term -> int
   117   val listT: typ -> typ
   118   val nil_const: typ -> term
   119   val cons_const: typ -> term
   120   val mk_list: typ -> term list -> term
   121   val dest_list: term -> term list
   122   val stringT: typ
   123   val mk_string: string -> term
   124   val dest_string: term -> string
   125   val literalT: typ
   126   val mk_literal: string -> term
   127   val dest_literal: term -> string
   128   val mk_typerep: typ -> term
   129   val termT: typ
   130   val term_of_const: typ -> term
   131   val mk_term_of: typ -> term -> term
   132   val reflect_term: term -> term
   133   val mk_valtermify_app: string -> (string * typ) list -> typ -> term
   134   val mk_return: typ -> typ -> term -> term
   135   val mk_ST: ((term * typ) * (string * typ) option)  list -> term -> typ -> typ option * typ -> term
   136   val mk_random: typ -> term -> term
   137 end;
   138 
   139 structure HOLogic: HOLOGIC =
   140 struct
   141 
   142 (* functions *)
   143 
   144 fun id_const T = Const ("Fun.id", T --> T);
   145 
   146 fun mk_comp (f, g) =
   147   let
   148     val fT = fastype_of f;
   149     val gT = fastype_of g;
   150     val compT = fT --> gT --> domain_type gT --> range_type fT;
   151   in Const ("Fun.comp", compT) $ f $ g end;
   152 
   153 
   154 (* bool and set *)
   155 
   156 val boolN = "HOL.bool";
   157 val boolT = Type (boolN, []);
   158 
   159 fun mk_induct_forall T = Const ("HOL.induct_forall", (T --> boolT) --> boolT);
   160 
   161 fun mk_setT T = Type ("Set.set", [T]);
   162 
   163 fun dest_setT (Type ("Set.set", [T])) = T
   164   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   165 
   166 fun mk_set T ts =
   167   let
   168     val sT = mk_setT T;
   169     val empty = Const ("Orderings.bot_class.bot", sT);
   170     fun insert t u = Const ("Set.insert", T --> sT --> sT) $ t $ u;
   171   in fold_rev insert ts empty end;
   172 
   173 fun mk_UNIV T = Const ("Orderings.top_class.top", mk_setT T);
   174 
   175 fun dest_set (Const ("Orderings.bot_class.bot", _)) = []
   176   | dest_set (Const ("Set.insert", _) $ t $ u) = t :: dest_set u
   177   | dest_set t = raise TERM ("dest_set", [t]);
   178 
   179 fun Collect_const T = Const ("Set.Collect", (T --> boolT) --> mk_setT T);
   180 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T) t;
   181 
   182 fun mk_mem (x, A) =
   183   let val setT = fastype_of A in
   184     Const ("Set.member", dest_setT setT --> setT --> boolT) $ x $ A
   185   end;
   186 
   187 fun dest_mem (Const ("Set.member", _) $ x $ A) = (x, A)
   188   | dest_mem t = raise TERM ("dest_mem", [t]);
   189 
   190 
   191 (* logic *)
   192 
   193 val Trueprop = Const (@{const_name Trueprop}, boolT --> propT);
   194 
   195 fun mk_Trueprop P = Trueprop $ P;
   196 
   197 fun dest_Trueprop (Const (@{const_name Trueprop}, _) $ P) = P
   198   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   199 
   200 fun Trueprop_conv cv ct =
   201   (case Thm.term_of ct of
   202     Const (@{const_name Trueprop}, _) $ _ => Conv.arg_conv cv ct
   203   | _ => raise CTERM ("Trueprop_conv", [ct]))
   204 
   205 
   206 fun conj_intr thP thQ =
   207   let
   208     val (P, Q) = pairself (Object_Logic.dest_judgment o Thm.cprop_of) (thP, thQ)
   209       handle CTERM (msg, _) => raise THM (msg, 0, [thP, thQ]);
   210     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   211   in Drule.implies_elim_list (inst @{thm conjI}) [thP, thQ] end;
   212 
   213 fun conj_elim thPQ =
   214   let
   215     val (P, Q) = Thm.dest_binop (Object_Logic.dest_judgment (Thm.cprop_of thPQ))
   216       handle CTERM (msg, _) => raise THM (msg, 0, [thPQ]);
   217     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   218     val thP = Thm.implies_elim (inst @{thm conjunct1}) thPQ;
   219     val thQ = Thm.implies_elim (inst @{thm conjunct2}) thPQ;
   220   in (thP, thQ) end;
   221 
   222 fun conj_elims th =
   223   let val (th1, th2) = conj_elim th
   224   in conj_elims th1 @ conj_elims th2 end handle THM _ => [th];
   225 
   226 val conj = @{term HOL.conj}
   227 and disj = @{term HOL.disj}
   228 and imp = @{term implies}
   229 and Not = @{term Not};
   230 
   231 fun mk_conj (t1, t2) = conj $ t1 $ t2
   232 and mk_disj (t1, t2) = disj $ t1 $ t2
   233 and mk_imp (t1, t2) = imp $ t1 $ t2
   234 and mk_not t = Not $ t;
   235 
   236 fun dest_conj (Const ("HOL.conj", _) $ t $ t') = t :: dest_conj t'
   237   | dest_conj t = [t];
   238 
   239 (*Like dest_conj, but flattens conjunctions however nested*)
   240 fun conjuncts_aux (Const ("HOL.conj", _) $ t $ t') conjs = conjuncts_aux t (conjuncts_aux t' conjs)
   241   | conjuncts_aux t conjs = t::conjs;
   242 
   243 fun conjuncts t = conjuncts_aux t [];
   244 
   245 fun dest_disj (Const ("HOL.disj", _) $ t $ t') = t :: dest_disj t'
   246   | dest_disj t = [t];
   247 
   248 (*Like dest_disj, but flattens disjunctions however nested*)
   249 fun disjuncts_aux (Const ("HOL.disj", _) $ t $ t') disjs = disjuncts_aux t (disjuncts_aux t' disjs)
   250   | disjuncts_aux t disjs = t::disjs;
   251 
   252 fun disjuncts t = disjuncts_aux t [];
   253 
   254 fun dest_imp (Const ("HOL.implies", _) $ A $ B) = (A, B)
   255   | dest_imp  t = raise TERM ("dest_imp", [t]);
   256 
   257 fun dest_not (Const ("HOL.Not", _) $ t) = t
   258   | dest_not t = raise TERM ("dest_not", [t]);
   259 
   260 
   261 fun conj_conv cv1 cv2 ct =
   262   (case Thm.term_of ct of
   263     Const (@{const_name HOL.conj}, _) $ _ $ _ =>
   264       Conv.combination_conv (Conv.arg_conv cv1) cv2 ct
   265   | _ => raise CTERM ("conj_conv", [ct]));
   266 
   267 
   268 fun eq_const T = Const (@{const_name HOL.eq}, T --> T --> boolT);
   269 
   270 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   271 
   272 fun dest_eq (Const (@{const_name HOL.eq}, _) $ lhs $ rhs) = (lhs, rhs)
   273   | dest_eq t = raise TERM ("dest_eq", [t])
   274 
   275 fun eq_conv cv1 cv2 ct =
   276   (case Thm.term_of ct of
   277     Const (@{const_name HOL.eq}, _) $ _ $ _ => Conv.combination_conv (Conv.arg_conv cv1) cv2 ct
   278   | _ => raise CTERM ("eq_conv", [ct]));
   279 
   280 
   281 fun all_const T = Const ("HOL.All", (T --> boolT) --> boolT);
   282 fun mk_all (x, T, P) = all_const T $ absfree (x, T) P;
   283 fun list_all (xs, t) = fold_rev (fn (x, T) => fn P => all_const T $ Abs (x, T, P)) xs t;
   284 
   285 fun exists_const T = Const ("HOL.Ex", (T --> boolT) --> boolT);
   286 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T) P;
   287 
   288 fun choice_const T = Const("Hilbert_Choice.Eps", (T --> boolT) --> T);
   289 
   290 val class_equal = "HOL.equal";
   291 
   292 
   293 (* binary operations and relations *)
   294 
   295 fun mk_binop c (t, u) =
   296   let val T = fastype_of t
   297   in Const (c, T --> T --> T) $ t $ u end;
   298 
   299 fun mk_binrel c (t, u) =
   300   let val T = fastype_of t
   301   in Const (c, T --> T --> boolT) $ t $ u end;
   302 
   303 (*destruct the application of a binary operator. The dummyT case is a crude
   304   way of handling polymorphic operators.*)
   305 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   306       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   307       else raise TERM ("dest_bin " ^ c, [tm])
   308   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   309 
   310 
   311 (* unit *)
   312 
   313 val unitT = Type ("Product_Type.unit", []);
   314 
   315 fun is_unitT (Type ("Product_Type.unit", [])) = true
   316   | is_unitT _ = false;
   317 
   318 val unit = Const ("Product_Type.Unity", unitT);
   319 
   320 fun is_unit (Const ("Product_Type.Unity", _)) = true
   321   | is_unit _ = false;
   322 
   323 
   324 (* prod *)
   325 
   326 fun mk_prodT (T1, T2) = Type ("Product_Type.prod", [T1, T2]);
   327 
   328 fun dest_prodT (Type ("Product_Type.prod", [T1, T2])) = (T1, T2)
   329   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   330 
   331 fun pair_const T1 T2 = Const ("Product_Type.Pair", T1 --> T2 --> mk_prodT (T1, T2));
   332 
   333 fun mk_prod (t1, t2) =
   334   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   335     pair_const T1 T2 $ t1 $ t2
   336   end;
   337 
   338 fun dest_prod (Const ("Product_Type.Pair", _) $ t1 $ t2) = (t1, t2)
   339   | dest_prod t = raise TERM ("dest_prod", [t]);
   340 
   341 fun mk_fst p =
   342   let val pT = fastype_of p in
   343     Const ("Product_Type.prod.fst", pT --> fst (dest_prodT pT)) $ p
   344   end;
   345 
   346 fun mk_snd p =
   347   let val pT = fastype_of p in
   348     Const ("Product_Type.prod.snd", pT --> snd (dest_prodT pT)) $ p
   349   end;
   350 
   351 fun split_const (A, B, C) =
   352   Const ("Product_Type.prod.case_prod", (A --> B --> C) --> mk_prodT (A, B) --> C);
   353 
   354 fun mk_split t =
   355   (case Term.fastype_of t of
   356     T as (Type ("fun", [A, Type ("fun", [B, C])])) =>
   357       Const ("Product_Type.prod.case_prod", T --> mk_prodT (A, B) --> C) $ t
   358   | _ => raise TERM ("mk_split: bad body type", [t]));
   359 
   360 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   361 fun flatten_tupleT (Type ("Product_Type.prod", [T1, T2])) = flatten_tupleT T1 @ flatten_tupleT T2
   362   | flatten_tupleT T = [T];
   363 
   364 (*abstraction over nested tuples*)
   365 fun tupled_lambda (x as Free _) b = lambda x b
   366   | tupled_lambda (x as Var _) b = lambda x b
   367   | tupled_lambda (Const ("Product_Type.Pair", _) $ u $ v) b =
   368       mk_split (tupled_lambda u (tupled_lambda v b))
   369   | tupled_lambda (Const ("Product_Type.Unity", _)) b =
   370       Abs ("x", unitT, b)
   371   | tupled_lambda t _ = raise TERM ("tupled_lambda: bad tuple", [t]);
   372 
   373 
   374 (* tuples with right-fold structure *)
   375 
   376 fun mk_tupleT [] = unitT
   377   | mk_tupleT Ts = foldr1 mk_prodT Ts;
   378 
   379 fun strip_tupleT (Type ("Product_Type.unit", [])) = []
   380   | strip_tupleT (Type ("Product_Type.prod", [T1, T2])) = T1 :: strip_tupleT T2
   381   | strip_tupleT T = [T];
   382 
   383 fun mk_tuple [] = unit
   384   | mk_tuple ts = foldr1 mk_prod ts;
   385 
   386 fun strip_tuple (Const ("Product_Type.Unity", _)) = []
   387   | strip_tuple (Const ("Product_Type.Pair", _) $ t1 $ t2) = t1 :: strip_tuple t2
   388   | strip_tuple t = [t];
   389 
   390 
   391 (* tuples with specific arities
   392 
   393    an "arity" of a tuple is a list of lists of integers,
   394    denoting paths to subterms that are pairs
   395 *)
   396 
   397 fun ptuple_err s = raise TERM (s ^ ": inconsistent use of nested products", []);
   398 
   399 fun mk_ptupleT ps =
   400   let
   401     fun mk p Ts =
   402       if member (op =) ps p then
   403         let
   404           val (T, Ts') = mk (1::p) Ts;
   405           val (U, Ts'') = mk (2::p) Ts'
   406         in (mk_prodT (T, U), Ts'') end
   407       else (hd Ts, tl Ts)
   408   in fst o mk [] end;
   409 
   410 fun strip_ptupleT ps =
   411   let
   412     fun factors p T = if member (op =) ps p then (case T of
   413         Type ("Product_Type.prod", [T1, T2]) =>
   414           factors (1::p) T1 @ factors (2::p) T2
   415       | _ => ptuple_err "strip_ptupleT") else [T]
   416   in factors [] end;
   417 
   418 val flat_tupleT_paths =
   419   let
   420     fun factors p (Type ("Product_Type.prod", [T1, T2])) =
   421           p :: factors (1::p) T1 @ factors (2::p) T2
   422       | factors p _ = []
   423   in factors [] end;
   424 
   425 fun mk_ptuple ps =
   426   let
   427     fun mk p T ts =
   428       if member (op =) ps p then (case T of
   429           Type ("Product_Type.prod", [T1, T2]) =>
   430             let
   431               val (t, ts') = mk (1::p) T1 ts;
   432               val (u, ts'') = mk (2::p) T2 ts'
   433             in (pair_const T1 T2 $ t $ u, ts'') end
   434         | _ => ptuple_err "mk_ptuple")
   435       else (hd ts, tl ts)
   436   in fst oo mk [] end;
   437 
   438 fun strip_ptuple ps =
   439   let
   440     fun dest p t = if member (op =) ps p then (case t of
   441         Const ("Product_Type.Pair", _) $ t $ u =>
   442           dest (1::p) t @ dest (2::p) u
   443       | _ => ptuple_err "strip_ptuple") else [t]
   444   in dest [] end;
   445 
   446 val flat_tuple_paths =
   447   let
   448     fun factors p (Const ("Product_Type.Pair", _) $ t $ u) =
   449           p :: factors (1::p) t @ factors (2::p) u
   450       | factors p _ = []
   451   in factors [] end;
   452 
   453 (*In mk_psplits ps S T u, term u expects separate arguments for the factors of S,
   454   with result type T.  The call creates a new term expecting one argument
   455   of type S.*)
   456 fun mk_psplits ps T T3 u =
   457   let
   458     fun ap ((p, T) :: pTs) =
   459           if member (op =) ps p then (case T of
   460               Type ("Product_Type.prod", [T1, T2]) =>
   461                 split_const (T1, T2, map snd pTs ---> T3) $
   462                   ap ((1::p, T1) :: (2::p, T2) :: pTs)
   463             | _ => ptuple_err "mk_psplits")
   464           else Abs ("x", T, ap pTs)
   465       | ap [] =
   466           let val k = length ps
   467           in list_comb (incr_boundvars (k + 1) u, map Bound (k downto 0)) end
   468   in ap [([], T)] end;
   469 
   470 val strip_psplits =
   471   let
   472     fun strip [] qs Ts t = (t, rev Ts, qs)
   473       | strip (p :: ps) qs Ts (Const ("Product_Type.prod.case_prod", _) $ t) =
   474           strip ((1 :: p) :: (2 :: p) :: ps) (p :: qs) Ts t
   475       | strip (p :: ps) qs Ts (Abs (s, T, t)) = strip ps qs (T :: Ts) t
   476       | strip (p :: ps) qs Ts t = strip ps qs
   477           (hd (binder_types (fastype_of1 (Ts, t))) :: Ts)
   478           (incr_boundvars 1 t $ Bound 0)
   479   in strip [[]] [] [] end;
   480 
   481 
   482 (* nat *)
   483 
   484 val natT = Type ("Nat.nat", []);
   485 
   486 val zero = Const ("Groups.zero_class.zero", natT);
   487 
   488 fun is_zero (Const ("Groups.zero_class.zero", _)) = true
   489   | is_zero _ = false;
   490 
   491 fun mk_Suc t = Const ("Nat.Suc", natT --> natT) $ t;
   492 
   493 fun dest_Suc (Const ("Nat.Suc", _) $ t) = t
   494   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   495 
   496 val Suc_zero = mk_Suc zero;
   497 
   498 fun mk_nat n =
   499   let
   500     fun mk 0 = zero
   501       | mk n = mk_Suc (mk (n - 1));
   502   in if n < 0 then raise TERM ("mk_nat: negative number", []) else mk n end;
   503 
   504 fun dest_nat (Const ("Groups.zero_class.zero", _)) = 0
   505   | dest_nat (Const ("Nat.Suc", _) $ t) = dest_nat t + 1
   506   | dest_nat t = raise TERM ("dest_nat", [t]);
   507 
   508 val class_size = "Nat.size";
   509 
   510 fun size_const T = Const ("Nat.size_class.size", T --> natT);
   511 
   512 
   513 (* binary numerals and int *)
   514 
   515 val numT = Type ("Num.num", []);
   516 val intT = Type ("Int.int", []);
   517 
   518 val one_const = Const ("Num.num.One", numT)
   519 and bit0_const = Const ("Num.num.Bit0", numT --> numT)
   520 and bit1_const = Const ("Num.num.Bit1", numT --> numT);
   521 
   522 fun mk_bit 0 = bit0_const
   523   | mk_bit 1 = bit1_const
   524   | mk_bit _ = raise TERM ("mk_bit", []);
   525 
   526 fun dest_bit (Const ("Num.num.Bit0", _)) = 0
   527   | dest_bit (Const ("Num.num.Bit1", _)) = 1
   528   | dest_bit t = raise TERM ("dest_bit", [t]);
   529 
   530 fun mk_numeral i =
   531   let fun mk 1 = one_const
   532         | mk i = let val (q, r) = Integer.div_mod i 2 in mk_bit r $ mk q end
   533   in if i > 0 then mk i else raise TERM ("mk_numeral: " ^ string_of_int i, [])
   534   end
   535 
   536 fun dest_num (Const ("Num.num.One", _)) = 1
   537   | dest_num (Const ("Num.num.Bit0", _) $ bs) = 2 * dest_num bs
   538   | dest_num (Const ("Num.num.Bit1", _) $ bs) = 2 * dest_num bs + 1
   539   | dest_num t = raise TERM ("dest_num", [t]);
   540 
   541 fun numeral_const T = Const ("Num.numeral_class.numeral", numT --> T);
   542 
   543 fun add_numerals (Const ("Num.numeral_class.numeral", Type (_, [_, T])) $ t) = cons (t, T)
   544   | add_numerals (t $ u) = add_numerals t #> add_numerals u
   545   | add_numerals (Abs (_, _, t)) = add_numerals t
   546   | add_numerals _ = I;
   547 
   548 fun mk_number T 0 = Const ("Groups.zero_class.zero", T)
   549   | mk_number T 1 = Const ("Groups.one_class.one", T)
   550   | mk_number T i =
   551     if i > 0 then numeral_const T $ mk_numeral i
   552     else Const ("Groups.uminus_class.uminus", T --> T) $ mk_number T (~ i);
   553 
   554 fun dest_number (Const ("Groups.zero_class.zero", T)) = (T, 0)
   555   | dest_number (Const ("Groups.one_class.one", T)) = (T, 1)
   556   | dest_number (Const ("Num.numeral_class.numeral", Type ("fun", [_, T])) $ t) =
   557       (T, dest_num t)
   558   | dest_number (Const ("Groups.uminus_class.uminus", Type ("fun", [_, T])) $ t) =
   559       apsnd (op ~) (dest_number t)
   560   | dest_number t = raise TERM ("dest_number", [t]);
   561 
   562 
   563 (* code target numerals *)
   564 
   565 val code_integerT = Type ("Code_Numeral.integer", []);
   566 
   567 val code_naturalT = Type ("Code_Numeral.natural", []);
   568 
   569 
   570 (* real *)
   571 
   572 val realT = Type ("Real.real", []);
   573 
   574 
   575 (* list *)
   576 
   577 fun listT T = Type ("List.list", [T]);
   578 
   579 fun nil_const T = Const ("List.list.Nil", listT T);
   580 
   581 fun cons_const T =
   582   let val lT = listT T
   583   in Const ("List.list.Cons", T --> lT --> lT) end;
   584 
   585 fun mk_list T ts =
   586   let
   587     val lT = listT T;
   588     val Nil = Const ("List.list.Nil", lT);
   589     fun Cons t u = Const ("List.list.Cons", T --> lT --> lT) $ t $ u;
   590   in fold_rev Cons ts Nil end;
   591 
   592 fun dest_list (Const ("List.list.Nil", _)) = []
   593   | dest_list (Const ("List.list.Cons", _) $ t $ u) = t :: dest_list u
   594   | dest_list t = raise TERM ("dest_list", [t]);
   595 
   596 
   597 (* nibble *)
   598 
   599 val nibbleT = Type ("String.nibble", []);
   600 
   601 fun mk_nibble n =
   602   let val s =
   603     if 0 <= n andalso n <= 9 then chr (n + ord "0")
   604     else if 10 <= n andalso n <= 15 then chr (n + ord "A" - 10)
   605     else raise TERM ("mk_nibble", [])
   606   in Const ("String.nibble.Nibble" ^ s, nibbleT) end;
   607 
   608 fun dest_nibble t =
   609   let fun err () = raise TERM ("dest_nibble", [t]) in
   610     (case try (unprefix "String.nibble.Nibble" o fst o Term.dest_Const) t of
   611       NONE => err ()
   612     | SOME c =>
   613         if size c <> 1 then err ()
   614         else if "0" <= c andalso c <= "9" then ord c - ord "0"
   615         else if "A" <= c andalso c <= "F" then ord c - ord "A" + 10
   616         else err ())
   617   end;
   618 
   619 
   620 (* char *)
   621 
   622 val charT = Type ("String.char", []);
   623 
   624 fun mk_char n =
   625   if 0 <= n andalso n <= 255 then
   626     Const ("String.char.Char", nibbleT --> nibbleT --> charT) $
   627       mk_nibble (n div 16) $ mk_nibble (n mod 16)
   628   else raise TERM ("mk_char", []);
   629 
   630 fun dest_char (Const ("String.char.Char", _) $ t $ u) =
   631       dest_nibble t * 16 + dest_nibble u
   632   | dest_char t = raise TERM ("dest_char", [t]);
   633 
   634 
   635 (* string *)
   636 
   637 val stringT = listT charT;
   638 
   639 val mk_string = mk_list charT o map (mk_char o ord) o raw_explode;
   640 val dest_string = implode o map (chr o dest_char) o dest_list;
   641 
   642 
   643 (* literal *)
   644 
   645 val literalT = Type ("String.literal", []);
   646 
   647 fun mk_literal s = Const ("String.STR", stringT --> literalT)
   648       $ mk_string s;
   649 fun dest_literal (Const ("String.STR", _) $ t) =
   650       dest_string t
   651   | dest_literal t = raise TERM ("dest_literal", [t]);
   652 
   653 
   654 (* typerep and term *)
   655 
   656 val typerepT = Type ("Typerep.typerep", []);
   657 
   658 fun mk_typerep (Type (tyco, Ts)) = Const ("Typerep.typerep.Typerep",
   659       literalT --> listT typerepT --> typerepT) $ mk_literal tyco
   660         $ mk_list typerepT (map mk_typerep Ts)
   661   | mk_typerep (T as TFree _) = Const ("Typerep.typerep_class.typerep",
   662       Term.itselfT T --> typerepT) $ Logic.mk_type T;
   663 
   664 val termT = Type ("Code_Evaluation.term", []);
   665 
   666 fun term_of_const T = Const ("Code_Evaluation.term_of_class.term_of", T --> termT);
   667 
   668 fun mk_term_of T t = term_of_const T $ t;
   669 
   670 fun reflect_term (Const (c, T)) =
   671       Const ("Code_Evaluation.Const", literalT --> typerepT --> termT)
   672         $ mk_literal c $ mk_typerep T
   673   | reflect_term (t1 $ t2) =
   674       Const ("Code_Evaluation.App", termT --> termT --> termT)
   675         $ reflect_term t1 $ reflect_term t2
   676   | reflect_term (Abs (v, _, t)) = Abs (v, termT, reflect_term t)
   677   | reflect_term t = t;
   678 
   679 fun mk_valtermify_app c vs T =
   680   let
   681     fun termifyT T = mk_prodT (T, unitT --> termT);
   682     fun valapp T T' = Const ("Code_Evaluation.valapp",
   683       termifyT (T --> T') --> termifyT T --> termifyT T');
   684     fun mk_fTs [] _ = []
   685       | mk_fTs (_ :: Ts) T = (Ts ---> T) :: mk_fTs Ts T;
   686     val Ts = map snd vs;
   687     val t = Const (c, Ts ---> T);
   688     val tt = mk_prod (t, Abs ("u", unitT, reflect_term t));
   689     fun app (fT, (v, T)) t = valapp T fT $ t $ Free (v, termifyT T);
   690   in fold app (mk_fTs Ts T ~~ vs) tt end;
   691 
   692 
   693 (* open state monads *)
   694 
   695 fun mk_return T U x = pair_const T U $ x;
   696 
   697 fun mk_ST clauses t U (someT, V) =
   698   let
   699     val R = case someT of SOME T => mk_prodT (T, V) | NONE => V
   700     fun mk_clause ((t, U), SOME (v, T)) (t', U') =
   701           (Const ("Product_Type.scomp", (U --> mk_prodT (T, U')) --> (T --> U' --> R) --> U --> R)
   702             $ t $ lambda (Free (v, T)) t', U)
   703       | mk_clause ((t, U), NONE) (t', U') =
   704           (Const ("Product_Type.fcomp", (U --> U') --> (U' --> R) --> U --> R)
   705             $ t $ t', U)
   706   in fold_rev mk_clause clauses (t, U) |> fst end;
   707 
   708 
   709 (* random seeds *)
   710 
   711 val random_seedT = mk_prodT (code_naturalT, code_naturalT);
   712 
   713 fun mk_random T t = Const ("Quickcheck_Random.random_class.random", code_naturalT
   714   --> random_seedT --> mk_prodT (mk_prodT (T, unitT --> termT), random_seedT)) $ t;
   715 
   716 end;