src/HOL/MicroJava/J/TypeRel.thy
author streckem
Mon May 26 18:36:15 2003 +0200 (2003-05-26)
changeset 14045 a34d89ce6097
parent 13090 4fb7a2f2c1df
child 14134 0fdf5708c7a8
permissions -rw-r--r--
Introduced distinction wf_prog vs. ws_prog
     1 (*  Title:      HOL/MicroJava/J/TypeRel.thy
     2     ID:         $Id$
     3     Author:     David von Oheimb
     4     Copyright   1999 Technische Universitaet Muenchen
     5 *)
     6 
     7 header {* \isaheader{Relations between Java Types} *}
     8 
     9 theory TypeRel = Decl:
    10 
    11 consts
    12   subcls1 :: "'c prog => (cname \<times> cname) set"  -- "subclass"
    13   widen   :: "'c prog => (ty    \<times> ty   ) set"  -- "widening"
    14   cast    :: "'c prog => (ty    \<times> ty   ) set"  -- "casting"
    15 
    16 syntax (xsymbols)
    17   subcls1 :: "'c prog => [cname, cname] => bool" ("_ \<turnstile> _ \<prec>C1 _" [71,71,71] 70)
    18   subcls  :: "'c prog => [cname, cname] => bool" ("_ \<turnstile> _ \<preceq>C _"  [71,71,71] 70)
    19   widen   :: "'c prog => [ty   , ty   ] => bool" ("_ \<turnstile> _ \<preceq> _"   [71,71,71] 70)
    20   cast    :: "'c prog => [ty   , ty   ] => bool" ("_ \<turnstile> _ \<preceq>? _"  [71,71,71] 70)
    21 
    22 syntax
    23   subcls1 :: "'c prog => [cname, cname] => bool" ("_ |- _ <=C1 _" [71,71,71] 70)
    24   subcls  :: "'c prog => [cname, cname] => bool" ("_ |- _ <=C _"  [71,71,71] 70)
    25   widen   :: "'c prog => [ty   , ty   ] => bool" ("_ |- _ <= _"   [71,71,71] 70)
    26   cast    :: "'c prog => [ty   , ty   ] => bool" ("_ |- _ <=? _"  [71,71,71] 70)
    27 
    28 translations
    29   "G\<turnstile>C \<prec>C1 D" == "(C,D) \<in> subcls1 G"
    30   "G\<turnstile>C \<preceq>C  D" == "(C,D) \<in> (subcls1 G)^*"
    31   "G\<turnstile>S \<preceq>   T" == "(S,T) \<in> widen   G"
    32   "G\<turnstile>C \<preceq>?  D" == "(C,D) \<in> cast    G"
    33 
    34 -- "direct subclass, cf. 8.1.3"
    35 inductive "subcls1 G" intros
    36   subcls1I: "\<lbrakk>class G C = Some (D,rest); C \<noteq> Object\<rbrakk> \<Longrightarrow> G\<turnstile>C\<prec>C1D"
    37   
    38 lemma subcls1D: 
    39   "G\<turnstile>C\<prec>C1D \<Longrightarrow> C \<noteq> Object \<and> (\<exists>fs ms. class G C = Some (D,fs,ms))"
    40 apply (erule subcls1.elims)
    41 apply auto
    42 done
    43 
    44 lemma subcls1_def2: 
    45 "subcls1 G = (\<Sigma>C\<in>{C. is_class G C} . {D. C\<noteq>Object \<and> fst (the (class G C))=D})"
    46   by (auto simp add: is_class_def dest: subcls1D intro: subcls1I)
    47 
    48 lemma finite_subcls1: "finite (subcls1 G)"
    49 apply(subst subcls1_def2)
    50 apply(rule finite_SigmaI [OF finite_is_class])
    51 apply(rule_tac B = "{fst (the (class G C))}" in finite_subset)
    52 apply  auto
    53 done
    54 
    55 lemma subcls_is_class: "(C,D) \<in> (subcls1 G)^+ ==> is_class G C"
    56 apply (unfold is_class_def)
    57 apply(erule trancl_trans_induct)
    58 apply (auto dest!: subcls1D)
    59 done
    60 
    61 lemma subcls_is_class2 [rule_format (no_asm)]: 
    62   "G\<turnstile>C\<preceq>C D \<Longrightarrow> is_class G D \<longrightarrow> is_class G C"
    63 apply (unfold is_class_def)
    64 apply (erule rtrancl_induct)
    65 apply  (drule_tac [2] subcls1D)
    66 apply  auto
    67 done
    68 
    69 constdefs
    70   class_rec :: "'c prog \<Rightarrow> cname \<Rightarrow> 'a \<Rightarrow>
    71     (cname \<Rightarrow> fdecl list \<Rightarrow> 'c mdecl list \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> 'a"
    72   "class_rec G == wfrec ((subcls1 G)^-1)
    73     (\<lambda>r C t f. case class G C of
    74          None \<Rightarrow> arbitrary
    75        | Some (D,fs,ms) \<Rightarrow> 
    76            f C fs ms (if C = Object then t else r D t f))"
    77 
    78 lemma class_rec_lemma: "wf ((subcls1 G)^-1) \<Longrightarrow> class G C = Some (D,fs,ms) \<Longrightarrow>
    79  class_rec G C t f = f C fs ms (if C=Object then t else class_rec G D t f)"
    80   by (simp add: class_rec_def wfrec cut_apply [OF converseI [OF subcls1I]])
    81 
    82 consts
    83 
    84   method :: "'c prog \<times> cname => ( sig   \<leadsto> cname \<times> ty \<times> 'c)" (* ###curry *)
    85   field  :: "'c prog \<times> cname => ( vname \<leadsto> cname \<times> ty     )" (* ###curry *)
    86   fields :: "'c prog \<times> cname => ((vname \<times> cname) \<times> ty) list" (* ###curry *)
    87 
    88 -- "methods of a class, with inheritance, overriding and hiding, cf. 8.4.6"
    89 defs method_def: "method \<equiv> \<lambda>(G,C). class_rec G C empty (\<lambda>C fs ms ts.
    90                            ts ++ map_of (map (\<lambda>(s,m). (s,(C,m))) ms))"
    91 
    92 lemma method_rec_lemma: "[|class G C = Some (D,fs,ms); wf ((subcls1 G)^-1)|] ==>
    93   method (G,C) = (if C = Object then empty else method (G,D)) ++  
    94   map_of (map (\<lambda>(s,m). (s,(C,m))) ms)"
    95 apply (unfold method_def)
    96 apply (simp split del: split_if)
    97 apply (erule (1) class_rec_lemma [THEN trans]);
    98 apply auto
    99 done
   100 
   101 
   102 -- "list of fields of a class, including inherited and hidden ones"
   103 defs fields_def: "fields \<equiv> \<lambda>(G,C). class_rec G C []    (\<lambda>C fs ms ts.
   104                            map (\<lambda>(fn,ft). ((fn,C),ft)) fs @ ts)"
   105 
   106 lemma fields_rec_lemma: "[|class G C = Some (D,fs,ms); wf ((subcls1 G)^-1)|] ==>
   107  fields (G,C) = 
   108   map (\<lambda>(fn,ft). ((fn,C),ft)) fs @ (if C = Object then [] else fields (G,D))"
   109 apply (unfold fields_def)
   110 apply (simp split del: split_if)
   111 apply (erule (1) class_rec_lemma [THEN trans]);
   112 apply auto
   113 done
   114 
   115 
   116 defs field_def: "field == map_of o (map (\<lambda>((fn,fd),ft). (fn,(fd,ft)))) o fields"
   117 
   118 lemma field_fields: 
   119 "field (G,C) fn = Some (fd, fT) \<Longrightarrow> map_of (fields (G,C)) (fn, fd) = Some fT"
   120 apply (unfold field_def)
   121 apply (rule table_of_remap_SomeD)
   122 apply simp
   123 done
   124 
   125 
   126 -- "widening, viz. method invocation conversion,cf. 5.3 i.e. sort of syntactic subtyping"
   127 inductive "widen G" intros 
   128   refl   [intro!, simp]:       "G\<turnstile>      T \<preceq> T"   -- "identity conv., cf. 5.1.1"
   129   subcls         : "G\<turnstile>C\<preceq>C D ==> G\<turnstile>Class C \<preceq> Class D"
   130   null   [intro!]:             "G\<turnstile>     NT \<preceq> RefT R"
   131 
   132 -- "casting conversion, cf. 5.5 / 5.1.5"
   133 -- "left out casts on primitve types"
   134 inductive "cast G" intros
   135   widen:  "G\<turnstile> C\<preceq> D ==> G\<turnstile>C \<preceq>? D"
   136   subcls: "G\<turnstile> D\<preceq>C C ==> G\<turnstile>Class C \<preceq>? Class D"
   137 
   138 lemma widen_PrimT_RefT [iff]: "(G\<turnstile>PrimT pT\<preceq>RefT rT) = False"
   139 apply (rule iffI)
   140 apply (erule widen.elims)
   141 apply auto
   142 done
   143 
   144 lemma widen_RefT: "G\<turnstile>RefT R\<preceq>T ==> \<exists>t. T=RefT t"
   145 apply (ind_cases "G\<turnstile>S\<preceq>T")
   146 apply auto
   147 done
   148 
   149 lemma widen_RefT2: "G\<turnstile>S\<preceq>RefT R ==> \<exists>t. S=RefT t"
   150 apply (ind_cases "G\<turnstile>S\<preceq>T")
   151 apply auto
   152 done
   153 
   154 lemma widen_Class: "G\<turnstile>Class C\<preceq>T ==> \<exists>D. T=Class D"
   155 apply (ind_cases "G\<turnstile>S\<preceq>T")
   156 apply auto
   157 done
   158 
   159 lemma widen_Class_NullT [iff]: "(G\<turnstile>Class C\<preceq>NT) = False"
   160 apply (rule iffI)
   161 apply (ind_cases "G\<turnstile>S\<preceq>T")
   162 apply auto
   163 done
   164 
   165 lemma widen_Class_Class [iff]: "(G\<turnstile>Class C\<preceq> Class D) = (G\<turnstile>C\<preceq>C D)"
   166 apply (rule iffI)
   167 apply (ind_cases "G\<turnstile>S\<preceq>T")
   168 apply (auto elim: widen.subcls)
   169 done
   170 
   171 lemma widen_NT_Class [simp]: "G \<turnstile> T \<preceq> NT \<Longrightarrow> G \<turnstile> T \<preceq> Class D"
   172 by (ind_cases "G \<turnstile> T \<preceq> NT",  auto)
   173 
   174 lemma cast_PrimT_RefT [iff]: "(G\<turnstile>PrimT pT\<preceq>? RefT rT) = False"
   175 apply (rule iffI)
   176 apply (erule cast.elims)
   177 apply auto
   178 done
   179 
   180 lemma cast_RefT: "G \<turnstile> C \<preceq>? Class D \<Longrightarrow> \<exists> rT. C = RefT rT"
   181 apply (erule cast.cases)
   182 apply simp apply (erule widen.cases) 
   183 apply auto
   184 done
   185 
   186 theorem widen_trans[trans]: "\<lbrakk>G\<turnstile>S\<preceq>U; G\<turnstile>U\<preceq>T\<rbrakk> \<Longrightarrow> G\<turnstile>S\<preceq>T"
   187 proof -
   188   assume "G\<turnstile>S\<preceq>U" thus "\<And>T. G\<turnstile>U\<preceq>T \<Longrightarrow> G\<turnstile>S\<preceq>T"
   189   proof induct
   190     case (refl T T') thus "G\<turnstile>T\<preceq>T'" .
   191   next
   192     case (subcls C D T)
   193     then obtain E where "T = Class E" by (blast dest: widen_Class)
   194     with subcls show "G\<turnstile>Class C\<preceq>T" by (auto elim: rtrancl_trans)
   195   next
   196     case (null R RT)
   197     then obtain rt where "RT = RefT rt" by (blast dest: widen_RefT)
   198     thus "G\<turnstile>NT\<preceq>RT" by auto
   199   qed
   200 qed
   201 
   202 end