src/Tools/Code/code_thingol.ML
author haftmann
Tue Jun 15 11:38:40 2010 +0200 (2010-06-15)
changeset 37440 a5d44161ba2a
parent 37437 4202e11ae7dc
child 37445 e372fa3c7239
permissions -rw-r--r--
maintain cong rules for case combinators; more precise permissiveness
     1 (*  Title:      Tools/code/code_thingol.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Intermediate language ("Thin-gol") representing executable code.
     5 Representation and translation.
     6 *)
     7 
     8 infix 8 `%%;
     9 infix 4 `$;
    10 infix 4 `$$;
    11 infixr 3 `|=>;
    12 infixr 3 `|==>;
    13 
    14 signature BASIC_CODE_THINGOL =
    15 sig
    16   type vname = string;
    17   datatype dict =
    18       DictConst of string * dict list list
    19     | DictVar of string list * (vname * (int * int));
    20   datatype itype =
    21       `%% of string * itype list
    22     | ITyVar of vname;
    23   type const = string * ((itype list * dict list list) * itype list (*types of arguments*))
    24   datatype iterm =
    25       IConst of const
    26     | IVar of vname option
    27     | `$ of iterm * iterm
    28     | `|=> of (vname option * itype) * iterm
    29     | ICase of ((iterm * itype) * (iterm * iterm) list) * iterm;
    30         (*((term, type), [(selector pattern, body term )]), primitive term)*)
    31   val `$$ : iterm * iterm list -> iterm;
    32   val `|==> : (vname option * itype) list * iterm -> iterm;
    33   type typscheme = (vname * sort) list * itype;
    34 end;
    35 
    36 signature CODE_THINGOL =
    37 sig
    38   include BASIC_CODE_THINGOL
    39   val fun_tyco: string
    40   val unfoldl: ('a -> ('a * 'b) option) -> 'a -> 'a * 'b list
    41   val unfoldr: ('a -> ('b * 'a) option) -> 'a -> 'b list * 'a
    42   val unfold_fun: itype -> itype list * itype
    43   val unfold_app: iterm -> iterm * iterm list
    44   val unfold_abs: iterm -> (vname option * itype) list * iterm
    45   val split_let: iterm -> (((iterm * itype) * iterm) * iterm) option
    46   val unfold_let: iterm -> ((iterm * itype) * iterm) list * iterm
    47   val split_pat_abs: iterm -> ((iterm * itype) * iterm) option
    48   val unfold_pat_abs: iterm -> (iterm * itype) list * iterm
    49   val unfold_const_app: iterm -> (const * iterm list) option
    50   val is_IVar: iterm -> bool
    51   val eta_expand: int -> const * iterm list -> iterm
    52   val contains_dictvar: iterm -> bool
    53   val locally_monomorphic: iterm -> bool
    54   val add_constnames: iterm -> string list -> string list
    55   val add_tyconames: iterm -> string list -> string list
    56   val fold_varnames: (string -> 'a -> 'a) -> iterm -> 'a -> 'a
    57 
    58   type naming
    59   val empty_naming: naming
    60   val lookup_class: naming -> class -> string option
    61   val lookup_classrel: naming -> class * class -> string option
    62   val lookup_tyco: naming -> string -> string option
    63   val lookup_instance: naming -> class * string -> string option
    64   val lookup_const: naming -> string -> string option
    65   val ensure_declared_const: theory -> string -> naming -> string * naming
    66 
    67   datatype stmt =
    68       NoStmt
    69     | Fun of string * ((typscheme * ((iterm list * iterm) * (thm option * bool)) list) * thm option)
    70     | Datatype of string * ((vname * sort) list * (string * itype list) list)
    71     | Datatypecons of string * string
    72     | Class of class * (vname * ((class * string) list * (string * itype) list))
    73     | Classrel of class * class
    74     | Classparam of string * class
    75     | Classinst of (class * (string * (vname * sort) list) (*class and arity*) )
    76           * (((class * (string * (string * dict list list))) list (*super instances*)
    77             * (class * class) list list (*type argument weakening mapping*))
    78         * ((string * const) * (thm * bool)) list (*class parameter instances*))
    79   type program = stmt Graph.T
    80   val empty_funs: program -> string list
    81   val map_terms_bottom_up: (iterm -> iterm) -> iterm -> iterm
    82   val map_terms_stmt: (iterm -> iterm) -> stmt -> stmt
    83   val is_cons: program -> string -> bool
    84   val is_case: stmt -> bool
    85   val contr_classparam_typs: program -> string -> itype option list
    86   val labelled_name: theory -> program -> string -> string
    87   val group_stmts: theory -> program
    88     -> ((string * stmt) list * (string * stmt) list
    89       * ((string * stmt) list * (string * stmt) list)) list
    90 
    91   val read_const_exprs: theory -> string list -> string list * string list
    92   val consts_program: theory -> bool -> string list -> string list * (naming * program)
    93   val eval_conv: theory
    94     -> (naming -> program -> ((string * sort) list * typscheme) * iterm -> string list -> cterm -> thm)
    95     -> cterm -> thm
    96   val eval: theory -> ((term -> term) -> 'a -> 'a)
    97     -> (naming -> program -> ((string * sort) list * typscheme) * iterm -> string list -> 'a)
    98     -> term -> 'a
    99 end;
   100 
   101 structure Code_Thingol: CODE_THINGOL =
   102 struct
   103 
   104 (** auxiliary **)
   105 
   106 fun unfoldl dest x =
   107   case dest x
   108    of NONE => (x, [])
   109     | SOME (x1, x2) =>
   110         let val (x', xs') = unfoldl dest x1 in (x', xs' @ [x2]) end;
   111 
   112 fun unfoldr dest x =
   113   case dest x
   114    of NONE => ([], x)
   115     | SOME (x1, x2) =>
   116         let val (xs', x') = unfoldr dest x2 in (x1::xs', x') end;
   117 
   118 
   119 (** language core - types, terms **)
   120 
   121 type vname = string;
   122 
   123 datatype dict =
   124     DictConst of string * dict list list
   125   | DictVar of string list * (vname * (int * int));
   126 
   127 datatype itype =
   128     `%% of string * itype list
   129   | ITyVar of vname;
   130 
   131 type const = string * ((itype list * dict list list) * itype list (*types of arguments*))
   132 
   133 datatype iterm =
   134     IConst of const
   135   | IVar of vname option
   136   | `$ of iterm * iterm
   137   | `|=> of (vname option * itype) * iterm
   138   | ICase of ((iterm * itype) * (iterm * iterm) list) * iterm;
   139     (*see also signature*)
   140 
   141 fun is_IVar (IVar _) = true
   142   | is_IVar _ = false;
   143 
   144 val op `$$ = Library.foldl (op `$);
   145 val op `|==> = Library.foldr (op `|=>);
   146 
   147 val unfold_app = unfoldl
   148   (fn op `$ t => SOME t
   149     | _ => NONE);
   150 
   151 val unfold_abs = unfoldr
   152   (fn op `|=> t => SOME t
   153     | _ => NONE);
   154 
   155 val split_let = 
   156   (fn ICase (((td, ty), [(p, t)]), _) => SOME (((p, ty), td), t)
   157     | _ => NONE);
   158 
   159 val unfold_let = unfoldr split_let;
   160 
   161 fun unfold_const_app t =
   162  case unfold_app t
   163   of (IConst c, ts) => SOME (c, ts)
   164    | _ => NONE;
   165 
   166 fun fold_constexprs f =
   167   let
   168     fun fold' (IConst c) = f c
   169       | fold' (IVar _) = I
   170       | fold' (t1 `$ t2) = fold' t1 #> fold' t2
   171       | fold' (_ `|=> t) = fold' t
   172       | fold' (ICase (((t, _), ds), _)) = fold' t
   173           #> fold (fn (pat, body) => fold' pat #> fold' body) ds
   174   in fold' end;
   175 
   176 val add_constnames = fold_constexprs (fn (c, _) => insert (op =) c);
   177 
   178 fun add_tycos (tyco `%% tys) = insert (op =) tyco #> fold add_tycos tys
   179   | add_tycos (ITyVar _) = I;
   180 
   181 val add_tyconames = fold_constexprs (fn (_, ((tys, _), _)) => fold add_tycos tys);
   182 
   183 fun fold_varnames f =
   184   let
   185     fun fold_aux add f =
   186       let
   187         fun fold_term _ (IConst _) = I
   188           | fold_term vs (IVar (SOME v)) = if member (op =) vs v then I else f v
   189           | fold_term _ (IVar NONE) = I
   190           | fold_term vs (t1 `$ t2) = fold_term vs t1 #> fold_term vs t2
   191           | fold_term vs ((SOME v, _) `|=> t) = fold_term (insert (op =) v vs) t
   192           | fold_term vs ((NONE, _) `|=> t) = fold_term vs t
   193           | fold_term vs (ICase (((t, _), ds), _)) = fold_term vs t #> fold (fold_case vs) ds
   194         and fold_case vs (p, t) = fold_term (add p vs) t;
   195       in fold_term [] end;
   196     fun add t = fold_aux add (insert (op =)) t;
   197   in fold_aux add f end;
   198 
   199 fun exists_var t v = fold_varnames (fn w => fn b => v = w orelse b) t false;
   200 
   201 fun split_pat_abs ((NONE, ty) `|=> t) = SOME ((IVar NONE, ty), t)
   202   | split_pat_abs ((SOME v, ty) `|=> t) = SOME (case t
   203      of ICase (((IVar (SOME w), _), [(p, t')]), _) =>
   204           if v = w andalso (exists_var p v orelse not (exists_var t' v))
   205           then ((p, ty), t')
   206           else ((IVar (SOME v), ty), t)
   207       | _ => ((IVar (SOME v), ty), t))
   208   | split_pat_abs _ = NONE;
   209 
   210 val unfold_pat_abs = unfoldr split_pat_abs;
   211 
   212 fun unfold_abs_eta [] t = ([], t)
   213   | unfold_abs_eta (_ :: tys) (v_ty `|=> t) =
   214       let
   215         val (vs_tys, t') = unfold_abs_eta tys t;
   216       in (v_ty :: vs_tys, t') end
   217   | unfold_abs_eta tys t =
   218       let
   219         val ctxt = fold_varnames Name.declare t Name.context;
   220         val vs_tys = (map o apfst) SOME (Name.names ctxt "a" tys);
   221       in (vs_tys, t `$$ map (IVar o fst) vs_tys) end;
   222 
   223 fun eta_expand k (c as (_, (_, tys)), ts) =
   224   let
   225     val j = length ts;
   226     val l = k - j;
   227     val ctxt = (fold o fold_varnames) Name.declare ts Name.context;
   228     val vs_tys = (map o apfst) SOME
   229       (Name.names ctxt "a" ((take l o drop j) tys));
   230   in vs_tys `|==> IConst c `$$ ts @ map (IVar o fst) vs_tys end;
   231 
   232 fun contains_dictvar t =
   233   let
   234     fun cont_dict (DictConst (_, dss)) = (exists o exists) cont_dict dss
   235       | cont_dict (DictVar _) = true;
   236     fun cont_term (IConst (_, ((_, dss), _))) = (exists o exists) cont_dict dss
   237       | cont_term (IVar _) = false
   238       | cont_term (t1 `$ t2) = cont_term t1 orelse cont_term t2
   239       | cont_term (_ `|=> t) = cont_term t
   240       | cont_term (ICase (_, t)) = cont_term t;
   241   in cont_term t end;
   242   
   243 fun locally_monomorphic (IConst _) = false
   244   | locally_monomorphic (IVar _) = true
   245   | locally_monomorphic (t `$ _) = locally_monomorphic t
   246   | locally_monomorphic (_ `|=> t) = locally_monomorphic t
   247   | locally_monomorphic (ICase ((_, ds), _)) = exists (locally_monomorphic o snd) ds;
   248 
   249 
   250 (** namings **)
   251 
   252 (* policies *)
   253 
   254 local
   255   fun thyname_of_class thy = #theory_name o Name_Space.the_entry (Sign.class_space thy);
   256   fun thyname_of_instance thy inst = case AxClass.thynames_of_arity thy inst
   257    of [] => error ("No such instance: " ^ quote (snd inst ^ " :: " ^ fst inst))
   258     | thyname :: _ => thyname;
   259   fun thyname_of_const thy c = case AxClass.class_of_param thy c
   260    of SOME class => thyname_of_class thy class
   261     | NONE => (case Code.get_type_of_constr_or_abstr thy c
   262        of SOME (tyco, _) => Codegen.thyname_of_type thy tyco
   263         | NONE => Codegen.thyname_of_const thy c);
   264   fun purify_base "==>" = "follows"
   265     | purify_base "op &" = "and"
   266     | purify_base "op |" = "or"
   267     | purify_base "op -->" = "implies"
   268     | purify_base "op :" = "member"
   269     | purify_base "op =" = "eq"
   270     | purify_base "*" = "product"
   271     | purify_base "+" = "sum"
   272     | purify_base s = Name.desymbolize false s;
   273   fun namify thy get_basename get_thyname name =
   274     let
   275       val prefix = get_thyname thy name;
   276       val base = (purify_base o get_basename) name;
   277     in Long_Name.append prefix base end;
   278 in
   279 
   280 fun namify_class thy = namify thy Long_Name.base_name thyname_of_class;
   281 fun namify_classrel thy = namify thy (fn (sub_class, super_class) => 
   282     Long_Name.base_name super_class ^ "_" ^ Long_Name.base_name sub_class)
   283   (fn thy => thyname_of_class thy o fst);
   284   (*order fits nicely with composed projections*)
   285 fun namify_tyco thy "fun" = "Pure.fun"
   286   | namify_tyco thy tyco = namify thy Long_Name.base_name Codegen.thyname_of_type tyco;
   287 fun namify_instance thy = namify thy (fn (class, tyco) => 
   288   Long_Name.base_name class ^ "_" ^ Long_Name.base_name tyco) thyname_of_instance;
   289 fun namify_const thy = namify thy Long_Name.base_name thyname_of_const;
   290 
   291 end; (* local *)
   292 
   293 
   294 (* data *)
   295 
   296 datatype naming = Naming of {
   297   class: class Symtab.table * Name.context,
   298   classrel: string Symreltab.table * Name.context,
   299   tyco: string Symtab.table * Name.context,
   300   instance: string Symreltab.table * Name.context,
   301   const: string Symtab.table * Name.context
   302 }
   303 
   304 fun dest_Naming (Naming naming) = naming;
   305 
   306 val empty_naming = Naming {
   307   class = (Symtab.empty, Name.context),
   308   classrel = (Symreltab.empty, Name.context),
   309   tyco = (Symtab.empty, Name.context),
   310   instance = (Symreltab.empty, Name.context),
   311   const = (Symtab.empty, Name.context)
   312 };
   313 
   314 local
   315   fun mk_naming (class, classrel, tyco, instance, const) =
   316     Naming { class = class, classrel = classrel,
   317       tyco = tyco, instance = instance, const = const };
   318   fun map_naming f (Naming { class, classrel, tyco, instance, const }) =
   319     mk_naming (f (class, classrel, tyco, instance, const));
   320 in
   321   fun map_class f = map_naming
   322     (fn (class, classrel, tyco, inst, const) =>
   323       (f class, classrel, tyco, inst, const));
   324   fun map_classrel f = map_naming
   325     (fn (class, classrel, tyco, inst, const) =>
   326       (class, f classrel, tyco, inst, const));
   327   fun map_tyco f = map_naming
   328     (fn (class, classrel, tyco, inst, const) =>
   329       (class, classrel, f tyco, inst, const));
   330   fun map_instance f = map_naming
   331     (fn (class, classrel, tyco, inst, const) =>
   332       (class, classrel, tyco, f inst, const));
   333   fun map_const f = map_naming
   334     (fn (class, classrel, tyco, inst, const) =>
   335       (class, classrel, tyco, inst, f const));
   336 end; (*local*)
   337 
   338 fun add_variant update (thing, name) (tab, used) =
   339   let
   340     val (name', used') = yield_singleton Name.variants name used;
   341     val tab' = update (thing, name') tab;
   342   in (tab', used') end;
   343 
   344 fun declare thy mapp lookup update namify thing =
   345   mapp (add_variant update (thing, namify thy thing))
   346   #> `(fn naming => the (lookup naming thing));
   347 
   348 
   349 (* lookup and declare *)
   350 
   351 local
   352 
   353 val suffix_class = "class";
   354 val suffix_classrel = "classrel"
   355 val suffix_tyco = "tyco";
   356 val suffix_instance = "inst";
   357 val suffix_const = "const";
   358 
   359 fun add_suffix nsp NONE = NONE
   360   | add_suffix nsp (SOME name) = SOME (Long_Name.append name nsp);
   361 
   362 in
   363 
   364 val lookup_class = add_suffix suffix_class
   365   oo Symtab.lookup o fst o #class o dest_Naming;
   366 val lookup_classrel = add_suffix suffix_classrel
   367   oo Symreltab.lookup o fst o #classrel o dest_Naming;
   368 val lookup_tyco = add_suffix suffix_tyco
   369   oo Symtab.lookup o fst o #tyco o dest_Naming;
   370 val lookup_instance = add_suffix suffix_instance
   371   oo Symreltab.lookup o fst o #instance o dest_Naming;
   372 val lookup_const = add_suffix suffix_const
   373   oo Symtab.lookup o fst o #const o dest_Naming;
   374 
   375 fun declare_class thy = declare thy map_class
   376   lookup_class Symtab.update_new namify_class;
   377 fun declare_classrel thy = declare thy map_classrel
   378   lookup_classrel Symreltab.update_new namify_classrel;
   379 fun declare_tyco thy = declare thy map_tyco
   380   lookup_tyco Symtab.update_new namify_tyco;
   381 fun declare_instance thy = declare thy map_instance
   382   lookup_instance Symreltab.update_new namify_instance;
   383 fun declare_const thy = declare thy map_const
   384   lookup_const Symtab.update_new namify_const;
   385 
   386 fun ensure_declared_const thy const naming =
   387   case lookup_const naming const
   388    of SOME const' => (const', naming)
   389     | NONE => declare_const thy const naming;
   390 
   391 val fun_tyco = Long_Name.append (namify_tyco Pure.thy "fun") suffix_tyco
   392   (*depends on add_suffix*);
   393 
   394 val unfold_fun = unfoldr
   395   (fn tyco `%% [ty1, ty2] => if tyco = fun_tyco then SOME (ty1, ty2) else NONE
   396     | _ => NONE);
   397 
   398 end; (* local *)
   399 
   400 
   401 (** statements, abstract programs **)
   402 
   403 type typscheme = (vname * sort) list * itype;
   404 datatype stmt =
   405     NoStmt
   406   | Fun of string * ((typscheme * ((iterm list * iterm) * (thm option * bool)) list) * thm option)
   407   | Datatype of string * ((vname * sort) list * (string * itype list) list)
   408   | Datatypecons of string * string
   409   | Class of class * (vname * ((class * string) list * (string * itype) list))
   410   | Classrel of class * class
   411   | Classparam of string * class
   412   | Classinst of (class * (string * (vname * sort) list))
   413         * (((class * (string * (string * dict list list))) list
   414           * (class * class) list list)
   415       * ((string * const) * (thm * bool)) list) (*see also signature*);
   416 
   417 type program = stmt Graph.T;
   418 
   419 fun empty_funs program =
   420   Graph.fold (fn (name, (Fun (c, ((_, []), _)), _)) => cons c
   421                | _ => I) program [];
   422 
   423 fun map_terms_bottom_up f (t as IConst _) = f t
   424   | map_terms_bottom_up f (t as IVar _) = f t
   425   | map_terms_bottom_up f (t1 `$ t2) = f
   426       (map_terms_bottom_up f t1 `$ map_terms_bottom_up f t2)
   427   | map_terms_bottom_up f ((v, ty) `|=> t) = f
   428       ((v, ty) `|=> map_terms_bottom_up f t)
   429   | map_terms_bottom_up f (ICase (((t, ty), ps), t0)) = f
   430       (ICase (((map_terms_bottom_up f t, ty), (map o pairself)
   431         (map_terms_bottom_up f) ps), map_terms_bottom_up f t0));
   432 
   433 fun map_terms_stmt f NoStmt = NoStmt
   434   | map_terms_stmt f (Fun (c, ((tysm, eqs), case_cong))) = Fun (c, ((tysm, (map o apfst)
   435       (fn (ts, t) => (map f ts, f t)) eqs), case_cong))
   436   | map_terms_stmt f (stmt as Datatype _) = stmt
   437   | map_terms_stmt f (stmt as Datatypecons _) = stmt
   438   | map_terms_stmt f (stmt as Class _) = stmt
   439   | map_terms_stmt f (stmt as Classrel _) = stmt
   440   | map_terms_stmt f (stmt as Classparam _) = stmt
   441   | map_terms_stmt f (Classinst (arity, ((super_instances, weakening), classparams))) =
   442       Classinst (arity, ((super_instances, weakening), (map o apfst o apsnd) (fn const =>
   443         case f (IConst const) of IConst const' => const') classparams));
   444 
   445 fun is_cons program name = case Graph.get_node program name
   446  of Datatypecons _ => true
   447   | _ => false;
   448 
   449 fun is_case (Fun (_, (_, SOME _))) = true
   450   | is_case _ = false;
   451 
   452 fun contr_classparam_typs program name = case Graph.get_node program name
   453  of Classparam (_, class) => let
   454         val Class (_, (_, (_, params))) = Graph.get_node program class;
   455         val SOME ty = AList.lookup (op =) params name;
   456         val (tys, res_ty) = unfold_fun ty;
   457         fun no_tyvar (_ `%% tys) = forall no_tyvar tys
   458           | no_tyvar (ITyVar _) = false;
   459       in if no_tyvar res_ty
   460         then map (fn ty => if no_tyvar ty then NONE else SOME ty) tys
   461         else []
   462       end
   463   | _ => [];
   464 
   465 fun labelled_name thy program name = case Graph.get_node program name
   466  of Fun (c, _) => quote (Code.string_of_const thy c)
   467   | Datatype (tyco, _) => "type " ^ quote (Sign.extern_type thy tyco)
   468   | Datatypecons (c, _) => quote (Code.string_of_const thy c)
   469   | Class (class, _) => "class " ^ quote (Sign.extern_class thy class)
   470   | Classrel (sub, super) => let
   471         val Class (sub, _) = Graph.get_node program sub
   472         val Class (super, _) = Graph.get_node program super
   473       in quote (Sign.extern_class thy sub ^ " < " ^ Sign.extern_class thy super) end
   474   | Classparam (c, _) => quote (Code.string_of_const thy c)
   475   | Classinst ((class, (tyco, _)), _) => let
   476         val Class (class, _) = Graph.get_node program class
   477         val Datatype (tyco, _) = Graph.get_node program tyco
   478       in quote (Sign.extern_type thy tyco ^ " :: " ^ Sign.extern_class thy class) end
   479 
   480 fun linear_stmts program =
   481   rev (Graph.strong_conn program)
   482   |> map (AList.make (Graph.get_node program));
   483 
   484 fun group_stmts thy program =
   485   let
   486     fun is_fun (_, Fun _) = true | is_fun _ = false;
   487     fun is_datatypecons (_, Datatypecons _) = true | is_datatypecons _ = false;
   488     fun is_datatype (_, Datatype _) = true | is_datatype _ = false;
   489     fun is_class (_, Class _) = true | is_class _ = false;
   490     fun is_classrel (_, Classrel _) = true | is_classrel _ = false;
   491     fun is_classparam (_, Classparam _) = true | is_classparam _ = false;
   492     fun is_classinst (_, Classinst _) = true | is_classinst _ = false;
   493     fun group stmts =
   494       if forall (is_datatypecons orf is_datatype) stmts
   495       then (filter is_datatype stmts, [], ([], []))
   496       else if forall (is_class orf is_classrel orf is_classparam) stmts
   497       then ([], filter is_class stmts, ([], []))
   498       else if forall (is_fun orf is_classinst) stmts
   499       then ([], [], List.partition is_fun stmts)
   500       else error ("Illegal mutual dependencies: " ^
   501         (commas o map (labelled_name thy program o fst)) stmts)
   502   in
   503     linear_stmts program
   504     |> map group
   505   end;
   506 
   507 
   508 (** translation kernel **)
   509 
   510 (* generic mechanisms *)
   511 
   512 fun ensure_stmt lookup declare generate thing (dep, (naming, program)) =
   513   let
   514     fun add_dep name = case dep of NONE => I
   515       | SOME dep => Graph.add_edge (dep, name);
   516     val (name, naming') = case lookup naming thing
   517      of SOME name => (name, naming)
   518       | NONE => declare thing naming;
   519   in case try (Graph.get_node program) name
   520    of SOME stmt => program
   521         |> add_dep name
   522         |> pair naming'
   523         |> pair dep
   524         |> pair name
   525     | NONE => program
   526         |> Graph.default_node (name, NoStmt)
   527         |> add_dep name
   528         |> pair naming'
   529         |> curry generate (SOME name)
   530         ||> snd
   531         |-> (fn stmt => (apsnd o Graph.map_node name) (K stmt))
   532         |> pair dep
   533         |> pair name
   534   end;
   535 
   536 exception PERMISSIVE of unit;
   537 
   538 fun translation_error thy permissive some_thm msg sub_msg =
   539   if permissive
   540   then raise PERMISSIVE ()
   541   else let
   542     val err_thm = case some_thm
   543      of SOME thm => "\n(in code equation " ^ Display.string_of_thm_global thy thm ^ ")"
   544       | NONE => "";
   545   in error (msg ^ err_thm ^ ":\n" ^ sub_msg) end;
   546 
   547 fun not_wellsorted thy permissive some_thm ty sort e =
   548   let
   549     val err_class = Sorts.class_error (Syntax.pp_global thy) e;
   550     val err_typ = "Type " ^ Syntax.string_of_typ_global thy ty ^ " not of sort "
   551       ^ Syntax.string_of_sort_global thy sort;
   552   in translation_error thy permissive some_thm "Wellsortedness error" (err_typ ^ "\n" ^ err_class) end;
   553 
   554 
   555 (* translation *)
   556 
   557 fun ensure_tyco thy algbr eqngr permissive tyco =
   558   let
   559     val (vs, cos) = Code.get_type thy tyco;
   560     val stmt_datatype =
   561       fold_map (translate_tyvar_sort thy algbr eqngr permissive) vs
   562       ##>> fold_map (fn (c, tys) =>
   563         ensure_const thy algbr eqngr permissive c
   564         ##>> fold_map (translate_typ thy algbr eqngr permissive) tys) cos
   565       #>> (fn info => Datatype (tyco, info));
   566   in ensure_stmt lookup_tyco (declare_tyco thy) stmt_datatype tyco end
   567 and ensure_const thy algbr eqngr permissive c =
   568   let
   569     fun stmt_datatypecons tyco =
   570       ensure_tyco thy algbr eqngr permissive tyco
   571       #>> (fn tyco => Datatypecons (c, tyco));
   572     fun stmt_classparam class =
   573       ensure_class thy algbr eqngr permissive class
   574       #>> (fn class => Classparam (c, class));
   575     fun stmt_fun cert =
   576       let
   577         val ((vs, ty), eqns) = Code.equations_of_cert thy cert;
   578         val some_case_cong = Code.get_case_cong thy c;
   579       in
   580         fold_map (translate_tyvar_sort thy algbr eqngr permissive) vs
   581         ##>> translate_typ thy algbr eqngr permissive ty
   582         ##>> translate_eqns thy algbr eqngr permissive eqns
   583         #>> (fn info => Fun (c, (info, some_case_cong)))
   584       end;
   585     val stmt_const = case Code.get_type_of_constr_or_abstr thy c
   586      of SOME (tyco, _) => stmt_datatypecons tyco
   587       | NONE => (case AxClass.class_of_param thy c
   588          of SOME class => stmt_classparam class
   589           | NONE => stmt_fun (Code_Preproc.cert eqngr c))
   590   in ensure_stmt lookup_const (declare_const thy) stmt_const c end
   591 and ensure_class thy (algbr as (_, algebra)) eqngr permissive class =
   592   let
   593     val super_classes = (Sorts.minimize_sort algebra o Sorts.super_classes algebra) class;
   594     val cs = #params (AxClass.get_info thy class);
   595     val stmt_class =
   596       fold_map (fn super_class => ensure_class thy algbr eqngr permissive super_class
   597         ##>> ensure_classrel thy algbr eqngr permissive (class, super_class)) super_classes
   598       ##>> fold_map (fn (c, ty) => ensure_const thy algbr eqngr permissive c
   599         ##>> translate_typ thy algbr eqngr permissive ty) cs
   600       #>> (fn info => Class (class, (unprefix "'" Name.aT, info)))
   601   in ensure_stmt lookup_class (declare_class thy) stmt_class class end
   602 and ensure_classrel thy algbr eqngr permissive (sub_class, super_class) =
   603   let
   604     val stmt_classrel =
   605       ensure_class thy algbr eqngr permissive sub_class
   606       ##>> ensure_class thy algbr eqngr permissive super_class
   607       #>> Classrel;
   608   in ensure_stmt lookup_classrel (declare_classrel thy) stmt_classrel (sub_class, super_class) end
   609 and ensure_inst thy (algbr as (_, algebra)) eqngr permissive (class, tyco) =
   610   let
   611     val super_classes = (Sorts.minimize_sort algebra o Sorts.super_classes algebra) class;
   612     val classparams = these (try (#params o AxClass.get_info thy) class);
   613     val vs = Name.names Name.context "'a" (Sorts.mg_domain algebra tyco [class]);
   614     val sorts' = Sorts.mg_domain (Sign.classes_of thy) tyco [class];
   615     val vs' = map2 (fn (v, sort1) => fn sort2 => (v,
   616       Sorts.inter_sort (Sign.classes_of thy) (sort1, sort2))) vs sorts';
   617     val arity_typ = Type (tyco, map TFree vs);
   618     val arity_typ' = Type (tyco, map (fn (v, sort) => TVar ((v, 0), sort)) vs');
   619     fun translate_super_instance super_class =
   620       ensure_class thy algbr eqngr permissive super_class
   621       ##>> ensure_classrel thy algbr eqngr permissive (class, super_class)
   622       ##>> translate_dicts thy algbr eqngr permissive NONE (arity_typ, [super_class])
   623       #>> (fn ((super_class, classrel), [DictConst (inst, dss)]) =>
   624             (super_class, (classrel, (inst, dss))));
   625     fun translate_classparam_instance (c, ty) =
   626       let
   627         val raw_const = Const (c, map_type_tfree (K arity_typ') ty);
   628         val thm = AxClass.unoverload_conv thy (Thm.cterm_of thy raw_const);
   629         val const = (apsnd Logic.unvarifyT_global o dest_Const o snd
   630           o Logic.dest_equals o Thm.prop_of) thm;
   631       in
   632         ensure_const thy algbr eqngr permissive c
   633         ##>> translate_const thy algbr eqngr permissive (SOME thm) (const, NONE)
   634         #>> (fn (c, IConst const') => ((c, const'), (thm, true)))
   635       end;
   636     val stmt_inst =
   637       ensure_class thy algbr eqngr permissive class
   638       ##>> ensure_tyco thy algbr eqngr permissive tyco
   639       ##>> fold_map (translate_tyvar_sort thy algbr eqngr permissive) vs
   640       ##>> fold_map translate_super_instance super_classes
   641       ##>> fold_map translate_classparam_instance classparams
   642       #>> (fn ((((class, tyco), arity_args), super_instances), classparam_instances) =>
   643              Classinst ((class, (tyco, arity_args)), ((super_instances, []), classparam_instances)));
   644   in ensure_stmt lookup_instance (declare_instance thy) stmt_inst (class, tyco) end
   645 and translate_typ thy algbr eqngr permissive (TFree (v, _)) =
   646       pair (ITyVar (unprefix "'" v))
   647   | translate_typ thy algbr eqngr permissive (Type (tyco, tys)) =
   648       ensure_tyco thy algbr eqngr permissive tyco
   649       ##>> fold_map (translate_typ thy algbr eqngr permissive) tys
   650       #>> (fn (tyco, tys) => tyco `%% tys)
   651 and translate_term thy algbr eqngr permissive some_thm (Const (c, ty), some_abs) =
   652       translate_app thy algbr eqngr permissive some_thm (((c, ty), []), some_abs)
   653   | translate_term thy algbr eqngr permissive some_thm (Free (v, _), some_abs) =
   654       pair (IVar (SOME v))
   655   | translate_term thy algbr eqngr permissive some_thm (Abs (v, ty, t), some_abs) =
   656       let
   657         val (v', t') = Syntax.variant_abs (Name.desymbolize false v, ty, t);
   658         val v'' = if member (op =) (Term.add_free_names t' []) v'
   659           then SOME v' else NONE
   660       in
   661         translate_typ thy algbr eqngr permissive ty
   662         ##>> translate_term thy algbr eqngr permissive some_thm (t', some_abs)
   663         #>> (fn (ty, t) => (v'', ty) `|=> t)
   664       end
   665   | translate_term thy algbr eqngr permissive some_thm (t as _ $ _, some_abs) =
   666       case strip_comb t
   667        of (Const (c, ty), ts) =>
   668             translate_app thy algbr eqngr permissive some_thm (((c, ty), ts), some_abs)
   669         | (t', ts) =>
   670             translate_term thy algbr eqngr permissive some_thm (t', some_abs)
   671             ##>> fold_map (translate_term thy algbr eqngr permissive some_thm o rpair NONE) ts
   672             #>> (fn (t, ts) => t `$$ ts)
   673 and translate_eqn thy algbr eqngr permissive ((args, (rhs, some_abs)), (some_thm, proper)) =
   674   fold_map (translate_term thy algbr eqngr permissive some_thm) args
   675   ##>> translate_term thy algbr eqngr permissive some_thm (rhs, some_abs)
   676   #>> rpair (some_thm, proper)
   677 and translate_eqns thy algbr eqngr permissive eqns prgrm =
   678   prgrm |> fold_map (translate_eqn thy algbr eqngr permissive) eqns
   679     handle PERMISSIVE () => ([], prgrm)
   680 and translate_const thy algbr eqngr permissive some_thm ((c, ty), some_abs) =
   681   let
   682     val _ = if (case some_abs of NONE => true | SOME abs => not (c = abs))
   683         andalso Code.is_abstr thy c
   684         then translation_error thy permissive some_thm
   685           "Abstraction violation" ("constant " ^ Code.string_of_const thy c)
   686       else ()
   687     val tys = Sign.const_typargs thy (c, ty);
   688     val sorts = Code_Preproc.sortargs eqngr c;
   689     val tys_args = (fst o Term.strip_type) ty;
   690   in
   691     ensure_const thy algbr eqngr permissive c
   692     ##>> fold_map (translate_typ thy algbr eqngr permissive) tys
   693     ##>> fold_map (translate_dicts thy algbr eqngr permissive some_thm) (tys ~~ sorts)
   694     ##>> fold_map (translate_typ thy algbr eqngr permissive) tys_args
   695     #>> (fn (((c, tys), iss), tys_args) => IConst (c, ((tys, iss), tys_args)))
   696   end
   697 and translate_app_const thy algbr eqngr permissive some_thm ((c_ty, ts), some_abs) =
   698   translate_const thy algbr eqngr permissive some_thm (c_ty, some_abs)
   699   ##>> fold_map (translate_term thy algbr eqngr permissive some_thm o rpair NONE) ts
   700   #>> (fn (t, ts) => t `$$ ts)
   701 and translate_case thy algbr eqngr permissive some_thm (num_args, (t_pos, case_pats)) (c_ty, ts) =
   702   let
   703     fun arg_types num_args ty = (fst o chop num_args o fst o strip_type) ty;
   704     val tys = arg_types num_args (snd c_ty);
   705     val ty = nth tys t_pos;
   706     fun mk_constr c t = let val n = Code.args_number thy c
   707       in ((c, arg_types n (fastype_of t) ---> ty), n) end;
   708     val constrs = if null case_pats then []
   709       else map2 mk_constr case_pats (nth_drop t_pos ts);
   710     fun casify naming constrs ty ts =
   711       let
   712         val undefineds = map_filter (lookup_const naming) (Code.undefineds thy);
   713         fun collapse_clause vs_map ts body =
   714           let
   715           in case body
   716            of IConst (c, _) => if member (op =) undefineds c
   717                 then []
   718                 else [(ts, body)]
   719             | ICase (((IVar (SOME v), _), subclauses), _) =>
   720                 if forall (fn (pat', body') => exists_var pat' v
   721                   orelse not (exists_var body' v)) subclauses
   722                 then case AList.lookup (op =) vs_map v
   723                  of SOME i => maps (fn (pat', body') =>
   724                       collapse_clause (AList.delete (op =) v vs_map)
   725                         (nth_map i (K pat') ts) body') subclauses
   726                   | NONE => [(ts, body)]
   727                 else [(ts, body)]
   728             | _ => [(ts, body)]
   729           end;
   730         fun mk_clause mk tys t =
   731           let
   732             val (vs, body) = unfold_abs_eta tys t;
   733             val vs_map = fold_index (fn (i, (SOME v, _)) => cons (v, i) | _ => I) vs [];
   734             val ts = map (IVar o fst) vs;
   735           in map mk (collapse_clause vs_map ts body) end;
   736         val t = nth ts t_pos;
   737         val ts_clause = nth_drop t_pos ts;
   738         val clauses = if null case_pats
   739           then mk_clause (fn ([t], body) => (t, body)) [ty] (the_single ts_clause)
   740           else maps (fn ((constr as IConst (_, (_, tys)), n), t) =>
   741             mk_clause (fn (ts, body) => (constr `$$ ts, body)) (take n tys) t)
   742               (constrs ~~ ts_clause);
   743       in ((t, ty), clauses) end;
   744   in
   745     translate_const thy algbr eqngr permissive some_thm (c_ty, NONE)
   746     ##>> fold_map (fn (constr, n) => translate_const thy algbr eqngr permissive some_thm (constr, NONE)
   747       #>> rpair n) constrs
   748     ##>> translate_typ thy algbr eqngr permissive ty
   749     ##>> fold_map (translate_term thy algbr eqngr permissive some_thm o rpair NONE) ts
   750     #-> (fn (((t, constrs), ty), ts) =>
   751       `(fn (_, (naming, _)) => ICase (casify naming constrs ty ts, t `$$ ts)))
   752   end
   753 and translate_app_case thy algbr eqngr permissive some_thm (case_scheme as (num_args, _)) ((c, ty), ts) =
   754   if length ts < num_args then
   755     let
   756       val k = length ts;
   757       val tys = (take (num_args - k) o drop k o fst o strip_type) ty;
   758       val ctxt = (fold o fold_aterms) Term.declare_term_frees ts Name.context;
   759       val vs = Name.names ctxt "a" tys;
   760     in
   761       fold_map (translate_typ thy algbr eqngr permissive) tys
   762       ##>> translate_case thy algbr eqngr permissive some_thm case_scheme ((c, ty), ts @ map Free vs)
   763       #>> (fn (tys, t) => map2 (fn (v, _) => pair (SOME v)) vs tys `|==> t)
   764     end
   765   else if length ts > num_args then
   766     translate_case thy algbr eqngr permissive some_thm case_scheme ((c, ty), take num_args ts)
   767     ##>> fold_map (translate_term thy algbr eqngr permissive some_thm o rpair NONE) (drop num_args ts)
   768     #>> (fn (t, ts) => t `$$ ts)
   769   else
   770     translate_case thy algbr eqngr permissive some_thm case_scheme ((c, ty), ts)
   771 and translate_app thy algbr eqngr permissive some_thm (c_ty_ts as ((c, _), _), some_abs) =
   772   case Code.get_case_scheme thy c
   773    of SOME case_scheme => translate_app_case thy algbr eqngr permissive some_thm case_scheme c_ty_ts
   774     | NONE => translate_app_const thy algbr eqngr permissive some_thm (c_ty_ts, some_abs)
   775 and translate_tyvar_sort thy (algbr as (proj_sort, _)) eqngr permissive (v, sort) =
   776   fold_map (ensure_class thy algbr eqngr permissive) (proj_sort sort)
   777   #>> (fn sort => (unprefix "'" v, sort))
   778 and translate_dicts thy (algbr as (proj_sort, algebra)) eqngr permissive some_thm (ty, sort) =
   779   let
   780     datatype typarg =
   781         Global of (class * string) * typarg list list
   782       | Local of (class * class) list * (string * (int * sort));
   783     fun class_relation (Global ((_, tyco), yss), _) class =
   784           Global ((class, tyco), yss)
   785       | class_relation (Local (classrels, v), sub_class) super_class =
   786           Local ((sub_class, super_class) :: classrels, v);
   787     fun type_constructor (tyco, _) yss class =
   788       Global ((class, tyco), (map o map) fst yss);
   789     fun type_variable (TFree (v, sort)) =
   790       let
   791         val sort' = proj_sort sort;
   792       in map_index (fn (n, class) => (Local ([], (v, (n, sort'))), class)) sort' end;
   793     val typargs = Sorts.of_sort_derivation algebra
   794       {class_relation = K (Sorts.classrel_derivation algebra class_relation),
   795        type_constructor = type_constructor,
   796        type_variable = type_variable} (ty, proj_sort sort)
   797       handle Sorts.CLASS_ERROR e => not_wellsorted thy permissive some_thm ty sort e;
   798     fun mk_dict (Global (inst, yss)) =
   799           ensure_inst thy algbr eqngr permissive inst
   800           ##>> (fold_map o fold_map) mk_dict yss
   801           #>> (fn (inst, dss) => DictConst (inst, dss))
   802       | mk_dict (Local (classrels, (v, (n, sort)))) =
   803           fold_map (ensure_classrel thy algbr eqngr permissive) classrels
   804           #>> (fn classrels => DictVar (classrels, (unprefix "'" v, (n, length sort))))
   805   in fold_map mk_dict typargs end;
   806 
   807 
   808 (* store *)
   809 
   810 structure Program = Code_Data
   811 (
   812   type T = naming * program;
   813   val empty = (empty_naming, Graph.empty);
   814 );
   815 
   816 fun cache_generation thy (algebra, eqngr) f name =
   817   Program.change_yield thy (fn naming_program => (NONE, naming_program)
   818     |> f thy algebra eqngr name
   819     |-> (fn name => fn (_, naming_program) => (name, naming_program)));
   820 
   821 fun transient_generation thy (algebra, eqngr) f name =
   822   (NONE, (empty_naming, Graph.empty))
   823   |> f thy algebra eqngr name
   824   |-> (fn name => fn (_, naming_program) => (name, naming_program));
   825 
   826 
   827 (* program generation *)
   828 
   829 fun consts_program thy permissive cs =
   830   let
   831     fun project_consts cs (naming, program) =
   832       let
   833         val cs_all = Graph.all_succs program cs;
   834       in (cs, (naming, Graph.subgraph (member (op =) cs_all) program)) end;
   835     fun generate_consts thy algebra eqngr =
   836       fold_map (ensure_const thy algebra eqngr permissive);
   837     val invoke_generation = if permissive
   838       then transient_generation else cache_generation
   839   in
   840     invoke_generation thy (Code_Preproc.obtain thy cs []) generate_consts cs
   841     |-> project_consts
   842   end;
   843 
   844 
   845 (* value evaluation *)
   846 
   847 fun ensure_value thy algbr eqngr t =
   848   let
   849     val ty = fastype_of t;
   850     val vs = fold_term_types (K (fold_atyps (insert (eq_fst op =)
   851       o dest_TFree))) t [];
   852     val stmt_value =
   853       fold_map (translate_tyvar_sort thy algbr eqngr false) vs
   854       ##>> translate_typ thy algbr eqngr false ty
   855       ##>> translate_term thy algbr eqngr false NONE (Code.subst_signatures thy t, NONE)
   856       #>> (fn ((vs, ty), t) => Fun
   857         (Term.dummy_patternN, (((vs, ty), [(([], t), (NONE, true))]), NONE)));
   858     fun term_value (dep, (naming, program1)) =
   859       let
   860         val Fun (_, ((vs_ty, [(([], t), _)]), _)) =
   861           Graph.get_node program1 Term.dummy_patternN;
   862         val deps = Graph.imm_succs program1 Term.dummy_patternN;
   863         val program2 = Graph.del_nodes [Term.dummy_patternN] program1;
   864         val deps_all = Graph.all_succs program2 deps;
   865         val program3 = Graph.subgraph (member (op =) deps_all) program2;
   866       in (((naming, program3), ((vs_ty, t), deps)), (dep, (naming, program2))) end;
   867   in
   868     ensure_stmt ((K o K) NONE) pair stmt_value Term.dummy_patternN
   869     #> snd
   870     #> term_value
   871   end;
   872 
   873 fun base_evaluator thy evaluator algebra eqngr vs t =
   874   let
   875     val (((naming, program), (((vs', ty'), t'), deps)), _) =
   876       cache_generation thy (algebra, eqngr) ensure_value t;
   877     val vs'' = map (fn (v, _) => (v, (the o AList.lookup (op =) vs o prefix "'") v)) vs';
   878   in evaluator naming program ((vs'', (vs', ty')), t') deps end;
   879 
   880 fun eval_conv thy = Code_Preproc.eval_conv thy o base_evaluator thy;
   881 fun eval thy postproc = Code_Preproc.eval thy postproc o base_evaluator thy;
   882 
   883 
   884 (** diagnostic commands **)
   885 
   886 fun read_const_exprs thy =
   887   let
   888     fun consts_of thy' = Symtab.fold (fn (c, (_, NONE)) => cons c | _ => I)
   889       ((snd o #constants o Consts.dest o #consts o Sign.rep_sg) thy') [];
   890     fun belongs_here thy' c = forall
   891       (fn thy'' => not (Sign.declared_const thy'' c)) (Theory.parents_of thy');
   892     fun consts_of_select thy' = filter (belongs_here thy') (consts_of thy');
   893     fun read_const_expr "*" = ([], consts_of thy)
   894       | read_const_expr s = if String.isSuffix ".*" s
   895           then ([], consts_of_select (Thy_Info.the_theory (unsuffix ".*" s) thy))
   896           else ([Code.read_const thy s], []);
   897   in pairself flat o split_list o map read_const_expr end;
   898 
   899 fun code_depgr thy consts =
   900   let
   901     val (_, eqngr) = Code_Preproc.obtain thy consts [];
   902     val all_consts = Graph.all_succs eqngr consts;
   903   in Graph.subgraph (member (op =) all_consts) eqngr end;
   904 
   905 fun code_thms thy = Pretty.writeln o Code_Preproc.pretty thy o code_depgr thy;
   906 
   907 fun code_deps thy consts =
   908   let
   909     val eqngr = code_depgr thy consts;
   910     val constss = Graph.strong_conn eqngr;
   911     val mapping = Symtab.empty |> fold (fn consts => fold (fn const =>
   912       Symtab.update (const, consts)) consts) constss;
   913     fun succs consts = consts
   914       |> maps (Graph.imm_succs eqngr)
   915       |> subtract (op =) consts
   916       |> map (the o Symtab.lookup mapping)
   917       |> distinct (op =);
   918     val conn = [] |> fold (fn consts => cons (consts, succs consts)) constss;
   919     fun namify consts = map (Code.string_of_const thy) consts
   920       |> commas;
   921     val prgr = map (fn (consts, constss) =>
   922       { name = namify consts, ID = namify consts, dir = "", unfold = true,
   923         path = "", parents = map namify constss }) conn;
   924   in Present.display_graph prgr end;
   925 
   926 local
   927 
   928 fun code_thms_cmd thy = code_thms thy o op @ o read_const_exprs thy;
   929 fun code_deps_cmd thy = code_deps thy o op @ o read_const_exprs thy;
   930 
   931 in
   932 
   933 val _ =
   934   Outer_Syntax.improper_command "code_thms" "print system of code equations for code" Keyword.diag
   935     (Scan.repeat1 Parse.term_group
   936       >> (fn cs => Toplevel.no_timing o Toplevel.unknown_theory
   937         o Toplevel.keep ((fn thy => code_thms_cmd thy cs) o Toplevel.theory_of)));
   938 
   939 val _ =
   940   Outer_Syntax.improper_command "code_deps" "visualize dependencies of code equations for code"
   941     Keyword.diag
   942     (Scan.repeat1 Parse.term_group
   943       >> (fn cs => Toplevel.no_timing o Toplevel.unknown_theory
   944         o Toplevel.keep ((fn thy => code_deps_cmd thy cs) o Toplevel.theory_of)));
   945 
   946 end;
   947 
   948 end; (*struct*)
   949 
   950 
   951 structure Basic_Code_Thingol: BASIC_CODE_THINGOL = Code_Thingol;