src/Pure/thm.ML
author wenzelm
Thu Mar 05 19:48:02 2009 +0100 (2009-03-05)
changeset 30288 a32700e45ab3
parent 29636 d01bada1df33
child 30342 d32daa6aba3c
permissions -rw-r--r--
Thm.add_oracle interface: replaced old bstring by binding;
     1 (*  Title:      Pure/thm.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Makarius
     4 
     5 The very core of Isabelle's Meta Logic: certified types and terms,
     6 derivations, theorems, framework rules (including lifting and
     7 resolution), oracles.
     8 *)
     9 
    10 signature BASIC_THM =
    11   sig
    12   (*certified types*)
    13   type ctyp
    14   val rep_ctyp: ctyp ->
    15    {thy_ref: theory_ref,
    16     T: typ,
    17     maxidx: int,
    18     sorts: sort OrdList.T}
    19   val theory_of_ctyp: ctyp -> theory
    20   val typ_of: ctyp -> typ
    21   val ctyp_of: theory -> typ -> ctyp
    22 
    23   (*certified terms*)
    24   type cterm
    25   exception CTERM of string * cterm list
    26   val rep_cterm: cterm ->
    27    {thy_ref: theory_ref,
    28     t: term,
    29     T: typ,
    30     maxidx: int,
    31     sorts: sort OrdList.T}
    32   val crep_cterm: cterm ->
    33     {thy_ref: theory_ref, t: term, T: ctyp, maxidx: int, sorts: sort OrdList.T}
    34   val theory_of_cterm: cterm -> theory
    35   val term_of: cterm -> term
    36   val cterm_of: theory -> term -> cterm
    37   val ctyp_of_term: cterm -> ctyp
    38 
    39   (*theorems*)
    40   type thm
    41   type conv = cterm -> thm
    42   type attribute = Context.generic * thm -> Context.generic * thm
    43   val rep_thm: thm ->
    44    {thy_ref: theory_ref,
    45     tags: Properties.T,
    46     maxidx: int,
    47     shyps: sort OrdList.T,
    48     hyps: term OrdList.T,
    49     tpairs: (term * term) list,
    50     prop: term}
    51   val crep_thm: thm ->
    52    {thy_ref: theory_ref,
    53     tags: Properties.T,
    54     maxidx: int,
    55     shyps: sort OrdList.T,
    56     hyps: cterm OrdList.T,
    57     tpairs: (cterm * cterm) list,
    58     prop: cterm}
    59   exception THM of string * int * thm list
    60   val theory_of_thm: thm -> theory
    61   val prop_of: thm -> term
    62   val tpairs_of: thm -> (term * term) list
    63   val concl_of: thm -> term
    64   val prems_of: thm -> term list
    65   val nprems_of: thm -> int
    66   val cprop_of: thm -> cterm
    67   val cprem_of: thm -> int -> cterm
    68   val transfer: theory -> thm -> thm
    69   val weaken: cterm -> thm -> thm
    70   val weaken_sorts: sort list -> cterm -> cterm
    71   val extra_shyps: thm -> sort list
    72   val strip_shyps: thm -> thm
    73 
    74   (*meta rules*)
    75   val assume: cterm -> thm
    76   val implies_intr: cterm -> thm -> thm
    77   val implies_elim: thm -> thm -> thm
    78   val forall_intr: cterm -> thm -> thm
    79   val forall_elim: cterm -> thm -> thm
    80   val reflexive: cterm -> thm
    81   val symmetric: thm -> thm
    82   val transitive: thm -> thm -> thm
    83   val beta_conversion: bool -> conv
    84   val eta_conversion: conv
    85   val eta_long_conversion: conv
    86   val abstract_rule: string -> cterm -> thm -> thm
    87   val combination: thm -> thm -> thm
    88   val equal_intr: thm -> thm -> thm
    89   val equal_elim: thm -> thm -> thm
    90   val flexflex_rule: thm -> thm Seq.seq
    91   val generalize: string list * string list -> int -> thm -> thm
    92   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    93   val instantiate_cterm: (ctyp * ctyp) list * (cterm * cterm) list -> cterm -> cterm
    94   val trivial: cterm -> thm
    95   val class_triv: theory -> class -> thm
    96   val unconstrainT: ctyp -> thm -> thm
    97   val dest_state: thm * int -> (term * term) list * term list * term * term
    98   val lift_rule: cterm -> thm -> thm
    99   val incr_indexes: int -> thm -> thm
   100   val assumption: int -> thm -> thm Seq.seq
   101   val eq_assumption: int -> thm -> thm
   102   val rotate_rule: int -> int -> thm -> thm
   103   val permute_prems: int -> int -> thm -> thm
   104   val rename_params_rule: string list * int -> thm -> thm
   105   val compose_no_flatten: bool -> thm * int -> int -> thm -> thm Seq.seq
   106   val bicompose: bool -> bool * thm * int -> int -> thm -> thm Seq.seq
   107   val biresolution: bool -> (bool * thm) list -> int -> thm -> thm Seq.seq
   108 end;
   109 
   110 signature THM =
   111 sig
   112   include BASIC_THM
   113   val dest_ctyp: ctyp -> ctyp list
   114   val dest_comb: cterm -> cterm * cterm
   115   val dest_fun: cterm -> cterm
   116   val dest_arg: cterm -> cterm
   117   val dest_fun2: cterm -> cterm
   118   val dest_arg1: cterm -> cterm
   119   val dest_abs: string option -> cterm -> cterm * cterm
   120   val adjust_maxidx_cterm: int -> cterm -> cterm
   121   val capply: cterm -> cterm -> cterm
   122   val cabs: cterm -> cterm -> cterm
   123   val major_prem_of: thm -> term
   124   val no_prems: thm -> bool
   125   val terms_of_tpairs: (term * term) list -> term list
   126   val maxidx_of: thm -> int
   127   val maxidx_thm: thm -> int -> int
   128   val hyps_of: thm -> term list
   129   val full_prop_of: thm -> term
   130   val axiom: theory -> string -> thm
   131   val def_name: string -> string
   132   val def_name_optional: string -> string -> string
   133   val get_def: theory -> xstring -> thm
   134   val axioms_of: theory -> (string * thm) list
   135   val get_name: thm -> string
   136   val put_name: string -> thm -> thm
   137   val get_tags: thm -> Properties.T
   138   val map_tags: (Properties.T -> Properties.T) -> thm -> thm
   139   val norm_proof: thm -> thm
   140   val adjust_maxidx_thm: int -> thm -> thm
   141   val rename_boundvars: term -> term -> thm -> thm
   142   val match: cterm * cterm -> (ctyp * ctyp) list * (cterm * cterm) list
   143   val first_order_match: cterm * cterm -> (ctyp * ctyp) list * (cterm * cterm) list
   144   val incr_indexes_cterm: int -> cterm -> cterm
   145   val varifyT: thm -> thm
   146   val varifyT': (string * sort) list -> thm -> ((string * sort) * indexname) list * thm
   147   val freezeT: thm -> thm
   148   val future: thm future -> cterm -> thm
   149   val pending_groups: thm -> Task_Queue.group list -> Task_Queue.group list
   150   val proof_body_of: thm -> proof_body
   151   val proof_of: thm -> proof
   152   val join_proof: thm -> unit
   153   val extern_oracles: theory -> xstring list
   154   val add_oracle: binding * ('a -> cterm) -> theory -> (string * ('a -> thm)) * theory
   155 end;
   156 
   157 structure Thm:> THM =
   158 struct
   159 
   160 structure Pt = Proofterm;
   161 
   162 
   163 (*** Certified terms and types ***)
   164 
   165 (** certified types **)
   166 
   167 datatype ctyp = Ctyp of
   168  {thy_ref: theory_ref,
   169   T: typ,
   170   maxidx: int,
   171   sorts: sort OrdList.T};
   172 
   173 fun rep_ctyp (Ctyp args) = args;
   174 fun theory_of_ctyp (Ctyp {thy_ref, ...}) = Theory.deref thy_ref;
   175 fun typ_of (Ctyp {T, ...}) = T;
   176 
   177 fun ctyp_of thy raw_T =
   178   let
   179     val T = Sign.certify_typ thy raw_T;
   180     val maxidx = Term.maxidx_of_typ T;
   181     val sorts = Sorts.insert_typ T [];
   182   in Ctyp {thy_ref = Theory.check_thy thy, T = T, maxidx = maxidx, sorts = sorts} end;
   183 
   184 fun dest_ctyp (Ctyp {thy_ref, T = Type (s, Ts), maxidx, sorts}) =
   185       map (fn T => Ctyp {thy_ref = thy_ref, T = T, maxidx = maxidx, sorts = sorts}) Ts
   186   | dest_ctyp cT = raise TYPE ("dest_ctyp", [typ_of cT], []);
   187 
   188 
   189 
   190 (** certified terms **)
   191 
   192 (*certified terms with checked typ, maxidx, and sorts*)
   193 datatype cterm = Cterm of
   194  {thy_ref: theory_ref,
   195   t: term,
   196   T: typ,
   197   maxidx: int,
   198   sorts: sort OrdList.T};
   199 
   200 exception CTERM of string * cterm list;
   201 
   202 fun rep_cterm (Cterm args) = args;
   203 
   204 fun crep_cterm (Cterm {thy_ref, t, T, maxidx, sorts}) =
   205   {thy_ref = thy_ref, t = t, maxidx = maxidx, sorts = sorts,
   206     T = Ctyp {thy_ref = thy_ref, T = T, maxidx = maxidx, sorts = sorts}};
   207 
   208 fun theory_of_cterm (Cterm {thy_ref, ...}) = Theory.deref thy_ref;
   209 fun term_of (Cterm {t, ...}) = t;
   210 
   211 fun ctyp_of_term (Cterm {thy_ref, T, maxidx, sorts, ...}) =
   212   Ctyp {thy_ref = thy_ref, T = T, maxidx = maxidx, sorts = sorts};
   213 
   214 fun cterm_of thy tm =
   215   let
   216     val (t, T, maxidx) = Sign.certify_term thy tm;
   217     val sorts = Sorts.insert_term t [];
   218   in Cterm {thy_ref = Theory.check_thy thy, t = t, T = T, maxidx = maxidx, sorts = sorts} end;
   219 
   220 fun merge_thys0 (Cterm {thy_ref = r1, t = t1, ...}) (Cterm {thy_ref = r2, t = t2, ...}) =
   221   Theory.merge_refs (r1, r2);
   222 
   223 
   224 (* destructors *)
   225 
   226 fun dest_comb (ct as Cterm {t = c $ a, T, thy_ref, maxidx, sorts}) =
   227       let val A = Term.argument_type_of c 0 in
   228         (Cterm {t = c, T = A --> T, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts},
   229          Cterm {t = a, T = A, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts})
   230       end
   231   | dest_comb ct = raise CTERM ("dest_comb", [ct]);
   232 
   233 fun dest_fun (ct as Cterm {t = c $ _, T, thy_ref, maxidx, sorts}) =
   234       let val A = Term.argument_type_of c 0
   235       in Cterm {t = c, T = A --> T, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts} end
   236   | dest_fun ct = raise CTERM ("dest_fun", [ct]);
   237 
   238 fun dest_arg (ct as Cterm {t = c $ a, T = _, thy_ref, maxidx, sorts}) =
   239       let val A = Term.argument_type_of c 0
   240       in Cterm {t = a, T = A, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts} end
   241   | dest_arg ct = raise CTERM ("dest_arg", [ct]);
   242 
   243 
   244 fun dest_fun2 (Cterm {t = c $ a $ b, T, thy_ref, maxidx, sorts}) =
   245       let
   246         val A = Term.argument_type_of c 0;
   247         val B = Term.argument_type_of c 1;
   248       in Cterm {t = c, T = A --> B --> T, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts} end
   249   | dest_fun2 ct = raise CTERM ("dest_fun2", [ct]);
   250 
   251 fun dest_arg1 (Cterm {t = c $ a $ _, T = _, thy_ref, maxidx, sorts}) =
   252       let val A = Term.argument_type_of c 0
   253       in Cterm {t = a, T = A, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts} end
   254   | dest_arg1 ct = raise CTERM ("dest_arg1", [ct]);
   255 
   256 fun dest_abs a (ct as
   257         Cterm {t = Abs (x, T, t), T = Type ("fun", [_, U]), thy_ref, maxidx, sorts}) =
   258       let val (y', t') = Term.dest_abs (the_default x a, T, t) in
   259         (Cterm {t = Free (y', T), T = T, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts},
   260           Cterm {t = t', T = U, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts})
   261       end
   262   | dest_abs _ ct = raise CTERM ("dest_abs", [ct]);
   263 
   264 
   265 (* constructors *)
   266 
   267 fun capply
   268   (cf as Cterm {t = f, T = Type ("fun", [dty, rty]), maxidx = maxidx1, sorts = sorts1, ...})
   269   (cx as Cterm {t = x, T, maxidx = maxidx2, sorts = sorts2, ...}) =
   270     if T = dty then
   271       Cterm {thy_ref = merge_thys0 cf cx,
   272         t = f $ x,
   273         T = rty,
   274         maxidx = Int.max (maxidx1, maxidx2),
   275         sorts = Sorts.union sorts1 sorts2}
   276       else raise CTERM ("capply: types don't agree", [cf, cx])
   277   | capply cf cx = raise CTERM ("capply: first arg is not a function", [cf, cx]);
   278 
   279 fun cabs
   280   (ct1 as Cterm {t = t1, T = T1, maxidx = maxidx1, sorts = sorts1, ...})
   281   (ct2 as Cterm {t = t2, T = T2, maxidx = maxidx2, sorts = sorts2, ...}) =
   282     let val t = Term.lambda t1 t2 in
   283       Cterm {thy_ref = merge_thys0 ct1 ct2,
   284         t = t, T = T1 --> T2,
   285         maxidx = Int.max (maxidx1, maxidx2),
   286         sorts = Sorts.union sorts1 sorts2}
   287     end;
   288 
   289 
   290 (* indexes *)
   291 
   292 fun adjust_maxidx_cterm i (ct as Cterm {thy_ref, t, T, maxidx, sorts}) =
   293   if maxidx = i then ct
   294   else if maxidx < i then
   295     Cterm {maxidx = i, thy_ref = thy_ref, t = t, T = T, sorts = sorts}
   296   else
   297     Cterm {maxidx = Int.max (maxidx_of_term t, i), thy_ref = thy_ref, t = t, T = T, sorts = sorts};
   298 
   299 fun incr_indexes_cterm i (ct as Cterm {thy_ref, t, T, maxidx, sorts}) =
   300   if i < 0 then raise CTERM ("negative increment", [ct])
   301   else if i = 0 then ct
   302   else Cterm {thy_ref = thy_ref, t = Logic.incr_indexes ([], i) t,
   303     T = Logic.incr_tvar i T, maxidx = maxidx + i, sorts = sorts};
   304 
   305 
   306 (* matching *)
   307 
   308 local
   309 
   310 fun gen_match match
   311     (ct1 as Cterm {t = t1, sorts = sorts1, ...},
   312      ct2 as Cterm {t = t2, sorts = sorts2, maxidx = maxidx2, ...}) =
   313   let
   314     val thy = Theory.deref (merge_thys0 ct1 ct2);
   315     val (Tinsts, tinsts) = match thy (t1, t2) (Vartab.empty, Vartab.empty);
   316     val sorts = Sorts.union sorts1 sorts2;
   317     fun mk_cTinst ((a, i), (S, T)) =
   318       (Ctyp {T = TVar ((a, i), S), thy_ref = Theory.check_thy thy, maxidx = i, sorts = sorts},
   319        Ctyp {T = T, thy_ref = Theory.check_thy thy, maxidx = maxidx2, sorts = sorts});
   320     fun mk_ctinst ((x, i), (T, t)) =
   321       let val T = Envir.typ_subst_TVars Tinsts T in
   322         (Cterm {t = Var ((x, i), T), T = T, thy_ref = Theory.check_thy thy,
   323           maxidx = i, sorts = sorts},
   324          Cterm {t = t, T = T, thy_ref = Theory.check_thy thy, maxidx = maxidx2, sorts = sorts})
   325       end;
   326   in (Vartab.fold (cons o mk_cTinst) Tinsts [], Vartab.fold (cons o mk_ctinst) tinsts []) end;
   327 
   328 in
   329 
   330 val match = gen_match Pattern.match;
   331 val first_order_match = gen_match Pattern.first_order_match;
   332 
   333 end;
   334 
   335 
   336 
   337 (*** Derivations and Theorems ***)
   338 
   339 datatype thm = Thm of
   340  deriv *                                        (*derivation*)
   341  {thy_ref: theory_ref,                          (*dynamic reference to theory*)
   342   tags: Properties.T,                           (*additional annotations/comments*)
   343   maxidx: int,                                  (*maximum index of any Var or TVar*)
   344   shyps: sort OrdList.T,                        (*sort hypotheses*)
   345   hyps: term OrdList.T,                         (*hypotheses*)
   346   tpairs: (term * term) list,                   (*flex-flex pairs*)
   347   prop: term}                                   (*conclusion*)
   348 and deriv = Deriv of
   349  {max_promise: serial,
   350   open_promises: (serial * thm future) OrdList.T,
   351   promises: (serial * thm future) OrdList.T,
   352   body: Pt.proof_body};
   353 
   354 type conv = cterm -> thm;
   355 
   356 (*attributes subsume any kind of rules or context modifiers*)
   357 type attribute = Context.generic * thm -> Context.generic * thm;
   358 
   359 (*errors involving theorems*)
   360 exception THM of string * int * thm list;
   361 
   362 fun rep_thm (Thm (_, args)) = args;
   363 
   364 fun crep_thm (Thm (_, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
   365   let fun cterm max t = Cterm {thy_ref = thy_ref, t = t, T = propT, maxidx = max, sorts = shyps} in
   366    {thy_ref = thy_ref, tags = tags, maxidx = maxidx, shyps = shyps,
   367     hyps = map (cterm ~1) hyps,
   368     tpairs = map (pairself (cterm maxidx)) tpairs,
   369     prop = cterm maxidx prop}
   370   end;
   371 
   372 fun terms_of_tpairs tpairs = fold_rev (fn (t, u) => cons t o cons u) tpairs [];
   373 
   374 fun eq_tpairs ((t, u), (t', u')) = t aconv t' andalso u aconv u';
   375 fun union_tpairs ts us = Library.merge eq_tpairs (ts, us);
   376 val maxidx_tpairs = fold (fn (t, u) => Term.maxidx_term t #> Term.maxidx_term u);
   377 
   378 fun attach_tpairs tpairs prop =
   379   Logic.list_implies (map Logic.mk_equals tpairs, prop);
   380 
   381 fun full_prop_of (Thm (_, {tpairs, prop, ...})) = attach_tpairs tpairs prop;
   382 
   383 val union_hyps = OrdList.union TermOrd.fast_term_ord;
   384 val insert_hyps = OrdList.insert TermOrd.fast_term_ord;
   385 val remove_hyps = OrdList.remove TermOrd.fast_term_ord;
   386 
   387 
   388 (* merge theories of cterms/thms -- trivial absorption only *)
   389 
   390 fun merge_thys1 (Cterm {thy_ref = r1, ...}) (th as Thm (_, {thy_ref = r2, ...})) =
   391   Theory.merge_refs (r1, r2);
   392 
   393 fun merge_thys2 (th1 as Thm (_, {thy_ref = r1, ...})) (th2 as Thm (_, {thy_ref = r2, ...})) =
   394   Theory.merge_refs (r1, r2);
   395 
   396 
   397 (* basic components *)
   398 
   399 val theory_of_thm = Theory.deref o #thy_ref o rep_thm;
   400 val maxidx_of = #maxidx o rep_thm;
   401 fun maxidx_thm th i = Int.max (maxidx_of th, i);
   402 val hyps_of = #hyps o rep_thm;
   403 val prop_of = #prop o rep_thm;
   404 val tpairs_of = #tpairs o rep_thm;
   405 
   406 val concl_of = Logic.strip_imp_concl o prop_of;
   407 val prems_of = Logic.strip_imp_prems o prop_of;
   408 val nprems_of = Logic.count_prems o prop_of;
   409 fun no_prems th = nprems_of th = 0;
   410 
   411 fun major_prem_of th =
   412   (case prems_of th of
   413     prem :: _ => Logic.strip_assums_concl prem
   414   | [] => raise THM ("major_prem_of: rule with no premises", 0, [th]));
   415 
   416 (*the statement of any thm is a cterm*)
   417 fun cprop_of (Thm (_, {thy_ref, maxidx, shyps, prop, ...})) =
   418   Cterm {thy_ref = thy_ref, maxidx = maxidx, T = propT, t = prop, sorts = shyps};
   419 
   420 fun cprem_of (th as Thm (_, {thy_ref, maxidx, shyps, prop, ...})) i =
   421   Cterm {thy_ref = thy_ref, maxidx = maxidx, T = propT, sorts = shyps,
   422     t = Logic.nth_prem (i, prop) handle TERM _ => raise THM ("cprem_of", i, [th])};
   423 
   424 (*explicit transfer to a super theory*)
   425 fun transfer thy' thm =
   426   let
   427     val Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop}) = thm;
   428     val thy = Theory.deref thy_ref;
   429     val _ = Theory.subthy (thy, thy') orelse raise THM ("transfer: not a super theory", 0, [thm]);
   430     val is_eq = Theory.eq_thy (thy, thy');
   431     val _ = Theory.check_thy thy;
   432   in
   433     if is_eq then thm
   434     else
   435       Thm (der,
   436        {thy_ref = Theory.check_thy thy',
   437         tags = tags,
   438         maxidx = maxidx,
   439         shyps = shyps,
   440         hyps = hyps,
   441         tpairs = tpairs,
   442         prop = prop})
   443   end;
   444 
   445 (*explicit weakening: maps |- B to A |- B*)
   446 fun weaken raw_ct th =
   447   let
   448     val ct as Cterm {t = A, T, sorts, maxidx = maxidxA, ...} = adjust_maxidx_cterm ~1 raw_ct;
   449     val Thm (der, {tags, maxidx, shyps, hyps, tpairs, prop, ...}) = th;
   450   in
   451     if T <> propT then
   452       raise THM ("weaken: assumptions must have type prop", 0, [])
   453     else if maxidxA <> ~1 then
   454       raise THM ("weaken: assumptions may not contain schematic variables", maxidxA, [])
   455     else
   456       Thm (der,
   457        {thy_ref = merge_thys1 ct th,
   458         tags = tags,
   459         maxidx = maxidx,
   460         shyps = Sorts.union sorts shyps,
   461         hyps = insert_hyps A hyps,
   462         tpairs = tpairs,
   463         prop = prop})
   464   end;
   465 
   466 fun weaken_sorts raw_sorts ct =
   467   let
   468     val Cterm {thy_ref, t, T, maxidx, sorts} = ct;
   469     val thy = Theory.deref thy_ref;
   470     val more_sorts = Sorts.make (map (Sign.certify_sort thy) raw_sorts);
   471     val sorts' = Sorts.union sorts more_sorts;
   472   in Cterm {thy_ref = Theory.check_thy thy, t = t, T = T, maxidx = maxidx, sorts = sorts'} end;
   473 
   474 
   475 
   476 (** sort contexts of theorems **)
   477 
   478 fun present_sorts (Thm (_, {hyps, tpairs, prop, ...})) =
   479   fold (fn (t, u) => Sorts.insert_term t o Sorts.insert_term u) tpairs
   480     (Sorts.insert_terms hyps (Sorts.insert_term prop []));
   481 
   482 (*remove extra sorts that are non-empty by virtue of type signature information*)
   483 fun strip_shyps (thm as Thm (_, {shyps = [], ...})) = thm
   484   | strip_shyps (thm as Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
   485       let
   486         val thy = Theory.deref thy_ref;
   487         val present = present_sorts thm;
   488         val extra = Sorts.subtract present shyps;
   489         val extra' =
   490           Sorts.subtract (map #2 (Sign.witness_sorts thy present extra)) extra
   491           |> Sorts.minimal_sorts (Sign.classes_of thy);
   492         val shyps' = Sorts.union present extra';
   493       in
   494         Thm (der, {thy_ref = Theory.check_thy thy, tags = tags, maxidx = maxidx,
   495           shyps = shyps', hyps = hyps, tpairs = tpairs, prop = prop})
   496       end;
   497 
   498 (*dangling sort constraints of a thm*)
   499 fun extra_shyps (th as Thm (_, {shyps, ...})) = Sorts.subtract (present_sorts th) shyps;
   500 
   501 
   502 
   503 (** derivations **)
   504 
   505 fun make_deriv max_promise open_promises promises oracles thms proof =
   506   Deriv {max_promise = max_promise, open_promises = open_promises, promises = promises,
   507     body = PBody {oracles = oracles, thms = thms, proof = proof}};
   508 
   509 val empty_deriv = make_deriv ~1 [] [] [] [] Pt.MinProof;
   510 
   511 
   512 (* inference rules *)
   513 
   514 fun promise_ord ((i, _), (j, _)) = int_ord (j, i);
   515 
   516 fun deriv_rule2 f
   517     (Deriv {max_promise = max1, open_promises = open_ps1, promises = ps1,
   518       body = PBody {oracles = oras1, thms = thms1, proof = prf1}})
   519     (Deriv {max_promise = max2, open_promises = open_ps2, promises = ps2,
   520       body = PBody {oracles = oras2, thms = thms2, proof = prf2}}) =
   521   let
   522     val max = Int.max (max1, max2);
   523     val open_ps = OrdList.union promise_ord open_ps1 open_ps2;
   524     val ps = OrdList.union promise_ord ps1 ps2;
   525     val oras = Pt.merge_oracles oras1 oras2;
   526     val thms = Pt.merge_thms thms1 thms2;
   527     val prf =
   528       (case ! Pt.proofs of
   529         2 => f prf1 prf2
   530       | 1 => MinProof
   531       | 0 => MinProof
   532       | i => error ("Illegal level of detail for proof objects: " ^ string_of_int i));
   533   in make_deriv max open_ps ps oras thms prf end;
   534 
   535 fun deriv_rule1 f = deriv_rule2 (K f) empty_deriv;
   536 fun deriv_rule0 prf = deriv_rule1 I (make_deriv ~1 [] [] [] [] prf);
   537 
   538 
   539 
   540 (** Axioms **)
   541 
   542 fun axiom theory name =
   543   let
   544     fun get_ax thy =
   545       Symtab.lookup (Theory.axiom_table thy) name
   546       |> Option.map (fn prop =>
   547            let
   548              val der = deriv_rule0 (Pt.axm_proof name prop);
   549              val maxidx = maxidx_of_term prop;
   550              val shyps = Sorts.insert_term prop [];
   551            in
   552              Thm (der, {thy_ref = Theory.check_thy thy, tags = [],
   553                maxidx = maxidx, shyps = shyps, hyps = [], tpairs = [], prop = prop})
   554            end);
   555   in
   556     (case get_first get_ax (theory :: Theory.ancestors_of theory) of
   557       SOME thm => thm
   558     | NONE => raise THEORY ("No axiom " ^ quote name, [theory]))
   559   end;
   560 
   561 fun def_name c = c ^ "_def";
   562 
   563 fun def_name_optional c "" = def_name c
   564   | def_name_optional _ name = name;
   565 
   566 fun get_def thy = axiom thy o NameSpace.intern (Theory.axiom_space thy) o def_name;
   567 
   568 
   569 (*return additional axioms of this theory node*)
   570 fun axioms_of thy =
   571   map (fn s => (s, axiom thy s)) (Symtab.keys (Theory.axiom_table thy));
   572 
   573 
   574 (* tags *)
   575 
   576 val get_tags = #tags o rep_thm;
   577 
   578 fun map_tags f (Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
   579   Thm (der, {thy_ref = thy_ref, tags = f tags, maxidx = maxidx,
   580     shyps = shyps, hyps = hyps, tpairs = tpairs, prop = prop});
   581 
   582 
   583 fun norm_proof (Thm (der, args as {thy_ref, ...})) =
   584   let
   585     val thy = Theory.deref thy_ref;
   586     val der' = deriv_rule1 (Pt.rew_proof thy) der;
   587     val _ = Theory.check_thy thy;
   588   in Thm (der', args) end;
   589 
   590 fun adjust_maxidx_thm i (th as Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
   591   if maxidx = i then th
   592   else if maxidx < i then
   593     Thm (der, {maxidx = i, thy_ref = thy_ref, tags = tags, shyps = shyps,
   594       hyps = hyps, tpairs = tpairs, prop = prop})
   595   else
   596     Thm (der, {maxidx = Int.max (maxidx_tpairs tpairs (maxidx_of_term prop), i), thy_ref = thy_ref,
   597       tags = tags, shyps = shyps, hyps = hyps, tpairs = tpairs, prop = prop});
   598 
   599 
   600 
   601 (*** Meta rules ***)
   602 
   603 (** primitive rules **)
   604 
   605 (*The assumption rule A |- A*)
   606 fun assume raw_ct =
   607   let val Cterm {thy_ref, t = prop, T, maxidx, sorts} = adjust_maxidx_cterm ~1 raw_ct in
   608     if T <> propT then
   609       raise THM ("assume: prop", 0, [])
   610     else if maxidx <> ~1 then
   611       raise THM ("assume: variables", maxidx, [])
   612     else Thm (deriv_rule0 (Pt.Hyp prop),
   613      {thy_ref = thy_ref,
   614       tags = [],
   615       maxidx = ~1,
   616       shyps = sorts,
   617       hyps = [prop],
   618       tpairs = [],
   619       prop = prop})
   620   end;
   621 
   622 (*Implication introduction
   623     [A]
   624      :
   625      B
   626   -------
   627   A ==> B
   628 *)
   629 fun implies_intr
   630     (ct as Cterm {t = A, T, maxidx = maxidxA, sorts, ...})
   631     (th as Thm (der, {maxidx, hyps, shyps, tpairs, prop, ...})) =
   632   if T <> propT then
   633     raise THM ("implies_intr: assumptions must have type prop", 0, [th])
   634   else
   635     Thm (deriv_rule1 (Pt.implies_intr_proof A) der,
   636      {thy_ref = merge_thys1 ct th,
   637       tags = [],
   638       maxidx = Int.max (maxidxA, maxidx),
   639       shyps = Sorts.union sorts shyps,
   640       hyps = remove_hyps A hyps,
   641       tpairs = tpairs,
   642       prop = Logic.mk_implies (A, prop)});
   643 
   644 
   645 (*Implication elimination
   646   A ==> B    A
   647   ------------
   648         B
   649 *)
   650 fun implies_elim thAB thA =
   651   let
   652     val Thm (derA, {maxidx = maxA, hyps = hypsA, shyps = shypsA, tpairs = tpairsA,
   653       prop = propA, ...}) = thA
   654     and Thm (der, {maxidx, hyps, shyps, tpairs, prop, ...}) = thAB;
   655     fun err () = raise THM ("implies_elim: major premise", 0, [thAB, thA]);
   656   in
   657     case prop of
   658       Const ("==>", _) $ A $ B =>
   659         if A aconv propA then
   660           Thm (deriv_rule2 (curry Pt.%%) der derA,
   661            {thy_ref = merge_thys2 thAB thA,
   662             tags = [],
   663             maxidx = Int.max (maxA, maxidx),
   664             shyps = Sorts.union shypsA shyps,
   665             hyps = union_hyps hypsA hyps,
   666             tpairs = union_tpairs tpairsA tpairs,
   667             prop = B})
   668         else err ()
   669     | _ => err ()
   670   end;
   671 
   672 (*Forall introduction.  The Free or Var x must not be free in the hypotheses.
   673     [x]
   674      :
   675      A
   676   ------
   677   !!x. A
   678 *)
   679 fun forall_intr
   680     (ct as Cterm {t = x, T, sorts, ...})
   681     (th as Thm (der, {maxidx, shyps, hyps, tpairs, prop, ...})) =
   682   let
   683     fun result a =
   684       Thm (deriv_rule1 (Pt.forall_intr_proof x a) der,
   685        {thy_ref = merge_thys1 ct th,
   686         tags = [],
   687         maxidx = maxidx,
   688         shyps = Sorts.union sorts shyps,
   689         hyps = hyps,
   690         tpairs = tpairs,
   691         prop = Term.all T $ Abs (a, T, abstract_over (x, prop))});
   692     fun check_occs a x ts =
   693       if exists (fn t => Logic.occs (x, t)) ts then
   694         raise THM ("forall_intr: variable " ^ quote a ^ " free in assumptions", 0, [th])
   695       else ();
   696   in
   697     case x of
   698       Free (a, _) => (check_occs a x hyps; check_occs a x (terms_of_tpairs tpairs); result a)
   699     | Var ((a, _), _) => (check_occs a x (terms_of_tpairs tpairs); result a)
   700     | _ => raise THM ("forall_intr: not a variable", 0, [th])
   701   end;
   702 
   703 (*Forall elimination
   704   !!x. A
   705   ------
   706   A[t/x]
   707 *)
   708 fun forall_elim
   709     (ct as Cterm {t, T, maxidx = maxt, sorts, ...})
   710     (th as Thm (der, {maxidx, shyps, hyps, tpairs, prop, ...})) =
   711   (case prop of
   712     Const ("all", Type ("fun", [Type ("fun", [qary, _]), _])) $ A =>
   713       if T <> qary then
   714         raise THM ("forall_elim: type mismatch", 0, [th])
   715       else
   716         Thm (deriv_rule1 (Pt.% o rpair (SOME t)) der,
   717          {thy_ref = merge_thys1 ct th,
   718           tags = [],
   719           maxidx = Int.max (maxidx, maxt),
   720           shyps = Sorts.union sorts shyps,
   721           hyps = hyps,
   722           tpairs = tpairs,
   723           prop = Term.betapply (A, t)})
   724   | _ => raise THM ("forall_elim: not quantified", 0, [th]));
   725 
   726 
   727 (* Equality *)
   728 
   729 (*Reflexivity
   730   t == t
   731 *)
   732 fun reflexive (ct as Cterm {thy_ref, t, T, maxidx, sorts}) =
   733   Thm (deriv_rule0 Pt.reflexive,
   734    {thy_ref = thy_ref,
   735     tags = [],
   736     maxidx = maxidx,
   737     shyps = sorts,
   738     hyps = [],
   739     tpairs = [],
   740     prop = Logic.mk_equals (t, t)});
   741 
   742 (*Symmetry
   743   t == u
   744   ------
   745   u == t
   746 *)
   747 fun symmetric (th as Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
   748   (case prop of
   749     (eq as Const ("==", Type (_, [T, _]))) $ t $ u =>
   750       Thm (deriv_rule1 Pt.symmetric der,
   751        {thy_ref = thy_ref,
   752         tags = [],
   753         maxidx = maxidx,
   754         shyps = shyps,
   755         hyps = hyps,
   756         tpairs = tpairs,
   757         prop = eq $ u $ t})
   758     | _ => raise THM ("symmetric", 0, [th]));
   759 
   760 (*Transitivity
   761   t1 == u    u == t2
   762   ------------------
   763        t1 == t2
   764 *)
   765 fun transitive th1 th2 =
   766   let
   767     val Thm (der1, {maxidx = max1, hyps = hyps1, shyps = shyps1, tpairs = tpairs1,
   768       prop = prop1, ...}) = th1
   769     and Thm (der2, {maxidx = max2, hyps = hyps2, shyps = shyps2, tpairs = tpairs2,
   770       prop = prop2, ...}) = th2;
   771     fun err msg = raise THM ("transitive: " ^ msg, 0, [th1, th2]);
   772   in
   773     case (prop1, prop2) of
   774       ((eq as Const ("==", Type (_, [T, _]))) $ t1 $ u, Const ("==", _) $ u' $ t2) =>
   775         if not (u aconv u') then err "middle term"
   776         else
   777           Thm (deriv_rule2 (Pt.transitive u T) der1 der2,
   778            {thy_ref = merge_thys2 th1 th2,
   779             tags = [],
   780             maxidx = Int.max (max1, max2),
   781             shyps = Sorts.union shyps1 shyps2,
   782             hyps = union_hyps hyps1 hyps2,
   783             tpairs = union_tpairs tpairs1 tpairs2,
   784             prop = eq $ t1 $ t2})
   785      | _ =>  err "premises"
   786   end;
   787 
   788 (*Beta-conversion
   789   (%x. t)(u) == t[u/x]
   790   fully beta-reduces the term if full = true
   791 *)
   792 fun beta_conversion full (Cterm {thy_ref, t, T, maxidx, sorts}) =
   793   let val t' =
   794     if full then Envir.beta_norm t
   795     else
   796       (case t of Abs (_, _, bodt) $ u => subst_bound (u, bodt)
   797       | _ => raise THM ("beta_conversion: not a redex", 0, []));
   798   in
   799     Thm (deriv_rule0 Pt.reflexive,
   800      {thy_ref = thy_ref,
   801       tags = [],
   802       maxidx = maxidx,
   803       shyps = sorts,
   804       hyps = [],
   805       tpairs = [],
   806       prop = Logic.mk_equals (t, t')})
   807   end;
   808 
   809 fun eta_conversion (Cterm {thy_ref, t, T, maxidx, sorts}) =
   810   Thm (deriv_rule0 Pt.reflexive,
   811    {thy_ref = thy_ref,
   812     tags = [],
   813     maxidx = maxidx,
   814     shyps = sorts,
   815     hyps = [],
   816     tpairs = [],
   817     prop = Logic.mk_equals (t, Envir.eta_contract t)});
   818 
   819 fun eta_long_conversion (Cterm {thy_ref, t, T, maxidx, sorts}) =
   820   Thm (deriv_rule0 Pt.reflexive,
   821    {thy_ref = thy_ref,
   822     tags = [],
   823     maxidx = maxidx,
   824     shyps = sorts,
   825     hyps = [],
   826     tpairs = [],
   827     prop = Logic.mk_equals (t, Pattern.eta_long [] t)});
   828 
   829 (*The abstraction rule.  The Free or Var x must not be free in the hypotheses.
   830   The bound variable will be named "a" (since x will be something like x320)
   831       t == u
   832   --------------
   833   %x. t == %x. u
   834 *)
   835 fun abstract_rule a
   836     (Cterm {t = x, T, sorts, ...})
   837     (th as Thm (der, {thy_ref, maxidx, hyps, shyps, tpairs, prop, ...})) =
   838   let
   839     val (t, u) = Logic.dest_equals prop
   840       handle TERM _ => raise THM ("abstract_rule: premise not an equality", 0, [th]);
   841     val result =
   842       Thm (deriv_rule1 (Pt.abstract_rule x a) der,
   843        {thy_ref = thy_ref,
   844         tags = [],
   845         maxidx = maxidx,
   846         shyps = Sorts.union sorts shyps,
   847         hyps = hyps,
   848         tpairs = tpairs,
   849         prop = Logic.mk_equals
   850           (Abs (a, T, abstract_over (x, t)), Abs (a, T, abstract_over (x, u)))});
   851     fun check_occs a x ts =
   852       if exists (fn t => Logic.occs (x, t)) ts then
   853         raise THM ("abstract_rule: variable " ^ quote a ^ " free in assumptions", 0, [th])
   854       else ();
   855   in
   856     case x of
   857       Free (a, _) => (check_occs a x hyps; check_occs a x (terms_of_tpairs tpairs); result)
   858     | Var ((a, _), _) => (check_occs a x (terms_of_tpairs tpairs); result)
   859     | _ => raise THM ("abstract_rule: not a variable", 0, [th])
   860   end;
   861 
   862 (*The combination rule
   863   f == g  t == u
   864   --------------
   865     f t == g u
   866 *)
   867 fun combination th1 th2 =
   868   let
   869     val Thm (der1, {maxidx = max1, shyps = shyps1, hyps = hyps1, tpairs = tpairs1,
   870       prop = prop1, ...}) = th1
   871     and Thm (der2, {maxidx = max2, shyps = shyps2, hyps = hyps2, tpairs = tpairs2,
   872       prop = prop2, ...}) = th2;
   873     fun chktypes fT tT =
   874       (case fT of
   875         Type ("fun", [T1, T2]) =>
   876           if T1 <> tT then
   877             raise THM ("combination: types", 0, [th1, th2])
   878           else ()
   879       | _ => raise THM ("combination: not function type", 0, [th1, th2]));
   880   in
   881     case (prop1, prop2) of
   882       (Const ("==", Type ("fun", [fT, _])) $ f $ g,
   883        Const ("==", Type ("fun", [tT, _])) $ t $ u) =>
   884         (chktypes fT tT;
   885           Thm (deriv_rule2 (Pt.combination f g t u fT) der1 der2,
   886            {thy_ref = merge_thys2 th1 th2,
   887             tags = [],
   888             maxidx = Int.max (max1, max2),
   889             shyps = Sorts.union shyps1 shyps2,
   890             hyps = union_hyps hyps1 hyps2,
   891             tpairs = union_tpairs tpairs1 tpairs2,
   892             prop = Logic.mk_equals (f $ t, g $ u)}))
   893      | _ => raise THM ("combination: premises", 0, [th1, th2])
   894   end;
   895 
   896 (*Equality introduction
   897   A ==> B  B ==> A
   898   ----------------
   899        A == B
   900 *)
   901 fun equal_intr th1 th2 =
   902   let
   903     val Thm (der1, {maxidx = max1, shyps = shyps1, hyps = hyps1, tpairs = tpairs1,
   904       prop = prop1, ...}) = th1
   905     and Thm (der2, {maxidx = max2, shyps = shyps2, hyps = hyps2, tpairs = tpairs2,
   906       prop = prop2, ...}) = th2;
   907     fun err msg = raise THM ("equal_intr: " ^ msg, 0, [th1, th2]);
   908   in
   909     case (prop1, prop2) of
   910       (Const("==>", _) $ A $ B, Const("==>", _) $ B' $ A') =>
   911         if A aconv A' andalso B aconv B' then
   912           Thm (deriv_rule2 (Pt.equal_intr A B) der1 der2,
   913            {thy_ref = merge_thys2 th1 th2,
   914             tags = [],
   915             maxidx = Int.max (max1, max2),
   916             shyps = Sorts.union shyps1 shyps2,
   917             hyps = union_hyps hyps1 hyps2,
   918             tpairs = union_tpairs tpairs1 tpairs2,
   919             prop = Logic.mk_equals (A, B)})
   920         else err "not equal"
   921     | _ =>  err "premises"
   922   end;
   923 
   924 (*The equal propositions rule
   925   A == B  A
   926   ---------
   927       B
   928 *)
   929 fun equal_elim th1 th2 =
   930   let
   931     val Thm (der1, {maxidx = max1, shyps = shyps1, hyps = hyps1,
   932       tpairs = tpairs1, prop = prop1, ...}) = th1
   933     and Thm (der2, {maxidx = max2, shyps = shyps2, hyps = hyps2,
   934       tpairs = tpairs2, prop = prop2, ...}) = th2;
   935     fun err msg = raise THM ("equal_elim: " ^ msg, 0, [th1, th2]);
   936   in
   937     case prop1 of
   938       Const ("==", _) $ A $ B =>
   939         if prop2 aconv A then
   940           Thm (deriv_rule2 (Pt.equal_elim A B) der1 der2,
   941            {thy_ref = merge_thys2 th1 th2,
   942             tags = [],
   943             maxidx = Int.max (max1, max2),
   944             shyps = Sorts.union shyps1 shyps2,
   945             hyps = union_hyps hyps1 hyps2,
   946             tpairs = union_tpairs tpairs1 tpairs2,
   947             prop = B})
   948         else err "not equal"
   949      | _ =>  err"major premise"
   950   end;
   951 
   952 
   953 
   954 (**** Derived rules ****)
   955 
   956 (*Smash unifies the list of term pairs leaving no flex-flex pairs.
   957   Instantiates the theorem and deletes trivial tpairs.  Resulting
   958   sequence may contain multiple elements if the tpairs are not all
   959   flex-flex.*)
   960 fun flexflex_rule (th as Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
   961   let val thy = Theory.deref thy_ref in
   962     Unify.smash_unifiers thy tpairs (Envir.empty maxidx)
   963     |> Seq.map (fn env =>
   964         if Envir.is_empty env then th
   965         else
   966           let
   967             val tpairs' = tpairs |> map (pairself (Envir.norm_term env))
   968               (*remove trivial tpairs, of the form t==t*)
   969               |> filter_out (op aconv);
   970             val der' = deriv_rule1 (Pt.norm_proof' env) der;
   971             val prop' = Envir.norm_term env prop;
   972             val maxidx = maxidx_tpairs tpairs' (maxidx_of_term prop');
   973             val shyps = Envir.insert_sorts env shyps;
   974           in
   975             Thm (der', {thy_ref = Theory.check_thy thy, tags = [], maxidx = maxidx,
   976               shyps = shyps, hyps = hyps, tpairs = tpairs', prop = prop'})
   977           end)
   978   end;
   979 
   980 
   981 (*Generalization of fixed variables
   982            A
   983   --------------------
   984   A[?'a/'a, ?x/x, ...]
   985 *)
   986 
   987 fun generalize ([], []) _ th = th
   988   | generalize (tfrees, frees) idx th =
   989       let
   990         val Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...}) = th;
   991         val _ = idx <= maxidx andalso raise THM ("generalize: bad index", idx, [th]);
   992 
   993         val bad_type = if null tfrees then K false else
   994           Term.exists_subtype (fn TFree (a, _) => member (op =) tfrees a | _ => false);
   995         fun bad_term (Free (x, T)) = bad_type T orelse member (op =) frees x
   996           | bad_term (Var (_, T)) = bad_type T
   997           | bad_term (Const (_, T)) = bad_type T
   998           | bad_term (Abs (_, T, t)) = bad_type T orelse bad_term t
   999           | bad_term (t $ u) = bad_term t orelse bad_term u
  1000           | bad_term (Bound _) = false;
  1001         val _ = exists bad_term hyps andalso
  1002           raise THM ("generalize: variable free in assumptions", 0, [th]);
  1003 
  1004         val gen = TermSubst.generalize (tfrees, frees) idx;
  1005         val prop' = gen prop;
  1006         val tpairs' = map (pairself gen) tpairs;
  1007         val maxidx' = maxidx_tpairs tpairs' (maxidx_of_term prop');
  1008       in
  1009         Thm (deriv_rule1 (Pt.generalize (tfrees, frees) idx) der,
  1010          {thy_ref = thy_ref,
  1011           tags = [],
  1012           maxidx = maxidx',
  1013           shyps = shyps,
  1014           hyps = hyps,
  1015           tpairs = tpairs',
  1016           prop = prop'})
  1017       end;
  1018 
  1019 
  1020 (*Instantiation of schematic variables
  1021            A
  1022   --------------------
  1023   A[t1/v1, ..., tn/vn]
  1024 *)
  1025 
  1026 local
  1027 
  1028 fun pretty_typing thy t T = Pretty.block
  1029   [Syntax.pretty_term_global thy t, Pretty.str " ::", Pretty.brk 1, Syntax.pretty_typ_global thy T];
  1030 
  1031 fun add_inst (ct, cu) (thy_ref, sorts) =
  1032   let
  1033     val Cterm {t = t, T = T, ...} = ct;
  1034     val Cterm {t = u, T = U, sorts = sorts_u, maxidx = maxidx_u, ...} = cu;
  1035     val thy_ref' = Theory.merge_refs (thy_ref, merge_thys0 ct cu);
  1036     val sorts' = Sorts.union sorts_u sorts;
  1037   in
  1038     (case t of Var v =>
  1039       if T = U then ((v, (u, maxidx_u)), (thy_ref', sorts'))
  1040       else raise TYPE (Pretty.string_of (Pretty.block
  1041        [Pretty.str "instantiate: type conflict",
  1042         Pretty.fbrk, pretty_typing (Theory.deref thy_ref') t T,
  1043         Pretty.fbrk, pretty_typing (Theory.deref thy_ref') u U]), [T, U], [t, u])
  1044     | _ => raise TYPE (Pretty.string_of (Pretty.block
  1045        [Pretty.str "instantiate: not a variable",
  1046         Pretty.fbrk, Syntax.pretty_term_global (Theory.deref thy_ref') t]), [], [t]))
  1047   end;
  1048 
  1049 fun add_instT (cT, cU) (thy_ref, sorts) =
  1050   let
  1051     val Ctyp {T, thy_ref = thy_ref1, ...} = cT
  1052     and Ctyp {T = U, thy_ref = thy_ref2, sorts = sorts_U, maxidx = maxidx_U, ...} = cU;
  1053     val thy' = Theory.deref (Theory.merge_refs (thy_ref, Theory.merge_refs (thy_ref1, thy_ref2)));
  1054     val sorts' = Sorts.union sorts_U sorts;
  1055   in
  1056     (case T of TVar (v as (_, S)) =>
  1057       if Sign.of_sort thy' (U, S) then ((v, (U, maxidx_U)), (Theory.check_thy thy', sorts'))
  1058       else raise TYPE ("Type not of sort " ^ Syntax.string_of_sort_global thy' S, [U], [])
  1059     | _ => raise TYPE (Pretty.string_of (Pretty.block
  1060         [Pretty.str "instantiate: not a type variable",
  1061          Pretty.fbrk, Syntax.pretty_typ_global thy' T]), [T], []))
  1062   end;
  1063 
  1064 in
  1065 
  1066 (*Left-to-right replacements: ctpairs = [..., (vi, ti), ...].
  1067   Instantiates distinct Vars by terms of same type.
  1068   Does NOT normalize the resulting theorem!*)
  1069 fun instantiate ([], []) th = th
  1070   | instantiate (instT, inst) th =
  1071       let
  1072         val Thm (der, {thy_ref, hyps, shyps, tpairs, prop, ...}) = th;
  1073         val (inst', (instT', (thy_ref', shyps'))) =
  1074           (thy_ref, shyps) |> fold_map add_inst inst ||> fold_map add_instT instT;
  1075         val subst = TermSubst.instantiate_maxidx (instT', inst');
  1076         val (prop', maxidx1) = subst prop ~1;
  1077         val (tpairs', maxidx') =
  1078           fold_map (fn (t, u) => fn i => subst t i ||>> subst u) tpairs maxidx1;
  1079       in
  1080         Thm (deriv_rule1 (fn d => Pt.instantiate (map (apsnd #1) instT', map (apsnd #1) inst') d) der,
  1081          {thy_ref = thy_ref',
  1082           tags = [],
  1083           maxidx = maxidx',
  1084           shyps = shyps',
  1085           hyps = hyps,
  1086           tpairs = tpairs',
  1087           prop = prop'})
  1088       end
  1089       handle TYPE (msg, _, _) => raise THM (msg, 0, [th]);
  1090 
  1091 fun instantiate_cterm ([], []) ct = ct
  1092   | instantiate_cterm (instT, inst) ct =
  1093       let
  1094         val Cterm {thy_ref, t, T, sorts, ...} = ct;
  1095         val (inst', (instT', (thy_ref', sorts'))) =
  1096           (thy_ref, sorts) |> fold_map add_inst inst ||> fold_map add_instT instT;
  1097         val subst = TermSubst.instantiate_maxidx (instT', inst');
  1098         val substT = TermSubst.instantiateT_maxidx instT';
  1099         val (t', maxidx1) = subst t ~1;
  1100         val (T', maxidx') = substT T maxidx1;
  1101       in Cterm {thy_ref = thy_ref', t = t', T = T', sorts = sorts', maxidx = maxidx'} end
  1102       handle TYPE (msg, _, _) => raise CTERM (msg, [ct]);
  1103 
  1104 end;
  1105 
  1106 
  1107 (*The trivial implication A ==> A, justified by assume and forall rules.
  1108   A can contain Vars, not so for assume!*)
  1109 fun trivial (Cterm {thy_ref, t =A, T, maxidx, sorts}) =
  1110   if T <> propT then
  1111     raise THM ("trivial: the term must have type prop", 0, [])
  1112   else
  1113     Thm (deriv_rule0 (Pt.AbsP ("H", NONE, Pt.PBound 0)),
  1114      {thy_ref = thy_ref,
  1115       tags = [],
  1116       maxidx = maxidx,
  1117       shyps = sorts,
  1118       hyps = [],
  1119       tpairs = [],
  1120       prop = Logic.mk_implies (A, A)});
  1121 
  1122 (*Axiom-scheme reflecting signature contents: "OFCLASS(?'a::c, c_class)" *)
  1123 fun class_triv thy c =
  1124   let
  1125     val Cterm {t, maxidx, sorts, ...} =
  1126       cterm_of thy (Logic.mk_inclass (TVar ((Name.aT, 0), [c]), Sign.certify_class thy c))
  1127         handle TERM (msg, _) => raise THM ("class_triv: " ^ msg, 0, []);
  1128     val der = deriv_rule0 (Pt.PAxm ("Pure.class_triv:" ^ c, t, SOME []));
  1129   in
  1130     Thm (der, {thy_ref = Theory.check_thy thy, tags = [], maxidx = maxidx,
  1131       shyps = sorts, hyps = [], tpairs = [], prop = t})
  1132   end;
  1133 
  1134 (*Internalize sort constraints of type variable*)
  1135 fun unconstrainT
  1136     (Ctyp {thy_ref = thy_ref1, T, ...})
  1137     (th as Thm (_, {thy_ref = thy_ref2, maxidx, shyps, hyps, tpairs, prop, ...})) =
  1138   let
  1139     val ((x, i), S) = Term.dest_TVar T handle TYPE _ =>
  1140       raise THM ("unconstrainT: not a type variable", 0, [th]);
  1141     val T' = TVar ((x, i), []);
  1142     val unconstrain = Term.map_types (Term.map_atyps (fn U => if U = T then T' else U));
  1143     val constraints = map (curry Logic.mk_inclass T') S;
  1144   in
  1145     Thm (deriv_rule0 (Pt.PAxm ("Pure.unconstrainT", prop, SOME [])),
  1146      {thy_ref = Theory.merge_refs (thy_ref1, thy_ref2),
  1147       tags = [],
  1148       maxidx = Int.max (maxidx, i),
  1149       shyps = Sorts.remove_sort S shyps,
  1150       hyps = hyps,
  1151       tpairs = map (pairself unconstrain) tpairs,
  1152       prop = Logic.list_implies (constraints, unconstrain prop)})
  1153   end;
  1154 
  1155 (* Replace all TFrees not fixed or in the hyps by new TVars *)
  1156 fun varifyT' fixed (Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
  1157   let
  1158     val tfrees = fold Term.add_tfrees hyps fixed;
  1159     val prop1 = attach_tpairs tpairs prop;
  1160     val (al, prop2) = Type.varify tfrees prop1;
  1161     val (ts, prop3) = Logic.strip_prems (length tpairs, [], prop2);
  1162   in
  1163     (al, Thm (deriv_rule1 (Pt.varify_proof prop tfrees) der,
  1164      {thy_ref = thy_ref,
  1165       tags = [],
  1166       maxidx = Int.max (0, maxidx),
  1167       shyps = shyps,
  1168       hyps = hyps,
  1169       tpairs = rev (map Logic.dest_equals ts),
  1170       prop = prop3}))
  1171   end;
  1172 
  1173 val varifyT = #2 o varifyT' [];
  1174 
  1175 (* Replace all TVars by new TFrees *)
  1176 fun freezeT (Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
  1177   let
  1178     val prop1 = attach_tpairs tpairs prop;
  1179     val prop2 = Type.freeze prop1;
  1180     val (ts, prop3) = Logic.strip_prems (length tpairs, [], prop2);
  1181   in
  1182     Thm (deriv_rule1 (Pt.freezeT prop1) der,
  1183      {thy_ref = thy_ref,
  1184       tags = [],
  1185       maxidx = maxidx_of_term prop2,
  1186       shyps = shyps,
  1187       hyps = hyps,
  1188       tpairs = rev (map Logic.dest_equals ts),
  1189       prop = prop3})
  1190   end;
  1191 
  1192 
  1193 (*** Inference rules for tactics ***)
  1194 
  1195 (*Destruct proof state into constraints, other goals, goal(i), rest *)
  1196 fun dest_state (state as Thm (_, {prop,tpairs,...}), i) =
  1197   (case  Logic.strip_prems(i, [], prop) of
  1198       (B::rBs, C) => (tpairs, rev rBs, B, C)
  1199     | _ => raise THM("dest_state", i, [state]))
  1200   handle TERM _ => raise THM("dest_state", i, [state]);
  1201 
  1202 (*Increment variables and parameters of orule as required for
  1203   resolution with a goal.*)
  1204 fun lift_rule goal orule =
  1205   let
  1206     val Cterm {t = gprop, T, maxidx = gmax, sorts, ...} = goal;
  1207     val inc = gmax + 1;
  1208     val lift_abs = Logic.lift_abs inc gprop;
  1209     val lift_all = Logic.lift_all inc gprop;
  1210     val Thm (der, {maxidx, shyps, hyps, tpairs, prop, ...}) = orule;
  1211     val (As, B) = Logic.strip_horn prop;
  1212   in
  1213     if T <> propT then raise THM ("lift_rule: the term must have type prop", 0, [])
  1214     else
  1215       Thm (deriv_rule1 (Pt.lift_proof gprop inc prop) der,
  1216        {thy_ref = merge_thys1 goal orule,
  1217         tags = [],
  1218         maxidx = maxidx + inc,
  1219         shyps = Sorts.union shyps sorts,  (*sic!*)
  1220         hyps = hyps,
  1221         tpairs = map (pairself lift_abs) tpairs,
  1222         prop = Logic.list_implies (map lift_all As, lift_all B)})
  1223   end;
  1224 
  1225 fun incr_indexes i (thm as Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
  1226   if i < 0 then raise THM ("negative increment", 0, [thm])
  1227   else if i = 0 then thm
  1228   else
  1229     Thm (deriv_rule1 (Pt.map_proof_terms (Logic.incr_indexes ([], i)) (Logic.incr_tvar i)) der,
  1230      {thy_ref = thy_ref,
  1231       tags = [],
  1232       maxidx = maxidx + i,
  1233       shyps = shyps,
  1234       hyps = hyps,
  1235       tpairs = map (pairself (Logic.incr_indexes ([], i))) tpairs,
  1236       prop = Logic.incr_indexes ([], i) prop});
  1237 
  1238 (*Solve subgoal Bi of proof state B1...Bn/C by assumption. *)
  1239 fun assumption i state =
  1240   let
  1241     val Thm (der, {thy_ref, maxidx, shyps, hyps, prop, ...}) = state;
  1242     val thy = Theory.deref thy_ref;
  1243     val (tpairs, Bs, Bi, C) = dest_state (state, i);
  1244     fun newth n (env as Envir.Envir {maxidx, ...}, tpairs) =
  1245       Thm (deriv_rule1
  1246           ((if Envir.is_empty env then I else (Pt.norm_proof' env)) o
  1247             Pt.assumption_proof Bs Bi n) der,
  1248        {tags = [],
  1249         maxidx = maxidx,
  1250         shyps = Envir.insert_sorts env shyps,
  1251         hyps = hyps,
  1252         tpairs =
  1253           if Envir.is_empty env then tpairs
  1254           else map (pairself (Envir.norm_term env)) tpairs,
  1255         prop =
  1256           if Envir.is_empty env then (*avoid wasted normalizations*)
  1257             Logic.list_implies (Bs, C)
  1258           else (*normalize the new rule fully*)
  1259             Envir.norm_term env (Logic.list_implies (Bs, C)),
  1260         thy_ref = Theory.check_thy thy});
  1261     fun addprfs [] _ = Seq.empty
  1262       | addprfs ((t, u) :: apairs) n = Seq.make (fn () => Seq.pull
  1263           (Seq.mapp (newth n)
  1264             (Unify.unifiers (thy, Envir.empty maxidx, (t, u) :: tpairs))
  1265             (addprfs apairs (n + 1))))
  1266   in addprfs (Logic.assum_pairs (~1, Bi)) 1 end;
  1267 
  1268 (*Solve subgoal Bi of proof state B1...Bn/C by assumption.
  1269   Checks if Bi's conclusion is alpha-convertible to one of its assumptions*)
  1270 fun eq_assumption i state =
  1271   let
  1272     val Thm (der, {thy_ref, maxidx, shyps, hyps, prop, ...}) = state;
  1273     val (tpairs, Bs, Bi, C) = dest_state (state, i);
  1274   in
  1275     (case find_index Pattern.aeconv (Logic.assum_pairs (~1, Bi)) of
  1276       ~1 => raise THM ("eq_assumption", 0, [state])
  1277     | n =>
  1278         Thm (deriv_rule1 (Pt.assumption_proof Bs Bi (n + 1)) der,
  1279          {thy_ref = thy_ref,
  1280           tags = [],
  1281           maxidx = maxidx,
  1282           shyps = shyps,
  1283           hyps = hyps,
  1284           tpairs = tpairs,
  1285           prop = Logic.list_implies (Bs, C)}))
  1286   end;
  1287 
  1288 
  1289 (*For rotate_tac: fast rotation of assumptions of subgoal i*)
  1290 fun rotate_rule k i state =
  1291   let
  1292     val Thm (der, {thy_ref, maxidx, shyps, hyps, prop, ...}) = state;
  1293     val (tpairs, Bs, Bi, C) = dest_state (state, i);
  1294     val params = Term.strip_all_vars Bi
  1295     and rest   = Term.strip_all_body Bi;
  1296     val asms   = Logic.strip_imp_prems rest
  1297     and concl  = Logic.strip_imp_concl rest;
  1298     val n = length asms;
  1299     val m = if k < 0 then n + k else k;
  1300     val Bi' =
  1301       if 0 = m orelse m = n then Bi
  1302       else if 0 < m andalso m < n then
  1303         let val (ps, qs) = chop m asms
  1304         in list_all (params, Logic.list_implies (qs @ ps, concl)) end
  1305       else raise THM ("rotate_rule", k, [state]);
  1306   in
  1307     Thm (deriv_rule1 (Pt.rotate_proof Bs Bi m) der,
  1308      {thy_ref = thy_ref,
  1309       tags = [],
  1310       maxidx = maxidx,
  1311       shyps = shyps,
  1312       hyps = hyps,
  1313       tpairs = tpairs,
  1314       prop = Logic.list_implies (Bs @ [Bi'], C)})
  1315   end;
  1316 
  1317 
  1318 (*Rotates a rule's premises to the left by k, leaving the first j premises
  1319   unchanged.  Does nothing if k=0 or if k equals n-j, where n is the
  1320   number of premises.  Useful with etac and underlies defer_tac*)
  1321 fun permute_prems j k rl =
  1322   let
  1323     val Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...}) = rl;
  1324     val prems = Logic.strip_imp_prems prop
  1325     and concl = Logic.strip_imp_concl prop;
  1326     val moved_prems = List.drop (prems, j)
  1327     and fixed_prems = List.take (prems, j)
  1328       handle Subscript => raise THM ("permute_prems: j", j, [rl]);
  1329     val n_j = length moved_prems;
  1330     val m = if k < 0 then n_j + k else k;
  1331     val prop' =
  1332       if 0 = m orelse m = n_j then prop
  1333       else if 0 < m andalso m < n_j then
  1334         let val (ps, qs) = chop m moved_prems
  1335         in Logic.list_implies (fixed_prems @ qs @ ps, concl) end
  1336       else raise THM ("permute_prems: k", k, [rl]);
  1337   in
  1338     Thm (deriv_rule1 (Pt.permute_prems_prf prems j m) der,
  1339      {thy_ref = thy_ref,
  1340       tags = [],
  1341       maxidx = maxidx,
  1342       shyps = shyps,
  1343       hyps = hyps,
  1344       tpairs = tpairs,
  1345       prop = prop'})
  1346   end;
  1347 
  1348 
  1349 (** User renaming of parameters in a subgoal **)
  1350 
  1351 (*Calls error rather than raising an exception because it is intended
  1352   for top-level use -- exception handling would not make sense here.
  1353   The names in cs, if distinct, are used for the innermost parameters;
  1354   preceding parameters may be renamed to make all params distinct.*)
  1355 fun rename_params_rule (cs, i) state =
  1356   let
  1357     val Thm (der, {thy_ref, tags, maxidx, shyps, hyps, ...}) = state;
  1358     val (tpairs, Bs, Bi, C) = dest_state (state, i);
  1359     val iparams = map #1 (Logic.strip_params Bi);
  1360     val short = length iparams - length cs;
  1361     val newnames =
  1362       if short < 0 then error "More names than abstractions!"
  1363       else Name.variant_list cs (Library.take (short, iparams)) @ cs;
  1364     val freenames = Term.fold_aterms (fn Free (x, _) => insert (op =) x | _ => I) Bi [];
  1365     val newBi = Logic.list_rename_params (newnames, Bi);
  1366   in
  1367     (case duplicates (op =) cs of
  1368       a :: _ => (warning ("Can't rename.  Bound variables not distinct: " ^ a); state)
  1369     | [] =>
  1370       (case cs inter_string freenames of
  1371         a :: _ => (warning ("Can't rename.  Bound/Free variable clash: " ^ a); state)
  1372       | [] =>
  1373         Thm (der,
  1374          {thy_ref = thy_ref,
  1375           tags = tags,
  1376           maxidx = maxidx,
  1377           shyps = shyps,
  1378           hyps = hyps,
  1379           tpairs = tpairs,
  1380           prop = Logic.list_implies (Bs @ [newBi], C)})))
  1381   end;
  1382 
  1383 
  1384 (*** Preservation of bound variable names ***)
  1385 
  1386 fun rename_boundvars pat obj (thm as Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
  1387   (case Term.rename_abs pat obj prop of
  1388     NONE => thm
  1389   | SOME prop' => Thm (der,
  1390       {thy_ref = thy_ref,
  1391        tags = tags,
  1392        maxidx = maxidx,
  1393        hyps = hyps,
  1394        shyps = shyps,
  1395        tpairs = tpairs,
  1396        prop = prop'}));
  1397 
  1398 
  1399 (* strip_apply f (A, B) strips off all assumptions/parameters from A
  1400    introduced by lifting over B, and applies f to remaining part of A*)
  1401 fun strip_apply f =
  1402   let fun strip(Const("==>",_)$ A1 $ B1,
  1403                 Const("==>",_)$ _  $ B2) = Logic.mk_implies (A1, strip(B1,B2))
  1404         | strip((c as Const("all",_)) $ Abs(a,T,t1),
  1405                       Const("all",_)  $ Abs(_,_,t2)) = c$Abs(a,T,strip(t1,t2))
  1406         | strip(A,_) = f A
  1407   in strip end;
  1408 
  1409 (*Use the alist to rename all bound variables and some unknowns in a term
  1410   dpairs = current disagreement pairs;  tpairs = permanent ones (flexflex);
  1411   Preserves unknowns in tpairs and on lhs of dpairs. *)
  1412 fun rename_bvs([],_,_,_) = I
  1413   | rename_bvs(al,dpairs,tpairs,B) =
  1414       let
  1415         val add_var = fold_aterms (fn Var ((x, _), _) => insert (op =) x | _ => I);
  1416         val vids = []
  1417           |> fold (add_var o fst) dpairs
  1418           |> fold (add_var o fst) tpairs
  1419           |> fold (add_var o snd) tpairs;
  1420         (*unknowns appearing elsewhere be preserved!*)
  1421         fun rename(t as Var((x,i),T)) =
  1422               (case AList.lookup (op =) al x of
  1423                 SOME y =>
  1424                   if member (op =) vids x orelse member (op =) vids y then t
  1425                   else Var((y,i),T)
  1426               | NONE=> t)
  1427           | rename(Abs(x,T,t)) =
  1428               Abs (the_default x (AList.lookup (op =) al x), T, rename t)
  1429           | rename(f$t) = rename f $ rename t
  1430           | rename(t) = t;
  1431         fun strip_ren Ai = strip_apply rename (Ai,B)
  1432       in strip_ren end;
  1433 
  1434 (*Function to rename bounds/unknowns in the argument, lifted over B*)
  1435 fun rename_bvars(dpairs, tpairs, B) =
  1436         rename_bvs(List.foldr Term.match_bvars [] dpairs, dpairs, tpairs, B);
  1437 
  1438 
  1439 (*** RESOLUTION ***)
  1440 
  1441 (** Lifting optimizations **)
  1442 
  1443 (*strip off pairs of assumptions/parameters in parallel -- they are
  1444   identical because of lifting*)
  1445 fun strip_assums2 (Const("==>", _) $ _ $ B1,
  1446                    Const("==>", _) $ _ $ B2) = strip_assums2 (B1,B2)
  1447   | strip_assums2 (Const("all",_)$Abs(a,T,t1),
  1448                    Const("all",_)$Abs(_,_,t2)) =
  1449       let val (B1,B2) = strip_assums2 (t1,t2)
  1450       in  (Abs(a,T,B1), Abs(a,T,B2))  end
  1451   | strip_assums2 BB = BB;
  1452 
  1453 
  1454 (*Faster normalization: skip assumptions that were lifted over*)
  1455 fun norm_term_skip env 0 t = Envir.norm_term env t
  1456   | norm_term_skip env n (Const("all",_)$Abs(a,T,t)) =
  1457         let val Envir.Envir{iTs, ...} = env
  1458             val T' = Envir.typ_subst_TVars iTs T
  1459             (*Must instantiate types of parameters because they are flattened;
  1460               this could be a NEW parameter*)
  1461         in Term.all T' $ Abs(a, T', norm_term_skip env n t)  end
  1462   | norm_term_skip env n (Const("==>", _) $ A $ B) =
  1463         Logic.mk_implies (A, norm_term_skip env (n-1) B)
  1464   | norm_term_skip env n t = error"norm_term_skip: too few assumptions??";
  1465 
  1466 
  1467 (*Composition of object rule r=(A1...Am/B) with proof state s=(B1...Bn/C)
  1468   Unifies B with Bi, replacing subgoal i    (1 <= i <= n)
  1469   If match then forbid instantiations in proof state
  1470   If lifted then shorten the dpair using strip_assums2.
  1471   If eres_flg then simultaneously proves A1 by assumption.
  1472   nsubgoal is the number of new subgoals (written m above).
  1473   Curried so that resolution calls dest_state only once.
  1474 *)
  1475 local exception COMPOSE
  1476 in
  1477 fun bicompose_aux flatten match (state, (stpairs, Bs, Bi, C), lifted)
  1478                         (eres_flg, orule, nsubgoal) =
  1479  let val Thm (sder, {maxidx=smax, shyps=sshyps, hyps=shyps, ...}) = state
  1480      and Thm (rder, {maxidx=rmax, shyps=rshyps, hyps=rhyps,
  1481              tpairs=rtpairs, prop=rprop,...}) = orule
  1482          (*How many hyps to skip over during normalization*)
  1483      and nlift = Logic.count_prems (strip_all_body Bi) + (if eres_flg then ~1 else 0)
  1484      val thy = Theory.deref (merge_thys2 state orule);
  1485      (** Add new theorem with prop = '[| Bs; As |] ==> C' to thq **)
  1486      fun addth A (As, oldAs, rder', n) ((env as Envir.Envir {maxidx, ...}, tpairs), thq) =
  1487        let val normt = Envir.norm_term env;
  1488            (*perform minimal copying here by examining env*)
  1489            val (ntpairs, normp) =
  1490              if Envir.is_empty env then (tpairs, (Bs @ As, C))
  1491              else
  1492              let val ntps = map (pairself normt) tpairs
  1493              in if Envir.above env smax then
  1494                   (*no assignments in state; normalize the rule only*)
  1495                   if lifted
  1496                   then (ntps, (Bs @ map (norm_term_skip env nlift) As, C))
  1497                   else (ntps, (Bs @ map normt As, C))
  1498                 else if match then raise COMPOSE
  1499                 else (*normalize the new rule fully*)
  1500                   (ntps, (map normt (Bs @ As), normt C))
  1501              end
  1502            val th =
  1503              Thm (deriv_rule2
  1504                    ((if Envir.is_empty env then I
  1505                      else if Envir.above env smax then
  1506                        (fn f => fn der => f (Pt.norm_proof' env der))
  1507                      else
  1508                        curry op oo (Pt.norm_proof' env))
  1509                     (Pt.bicompose_proof flatten Bs oldAs As A n (nlift+1))) rder' sder,
  1510                 {tags = [],
  1511                  maxidx = maxidx,
  1512                  shyps = Envir.insert_sorts env (Sorts.union rshyps sshyps),
  1513                  hyps = union_hyps rhyps shyps,
  1514                  tpairs = ntpairs,
  1515                  prop = Logic.list_implies normp,
  1516                  thy_ref = Theory.check_thy thy})
  1517         in  Seq.cons th thq  end  handle COMPOSE => thq;
  1518      val (rAs,B) = Logic.strip_prems(nsubgoal, [], rprop)
  1519        handle TERM _ => raise THM("bicompose: rule", 0, [orule,state]);
  1520      (*Modify assumptions, deleting n-th if n>0 for e-resolution*)
  1521      fun newAs(As0, n, dpairs, tpairs) =
  1522        let val (As1, rder') =
  1523          if not lifted then (As0, rder)
  1524          else (map (rename_bvars(dpairs,tpairs,B)) As0,
  1525            deriv_rule1 (Pt.map_proof_terms
  1526              (rename_bvars (dpairs, tpairs, Bound 0)) I) rder);
  1527        in (map (if flatten then (Logic.flatten_params n) else I) As1, As1, rder', n)
  1528           handle TERM _ =>
  1529           raise THM("bicompose: 1st premise", 0, [orule])
  1530        end;
  1531      val env = Envir.empty(Int.max(rmax,smax));
  1532      val BBi = if lifted then strip_assums2(B,Bi) else (B,Bi);
  1533      val dpairs = BBi :: (rtpairs@stpairs);
  1534      (*elim-resolution: try each assumption in turn.  Initially n=1*)
  1535      fun tryasms (_, _, _, []) = Seq.empty
  1536        | tryasms (A, As, n, (t,u)::apairs) =
  1537           (case Seq.pull(Unify.unifiers(thy, env, (t,u)::dpairs))  of
  1538               NONE                   => tryasms (A, As, n+1, apairs)
  1539             | cell as SOME((_,tpairs),_) =>
  1540                 Seq.it_right (addth A (newAs(As, n, [BBi,(u,t)], tpairs)))
  1541                     (Seq.make(fn()=> cell),
  1542                      Seq.make(fn()=> Seq.pull (tryasms(A, As, n+1, apairs)))))
  1543      fun eres [] = raise THM("bicompose: no premises", 0, [orule,state])
  1544        | eres (A1::As) = tryasms(SOME A1, As, 1, Logic.assum_pairs(nlift+1,A1))
  1545      (*ordinary resolution*)
  1546      fun res(NONE) = Seq.empty
  1547        | res(cell as SOME((_,tpairs),_)) =
  1548              Seq.it_right (addth NONE (newAs(rev rAs, 0, [BBi], tpairs)))
  1549                        (Seq.make (fn()=> cell), Seq.empty)
  1550  in  if eres_flg then eres(rev rAs)
  1551      else res(Seq.pull(Unify.unifiers(thy, env, dpairs)))
  1552  end;
  1553 end;
  1554 
  1555 fun compose_no_flatten match (orule, nsubgoal) i state =
  1556   bicompose_aux false match (state, dest_state (state, i), false) (false, orule, nsubgoal);
  1557 
  1558 fun bicompose match arg i state =
  1559   bicompose_aux true match (state, dest_state (state,i), false) arg;
  1560 
  1561 (*Quick test whether rule is resolvable with the subgoal with hyps Hs
  1562   and conclusion B.  If eres_flg then checks 1st premise of rule also*)
  1563 fun could_bires (Hs, B, eres_flg, rule) =
  1564     let fun could_reshyp (A1::_) = exists (fn H => Term.could_unify (A1, H)) Hs
  1565           | could_reshyp [] = false;  (*no premise -- illegal*)
  1566     in  Term.could_unify(concl_of rule, B) andalso
  1567         (not eres_flg  orelse  could_reshyp (prems_of rule))
  1568     end;
  1569 
  1570 (*Bi-resolution of a state with a list of (flag,rule) pairs.
  1571   Puts the rule above:  rule/state.  Renames vars in the rules. *)
  1572 fun biresolution match brules i state =
  1573     let val (stpairs, Bs, Bi, C) = dest_state(state,i);
  1574         val lift = lift_rule (cprem_of state i);
  1575         val B = Logic.strip_assums_concl Bi;
  1576         val Hs = Logic.strip_assums_hyp Bi;
  1577         val compose = bicompose_aux true match (state, (stpairs, Bs, Bi, C), true);
  1578         fun res [] = Seq.empty
  1579           | res ((eres_flg, rule)::brules) =
  1580               if !Pattern.trace_unify_fail orelse
  1581                  could_bires (Hs, B, eres_flg, rule)
  1582               then Seq.make (*delay processing remainder till needed*)
  1583                   (fn()=> SOME(compose (eres_flg, lift rule, nprems_of rule),
  1584                                res brules))
  1585               else res brules
  1586     in  Seq.flat (res brules)  end;
  1587 
  1588 
  1589 
  1590 (*** Future theorems -- proofs with promises ***)
  1591 
  1592 (* future rule *)
  1593 
  1594 fun future_result i orig_thy orig_shyps orig_prop raw_thm =
  1595   let
  1596     val _ = Theory.check_thy orig_thy;
  1597     val thm = strip_shyps (transfer orig_thy raw_thm);
  1598     val _ = Theory.check_thy orig_thy;
  1599     fun err msg = raise THM ("future_result: " ^ msg, 0, [thm]);
  1600 
  1601     val Thm (Deriv {max_promise, ...}, {shyps, hyps, tpairs, prop, ...}) = thm;
  1602     val _ = prop aconv orig_prop orelse err "bad prop";
  1603     val _ = null tpairs orelse err "bad tpairs";
  1604     val _ = null hyps orelse err "bad hyps";
  1605     val _ = Sorts.subset (shyps, orig_shyps) orelse err "bad shyps";
  1606     val _ = max_promise < i orelse err "bad dependencies";
  1607   in thm end;
  1608 
  1609 fun future future_thm ct =
  1610   let
  1611     val Cterm {thy_ref = thy_ref, t = prop, T, maxidx, sorts} = ct;
  1612     val thy = Context.reject_draft (Theory.deref thy_ref);
  1613     val _ = T <> propT andalso raise CTERM ("future: prop expected", [ct]);
  1614 
  1615     val i = serial ();
  1616     val future = future_thm |> Future.map (future_result i thy sorts prop);
  1617     val promise = (i, future);
  1618   in
  1619     Thm (make_deriv i [promise] [promise] [] [] (Pt.promise_proof thy i prop),
  1620      {thy_ref = thy_ref,
  1621       tags = [],
  1622       maxidx = maxidx,
  1623       shyps = sorts,
  1624       hyps = [],
  1625       tpairs = [],
  1626       prop = prop})
  1627   end;
  1628 
  1629 
  1630 (* pending task groups *)
  1631 
  1632 fun pending_groups (Thm (Deriv {open_promises, ...}, _)) =
  1633   fold (insert Task_Queue.eq_group o Future.group_of o #2) open_promises;
  1634 
  1635 
  1636 (* fulfilled proofs *)
  1637 
  1638 fun raw_proof_of (Thm (Deriv {body, ...}, _)) = Proofterm.proof_of body;
  1639 
  1640 fun proof_body_of (Thm (Deriv {open_promises, promises, body, ...}, {thy_ref, ...})) =
  1641   let
  1642     val _ = Exn.release_all (map (Future.join_result o #2) (rev open_promises));
  1643     val ps = map (apsnd (raw_proof_of o Future.join)) promises;
  1644   in Pt.fulfill_proof (Theory.deref thy_ref) ps body end;
  1645 
  1646 val proof_of = Proofterm.proof_of o proof_body_of;
  1647 val join_proof = ignore o proof_body_of;
  1648 
  1649 
  1650 (* closed derivations with official name *)
  1651 
  1652 fun get_name thm =
  1653   Pt.get_name (hyps_of thm) (prop_of thm) (raw_proof_of thm);
  1654 
  1655 fun put_name name (thm as Thm (der, args)) =
  1656   let
  1657     val Deriv {max_promise, open_promises, promises, body, ...} = der;
  1658     val {thy_ref, hyps, prop, tpairs, ...} = args;
  1659     val _ = null tpairs orelse raise THM ("put_name: unsolved flex-flex constraints", 0, [thm]);
  1660 
  1661     val ps = map (apsnd (Future.map proof_of)) promises;
  1662     val thy = Theory.deref thy_ref;
  1663     val (pthm, proof) = Pt.thm_proof thy name hyps prop ps body;
  1664 
  1665     val open_promises' = open_promises |> filter (fn (_, p) =>
  1666       (case Future.peek p of SOME (Exn.Result _) => false | _ => true));
  1667     val der' = make_deriv max_promise open_promises' [] [] [pthm] proof;
  1668     val _ = Theory.check_thy thy;
  1669   in Thm (der', args) end;
  1670 
  1671 
  1672 
  1673 (*** Oracles ***)
  1674 
  1675 (* oracle rule *)
  1676 
  1677 fun invoke_oracle thy_ref1 name oracle arg =
  1678   let val Cterm {thy_ref = thy_ref2, t = prop, T, maxidx, sorts} = oracle arg in
  1679     if T <> propT then
  1680       raise THM ("Oracle's result must have type prop: " ^ name, 0, [])
  1681     else
  1682       let val prf = Pt.oracle_proof name prop in
  1683         Thm (make_deriv ~1 [] [] (Pt.make_oracles prf) [] prf,
  1684          {thy_ref = Theory.merge_refs (thy_ref1, thy_ref2),
  1685           tags = [],
  1686           maxidx = maxidx,
  1687           shyps = sorts,
  1688           hyps = [],
  1689           tpairs = [],
  1690           prop = prop})
  1691       end
  1692   end;
  1693 
  1694 
  1695 (* authentic derivation names *)
  1696 
  1697 fun err_dup_ora dup = error ("Duplicate oracle: " ^ quote dup);
  1698 
  1699 structure Oracles = TheoryDataFun
  1700 (
  1701   type T = serial NameSpace.table;
  1702   val empty = NameSpace.empty_table;
  1703   val copy = I;
  1704   val extend = I;
  1705   fun merge _ oracles : T = NameSpace.merge_tables (op =) oracles
  1706     handle Symtab.DUP dup => err_dup_ora dup;
  1707 );
  1708 
  1709 val extern_oracles = map #1 o NameSpace.extern_table o Oracles.get;
  1710 
  1711 fun add_oracle (b, oracle) thy =
  1712   let
  1713     val naming = Sign.naming_of thy;
  1714     val (name, tab') = NameSpace.bind naming (b, serial ()) (Oracles.get thy)
  1715       handle Symtab.DUP _ => err_dup_ora (Binding.str_of b);
  1716     val thy' = Oracles.put tab' thy;
  1717   in ((name, invoke_oracle (Theory.check_thy thy') name oracle), thy') end;
  1718 
  1719 end;
  1720 
  1721 structure BasicThm: BASIC_THM = Thm;
  1722 open BasicThm;