src/Pure/theory.ML
author wenzelm
Mon Nov 09 15:40:26 1998 +0100 (1998-11-09)
changeset 5838 a4122945d638
parent 5837 ce9a8b05d652
child 5862 3a1f9ec7c8a2
permissions -rw-r--r--
added metacuts_tac;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4     Copyright   1996  University of Cambridge
     5 
     6 The abstract type "theory" of theories.
     7 *)
     8 
     9 signature BASIC_THEORY =
    10 sig
    11   type theory
    12   exception THEORY of string * theory list
    13   val rep_theory: theory ->
    14     {sign: Sign.sg,
    15       axioms: term Symtab.table,
    16       oracles: ((Sign.sg * Object.T -> term) * stamp) Symtab.table,
    17       parents: theory list,
    18       ancestors: theory list}
    19   val sign_of: theory -> Sign.sg
    20   val syn_of: theory -> Syntax.syntax
    21   val parents_of: theory -> theory list
    22   val ancestors_of: theory -> theory list
    23   val subthy: theory * theory -> bool
    24   val eq_thy: theory * theory -> bool
    25   val cert_axm: Sign.sg -> string * term -> string * term
    26   val read_def_axm: Sign.sg * (indexname -> typ option) * (indexname -> sort option) -> string list ->
    27     string * string -> string * term
    28   val read_axm: Sign.sg -> string * string -> string * term
    29   val inferT_axm: Sign.sg -> string * term -> string * term
    30   val merge_theories: string -> theory * theory -> theory
    31 end
    32 
    33 signature THEORY =
    34 sig
    35   include BASIC_THEORY
    36   val apply: (theory -> theory) list -> theory -> theory
    37   val axiomK: string
    38   val oracleK: string
    39   (*theory extension primitives*)
    40   val add_classes: (bclass * xclass list) list -> theory -> theory
    41   val add_classes_i: (bclass * class list) list -> theory -> theory
    42   val add_classrel: (xclass * xclass) list -> theory -> theory
    43   val add_classrel_i: (class * class) list -> theory -> theory
    44   val add_defsort: xsort -> theory -> theory
    45   val add_defsort_i: sort -> theory -> theory
    46   val add_types: (bstring * int * mixfix) list -> theory -> theory
    47   val add_nonterminals: bstring list -> theory -> theory
    48   val add_tyabbrs: (bstring * string list * string * mixfix) list
    49     -> theory -> theory
    50   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list
    51     -> theory -> theory
    52   val add_arities: (xstring * xsort list * xsort) list -> theory -> theory
    53   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    54   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    55   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    56   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    57   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    58   val add_modesyntax: string * bool -> (bstring * string * mixfix) list -> theory -> theory
    59   val add_modesyntax_i: string * bool -> (bstring * typ * mixfix) list -> theory -> theory
    60   val add_trfuns:
    61     (string * (Syntax.ast list -> Syntax.ast)) list *
    62     (string * (term list -> term)) list *
    63     (string * (term list -> term)) list *
    64     (string * (Syntax.ast list -> Syntax.ast)) list -> theory -> theory
    65   val add_trfunsT:
    66     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    67   val add_tokentrfuns:
    68     (string * string * (string -> string * int)) list -> theory -> theory
    69   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    70   val add_trrules_i: Syntax.ast Syntax.trrule list -> theory -> theory
    71   val add_axioms: (bstring * string) list -> theory -> theory
    72   val add_axioms_i: (bstring * term) list -> theory -> theory
    73   val add_oracle: bstring * (Sign.sg * Object.T -> term) -> theory -> theory
    74   val add_defs: (bstring * string) list -> theory -> theory
    75   val add_defs_i: (bstring * term) list -> theory -> theory
    76   val add_path: string -> theory -> theory
    77   val parent_path: theory -> theory
    78   val root_path: theory -> theory
    79   val add_space: string * string list -> theory -> theory
    80   val add_name: string -> theory -> theory
    81   val prep_ext: theory -> theory
    82   val prep_ext_merge: theory list -> theory
    83   val requires: theory -> string -> string -> unit
    84   val pre_pure: theory
    85 end;
    86 
    87 signature THEORY_PRIVATE =
    88 sig
    89   include THEORY
    90   val init_data: Object.kind -> (Object.T * (Object.T -> Object.T) *
    91     (Object.T * Object.T -> Object.T) * (Sign.sg -> Object.T -> unit)) -> theory -> theory
    92   val print_data: Object.kind -> theory -> unit
    93   val get_data: Object.kind -> (Object.T -> 'a) -> theory -> 'a
    94   val put_data: Object.kind -> ('a -> Object.T) -> 'a -> theory -> theory
    95 end;
    96 
    97 
    98 structure Theory: THEORY_PRIVATE =
    99 struct
   100 
   101 
   102 (** datatype theory **)
   103 
   104 datatype theory =
   105   Theory of {
   106     sign: Sign.sg,
   107     axioms: term Symtab.table,
   108     oracles: ((Sign.sg * Object.T -> term) * stamp) Symtab.table,
   109     parents: theory list,
   110     ancestors: theory list};
   111 
   112 fun make_theory sign axms oras parents ancestors =
   113   Theory {sign = sign, axioms = axms, oracles = oras,
   114     parents = parents, ancestors = ancestors};
   115 
   116 fun rep_theory (Theory args) = args;
   117 
   118 val sign_of = #sign o rep_theory;
   119 val syn_of = #syn o Sign.rep_sg o sign_of;
   120 val parents_of = #parents o rep_theory;
   121 val ancestors_of = #ancestors o rep_theory;
   122 
   123 (*errors involving theories*)
   124 exception THEORY of string * theory list;
   125 
   126 (*compare theories*)
   127 val subthy = Sign.subsig o pairself sign_of;
   128 val eq_thy = Sign.eq_sg o pairself sign_of;
   129 
   130 (*check for some named theory*)
   131 fun requires thy name what =
   132   if exists (equal name) (Sign.stamp_names_of (sign_of thy)) then ()
   133   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   134 
   135 (*partial Pure theory*)
   136 val pre_pure = make_theory Sign.pre_pure Symtab.empty Symtab.empty [] [];
   137 
   138 (*apply transformers*)
   139 fun apply [] thy = thy
   140   | apply (f :: fs) thy = apply fs (f thy);
   141 
   142 
   143 
   144 (** extend theory **)
   145 
   146 (*name space kinds*)
   147 val axiomK = "axiom";
   148 val oracleK = "oracle";
   149 
   150 
   151 (* extend logical part of a theory *)
   152 
   153 fun err_dup_axms names =
   154   error ("Duplicate axiom name(s) " ^ commas_quote names);
   155 
   156 fun err_dup_oras names =
   157   error ("Duplicate oracles " ^ commas_quote names);
   158 
   159 fun ext_theory thy ext_sg new_axms new_oras =
   160   let
   161     val Theory {sign, axioms, oracles, parents, ancestors} = thy;
   162     val draft = Sign.is_draft sign;
   163     val axioms' =
   164       Symtab.extend (if draft then axioms else Symtab.empty, new_axms)
   165         handle Symtab.DUPS names => err_dup_axms names;
   166     val oracles' =
   167       Symtab.extend (oracles, new_oras)
   168         handle Symtab.DUPS names => err_dup_oras names;
   169     val (parents', ancestors') =
   170       if draft then (parents, ancestors) else ([thy], thy :: ancestors);
   171   in
   172     make_theory (ext_sg sign) axioms' oracles' parents' ancestors'
   173   end;
   174 
   175 
   176 (* extend signature of a theory *)
   177 
   178 fun ext_sign extfun decls thy = ext_theory thy (extfun decls) [] [];
   179 
   180 val add_classes      = ext_sign Sign.add_classes;
   181 val add_classes_i    = ext_sign Sign.add_classes_i;
   182 val add_classrel     = ext_sign Sign.add_classrel;
   183 val add_classrel_i   = ext_sign Sign.add_classrel_i;
   184 val add_defsort      = ext_sign Sign.add_defsort;
   185 val add_defsort_i    = ext_sign Sign.add_defsort_i;
   186 val add_types        = ext_sign Sign.add_types;
   187 val add_nonterminals = ext_sign Sign.add_nonterminals;
   188 val add_tyabbrs      = ext_sign Sign.add_tyabbrs;
   189 val add_tyabbrs_i    = ext_sign Sign.add_tyabbrs_i;
   190 val add_arities      = ext_sign Sign.add_arities;
   191 val add_arities_i    = ext_sign Sign.add_arities_i;
   192 val add_consts       = ext_sign Sign.add_consts;
   193 val add_consts_i     = ext_sign Sign.add_consts_i;
   194 val add_syntax       = ext_sign Sign.add_syntax;
   195 val add_syntax_i     = ext_sign Sign.add_syntax_i;
   196 val add_modesyntax   = curry (ext_sign Sign.add_modesyntax);
   197 val add_modesyntax_i = curry (ext_sign Sign.add_modesyntax_i);
   198 val add_trfuns       = ext_sign Sign.add_trfuns;
   199 val add_trfunsT      = ext_sign Sign.add_trfunsT;
   200 val add_tokentrfuns  = ext_sign Sign.add_tokentrfuns;
   201 val add_trrules      = ext_sign Sign.add_trrules;
   202 val add_trrules_i    = ext_sign Sign.add_trrules_i;
   203 val add_path         = ext_sign Sign.add_path;
   204 val parent_path      = add_path "..";
   205 val root_path        = add_path "/";
   206 val add_space        = ext_sign Sign.add_space;
   207 val add_name         = ext_sign Sign.add_name;
   208 val prep_ext         = ext_sign (K Sign.prep_ext) ();
   209 
   210 
   211 
   212 (** add axioms **)
   213 
   214 (* prepare axioms *)
   215 
   216 fun err_in_axm name =
   217   error ("The error(s) above occurred in axiom " ^ quote name);
   218 
   219 fun no_vars tm =
   220   if null (term_vars tm) andalso null (term_tvars tm) then tm
   221   else error "Illegal schematic variable(s) in term";
   222 
   223 fun cert_axm sg (name, raw_tm) =
   224   let
   225     val (t, T, _) = Sign.certify_term sg raw_tm
   226       handle TYPE (msg, _, _) => error msg
   227            | TERM (msg, _) => error msg;
   228   in
   229     assert (T = propT) "Term not of type prop";
   230     (name, no_vars t)
   231   end
   232   handle ERROR => err_in_axm name;
   233 
   234 (*some duplication of code with read_def_cterm*)
   235 fun read_def_axm (sg, types, sorts) used (name, str) = 
   236   let
   237     val ts = Syntax.read (#syn (Sign.rep_sg sg)) propT str;
   238     val (t, _) = Sign.infer_types sg types sorts used true (ts, propT);
   239   in cert_axm sg (name,t) end
   240   handle ERROR => err_in_axm name;
   241 
   242 fun read_axm sg name_str = read_def_axm (sg, K None, K None) [] name_str;
   243 
   244 fun inferT_axm sg (name, pre_tm) =
   245   let
   246     val (t, _) = Sign.infer_types sg (K None) (K None) [] true ([pre_tm], propT);
   247   in (name, no_vars t) end
   248   handle ERROR => err_in_axm name;
   249 
   250 
   251 (* extend axioms of a theory *)
   252 
   253 fun ext_axms prep_axm raw_axms (thy as Theory {sign, ...}) =
   254   let
   255     val raw_axms' = map (apfst (Sign.full_name sign)) raw_axms;
   256     val axioms =
   257       map (apsnd (Term.compress_term o Logic.varify) o prep_axm sign) raw_axms';
   258     val ext_sg = Sign.add_space (axiomK, map fst axioms);
   259   in
   260     ext_theory thy ext_sg axioms []
   261   end;
   262 
   263 val add_axioms = ext_axms read_axm;
   264 val add_axioms_i = ext_axms cert_axm;
   265 
   266 
   267 (* add oracle **)
   268 
   269 fun add_oracle (raw_name, oracle) (thy as Theory {sign, ...}) =
   270   let
   271     val name = Sign.full_name sign raw_name;
   272     val ext_sg = Sign.add_space (oracleK, [name]);
   273   in
   274     ext_theory thy ext_sg [] [(name, (oracle, stamp ()))]
   275   end;
   276 
   277 
   278 
   279 (** add constant definitions **)
   280 
   281 (* all_axioms_of *)
   282 
   283 (*results may contain duplicates!*)
   284 
   285 fun all_axioms_of thy =
   286   flat (map (Symtab.dest o #axioms o rep_theory) (thy :: ancestors_of thy));
   287 
   288 
   289 (* clash_types, clash_consts *)
   290 
   291 (*check if types have common instance (ignoring sorts)*)
   292 
   293 fun clash_types ty1 ty2 =
   294   let
   295     val ty1' = Type.varifyT ty1;
   296     val ty2' = incr_tvar (maxidx_of_typ ty1' + 1) (Type.varifyT ty2);
   297   in
   298     Type.raw_unify (ty1', ty2')
   299   end;
   300 
   301 fun clash_consts (c1, ty1) (c2, ty2) =
   302   c1 = c2 andalso clash_types ty1 ty2;
   303 
   304 
   305 (* clash_defns *)
   306 
   307 fun clash_defn c_ty (name, tm) =
   308   let val (c, ty') = dest_Const (head_of (fst (Logic.dest_equals tm))) in
   309     if clash_consts c_ty (c, ty') then Some (name, ty') else None
   310   end handle TERM _ => None;
   311 
   312 fun clash_defns c_ty axms =
   313   distinct (mapfilter (clash_defn c_ty) axms);
   314 
   315 
   316 (* dest_defn *)
   317 
   318 fun dest_defn tm =
   319   let
   320     fun err msg = raise TERM (msg, [tm]);
   321 
   322     val (lhs, rhs) = Logic.dest_equals (Logic.strip_imp_concl tm)
   323       handle TERM _ => err "Not a meta-equality (==)";
   324     val (head, args) = strip_comb lhs;
   325     val (c, ty) = dest_Const head
   326       handle TERM _ => err "Head of lhs not a constant";
   327 
   328     fun occs_const (Const c_ty') = (c_ty' = (c, ty))
   329       | occs_const (Abs (_, _, t)) = occs_const t
   330       | occs_const (t $ u) = occs_const t orelse occs_const u
   331       | occs_const _ = false;
   332 
   333     fun dest_free (Free (x, _)) = x
   334       | dest_free (Const ("TYPE", Type ("itself", [TFree (x, _)]))) = x
   335       | dest_free _ = raise Match;
   336 
   337     val show_frees = commas_quote o map dest_free;
   338     val show_tfrees = commas_quote o map fst;
   339 
   340     val lhs_dups = duplicates args;
   341     val rhs_extras = gen_rems (op =) (term_frees rhs, args);
   342     val rhs_extrasT = gen_rems (op =) (term_tfrees rhs, typ_tfrees ty);
   343   in
   344     if not (forall (can dest_free) args) then
   345       err "Arguments (on lhs) must be variables"
   346     else if not (null lhs_dups) then
   347       err ("Duplicate variables on lhs: " ^ show_frees lhs_dups)
   348     else if not (null rhs_extras) then
   349       err ("Extra variables on rhs: " ^ show_frees rhs_extras)
   350     else if not (null rhs_extrasT) then
   351       err ("Extra type variables on rhs: " ^ show_tfrees rhs_extrasT)
   352     else if occs_const rhs then
   353       err ("Constant to be defined occurs on rhs")
   354     else (c, ty)
   355   end;
   356 
   357 
   358 (* check_defn *)
   359 
   360 fun err_in_defn sg name msg =
   361   (error_msg msg; error ("The error(s) above occurred in definition " ^
   362     quote (Sign.full_name sg name)));
   363 
   364 fun check_defn sign (axms, (name, tm)) =
   365   let
   366     fun show_const (c, ty) = quote (Pretty.string_of (Pretty.block
   367       [Pretty.str (c ^ " ::"), Pretty.brk 1, Sign.pretty_typ sign ty]));
   368 
   369     fun show_defn c (dfn, ty') = show_const (c, ty') ^ " in " ^ dfn;
   370     fun show_defns c = cat_lines o map (show_defn c);
   371 
   372     val (c, ty) = dest_defn tm
   373       handle TERM (msg, _) => err_in_defn sign name msg;
   374     val defns = clash_defns (c, ty) axms;
   375   in
   376     if not (null defns) then
   377       err_in_defn sign name ("Definition of " ^ show_const (c, ty) ^
   378         "\nclashes with " ^ show_defns c defns)
   379     else (name, tm) :: axms
   380   end;
   381 
   382 
   383 (* add_defs *)
   384 
   385 fun ext_defns prep_axm raw_axms thy =
   386   let
   387     val axms = map (prep_axm (sign_of thy)) raw_axms;
   388     val all_axms = all_axioms_of thy;
   389   in
   390     foldl (check_defn (sign_of thy)) (all_axms, axms);
   391     add_axioms_i axms thy
   392   end;
   393 
   394 val add_defs_i = ext_defns cert_axm;
   395 val add_defs = ext_defns read_axm;
   396 
   397 
   398 
   399 (** additional theory data **)
   400 
   401 val init_data = curry (ext_sign Sign.init_data);
   402 fun print_data kind = Sign.print_data kind o sign_of;
   403 fun get_data kind f = Sign.get_data kind f o sign_of;
   404 fun put_data kind f = ext_sign (Sign.put_data kind f);
   405 
   406 
   407 
   408 (** merge theories **)		(*exception ERROR*)
   409 
   410 fun merge_sign (sg, thy) =
   411   Sign.nontriv_merge (sg, sign_of thy) handle TERM (msg, _) => error msg;
   412 
   413 (*merge list of theories from left to right, preparing extend*)
   414 fun prep_ext_merge thys =
   415   if null thys then
   416     error "Merge: no parent theories"
   417   else if exists (Sign.is_draft o sign_of) thys then
   418     error "Attempt to merge draft theories"
   419   else
   420     let
   421       val sign' =
   422         foldl merge_sign (sign_of (hd thys), tl thys)
   423         |> Sign.prep_ext
   424         |> Sign.add_path "/";
   425 
   426       val axioms' = Symtab.empty;
   427 
   428       fun eq_ora ((_, (_, s1: stamp)), (_, (_, s2))) = s1 = s2;
   429       val oracles' =
   430         Symtab.make (gen_distinct eq_ora
   431           (flat (map (Symtab.dest o #oracles o rep_theory) thys)))
   432         handle Symtab.DUPS names => err_dup_oras names;
   433 
   434       val parents' = gen_distinct eq_thy thys;
   435       val ancestors' =
   436         gen_distinct eq_thy (parents' @ flat (map ancestors_of thys));
   437     in
   438       make_theory sign' axioms' oracles' parents' ancestors'
   439     end;
   440 
   441 fun merge_theories name (thy1, thy2) =
   442   prep_ext_merge [thy1, thy2]
   443   |> add_name name;
   444 
   445 
   446 end;
   447 
   448 structure BasicTheory: BASIC_THEORY = Theory;
   449 open BasicTheory;