src/HOL/Orderings.thy
author ballarin
Thu Sep 27 17:28:05 2007 +0200 (2007-09-27)
changeset 24741 a53f5db5acbb
parent 24704 9a95634ab135
child 24748 ee0a0eb6b738
permissions -rw-r--r--
Fixed setup of transitivity reasoner (function decomp).
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports Set Fun
    10 uses
    11   "~~/src/Provers/order.ML"
    12 begin
    13 
    14 subsection {* Partial orders *}
    15 
    16 class order = ord +
    17   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    18   and order_refl [iff]: "x \<sqsubseteq> x"
    19   and order_trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    20   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
    21 
    22 begin
    23 
    24 text {* Reflexivity. *}
    25 
    26 lemma eq_refl: "x = y \<Longrightarrow> x \<^loc>\<le> y"
    27     -- {* This form is useful with the classical reasoner. *}
    28 by (erule ssubst) (rule order_refl)
    29 
    30 lemma less_irrefl [iff]: "\<not> x \<^loc>< x"
    31 by (simp add: less_le)
    32 
    33 lemma le_less: "x \<^loc>\<le> y \<longleftrightarrow> x \<^loc>< y \<or> x = y"
    34     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    35 by (simp add: less_le) blast
    36 
    37 lemma le_imp_less_or_eq: "x \<^loc>\<le> y \<Longrightarrow> x \<^loc>< y \<or> x = y"
    38 unfolding less_le by blast
    39 
    40 lemma less_imp_le: "x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y"
    41 unfolding less_le by blast
    42 
    43 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    44 by (erule contrapos_pn, erule subst, rule less_irrefl)
    45 
    46 
    47 text {* Useful for simplification, but too risky to include by default. *}
    48 
    49 lemma less_imp_not_eq: "x \<^loc>< y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
    50 by auto
    51 
    52 lemma less_imp_not_eq2: "x \<^loc>< y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
    53 by auto
    54 
    55 
    56 text {* Transitivity rules for calculational reasoning *}
    57 
    58 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<^loc>\<le> b \<Longrightarrow> a \<^loc>< b"
    59 by (simp add: less_le)
    60 
    61 lemma le_neq_trans: "a \<^loc>\<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<^loc>< b"
    62 by (simp add: less_le)
    63 
    64 
    65 text {* Asymmetry. *}
    66 
    67 lemma less_not_sym: "x \<^loc>< y \<Longrightarrow> \<not> (y \<^loc>< x)"
    68 by (simp add: less_le antisym)
    69 
    70 lemma less_asym: "x \<^loc>< y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<^loc>< x) \<Longrightarrow> P"
    71 by (drule less_not_sym, erule contrapos_np) simp
    72 
    73 lemma eq_iff: "x = y \<longleftrightarrow> x \<^loc>\<le> y \<and> y \<^loc>\<le> x"
    74 by (blast intro: antisym)
    75 
    76 lemma antisym_conv: "y \<^loc>\<le> x \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
    77 by (blast intro: antisym)
    78 
    79 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    80 by (erule contrapos_pn, erule subst, rule less_irrefl)
    81 
    82 
    83 text {* Transitivity. *}
    84 
    85 lemma less_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    86 by (simp add: less_le) (blast intro: order_trans antisym)
    87 
    88 lemma le_less_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    89 by (simp add: less_le) (blast intro: order_trans antisym)
    90 
    91 lemma less_le_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>< z"
    92 by (simp add: less_le) (blast intro: order_trans antisym)
    93 
    94 
    95 text {* Useful for simplification, but too risky to include by default. *}
    96 
    97 lemma less_imp_not_less: "x \<^loc>< y \<Longrightarrow> (\<not> y \<^loc>< x) \<longleftrightarrow> True"
    98 by (blast elim: less_asym)
    99 
   100 lemma less_imp_triv: "x \<^loc>< y \<Longrightarrow> (y \<^loc>< x \<longrightarrow> P) \<longleftrightarrow> True"
   101 by (blast elim: less_asym)
   102 
   103 
   104 text {* Transitivity rules for calculational reasoning *}
   105 
   106 lemma less_asym': "a \<^loc>< b \<Longrightarrow> b \<^loc>< a \<Longrightarrow> P"
   107 by (rule less_asym)
   108 
   109 
   110 text {* Reverse order *}
   111 
   112 lemma order_reverse:
   113   "order (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   114 by unfold_locales
   115    (simp add: less_le, auto intro: antisym order_trans)
   116 
   117 end
   118 
   119 
   120 subsection {* Linear (total) orders *}
   121 
   122 class linorder = order +
   123   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   124 begin
   125 
   126 lemma less_linear: "x \<^loc>< y \<or> x = y \<or> y \<^loc>< x"
   127 unfolding less_le using less_le linear by blast
   128 
   129 lemma le_less_linear: "x \<^loc>\<le> y \<or> y \<^loc>< x"
   130 by (simp add: le_less less_linear)
   131 
   132 lemma le_cases [case_names le ge]:
   133   "(x \<^loc>\<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>\<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   134 using linear by blast
   135 
   136 lemma linorder_cases [case_names less equal greater]:
   137   "(x \<^loc>< y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> P) \<Longrightarrow> P"
   138 using less_linear by blast
   139 
   140 lemma not_less: "\<not> x \<^loc>< y \<longleftrightarrow> y \<^loc>\<le> x"
   141 apply (simp add: less_le)
   142 using linear apply (blast intro: antisym)
   143 done
   144 
   145 lemma not_less_iff_gr_or_eq:
   146  "\<not>(x \<^loc>< y) \<longleftrightarrow> (x \<^loc>> y | x = y)"
   147 apply(simp add:not_less le_less)
   148 apply blast
   149 done
   150 
   151 lemma not_le: "\<not> x \<^loc>\<le> y \<longleftrightarrow> y \<^loc>< x"
   152 apply (simp add: less_le)
   153 using linear apply (blast intro: antisym)
   154 done
   155 
   156 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<^loc>< y \<or> y \<^loc>< x"
   157 by (cut_tac x = x and y = y in less_linear, auto)
   158 
   159 lemma neqE: "x \<noteq> y \<Longrightarrow> (x \<^loc>< y \<Longrightarrow> R) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> R) \<Longrightarrow> R"
   160 by (simp add: neq_iff) blast
   161 
   162 lemma antisym_conv1: "\<not> x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   163 by (blast intro: antisym dest: not_less [THEN iffD1])
   164 
   165 lemma antisym_conv2: "x \<^loc>\<le> y \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   166 by (blast intro: antisym dest: not_less [THEN iffD1])
   167 
   168 lemma antisym_conv3: "\<not> y \<^loc>< x \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   169 by (blast intro: antisym dest: not_less [THEN iffD1])
   170 
   171 text{*Replacing the old Nat.leI*}
   172 lemma leI: "\<not> x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x"
   173 unfolding not_less .
   174 
   175 lemma leD: "y \<^loc>\<le> x \<Longrightarrow> \<not> x \<^loc>< y"
   176 unfolding not_less .
   177 
   178 (*FIXME inappropriate name (or delete altogether)*)
   179 lemma not_leE: "\<not> y \<^loc>\<le> x \<Longrightarrow> x \<^loc>< y"
   180 unfolding not_le .
   181 
   182 
   183 text {* Reverse order *}
   184 
   185 lemma linorder_reverse:
   186   "linorder (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   187 by unfold_locales
   188   (simp add: less_le, auto intro: antisym order_trans simp add: linear)
   189 
   190 
   191 text {* min/max *}
   192 
   193 text {* for historic reasons, definitions are done in context ord *}
   194 
   195 definition (in ord)
   196   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   197   [code unfold, code inline del]: "min a b = (if a \<^loc>\<le> b then a else b)"
   198 
   199 definition (in ord)
   200   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   201   [code unfold, code inline del]: "max a b = (if a \<^loc>\<le> b then b else a)"
   202 
   203 lemma min_le_iff_disj:
   204   "min x y \<^loc>\<le> z \<longleftrightarrow> x \<^loc>\<le> z \<or> y \<^loc>\<le> z"
   205 unfolding min_def using linear by (auto intro: order_trans)
   206 
   207 lemma le_max_iff_disj:
   208   "z \<^loc>\<le> max x y \<longleftrightarrow> z \<^loc>\<le> x \<or> z \<^loc>\<le> y"
   209 unfolding max_def using linear by (auto intro: order_trans)
   210 
   211 lemma min_less_iff_disj:
   212   "min x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<or> y \<^loc>< z"
   213 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   214 
   215 lemma less_max_iff_disj:
   216   "z \<^loc>< max x y \<longleftrightarrow> z \<^loc>< x \<or> z \<^loc>< y"
   217 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   218 
   219 lemma min_less_iff_conj [simp]:
   220   "z \<^loc>< min x y \<longleftrightarrow> z \<^loc>< x \<and> z \<^loc>< y"
   221 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   222 
   223 lemma max_less_iff_conj [simp]:
   224   "max x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<and> y \<^loc>< z"
   225 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   226 
   227 lemma split_min [noatp]:
   228   "P (min i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P i) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P j)"
   229 by (simp add: min_def)
   230 
   231 lemma split_max [noatp]:
   232   "P (max i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P j) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P i)"
   233 by (simp add: max_def)
   234 
   235 end
   236 
   237 
   238 subsection {* Reasoning tools setup *}
   239 
   240 ML {*
   241 
   242 signature ORDERS =
   243 sig
   244   val print_structures: Proof.context -> unit
   245   val setup: theory -> theory
   246   val order_tac: thm list -> Proof.context -> int -> tactic
   247 end;
   248 
   249 structure Orders: ORDERS =
   250 struct
   251 
   252 (** Theory and context data **)
   253 
   254 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   255   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   256 
   257 structure Data = GenericDataFun
   258 (
   259   type T = ((string * term list) * Order_Tac.less_arith) list;
   260     (* Order structures:
   261        identifier of the structure, list of operations and record of theorems
   262        needed to set up the transitivity reasoner,
   263        identifier and operations identify the structure uniquely. *)
   264   val empty = [];
   265   val extend = I;
   266   fun merge _ = AList.join struct_eq (K fst);
   267 );
   268 
   269 fun print_structures ctxt =
   270   let
   271     val structs = Data.get (Context.Proof ctxt);
   272     fun pretty_term t = Pretty.block
   273       [Pretty.quote (ProofContext.pretty_term ctxt t), Pretty.brk 1,
   274         Pretty.str "::", Pretty.brk 1,
   275         Pretty.quote (ProofContext.pretty_typ ctxt (type_of t))];
   276     fun pretty_struct ((s, ts), _) = Pretty.block
   277       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   278        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   279   in
   280     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   281   end;
   282 
   283 
   284 (** Method **)
   285 
   286 fun struct_tac ((s, [eq, le, less]), thms) prems =
   287   let
   288     fun decomp thy (Trueprop $ t) =
   289       let
   290         fun excluded t =
   291           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   292           let val T = type_of t
   293           in
   294 	    T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   295           end;
   296 	fun rel (bin_op $ t1 $ t2) =
   297               if excluded t1 then NONE
   298               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   299               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   300               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   301               else NONE
   302 	  | rel _ = NONE;
   303 	fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   304 	      of NONE => NONE
   305 	       | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   306           | dec x = rel x;
   307       in dec t end;
   308   in
   309     case s of
   310       "order" => Order_Tac.partial_tac decomp thms prems
   311     | "linorder" => Order_Tac.linear_tac decomp thms prems
   312     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   313   end
   314 
   315 fun order_tac prems ctxt =
   316   FIRST' (map (fn s => CHANGED o struct_tac s prems) (Data.get (Context.Proof ctxt)));
   317 
   318 
   319 (** Attribute **)
   320 
   321 fun add_struct_thm s tag =
   322   Thm.declaration_attribute
   323     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   324 fun del_struct s =
   325   Thm.declaration_attribute
   326     (fn _ => Data.map (AList.delete struct_eq s));
   327 
   328 val attribute = Attrib.syntax
   329      (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) ||
   330           Args.del >> K NONE) --| Args.colon (* FIXME ||
   331         Scan.succeed true *) ) -- Scan.lift Args.name --
   332       Scan.repeat Args.term
   333       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   334            | ((NONE, n), ts) => del_struct (n, ts)));
   335 
   336 
   337 (** Diagnostic command **)
   338 
   339 val print = Toplevel.unknown_context o
   340   Toplevel.keep (Toplevel.node_case
   341     (Context.cases (print_structures o ProofContext.init) print_structures)
   342     (print_structures o Proof.context_of));
   343 
   344 val printP =
   345   OuterSyntax.improper_command "print_orders"
   346     "print order structures available to transitivity reasoner" OuterKeyword.diag
   347     (Scan.succeed (Toplevel.no_timing o print));
   348 
   349 
   350 (** Setup **)
   351 
   352 val setup = let val _ = OuterSyntax.add_parsers [printP] in
   353     Method.add_methods [("order", Method.ctxt_args (Method.SIMPLE_METHOD' o order_tac []),
   354       "normalisation of algebraic structure")] #>
   355     Attrib.add_attributes [("order", attribute, "theorems controlling transitivity reasoner")]
   356   end;
   357 
   358 end;
   359 
   360 *}
   361 
   362 setup Orders.setup
   363 
   364 
   365 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   366 
   367 (* The type constraint on @{term op =} below is necessary since the operation
   368    is not a parameter of the locale. *)
   369 lemmas (in order)
   370   [order add less_reflE: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   371   less_irrefl [THEN notE]
   372 lemmas (in order)
   373   [order add le_refl: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   374   order_refl
   375 lemmas (in order)
   376   [order add less_imp_le: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   377   less_imp_le
   378 lemmas (in order)
   379   [order add eqI: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   380   antisym
   381 lemmas (in order)
   382   [order add eqD1: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   383   eq_refl
   384 lemmas (in order)
   385   [order add eqD2: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   386   sym [THEN eq_refl]
   387 lemmas (in order)
   388   [order add less_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   389   less_trans
   390 lemmas (in order)
   391   [order add less_le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   392   less_le_trans
   393 lemmas (in order)
   394   [order add le_less_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   395   le_less_trans
   396 lemmas (in order)
   397   [order add le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   398   order_trans
   399 lemmas (in order)
   400   [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   401   le_neq_trans
   402 lemmas (in order)
   403   [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   404   neq_le_trans
   405 lemmas (in order)
   406   [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   407   less_imp_neq
   408 lemmas (in order)
   409   [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   410    eq_neq_eq_imp_neq
   411 lemmas (in order)
   412   [order add not_sym: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   413   not_sym
   414 
   415 lemmas (in linorder) [order del: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] = _
   416 
   417 lemmas (in linorder)
   418   [order add less_reflE: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   419   less_irrefl [THEN notE]
   420 lemmas (in linorder)
   421   [order add le_refl: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   422   order_refl
   423 lemmas (in linorder)
   424   [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   425   less_imp_le
   426 lemmas (in linorder)
   427   [order add not_lessI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   428   not_less [THEN iffD2]
   429 lemmas (in linorder)
   430   [order add not_leI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   431   not_le [THEN iffD2]
   432 lemmas (in linorder)
   433   [order add not_lessD: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   434   not_less [THEN iffD1]
   435 lemmas (in linorder)
   436   [order add not_leD: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   437   not_le [THEN iffD1]
   438 lemmas (in linorder)
   439   [order add eqI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   440   antisym
   441 lemmas (in linorder)
   442   [order add eqD1: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   443   eq_refl
   444 lemmas (in linorder)
   445   [order add eqD2: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   446   sym [THEN eq_refl]
   447 lemmas (in linorder)
   448   [order add less_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   449   less_trans
   450 lemmas (in linorder)
   451   [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   452   less_le_trans
   453 lemmas (in linorder)
   454   [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   455   le_less_trans
   456 lemmas (in linorder)
   457   [order add le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   458   order_trans
   459 lemmas (in linorder)
   460   [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   461   le_neq_trans
   462 lemmas (in linorder)
   463   [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   464   neq_le_trans
   465 lemmas (in linorder)
   466   [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   467   less_imp_neq
   468 lemmas (in linorder)
   469   [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   470   eq_neq_eq_imp_neq
   471 lemmas (in linorder)
   472   [order add not_sym: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   473   not_sym
   474 
   475 
   476 setup {*
   477 let
   478 
   479 fun prp t thm = (#prop (rep_thm thm) = t);
   480 
   481 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   482   let val prems = prems_of_ss ss;
   483       val less = Const (@{const_name less}, T);
   484       val t = HOLogic.mk_Trueprop(le $ s $ r);
   485   in case find_first (prp t) prems of
   486        NONE =>
   487          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   488          in case find_first (prp t) prems of
   489               NONE => NONE
   490             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   491          end
   492      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   493   end
   494   handle THM _ => NONE;
   495 
   496 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   497   let val prems = prems_of_ss ss;
   498       val le = Const (@{const_name less_eq}, T);
   499       val t = HOLogic.mk_Trueprop(le $ r $ s);
   500   in case find_first (prp t) prems of
   501        NONE =>
   502          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   503          in case find_first (prp t) prems of
   504               NONE => NONE
   505             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   506          end
   507      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   508   end
   509   handle THM _ => NONE;
   510 
   511 fun add_simprocs procs thy =
   512   (Simplifier.change_simpset_of thy (fn ss => ss
   513     addsimprocs (map (fn (name, raw_ts, proc) =>
   514       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   515 fun add_solver name tac thy =
   516   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   517     (mk_solver' name (fn ss => tac (MetaSimplifier.prems_of_ss ss) (MetaSimplifier.the_context ss)))); thy);
   518 
   519 in
   520   add_simprocs [
   521        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   522        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   523      ]
   524   #> add_solver "Transitivity" Orders.order_tac
   525   (* Adding the transitivity reasoners also as safe solvers showed a slight
   526      speed up, but the reasoning strength appears to be not higher (at least
   527      no breaking of additional proofs in the entire HOL distribution, as
   528      of 5 March 2004, was observed). *)
   529 end
   530 *}
   531 
   532 
   533 subsection {* Dense orders *}
   534 
   535 class dense_linear_order = linorder + 
   536   assumes gt_ex: "\<exists>y. x \<sqsubset> y" 
   537   and lt_ex: "\<exists>y. y \<sqsubset> x"
   538   and dense: "x \<sqsubset> y \<Longrightarrow> (\<exists>z. x \<sqsubset> z \<and> z \<sqsubset> y)"
   539   (*see further theory Dense_Linear_Order*)
   540 
   541 
   542 lemma interval_empty_iff:
   543   fixes x y z :: "'a\<Colon>dense_linear_order"
   544   shows "{y. x < y \<and> y < z} = {} \<longleftrightarrow> \<not> x < z"
   545   by (auto dest: dense)
   546 
   547 subsection {* Name duplicates *}
   548 
   549 lemmas order_less_le = less_le
   550 lemmas order_eq_refl = order_class.eq_refl
   551 lemmas order_less_irrefl = order_class.less_irrefl
   552 lemmas order_le_less = order_class.le_less
   553 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   554 lemmas order_less_imp_le = order_class.less_imp_le
   555 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   556 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   557 lemmas order_neq_le_trans = order_class.neq_le_trans
   558 lemmas order_le_neq_trans = order_class.le_neq_trans
   559 
   560 lemmas order_antisym = antisym
   561 lemmas order_less_not_sym = order_class.less_not_sym
   562 lemmas order_less_asym = order_class.less_asym
   563 lemmas order_eq_iff = order_class.eq_iff
   564 lemmas order_antisym_conv = order_class.antisym_conv
   565 lemmas order_less_trans = order_class.less_trans
   566 lemmas order_le_less_trans = order_class.le_less_trans
   567 lemmas order_less_le_trans = order_class.less_le_trans
   568 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   569 lemmas order_less_imp_triv = order_class.less_imp_triv
   570 lemmas order_less_asym' = order_class.less_asym'
   571 
   572 lemmas linorder_linear = linear
   573 lemmas linorder_less_linear = linorder_class.less_linear
   574 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   575 lemmas linorder_le_cases = linorder_class.le_cases
   576 lemmas linorder_not_less = linorder_class.not_less
   577 lemmas linorder_not_le = linorder_class.not_le
   578 lemmas linorder_neq_iff = linorder_class.neq_iff
   579 lemmas linorder_neqE = linorder_class.neqE
   580 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   581 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   582 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   583 
   584 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj
   585 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj
   586 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj
   587 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj
   588 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj
   589 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj
   590 lemmas split_min = linorder_class.split_min
   591 lemmas split_max = linorder_class.split_max
   592 
   593 
   594 subsection {* Bounded quantifiers *}
   595 
   596 syntax
   597   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   598   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   599   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   600   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   601 
   602   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   603   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   604   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   605   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   606 
   607 syntax (xsymbols)
   608   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   609   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   610   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   611   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   612 
   613   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   614   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   615   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   616   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   617 
   618 syntax (HOL)
   619   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   620   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   621   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   622   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   623 
   624 syntax (HTML output)
   625   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   626   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   627   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   628   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   629 
   630   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   631   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   632   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   633   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   634 
   635 translations
   636   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   637   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   638   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   639   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   640   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   641   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   642   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   643   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   644 
   645 print_translation {*
   646 let
   647   val All_binder = Syntax.binder_name @{const_syntax All};
   648   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   649   val impl = @{const_syntax "op -->"};
   650   val conj = @{const_syntax "op &"};
   651   val less = @{const_syntax less};
   652   val less_eq = @{const_syntax less_eq};
   653 
   654   val trans =
   655    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   656     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   657     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   658     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   659 
   660   fun matches_bound v t = 
   661      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   662               | _ => false
   663   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   664   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   665 
   666   fun tr' q = (q,
   667     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   668       (case AList.lookup (op =) trans (q, c, d) of
   669         NONE => raise Match
   670       | SOME (l, g) =>
   671           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   672           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   673           else raise Match)
   674      | _ => raise Match);
   675 in [tr' All_binder, tr' Ex_binder] end
   676 *}
   677 
   678 
   679 subsection {* Transitivity reasoning *}
   680 
   681 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   682 by (rule subst)
   683 
   684 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   685 by (rule ssubst)
   686 
   687 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   688 by (rule subst)
   689 
   690 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   691 by (rule ssubst)
   692 
   693 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   694   (!!x y. x < y ==> f x < f y) ==> f a < c"
   695 proof -
   696   assume r: "!!x y. x < y ==> f x < f y"
   697   assume "a < b" hence "f a < f b" by (rule r)
   698   also assume "f b < c"
   699   finally (order_less_trans) show ?thesis .
   700 qed
   701 
   702 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   703   (!!x y. x < y ==> f x < f y) ==> a < f c"
   704 proof -
   705   assume r: "!!x y. x < y ==> f x < f y"
   706   assume "a < f b"
   707   also assume "b < c" hence "f b < f c" by (rule r)
   708   finally (order_less_trans) show ?thesis .
   709 qed
   710 
   711 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   712   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   713 proof -
   714   assume r: "!!x y. x <= y ==> f x <= f y"
   715   assume "a <= b" hence "f a <= f b" by (rule r)
   716   also assume "f b < c"
   717   finally (order_le_less_trans) show ?thesis .
   718 qed
   719 
   720 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   721   (!!x y. x < y ==> f x < f y) ==> a < f c"
   722 proof -
   723   assume r: "!!x y. x < y ==> f x < f y"
   724   assume "a <= f b"
   725   also assume "b < c" hence "f b < f c" by (rule r)
   726   finally (order_le_less_trans) show ?thesis .
   727 qed
   728 
   729 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   730   (!!x y. x < y ==> f x < f y) ==> f a < c"
   731 proof -
   732   assume r: "!!x y. x < y ==> f x < f y"
   733   assume "a < b" hence "f a < f b" by (rule r)
   734   also assume "f b <= c"
   735   finally (order_less_le_trans) show ?thesis .
   736 qed
   737 
   738 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   739   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   740 proof -
   741   assume r: "!!x y. x <= y ==> f x <= f y"
   742   assume "a < f b"
   743   also assume "b <= c" hence "f b <= f c" by (rule r)
   744   finally (order_less_le_trans) show ?thesis .
   745 qed
   746 
   747 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   748   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   749 proof -
   750   assume r: "!!x y. x <= y ==> f x <= f y"
   751   assume "a <= f b"
   752   also assume "b <= c" hence "f b <= f c" by (rule r)
   753   finally (order_trans) show ?thesis .
   754 qed
   755 
   756 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   757   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   758 proof -
   759   assume r: "!!x y. x <= y ==> f x <= f y"
   760   assume "a <= b" hence "f a <= f b" by (rule r)
   761   also assume "f b <= c"
   762   finally (order_trans) show ?thesis .
   763 qed
   764 
   765 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   766   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   767 proof -
   768   assume r: "!!x y. x <= y ==> f x <= f y"
   769   assume "a <= b" hence "f a <= f b" by (rule r)
   770   also assume "f b = c"
   771   finally (ord_le_eq_trans) show ?thesis .
   772 qed
   773 
   774 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   775   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   776 proof -
   777   assume r: "!!x y. x <= y ==> f x <= f y"
   778   assume "a = f b"
   779   also assume "b <= c" hence "f b <= f c" by (rule r)
   780   finally (ord_eq_le_trans) show ?thesis .
   781 qed
   782 
   783 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   784   (!!x y. x < y ==> f x < f y) ==> f a < c"
   785 proof -
   786   assume r: "!!x y. x < y ==> f x < f y"
   787   assume "a < b" hence "f a < f b" by (rule r)
   788   also assume "f b = c"
   789   finally (ord_less_eq_trans) show ?thesis .
   790 qed
   791 
   792 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   793   (!!x y. x < y ==> f x < f y) ==> a < f c"
   794 proof -
   795   assume r: "!!x y. x < y ==> f x < f y"
   796   assume "a = f b"
   797   also assume "b < c" hence "f b < f c" by (rule r)
   798   finally (ord_eq_less_trans) show ?thesis .
   799 qed
   800 
   801 text {*
   802   Note that this list of rules is in reverse order of priorities.
   803 *}
   804 
   805 lemmas order_trans_rules [trans] =
   806   order_less_subst2
   807   order_less_subst1
   808   order_le_less_subst2
   809   order_le_less_subst1
   810   order_less_le_subst2
   811   order_less_le_subst1
   812   order_subst2
   813   order_subst1
   814   ord_le_eq_subst
   815   ord_eq_le_subst
   816   ord_less_eq_subst
   817   ord_eq_less_subst
   818   forw_subst
   819   back_subst
   820   rev_mp
   821   mp
   822   order_neq_le_trans
   823   order_le_neq_trans
   824   order_less_trans
   825   order_less_asym'
   826   order_le_less_trans
   827   order_less_le_trans
   828   order_trans
   829   order_antisym
   830   ord_le_eq_trans
   831   ord_eq_le_trans
   832   ord_less_eq_trans
   833   ord_eq_less_trans
   834   trans
   835 
   836 
   837 (* FIXME cleanup *)
   838 
   839 text {* These support proving chains of decreasing inequalities
   840     a >= b >= c ... in Isar proofs. *}
   841 
   842 lemma xt1:
   843   "a = b ==> b > c ==> a > c"
   844   "a > b ==> b = c ==> a > c"
   845   "a = b ==> b >= c ==> a >= c"
   846   "a >= b ==> b = c ==> a >= c"
   847   "(x::'a::order) >= y ==> y >= x ==> x = y"
   848   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   849   "(x::'a::order) > y ==> y >= z ==> x > z"
   850   "(x::'a::order) >= y ==> y > z ==> x > z"
   851   "(a::'a::order) > b ==> b > a ==> P"
   852   "(x::'a::order) > y ==> y > z ==> x > z"
   853   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   854   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   855   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   856   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   857   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   858   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   859 by auto
   860 
   861 lemma xt2:
   862   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   863 by (subgoal_tac "f b >= f c", force, force)
   864 
   865 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   866     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   867 by (subgoal_tac "f a >= f b", force, force)
   868 
   869 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   870   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   871 by (subgoal_tac "f b >= f c", force, force)
   872 
   873 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   874     (!!x y. x > y ==> f x > f y) ==> f a > c"
   875 by (subgoal_tac "f a > f b", force, force)
   876 
   877 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   878     (!!x y. x > y ==> f x > f y) ==> a > f c"
   879 by (subgoal_tac "f b > f c", force, force)
   880 
   881 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   882     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   883 by (subgoal_tac "f a >= f b", force, force)
   884 
   885 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   886     (!!x y. x > y ==> f x > f y) ==> a > f c"
   887 by (subgoal_tac "f b > f c", force, force)
   888 
   889 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   890     (!!x y. x > y ==> f x > f y) ==> f a > c"
   891 by (subgoal_tac "f a > f b", force, force)
   892 
   893 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   894 
   895 (* 
   896   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   897   for the wrong thing in an Isar proof.
   898 
   899   The extra transitivity rules can be used as follows: 
   900 
   901 lemma "(a::'a::order) > z"
   902 proof -
   903   have "a >= b" (is "_ >= ?rhs")
   904     sorry
   905   also have "?rhs >= c" (is "_ >= ?rhs")
   906     sorry
   907   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   908     sorry
   909   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   910     sorry
   911   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   912     sorry
   913   also (xtrans) have "?rhs > z"
   914     sorry
   915   finally (xtrans) show ?thesis .
   916 qed
   917 
   918   Alternatively, one can use "declare xtrans [trans]" and then
   919   leave out the "(xtrans)" above.
   920 *)
   921 
   922 subsection {* Order on bool *}
   923 
   924 instance bool :: order 
   925   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   926   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   927   by intro_classes (auto simp add: le_bool_def less_bool_def)
   928 lemmas [code func del] = le_bool_def less_bool_def
   929 
   930 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   931 by (simp add: le_bool_def)
   932 
   933 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   934 by (simp add: le_bool_def)
   935 
   936 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   937 by (simp add: le_bool_def)
   938 
   939 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   940 by (simp add: le_bool_def)
   941 
   942 lemma [code func]:
   943   "False \<le> b \<longleftrightarrow> True"
   944   "True \<le> b \<longleftrightarrow> b"
   945   "False < b \<longleftrightarrow> b"
   946   "True < b \<longleftrightarrow> False"
   947   unfolding le_bool_def less_bool_def by simp_all
   948 
   949 
   950 subsection {* Order on sets *}
   951 
   952 instance set :: (type) order
   953   by (intro_classes,
   954       (assumption | rule subset_refl subset_trans subset_antisym psubset_eq)+)
   955 
   956 lemmas basic_trans_rules [trans] =
   957   order_trans_rules set_rev_mp set_mp
   958 
   959 
   960 subsection {* Order on functions *}
   961 
   962 instance "fun" :: (type, ord) ord
   963   le_fun_def: "f \<le> g \<equiv> \<forall>x. f x \<le> g x"
   964   less_fun_def: "f < g \<equiv> f \<le> g \<and> f \<noteq> g" ..
   965 
   966 lemmas [code func del] = le_fun_def less_fun_def
   967 
   968 instance "fun" :: (type, order) order
   969   by default
   970     (auto simp add: le_fun_def less_fun_def expand_fun_eq
   971        intro: order_trans order_antisym)
   972 
   973 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
   974   unfolding le_fun_def by simp
   975 
   976 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
   977   unfolding le_fun_def by simp
   978 
   979 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
   980   unfolding le_fun_def by simp
   981 
   982 text {*
   983   Handy introduction and elimination rules for @{text "\<le>"}
   984   on unary and binary predicates
   985 *}
   986 
   987 lemma predicate1I [Pure.intro!, intro!]:
   988   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
   989   shows "P \<le> Q"
   990   apply (rule le_funI)
   991   apply (rule le_boolI)
   992   apply (rule PQ)
   993   apply assumption
   994   done
   995 
   996 lemma predicate1D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
   997   apply (erule le_funE)
   998   apply (erule le_boolE)
   999   apply assumption+
  1000   done
  1001 
  1002 lemma predicate2I [Pure.intro!, intro!]:
  1003   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1004   shows "P \<le> Q"
  1005   apply (rule le_funI)+
  1006   apply (rule le_boolI)
  1007   apply (rule PQ)
  1008   apply assumption
  1009   done
  1010 
  1011 lemma predicate2D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1012   apply (erule le_funE)+
  1013   apply (erule le_boolE)
  1014   apply assumption+
  1015   done
  1016 
  1017 lemma rev_predicate1D: "P x ==> P <= Q ==> Q x"
  1018   by (rule predicate1D)
  1019 
  1020 lemma rev_predicate2D: "P x y ==> P <= Q ==> Q x y"
  1021   by (rule predicate2D)
  1022 
  1023 
  1024 subsection {* Monotonicity, least value operator and min/max *}
  1025 
  1026 locale mono =
  1027   fixes f
  1028   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
  1029 
  1030 lemmas monoI [intro?] = mono.intro
  1031   and monoD [dest?] = mono.mono
  1032 
  1033 lemma LeastI2_order:
  1034   "[| P (x::'a::order);
  1035       !!y. P y ==> x <= y;
  1036       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
  1037    ==> Q (Least P)"
  1038 apply (unfold Least_def)
  1039 apply (rule theI2)
  1040   apply (blast intro: order_antisym)+
  1041 done
  1042 
  1043 lemma Least_mono:
  1044   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1045     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1046     -- {* Courtesy of Stephan Merz *}
  1047   apply clarify
  1048   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  1049   apply (rule LeastI2_order)
  1050   apply (auto elim: monoD intro!: order_antisym)
  1051   done
  1052 
  1053 lemma Least_equality:
  1054   "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
  1055 apply (simp add: Least_def)
  1056 apply (rule the_equality)
  1057 apply (auto intro!: order_antisym)
  1058 done
  1059 
  1060 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
  1061 by (simp add: min_def)
  1062 
  1063 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
  1064 by (simp add: max_def)
  1065 
  1066 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
  1067 apply (simp add: min_def)
  1068 apply (blast intro: order_antisym)
  1069 done
  1070 
  1071 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
  1072 apply (simp add: max_def)
  1073 apply (blast intro: order_antisym)
  1074 done
  1075 
  1076 lemma min_of_mono:
  1077   "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
  1078 by (simp add: min_def)
  1079 
  1080 lemma max_of_mono:
  1081   "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
  1082 by (simp add: max_def)
  1083 
  1084 
  1085 subsection {* legacy ML bindings *}
  1086 
  1087 ML {*
  1088 val monoI = @{thm monoI};
  1089 *}
  1090 
  1091 end