src/Pure/pattern.ML
author nipkow
Thu Oct 10 19:02:23 2002 +0200 (2002-10-10)
changeset 13642 a3d97348ceb6
parent 13195 98975cc13d28
child 13645 430310b12c5b
permissions -rw-r--r--
added failure trace information to pattern unification
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 
     6 Unification of Higher-Order Patterns.
     7 
     8 See also:
     9 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
    10 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    11 
    12 TODO: optimize red by special-casing it
    13 *)
    14 
    15 infix aeconv;
    16 
    17 signature PATTERN =
    18   sig
    19   type type_sig
    20   type sg
    21   type env
    22   val trace_unify_fail  : bool ref
    23   val aeconv            : term * term -> bool
    24   val eta_contract      : term -> term
    25   val beta_eta_contract : term -> term
    26   val eta_contract_atom : term -> term
    27   val match             : type_sig -> term * term
    28                           -> (indexname*typ)list * (indexname*term)list
    29   val first_order_match : type_sig -> term * term
    30                           -> (indexname*typ)list * (indexname*term)list
    31   val matches           : type_sig -> term * term -> bool
    32   val matches_subterm   : type_sig -> term * term -> bool
    33   val unify             : sg * env * (term * term)list -> env
    34   val first_order       : term -> bool
    35   val pattern           : term -> bool
    36   val rewrite_term      : type_sig -> (term * term) list -> (term -> term option) list
    37                           -> term -> term
    38   exception Unif
    39   exception MATCH
    40   exception Pattern
    41   end;
    42 
    43 structure Pattern : PATTERN =
    44 struct
    45 
    46 type type_sig = Type.type_sig
    47 type sg = Sign.sg
    48 type env = Envir.env
    49 
    50 exception Unif;
    51 exception Pattern;
    52 
    53 val trace_unify_fail = ref false;
    54 
    55 (* Only for communication between unification and error message printing *)
    56 val sgr = ref Sign.pre_pure
    57 
    58 fun string_of_term env binders t = Sign.string_of_term (!sgr)
    59   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    60 
    61 fun bname binders i = fst(nth_elem(i,binders));
    62 fun bnames binders is = space_implode " " (map (bname binders) is);
    63 
    64 fun norm_typ tye =
    65   let fun chase(v,s) =
    66       (case  Vartab.lookup (tye, v) of
    67         Some U => norm_typ tye U
    68       | None => TVar(v,s))
    69   in map_type_tvar chase end
    70 
    71 fun typ_clash(tye,T,U) =
    72   if !trace_unify_fail
    73   then let val t = Sign.string_of_typ (!sgr) (norm_typ tye T)
    74            and u = Sign.string_of_typ (!sgr) (norm_typ tye U)
    75        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    76   else ()
    77 
    78 fun clash a b =
    79   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    80 
    81 fun boundVar binders i =
    82   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    83 
    84 fun clashBB binders i j =
    85   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    86   else ()
    87 
    88 fun clashB binders i s =
    89   if !trace_unify_fail then clash (boundVar binders i) s
    90   else ()
    91 
    92 fun proj_fail(env,binders,F,is,t) =
    93   if !trace_unify_fail
    94   then let val f = Syntax.string_of_vname F
    95            val xs = bnames binders is
    96            val u = string_of_term env binders t
    97            val ys = bnames binders (loose_bnos t \\ is)
    98        in tracing("Cannot unify variable " ^ f ^
    99                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
   100                "\nTerm contains additional bound variable(s) " ^ ys)
   101        end
   102   else ()
   103 
   104 fun ocheck_fail(F,t,binders,env) =
   105   if !trace_unify_fail
   106   then let val f = Syntax.string_of_vname F
   107            val u = string_of_term env binders t
   108        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
   109                   "\nCannot unify!\n")
   110        end
   111   else ()
   112 
   113 fun occurs(F,t,env) =
   114     let fun occ(Var(G,_))   = (case Envir.lookup(env,G) of
   115                                  Some(t) => occ t
   116                                | None    => F=G)
   117           | occ(t1$t2)      = occ t1 orelse occ t2
   118           | occ(Abs(_,_,t)) = occ t
   119           | occ _           = false
   120     in occ t end;
   121 
   122 
   123 fun mapbnd f =
   124     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   125           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   126           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   127           | mpb _ atom           = atom
   128     in mpb 0 end;
   129 
   130 fun idx [] j     = ~10000
   131   | idx(i::is) j = if i=j then length is else idx is j;
   132 
   133 fun at xs i = nth_elem (i,xs);
   134 
   135 fun mkabs (binders,is,t)  =
   136     let fun mk(i::is) = let val (x,T) = nth_elem(i,binders)
   137                         in Abs(x,T,mk is) end
   138           | mk []     = t
   139     in mk is end;
   140 
   141 val incr = mapbnd (fn i => i+1);
   142 
   143 fun ints_of []             = []
   144   | ints_of (Bound i ::bs) =
   145       let val is = ints_of bs
   146       in if i mem_int is then raise Pattern else i::is end
   147   | ints_of _              = raise Pattern;
   148 
   149 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   150 
   151 
   152 fun app (s,(i::is)) = app (s$Bound(i),is)
   153   | app (s,[])      = s;
   154 
   155 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   156   | red t            []      [] = t
   157   | red t            is      jn = app (mapbnd (at jn) t,is);
   158 
   159 
   160 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   161 fun split_type (T,0,Ts)                    = (Ts,T)
   162   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   163   | split_type _                           = error("split_type");
   164 
   165 fun type_of_G (T,n,is) =
   166   let val (Ts,U) = split_type(T,n,[]) in map(at Ts)is ---> U end;
   167 
   168 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   169 
   170 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   171   let val (env',G) = Envir.genvar a (env,type_of_G(T,length is,js))
   172   in Envir.update((F,mkhnf(binders,is,G,js)),env') end;
   173 
   174 
   175 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   176 fun mk_proj_list is =
   177     let fun mk(i::is,j) = if i >= 0 then j :: mk(is,j-1) else mk(is,j-1)
   178           | mk([],_)    = []
   179     in mk(is,length is - 1) end;
   180 
   181 fun proj(s,env,binders,is) =
   182     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   183         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   184               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   185                             in (Abs(a,T,t'),env') end
   186             | t => (case strip_comb t of
   187                 (c as Const _,ts) =>
   188                          let val (ts',env') = prs(ts,env,d,binders)
   189                          in (list_comb(c,ts'),env') end
   190                  | (f as Free _,ts) =>
   191                          let val (ts',env') = prs(ts,env,d,binders)
   192                          in (list_comb(f,ts'),env') end
   193                  | (Bound(i),ts) =>
   194                          let val j = trans d i
   195                          in if j < 0 then raise Unif
   196                             else let val (ts',env') = prs(ts,env,d,binders)
   197                                  in (list_comb(Bound j,ts'),env') end
   198                          end
   199                  | (Var(F as (a,_),Fty),ts) =>
   200                       let val js = ints_of' env ts;
   201                           val js' = map (trans d) js;
   202                           val ks = mk_proj_list js';
   203                           val ls = filter (fn i => i >= 0) js'
   204                           val Hty = type_of_G(Fty,length js,ks)
   205                           val (env',H) = Envir.genvar a (env,Hty)
   206                           val env'' =
   207                                 Envir.update((F,mkhnf(binders,js,H,ks)),env')
   208                       in (app(H,ls),env'') end
   209                  | _  => raise Pattern))
   210         and prs(s::ss,env,d,binders) =
   211               let val (s',env1) = pr(s,env,d,binders)
   212                   val (ss',env2) = prs(ss,env1,d,binders)
   213               in (s'::ss',env2) end
   214           | prs([],env,_,_) = ([],env)
   215    in if downto0(is,length binders - 1) then (s,env)
   216       else pr(s,env,0,binders)
   217    end;
   218 
   219 
   220 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   221 fun mk_ff_list(is,js) =
   222     let fun mk([],[],_)        = []
   223           | mk(i::is,j::js, k) = if i=j then k :: mk(is,js,k-1)
   224                                         else mk(is,js,k-1)
   225           | mk _               = error"mk_ff_list"
   226     in mk(is,js,length is-1) end;
   227 
   228 fun flexflex1(env,binders,F,Fty,is,js) =
   229   if is=js then env
   230   else let val ks = mk_ff_list(is,js)
   231        in mknewhnf(env,binders,is,F,Fty,ks) end;
   232 
   233 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   234   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   235             if js subset_int is
   236             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   237                  in Envir.update((F,t),env) end
   238             else let val ks = is inter_int js
   239                      val Hty = type_of_G(Fty,length is,map (idx is) ks)
   240                      val (env',H) = Envir.genvar a (env,Hty)
   241                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   242                  in Envir.update((G,lam js), Envir.update((F,lam is),env'))
   243                  end;
   244   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   245 
   246 val tsgr = ref(Type.tsig0);
   247 
   248 fun unify_types(T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   249   if T=U then env
   250   else let val (iTs',maxidx') = Type.unify (!tsgr) (iTs, maxidx) (U, T)
   251        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   252        handle Type.TUNIFY => (typ_clash(iTs,T,U); raise Unif);
   253 
   254 fun unif binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   255       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   256          let val name = if ns = "" then nt else ns
   257          in unif ((name,Ts)::binders) (env,(ts,tt)) end
   258     | (Abs(ns,Ts,ts),t) => unif ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   259     | (t,Abs(nt,Tt,tt)) => unif ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   260     | p => cases(binders,env,p)
   261 
   262 and cases(binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   263        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   264          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   265                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   266       | ((Var(F,_),ss),_)             => flexrigid(env,binders,F,ints_of' env ss,t)
   267       | (_,(Var(F,_),ts))             => flexrigid(env,binders,F,ints_of' env ts,s)
   268       | ((Const c,ss),(Const d,ts))   => rigidrigid(env,binders,c,d,ss,ts)
   269       | ((Free(f),ss),(Free(g),ts))   => rigidrigid(env,binders,f,g,ss,ts)
   270       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB (env,binders,i,j,ss,ts)
   271       | ((Abs(_),_),_)                => raise Pattern
   272       | (_,(Abs(_),_))                => raise Pattern
   273       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   274       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   275       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   276       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   277       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   278       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   279 
   280 
   281 and rigidrigid (env,binders,(a,Ta),(b,Tb),ss,ts) =
   282       if a<>b then (clash a b; raise Unif)
   283       else foldl (unif binders) (unify_types(Ta,Tb,env), ss~~ts)
   284 
   285 and rigidrigidB (env,binders,i,j,ss,ts) =
   286      if i <> j then (clashBB binders i j; raise Unif)
   287      else foldl (unif binders) (env ,ss~~ts)
   288 
   289 and flexrigid (params as (env,binders,F,is,t)) =
   290       if occurs(F,t,env) then (ocheck_fail(F,t,binders,env); raise Unif)
   291       else (let val (u,env') = proj(t,env,binders,is)
   292             in Envir.update((F,mkabs(binders,is,u)),env') end
   293             handle Unif => (proj_fail params; raise Unif));
   294 
   295 fun unify(sg,env,tus) = (sgr := sg; tsgr := #tsig(Sign.rep_sg sg);
   296                          foldl (unif []) (env,tus));
   297 
   298 
   299 (*Eta-contract a term (fully)*)
   300 
   301 fun eta_contract t =
   302   let
   303     exception SAME;
   304     fun eta (Abs (a, T, body)) = 
   305       ((case eta body of
   306           body' as (f $ Bound 0) => 
   307 	    if loose_bvar1 (f, 0) then Abs(a, T, body')
   308 	    else incr_boundvars ~1 f
   309         | body' => Abs (a, T, body')) handle SAME =>
   310        (case body of
   311           (f $ Bound 0) => 
   312 	    if loose_bvar1 (f, 0) then raise SAME
   313 	    else incr_boundvars ~1 f
   314         | _ => raise SAME))
   315       | eta (f $ t) =
   316           (let val f' = eta f
   317            in f' $ etah t end handle SAME => f $ eta t)
   318       | eta _ = raise SAME
   319     and etah t = (eta t handle SAME => t)
   320   in etah t end;
   321 
   322 val beta_eta_contract = eta_contract o Envir.beta_norm;
   323 
   324 (*Eta-contract a term from outside: just enough to reduce it to an atom
   325 DOESN'T QUITE WORK!
   326 *)
   327 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   328       (case  eta_contract2 body  of
   329         body' as (f $ Bound 0) =>
   330             if loose_bvar1(f,0) then Abs(a,T,body')
   331             else eta_contract_atom (incr_boundvars ~1 f)
   332       | _ => t0)
   333   | eta_contract_atom t = t
   334 and eta_contract2 (f$t) = f $ eta_contract_atom t
   335   | eta_contract2 t     = eta_contract_atom t;
   336 
   337 
   338 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   339   Note that Consts and Vars may have more than one type.*)
   340 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   341 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   342   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   343   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   344   | aconv_aux (Bound i,    Bound j)    = i=j
   345   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   346   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   347   | aconv_aux _ =  false;
   348 
   349 
   350 (*** Matching ***)
   351 
   352 exception MATCH;
   353 
   354 fun typ_match tsig args = (Type.typ_match tsig args)
   355                           handle Type.TYPE_MATCH => raise MATCH;
   356 
   357 (*First-order matching;
   358   fomatch tsig (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   359   The pattern and object may have variables in common.
   360   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   361   Object is eta-contracted on the fly (by eta-expanding the pattern).
   362   Precondition: the pattern is already eta-contracted!
   363   Note: types are matched on the fly *)
   364 fun fomatch tsig =
   365   let
   366     fun mtch (instsp as (tyinsts,insts)) = fn
   367         (Var(ixn,T), t)  =>
   368           if loose_bvar(t,0) then raise MATCH
   369           else (case assoc_string_int(insts,ixn) of
   370                   None => (typ_match tsig (tyinsts, (T, fastype_of t)),
   371                            (ixn,t)::insts)
   372                 | Some u => if t aeconv u then instsp else raise MATCH)
   373       | (Free (a,T), Free (b,U)) =>
   374           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   375       | (Const (a,T), Const (b,U))  =>
   376           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   377       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   378       | (Abs(_,T,t), Abs(_,U,u))  =>
   379           mtch (typ_match tsig (tyinsts,(T,U)),insts) (t,u)
   380       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   381       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   382       | _ => raise MATCH
   383   in mtch end;
   384 
   385 fun first_order_match tsig = apfst Vartab.dest o fomatch tsig (Vartab.empty, []);
   386 
   387 (* Matching of higher-order patterns *)
   388 
   389 fun match_bind(itms,binders,ixn,is,t) =
   390   let val js = loose_bnos t
   391   in if null is
   392      then if null js then (ixn,t)::itms else raise MATCH
   393      else if js subset_int is
   394           then let val t' = if downto0(is,length binders - 1) then t
   395                             else mapbnd (idx is) t
   396                in (ixn, mkabs(binders,is,t')) :: itms end
   397           else raise MATCH
   398   end;
   399 
   400 fun match tsg (po as (pat,obj)) =
   401 let
   402   (* Pre: pat and obj have same type *)
   403   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   404     case pat of
   405       Abs(ns,Ts,ts) =>
   406         (case obj of
   407            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   408          | _ => let val Tt = typ_subst_TVars_Vartab iTs Ts
   409                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   410     | _ => (case obj of
   411               Abs(nt,Tt,tt) =>
   412                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   413             | _ => cases(binders,env,pat,obj))
   414 
   415   and cases(binders,env as (iTs,itms),pat,obj) =
   416     let val (ph,pargs) = strip_comb pat
   417         fun rigrig1(iTs,oargs) =
   418               foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   419         fun rigrig2((a,Ta),(b,Tb),oargs) =
   420               if a<> b then raise MATCH
   421               else rigrig1(typ_match tsg (iTs,(Ta,Tb)), oargs)
   422     in case ph of
   423          Var(ixn,_) =>
   424            let val is = ints_of pargs
   425            in case assoc_string_int(itms,ixn) of
   426                 None => (iTs,match_bind(itms,binders,ixn,is,obj))
   427               | Some u => if obj aeconv (red u is []) then env
   428                           else raise MATCH
   429            end
   430        | _ =>
   431            let val (oh,oargs) = strip_comb obj
   432            in case (ph,oh) of
   433                 (Const c,Const d) => rigrig2(c,d,oargs)
   434               | (Free f,Free g)   => rigrig2(f,g,oargs)
   435               | (Bound i,Bound j) => if i<>j then raise MATCH
   436                                      else rigrig1(iTs,oargs)
   437               | (Abs _, _)        => raise Pattern
   438               | (_, Abs _)        => raise Pattern
   439               | _                 => raise MATCH
   440            end
   441     end;
   442 
   443   val pT = fastype_of pat
   444   and oT = fastype_of obj
   445   val iTs = typ_match tsg (Vartab.empty, (pT,oT))
   446   val insts2 = (iTs,[])
   447 
   448 in apfst Vartab.dest (mtch [] (insts2, po)
   449    handle Pattern => fomatch tsg insts2 po)
   450 end;
   451 
   452 (*Predicate: does the pattern match the object?*)
   453 fun matches tsig po = (match tsig po; true) handle MATCH => false;
   454 
   455 (* Does pat match a subterm of obj? *)
   456 fun matches_subterm tsig (pat,obj) =
   457   let fun msub(bounds,obj) = matches tsig (pat,obj) orelse
   458             case obj of
   459               Abs(x,T,t) => let val y = variant bounds x
   460                                 val f = Free(":" ^ y,T)
   461                             in msub(x::bounds,subst_bound(f,t)) end
   462             | s$t => msub(bounds,s) orelse msub(bounds,t)
   463             | _ => false
   464   in msub([],obj) end;
   465 
   466 fun first_order(Abs(_,_,t)) = first_order t
   467   | first_order(t $ u) = first_order t andalso first_order u andalso
   468                          not(is_Var t)
   469   | first_order _ = true;
   470 
   471 fun pattern(Abs(_,_,t)) = pattern t
   472   | pattern(t) = let val (head,args) = strip_comb t
   473                  in if is_Var head
   474                     then let val _ = ints_of args in true end
   475                          handle Pattern => false
   476                     else forall pattern args
   477                  end;
   478 
   479 
   480 (* rewriting -- simple but fast *)
   481 
   482 fun rewrite_term tsig rules procs tm =
   483   let
   484     val skel0 = Bound 0;
   485 
   486     val rhs_names =
   487       foldr (fn ((_, rhs), names) => add_term_free_names (rhs, names)) (rules, []);
   488 
   489     fun variant_absfree (x, T, t) =
   490       let
   491         val x' = variant (add_term_free_names (t, rhs_names)) x;
   492         val t' = subst_bound (Free (x', T), t);
   493       in (fn u => Abs (x, T, abstract_over (Free (x', T), u)), t') end;
   494 
   495     fun match_rew tm (tm1, tm2) =
   496       let val rtm = if_none (Term.rename_abs tm1 tm tm2) tm2
   497       in Some (subst_vars (match tsig (tm1, tm)) rtm, rtm)
   498         handle MATCH => None
   499       end;
   500 
   501     fun rew (Abs (_, _, body) $ t) = Some (subst_bound (t, body), skel0)
   502       | rew tm = (case get_first (match_rew tm) rules of
   503           None => apsome (rpair skel0) (get_first (fn p => p tm) procs)
   504         | x => x);
   505 
   506     fun rew1 (Var _) _ = None
   507       | rew1 skel tm = (case rew2 skel tm of
   508           Some tm1 => (case rew tm1 of
   509               Some (tm2, skel') => Some (if_none (rew1 skel' tm2) tm2)
   510             | None => Some tm1)
   511         | None => (case rew tm of
   512               Some (tm1, skel') => Some (if_none (rew1 skel' tm1) tm1)
   513             | None => None))
   514 
   515     and rew2 skel (tm1 $ tm2) = (case tm1 of
   516             Abs (_, _, body) =>
   517               let val tm' = subst_bound (tm2, body)
   518               in Some (if_none (rew2 skel0 tm') tm') end
   519           | _ => 
   520             let val (skel1, skel2) = (case skel of
   521                 skel1 $ skel2 => (skel1, skel2)
   522               | _ => (skel0, skel0))
   523             in case rew1 skel1 tm1 of
   524                 Some tm1' => (case rew1 skel2 tm2 of
   525                     Some tm2' => Some (tm1' $ tm2')
   526                   | None => Some (tm1' $ tm2))
   527               | None => (case rew1 skel2 tm2 of
   528                     Some tm2' => Some (tm1 $ tm2')
   529                   | None => None)
   530             end)
   531       | rew2 skel (Abs (x, T, tm)) =
   532           let
   533             val (abs, tm') = variant_absfree (x, T, tm);
   534             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   535           in case rew1 skel' tm' of
   536               Some tm'' => Some (abs tm'')
   537             | None => None
   538           end
   539       | rew2 _ _ = None
   540 
   541   in if_none (rew1 skel0 tm) tm end;
   542 
   543 end;
   544 
   545 val trace_unify_fail = Pattern.trace_unify_fail;