src/Pure/drule.ML
author berghofe
Thu Apr 21 19:12:03 2005 +0200 (2005-04-21)
changeset 15797 a63605582573
parent 15669 2b1f1902505d
child 15875 3e9a54e033b9
permissions -rw-r--r--
- Eliminated nodup_vars check.
- Unification and matching functions now check types of term variables / sorts
of type variables when applying a substitution.
- Thm.instantiate now takes (ctyp * ctyp) list instead of (indexname * ctyp) list
as argument, to allow for proper instantiation of theorems containing
type variables with same name but different sorts.
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val strip_imp_prems   : cterm -> cterm list
    18   val strip_imp_concl   : cterm -> cterm
    19   val cprems_of         : thm -> cterm list
    20   val cterm_fun         : (term -> term) -> (cterm -> cterm)
    21   val ctyp_fun          : (typ -> typ) -> (ctyp -> ctyp)
    22   val read_insts        :
    23           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    24                   -> (indexname -> typ option) * (indexname -> sort option)
    25                   -> string list -> (indexname * string) list
    26                   -> (ctyp * ctyp) list * (cterm * cterm) list
    27   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    28   val strip_shyps_warning : thm -> thm
    29   val forall_intr_list  : cterm list -> thm -> thm
    30   val forall_intr_frees : thm -> thm
    31   val forall_intr_vars  : thm -> thm
    32   val forall_elim_list  : cterm list -> thm -> thm
    33   val forall_elim_var   : int -> thm -> thm
    34   val forall_elim_vars  : int -> thm -> thm
    35   val gen_all           : thm -> thm
    36   val freeze_thaw       : thm -> thm * (thm -> thm)
    37   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    38   val implies_elim_list : thm -> thm list -> thm
    39   val implies_intr_list : cterm list -> thm -> thm
    40   val instantiate       :
    41     (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    42   val zero_var_indexes  : thm -> thm
    43   val standard          : thm -> thm
    44   val standard'         : thm -> thm
    45   val rotate_prems      : int -> thm -> thm
    46   val rearrange_prems   : int list -> thm -> thm
    47   val assume_ax         : theory -> string -> thm
    48   val RSN               : thm * (int * thm) -> thm
    49   val RS                : thm * thm -> thm
    50   val RLN               : thm list * (int * thm list) -> thm list
    51   val RL                : thm list * thm list -> thm list
    52   val MRS               : thm list * thm -> thm
    53   val MRL               : thm list list * thm list -> thm list
    54   val OF                : thm * thm list -> thm
    55   val compose           : thm * int * thm -> thm list
    56   val COMP              : thm * thm -> thm
    57   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    58   val read_instantiate  : (string*string)list -> thm -> thm
    59   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    60   val eq_thm_sg         : thm * thm -> bool
    61   val eq_thm_prop	: thm * thm -> bool
    62   val weak_eq_thm       : thm * thm -> bool
    63   val size_of_thm       : thm -> int
    64   val reflexive_thm     : thm
    65   val symmetric_thm     : thm
    66   val transitive_thm    : thm
    67   val symmetric_fun     : thm -> thm
    68   val extensional       : thm -> thm
    69   val imp_cong          : thm
    70   val swap_prems_eq     : thm
    71   val equal_abs_elim    : cterm  -> thm -> thm
    72   val equal_abs_elim_list: cterm list -> thm -> thm
    73   val asm_rl            : thm
    74   val cut_rl            : thm
    75   val revcut_rl         : thm
    76   val thin_rl           : thm
    77   val triv_forall_equality: thm
    78   val swap_prems_rl     : thm
    79   val equal_intr_rule   : thm
    80   val equal_elim_rule1  : thm
    81   val inst              : string -> string -> thm -> thm
    82   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    83   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    84 end;
    85 
    86 signature DRULE =
    87 sig
    88   include BASIC_DRULE
    89   val strip_comb: cterm -> cterm * cterm list
    90   val strip_type: ctyp -> ctyp list * ctyp
    91   val add_used: thm -> string list -> string list
    92   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    93   val tag_rule: tag -> thm -> thm
    94   val untag_rule: string -> thm -> thm
    95   val tag: tag -> 'a attribute
    96   val untag: string -> 'a attribute
    97   val get_kind: thm -> string
    98   val kind: string -> 'a attribute
    99   val theoremK: string
   100   val lemmaK: string
   101   val corollaryK: string
   102   val internalK: string
   103   val kind_internal: 'a attribute
   104   val has_internal: tag list -> bool
   105   val impose_hyps: cterm list -> thm -> thm
   106   val satisfy_hyps: thm list -> thm -> thm
   107   val close_derivation: thm -> thm
   108   val local_standard: thm -> thm
   109   val compose_single: thm * int * thm -> thm
   110   val add_rule: thm -> thm list -> thm list
   111   val del_rule: thm -> thm list -> thm list
   112   val add_rules: thm list -> thm list -> thm list
   113   val del_rules: thm list -> thm list -> thm list
   114   val merge_rules: thm list * thm list -> thm list
   115   val imp_cong'         : thm -> thm -> thm
   116   val beta_eta_conversion: cterm -> thm
   117   val goals_conv        : (int -> bool) -> (cterm -> thm) -> cterm -> thm
   118   val forall_conv       : (cterm -> thm) -> cterm -> thm
   119   val fconv_rule        : (cterm -> thm) -> thm -> thm
   120   val norm_hhf_eq: thm
   121   val is_norm_hhf: term -> bool
   122   val norm_hhf: Sign.sg -> term -> term
   123   val triv_goal: thm
   124   val rev_triv_goal: thm
   125   val implies_intr_goals: cterm list -> thm -> thm
   126   val freeze_all: thm -> thm
   127   val mk_triv_goal: cterm -> thm
   128   val tvars_of_terms: term list -> (indexname * sort) list
   129   val vars_of_terms: term list -> (indexname * typ) list
   130   val tvars_of: thm -> (indexname * sort) list
   131   val vars_of: thm -> (indexname * typ) list
   132   val rename_bvars: (string * string) list -> thm -> thm
   133   val rename_bvars': string option list -> thm -> thm
   134   val unvarifyT: thm -> thm
   135   val unvarify: thm -> thm
   136   val tvars_intr_list: string list -> thm -> thm * (string * (indexname * sort)) list
   137   val remdups_rl: thm
   138   val conj_intr: thm -> thm -> thm
   139   val conj_intr_list: thm list -> thm
   140   val conj_elim: thm -> thm * thm
   141   val conj_elim_list: thm -> thm list
   142   val conj_elim_precise: int -> thm -> thm list
   143   val conj_intr_thm: thm
   144   val abs_def: thm -> thm
   145   val read_instantiate_sg': Sign.sg -> (indexname * string) list -> thm -> thm
   146   val read_instantiate': (indexname * string) list -> thm -> thm
   147 end;
   148 
   149 structure Drule: DRULE =
   150 struct
   151 
   152 
   153 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   154 
   155 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   156 
   157 (*dest_implies for cterms. Note T=prop below*)
   158 fun dest_implies ct =
   159     case term_of ct of
   160         (Const("==>", _) $ _ $ _) =>
   161             let val (ct1,ct2) = Thm.dest_comb ct
   162             in  (#2 (Thm.dest_comb ct1), ct2)  end
   163       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   164 
   165 fun dest_equals ct =
   166     case term_of ct of
   167         (Const("==", _) $ _ $ _) =>
   168             let val (ct1,ct2) = Thm.dest_comb ct
   169             in  (#2 (Thm.dest_comb ct1), ct2)  end
   170       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   171 
   172 
   173 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   174 fun strip_imp_prems ct =
   175     let val (cA,cB) = dest_implies ct
   176     in  cA :: strip_imp_prems cB  end
   177     handle TERM _ => [];
   178 
   179 (* A1==>...An==>B  goes to B, where B is not an implication *)
   180 fun strip_imp_concl ct =
   181     case term_of ct of (Const("==>", _) $ _ $ _) =>
   182         strip_imp_concl (#2 (Thm.dest_comb ct))
   183   | _ => ct;
   184 
   185 (*The premises of a theorem, as a cterm list*)
   186 val cprems_of = strip_imp_prems o cprop_of;
   187 
   188 fun cterm_fun f ct =
   189   let val {t, sign, ...} = Thm.rep_cterm ct
   190   in Thm.cterm_of sign (f t) end;
   191 
   192 fun ctyp_fun f cT =
   193   let val {T, sign, ...} = Thm.rep_ctyp cT
   194   in Thm.ctyp_of sign (f T) end;
   195 
   196 val proto_sign = Theory.sign_of ProtoPure.thy;
   197 
   198 val implies = cterm_of proto_sign Term.implies;
   199 
   200 (*cterm version of mk_implies*)
   201 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   202 
   203 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   204 fun list_implies([], B) = B
   205   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   206 
   207 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   208 fun strip_comb ct = 
   209   let
   210     fun stripc (p as (ct, cts)) =
   211       let val (ct1, ct2) = Thm.dest_comb ct
   212       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   213   in stripc (ct, []) end;
   214 
   215 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   216 fun strip_type cT = (case Thm.typ_of cT of
   217     Type ("fun", _) =>
   218       let
   219         val [cT1, cT2] = Thm.dest_ctyp cT;
   220         val (cTs, cT') = strip_type cT2
   221       in (cT1 :: cTs, cT') end
   222   | _ => ([], cT));
   223 
   224 
   225 (** reading of instantiations **)
   226 
   227 fun absent ixn =
   228   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   229 
   230 fun inst_failure ixn =
   231   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   232 
   233 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   234 let
   235     fun is_tv ((a, _), _) =
   236       (case Symbol.explode a of "'" :: _ => true | _ => false);
   237     val (tvs, vs) = List.partition is_tv insts;
   238     fun sort_of ixn = case rsorts ixn of SOME S => S | NONE => absent ixn;
   239     fun readT (ixn, st) =
   240         let val S = sort_of ixn;
   241             val T = Sign.read_typ (sign,sorts) st;
   242         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   243            else inst_failure ixn
   244         end
   245     val tye = map readT tvs;
   246     fun mkty(ixn,st) = (case rtypes ixn of
   247                           SOME T => (ixn,(st,typ_subst_TVars tye T))
   248                         | NONE => absent ixn);
   249     val ixnsTs = map mkty vs;
   250     val ixns = map fst ixnsTs
   251     and sTs  = map snd ixnsTs
   252     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   253     fun mkcVar(ixn,T) =
   254         let val U = typ_subst_TVars tye2 T
   255         in cterm_of sign (Var(ixn,U)) end
   256     val ixnTs = ListPair.zip(ixns, map snd sTs)
   257 in (map (fn (ixn, T) => (ctyp_of sign (TVar (ixn, sort_of ixn)),
   258       ctyp_of sign T)) (tye2 @ tye),
   259     ListPair.zip(map mkcVar ixnTs,cts))
   260 end;
   261 
   262 
   263 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   264      Used for establishing default types (of variables) and sorts (of
   265      type variables) when reading another term.
   266      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   267 ***)
   268 
   269 fun types_sorts thm =
   270     let val {prop, hyps, tpairs, ...} = Thm.rep_thm thm;
   271         (* bogus term! *)
   272         val big = list_comb (list_comb (prop, hyps), Thm.terms_of_tpairs tpairs);
   273         val vars = map dest_Var (term_vars big);
   274         val frees = map dest_Free (term_frees big);
   275         val tvars = term_tvars big;
   276         val tfrees = term_tfrees big;
   277         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   278         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   279     in (typ,sort) end;
   280 
   281 fun add_used thm used =
   282   let val {prop, hyps, tpairs, ...} = Thm.rep_thm thm in
   283     add_term_tvarnames (prop, used)
   284     |> fold (curry add_term_tvarnames) hyps
   285     |> fold (curry add_term_tvarnames) (Thm.terms_of_tpairs tpairs)
   286   end;
   287 
   288 
   289 
   290 (** basic attributes **)
   291 
   292 (* dependent rules *)
   293 
   294 fun rule_attribute f (x, thm) = (x, (f x thm));
   295 
   296 
   297 (* add / delete tags *)
   298 
   299 fun map_tags f thm =
   300   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   301 
   302 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   303 fun untag_rule s = map_tags (filter_out (equal s o #1));
   304 
   305 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   306 fun untag s x = rule_attribute (K (untag_rule s)) x;
   307 
   308 fun simple_tag name x = tag (name, []) x;
   309 
   310 
   311 (* theorem kinds *)
   312 
   313 val theoremK = "theorem";
   314 val lemmaK = "lemma";
   315 val corollaryK = "corollary";
   316 val internalK = "internal";
   317 
   318 fun get_kind thm =
   319   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   320     SOME (k :: _) => k
   321   | _ => "unknown");
   322 
   323 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   324 fun kind k x = if k = "" then x else rule_attribute (K (kind_rule k)) x;
   325 fun kind_internal x = kind internalK x;
   326 fun has_internal tags = exists (equal internalK o fst) tags;
   327 
   328 
   329 
   330 (** Standardization of rules **)
   331 
   332 (*Strip extraneous shyps as far as possible*)
   333 fun strip_shyps_warning thm =
   334   let
   335     val str_of_sort = Pretty.str_of o Sign.pretty_sort (Thm.sign_of_thm thm);
   336     val thm' = Thm.strip_shyps thm;
   337     val xshyps = Thm.extra_shyps thm';
   338   in
   339     if null xshyps then ()
   340     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   341     thm'
   342   end;
   343 
   344 (*Generalization over a list of variables, IGNORING bad ones*)
   345 fun forall_intr_list [] th = th
   346   | forall_intr_list (y::ys) th =
   347         let val gth = forall_intr_list ys th
   348         in  forall_intr y gth   handle THM _ =>  gth  end;
   349 
   350 (*Generalization over all suitable Free variables*)
   351 fun forall_intr_frees th =
   352     let val {prop,sign,...} = rep_thm th
   353     in  forall_intr_list
   354          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   355          th
   356     end;
   357 
   358 val forall_elim_var = PureThy.forall_elim_var;
   359 val forall_elim_vars = PureThy.forall_elim_vars;
   360 
   361 fun gen_all thm =
   362   let
   363     val {sign, prop, maxidx, ...} = Thm.rep_thm thm;
   364     fun elim (th, (x, T)) = Thm.forall_elim (Thm.cterm_of sign (Var ((x, maxidx + 1), T))) th;
   365     val vs = Term.strip_all_vars prop;
   366   in Library.foldl elim (thm, Term.variantlist (map #1 vs, []) ~~ map #2 vs) end;
   367 
   368 (*Specialization over a list of cterms*)
   369 fun forall_elim_list cts th = foldr (uncurry forall_elim) th (rev cts);
   370 
   371 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   372 fun implies_intr_list cAs th = foldr (uncurry implies_intr) th cAs;
   373 
   374 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   375 fun implies_elim_list impth ths = Library.foldl (uncurry implies_elim) (impth,ths);
   376 
   377 (* maps |- B to A1,...,An |- B *)
   378 fun impose_hyps chyps th =
   379   let val chyps' = gen_rems (op aconv o apfst Thm.term_of) (chyps, #hyps (Thm.rep_thm th))
   380   in implies_elim_list (implies_intr_list chyps' th) (map Thm.assume chyps') end;
   381 
   382 (* maps A1,...,An and A1,...,An |- B to |- B *)
   383 fun satisfy_hyps ths th =
   384   implies_elim_list (implies_intr_list (map (#prop o Thm.crep_thm) ths) th) ths;
   385 
   386 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   387 fun zero_var_indexes th =
   388     let val {prop,sign,tpairs,...} = rep_thm th;
   389         val (tpair_l, tpair_r) = Library.split_list tpairs;
   390         val vars = foldr add_term_vars 
   391                          (foldr add_term_vars (term_vars prop) tpair_l) tpair_r;
   392         val bs = Library.foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   393         val inrs = 
   394             foldr add_term_tvars 
   395                   (foldr add_term_tvars (term_tvars prop) tpair_l) tpair_r;
   396         val nms' = rev(Library.foldl add_new_id ([], map (#1 o #1) inrs));
   397         val tye = ListPair.map (fn ((v, rs), a) => (TVar (v, rs), TVar ((a, 0), rs)))
   398                      (inrs, nms')
   399         val ctye = map (pairself (ctyp_of sign)) tye;
   400         fun varpairs([],[]) = []
   401           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   402                 let val T' = typ_subst_atomic tye T
   403                 in (cterm_of sign (Var(v,T')),
   404                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   405                 end
   406           | varpairs _ = raise TERM("varpairs", []);
   407     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   408 
   409 
   410 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   411     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   412 
   413 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   414   This step can lose information.*)
   415 fun flexflex_unique th =
   416     case Seq.chop (2, flexflex_rule th) of
   417       ([th],_) => th
   418     | ([],_)   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   419     |      _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   420 
   421 fun close_derivation thm =
   422   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   423   else thm;
   424 
   425 fun standard' th =
   426   let val {maxidx,...} = rep_thm th in
   427     th
   428     |> implies_intr_hyps
   429     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   430     |> strip_shyps_warning
   431     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   432   end;
   433 
   434 val standard = close_derivation o standard' o flexflex_unique;
   435 
   436 fun local_standard th =
   437   th |> strip_shyps |> zero_var_indexes
   438   |> Thm.compress |> close_derivation;
   439 
   440 
   441 (*Convert all Vars in a theorem to Frees.  Also return a function for
   442   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   443   Similar code in type/freeze_thaw*)
   444 
   445 fun freeze_thaw_robust th =
   446  let val fth = freezeT th
   447      val {prop, tpairs, sign, ...} = rep_thm fth
   448  in
   449    case foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   450        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   451      | vars =>
   452          let fun newName (Var(ix,_), pairs) =
   453                    let val v = gensym (string_of_indexname ix)
   454                    in  ((ix,v)::pairs)  end;
   455              val alist = foldr newName [] vars
   456              fun mk_inst (Var(v,T)) =
   457                  (cterm_of sign (Var(v,T)),
   458                   cterm_of sign (Free(valOf (assoc(alist,v)), T)))
   459              val insts = map mk_inst vars
   460              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   461                  th' |> forall_intr_list (map #2 insts)
   462                      |> forall_elim_list (map (Thm.cterm_incr_indexes i o #1) insts)
   463          in  (Thm.instantiate ([],insts) fth, thaw)  end
   464  end;
   465 
   466 (*Basic version of the function above. No option to rename Vars apart in thaw.
   467   The Frees created from Vars have nice names.*)
   468 fun freeze_thaw th =
   469  let val fth = freezeT th
   470      val {prop, tpairs, sign, ...} = rep_thm fth
   471  in
   472    case foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   473        [] => (fth, fn x => x)
   474      | vars =>
   475          let fun newName (Var(ix,_), (pairs,used)) =
   476                    let val v = variant used (string_of_indexname ix)
   477                    in  ((ix,v)::pairs, v::used)  end;
   478              val (alist, _) = foldr newName ([], Library.foldr add_term_names
   479                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   480              fun mk_inst (Var(v,T)) =
   481                  (cterm_of sign (Var(v,T)),
   482                   cterm_of sign (Free(valOf (assoc(alist,v)), T)))
   483              val insts = map mk_inst vars
   484              fun thaw th' =
   485                  th' |> forall_intr_list (map #2 insts)
   486                      |> forall_elim_list (map #1 insts)
   487          in  (Thm.instantiate ([],insts) fth, thaw)  end
   488  end;
   489 
   490 (*Rotates a rule's premises to the left by k*)
   491 val rotate_prems = permute_prems 0;
   492 
   493 (* permute prems, where the i-th position in the argument list (counting from 0)
   494    gives the position within the original thm to be transferred to position i.
   495    Any remaining trailing positions are left unchanged. *)
   496 val rearrange_prems = let
   497   fun rearr new []      thm = thm
   498   |   rearr new (p::ps) thm = rearr (new+1)
   499      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   500      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   501   in rearr 0 end;
   502 
   503 (*Assume a new formula, read following the same conventions as axioms.
   504   Generalizes over Free variables,
   505   creates the assumption, and then strips quantifiers.
   506   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   507              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   508 fun assume_ax thy sP =
   509     let val sign = Theory.sign_of thy
   510         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   511     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   512 
   513 (*Resolution: exactly one resolvent must be produced.*)
   514 fun tha RSN (i,thb) =
   515   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   516       ([th],_) => th
   517     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   518     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   519 
   520 (*resolution: P==>Q, Q==>R gives P==>R. *)
   521 fun tha RS thb = tha RSN (1,thb);
   522 
   523 (*For joining lists of rules*)
   524 fun thas RLN (i,thbs) =
   525   let val resolve = biresolution false (map (pair false) thas) i
   526       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   527   in  List.concat (map resb thbs)  end;
   528 
   529 fun thas RL thbs = thas RLN (1,thbs);
   530 
   531 (*Resolve a list of rules against bottom_rl from right to left;
   532   makes proof trees*)
   533 fun rls MRS bottom_rl =
   534   let fun rs_aux i [] = bottom_rl
   535         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   536   in  rs_aux 1 rls  end;
   537 
   538 (*As above, but for rule lists*)
   539 fun rlss MRL bottom_rls =
   540   let fun rs_aux i [] = bottom_rls
   541         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   542   in  rs_aux 1 rlss  end;
   543 
   544 (*A version of MRS with more appropriate argument order*)
   545 fun bottom_rl OF rls = rls MRS bottom_rl;
   546 
   547 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   548   with no lifting or renaming!  Q may contain ==> or meta-quants
   549   ALWAYS deletes premise i *)
   550 fun compose(tha,i,thb) =
   551     Seq.list_of (bicompose false (false,tha,0) i thb);
   552 
   553 fun compose_single (tha,i,thb) =
   554   (case compose (tha,i,thb) of
   555     [th] => th
   556   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   557 
   558 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   559 fun tha COMP thb =
   560     case compose(tha,1,thb) of
   561         [th] => th
   562       | _ =>   raise THM("COMP", 1, [tha,thb]);
   563 
   564 
   565 (** theorem equality **)
   566 
   567 (*True if the two theorems have the same signature.*)
   568 val eq_thm_sg = Sign.eq_sg o pairself Thm.sign_of_thm;
   569 
   570 (*True if the two theorems have the same prop field, ignoring hyps, der, etc.*)
   571 val eq_thm_prop = op aconv o pairself Thm.prop_of;
   572 
   573 (*Useful "distance" function for BEST_FIRST*)
   574 val size_of_thm = size_of_term o prop_of;
   575 
   576 (*maintain lists of theorems --- preserving canonical order*)
   577 fun del_rules rs rules = Library.gen_rems eq_thm_prop (rules, rs);
   578 fun add_rules rs rules = rs @ del_rules rs rules;
   579 val del_rule = del_rules o single;
   580 val add_rule = add_rules o single;
   581 fun merge_rules (rules1, rules2) = gen_merge_lists' eq_thm_prop rules1 rules2;
   582 
   583 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   584     (some) type variable renaming **)
   585 
   586  (* Can't use term_vars, because it sorts the resulting list of variable names.
   587     We instead need the unique list noramlised by the order of appearance
   588     in the term. *)
   589 fun term_vars' (t as Var(v,T)) = [t]
   590   | term_vars' (Abs(_,_,b)) = term_vars' b
   591   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   592   | term_vars' _ = [];
   593 
   594 fun forall_intr_vars th =
   595   let val {prop,sign,...} = rep_thm th;
   596       val vars = distinct (term_vars' prop);
   597   in forall_intr_list (map (cterm_of sign) vars) th end;
   598 
   599 val weak_eq_thm = Thm.eq_thm o pairself (forall_intr_vars o freezeT);
   600 
   601 
   602 (*** Meta-Rewriting Rules ***)
   603 
   604 fun read_prop s = read_cterm proto_sign (s, propT);
   605 
   606 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   607 fun store_standard_thm name thm = store_thm name (standard thm);
   608 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   609 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   610 
   611 val reflexive_thm =
   612   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),[])))
   613   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   614 
   615 val symmetric_thm =
   616   let val xy = read_prop "x == y"
   617   in store_standard_thm_open "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   618 
   619 val transitive_thm =
   620   let val xy = read_prop "x == y"
   621       val yz = read_prop "y == z"
   622       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   623   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   624 
   625 fun symmetric_fun thm = thm RS symmetric_thm;
   626 
   627 fun extensional eq =
   628   let val eq' =
   629     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   630   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   631 
   632 val imp_cong =
   633   let
   634     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   635     val AB = read_prop "PROP A ==> PROP B"
   636     val AC = read_prop "PROP A ==> PROP C"
   637     val A = read_prop "PROP A"
   638   in
   639     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   640       (implies_intr AB (implies_intr A
   641         (equal_elim (implies_elim (assume ABC) (assume A))
   642           (implies_elim (assume AB) (assume A)))))
   643       (implies_intr AC (implies_intr A
   644         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   645           (implies_elim (assume AC) (assume A)))))))
   646   end;
   647 
   648 val swap_prems_eq =
   649   let
   650     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   651     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   652     val A = read_prop "PROP A"
   653     val B = read_prop "PROP B"
   654   in
   655     store_standard_thm_open "swap_prems_eq" (equal_intr
   656       (implies_intr ABC (implies_intr B (implies_intr A
   657         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   658       (implies_intr BAC (implies_intr A (implies_intr B
   659         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   660   end;
   661 
   662 val imp_cong' = combination o combination (reflexive implies)
   663 
   664 fun abs_def thm =
   665   let
   666     val (_, cvs) = strip_comb (fst (dest_equals (cprop_of thm)));
   667     val thm' = foldr (fn (ct, thm) => Thm.abstract_rule
   668       (case term_of ct of Var ((a, _), _) => a | Free (a, _) => a | _ => "x")
   669         ct thm) thm cvs
   670   in transitive
   671     (symmetric (eta_conversion (fst (dest_equals (cprop_of thm'))))) thm'
   672   end;
   673 
   674 
   675 local
   676   val dest_eq = dest_equals o cprop_of
   677   val rhs_of = snd o dest_eq
   678 in
   679 fun beta_eta_conversion t =
   680   let val thm = beta_conversion true t
   681   in transitive thm (eta_conversion (rhs_of thm)) end
   682 end;
   683 
   684 (*In [A1,...,An]==>B, rewrite the selected A's only -- for rewrite_goals_tac*)
   685 fun goals_conv pred cv =
   686   let fun gconv i ct =
   687         let val (A,B) = dest_implies ct
   688         in imp_cong' (if pred i then cv A else reflexive A) (gconv (i+1) B) end
   689         handle TERM _ => reflexive ct
   690   in gconv 1 end
   691 
   692 (* Rewrite A in !!x1,...,xn. A *)
   693 fun forall_conv cv ct =
   694   let val p as (ct1, ct2) = Thm.dest_comb ct
   695   in (case pairself term_of p of
   696       (Const ("all", _), Abs (s, _, _)) =>
   697          let val (v, ct') = Thm.dest_abs (SOME "@") ct2;
   698          in Thm.combination (Thm.reflexive ct1)
   699            (Thm.abstract_rule s v (forall_conv cv ct'))
   700          end
   701     | _ => cv ct)
   702   end handle TERM _ => cv ct;
   703 
   704 (*Use a conversion to transform a theorem*)
   705 fun fconv_rule cv th = equal_elim (cv (cprop_of th)) th;
   706 
   707 (*** Some useful meta-theorems ***)
   708 
   709 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   710 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   711 val _ = store_thm "_" asm_rl;
   712 
   713 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   714 val cut_rl =
   715   store_standard_thm_open "cut_rl"
   716     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   717 
   718 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   719      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   720 val revcut_rl =
   721   let val V = read_prop "PROP V"
   722       and VW = read_prop "PROP V ==> PROP W";
   723   in
   724     store_standard_thm_open "revcut_rl"
   725       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   726   end;
   727 
   728 (*for deleting an unwanted assumption*)
   729 val thin_rl =
   730   let val V = read_prop "PROP V"
   731       and W = read_prop "PROP W";
   732   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   733 
   734 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   735 val triv_forall_equality =
   736   let val V  = read_prop "PROP V"
   737       and QV = read_prop "!!x::'a. PROP V"
   738       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   739   in
   740     store_standard_thm_open "triv_forall_equality"
   741       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   742         (implies_intr V  (forall_intr x (assume V))))
   743   end;
   744 
   745 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   746    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   747    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   748 *)
   749 val swap_prems_rl =
   750   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   751       val major = assume cmajor;
   752       val cminor1 = read_prop "PROP PhiA";
   753       val minor1 = assume cminor1;
   754       val cminor2 = read_prop "PROP PhiB";
   755       val minor2 = assume cminor2;
   756   in store_standard_thm_open "swap_prems_rl"
   757        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   758          (implies_elim (implies_elim major minor1) minor2))))
   759   end;
   760 
   761 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   762    ==> PROP ?phi == PROP ?psi
   763    Introduction rule for == as a meta-theorem.
   764 *)
   765 val equal_intr_rule =
   766   let val PQ = read_prop "PROP phi ==> PROP psi"
   767       and QP = read_prop "PROP psi ==> PROP phi"
   768   in
   769     store_standard_thm_open "equal_intr_rule"
   770       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   771   end;
   772 
   773 (* [| PROP ?phi == PROP ?psi; PROP ?phi |] ==> PROP ?psi *)
   774 val equal_elim_rule1 =
   775   let val eq = read_prop "PROP phi == PROP psi"
   776       and P = read_prop "PROP phi"
   777   in store_standard_thm_open "equal_elim_rule1"
   778     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   779   end;
   780 
   781 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   782 
   783 val remdups_rl =
   784   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   785   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   786 
   787 
   788 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   789   Rewrite rule for HHF normalization.*)
   790 
   791 val norm_hhf_eq =
   792   let
   793     val cert = Thm.cterm_of proto_sign;
   794     val aT = TFree ("'a", []);
   795     val all = Term.all aT;
   796     val x = Free ("x", aT);
   797     val phi = Free ("phi", propT);
   798     val psi = Free ("psi", aT --> propT);
   799 
   800     val cx = cert x;
   801     val cphi = cert phi;
   802     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   803     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   804   in
   805     Thm.equal_intr
   806       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   807         |> Thm.forall_elim cx
   808         |> Thm.implies_intr cphi
   809         |> Thm.forall_intr cx
   810         |> Thm.implies_intr lhs)
   811       (Thm.implies_elim
   812           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   813         |> Thm.forall_intr cx
   814         |> Thm.implies_intr cphi
   815         |> Thm.implies_intr rhs)
   816     |> store_standard_thm_open "norm_hhf_eq"
   817   end;
   818 
   819 fun is_norm_hhf tm =
   820   let
   821     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   822       | is_norm (t $ u) = is_norm t andalso is_norm u
   823       | is_norm (Abs (_, _, t)) = is_norm t
   824       | is_norm _ = true;
   825   in is_norm (Pattern.beta_eta_contract tm) end;
   826 
   827 fun norm_hhf sg t =
   828   if is_norm_hhf t then t
   829   else Pattern.rewrite_term (Sign.tsig_of sg) [Logic.dest_equals (prop_of norm_hhf_eq)] [] t;
   830 
   831 
   832 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   833 
   834 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   835 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   836 
   837 fun read_instantiate_sg' sg sinsts th =
   838     let val ts = types_sorts th;
   839         val used = add_used th [];
   840     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   841 
   842 fun read_instantiate_sg sg sinsts th =
   843   read_instantiate_sg' sg (map (apfst Syntax.indexname) sinsts) th;
   844 
   845 (*Instantiate theorem th, reading instantiations under theory of th*)
   846 fun read_instantiate sinsts th =
   847     read_instantiate_sg (Thm.sign_of_thm th) sinsts th;
   848 
   849 fun read_instantiate' sinsts th =
   850     read_instantiate_sg' (Thm.sign_of_thm th) sinsts th;
   851 
   852 
   853 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   854   Instantiates distinct Vars by terms, inferring type instantiations. *)
   855 local
   856   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   857     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   858         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   859         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   860         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   861         val (tye',maxi') = Type.unify (Sign.tsig_of sign') (tye, maxi) (T, U)
   862           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   863     in  (sign', tye', maxi')  end;
   864 in
   865 fun cterm_instantiate ctpairs0 th =
   866   let val (sign,tye,_) = foldr add_types (Thm.sign_of_thm th, Vartab.empty, 0) ctpairs0
   867       fun instT(ct,cu) = 
   868         let val inst = cterm_of sign o Envir.subst_TVars tye o term_of
   869         in (inst ct, inst cu) end
   870       fun ctyp2 (ixn, (S, T)) = (ctyp_of sign (TVar (ixn, S)), ctyp_of sign T)
   871   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   872   handle TERM _ =>
   873            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   874        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   875 end;
   876 
   877 
   878 (** Derived rules mainly for METAHYPS **)
   879 
   880 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   881 fun equal_abs_elim ca eqth =
   882   let val {sign=signa, t=a, ...} = rep_cterm ca
   883       and combth = combination eqth (reflexive ca)
   884       val {sign,prop,...} = rep_thm eqth
   885       val (abst,absu) = Logic.dest_equals prop
   886       val cterm = cterm_of (Sign.merge (sign,signa))
   887   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   888            (transitive combth (beta_conversion false (cterm (absu$a))))
   889   end
   890   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   891 
   892 (*Calling equal_abs_elim with multiple terms*)
   893 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) th (rev cts);
   894 
   895 
   896 (*** Goal (PROP A) <==> PROP A ***)
   897 
   898 local
   899   val cert = Thm.cterm_of proto_sign;
   900   val A = Free ("A", propT);
   901   val G = Logic.mk_goal A;
   902   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   903 in
   904   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   905       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   906   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   907       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   908 end;
   909 
   910 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   911 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   912 
   913 fun implies_intr_goals cprops thm =
   914   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   915   |> implies_intr_list (map mk_cgoal cprops);
   916 
   917 
   918 
   919 (** variations on instantiate **)
   920 
   921 (*shorthand for instantiating just one variable in the current theory*)
   922 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   923 
   924 
   925 (* collect vars in left-to-right order *)
   926 
   927 fun tvars_of_terms ts = rev (Library.foldl Term.add_tvars ([], ts));
   928 fun vars_of_terms ts = rev (Library.foldl Term.add_vars ([], ts));
   929 
   930 fun tvars_of thm = tvars_of_terms [prop_of thm];
   931 fun vars_of thm = vars_of_terms [prop_of thm];
   932 
   933 
   934 (* instantiate by left-to-right occurrence of variables *)
   935 
   936 fun instantiate' cTs cts thm =
   937   let
   938     fun err msg =
   939       raise TYPE ("instantiate': " ^ msg,
   940         List.mapPartial (Option.map Thm.typ_of) cTs,
   941         List.mapPartial (Option.map Thm.term_of) cts);
   942 
   943     fun inst_of (v, ct) =
   944       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   945         handle TYPE (msg, _, _) => err msg;
   946 
   947     fun tyinst_of (v, cT) =
   948       (Thm.ctyp_of (#sign (Thm.rep_ctyp cT)) (TVar v), cT)
   949         handle TYPE (msg, _, _) => err msg;
   950 
   951     fun zip_vars _ [] = []
   952       | zip_vars (_ :: vs) (NONE :: opt_ts) = zip_vars vs opt_ts
   953       | zip_vars (v :: vs) (SOME t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   954       | zip_vars [] _ = err "more instantiations than variables in thm";
   955 
   956     (*instantiate types first!*)
   957     val thm' =
   958       if forall is_none cTs then thm
   959       else Thm.instantiate (map tyinst_of (zip_vars (tvars_of thm) cTs), []) thm;
   960     in
   961       if forall is_none cts then thm'
   962       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   963     end;
   964 
   965 
   966 
   967 (** renaming of bound variables **)
   968 
   969 (* replace bound variables x_i in thm by y_i *)
   970 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   971 
   972 fun rename_bvars [] thm = thm
   973   | rename_bvars vs thm =
   974     let
   975       val {sign, prop, ...} = rep_thm thm;
   976       fun ren (Abs (x, T, t)) = Abs (getOpt (assoc (vs, x), x), T, ren t)
   977         | ren (t $ u) = ren t $ ren u
   978         | ren t = t;
   979     in equal_elim (reflexive (cterm_of sign (ren prop))) thm end;
   980 
   981 
   982 (* renaming in left-to-right order *)
   983 
   984 fun rename_bvars' xs thm =
   985   let
   986     val {sign, prop, ...} = rep_thm thm;
   987     fun rename [] t = ([], t)
   988       | rename (x' :: xs) (Abs (x, T, t)) =
   989           let val (xs', t') = rename xs t
   990           in (xs', Abs (getOpt (x',x), T, t')) end
   991       | rename xs (t $ u) =
   992           let
   993             val (xs', t') = rename xs t;
   994             val (xs'', u') = rename xs' u
   995           in (xs'', t' $ u') end
   996       | rename xs t = (xs, t);
   997   in case rename xs prop of
   998       ([], prop') => equal_elim (reflexive (cterm_of sign prop')) thm
   999     | _ => error "More names than abstractions in theorem"
  1000   end;
  1001 
  1002 
  1003 
  1004 (* unvarify(T) *)
  1005 
  1006 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
  1007 
  1008 fun unvarifyT thm =
  1009   let
  1010     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
  1011     val tfrees = map (fn ((x, _), S) => SOME (cT (TFree (x, S)))) (tvars_of thm);
  1012   in instantiate' tfrees [] thm end;
  1013 
  1014 fun unvarify raw_thm =
  1015   let
  1016     val thm = unvarifyT raw_thm;
  1017     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
  1018     val frees = map (fn ((x, _), T) => SOME (ct (Free (x, T)))) (vars_of thm);
  1019   in instantiate' [] frees thm end;
  1020 
  1021 
  1022 (* tvars_intr_list *)
  1023 
  1024 fun tfrees_of thm =
  1025   let val {hyps, prop, ...} = Thm.rep_thm thm
  1026   in foldr Term.add_term_tfrees [] (prop :: hyps) end;
  1027 
  1028 fun tvars_intr_list tfrees thm =
  1029   apsnd (map (fn ((s, S), ixn) => (s, (ixn, S)))) (Thm.varifyT'
  1030     (gen_rems (op = o apfst fst) (tfrees_of thm, tfrees)) thm);
  1031 
  1032 
  1033 (* increment var indexes *)
  1034 
  1035 fun incr_indexes_wrt is cTs cts thms =
  1036   let
  1037     val maxidx =
  1038       Library.foldl Int.max (~1, is @
  1039         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
  1040         map (#maxidx o Thm.rep_cterm) cts @
  1041         map (#maxidx o Thm.rep_thm) thms);
  1042   in Thm.incr_indexes (maxidx + 1) end;
  1043 
  1044 
  1045 (* freeze_all *)
  1046 
  1047 (*freeze all (T)Vars; assumes thm in standard form*)
  1048 
  1049 fun freeze_all_TVars thm =
  1050   (case tvars_of thm of
  1051     [] => thm
  1052   | tvars =>
  1053       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
  1054       in instantiate' (map (fn ((x, _), S) => SOME (cert (TFree (x, S)))) tvars) [] thm end);
  1055 
  1056 fun freeze_all_Vars thm =
  1057   (case vars_of thm of
  1058     [] => thm
  1059   | vars =>
  1060       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
  1061       in instantiate' [] (map (fn ((x, _), T) => SOME (cert (Free (x, T)))) vars) thm end);
  1062 
  1063 val freeze_all = freeze_all_Vars o freeze_all_TVars;
  1064 
  1065 
  1066 (* mk_triv_goal *)
  1067 
  1068 (*make an initial proof state, "PROP A ==> (PROP A)" *)
  1069 fun mk_triv_goal ct = instantiate' [] [SOME ct] triv_goal;
  1070 
  1071 
  1072 
  1073 (** meta-level conjunction **)
  1074 
  1075 local
  1076   val A = read_prop "PROP A";
  1077   val B = read_prop "PROP B";
  1078   val C = read_prop "PROP C";
  1079   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
  1080 
  1081   val proj1 =
  1082     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
  1083     |> forall_elim_vars 0;
  1084 
  1085   val proj2 =
  1086     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
  1087     |> forall_elim_vars 0;
  1088 
  1089   val conj_intr_rule =
  1090     forall_intr_list [A, B] (implies_intr_list [A, B]
  1091       (Thm.forall_intr C (Thm.implies_intr ABC
  1092         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
  1093     |> forall_elim_vars 0;
  1094 
  1095   val incr = incr_indexes_wrt [] [] [];
  1096 in
  1097 
  1098 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
  1099 
  1100 fun conj_intr_list [] = asm_rl
  1101   | conj_intr_list ths = foldr1 (uncurry conj_intr) ths;
  1102 
  1103 fun conj_elim th =
  1104   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
  1105   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
  1106 
  1107 fun conj_elim_list th =
  1108   let val (th1, th2) = conj_elim th
  1109   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
  1110 
  1111 fun conj_elim_precise 0 _ = []
  1112   | conj_elim_precise 1 th = [th]
  1113   | conj_elim_precise n th =
  1114       let val (th1, th2) = conj_elim th
  1115       in th1 :: conj_elim_precise (n - 1) th2 end;
  1116 
  1117 val conj_intr_thm = store_standard_thm_open "conjunctionI"
  1118   (implies_intr_list [A, B] (conj_intr (Thm.assume A) (Thm.assume B)));
  1119 
  1120 end;
  1121 
  1122 end;
  1123 
  1124 structure BasicDrule: BASIC_DRULE = Drule;
  1125 open BasicDrule;