src/HOL/Probability/Measurable.thy
author Andreas Lochbihler
Tue Nov 11 08:57:46 2014 +0100 (2014-11-11)
changeset 58965 a62cdcc5344b
parent 57025 e7fd64f82876
child 59000 6eb0725503fc
permissions -rw-r--r--
add del option to measurable;
make measurability rules available as dynamic theorem;
     1 (*  Title:      HOL/Probability/Measurable.thy
     2     Author:     Johannes Hölzl <hoelzl@in.tum.de>
     3 *)
     4 theory Measurable
     5   imports
     6     Sigma_Algebra
     7     "~~/src/HOL/Library/Order_Continuity"
     8 begin
     9 
    10 hide_const (open) Order_Continuity.continuous
    11 
    12 subsection {* Measurability prover *}
    13 
    14 lemma (in algebra) sets_Collect_finite_All:
    15   assumes "\<And>i. i \<in> S \<Longrightarrow> {x\<in>\<Omega>. P i x} \<in> M" "finite S"
    16   shows "{x\<in>\<Omega>. \<forall>i\<in>S. P i x} \<in> M"
    17 proof -
    18   have "{x\<in>\<Omega>. \<forall>i\<in>S. P i x} = (if S = {} then \<Omega> else \<Inter>i\<in>S. {x\<in>\<Omega>. P i x})"
    19     by auto
    20   with assms show ?thesis by (auto intro!: sets_Collect_finite_All')
    21 qed
    22 
    23 abbreviation "pred M P \<equiv> P \<in> measurable M (count_space (UNIV::bool set))"
    24 
    25 lemma pred_def: "pred M P \<longleftrightarrow> {x\<in>space M. P x} \<in> sets M"
    26 proof
    27   assume "pred M P"
    28   then have "P -` {True} \<inter> space M \<in> sets M"
    29     by (auto simp: measurable_count_space_eq2)
    30   also have "P -` {True} \<inter> space M = {x\<in>space M. P x}" by auto
    31   finally show "{x\<in>space M. P x} \<in> sets M" .
    32 next
    33   assume P: "{x\<in>space M. P x} \<in> sets M"
    34   moreover
    35   { fix X
    36     have "X \<in> Pow (UNIV :: bool set)" by simp
    37     then have "P -` X \<inter> space M = {x\<in>space M. ((X = {True} \<longrightarrow> P x) \<and> (X = {False} \<longrightarrow> \<not> P x) \<and> X \<noteq> {})}"
    38       unfolding UNIV_bool Pow_insert Pow_empty by auto
    39     then have "P -` X \<inter> space M \<in> sets M"
    40       by (auto intro!: sets.sets_Collect_neg sets.sets_Collect_imp sets.sets_Collect_conj sets.sets_Collect_const P) }
    41   then show "pred M P"
    42     by (auto simp: measurable_def)
    43 qed
    44 
    45 lemma pred_sets1: "{x\<in>space M. P x} \<in> sets M \<Longrightarrow> f \<in> measurable N M \<Longrightarrow> pred N (\<lambda>x. P (f x))"
    46   by (rule measurable_compose[where f=f and N=M]) (auto simp: pred_def)
    47 
    48 lemma pred_sets2: "A \<in> sets N \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> pred M (\<lambda>x. f x \<in> A)"
    49   by (rule measurable_compose[where f=f and N=N]) (auto simp: pred_def Int_def[symmetric])
    50 
    51 ML_file "measurable.ML"
    52 
    53 attribute_setup measurable = {*
    54   Scan.lift (Scan.optional (Args.$$$ "del" >> K false) true --
    55     Scan.optional (Args.parens (Scan.optional (Args.$$$ "raw" >> K true) false --
    56       Scan.optional (Args.$$$ "generic" >> K Measurable.Generic) Measurable.Concrete))
    57     (false, Measurable.Concrete) >> (Thm.declaration_attribute o uncurry Measurable.add_del_thm))
    58 *} "declaration of measurability theorems"
    59 
    60 attribute_setup measurable_dest = {*
    61   Scan.lift (Scan.succeed (Thm.declaration_attribute Measurable.add_dest))
    62 *} "add dest rule for measurability prover"
    63 
    64 attribute_setup measurable_app = {*
    65   Scan.lift (Scan.succeed (Thm.declaration_attribute Measurable.add_app))
    66 *} "add application rule for measurability prover"
    67 
    68 method_setup measurable = {*
    69   Scan.lift (Scan.succeed (fn ctxt => METHOD (fn facts => Measurable.measurable_tac ctxt facts)))
    70 *} "measurability prover"
    71 
    72 simproc_setup measurable ("A \<in> sets M" | "f \<in> measurable M N") = {* K Measurable.simproc *}
    73 
    74 setup {*
    75   Global_Theory.add_thms_dynamic (@{binding measurable}, Measurable.get_all o Context.proof_of)
    76 *}
    77 
    78 declare
    79   measurable_compose_rev[measurable_dest]
    80   pred_sets1[measurable_dest]
    81   pred_sets2[measurable_dest]
    82   sets.sets_into_space[measurable_dest]
    83 
    84 declare
    85   sets.top[measurable]
    86   sets.empty_sets[measurable (raw)]
    87   sets.Un[measurable (raw)]
    88   sets.Diff[measurable (raw)]
    89 
    90 declare
    91   measurable_count_space[measurable (raw)]
    92   measurable_ident[measurable (raw)]
    93   measurable_ident_sets[measurable (raw)]
    94   measurable_const[measurable (raw)]
    95   measurable_If[measurable (raw)]
    96   measurable_comp[measurable (raw)]
    97   measurable_sets[measurable (raw)]
    98 
    99 lemma predE[measurable (raw)]: 
   100   "pred M P \<Longrightarrow> {x\<in>space M. P x} \<in> sets M"
   101   unfolding pred_def .
   102 
   103 lemma pred_intros_imp'[measurable (raw)]:
   104   "(K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. K \<longrightarrow> P x)"
   105   by (cases K) auto
   106 
   107 lemma pred_intros_conj1'[measurable (raw)]:
   108   "(K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. K \<and> P x)"
   109   by (cases K) auto
   110 
   111 lemma pred_intros_conj2'[measurable (raw)]:
   112   "(K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. P x \<and> K)"
   113   by (cases K) auto
   114 
   115 lemma pred_intros_disj1'[measurable (raw)]:
   116   "(\<not> K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. K \<or> P x)"
   117   by (cases K) auto
   118 
   119 lemma pred_intros_disj2'[measurable (raw)]:
   120   "(\<not> K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. P x \<or> K)"
   121   by (cases K) auto
   122 
   123 lemma pred_intros_logic[measurable (raw)]:
   124   "pred M (\<lambda>x. x \<in> space M)"
   125   "pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. \<not> P x)"
   126   "pred M (\<lambda>x. Q x) \<Longrightarrow> pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. Q x \<and> P x)"
   127   "pred M (\<lambda>x. Q x) \<Longrightarrow> pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. Q x \<longrightarrow> P x)"
   128   "pred M (\<lambda>x. Q x) \<Longrightarrow> pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. Q x \<or> P x)"
   129   "pred M (\<lambda>x. Q x) \<Longrightarrow> pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. Q x = P x)"
   130   "pred M (\<lambda>x. f x \<in> UNIV)"
   131   "pred M (\<lambda>x. f x \<in> {})"
   132   "pred M (\<lambda>x. P' (f x) x) \<Longrightarrow> pred M (\<lambda>x. f x \<in> {y. P' y x})"
   133   "pred M (\<lambda>x. f x \<in> (B x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> - (B x))"
   134   "pred M (\<lambda>x. f x \<in> (A x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (B x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (A x) - (B x))"
   135   "pred M (\<lambda>x. f x \<in> (A x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (B x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (A x) \<inter> (B x))"
   136   "pred M (\<lambda>x. f x \<in> (A x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (B x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (A x) \<union> (B x))"
   137   "pred M (\<lambda>x. g x (f x) \<in> (X x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (g x) -` (X x))"
   138   by (auto simp: iff_conv_conj_imp pred_def)
   139 
   140 lemma pred_intros_countable[measurable (raw)]:
   141   fixes P :: "'a \<Rightarrow> 'i :: countable \<Rightarrow> bool"
   142   shows 
   143     "(\<And>i. pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<forall>i. P x i)"
   144     "(\<And>i. pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<exists>i. P x i)"
   145   by (auto intro!: sets.sets_Collect_countable_All sets.sets_Collect_countable_Ex simp: pred_def)
   146 
   147 lemma pred_intros_countable_bounded[measurable (raw)]:
   148   fixes X :: "'i :: countable set"
   149   shows 
   150     "(\<And>i. i \<in> X \<Longrightarrow> pred M (\<lambda>x. x \<in> N x i)) \<Longrightarrow> pred M (\<lambda>x. x \<in> (\<Inter>i\<in>X. N x i))"
   151     "(\<And>i. i \<in> X \<Longrightarrow> pred M (\<lambda>x. x \<in> N x i)) \<Longrightarrow> pred M (\<lambda>x. x \<in> (\<Union>i\<in>X. N x i))"
   152     "(\<And>i. i \<in> X \<Longrightarrow> pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<forall>i\<in>X. P x i)"
   153     "(\<And>i. i \<in> X \<Longrightarrow> pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<exists>i\<in>X. P x i)"
   154   by (auto simp: Bex_def Ball_def)
   155 
   156 lemma pred_intros_finite[measurable (raw)]:
   157   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> pred M (\<lambda>x. x \<in> N x i)) \<Longrightarrow> pred M (\<lambda>x. x \<in> (\<Inter>i\<in>I. N x i))"
   158   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> pred M (\<lambda>x. x \<in> N x i)) \<Longrightarrow> pred M (\<lambda>x. x \<in> (\<Union>i\<in>I. N x i))"
   159   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<forall>i\<in>I. P x i)"
   160   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<exists>i\<in>I. P x i)"
   161   by (auto intro!: sets.sets_Collect_finite_Ex sets.sets_Collect_finite_All simp: iff_conv_conj_imp pred_def)
   162 
   163 lemma countable_Un_Int[measurable (raw)]:
   164   "(\<And>i :: 'i :: countable. i \<in> I \<Longrightarrow> N i \<in> sets M) \<Longrightarrow> (\<Union>i\<in>I. N i) \<in> sets M"
   165   "I \<noteq> {} \<Longrightarrow> (\<And>i :: 'i :: countable. i \<in> I \<Longrightarrow> N i \<in> sets M) \<Longrightarrow> (\<Inter>i\<in>I. N i) \<in> sets M"
   166   by auto
   167 
   168 declare
   169   finite_UN[measurable (raw)]
   170   finite_INT[measurable (raw)]
   171 
   172 lemma sets_Int_pred[measurable (raw)]:
   173   assumes space: "A \<inter> B \<subseteq> space M" and [measurable]: "pred M (\<lambda>x. x \<in> A)" "pred M (\<lambda>x. x \<in> B)"
   174   shows "A \<inter> B \<in> sets M"
   175 proof -
   176   have "{x\<in>space M. x \<in> A \<inter> B} \<in> sets M" by auto
   177   also have "{x\<in>space M. x \<in> A \<inter> B} = A \<inter> B"
   178     using space by auto
   179   finally show ?thesis .
   180 qed
   181 
   182 lemma [measurable (raw generic)]:
   183   assumes f: "f \<in> measurable M N" and c: "c \<in> space N \<Longrightarrow> {c} \<in> sets N"
   184   shows pred_eq_const1: "pred M (\<lambda>x. f x = c)"
   185     and pred_eq_const2: "pred M (\<lambda>x. c = f x)"
   186 proof -
   187   show "pred M (\<lambda>x. f x = c)"
   188   proof cases
   189     assume "c \<in> space N"
   190     with measurable_sets[OF f c] show ?thesis
   191       by (auto simp: Int_def conj_commute pred_def)
   192   next
   193     assume "c \<notin> space N"
   194     with f[THEN measurable_space] have "{x \<in> space M. f x = c} = {}" by auto
   195     then show ?thesis by (auto simp: pred_def cong: conj_cong)
   196   qed
   197   then show "pred M (\<lambda>x. c = f x)"
   198     by (simp add: eq_commute)
   199 qed
   200 
   201 lemma pred_le_const[measurable (raw generic)]:
   202   assumes f: "f \<in> measurable M N" and c: "{.. c} \<in> sets N" shows "pred M (\<lambda>x. f x \<le> c)"
   203   using measurable_sets[OF f c]
   204   by (auto simp: Int_def conj_commute eq_commute pred_def)
   205 
   206 lemma pred_const_le[measurable (raw generic)]:
   207   assumes f: "f \<in> measurable M N" and c: "{c ..} \<in> sets N" shows "pred M (\<lambda>x. c \<le> f x)"
   208   using measurable_sets[OF f c]
   209   by (auto simp: Int_def conj_commute eq_commute pred_def)
   210 
   211 lemma pred_less_const[measurable (raw generic)]:
   212   assumes f: "f \<in> measurable M N" and c: "{..< c} \<in> sets N" shows "pred M (\<lambda>x. f x < c)"
   213   using measurable_sets[OF f c]
   214   by (auto simp: Int_def conj_commute eq_commute pred_def)
   215 
   216 lemma pred_const_less[measurable (raw generic)]:
   217   assumes f: "f \<in> measurable M N" and c: "{c <..} \<in> sets N" shows "pred M (\<lambda>x. c < f x)"
   218   using measurable_sets[OF f c]
   219   by (auto simp: Int_def conj_commute eq_commute pred_def)
   220 
   221 declare
   222   sets.Int[measurable (raw)]
   223 
   224 lemma pred_in_If[measurable (raw)]:
   225   "(P \<Longrightarrow> pred M (\<lambda>x. x \<in> A x)) \<Longrightarrow> (\<not> P \<Longrightarrow> pred M (\<lambda>x. x \<in> B x)) \<Longrightarrow>
   226     pred M (\<lambda>x. x \<in> (if P then A x else B x))"
   227   by auto
   228 
   229 lemma sets_range[measurable_dest]:
   230   "A ` I \<subseteq> sets M \<Longrightarrow> i \<in> I \<Longrightarrow> A i \<in> sets M"
   231   by auto
   232 
   233 lemma pred_sets_range[measurable_dest]:
   234   "A ` I \<subseteq> sets N \<Longrightarrow> i \<in> I \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> pred M (\<lambda>x. f x \<in> A i)"
   235   using pred_sets2[OF sets_range] by auto
   236 
   237 lemma sets_All[measurable_dest]:
   238   "\<forall>i. A i \<in> sets (M i) \<Longrightarrow> A i \<in> sets (M i)"
   239   by auto
   240 
   241 lemma pred_sets_All[measurable_dest]:
   242   "\<forall>i. A i \<in> sets (N i) \<Longrightarrow> f \<in> measurable M (N i) \<Longrightarrow> pred M (\<lambda>x. f x \<in> A i)"
   243   using pred_sets2[OF sets_All, of A N f] by auto
   244 
   245 lemma sets_Ball[measurable_dest]:
   246   "\<forall>i\<in>I. A i \<in> sets (M i) \<Longrightarrow> i\<in>I \<Longrightarrow> A i \<in> sets (M i)"
   247   by auto
   248 
   249 lemma pred_sets_Ball[measurable_dest]:
   250   "\<forall>i\<in>I. A i \<in> sets (N i) \<Longrightarrow> i\<in>I \<Longrightarrow> f \<in> measurable M (N i) \<Longrightarrow> pred M (\<lambda>x. f x \<in> A i)"
   251   using pred_sets2[OF sets_Ball, of _ _ _ f] by auto
   252 
   253 lemma measurable_finite[measurable (raw)]:
   254   fixes S :: "'a \<Rightarrow> nat set"
   255   assumes [measurable]: "\<And>i. {x\<in>space M. i \<in> S x} \<in> sets M"
   256   shows "pred M (\<lambda>x. finite (S x))"
   257   unfolding finite_nat_set_iff_bounded by (simp add: Ball_def)
   258 
   259 lemma measurable_Least[measurable]:
   260   assumes [measurable]: "(\<And>i::nat. (\<lambda>x. P i x) \<in> measurable M (count_space UNIV))"q
   261   shows "(\<lambda>x. LEAST i. P i x) \<in> measurable M (count_space UNIV)"
   262   unfolding measurable_def by (safe intro!: sets_Least) simp_all
   263 
   264 lemma measurable_Max_nat[measurable (raw)]: 
   265   fixes P :: "nat \<Rightarrow> 'a \<Rightarrow> bool"
   266   assumes [measurable]: "\<And>i. Measurable.pred M (P i)"
   267   shows "(\<lambda>x. Max {i. P i x}) \<in> measurable M (count_space UNIV)"
   268   unfolding measurable_count_space_eq2_countable
   269 proof safe
   270   fix n
   271 
   272   { fix x assume "\<forall>i. \<exists>n\<ge>i. P n x"
   273     then have "infinite {i. P i x}"
   274       unfolding infinite_nat_iff_unbounded_le by auto
   275     then have "Max {i. P i x} = the None"
   276       by (rule Max.infinite) }
   277   note 1 = this
   278 
   279   { fix x i j assume "P i x" "\<forall>n\<ge>j. \<not> P n x"
   280     then have "finite {i. P i x}"
   281       by (auto simp: subset_eq not_le[symmetric] finite_nat_iff_bounded)
   282     with `P i x` have "P (Max {i. P i x}) x" "i \<le> Max {i. P i x}" "finite {i. P i x}"
   283       using Max_in[of "{i. P i x}"] by auto }
   284   note 2 = this
   285 
   286   have "(\<lambda>x. Max {i. P i x}) -` {n} \<inter> space M = {x\<in>space M. Max {i. P i x} = n}"
   287     by auto
   288   also have "\<dots> = 
   289     {x\<in>space M. if (\<forall>i. \<exists>n\<ge>i. P n x) then the None = n else 
   290       if (\<exists>i. P i x) then P n x \<and> (\<forall>i>n. \<not> P i x)
   291       else Max {} = n}"
   292     by (intro arg_cong[where f=Collect] ext conj_cong)
   293        (auto simp add: 1 2 not_le[symmetric] intro!: Max_eqI)
   294   also have "\<dots> \<in> sets M"
   295     by measurable
   296   finally show "(\<lambda>x. Max {i. P i x}) -` {n} \<inter> space M \<in> sets M" .
   297 qed simp
   298 
   299 lemma measurable_Min_nat[measurable (raw)]: 
   300   fixes P :: "nat \<Rightarrow> 'a \<Rightarrow> bool"
   301   assumes [measurable]: "\<And>i. Measurable.pred M (P i)"
   302   shows "(\<lambda>x. Min {i. P i x}) \<in> measurable M (count_space UNIV)"
   303   unfolding measurable_count_space_eq2_countable
   304 proof safe
   305   fix n
   306 
   307   { fix x assume "\<forall>i. \<exists>n\<ge>i. P n x"
   308     then have "infinite {i. P i x}"
   309       unfolding infinite_nat_iff_unbounded_le by auto
   310     then have "Min {i. P i x} = the None"
   311       by (rule Min.infinite) }
   312   note 1 = this
   313 
   314   { fix x i j assume "P i x" "\<forall>n\<ge>j. \<not> P n x"
   315     then have "finite {i. P i x}"
   316       by (auto simp: subset_eq not_le[symmetric] finite_nat_iff_bounded)
   317     with `P i x` have "P (Min {i. P i x}) x" "Min {i. P i x} \<le> i" "finite {i. P i x}"
   318       using Min_in[of "{i. P i x}"] by auto }
   319   note 2 = this
   320 
   321   have "(\<lambda>x. Min {i. P i x}) -` {n} \<inter> space M = {x\<in>space M. Min {i. P i x} = n}"
   322     by auto
   323   also have "\<dots> = 
   324     {x\<in>space M. if (\<forall>i. \<exists>n\<ge>i. P n x) then the None = n else 
   325       if (\<exists>i. P i x) then P n x \<and> (\<forall>i<n. \<not> P i x)
   326       else Min {} = n}"
   327     by (intro arg_cong[where f=Collect] ext conj_cong)
   328        (auto simp add: 1 2 not_le[symmetric] intro!: Min_eqI)
   329   also have "\<dots> \<in> sets M"
   330     by measurable
   331   finally show "(\<lambda>x. Min {i. P i x}) -` {n} \<inter> space M \<in> sets M" .
   332 qed simp
   333 
   334 lemma measurable_count_space_insert[measurable (raw)]:
   335   "s \<in> S \<Longrightarrow> A \<in> sets (count_space S) \<Longrightarrow> insert s A \<in> sets (count_space S)"
   336   by simp
   337 
   338 lemma measurable_card[measurable]:
   339   fixes S :: "'a \<Rightarrow> nat set"
   340   assumes [measurable]: "\<And>i. {x\<in>space M. i \<in> S x} \<in> sets M"
   341   shows "(\<lambda>x. card (S x)) \<in> measurable M (count_space UNIV)"
   342   unfolding measurable_count_space_eq2_countable
   343 proof safe
   344   fix n show "(\<lambda>x. card (S x)) -` {n} \<inter> space M \<in> sets M"
   345   proof (cases n)
   346     case 0
   347     then have "(\<lambda>x. card (S x)) -` {n} \<inter> space M = {x\<in>space M. infinite (S x) \<or> (\<forall>i. i \<notin> S x)}"
   348       by auto
   349     also have "\<dots> \<in> sets M"
   350       by measurable
   351     finally show ?thesis .
   352   next
   353     case (Suc i)
   354     then have "(\<lambda>x. card (S x)) -` {n} \<inter> space M =
   355       (\<Union>F\<in>{A\<in>{A. finite A}. card A = n}. {x\<in>space M. (\<forall>i. i \<in> S x \<longleftrightarrow> i \<in> F)})"
   356       unfolding set_eq_iff[symmetric] Collect_bex_eq[symmetric] by (auto intro: card_ge_0_finite)
   357     also have "\<dots> \<in> sets M"
   358       by (intro sets.countable_UN' countable_Collect countable_Collect_finite) auto
   359     finally show ?thesis .
   360   qed
   361 qed rule
   362 
   363 subsection {* Measurability for (co)inductive predicates *}
   364 
   365 lemma measurable_lfp:
   366   assumes "Order_Continuity.continuous F"
   367   assumes *: "\<And>A. pred M A \<Longrightarrow> pred M (F A)"
   368   shows "pred M (lfp F)"
   369 proof -
   370   { fix i have "Measurable.pred M (\<lambda>x. (F ^^ i) (\<lambda>x. False) x)"
   371       by (induct i) (auto intro!: *) }
   372   then have "Measurable.pred M (\<lambda>x. \<exists>i. (F ^^ i) (\<lambda>x. False) x)"
   373     by measurable
   374   also have "(\<lambda>x. \<exists>i. (F ^^ i) (\<lambda>x. False) x) = (SUP i. (F ^^ i) bot)"
   375     by (auto simp add: bot_fun_def)
   376   also have "\<dots> = lfp F"
   377     by (rule continuous_lfp[symmetric]) fact
   378   finally show ?thesis .
   379 qed
   380 
   381 lemma measurable_gfp:
   382   assumes "Order_Continuity.down_continuous F"
   383   assumes *: "\<And>A. pred M A \<Longrightarrow> pred M (F A)"
   384   shows "pred M (gfp F)"
   385 proof -
   386   { fix i have "Measurable.pred M (\<lambda>x. (F ^^ i) (\<lambda>x. True) x)"
   387       by (induct i) (auto intro!: *) }
   388   then have "Measurable.pred M (\<lambda>x. \<forall>i. (F ^^ i) (\<lambda>x. True) x)"
   389     by measurable
   390   also have "(\<lambda>x. \<forall>i. (F ^^ i) (\<lambda>x. True) x) = (INF i. (F ^^ i) top)"
   391     by (auto simp add: top_fun_def)
   392   also have "\<dots> = gfp F"
   393     by (rule down_continuous_gfp[symmetric]) fact
   394   finally show ?thesis .
   395 qed
   396 
   397 hide_const (open) pred
   398 
   399 end