src/Pure/library.ML
author nipkow
Sun Aug 07 12:28:10 2005 +0200 (2005-08-07)
changeset 17028 a497f621bfd4
parent 16984 abc48b981e60
child 17032 3e41d98bf6d4
permissions -rw-r--r--
added more rat functions
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |-> ||> ||>> |>> |>>> #> #-> ~~ \ \\ ins ins_string ins_int
    12   orf andf prefix upto downto mem mem_int mem_string union union_int
    13   union_string inter inter_int inter_string subset subset_int
    14   subset_string;
    15 
    16 infix 3 oo ooo oooo;
    17 
    18 signature BASIC_LIBRARY =
    19 sig
    20   (*functions*)
    21   val I: 'a -> 'a
    22   val K: 'a -> 'b -> 'a
    23   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    24   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    25   val |> : 'a * ('a -> 'b) -> 'b
    26   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    27   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    28   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    29   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    30   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    31   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    32   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    33   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    34   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    35   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    36   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    37   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    38   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    39   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    40 
    41   (*old options -- invalidated*)
    42   datatype invalid = None of invalid
    43   exception OPTION of invalid
    44 
    45   (*options*)
    46   val the: 'a option -> 'a
    47   val if_none: 'a option -> 'a -> 'a
    48   val is_some: 'a option -> bool
    49   val is_none: 'a option -> bool
    50 
    51   exception ERROR
    52   val try: ('a -> 'b) -> 'a -> 'b option
    53   val can: ('a -> 'b) -> 'a -> bool
    54   datatype 'a result = Result of 'a | Exn of exn
    55   val capture: ('a -> 'b) -> 'a -> 'b result
    56   val release: 'a result -> 'a
    57   val get_result: 'a result -> 'a option
    58   val get_exn: 'a result -> exn option
    59 
    60   (*pairs*)
    61   val pair: 'a -> 'b -> 'a * 'b
    62   val rpair: 'a -> 'b -> 'b * 'a
    63   val fst: 'a * 'b -> 'a
    64   val snd: 'a * 'b -> 'b
    65   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    66   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    67   val swap: 'a * 'b -> 'b * 'a
    68   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    69   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    70   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    71 
    72   (*booleans*)
    73   val equal: ''a -> ''a -> bool
    74   val not_equal: ''a -> ''a -> bool
    75   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    76   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    77   val exists: ('a -> bool) -> 'a list -> bool
    78   val forall: ('a -> bool) -> 'a list -> bool
    79   val set: bool ref -> bool
    80   val reset: bool ref -> bool
    81   val toggle: bool ref -> bool
    82   val change: 'a ref -> ('a -> 'a) -> unit
    83   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    84   val conditional: bool -> (unit -> unit) -> unit
    85 
    86   (*lists*)
    87   exception UnequalLengths
    88   val cons: 'a -> 'a list -> 'a list
    89   val single: 'a -> 'a list
    90   val append: 'a list -> 'a list -> 'a list
    91   val apply: ('a -> 'a) list -> 'a -> 'a
    92   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    93   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    94   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
    95   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    96   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    97   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    98   val unflat: 'a list list -> 'b list -> 'b list list
    99   val splitAt: int * 'a list -> 'a list * 'a list
   100   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   101   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
   102   val split_last: 'a list -> 'a list * 'a
   103   val nth_update: 'a -> int * 'a list -> 'a list
   104   val find_index: ('a -> bool) -> 'a list -> int
   105   val find_index_eq: ''a -> ''a list -> int
   106   val find_first: ('a -> bool) -> 'a list -> 'a option
   107   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   108   val separate: 'a -> 'a list -> 'a list
   109   val replicate: int -> 'a -> 'a list
   110   val multiply: 'a list * 'a list list -> 'a list list
   111   val product: 'a list -> 'b list -> ('a * 'b) list
   112   val filter: ('a -> bool) -> 'a list -> 'a list
   113   val filter_out: ('a -> bool) -> 'a list -> 'a list
   114   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   115   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   116   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   117   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   118   val ~~ : 'a list * 'b list -> ('a * 'b) list
   119   val split_list: ('a * 'b) list -> 'a list * 'b list
   120   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   121   val prefix: ''a list * ''a list -> bool
   122   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   123   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   124   val prefixes1: 'a list -> 'a list list
   125   val suffixes1: 'a list -> 'a list list
   126 
   127   (*integers*)
   128   val gcd: IntInf.int * IntInf.int -> IntInf.int
   129   val lcm: IntInf.int * IntInf.int -> IntInf.int
   130   val inc: int ref -> int
   131   val dec: int ref -> int
   132   val upto: int * int -> int list
   133   val downto: int * int -> int list
   134   val downto0: int list * int -> bool
   135   val radixpand: int * int -> int list
   136   val radixstring: int * string * int -> string
   137   val string_of_int: int -> string
   138   val string_of_indexname: string * int -> string
   139   val read_radixint: int * string list -> int * string list
   140   val read_int: string list -> int * string list
   141   val oct_char: string -> string
   142 
   143   (*rational numbers*)
   144   type rat
   145   exception RAT of string
   146   val rep_rat: rat -> IntInf.int * IntInf.int
   147   val ratge0: rat -> bool
   148   val ratgt0: rat -> bool
   149   val ratle: rat * rat -> bool
   150   val ratlt: rat * rat -> bool
   151   val ratadd: rat * rat -> rat
   152   val ratmul: rat * rat -> rat
   153   val ratinv: rat -> rat
   154   val int_ratdiv: IntInf.int * IntInf.int -> rat
   155   val ratneg: rat -> rat
   156   val rat_of_int: int -> rat
   157   val rat_of_intinf: IntInf.int -> rat
   158   val rat0: rat
   159 
   160   (*strings*)
   161   val nth_elem_string: int * string -> string
   162   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   163   val exists_string: (string -> bool) -> string -> bool
   164   val forall_string: (string -> bool) -> string -> bool
   165   val enclose: string -> string -> string -> string
   166   val unenclose: string -> string
   167   val quote: string -> string
   168   val space_implode: string -> string list -> string
   169   val commas: string list -> string
   170   val commas_quote: string list -> string
   171   val cat_lines: string list -> string
   172   val space_explode: string -> string -> string list
   173   val split_lines: string -> string list
   174   val prefix_lines: string -> string -> string
   175   val untabify: string list -> string list
   176   val suffix: string -> string -> string
   177   val unsuffix: string -> string -> string
   178   val unprefix: string -> string -> string
   179   val replicate_string: int -> string -> string
   180   val translate_string: (string -> string) -> string -> string
   181 
   182   (*lists as sets -- see also Pure/General/ord_list.ML*)
   183   val mem: ''a * ''a list -> bool
   184   val mem_int: int * int list -> bool
   185   val mem_string: string * string list -> bool
   186   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   187   val ins: ''a * ''a list -> ''a list
   188   val ins_int: int * int list -> int list
   189   val ins_string: string * string list -> string list
   190   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   191   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   192   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   193   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   194   val union: ''a list * ''a list -> ''a list
   195   val union_int: int list * int list -> int list
   196   val union_string: string list * string list -> string list
   197   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   198   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   199   val inter: ''a list * ''a list -> ''a list
   200   val inter_int: int list * int list -> int list
   201   val inter_string: string list * string list -> string list
   202   val subset: ''a list * ''a list -> bool
   203   val subset_int: int list * int list -> bool
   204   val subset_string: string list * string list -> bool
   205   val eq_set: ''a list * ''a list -> bool
   206   val eq_set_string: string list * string list -> bool
   207   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   208   val \ : ''a list * ''a -> ''a list
   209   val \\ : ''a list * ''a list -> ''a list
   210   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   211   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   212   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   213   val distinct: ''a list -> ''a list
   214   val findrep: ''a list -> ''a list
   215   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   216   val duplicates: ''a list -> ''a list
   217   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   218 
   219   (*association lists*)
   220   val assoc: (''a * 'b) list * ''a -> 'b option
   221   val assoc_int: (int * 'a) list * int -> 'a option
   222   val assoc_string: (string * 'a) list * string -> 'a option
   223   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   224   val assocs: (''a * 'b list) list -> ''a -> 'b list
   225   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   226   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   227   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   228   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   229 
   230   (*lists as tables*)
   231   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   232   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   233   val merge_lists: ''a list -> ''a list -> ''a list
   234   val merge_lists': ''a list -> ''a list -> ''a list
   235   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   236   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   237 
   238   (*balanced trees*)
   239   exception Balance
   240   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   241   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   242   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   243 
   244   (*orders*)
   245   val rev_order: order -> order
   246   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   247   val int_ord: int * int -> order
   248   val string_ord: string * string -> order
   249   val fast_string_ord: string * string -> order
   250   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   251   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   252   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   253   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   254   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   255   val sort_strings: string list -> string list
   256   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   257   val unique_strings: string list -> string list
   258 
   259   (*random numbers*)
   260   exception RANDOM
   261   val random: unit -> real
   262   val random_range: int -> int -> int
   263   val one_of: 'a list -> 'a
   264   val frequency: (int * 'a) list -> 'a
   265 
   266   (*current directory*)
   267   val cd: string -> unit
   268   val pwd: unit -> string
   269 
   270   (*misc*)
   271   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   272   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   273   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   274   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   275   val gensym: string -> string
   276   val scanwords: (string -> bool) -> string list -> string list
   277   type stamp
   278   val stamp: unit -> stamp
   279   type serial
   280   val serial: unit -> serial
   281   structure Object: sig type T end
   282 end;
   283 
   284 signature LIBRARY =
   285 sig
   286   include BASIC_LIBRARY
   287   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   288   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   289   val take: int * 'a list -> 'a list
   290   val drop: int * 'a list -> 'a list
   291   val nth_elem: int * 'a list -> 'a
   292   val last_elem: 'a list -> 'a
   293   val flat: 'a list list -> 'a list
   294   val seq: ('a -> unit) -> 'a list -> unit
   295   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   296   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   297 end;
   298 
   299 structure Library: LIBRARY =
   300 struct
   301 
   302 
   303 (** functions **)
   304 
   305 fun I x = x;
   306 fun K x = fn _ => x;
   307 fun curry f x y = f (x, y);
   308 fun uncurry f (x, y) = f x y;
   309 
   310 (*reverse application and structured results*)
   311 fun x |> f = f x;
   312 fun (x, y) |-> f = f x y;
   313 fun (x, y) |>> f = (f x, y);
   314 fun (x, y) ||> f = (x, f y);
   315 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   316 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   317 
   318 (*reverse composition*)
   319 fun f #> g = g o f;
   320 fun f #-> g = uncurry g o f;
   321 
   322 (*view results*)
   323 fun `f = fn x => (f x, x);
   324 
   325 (*composition with multiple args*)
   326 fun (f oo g) x y = f (g x y);
   327 fun (f ooo g) x y z = f (g x y z);
   328 fun (f oooo g) x y z w = f (g x y z w);
   329 
   330 (*function exponentiation: f(...(f x)...) with n applications of f*)
   331 fun funpow n f x =
   332   let fun rep (0, x) = x
   333         | rep (n, x) = rep (n - 1, f x)
   334   in rep (n, x) end;
   335 
   336 (*application of (infix) operator to its left or right argument*)
   337 fun apl (x, f) y = f (x, y);
   338 fun apr (f, y) x = f (x, y);
   339 
   340 
   341 (** options **)
   342 
   343 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   344 datatype invalid = None of invalid;
   345 exception OPTION of invalid;
   346 
   347 val the = Option.valOf;
   348 
   349 (*strict!*)
   350 fun if_none NONE y = y
   351   | if_none (SOME x) _ = x;
   352 
   353 fun is_some (SOME _) = true
   354   | is_some NONE = false;
   355 
   356 fun is_none (SOME _) = false
   357   | is_none NONE = true;
   358 
   359 
   360 (* exception handling *)
   361 
   362 exception ERROR;
   363 
   364 fun try f x = SOME (f x)
   365   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   366 
   367 fun can f x = is_some (try f x);
   368 
   369 
   370 datatype 'a result =
   371   Result of 'a |
   372   Exn of exn;
   373 
   374 fun capture f x = Result (f x) handle e => Exn e;
   375 
   376 fun release (Result y) = y
   377   | release (Exn e) = raise e;
   378 
   379 fun get_result (Result x) = SOME x
   380   | get_result _ = NONE;
   381 
   382 fun get_exn (Exn exn) = SOME exn
   383   | get_exn _ = NONE;
   384 
   385 
   386 
   387 (** pairs **)
   388 
   389 fun pair x y = (x, y);
   390 fun rpair x y = (y, x);
   391 
   392 fun fst (x, y) = x;
   393 fun snd (x, y) = y;
   394 
   395 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   396 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   397 
   398 fun swap (x, y) = (y, x);
   399 
   400 (*apply function to components*)
   401 fun apfst f (x, y) = (f x, y);
   402 fun apsnd f (x, y) = (x, f y);
   403 fun pairself f (x, y) = (f x, f y);
   404 
   405 
   406 
   407 (** booleans **)
   408 
   409 (* equality *)
   410 
   411 fun equal x y = x = y;
   412 fun not_equal x y = x <> y;
   413 
   414 
   415 (* operators for combining predicates *)
   416 
   417 fun p orf q = fn x => p x orelse q x;
   418 fun p andf q = fn x => p x andalso q x;
   419 
   420 
   421 (* predicates on lists *)
   422 
   423 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   424 fun exists (pred: 'a -> bool) : 'a list -> bool =
   425   let fun boolf [] = false
   426         | boolf (x :: xs) = pred x orelse boolf xs
   427   in boolf end;
   428 
   429 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   430 fun forall (pred: 'a -> bool) : 'a list -> bool =
   431   let fun boolf [] = true
   432         | boolf (x :: xs) = pred x andalso boolf xs
   433   in boolf end;
   434 
   435 
   436 (* flags *)
   437 
   438 fun set flag = (flag := true; true);
   439 fun reset flag = (flag := false; false);
   440 fun toggle flag = (flag := not (! flag); ! flag);
   441 
   442 fun change r f = r := f (! r);
   443 
   444 (*temporarily set flag, handling exceptions*)
   445 fun setmp flag value f x =
   446   let
   447     val orig_value = ! flag;
   448     fun return y = (flag := orig_value; y);
   449   in
   450     flag := value;
   451     return (f x handle exn => (return (); raise exn))
   452   end;
   453 
   454 
   455 (* conditional execution *)
   456 
   457 fun conditional b f = if b then f () else ();
   458 
   459 
   460 
   461 (** lists **)
   462 
   463 exception UnequalLengths;
   464 
   465 fun cons x xs = x :: xs;
   466 fun single x = [x];
   467 
   468 fun append xs ys = xs @ ys;
   469 
   470 fun apply [] x = x
   471   | apply (f :: fs) x = apply fs (f x);
   472 
   473 
   474 (* fold *)
   475 
   476 fun fold f =
   477   let
   478     fun fold_aux [] y = y
   479       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   480   in fold_aux end;
   481 
   482 fun fold_rev f =
   483   let
   484     fun fold_aux [] y = y
   485       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   486   in fold_aux end;
   487 
   488 fun fold_map f =
   489   let
   490     fun fold_aux [] y = ([], y)
   491       | fold_aux (x :: xs) y =
   492           let
   493             val (x', y') = f x y;
   494             val (xs', y'') = fold_aux xs y';
   495           in (x' :: xs', y'') end;
   496   in fold_aux end;
   497 
   498 (*the following versions of fold are designed to fit nicely with infixes*)
   499 
   500 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   501     for operators that associate to the left (TAIL RECURSIVE)*)
   502 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   503   let fun itl (e, [])  = e
   504         | itl (e, a::l) = itl (f(e, a), l)
   505   in  itl end;
   506 
   507 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   508     for operators that associate to the right (not tail recursive)*)
   509 fun foldr f (l, e) =
   510   let fun itr [] = e
   511         | itr (a::l) = f(a, itr l)
   512   in  itr l  end;
   513 
   514 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   515     for n > 0, operators that associate to the right (not tail recursive)*)
   516 fun foldr1 f l =
   517   let fun itr [x] = x
   518         | itr (x::l) = f(x, itr l)
   519   in  itr l  end;
   520 
   521 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   522 
   523 fun foldl_map f =
   524   let
   525     fun fold_aux (x, []) = (x, [])
   526       | fold_aux (x, y :: ys) =
   527           let
   528             val (x', y') = f (x, y);
   529             val (x'', ys') = fold_aux (x', ys);
   530           in (x'', y' :: ys') end;
   531   in fold_aux end;
   532 
   533 
   534 (* basic list functions *)
   535 
   536 (*take the first n elements from a list*)
   537 fun take (n, []) = []
   538   | take (n, x :: xs) =
   539       if n > 0 then x :: take (n - 1, xs) else [];
   540 
   541 (*drop the first n elements from a list*)
   542 fun drop (n, []) = []
   543   | drop (n, x :: xs) =
   544       if n > 0 then drop (n - 1, xs) else x :: xs;
   545 
   546 fun splitAt(n,[]) = ([],[])
   547   | splitAt(n,xs as x::ys) =
   548       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   549       else ([],xs)
   550 
   551 fun dropwhile P [] = []
   552   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   553 
   554 (*return nth element of a list, where 0 designates the first element;
   555   raise EXCEPTION if list too short*)
   556 fun nth_elem (i,xs) = List.nth(xs,i);
   557 
   558 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   559   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   560   | map_nth_elem _ _ [] = raise Subscript;
   561 
   562 (*last element of a list*)
   563 val last_elem = List.last;
   564 
   565 (*rear decomposition*)
   566 fun split_last [] = raise Empty
   567   | split_last [x] = ([], x)
   568   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   569 
   570 (*update nth element*)
   571 fun nth_update x n_xs =
   572     (case splitAt n_xs of
   573       (_,[]) => raise Subscript
   574     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   575 
   576 (*find the position of an element in a list*)
   577 fun find_index pred =
   578   let fun find _ [] = ~1
   579         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   580   in find 0 end;
   581 
   582 fun find_index_eq x = find_index (equal x);
   583 
   584 (*find first element satisfying predicate*)
   585 fun find_first _ [] = NONE
   586   | find_first pred (x :: xs) =
   587       if pred x then SOME x else find_first pred xs;
   588 
   589 (*get first element by lookup function*)
   590 fun get_first _ [] = NONE
   591   | get_first f (x :: xs) =
   592       (case f x of
   593         NONE => get_first f xs
   594       | some => some);
   595 
   596 (*flatten a list of lists to a list*)
   597 val flat = List.concat;
   598 
   599 fun unflat (xs :: xss) ys =
   600       let val (ps,qs) = splitAt(length xs,ys)
   601       in ps :: unflat xss qs end
   602   | unflat [] [] = []
   603   | unflat _ _ = raise UnequalLengths;
   604 
   605 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   606   (proc x1; ...; proc xn) for side effects*)
   607 val seq = List.app;
   608 
   609 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   610 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   611   | separate _ xs = xs;
   612 
   613 (*make the list [x, x, ..., x] of length n*)
   614 fun replicate n (x: 'a) : 'a list =
   615   let fun rep (0, xs) = xs
   616         | rep (n, xs) = rep (n - 1, x :: xs)
   617   in
   618     if n < 0 then raise Subscript
   619     else rep (n, [])
   620   end;
   621 
   622 fun translate_string f = String.translate (f o String.str);
   623 
   624 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   625 fun multiply ([], _) = []
   626   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   627 
   628 (*direct product*)
   629 fun product _ [] = []
   630   | product [] _ = []
   631   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   632 
   633 
   634 (* filter *)
   635 
   636 (*copy the list preserving elements that satisfy the predicate*)
   637 val filter = List.filter;
   638 fun filter_out f = filter (not o f);
   639 val mapfilter = List.mapPartial;
   640 
   641 
   642 (* lists of pairs *)
   643 
   644 exception UnequalLengths;
   645 
   646 fun map2 _ ([], []) = []
   647   | map2 f (x :: xs, y :: ys) = f (x, y) :: map2 f (xs, ys)
   648   | map2 _ _ = raise UnequalLengths;
   649 
   650 fun exists2 _ ([], []) = false
   651   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   652   | exists2 _ _ = raise UnequalLengths;
   653 
   654 fun forall2 _ ([], []) = true
   655   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   656   | forall2 _ _ = raise UnequalLengths;
   657 
   658 fun seq2 _ ([], []) = ()
   659   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   660   | seq2 _ _ = raise UnequalLengths;
   661 
   662 (*combine two lists forming a list of pairs:
   663   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   664 fun [] ~~ [] = []
   665   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   666   | _ ~~ _ = raise UnequalLengths;
   667 
   668 (*inverse of ~~; the old 'split':
   669   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   670 val split_list = ListPair.unzip;
   671 
   672 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   673 
   674 
   675 (* prefixes, suffixes *)
   676 
   677 fun [] prefix _ = true
   678   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   679   | _ prefix _ = false;
   680 
   681 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   682    where xi is the first element that does not satisfy the predicate*)
   683 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   684   let fun take (rxs, []) = (rev rxs, [])
   685         | take (rxs, x :: xs) =
   686             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   687   in  take([], xs)  end;
   688 
   689 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   690    where xi is the last element that does not satisfy the predicate*)
   691 fun take_suffix _ [] = ([], [])
   692   | take_suffix pred (x :: xs) =
   693       (case take_suffix pred xs of
   694         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   695       | (prfx, sffx) => (x :: prfx, sffx));
   696 
   697 fun prefixes1 [] = []
   698   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   699 
   700 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   701 
   702 
   703 
   704 (** integers **)
   705 
   706 fun gcd (x, y) =
   707   let fun gxd x y : IntInf.int =
   708     if y = 0 then x else gxd y (x mod y)
   709   in if x < y then gxd y x else gxd x y end;
   710 
   711 fun lcm (x, y) = (x * y) div gcd (x, y);
   712 
   713 fun inc i = (i := ! i + 1; ! i);
   714 fun dec i = (i := ! i - 1; ! i);
   715 
   716 
   717 (* lists of integers *)
   718 
   719 (*make the list [from, from + 1, ..., to]*)
   720 fun (from upto to) =
   721   if from > to then [] else from :: ((from + 1) upto to);
   722 
   723 (*make the list [from, from - 1, ..., to]*)
   724 fun (from downto to) =
   725   if from < to then [] else from :: ((from - 1) downto to);
   726 
   727 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   728 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   729   | downto0 ([], n) = n = ~1;
   730 
   731 
   732 (* convert integers to strings *)
   733 
   734 (*expand the number in the given base;
   735   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   736 fun radixpand (base, num) : int list =
   737   let
   738     fun radix (n, tail) =
   739       if n < base then n :: tail
   740       else radix (n div base, (n mod base) :: tail)
   741   in radix (num, []) end;
   742 
   743 (*expands a number into a string of characters starting from "zerochar";
   744   example: radixstring (2, "0", 8) gives "1000"*)
   745 fun radixstring (base, zerochar, num) =
   746   let val offset = ord zerochar;
   747       fun chrof n = chr (offset + n)
   748   in implode (map chrof (radixpand (base, num))) end;
   749 
   750 
   751 val string_of_int = Int.toString;
   752 
   753 fun string_of_indexname (a,0) = a
   754   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   755 
   756 
   757 (* read integers *)
   758 
   759 fun read_radixint (radix: int, cs) : int * string list =
   760   let val zero = ord"0"
   761       val limit = zero+radix
   762       fun scan (num,[]) = (num,[])
   763         | scan (num, c::cs) =
   764               if  zero <= ord c  andalso  ord c < limit
   765               then scan(radix*num + ord c - zero, cs)
   766               else (num, c::cs)
   767   in  scan(0,cs)  end;
   768 
   769 fun read_int cs = read_radixint (10, cs);
   770 
   771 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   772 
   773 
   774 
   775 (** strings **)
   776 
   777 (* functions tuned for strings, avoiding explode *)
   778 
   779 fun nth_elem_string (i, str) =
   780   (case try String.substring (str, i, 1) of
   781     SOME s => s
   782   | NONE => raise Subscript);
   783 
   784 fun fold_string f str x0 =
   785   let
   786     val n = size str;
   787     fun iter (x, i) =
   788       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   789   in iter (x0, 0) end;
   790 
   791 fun exists_string pred str =
   792   let
   793     val n = size str;
   794     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   795   in ex 0 end;
   796 
   797 fun forall_string pred = not o exists_string (not o pred);
   798 
   799 (*enclose in brackets*)
   800 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   801 fun unenclose str = String.substring (str, 1, size str - 2);
   802 
   803 (*simple quoting (does not escape special chars)*)
   804 val quote = enclose "\"" "\"";
   805 
   806 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   807 fun space_implode a bs = implode (separate a bs);
   808 
   809 val commas = space_implode ", ";
   810 val commas_quote = commas o map quote;
   811 
   812 (*concatenate messages, one per line, into a string*)
   813 val cat_lines = space_implode "\n";
   814 
   815 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   816 fun space_explode _ "" = []
   817   | space_explode sep str =
   818       let
   819         fun expl chs =
   820           (case take_prefix (not_equal sep) chs of
   821             (cs, []) => [implode cs]
   822           | (cs, _ :: cs') => implode cs :: expl cs');
   823       in expl (explode str) end;
   824 
   825 val split_lines = space_explode "\n";
   826 
   827 fun prefix_lines "" txt = txt
   828   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   829 
   830 fun untabify chs =
   831   let
   832     val tab_width = 8;
   833 
   834     fun untab (_, "\n") = (0, ["\n"])
   835       | untab (pos, "\t") =
   836           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   837       | untab (pos, c) = (pos + 1, [c]);
   838   in
   839     if not (exists (equal "\t") chs) then chs
   840     else flat (#2 (foldl_map untab (0, chs)))
   841   end;
   842 
   843 fun suffix sffx s = s ^ sffx;
   844 
   845 fun unsuffix sffx s =
   846   let val m = size sffx; val n = size s - m in
   847     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   848     else raise Fail "unsuffix"
   849   end;
   850 
   851 fun unprefix prfx s =
   852   let val m = size prfx; val n = size s - m in
   853     if String.isPrefix prfx s then String.substring (s, m, n)
   854     else raise Fail "unprefix"
   855   end;
   856 
   857 fun replicate_string 0 _ = ""
   858   | replicate_string 1 a = a
   859   | replicate_string k a =
   860       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   861       else replicate_string (k div 2) (a ^ a) ^ a;
   862 
   863 
   864 
   865 (** lists as sets -- see also Pure/General/ord_list.ML **)
   866 
   867 (*membership in a list*)
   868 fun x mem [] = false
   869   | x mem (y :: ys) = x = y orelse x mem ys;
   870 
   871 (*membership in a list, optimized version for ints*)
   872 fun (x:int) mem_int [] = false
   873   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   874 
   875 (*membership in a list, optimized version for strings*)
   876 fun (x:string) mem_string [] = false
   877   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   878 
   879 (*generalized membership test*)
   880 fun gen_mem eq (x, []) = false
   881   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   882 
   883 (*member, insert, and remove -- with canonical argument order*)
   884 fun member eq xs x = gen_mem eq (x, xs);
   885 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   886 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   887 
   888 (*insertion into list if not already there*)
   889 fun (x ins xs) = if x mem xs then xs else x :: xs;
   890 
   891 (*insertion into list, optimized version for ints*)
   892 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   893 
   894 (*insertion into list, optimized version for strings*)
   895 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   896 
   897 (*generalized insertion*)
   898 fun gen_ins eq (x, xs) = insert eq x xs;
   899 
   900 (*union of sets represented as lists: no repetitions*)
   901 fun xs union [] = xs
   902   | [] union ys = ys
   903   | (x :: xs) union ys = xs union (x ins ys);
   904 
   905 (*union of sets, optimized version for ints*)
   906 fun (xs:int list) union_int [] = xs
   907   | [] union_int ys = ys
   908   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   909 
   910 (*union of sets, optimized version for strings*)
   911 fun (xs:string list) union_string [] = xs
   912   | [] union_string ys = ys
   913   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   914 
   915 (*generalized union*)
   916 fun gen_union eq (xs, []) = xs
   917   | gen_union eq ([], ys) = ys
   918   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   919 
   920 
   921 (*intersection*)
   922 fun [] inter ys = []
   923   | (x :: xs) inter ys =
   924       if x mem ys then x :: (xs inter ys) else xs inter ys;
   925 
   926 (*intersection, optimized version for ints*)
   927 fun ([]:int list) inter_int ys = []
   928   | (x :: xs) inter_int ys =
   929       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   930 
   931 (*intersection, optimized version for strings *)
   932 fun ([]:string list) inter_string ys = []
   933   | (x :: xs) inter_string ys =
   934       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   935 
   936 (*generalized intersection*)
   937 fun gen_inter eq ([], ys) = []
   938   | gen_inter eq (x::xs, ys) =
   939       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   940                            else      gen_inter eq (xs, ys);
   941 
   942 
   943 (*subset*)
   944 fun [] subset ys = true
   945   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   946 
   947 (*subset, optimized version for ints*)
   948 fun ([]: int list) subset_int ys = true
   949   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   950 
   951 (*subset, optimized version for strings*)
   952 fun ([]: string list) subset_string ys = true
   953   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   954 
   955 (*set equality*)
   956 fun eq_set (xs, ys) =
   957   xs = ys orelse (xs subset ys andalso ys subset xs);
   958 
   959 (*set equality for strings*)
   960 fun eq_set_string ((xs: string list), ys) =
   961   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   962 
   963 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   964 
   965 
   966 (*removing an element from a list WITHOUT duplicates*)
   967 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   968   | [] \ x = [];
   969 
   970 fun ys \\ xs = foldl (op \) (ys,xs);
   971 
   972 (*removing an element from a list -- possibly WITH duplicates*)
   973 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   974 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   975 
   976 (*makes a list of the distinct members of the input; preserves order, takes
   977   first of equal elements*)
   978 fun gen_distinct eq lst =
   979   let
   980     val memb = gen_mem eq;
   981 
   982     fun dist (rev_seen, []) = rev rev_seen
   983       | dist (rev_seen, x :: xs) =
   984           if memb (x, rev_seen) then dist (rev_seen, xs)
   985           else dist (x :: rev_seen, xs);
   986   in
   987     dist ([], lst)
   988   end;
   989 
   990 fun distinct l = gen_distinct (op =) l;
   991 
   992 (*returns the tail beginning with the first repeated element, or []*)
   993 fun findrep [] = []
   994   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   995 
   996 
   997 (*returns a list containing all repeated elements exactly once; preserves
   998   order, takes first of equal elements*)
   999 fun gen_duplicates eq lst =
  1000   let
  1001     val memb = gen_mem eq;
  1002 
  1003     fun dups (rev_dups, []) = rev rev_dups
  1004       | dups (rev_dups, x :: xs) =
  1005           if memb (x, rev_dups) orelse not (memb (x, xs)) then
  1006             dups (rev_dups, xs)
  1007           else dups (x :: rev_dups, xs);
  1008   in
  1009     dups ([], lst)
  1010   end;
  1011 
  1012 fun duplicates l = gen_duplicates (op =) l;
  1013 
  1014 fun has_duplicates eq =
  1015   let
  1016     fun dups [] = false
  1017       | dups (x :: xs) = member eq xs x orelse dups xs;
  1018   in dups end;
  1019 
  1020 
  1021 
  1022 (** association lists **)
  1023 
  1024 (*association list lookup*)
  1025 fun assoc ([], key) = NONE
  1026   | assoc ((keyi, xi) :: pairs, key) =
  1027       if key = keyi then SOME xi else assoc (pairs, key);
  1028 
  1029 (*association list lookup, optimized version for ints*)
  1030 fun assoc_int ([], (key:int)) = NONE
  1031   | assoc_int ((keyi, xi) :: pairs, key) =
  1032       if key = keyi then SOME xi else assoc_int (pairs, key);
  1033 
  1034 (*association list lookup, optimized version for strings*)
  1035 fun assoc_string ([], (key:string)) = NONE
  1036   | assoc_string ((keyi, xi) :: pairs, key) =
  1037       if key = keyi then SOME xi else assoc_string (pairs, key);
  1038 
  1039 (*association list lookup, optimized version for string*ints*)
  1040 fun assoc_string_int ([], (key:string*int)) = NONE
  1041   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1042       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1043 
  1044 fun assocs ps x =
  1045   (case assoc (ps, x) of
  1046     NONE => []
  1047   | SOME ys => ys);
  1048 
  1049 (*two-fold association list lookup*)
  1050 fun assoc2 (aal, (key1, key2)) =
  1051   (case assoc (aal, key1) of
  1052     SOME al => assoc (al, key2)
  1053   | NONE => NONE);
  1054 
  1055 (*generalized association list lookup*)
  1056 fun gen_assoc eq ([], key) = NONE
  1057   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1058       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1059 
  1060 (*association list update*)
  1061 fun overwrite (al, p as (key, _)) =
  1062   let fun over ((q as (keyi, _)) :: pairs) =
  1063             if keyi = key then p :: pairs else q :: (over pairs)
  1064         | over [] = [p]
  1065   in over al end;
  1066 
  1067 fun gen_overwrite eq (al, p as (key, _)) =
  1068   let fun over ((q as (keyi, _)) :: pairs) =
  1069             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1070         | over [] = [p]
  1071   in over al end;
  1072 
  1073 
  1074 (* lists as tables *)
  1075 
  1076 fun gen_merge_lists _ xs [] = xs
  1077   | gen_merge_lists _ [] ys = ys
  1078   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1079 
  1080 fun gen_merge_lists' _ xs [] = xs
  1081   | gen_merge_lists' _ [] ys = ys
  1082   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1083 
  1084 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1085 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1086 fun merge_alists al = gen_merge_lists eq_fst al;
  1087 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1088 
  1089 
  1090 
  1091 (** balanced trees **)
  1092 
  1093 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1094 
  1095 (*balanced folding; avoids deep nesting*)
  1096 fun fold_bal f [x] = x
  1097   | fold_bal f [] = raise Balance
  1098   | fold_bal f xs =
  1099       let val (ps,qs) = splitAt(length xs div 2, xs)
  1100       in  f (fold_bal f ps, fold_bal f qs)  end;
  1101 
  1102 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1103 fun access_bal (f, g, x) n i =
  1104   let fun acc n i =     (*1<=i<=n*)
  1105           if n=1 then x else
  1106           let val n2 = n div 2
  1107           in  if i<=n2 then f (acc n2 i)
  1108                        else g (acc (n-n2) (i-n2))
  1109           end
  1110   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1111 
  1112 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1113 fun accesses_bal (f, g, x) n =
  1114   let fun acc n =
  1115           if n=1 then [x] else
  1116           let val n2 = n div 2
  1117               val acc2 = acc n2
  1118           in  if n-n2=n2 then map f acc2 @ map g acc2
  1119                          else map f acc2 @ map g (acc (n-n2)) end
  1120   in  if 1<=n then acc n else raise Balance  end;
  1121 
  1122 
  1123 
  1124 (** orders **)
  1125 
  1126 fun rev_order LESS = GREATER
  1127   | rev_order EQUAL = EQUAL
  1128   | rev_order GREATER = LESS;
  1129 
  1130 (*assume rel is a linear strict order*)
  1131 fun make_ord rel (x, y) =
  1132   if rel (x, y) then LESS
  1133   else if rel (y, x) then GREATER
  1134   else EQUAL;
  1135 
  1136 val int_ord = Int.compare;
  1137 val string_ord = String.compare;
  1138 
  1139 fun fast_string_ord (s1, s2) =
  1140   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1141 
  1142 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1143   | option_ord _ (NONE, NONE) = EQUAL
  1144   | option_ord _ (NONE, SOME _) = LESS
  1145   | option_ord _ (SOME _, NONE) = GREATER;
  1146 
  1147 (*lexicographic product*)
  1148 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1149   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1150 
  1151 (*dictionary order -- in general NOT well-founded!*)
  1152 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1153       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1154   | dict_ord _ ([], []) = EQUAL
  1155   | dict_ord _ ([], _ :: _) = LESS
  1156   | dict_ord _ (_ :: _, []) = GREATER;
  1157 
  1158 (*lexicographic product of lists*)
  1159 fun list_ord elem_ord (xs, ys) =
  1160   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1161 
  1162 
  1163 (* sorting *)
  1164 
  1165 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1166 fun sort ord =
  1167   let
  1168     fun qsort [] = []
  1169       | qsort (xs as [_]) = xs
  1170       | qsort (xs as [x, y]) = if ord (x, y) = GREATER then [y, x] else xs
  1171       | qsort xs =
  1172           let val (lts, eqs, gts) = part (nth_elem (length xs div 2, xs)) xs
  1173           in qsort lts @ eqs @ qsort gts end
  1174     and part _ [] = ([], [], [])
  1175       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1176     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1177       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1178       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1179   in qsort end;
  1180 
  1181 (*sort strings*)
  1182 val sort_strings = sort string_ord;
  1183 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1184 
  1185 fun unique_strings ([]: string list) = []
  1186   | unique_strings [x] = [x]
  1187   | unique_strings (x :: y :: ys) =
  1188       if x = y then unique_strings (y :: ys)
  1189       else x :: unique_strings (y :: ys);
  1190 
  1191 
  1192 (** random numbers **)
  1193 
  1194 exception RANDOM;
  1195 
  1196 fun rmod x y = x - y * Real.realFloor (x / y);
  1197 
  1198 local
  1199   val a = 16807.0;
  1200   val m = 2147483647.0;
  1201   val random_seed = ref 1.0;
  1202 in
  1203 
  1204 fun random () =
  1205   let val r = rmod (a * !random_seed) m
  1206   in (random_seed := r; r) end;
  1207 
  1208 end;
  1209 
  1210 fun random_range l h =
  1211   if h < l orelse l < 0 then raise RANDOM
  1212   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1213 
  1214 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1215 
  1216 fun frequency xs =
  1217   let
  1218     val sum = foldl op + (0, map fst xs);
  1219     fun pick n ((k, x) :: xs) =
  1220       if n <= k then x else pick (n - k) xs
  1221   in pick (random_range 1 sum) xs end;
  1222 
  1223 
  1224 (** current directory **)
  1225 
  1226 val cd = OS.FileSys.chDir;
  1227 val pwd = OS.FileSys.getDir;
  1228 
  1229 
  1230 
  1231 (** rational numbers **)
  1232 (* Keep them normalized! *)
  1233 
  1234 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1235 
  1236 exception RAT of string;
  1237 
  1238 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1239 
  1240 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1241   let val absp = abs p
  1242       val m = gcd(absp,q)
  1243   in Rat(a = (0 <= p), absp div m, q div m) end;
  1244 
  1245 fun ratcommon(p,q,r,s) =
  1246   let val den = lcm(q,s)
  1247   in (p*(den div q), r*(den div s), den) end
  1248 
  1249 fun ratge0(Rat(a,p,q)) = a;
  1250 fun ratgt0(Rat(a,p,q)) = a andalso p > 0;
  1251 
  1252 fun ratle(Rat(a,p,q),Rat(b,r,s)) =
  1253   not a andalso b orelse
  1254   a = b andalso
  1255     let val (p,r,_) = ratcommon(p,q,r,s)
  1256     in if a then p <= r else r <= p end
  1257 
  1258 fun ratlt(Rat(a,p,q),Rat(b,r,s)) =
  1259   not a andalso b orelse
  1260   a = b andalso
  1261     let val (p,r,_) = ratcommon(p,q,r,s)
  1262     in if a then p < r else r < p end
  1263 
  1264 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1265   let val (p,q,den) = ratcommon(p,q,r,s)
  1266       val num = (if a then p else ~p) + (if b then r else ~r)
  1267   in ratnorm(true,num,den) end;
  1268 
  1269 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1270 
  1271 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1272 
  1273 fun int_ratdiv(p,q) =
  1274   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1275 
  1276 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1277 
  1278 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1279 
  1280 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1281 
  1282 val rat0 = rat_of_int 0; 
  1283 
  1284 (** misc **)
  1285 
  1286 (*use the keyfun to make a list of (x, key) pairs*)
  1287 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1288   let fun keypair x = (x, keyfun x)
  1289   in map keypair end;
  1290 
  1291 (*given a list of (x, key) pairs and a searchkey
  1292   return the list of xs from each pair whose key equals searchkey*)
  1293 fun keyfilter [] searchkey = []
  1294   | keyfilter ((x, key) :: pairs) searchkey =
  1295       if key = searchkey then x :: keyfilter pairs searchkey
  1296       else keyfilter pairs searchkey;
  1297 
  1298 
  1299 (*Partition list into elements that satisfy predicate and those that don't.
  1300   Preserves order of elements in both lists.*)
  1301 val partition = List.partition;
  1302 
  1303 fun partition_eq (eq:'a * 'a -> bool) =
  1304   let
  1305     fun part [] = []
  1306       | part (x :: ys) =
  1307           let val (xs, xs') = partition (fn y => eq (x, y)) ys
  1308           in (x::xs)::(part xs') end
  1309   in part end;
  1310 
  1311 
  1312 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1313    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1314 fun partition_list p i j =
  1315   let fun part k xs =
  1316             if k>j then
  1317               (case xs of [] => []
  1318                          | _ => raise Fail "partition_list")
  1319             else
  1320             let val (ns, rest) = partition (p k) xs;
  1321             in  ns :: part(k+1)rest  end
  1322   in  part i end;
  1323 
  1324 
  1325 (* generating identifiers *)
  1326 
  1327 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1328 local
  1329 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1330 fun char i =      if i<26 then chr (ord "A" + i)
  1331              else if i<52 then chr (ord "a" + i - 26)
  1332              else if i<62 then chr (ord"0" + i - 52)
  1333              else if i=62 then "_"
  1334              else  (*i=63*)    "'";
  1335 
  1336 val charVec = Vector.tabulate (64, char);
  1337 
  1338 fun newid n =
  1339   let
  1340   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1341 
  1342 val seedr = ref 0;
  1343 
  1344 in
  1345 
  1346 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1347 
  1348 end;
  1349 
  1350 
  1351 (* lexical scanning *)
  1352 
  1353 (*scan a list of characters into "words" composed of "letters" (recognized by
  1354   is_let) and separated by any number of non-"letters"*)
  1355 fun scanwords is_let cs =
  1356   let fun scan1 [] = []
  1357         | scan1 cs =
  1358             let val (lets, rest) = take_prefix is_let cs
  1359             in implode lets :: scanwords is_let rest end;
  1360   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1361 
  1362 
  1363 (* stamps and serial numbers *)
  1364 
  1365 type stamp = unit ref;
  1366 val stamp: unit -> stamp = ref;
  1367 
  1368 type serial = int;
  1369 local val count = ref 0
  1370 in fun serial () = inc count end;
  1371 
  1372 
  1373 (* generic objects *)
  1374 
  1375 (*note that the builtin exception datatype may be extended by new
  1376   constructors at any time*)
  1377 structure Object = struct type T = exn end;
  1378 
  1379 end;
  1380 
  1381 structure BasicLibrary: BASIC_LIBRARY = Library;
  1382 open BasicLibrary;