src/HOL/Codatatype/Tools/bnf_wrap.ML
author blanchet
Wed Sep 12 17:26:05 2012 +0200 (2012-09-12)
changeset 49336 a2e6473145e4
parent 49311 56fcd826f90c
child 49364 838b5e8ede73
permissions -rw-r--r--
tuning
     1 (*  Title:      HOL/Codatatype/Tools/bnf_wrap.ML
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2012
     4 
     5 Wrapping existing datatypes.
     6 *)
     7 
     8 signature BNF_WRAP =
     9 sig
    10   val no_binding: binding
    11   val mk_half_pairss: 'a list -> ('a * 'a) list list
    12   val mk_ctr: typ list -> term -> term
    13   val wrap_datatype: ({prems: thm list, context: Proof.context} -> tactic) list list ->
    14     ((bool * term list) * term) *
    15       (binding list * (binding list list * (binding * term) list list)) -> local_theory ->
    16     (term list list * thm list * thm list list) * local_theory
    17   val parse_wrap_options: bool parser
    18   val parse_bound_term: (binding * string) parser
    19 end;
    20 
    21 structure BNF_Wrap : BNF_WRAP =
    22 struct
    23 
    24 open BNF_Util
    25 open BNF_Wrap_Tactics
    26 
    27 val isN = "is_";
    28 val unN = "un_";
    29 fun mk_unN 1 1 suf = unN ^ suf
    30   | mk_unN _ l suf = unN ^ suf ^ string_of_int l;
    31 
    32 val case_congN = "case_cong";
    33 val case_eqN = "case_eq";
    34 val casesN = "cases";
    35 val collapseN = "collapse";
    36 val disc_excludeN = "disc_exclude";
    37 val disc_exhaustN = "disc_exhaust";
    38 val discsN = "discs";
    39 val distinctN = "distinct";
    40 val exhaustN = "exhaust";
    41 val injectN = "inject";
    42 val nchotomyN = "nchotomy";
    43 val selsN = "sels";
    44 val splitN = "split";
    45 val split_asmN = "split_asm";
    46 val weak_case_cong_thmsN = "weak_case_cong";
    47 
    48 val no_binding = @{binding ""};
    49 val std_binding = @{binding _};
    50 
    51 val induct_simp_attrs = @{attributes [induct_simp]};
    52 val cong_attrs = @{attributes [cong]};
    53 val iff_attrs = @{attributes [iff]};
    54 val safe_elim_attrs = @{attributes [elim!]};
    55 val simp_attrs = @{attributes [simp]};
    56 
    57 fun pad_list x n xs = xs @ replicate (n - length xs) x;
    58 
    59 fun unflat_lookup eq ys zs = map (map (fn x => nth zs (find_index (curry eq x) ys)));
    60 
    61 fun mk_half_pairss' _ [] = []
    62   | mk_half_pairss' indent (y :: ys) =
    63     indent @ fold_rev (cons o single o pair y) ys (mk_half_pairss' ([] :: indent) ys);
    64 
    65 fun mk_half_pairss ys = mk_half_pairss' [[]] ys;
    66 
    67 fun mk_undefined T = Const (@{const_name undefined}, T);
    68 
    69 fun mk_ctr Ts ctr =
    70   let val Type (_, Ts0) = body_type (fastype_of ctr) in
    71     Term.subst_atomic_types (Ts0 ~~ Ts) ctr
    72   end;
    73 
    74 fun eta_expand_case_arg xs f_xs = fold_rev Term.lambda xs f_xs;
    75 
    76 fun base_name_of_ctr c =
    77   Long_Name.base_name (case head_of c of
    78       Const (s, _) => s
    79     | Free (s, _) => s
    80     | _ => error "Cannot extract name of constructor");
    81 
    82 fun prepare_wrap_datatype prep_term (((no_dests, raw_ctrs), raw_case),
    83     (raw_disc_bindings, (raw_sel_bindingss, raw_sel_defaultss))) no_defs_lthy =
    84   let
    85     (* TODO: sanity checks on arguments *)
    86     (* TODO: attributes (simp, case_names, etc.) *)
    87     (* TODO: case syntax *)
    88     (* TODO: integration with function package ("size") *)
    89 
    90     val n = length raw_ctrs;
    91     val ks = 1 upto n;
    92 
    93     val _ = if n > 0 then () else error "No constructors specified";
    94 
    95     val ctrs0 = map (prep_term no_defs_lthy) raw_ctrs;
    96     val case0 = prep_term no_defs_lthy raw_case;
    97     val sel_defaultss =
    98       pad_list [] n (map (map (apsnd (prep_term no_defs_lthy))) raw_sel_defaultss);
    99 
   100     val Type (dataT_name, As0) = body_type (fastype_of (hd ctrs0));
   101     val data_b = Binding.qualified_name dataT_name;
   102 
   103     val (As, B) =
   104       no_defs_lthy
   105       |> mk_TFrees' (map Type.sort_of_atyp As0)
   106       ||> the_single o fst o mk_TFrees 1;
   107 
   108     val dataT = Type (dataT_name, As);
   109     val ctrs = map (mk_ctr As) ctrs0;
   110     val ctr_Tss = map (binder_types o fastype_of) ctrs;
   111 
   112     val ms = map length ctr_Tss;
   113 
   114     val raw_disc_bindings' = pad_list no_binding n raw_disc_bindings;
   115 
   116     fun can_really_rely_on_disc k =
   117       not (Binding.eq_name (nth raw_disc_bindings' (k - 1), no_binding)) orelse nth ms (k - 1) = 0;
   118     fun can_rely_on_disc k =
   119       can_really_rely_on_disc k orelse (k = 1 andalso not (can_really_rely_on_disc 2));
   120     fun can_omit_disc_binding k m =
   121       n = 1 orelse m = 0 orelse (n = 2 andalso can_rely_on_disc (3 - k));
   122 
   123     val std_disc_binding =
   124       Binding.qualify false (Binding.name_of data_b) o Binding.name o prefix isN o base_name_of_ctr;
   125 
   126     val disc_bindings =
   127       raw_disc_bindings'
   128       |> map4 (fn k => fn m => fn ctr => fn disc =>
   129         Option.map (Binding.qualify false (Binding.name_of data_b))
   130           (if Binding.eq_name (disc, no_binding) then
   131              if can_omit_disc_binding k m then NONE else SOME (std_disc_binding ctr)
   132            else if Binding.eq_name (disc, std_binding) then
   133              SOME (std_disc_binding ctr)
   134            else
   135              SOME disc)) ks ms ctrs0;
   136 
   137     val no_discs = map is_none disc_bindings;
   138     val no_discs_at_all = forall I no_discs;
   139 
   140     fun std_sel_binding m l = Binding.name o mk_unN m l o base_name_of_ctr;
   141 
   142     val sel_bindingss =
   143       pad_list [] n raw_sel_bindingss
   144       |> map3 (fn ctr => fn m => map2 (fn l => fn sel =>
   145         Binding.qualify false (Binding.name_of data_b)
   146           (if Binding.eq_name (sel, no_binding) orelse Binding.eq_name (sel, std_binding) then
   147             std_sel_binding m l ctr
   148           else
   149             sel)) (1 upto m) o pad_list no_binding m) ctrs0 ms;
   150 
   151     fun mk_case Ts T =
   152       let
   153         val (bindings, body) = strip_type (fastype_of case0)
   154         val Type (_, Ts0) = List.last bindings
   155       in Term.subst_atomic_types ((body, T) :: (Ts0 ~~ Ts)) case0 end;
   156 
   157     val casex = mk_case As B;
   158     val case_Ts = map (fn Ts => Ts ---> B) ctr_Tss;
   159 
   160     val (((((((xss, yss), fs), gs), (v, v')), w), (p, p')), names_lthy) = no_defs_lthy |>
   161       mk_Freess "x" ctr_Tss
   162       ||>> mk_Freess "y" ctr_Tss
   163       ||>> mk_Frees "f" case_Ts
   164       ||>> mk_Frees "g" case_Ts
   165       ||>> yield_singleton (apfst (op ~~) oo mk_Frees' "v") dataT
   166       ||>> yield_singleton (mk_Frees "w") dataT
   167       ||>> yield_singleton (apfst (op ~~) oo mk_Frees' "P") HOLogic.boolT;
   168 
   169     val q = Free (fst p', B --> HOLogic.boolT);
   170 
   171     fun ap_v t = t $ v;
   172     fun mk_v_eq_v () = HOLogic.mk_eq (v, v);
   173 
   174     val xctrs = map2 (curry Term.list_comb) ctrs xss;
   175     val yctrs = map2 (curry Term.list_comb) ctrs yss;
   176 
   177     val xfs = map2 (curry Term.list_comb) fs xss;
   178     val xgs = map2 (curry Term.list_comb) gs xss;
   179 
   180     val eta_fs = map2 eta_expand_case_arg xss xfs;
   181     val eta_gs = map2 eta_expand_case_arg xss xgs;
   182 
   183     val fcase = Term.list_comb (casex, eta_fs);
   184     val gcase = Term.list_comb (casex, eta_gs);
   185 
   186     val exist_xs_v_eq_ctrs =
   187       map2 (fn xctr => fn xs => list_exists_free xs (HOLogic.mk_eq (v, xctr))) xctrs xss;
   188 
   189     val unique_disc_no_def = TrueI; (*arbitrary marker*)
   190     val alternate_disc_no_def = FalseE; (*arbitrary marker*)
   191 
   192     fun alternate_disc_lhs get_disc k =
   193       HOLogic.mk_not
   194         (case nth disc_bindings (k - 1) of
   195           NONE => nth exist_xs_v_eq_ctrs (k - 1)
   196         | SOME b => get_disc b (k - 1) $ v);
   197 
   198     val (all_sels_distinct, discs, selss, disc_defs, sel_defs, sel_defss, lthy') =
   199       if no_dests then
   200         (true, [], [], [], [], [], no_defs_lthy)
   201       else
   202         let
   203           fun disc_free b = Free (Binding.name_of b, dataT --> HOLogic.boolT);
   204 
   205           fun disc_spec b exist_xs_v_eq_ctr = mk_Trueprop_eq (disc_free b $ v, exist_xs_v_eq_ctr);
   206 
   207           fun alternate_disc k = Term.lambda v (alternate_disc_lhs (K o disc_free) (3 - k));
   208 
   209           fun mk_sel_case_args b proto_sels T =
   210             map2 (fn Ts => fn k =>
   211               (case AList.lookup (op =) proto_sels k of
   212                 NONE =>
   213                 let val def_T = Ts ---> T in
   214                   (case AList.lookup Binding.eq_name (rev (nth sel_defaultss (k - 1))) b of
   215                     NONE => mk_undefined def_T
   216                   | SOME t => fold_rev (fn T => Term.lambda (Free (Name.uu, T))) Ts
   217                       (Term.subst_atomic_types [(fastype_of t, T)] t))
   218                 end
   219               | SOME (xs, x) => fold_rev Term.lambda xs x)) ctr_Tss ks;
   220 
   221           fun sel_spec b proto_sels =
   222             let
   223               val _ =
   224                 (case duplicates (op =) (map fst proto_sels) of
   225                    k :: _ => error ("Duplicate selector name " ^ quote (Binding.name_of b) ^
   226                      " for constructor " ^
   227                      quote (Syntax.string_of_term no_defs_lthy (nth ctrs (k - 1))))
   228                  | [] => ())
   229               val T =
   230                 (case distinct (op =) (map (fastype_of o snd o snd) proto_sels) of
   231                   [T] => T
   232                 | T :: T' :: _ => error ("Inconsistent range type for selector " ^
   233                     quote (Binding.name_of b) ^ ": " ^ quote (Syntax.string_of_typ no_defs_lthy T) ^
   234                     " vs. " ^ quote (Syntax.string_of_typ no_defs_lthy T')));
   235             in
   236               mk_Trueprop_eq (Free (Binding.name_of b, dataT --> T) $ v,
   237                 Term.list_comb (mk_case As T, mk_sel_case_args b proto_sels T) $ v)
   238             end;
   239 
   240           val sel_bindings = flat sel_bindingss;
   241           val uniq_sel_bindings = distinct Binding.eq_name sel_bindings;
   242           val all_sels_distinct = (length uniq_sel_bindings = length sel_bindings);
   243 
   244           val sel_binding_index =
   245             if all_sels_distinct then 1 upto length sel_bindings
   246             else map (fn b => find_index (curry Binding.eq_name b) uniq_sel_bindings) sel_bindings;
   247 
   248           val proto_sels = flat (map3 (fn k => fn xs => map (fn x => (k, (xs, x)))) ks xss xss);
   249           val sel_infos =
   250             AList.group (op =) (sel_binding_index ~~ proto_sels)
   251             |> sort (int_ord o pairself fst)
   252             |> map snd |> curry (op ~~) uniq_sel_bindings;
   253           val sel_bindings = map fst sel_infos;
   254 
   255           fun unflat_selss xs = unflat_lookup Binding.eq_name sel_bindings xs sel_bindingss;
   256 
   257           val (((raw_discs, raw_disc_defs), (raw_sels, raw_sel_defs)), (lthy', lthy)) =
   258             no_defs_lthy
   259             |> apfst split_list o fold_map4 (fn k => fn m => fn exist_xs_v_eq_ctr =>
   260               fn NONE =>
   261                  if n = 1 then pair (Term.lambda v (mk_v_eq_v ()), unique_disc_no_def)
   262                  else if m = 0 then pair (Term.lambda v exist_xs_v_eq_ctr, refl)
   263                  else pair (alternate_disc k, alternate_disc_no_def)
   264                | SOME b => Specification.definition (SOME (b, NONE, NoSyn),
   265                    ((Thm.def_binding b, []), disc_spec b exist_xs_v_eq_ctr)) #>> apsnd snd)
   266               ks ms exist_xs_v_eq_ctrs disc_bindings
   267             ||>> apfst split_list o fold_map (fn (b, proto_sels) =>
   268               Specification.definition (SOME (b, NONE, NoSyn),
   269                 ((Thm.def_binding b, []), sel_spec b proto_sels)) #>> apsnd snd) sel_infos
   270             ||> `Local_Theory.restore;
   271 
   272           val phi = Proof_Context.export_morphism lthy lthy';
   273 
   274           val disc_defs = map (Morphism.thm phi) raw_disc_defs;
   275           val sel_defs = map (Morphism.thm phi) raw_sel_defs;
   276           val sel_defss = unflat_selss sel_defs;
   277 
   278           val discs0 = map (Morphism.term phi) raw_discs;
   279           val selss0 = unflat_selss (map (Morphism.term phi) raw_sels);
   280 
   281           fun mk_disc_or_sel Ts c =
   282             Term.subst_atomic_types (snd (Term.dest_Type (domain_type (fastype_of c))) ~~ Ts) c;
   283 
   284           val discs = map (mk_disc_or_sel As) discs0;
   285           val selss = map (map (mk_disc_or_sel As)) selss0;
   286         in
   287           (all_sels_distinct, discs, selss, disc_defs, sel_defs, sel_defss, lthy')
   288         end;
   289 
   290     fun mk_imp_p Qs = Logic.list_implies (Qs, HOLogic.mk_Trueprop p);
   291 
   292     val goal_exhaust =
   293       let fun mk_prem xctr xs = fold_rev Logic.all xs (mk_imp_p [mk_Trueprop_eq (v, xctr)]) in
   294         fold_rev Logic.all [p, v] (mk_imp_p (map2 mk_prem xctrs xss))
   295       end;
   296 
   297     val goal_injectss =
   298       let
   299         fun mk_goal _ _ [] [] = []
   300           | mk_goal xctr yctr xs ys =
   301             [fold_rev Logic.all (xs @ ys) (mk_Trueprop_eq (HOLogic.mk_eq (xctr, yctr),
   302               Library.foldr1 HOLogic.mk_conj (map2 (curry HOLogic.mk_eq) xs ys)))];
   303       in
   304         map4 mk_goal xctrs yctrs xss yss
   305       end;
   306 
   307     val goal_half_distinctss =
   308       let
   309         fun mk_goal ((xs, xc), (xs', xc')) =
   310           fold_rev Logic.all (xs @ xs')
   311             (HOLogic.mk_Trueprop (HOLogic.mk_not (HOLogic.mk_eq (xc, xc'))));
   312       in
   313         map (map mk_goal) (mk_half_pairss (xss ~~ xctrs))
   314       end;
   315 
   316     val goal_cases =
   317       map3 (fn xs => fn xctr => fn xf =>
   318         fold_rev Logic.all (fs @ xs) (mk_Trueprop_eq (fcase $ xctr, xf))) xss xctrs xfs;
   319 
   320     val goalss = [goal_exhaust] :: goal_injectss @ goal_half_distinctss @ [goal_cases];
   321 
   322     fun after_qed thmss lthy =
   323       let
   324         val ([exhaust_thm], (inject_thmss, (half_distinct_thmss, [case_thms]))) =
   325           (hd thmss, apsnd (chop (n * n)) (chop n (tl thmss)));
   326 
   327         val exhaust_thm' =
   328           let val Tinst = map (pairself (certifyT lthy)) (map Logic.varifyT_global As ~~ As) in
   329             Drule.instantiate' [] [SOME (certify lthy v)]
   330               (Thm.instantiate (Tinst, []) (Drule.zero_var_indexes exhaust_thm))
   331           end;
   332 
   333         val exhaust_cases = map base_name_of_ctr ctrs;
   334 
   335         val other_half_distinct_thmss = map (map (fn thm => thm RS not_sym)) half_distinct_thmss;
   336 
   337         val (distinct_thmsss', distinct_thmsss) =
   338           map2 (map2 append) (Library.chop_groups n half_distinct_thmss)
   339             (transpose (Library.chop_groups n other_half_distinct_thmss))
   340           |> `transpose;
   341         val distinct_thms = interleave (flat half_distinct_thmss) (flat other_half_distinct_thmss);
   342 
   343         val nchotomy_thm =
   344           let
   345             val goal =
   346               HOLogic.mk_Trueprop (HOLogic.mk_all (fst v', snd v',
   347                 Library.foldr1 HOLogic.mk_disj exist_xs_v_eq_ctrs));
   348           in
   349             Skip_Proof.prove lthy [] [] goal (fn _ => mk_nchotomy_tac n exhaust_thm)
   350           end;
   351 
   352         val (all_sel_thms, sel_thmss, disc_thms, discI_thms, disc_exclude_thms, disc_exhaust_thms,
   353              collapse_thms, case_eq_thms) =
   354           if no_dests then
   355             ([], [], [], [], [], [], [], [])
   356           else
   357             let
   358               fun make_sel_thm case_thm sel_def = case_thm RS (sel_def RS trans);
   359 
   360               fun has_undefined_rhs thm =
   361                 (case snd (HOLogic.dest_eq (HOLogic.dest_Trueprop (prop_of thm))) of
   362                   Const (@{const_name undefined}, _) => true
   363                 | _ => false);
   364 
   365               val sel_thmss = map2 (map o make_sel_thm) case_thms sel_defss;
   366 
   367               val all_sel_thms =
   368                 (if all_sels_distinct andalso forall null sel_defaultss then
   369                    flat sel_thmss
   370                  else
   371                    map_product (fn s => fn c => make_sel_thm c s) sel_defs case_thms)
   372                 |> filter_out has_undefined_rhs;
   373 
   374               fun mk_unique_disc_def () =
   375                 let
   376                   val m = the_single ms;
   377                   val goal = mk_Trueprop_eq (mk_v_eq_v (), the_single exist_xs_v_eq_ctrs);
   378                 in
   379                   Skip_Proof.prove lthy [] [] goal (fn _ => mk_unique_disc_def_tac m exhaust_thm')
   380                   |> singleton (Proof_Context.export names_lthy lthy)
   381                   |> Thm.close_derivation
   382                 end;
   383 
   384               fun mk_alternate_disc_def k =
   385                 let
   386                   val goal =
   387                     mk_Trueprop_eq (alternate_disc_lhs (K (nth discs)) (3 - k),
   388                       nth exist_xs_v_eq_ctrs (k - 1));
   389                 in
   390                   Skip_Proof.prove lthy [] [] goal (fn {context = ctxt, ...} =>
   391                     mk_alternate_disc_def_tac ctxt k (nth disc_defs (2 - k))
   392                       (nth distinct_thms (2 - k)) exhaust_thm')
   393                   |> singleton (Proof_Context.export names_lthy lthy)
   394                   |> Thm.close_derivation
   395                 end;
   396 
   397               val has_alternate_disc_def =
   398                 exists (fn def => Thm.eq_thm_prop (def, alternate_disc_no_def)) disc_defs;
   399 
   400               val disc_defs' =
   401                 map2 (fn k => fn def =>
   402                   if Thm.eq_thm_prop (def, unique_disc_no_def) then mk_unique_disc_def ()
   403                   else if Thm.eq_thm_prop (def, alternate_disc_no_def) then mk_alternate_disc_def k
   404                   else def) ks disc_defs;
   405 
   406               val discD_thms = map (fn def => def RS iffD1) disc_defs';
   407               val discI_thms =
   408                 map2 (fn m => fn def => funpow m (fn thm => exI RS thm) (def RS iffD2)) ms
   409                   disc_defs';
   410               val not_discI_thms =
   411                 map2 (fn m => fn def => funpow m (fn thm => allI RS thm)
   412                     (Local_Defs.unfold lthy @{thms not_ex} (def RS @{thm ssubst[of _ _ Not]})))
   413                   ms disc_defs';
   414 
   415               val (disc_thmss', disc_thmss) =
   416                 let
   417                   fun mk_thm discI _ [] = refl RS discI
   418                     | mk_thm _ not_discI [distinct] = distinct RS not_discI;
   419                   fun mk_thms discI not_discI distinctss = map (mk_thm discI not_discI) distinctss;
   420                 in
   421                   map3 mk_thms discI_thms not_discI_thms distinct_thmsss' |> `transpose
   422                 end;
   423 
   424               val disc_thms = flat (map2 (fn true => K [] | false => I) no_discs disc_thmss);
   425 
   426               val disc_exclude_thms =
   427                 if has_alternate_disc_def then
   428                   []
   429                 else
   430                   let
   431                     fun mk_goal [] = []
   432                       | mk_goal [((_, true), (_, true))] = []
   433                       | mk_goal [(((_, disc), _), ((_, disc'), _))] =
   434                         [Logic.all v (Logic.mk_implies (HOLogic.mk_Trueprop (betapply (disc, v)),
   435                            HOLogic.mk_Trueprop (HOLogic.mk_not (betapply (disc', v)))))];
   436                     fun prove tac goal = Skip_Proof.prove lthy [] [] goal (K tac);
   437 
   438                     val infos = ms ~~ discD_thms ~~ discs ~~ no_discs;
   439                     val half_pairss = mk_half_pairss infos;
   440 
   441                     val goal_halvess = map mk_goal half_pairss;
   442                     val half_thmss =
   443                       map3 (fn [] => K (K []) | [goal] => fn [((((m, discD), _), _), _)] =>
   444                           fn disc_thm => [prove (mk_half_disc_exclude_tac m discD disc_thm) goal])
   445                         goal_halvess half_pairss (flat disc_thmss');
   446 
   447                     val goal_other_halvess = map (mk_goal o map swap) half_pairss;
   448                     val other_half_thmss =
   449                       map2 (map2 (prove o mk_other_half_disc_exclude_tac)) half_thmss
   450                         goal_other_halvess;
   451                   in
   452                     interleave (flat half_thmss) (flat other_half_thmss)
   453                   end;
   454 
   455               val disc_exhaust_thms =
   456                 if has_alternate_disc_def orelse no_discs_at_all then
   457                   []
   458                 else
   459                   let
   460                     fun mk_prem disc = mk_imp_p [HOLogic.mk_Trueprop (betapply (disc, v))];
   461                     val goal = fold_rev Logic.all [p, v] (mk_imp_p (map mk_prem discs));
   462                   in
   463                     [Skip_Proof.prove lthy [] [] goal (fn _ =>
   464                        mk_disc_exhaust_tac n exhaust_thm discI_thms)]
   465                   end;
   466 
   467               val collapse_thms =
   468                 if no_dests then
   469                   []
   470                 else
   471                   let
   472                     fun mk_goal ctr disc sels =
   473                       let
   474                         val prem = HOLogic.mk_Trueprop (betapply (disc, v));
   475                         val concl =
   476                           mk_Trueprop_eq ((null sels ? swap)
   477                             (Term.list_comb (ctr, map ap_v sels), v));
   478                       in
   479                         if prem aconv concl then NONE
   480                         else SOME (Logic.all v (Logic.mk_implies (prem, concl)))
   481                       end;
   482                     val goals = map3 mk_goal ctrs discs selss;
   483                   in
   484                     map4 (fn m => fn discD => fn sel_thms => Option.map (fn goal =>
   485                       Skip_Proof.prove lthy [] [] goal (fn {context = ctxt, ...} =>
   486                         mk_collapse_tac ctxt m discD sel_thms)
   487                       |> perhaps (try (fn thm => refl RS thm)))) ms discD_thms sel_thmss goals
   488                     |> map_filter I
   489                   end;
   490 
   491               val case_eq_thms =
   492                 if no_dests then
   493                   []
   494                 else
   495                   let
   496                     fun mk_body f sels = Term.list_comb (f, map ap_v sels);
   497                     val goal =
   498                       mk_Trueprop_eq (fcase $ v, mk_IfN B (map ap_v discs) (map2 mk_body fs selss));
   499                   in
   500                     [Skip_Proof.prove lthy [] [] goal (fn {context = ctxt, ...} =>
   501                       mk_case_eq_tac ctxt n exhaust_thm' case_thms disc_thmss' sel_thmss)]
   502                     |> Proof_Context.export names_lthy lthy
   503                   end;
   504             in
   505               (all_sel_thms, sel_thmss, disc_thms, discI_thms, disc_exclude_thms, disc_exhaust_thms,
   506                collapse_thms, case_eq_thms)
   507             end;
   508 
   509         val (case_cong_thm, weak_case_cong_thm) =
   510           let
   511             fun mk_prem xctr xs f g =
   512               fold_rev Logic.all xs (Logic.mk_implies (mk_Trueprop_eq (w, xctr),
   513                 mk_Trueprop_eq (f, g)));
   514 
   515             val v_eq_w = mk_Trueprop_eq (v, w);
   516 
   517             val goal =
   518               Logic.list_implies (v_eq_w :: map4 mk_prem xctrs xss fs gs,
   519                  mk_Trueprop_eq (fcase $ v, gcase $ w));
   520             val goal_weak = Logic.mk_implies (v_eq_w, mk_Trueprop_eq (fcase $ v, fcase $ w));
   521           in
   522             (Skip_Proof.prove lthy [] [] goal (fn _ => mk_case_cong_tac exhaust_thm' case_thms),
   523              Skip_Proof.prove lthy [] [] goal_weak (K (etac arg_cong 1)))
   524             |> pairself (singleton (Proof_Context.export names_lthy lthy))
   525           end;
   526 
   527         val (split_thm, split_asm_thm) =
   528           let
   529             fun mk_conjunct xctr xs f_xs =
   530               list_all_free xs (HOLogic.mk_imp (HOLogic.mk_eq (v, xctr), q $ f_xs));
   531             fun mk_disjunct xctr xs f_xs =
   532               list_exists_free xs (HOLogic.mk_conj (HOLogic.mk_eq (v, xctr),
   533                 HOLogic.mk_not (q $ f_xs)));
   534 
   535             val lhs = q $ (fcase $ v);
   536 
   537             val goal =
   538               mk_Trueprop_eq (lhs, Library.foldr1 HOLogic.mk_conj (map3 mk_conjunct xctrs xss xfs));
   539             val goal_asm =
   540               mk_Trueprop_eq (lhs, HOLogic.mk_not (Library.foldr1 HOLogic.mk_disj
   541                 (map3 mk_disjunct xctrs xss xfs)));
   542 
   543             val split_thm =
   544               Skip_Proof.prove lthy [] [] goal
   545                 (fn _ => mk_split_tac exhaust_thm' case_thms inject_thmss distinct_thmsss)
   546               |> singleton (Proof_Context.export names_lthy lthy)
   547             val split_asm_thm =
   548               Skip_Proof.prove lthy [] [] goal_asm (fn {context = ctxt, ...} =>
   549                 mk_split_asm_tac ctxt split_thm)
   550               |> singleton (Proof_Context.export names_lthy lthy)
   551           in
   552             (split_thm, split_asm_thm)
   553           end;
   554 
   555         val cases_type_attr = Attrib.internal (K (Induct.cases_type dataT_name));
   556         val exhaust_case_names_attr = Attrib.internal (K (Rule_Cases.case_names exhaust_cases));
   557 
   558         val notes =
   559           [(case_congN, [case_cong_thm], []),
   560            (case_eqN, case_eq_thms, []),
   561            (casesN, case_thms, simp_attrs),
   562            (collapseN, collapse_thms, simp_attrs),
   563            (discsN, disc_thms, simp_attrs),
   564            (disc_excludeN, disc_exclude_thms, []),
   565            (disc_exhaustN, disc_exhaust_thms, [exhaust_case_names_attr]),
   566            (distinctN, distinct_thms, simp_attrs @ induct_simp_attrs),
   567            (exhaustN, [exhaust_thm], [exhaust_case_names_attr, cases_type_attr]),
   568            (injectN, flat inject_thmss, iff_attrs @ induct_simp_attrs),
   569            (nchotomyN, [nchotomy_thm], []),
   570            (selsN, all_sel_thms, simp_attrs),
   571            (splitN, [split_thm], []),
   572            (split_asmN, [split_asm_thm], []),
   573            (weak_case_cong_thmsN, [weak_case_cong_thm], cong_attrs)]
   574           |> filter_out (null o #2)
   575           |> map (fn (thmN, thms, attrs) =>
   576             ((Binding.qualify true (Binding.name_of data_b) (Binding.name thmN), attrs),
   577              [(thms, [])]));
   578 
   579         val notes' =
   580           [(map (fn th => th RS notE) distinct_thms, safe_elim_attrs)]
   581           |> map (fn (thms, attrs) => ((Binding.empty, attrs), [(thms, [])]));
   582       in
   583         ((selss, discI_thms, sel_thmss), lthy |> Local_Theory.notes (notes' @ notes) |> snd)
   584       end;
   585   in
   586     (goalss, after_qed, lthy')
   587   end;
   588 
   589 fun wrap_datatype tacss = (fn (goalss, after_qed, lthy) =>
   590   map2 (map2 (Skip_Proof.prove lthy [] [])) goalss tacss
   591   |> (fn thms => after_qed thms lthy)) oo prepare_wrap_datatype (K I);
   592 
   593 val wrap_datatype_cmd = (fn (goalss, after_qed, lthy) =>
   594   Proof.theorem NONE (snd oo after_qed) (map (map (rpair [])) goalss) lthy) oo
   595   prepare_wrap_datatype Syntax.read_term;
   596 
   597 fun parse_bracket_list parser = @{keyword "["} |-- Parse.list parser --|  @{keyword "]"};
   598 
   599 val parse_bindings = parse_bracket_list Parse.binding;
   600 val parse_bindingss = parse_bracket_list parse_bindings;
   601 
   602 val parse_bound_term = (Parse.binding --| @{keyword ":"}) -- Parse.term;
   603 val parse_bound_terms = parse_bracket_list parse_bound_term;
   604 val parse_bound_termss = parse_bracket_list parse_bound_terms;
   605 
   606 val parse_wrap_options =
   607   Scan.optional (@{keyword "("} |-- (@{keyword "no_dests"} >> K true) --| @{keyword ")"}) false;
   608 
   609 val _ =
   610   Outer_Syntax.local_theory_to_proof @{command_spec "wrap_data"} "wraps an existing datatype"
   611     ((parse_wrap_options -- (@{keyword "["} |-- Parse.list Parse.term --| @{keyword "]"}) --
   612       Parse.term -- Scan.optional (parse_bindings -- Scan.optional (parse_bindingss --
   613         Scan.optional parse_bound_termss []) ([], [])) ([], ([], [])))
   614      >> wrap_datatype_cmd);
   615 
   616 end;