src/HOL/Rings.thy
author haftmann
Sun Oct 12 17:05:34 2014 +0200 (2014-10-12)
changeset 58649 a62065b5e1e2
parent 58647 fce800afeec7
child 58776 95e58e04e534
permissions -rw-r--r--
generalized and consolidated some theorems concerning divisibility
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 header {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps, field_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps, field_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right ac_simps)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 begin
    32 
    33 lemma mult_not_zero:
    34   "a * b \<noteq> 0 \<Longrightarrow> a \<noteq> 0 \<and> b \<noteq> 0"
    35   by auto
    36 
    37 end
    38 
    39 class semiring_0 = semiring + comm_monoid_add + mult_zero
    40 
    41 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    42 begin
    43 
    44 subclass semiring_0
    45 proof
    46   fix a :: 'a
    47   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    48   thus "0 * a = 0" by (simp only: add_left_cancel)
    49 next
    50   fix a :: 'a
    51   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    52   thus "a * 0 = 0" by (simp only: add_left_cancel)
    53 qed
    54 
    55 end
    56 
    57 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    58   assumes distrib: "(a + b) * c = a * c + b * c"
    59 begin
    60 
    61 subclass semiring
    62 proof
    63   fix a b c :: 'a
    64   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    65   have "a * (b + c) = (b + c) * a" by (simp add: ac_simps)
    66   also have "... = b * a + c * a" by (simp only: distrib)
    67   also have "... = a * b + a * c" by (simp add: ac_simps)
    68   finally show "a * (b + c) = a * b + a * c" by blast
    69 qed
    70 
    71 end
    72 
    73 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    74 begin
    75 
    76 subclass semiring_0 ..
    77 
    78 end
    79 
    80 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    81 begin
    82 
    83 subclass semiring_0_cancel ..
    84 
    85 subclass comm_semiring_0 ..
    86 
    87 end
    88 
    89 class zero_neq_one = zero + one +
    90   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    91 begin
    92 
    93 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    94 by (rule not_sym) (rule zero_neq_one)
    95 
    96 definition of_bool :: "bool \<Rightarrow> 'a"
    97 where
    98   "of_bool p = (if p then 1 else 0)" 
    99 
   100 lemma of_bool_eq [simp, code]:
   101   "of_bool False = 0"
   102   "of_bool True = 1"
   103   by (simp_all add: of_bool_def)
   104 
   105 lemma of_bool_eq_iff:
   106   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   107   by (simp add: of_bool_def)
   108 
   109 lemma split_of_bool [split]:
   110   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   111   by (cases p) simp_all
   112 
   113 lemma split_of_bool_asm:
   114   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   115   by (cases p) simp_all
   116   
   117 end  
   118 
   119 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   120 
   121 text {* Abstract divisibility *}
   122 
   123 class dvd = times
   124 begin
   125 
   126 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   127   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   128 
   129 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   130   unfolding dvd_def ..
   131 
   132 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   133   unfolding dvd_def by blast 
   134 
   135 end
   136 
   137 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult + dvd
   138   (*previously almost_semiring*)
   139 begin
   140 
   141 subclass semiring_1 ..
   142 
   143 lemma dvd_refl[simp]: "a dvd a"
   144 proof
   145   show "a = a * 1" by simp
   146 qed
   147 
   148 lemma dvd_trans:
   149   assumes "a dvd b" and "b dvd c"
   150   shows "a dvd c"
   151 proof -
   152   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   153   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   154   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   155   then show ?thesis ..
   156 qed
   157 
   158 lemma dvd_0_left_iff [simp]: "0 dvd a \<longleftrightarrow> a = 0"
   159 by (auto intro: dvd_refl elim!: dvdE)
   160 
   161 lemma dvd_0_right [iff]: "a dvd 0"
   162 proof
   163   show "0 = a * 0" by simp
   164 qed
   165 
   166 lemma one_dvd [simp]: "1 dvd a"
   167 by (auto intro!: dvdI)
   168 
   169 lemma dvd_mult[simp]: "a dvd c \<Longrightarrow> a dvd (b * c)"
   170 by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   171 
   172 lemma dvd_mult2[simp]: "a dvd b \<Longrightarrow> a dvd (b * c)"
   173   apply (subst mult.commute)
   174   apply (erule dvd_mult)
   175   done
   176 
   177 lemma dvd_triv_right [simp]: "a dvd b * a"
   178 by (rule dvd_mult) (rule dvd_refl)
   179 
   180 lemma dvd_triv_left [simp]: "a dvd a * b"
   181 by (rule dvd_mult2) (rule dvd_refl)
   182 
   183 lemma mult_dvd_mono:
   184   assumes "a dvd b"
   185     and "c dvd d"
   186   shows "a * c dvd b * d"
   187 proof -
   188   from `a dvd b` obtain b' where "b = a * b'" ..
   189   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   190   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: ac_simps)
   191   then show ?thesis ..
   192 qed
   193 
   194 lemma dvd_mult_left: "a * b dvd c \<Longrightarrow> a dvd c"
   195 by (simp add: dvd_def mult.assoc, blast)
   196 
   197 lemma dvd_mult_right: "a * b dvd c \<Longrightarrow> b dvd c"
   198   unfolding mult.commute [of a] by (rule dvd_mult_left)
   199 
   200 lemma dvd_0_left: "0 dvd a \<Longrightarrow> a = 0"
   201 by simp
   202 
   203 lemma dvd_add[simp]:
   204   assumes "a dvd b" and "a dvd c" shows "a dvd (b + c)"
   205 proof -
   206   from `a dvd b` obtain b' where "b = a * b'" ..
   207   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   208   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   209   then show ?thesis ..
   210 qed
   211 
   212 end
   213 
   214 class semiring_dvd = comm_semiring_1 +
   215   assumes dvd_add_times_triv_left_iff [simp]: "a dvd c * a + b \<longleftrightarrow> a dvd b"
   216   assumes dvd_addD: "a dvd b + c \<Longrightarrow> a dvd b \<Longrightarrow> a dvd c"
   217 begin
   218 
   219 lemma dvd_add_times_triv_right_iff [simp]:
   220   "a dvd b + c * a \<longleftrightarrow> a dvd b"
   221   using dvd_add_times_triv_left_iff [of a c b] by (simp add: ac_simps)
   222 
   223 lemma dvd_add_triv_left_iff [simp]:
   224   "a dvd a + b \<longleftrightarrow> a dvd b"
   225   using dvd_add_times_triv_left_iff [of a 1 b] by simp
   226 
   227 lemma dvd_add_triv_right_iff [simp]:
   228   "a dvd b + a \<longleftrightarrow> a dvd b"
   229   using dvd_add_times_triv_right_iff [of a b 1] by simp
   230 
   231 lemma dvd_add_right_iff:
   232   assumes "a dvd b"
   233   shows "a dvd b + c \<longleftrightarrow> a dvd c"
   234   using assms by (auto dest: dvd_addD)
   235 
   236 lemma dvd_add_left_iff:
   237   assumes "a dvd c"
   238   shows "a dvd b + c \<longleftrightarrow> a dvd b"
   239   using assms dvd_add_right_iff [of a c b] by (simp add: ac_simps)
   240 
   241 end
   242 
   243 class no_zero_divisors = zero + times +
   244   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   245 begin
   246 
   247 lemma divisors_zero:
   248   assumes "a * b = 0"
   249   shows "a = 0 \<or> b = 0"
   250 proof (rule classical)
   251   assume "\<not> (a = 0 \<or> b = 0)"
   252   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   253   with no_zero_divisors have "a * b \<noteq> 0" by blast
   254   with assms show ?thesis by simp
   255 qed
   256 
   257 end
   258 
   259 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   260   + zero_neq_one + monoid_mult
   261 begin
   262 
   263 subclass semiring_0_cancel ..
   264 
   265 subclass semiring_1 ..
   266 
   267 end
   268 
   269 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add
   270   + zero_neq_one + comm_monoid_mult
   271 begin
   272 
   273 subclass semiring_1_cancel ..
   274 subclass comm_semiring_0_cancel ..
   275 subclass comm_semiring_1 ..
   276 
   277 end
   278 
   279 class ring = semiring + ab_group_add
   280 begin
   281 
   282 subclass semiring_0_cancel ..
   283 
   284 text {* Distribution rules *}
   285 
   286 lemma minus_mult_left: "- (a * b) = - a * b"
   287 by (rule minus_unique) (simp add: distrib_right [symmetric]) 
   288 
   289 lemma minus_mult_right: "- (a * b) = a * - b"
   290 by (rule minus_unique) (simp add: distrib_left [symmetric]) 
   291 
   292 text{*Extract signs from products*}
   293 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   294 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   295 
   296 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   297 by simp
   298 
   299 lemma minus_mult_commute: "- a * b = a * - b"
   300 by simp
   301 
   302 lemma right_diff_distrib [algebra_simps, field_simps]:
   303   "a * (b - c) = a * b - a * c"
   304   using distrib_left [of a b "-c "] by simp
   305 
   306 lemma left_diff_distrib [algebra_simps, field_simps]:
   307   "(a - b) * c = a * c - b * c"
   308   using distrib_right [of a "- b" c] by simp
   309 
   310 lemmas ring_distribs =
   311   distrib_left distrib_right left_diff_distrib right_diff_distrib
   312 
   313 lemma eq_add_iff1:
   314   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   315 by (simp add: algebra_simps)
   316 
   317 lemma eq_add_iff2:
   318   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   319 by (simp add: algebra_simps)
   320 
   321 end
   322 
   323 lemmas ring_distribs =
   324   distrib_left distrib_right left_diff_distrib right_diff_distrib
   325 
   326 class comm_ring = comm_semiring + ab_group_add
   327 begin
   328 
   329 subclass ring ..
   330 subclass comm_semiring_0_cancel ..
   331 
   332 lemma square_diff_square_factored:
   333   "x * x - y * y = (x + y) * (x - y)"
   334   by (simp add: algebra_simps)
   335 
   336 end
   337 
   338 class ring_1 = ring + zero_neq_one + monoid_mult
   339 begin
   340 
   341 subclass semiring_1_cancel ..
   342 
   343 lemma square_diff_one_factored:
   344   "x * x - 1 = (x + 1) * (x - 1)"
   345   by (simp add: algebra_simps)
   346 
   347 end
   348 
   349 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   350   (*previously ring*)
   351 begin
   352 
   353 subclass ring_1 ..
   354 subclass comm_semiring_1_cancel ..
   355 
   356 subclass semiring_dvd
   357 proof
   358   fix a b c
   359   show "a dvd c * a + b \<longleftrightarrow> a dvd b" (is "?P \<longleftrightarrow> ?Q")
   360   proof
   361     assume ?Q then show ?P by simp
   362   next
   363     assume ?P then obtain d where "c * a + b = a * d" ..
   364     then have "b = a * (d - c)" by (simp add: algebra_simps)
   365     then show ?Q ..
   366   qed
   367   assume "a dvd b + c" and "a dvd b"
   368   show "a dvd c"
   369   proof -
   370     from `a dvd b` obtain d where "b = a * d" ..
   371     moreover from `a dvd b + c` obtain e where "b + c = a * e" ..
   372     ultimately have "a * d + c = a * e" by simp
   373     then have "c = a * (e - d)" by (simp add: algebra_simps)
   374     then show "a dvd c" ..
   375   qed
   376 qed
   377 
   378 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   379 proof
   380   assume "x dvd - y"
   381   then have "x dvd - 1 * - y" by (rule dvd_mult)
   382   then show "x dvd y" by simp
   383 next
   384   assume "x dvd y"
   385   then have "x dvd - 1 * y" by (rule dvd_mult)
   386   then show "x dvd - y" by simp
   387 qed
   388 
   389 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   390 proof
   391   assume "- x dvd y"
   392   then obtain k where "y = - x * k" ..
   393   then have "y = x * - k" by simp
   394   then show "x dvd y" ..
   395 next
   396   assume "x dvd y"
   397   then obtain k where "y = x * k" ..
   398   then have "y = - x * - k" by simp
   399   then show "- x dvd y" ..
   400 qed
   401 
   402 lemma dvd_diff [simp]:
   403   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   404   using dvd_add [of x y "- z"] by simp
   405 
   406 end
   407 
   408 class ring_no_zero_divisors = ring + no_zero_divisors
   409 begin
   410 
   411 lemma mult_eq_0_iff [simp]:
   412   shows "a * b = 0 \<longleftrightarrow> (a = 0 \<or> b = 0)"
   413 proof (cases "a = 0 \<or> b = 0")
   414   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   415     then show ?thesis using no_zero_divisors by simp
   416 next
   417   case True then show ?thesis by auto
   418 qed
   419 
   420 text{*Cancellation of equalities with a common factor*}
   421 lemma mult_cancel_right [simp]:
   422   "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   423 proof -
   424   have "(a * c = b * c) = ((a - b) * c = 0)"
   425     by (simp add: algebra_simps)
   426   thus ?thesis by (simp add: disj_commute)
   427 qed
   428 
   429 lemma mult_cancel_left [simp]:
   430   "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   431 proof -
   432   have "(c * a = c * b) = (c * (a - b) = 0)"
   433     by (simp add: algebra_simps)
   434   thus ?thesis by simp
   435 qed
   436 
   437 lemma mult_left_cancel: "c \<noteq> 0 \<Longrightarrow> (c*a=c*b) = (a=b)"
   438 by simp 
   439 
   440 lemma mult_right_cancel: "c \<noteq> 0 \<Longrightarrow> (a*c=b*c) = (a=b)"
   441 by simp 
   442 
   443 end
   444 
   445 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   446 begin
   447 
   448 lemma square_eq_1_iff:
   449   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   450 proof -
   451   have "(x - 1) * (x + 1) = x * x - 1"
   452     by (simp add: algebra_simps)
   453   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   454     by simp
   455   thus ?thesis
   456     by (simp add: eq_neg_iff_add_eq_0)
   457 qed
   458 
   459 lemma mult_cancel_right1 [simp]:
   460   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   461 by (insert mult_cancel_right [of 1 c b], force)
   462 
   463 lemma mult_cancel_right2 [simp]:
   464   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   465 by (insert mult_cancel_right [of a c 1], simp)
   466  
   467 lemma mult_cancel_left1 [simp]:
   468   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   469 by (insert mult_cancel_left [of c 1 b], force)
   470 
   471 lemma mult_cancel_left2 [simp]:
   472   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   473 by (insert mult_cancel_left [of c a 1], simp)
   474 
   475 end
   476 
   477 class idom = comm_ring_1 + no_zero_divisors
   478 begin
   479 
   480 subclass ring_1_no_zero_divisors ..
   481 
   482 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> (a = b \<or> a = - b)"
   483 proof
   484   assume "a * a = b * b"
   485   then have "(a - b) * (a + b) = 0"
   486     by (simp add: algebra_simps)
   487   then show "a = b \<or> a = - b"
   488     by (simp add: eq_neg_iff_add_eq_0)
   489 next
   490   assume "a = b \<or> a = - b"
   491   then show "a * a = b * b" by auto
   492 qed
   493 
   494 lemma dvd_mult_cancel_right [simp]:
   495   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   496 proof -
   497   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   498     unfolding dvd_def by (simp add: ac_simps)
   499   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   500     unfolding dvd_def by simp
   501   finally show ?thesis .
   502 qed
   503 
   504 lemma dvd_mult_cancel_left [simp]:
   505   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   506 proof -
   507   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   508     unfolding dvd_def by (simp add: ac_simps)
   509   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   510     unfolding dvd_def by simp
   511   finally show ?thesis .
   512 qed
   513 
   514 end
   515 
   516 text {*
   517   The theory of partially ordered rings is taken from the books:
   518   \begin{itemize}
   519   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
   520   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   521   \end{itemize}
   522   Most of the used notions can also be looked up in 
   523   \begin{itemize}
   524   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   525   \item \emph{Algebra I} by van der Waerden, Springer.
   526   \end{itemize}
   527 *}
   528 
   529 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   530   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   531   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   532 begin
   533 
   534 lemma mult_mono:
   535   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   536 apply (erule mult_right_mono [THEN order_trans], assumption)
   537 apply (erule mult_left_mono, assumption)
   538 done
   539 
   540 lemma mult_mono':
   541   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   542 apply (rule mult_mono)
   543 apply (fast intro: order_trans)+
   544 done
   545 
   546 end
   547 
   548 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   549 begin
   550 
   551 subclass semiring_0_cancel ..
   552 
   553 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   554 using mult_left_mono [of 0 b a] by simp
   555 
   556 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   557 using mult_left_mono [of b 0 a] by simp
   558 
   559 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   560 using mult_right_mono [of a 0 b] by simp
   561 
   562 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   563 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0" 
   564 by (drule mult_right_mono [of b 0], auto)
   565 
   566 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0" 
   567 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   568 
   569 end
   570 
   571 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   572 begin
   573 
   574 subclass ordered_cancel_semiring ..
   575 
   576 subclass ordered_comm_monoid_add ..
   577 
   578 lemma mult_left_less_imp_less:
   579   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   580 by (force simp add: mult_left_mono not_le [symmetric])
   581  
   582 lemma mult_right_less_imp_less:
   583   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   584 by (force simp add: mult_right_mono not_le [symmetric])
   585 
   586 end
   587 
   588 class linordered_semiring_1 = linordered_semiring + semiring_1
   589 begin
   590 
   591 lemma convex_bound_le:
   592   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   593   shows "u * x + v * y \<le> a"
   594 proof-
   595   from assms have "u * x + v * y \<le> u * a + v * a"
   596     by (simp add: add_mono mult_left_mono)
   597   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   598 qed
   599 
   600 end
   601 
   602 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   603   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   604   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   605 begin
   606 
   607 subclass semiring_0_cancel ..
   608 
   609 subclass linordered_semiring
   610 proof
   611   fix a b c :: 'a
   612   assume A: "a \<le> b" "0 \<le> c"
   613   from A show "c * a \<le> c * b"
   614     unfolding le_less
   615     using mult_strict_left_mono by (cases "c = 0") auto
   616   from A show "a * c \<le> b * c"
   617     unfolding le_less
   618     using mult_strict_right_mono by (cases "c = 0") auto
   619 qed
   620 
   621 lemma mult_left_le_imp_le:
   622   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   623 by (force simp add: mult_strict_left_mono _not_less [symmetric])
   624  
   625 lemma mult_right_le_imp_le:
   626   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   627 by (force simp add: mult_strict_right_mono not_less [symmetric])
   628 
   629 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
   630 using mult_strict_left_mono [of 0 b a] by simp
   631 
   632 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
   633 using mult_strict_left_mono [of b 0 a] by simp
   634 
   635 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
   636 using mult_strict_right_mono [of a 0 b] by simp
   637 
   638 text {* Legacy - use @{text mult_neg_pos} *}
   639 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0" 
   640 by (drule mult_strict_right_mono [of b 0], auto)
   641 
   642 lemma zero_less_mult_pos:
   643   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   644 apply (cases "b\<le>0")
   645  apply (auto simp add: le_less not_less)
   646 apply (drule_tac mult_pos_neg [of a b])
   647  apply (auto dest: less_not_sym)
   648 done
   649 
   650 lemma zero_less_mult_pos2:
   651   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   652 apply (cases "b\<le>0")
   653  apply (auto simp add: le_less not_less)
   654 apply (drule_tac mult_pos_neg2 [of a b])
   655  apply (auto dest: less_not_sym)
   656 done
   657 
   658 text{*Strict monotonicity in both arguments*}
   659 lemma mult_strict_mono:
   660   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
   661   shows "a * c < b * d"
   662   using assms apply (cases "c=0")
   663   apply (simp)
   664   apply (erule mult_strict_right_mono [THEN less_trans])
   665   apply (force simp add: le_less)
   666   apply (erule mult_strict_left_mono, assumption)
   667   done
   668 
   669 text{*This weaker variant has more natural premises*}
   670 lemma mult_strict_mono':
   671   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
   672   shows "a * c < b * d"
   673 by (rule mult_strict_mono) (insert assms, auto)
   674 
   675 lemma mult_less_le_imp_less:
   676   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
   677   shows "a * c < b * d"
   678   using assms apply (subgoal_tac "a * c < b * c")
   679   apply (erule less_le_trans)
   680   apply (erule mult_left_mono)
   681   apply simp
   682   apply (erule mult_strict_right_mono)
   683   apply assumption
   684   done
   685 
   686 lemma mult_le_less_imp_less:
   687   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
   688   shows "a * c < b * d"
   689   using assms apply (subgoal_tac "a * c \<le> b * c")
   690   apply (erule le_less_trans)
   691   apply (erule mult_strict_left_mono)
   692   apply simp
   693   apply (erule mult_right_mono)
   694   apply simp
   695   done
   696 
   697 lemma mult_less_imp_less_left:
   698   assumes less: "c * a < c * b" and nonneg: "0 \<le> c"
   699   shows "a < b"
   700 proof (rule ccontr)
   701   assume "\<not>  a < b"
   702   hence "b \<le> a" by (simp add: linorder_not_less)
   703   hence "c * b \<le> c * a" using nonneg by (rule mult_left_mono)
   704   with this and less show False by (simp add: not_less [symmetric])
   705 qed
   706 
   707 lemma mult_less_imp_less_right:
   708   assumes less: "a * c < b * c" and nonneg: "0 \<le> c"
   709   shows "a < b"
   710 proof (rule ccontr)
   711   assume "\<not> a < b"
   712   hence "b \<le> a" by (simp add: linorder_not_less)
   713   hence "b * c \<le> a * c" using nonneg by (rule mult_right_mono)
   714   with this and less show False by (simp add: not_less [symmetric])
   715 qed  
   716 
   717 end
   718 
   719 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
   720 begin
   721 
   722 subclass linordered_semiring_1 ..
   723 
   724 lemma convex_bound_lt:
   725   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   726   shows "u * x + v * y < a"
   727 proof -
   728   from assms have "u * x + v * y < u * a + v * a"
   729     by (cases "u = 0")
   730        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
   731   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   732 qed
   733 
   734 end
   735 
   736 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add + 
   737   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   738 begin
   739 
   740 subclass ordered_semiring
   741 proof
   742   fix a b c :: 'a
   743   assume "a \<le> b" "0 \<le> c"
   744   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
   745   thus "a * c \<le> b * c" by (simp only: mult.commute)
   746 qed
   747 
   748 end
   749 
   750 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
   751 begin
   752 
   753 subclass comm_semiring_0_cancel ..
   754 subclass ordered_comm_semiring ..
   755 subclass ordered_cancel_semiring ..
   756 
   757 end
   758 
   759 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
   760   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   761 begin
   762 
   763 subclass linordered_semiring_strict
   764 proof
   765   fix a b c :: 'a
   766   assume "a < b" "0 < c"
   767   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
   768   thus "a * c < b * c" by (simp only: mult.commute)
   769 qed
   770 
   771 subclass ordered_cancel_comm_semiring
   772 proof
   773   fix a b c :: 'a
   774   assume "a \<le> b" "0 \<le> c"
   775   thus "c * a \<le> c * b"
   776     unfolding le_less
   777     using mult_strict_left_mono by (cases "c = 0") auto
   778 qed
   779 
   780 end
   781 
   782 class ordered_ring = ring + ordered_cancel_semiring 
   783 begin
   784 
   785 subclass ordered_ab_group_add ..
   786 
   787 lemma less_add_iff1:
   788   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
   789 by (simp add: algebra_simps)
   790 
   791 lemma less_add_iff2:
   792   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
   793 by (simp add: algebra_simps)
   794 
   795 lemma le_add_iff1:
   796   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
   797 by (simp add: algebra_simps)
   798 
   799 lemma le_add_iff2:
   800   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
   801 by (simp add: algebra_simps)
   802 
   803 lemma mult_left_mono_neg:
   804   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
   805   apply (drule mult_left_mono [of _ _ "- c"])
   806   apply simp_all
   807   done
   808 
   809 lemma mult_right_mono_neg:
   810   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
   811   apply (drule mult_right_mono [of _ _ "- c"])
   812   apply simp_all
   813   done
   814 
   815 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
   816 using mult_right_mono_neg [of a 0 b] by simp
   817 
   818 lemma split_mult_pos_le:
   819   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
   820 by (auto simp add: mult_nonpos_nonpos)
   821 
   822 end
   823 
   824 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
   825 begin
   826 
   827 subclass ordered_ring ..
   828 
   829 subclass ordered_ab_group_add_abs
   830 proof
   831   fix a b
   832   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   833     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
   834 qed (auto simp add: abs_if)
   835 
   836 lemma zero_le_square [simp]: "0 \<le> a * a"
   837   using linear [of 0 a]
   838   by (auto simp add: mult_nonpos_nonpos)
   839 
   840 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
   841   by (simp add: not_less)
   842 
   843 end
   844 
   845 (* The "strict" suffix can be seen as describing the combination of linordered_ring and no_zero_divisors.
   846    Basically, linordered_ring + no_zero_divisors = linordered_ring_strict.
   847  *)
   848 class linordered_ring_strict = ring + linordered_semiring_strict
   849   + ordered_ab_group_add + abs_if
   850 begin
   851 
   852 subclass linordered_ring ..
   853 
   854 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
   855 using mult_strict_left_mono [of b a "- c"] by simp
   856 
   857 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
   858 using mult_strict_right_mono [of b a "- c"] by simp
   859 
   860 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
   861 using mult_strict_right_mono_neg [of a 0 b] by simp
   862 
   863 subclass ring_no_zero_divisors
   864 proof
   865   fix a b
   866   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
   867   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
   868   have "a * b < 0 \<or> 0 < a * b"
   869   proof (cases "a < 0")
   870     case True note A' = this
   871     show ?thesis proof (cases "b < 0")
   872       case True with A'
   873       show ?thesis by (auto dest: mult_neg_neg)
   874     next
   875       case False with B have "0 < b" by auto
   876       with A' show ?thesis by (auto dest: mult_strict_right_mono)
   877     qed
   878   next
   879     case False with A have A': "0 < a" by auto
   880     show ?thesis proof (cases "b < 0")
   881       case True with A'
   882       show ?thesis by (auto dest: mult_strict_right_mono_neg)
   883     next
   884       case False with B have "0 < b" by auto
   885       with A' show ?thesis by auto
   886     qed
   887   qed
   888   then show "a * b \<noteq> 0" by (simp add: neq_iff)
   889 qed
   890 
   891 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
   892   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
   893      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
   894 
   895 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
   896   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
   897 
   898 lemma mult_less_0_iff:
   899   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
   900   apply (insert zero_less_mult_iff [of "-a" b])
   901   apply force
   902   done
   903 
   904 lemma mult_le_0_iff:
   905   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
   906   apply (insert zero_le_mult_iff [of "-a" b]) 
   907   apply force
   908   done
   909 
   910 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
   911    also with the relations @{text "\<le>"} and equality.*}
   912 
   913 text{*These ``disjunction'' versions produce two cases when the comparison is
   914  an assumption, but effectively four when the comparison is a goal.*}
   915 
   916 lemma mult_less_cancel_right_disj:
   917   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   918   apply (cases "c = 0")
   919   apply (auto simp add: neq_iff mult_strict_right_mono 
   920                       mult_strict_right_mono_neg)
   921   apply (auto simp add: not_less 
   922                       not_le [symmetric, of "a*c"]
   923                       not_le [symmetric, of a])
   924   apply (erule_tac [!] notE)
   925   apply (auto simp add: less_imp_le mult_right_mono 
   926                       mult_right_mono_neg)
   927   done
   928 
   929 lemma mult_less_cancel_left_disj:
   930   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   931   apply (cases "c = 0")
   932   apply (auto simp add: neq_iff mult_strict_left_mono 
   933                       mult_strict_left_mono_neg)
   934   apply (auto simp add: not_less 
   935                       not_le [symmetric, of "c*a"]
   936                       not_le [symmetric, of a])
   937   apply (erule_tac [!] notE)
   938   apply (auto simp add: less_imp_le mult_left_mono 
   939                       mult_left_mono_neg)
   940   done
   941 
   942 text{*The ``conjunction of implication'' lemmas produce two cases when the
   943 comparison is a goal, but give four when the comparison is an assumption.*}
   944 
   945 lemma mult_less_cancel_right:
   946   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   947   using mult_less_cancel_right_disj [of a c b] by auto
   948 
   949 lemma mult_less_cancel_left:
   950   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   951   using mult_less_cancel_left_disj [of c a b] by auto
   952 
   953 lemma mult_le_cancel_right:
   954    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   955 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
   956 
   957 lemma mult_le_cancel_left:
   958   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   959 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
   960 
   961 lemma mult_le_cancel_left_pos:
   962   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
   963 by (auto simp: mult_le_cancel_left)
   964 
   965 lemma mult_le_cancel_left_neg:
   966   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
   967 by (auto simp: mult_le_cancel_left)
   968 
   969 lemma mult_less_cancel_left_pos:
   970   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
   971 by (auto simp: mult_less_cancel_left)
   972 
   973 lemma mult_less_cancel_left_neg:
   974   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
   975 by (auto simp: mult_less_cancel_left)
   976 
   977 end
   978 
   979 lemmas mult_sign_intros =
   980   mult_nonneg_nonneg mult_nonneg_nonpos
   981   mult_nonpos_nonneg mult_nonpos_nonpos
   982   mult_pos_pos mult_pos_neg
   983   mult_neg_pos mult_neg_neg
   984 
   985 class ordered_comm_ring = comm_ring + ordered_comm_semiring
   986 begin
   987 
   988 subclass ordered_ring ..
   989 subclass ordered_cancel_comm_semiring ..
   990 
   991 end
   992 
   993 class linordered_semidom = comm_semiring_1_cancel + linordered_comm_semiring_strict +
   994   (*previously linordered_semiring*)
   995   assumes zero_less_one [simp]: "0 < 1"
   996 begin
   997 
   998 lemma pos_add_strict:
   999   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
  1000   using add_strict_mono [of 0 a b c] by simp
  1001 
  1002 lemma zero_le_one [simp]: "0 \<le> 1"
  1003 by (rule zero_less_one [THEN less_imp_le]) 
  1004 
  1005 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
  1006 by (simp add: not_le) 
  1007 
  1008 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
  1009 by (simp add: not_less) 
  1010 
  1011 lemma less_1_mult:
  1012   assumes "1 < m" and "1 < n"
  1013   shows "1 < m * n"
  1014   using assms mult_strict_mono [of 1 m 1 n]
  1015     by (simp add:  less_trans [OF zero_less_one]) 
  1016 
  1017 end
  1018 
  1019 class linordered_idom = comm_ring_1 +
  1020   linordered_comm_semiring_strict + ordered_ab_group_add +
  1021   abs_if + sgn_if
  1022   (*previously linordered_ring*)
  1023 begin
  1024 
  1025 subclass linordered_semiring_1_strict ..
  1026 subclass linordered_ring_strict ..
  1027 subclass ordered_comm_ring ..
  1028 subclass idom ..
  1029 
  1030 subclass linordered_semidom
  1031 proof
  1032   have "0 \<le> 1 * 1" by (rule zero_le_square)
  1033   thus "0 < 1" by (simp add: le_less)
  1034 qed 
  1035 
  1036 lemma linorder_neqE_linordered_idom:
  1037   assumes "x \<noteq> y" obtains "x < y" | "y < x"
  1038   using assms by (rule neqE)
  1039 
  1040 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
  1041 
  1042 lemma mult_le_cancel_right1:
  1043   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1044 by (insert mult_le_cancel_right [of 1 c b], simp)
  1045 
  1046 lemma mult_le_cancel_right2:
  1047   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1048 by (insert mult_le_cancel_right [of a c 1], simp)
  1049 
  1050 lemma mult_le_cancel_left1:
  1051   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1052 by (insert mult_le_cancel_left [of c 1 b], simp)
  1053 
  1054 lemma mult_le_cancel_left2:
  1055   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1056 by (insert mult_le_cancel_left [of c a 1], simp)
  1057 
  1058 lemma mult_less_cancel_right1:
  1059   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1060 by (insert mult_less_cancel_right [of 1 c b], simp)
  1061 
  1062 lemma mult_less_cancel_right2:
  1063   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1064 by (insert mult_less_cancel_right [of a c 1], simp)
  1065 
  1066 lemma mult_less_cancel_left1:
  1067   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1068 by (insert mult_less_cancel_left [of c 1 b], simp)
  1069 
  1070 lemma mult_less_cancel_left2:
  1071   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1072 by (insert mult_less_cancel_left [of c a 1], simp)
  1073 
  1074 lemma sgn_sgn [simp]:
  1075   "sgn (sgn a) = sgn a"
  1076 unfolding sgn_if by simp
  1077 
  1078 lemma sgn_0_0:
  1079   "sgn a = 0 \<longleftrightarrow> a = 0"
  1080 unfolding sgn_if by simp
  1081 
  1082 lemma sgn_1_pos:
  1083   "sgn a = 1 \<longleftrightarrow> a > 0"
  1084 unfolding sgn_if by simp
  1085 
  1086 lemma sgn_1_neg:
  1087   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1088 unfolding sgn_if by auto
  1089 
  1090 lemma sgn_pos [simp]:
  1091   "0 < a \<Longrightarrow> sgn a = 1"
  1092 unfolding sgn_1_pos .
  1093 
  1094 lemma sgn_neg [simp]:
  1095   "a < 0 \<Longrightarrow> sgn a = - 1"
  1096 unfolding sgn_1_neg .
  1097 
  1098 lemma sgn_times:
  1099   "sgn (a * b) = sgn a * sgn b"
  1100 by (auto simp add: sgn_if zero_less_mult_iff)
  1101 
  1102 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1103 unfolding sgn_if abs_if by auto
  1104 
  1105 lemma sgn_greater [simp]:
  1106   "0 < sgn a \<longleftrightarrow> 0 < a"
  1107   unfolding sgn_if by auto
  1108 
  1109 lemma sgn_less [simp]:
  1110   "sgn a < 0 \<longleftrightarrow> a < 0"
  1111   unfolding sgn_if by auto
  1112 
  1113 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1114   by (simp add: abs_if)
  1115 
  1116 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1117   by (simp add: abs_if)
  1118 
  1119 lemma dvd_if_abs_eq:
  1120   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1121 by(subst abs_dvd_iff[symmetric]) simp
  1122 
  1123 text {* The following lemmas can be proven in more general structures, but
  1124 are dangerous as simp rules in absence of @{thm neg_equal_zero}, 
  1125 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1126 
  1127 lemma equation_minus_iff_1 [simp, no_atp]:
  1128   "1 = - a \<longleftrightarrow> a = - 1"
  1129   by (fact equation_minus_iff)
  1130 
  1131 lemma minus_equation_iff_1 [simp, no_atp]:
  1132   "- a = 1 \<longleftrightarrow> a = - 1"
  1133   by (subst minus_equation_iff, auto)
  1134 
  1135 lemma le_minus_iff_1 [simp, no_atp]:
  1136   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1137   by (fact le_minus_iff)
  1138 
  1139 lemma minus_le_iff_1 [simp, no_atp]:
  1140   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1141   by (fact minus_le_iff)
  1142 
  1143 lemma less_minus_iff_1 [simp, no_atp]:
  1144   "1 < - b \<longleftrightarrow> b < - 1"
  1145   by (fact less_minus_iff)
  1146 
  1147 lemma minus_less_iff_1 [simp, no_atp]:
  1148   "- a < 1 \<longleftrightarrow> - 1 < a"
  1149   by (fact minus_less_iff)
  1150 
  1151 end
  1152 
  1153 text {* Simprules for comparisons where common factors can be cancelled. *}
  1154 
  1155 lemmas mult_compare_simps =
  1156     mult_le_cancel_right mult_le_cancel_left
  1157     mult_le_cancel_right1 mult_le_cancel_right2
  1158     mult_le_cancel_left1 mult_le_cancel_left2
  1159     mult_less_cancel_right mult_less_cancel_left
  1160     mult_less_cancel_right1 mult_less_cancel_right2
  1161     mult_less_cancel_left1 mult_less_cancel_left2
  1162     mult_cancel_right mult_cancel_left
  1163     mult_cancel_right1 mult_cancel_right2
  1164     mult_cancel_left1 mult_cancel_left2
  1165 
  1166 text {* Reasoning about inequalities with division *}
  1167 
  1168 context linordered_semidom
  1169 begin
  1170 
  1171 lemma less_add_one: "a < a + 1"
  1172 proof -
  1173   have "a + 0 < a + 1"
  1174     by (blast intro: zero_less_one add_strict_left_mono)
  1175   thus ?thesis by simp
  1176 qed
  1177 
  1178 lemma zero_less_two: "0 < 1 + 1"
  1179 by (blast intro: less_trans zero_less_one less_add_one)
  1180 
  1181 end
  1182 
  1183 context linordered_idom
  1184 begin
  1185 
  1186 lemma mult_right_le_one_le:
  1187   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1188   by (auto simp add: mult_le_cancel_left2)
  1189 
  1190 lemma mult_left_le_one_le:
  1191   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1192   by (auto simp add: mult_le_cancel_right2)
  1193 
  1194 end
  1195 
  1196 text {* Absolute Value *}
  1197 
  1198 context linordered_idom
  1199 begin
  1200 
  1201 lemma mult_sgn_abs:
  1202   "sgn x * \<bar>x\<bar> = x"
  1203   unfolding abs_if sgn_if by auto
  1204 
  1205 lemma abs_one [simp]:
  1206   "\<bar>1\<bar> = 1"
  1207   by (simp add: abs_if)
  1208 
  1209 end
  1210 
  1211 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1212   assumes abs_eq_mult:
  1213     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1214 
  1215 context linordered_idom
  1216 begin
  1217 
  1218 subclass ordered_ring_abs proof
  1219 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1220 
  1221 lemma abs_mult:
  1222   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>" 
  1223   by (rule abs_eq_mult) auto
  1224 
  1225 lemma abs_mult_self:
  1226   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1227   by (simp add: abs_if) 
  1228 
  1229 lemma abs_mult_less:
  1230   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1231 proof -
  1232   assume ac: "\<bar>a\<bar> < c"
  1233   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1234   assume "\<bar>b\<bar> < d"
  1235   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1236 qed
  1237 
  1238 lemma abs_less_iff:
  1239   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b" 
  1240   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1241 
  1242 lemma abs_mult_pos:
  1243   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1244   by (simp add: abs_mult)
  1245 
  1246 lemma abs_diff_less_iff:
  1247   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1248   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1249 
  1250 end
  1251 
  1252 code_identifier
  1253   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1254 
  1255 end
  1256