src/Pure/library.ML
author berghofe
Thu Apr 21 19:12:03 2005 +0200 (2005-04-21)
changeset 15797 a63605582573
parent 15760 1ca99038c847
child 15965 f422f8283491
permissions -rw-r--r--
- Eliminated nodup_vars check.
- Unification and matching functions now check types of term variables / sorts
of type variables when applying a substitution.
- Thm.instantiate now takes (ctyp * ctyp) list instead of (indexname * ctyp) list
as argument, to allow for proper instantiation of theorems containing
type variables with same name but different sorts.
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Munich
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature BASIC_LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    26   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    27   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    28   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    29   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33 
    34   (*stamps*)
    35   type stamp
    36   val stamp: unit -> stamp
    37 
    38   (*options*)
    39   val is_none: 'a option -> bool
    40 
    41   (*old options -- invalidated*)
    42   datatype invalid = None of invalid
    43   exception OPTION of invalid
    44 
    45   exception ERROR
    46   val try: ('a -> 'b) -> 'a -> 'b option
    47   val can: ('a -> 'b) -> 'a -> bool
    48   datatype 'a result = Result of 'a | Exn of exn
    49   val capture: ('a -> 'b) -> 'a -> 'b result
    50   val release: 'a result -> 'a
    51   val get_result: 'a result -> 'a option
    52   val get_exn: 'a result -> exn option
    53 
    54   (*pairs*)
    55   val pair: 'a -> 'b -> 'a * 'b
    56   val rpair: 'a -> 'b -> 'b * 'a
    57   val fst: 'a * 'b -> 'a
    58   val snd: 'a * 'b -> 'b
    59   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    60   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    61   val swap: 'a * 'b -> 'b * 'a
    62   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    63   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    64   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    65 
    66   (*booleans*)
    67   val equal: ''a -> ''a -> bool
    68   val not_equal: ''a -> ''a -> bool
    69   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    71   val exists: ('a -> bool) -> 'a list -> bool
    72   val forall: ('a -> bool) -> 'a list -> bool
    73   val set: bool ref -> bool
    74   val reset: bool ref -> bool
    75   val toggle: bool ref -> bool
    76   val change: 'a ref -> ('a -> 'a) -> unit
    77   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    78   val conditional: bool -> (unit -> unit) -> unit
    79 
    80   (*lists*)
    81   exception UnequalLengths
    82   val cons: 'a -> 'a list -> 'a list
    83   val single: 'a -> 'a list
    84   val append: 'a list -> 'a list -> 'a list
    85   val apply: ('a -> 'a) list -> 'a -> 'a
    86   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    87   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    88   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    89   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    90   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val unflat: 'a list list -> 'b list -> 'b list list
    92   val splitAt: int * 'a list -> 'a list * 'a list
    93   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    94   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    95   val split_last: 'a list -> 'a list * 'a
    96   val nth_update: 'a -> int * 'a list -> 'a list
    97   val find_index: ('a -> bool) -> 'a list -> int
    98   val find_index_eq: ''a -> ''a list -> int
    99   val find_first: ('a -> bool) -> 'a list -> 'a option
   100   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   101   val separate: 'a -> 'a list -> 'a list
   102   val replicate: int -> 'a -> 'a list
   103   val multiply: 'a list * 'a list list -> 'a list list
   104   val product: 'a list -> 'b list -> ('a * 'b) list
   105   val filter_out: ('a -> bool) -> 'a list -> 'a list
   106   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   107   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   108   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   109   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val prefix: ''a list * ''a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val gcd: int * int -> int
   121   val lcm: int * int -> int
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val downto0: int list * int -> bool
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131     (* CB: note alternative Syntax.string_of_vname has nicer syntax *)
   132   val read_radixint: int * string list -> int * string list
   133   val read_int: string list -> int * string list
   134   val oct_char: string -> string
   135 
   136   (*rational numbers*)
   137   type rat
   138   exception RAT of string
   139   val rep_rat: rat -> int * int
   140   val ratadd: rat * rat -> rat
   141   val ratmul: rat * rat -> rat
   142   val ratinv: rat -> rat
   143   val int_ratdiv: int * int -> rat
   144   val ratneg: rat -> rat
   145   val rat_of_int: int -> rat
   146 
   147   (*strings*)
   148   val nth_elem_string: int * string -> string
   149   val foldl_string: ('a * string -> 'a) -> 'a * string -> 'a
   150   val exists_string: (string -> bool) -> string -> bool
   151   val enclose: string -> string -> string -> string
   152   val unenclose: string -> string
   153   val quote: string -> string
   154   val space_implode: string -> string list -> string
   155   val commas: string list -> string
   156   val commas_quote: string list -> string
   157   val cat_lines: string list -> string
   158   val space_explode: string -> string -> string list
   159   val split_lines: string -> string list
   160   val prefix_lines: string -> string -> string
   161   val untabify: string list -> string list
   162   val suffix: string -> string -> string
   163   val unsuffix: string -> string -> string
   164   val unprefix: string -> string -> string
   165   val replicate_string: int -> string -> string
   166   val translate_string: (string -> string) -> string -> string
   167 
   168   (*lists as sets*)
   169   val mem: ''a * ''a list -> bool
   170   val mem_int: int * int list -> bool
   171   val mem_string: string * string list -> bool
   172   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   173   val ins: ''a * ''a list -> ''a list
   174   val ins_int: int * int list -> int list
   175   val ins_string: string * string list -> string list
   176   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   177   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   178   val remove: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   179   val union: ''a list * ''a list -> ''a list
   180   val union_int: int list * int list -> int list
   181   val union_string: string list * string list -> string list
   182   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   183   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   184   val inter: ''a list * ''a list -> ''a list
   185   val inter_int: int list * int list -> int list
   186   val inter_string: string list * string list -> string list
   187   val subset: ''a list * ''a list -> bool
   188   val subset_int: int list * int list -> bool
   189   val subset_string: string list * string list -> bool
   190   val eq_set: ''a list * ''a list -> bool
   191   val eq_set_string: string list * string list -> bool
   192   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   193   val \ : ''a list * ''a -> ''a list
   194   val \\ : ''a list * ''a list -> ''a list
   195   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   196   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   197   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   198   val distinct: ''a list -> ''a list
   199   val findrep: ''a list -> ''a list
   200   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   201   val duplicates: ''a list -> ''a list
   202 
   203   (*association lists*)
   204   val assoc: (''a * 'b) list * ''a -> 'b option
   205   val assoc_int: (int * 'a) list * int -> 'a option
   206   val assoc_string: (string * 'a) list * string -> 'a option
   207   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   208   val assocs: (''a * 'b list) list -> ''a -> 'b list
   209   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   210   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   211   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   212   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   213 
   214   (*lists as tables*)
   215   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   216   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   217   val merge_lists: ''a list -> ''a list -> ''a list
   218   val merge_lists': ''a list -> ''a list -> ''a list
   219   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   220   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   221 
   222   (*balanced trees*)
   223   exception Balance
   224   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   225   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   226   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   227 
   228   (*orders*)
   229   val rev_order: order -> order
   230   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   231   val int_ord: int * int -> order
   232   val string_ord: string * string -> order
   233   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   234   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   235   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   236   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   237   val sort_strings: string list -> string list
   238   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   239   val unique_strings: string list -> string list
   240 
   241   (*random numbers*)
   242   exception RANDOM
   243   val random: unit -> real
   244   val random_range: int -> int -> int
   245   val one_of: 'a list -> 'a
   246   val frequency: (int * 'a) list -> 'a
   247 
   248   (*current directory*)
   249   val cd: string -> unit
   250   val pwd: unit -> string
   251 
   252   (*misc*)
   253   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   254   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   255   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   256   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   257   val gensym: string -> string
   258   val scanwords: (string -> bool) -> string list -> string list
   259 end;
   260 
   261 signature LIBRARY =
   262 sig
   263   include BASIC_LIBRARY
   264 
   265   val the: 'a option -> 'a
   266   val if_none: 'a option -> 'a -> 'a
   267   val is_some: 'a option -> bool
   268   val apsome: ('a -> 'b) -> 'a option -> 'b option
   269 
   270   val rev_append: 'a list -> 'a list -> 'a list
   271   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   272   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   273   val take: int * 'a list -> 'a list
   274   val drop: int * 'a list -> 'a list
   275   val nth_elem: int * 'a list -> 'a
   276   val last_elem: 'a list -> 'a
   277   val flat: 'a list list -> 'a list
   278   val seq: ('a -> unit) -> 'a list -> unit
   279   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   280   val filter: ('a -> bool) -> 'a list -> 'a list
   281   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   282 end;
   283 
   284 structure Library: LIBRARY =
   285 struct
   286 
   287 
   288 (** functions **)
   289 
   290 (*handy combinators*)
   291 fun curry f x y = f (x, y);
   292 fun uncurry f (x, y) = f x y;
   293 fun I x = x;
   294 fun K x y = x;
   295 
   296 (*reverse apply*)
   297 fun (x |> f) = f x;
   298 fun ((x, y) |>> f) = (f x, y);
   299 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   300 
   301 (*application of (infix) operator to its left or right argument*)
   302 fun apl (x, f) y = f (x, y);
   303 fun apr (f, y) x = f (x, y);
   304 
   305 (*function exponentiation: f(...(f x)...) with n applications of f*)
   306 fun funpow n f x =
   307   let fun rep (0, x) = x
   308         | rep (n, x) = rep (n - 1, f x)
   309   in rep (n, x) end;
   310 
   311 (*concatenation: 2 and 3 args*)
   312 fun (f oo g) x y = f (g x y);
   313 fun (f ooo g) x y z = f (g x y z);
   314 fun (f oooo g) x y z w = f (g x y z w);
   315 
   316 
   317 
   318 (** stamps **)
   319 
   320 type stamp = unit ref;
   321 val stamp: unit -> stamp = ref;
   322 
   323 
   324 
   325 (** options **)
   326 
   327 val the = valOf;
   328 fun if_none opt a = getOpt (opt, a);
   329 val is_some = isSome;
   330 fun is_none opt = not (isSome opt);
   331 val apsome = Option.map;
   332 
   333 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   334 datatype invalid = None of invalid;
   335 exception OPTION of invalid;
   336 
   337 
   338 (* exception handling *)
   339 
   340 exception ERROR;
   341 
   342 fun try f x = SOME (f x)
   343   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   344 
   345 fun can f x = is_some (try f x);
   346 
   347 
   348 datatype 'a result =
   349   Result of 'a |
   350   Exn of exn;
   351 
   352 fun capture f x = Result (f x) handle e => Exn e;
   353 
   354 fun release (Result y) = y
   355   | release (Exn e) = raise e;
   356 
   357 fun get_result (Result x) = SOME x
   358   | get_result _ = NONE;
   359 
   360 fun get_exn (Exn exn) = SOME exn
   361   | get_exn _ = NONE;
   362 
   363 
   364 
   365 (** pairs **)
   366 
   367 fun pair x y = (x, y);
   368 fun rpair x y = (y, x);
   369 
   370 fun fst (x, y) = x;
   371 fun snd (x, y) = y;
   372 
   373 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   374 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   375 
   376 fun swap (x, y) = (y, x);
   377 
   378 (*apply function to components*)
   379 fun apfst f (x, y) = (f x, y);
   380 fun apsnd f (x, y) = (x, f y);
   381 fun pairself f (x, y) = (f x, f y);
   382 
   383 
   384 
   385 (** booleans **)
   386 
   387 (* equality *)
   388 
   389 fun equal x y = x = y;
   390 fun not_equal x y = x <> y;
   391 
   392 
   393 (* operators for combining predicates *)
   394 
   395 fun (p orf q) = fn x => p x orelse q x;
   396 fun (p andf q) = fn x => p x andalso q x;
   397 
   398 
   399 (* predicates on lists *)
   400 
   401 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   402 fun exists (pred: 'a -> bool) : 'a list -> bool =
   403   let fun boolf [] = false
   404         | boolf (x :: xs) = pred x orelse boolf xs
   405   in boolf end;
   406 
   407 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   408 fun forall (pred: 'a -> bool) : 'a list -> bool =
   409   let fun boolf [] = true
   410         | boolf (x :: xs) = pred x andalso boolf xs
   411   in boolf end;
   412 
   413 
   414 (* flags *)
   415 
   416 fun set flag = (flag := true; true);
   417 fun reset flag = (flag := false; false);
   418 fun toggle flag = (flag := not (! flag); ! flag);
   419 
   420 fun change r f = r := f (! r);
   421 
   422 (*temporarily set flag, handling exceptions*)
   423 fun setmp flag value f x =
   424   let
   425     val orig_value = ! flag;
   426     fun return y = (flag := orig_value; y);
   427   in
   428     flag := value;
   429     return (f x handle exn => (return (); raise exn))
   430   end;
   431 
   432 
   433 (* conditional execution *)
   434 
   435 fun conditional b f = if b then f () else ();
   436 
   437 
   438 
   439 (** lists **)
   440 
   441 exception UnequalLengths;
   442 
   443 fun cons x xs = x :: xs;
   444 fun single x = [x];
   445 
   446 fun append xs ys = xs @ ys;
   447 
   448 fun rev_append xs ys = List.revAppend (xs, ys);
   449 
   450 fun apply [] x = x
   451   | apply (f :: fs) x = apply fs (f x);
   452 
   453 
   454 (* fold *)
   455 
   456 fun fold _ [] y = y
   457   | fold f (x :: xs) y = fold f xs (f x y);
   458 
   459 fun fold_rev _ [] y = y
   460   | fold_rev f (x :: xs) y = f x (fold_rev f xs y);
   461 
   462 fun foldl_map _ (x, []) = (x, [])
   463   | foldl_map f (x, y :: ys) =
   464       let
   465         val (x', y') = f (x, y);
   466         val (x'', ys') = foldl_map f (x', ys);
   467       in (x'', y' :: ys') end;
   468 
   469 (*the following versions of fold are designed to fit nicely with infixes*)
   470 
   471 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   472     for operators that associate to the left (TAIL RECURSIVE)*)
   473 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   474   let fun itl (e, [])  = e
   475         | itl (e, a::l) = itl (f(e, a), l)
   476   in  itl end;
   477 
   478 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   479     for operators that associate to the right (not tail recursive)*)
   480 fun foldr f (l, e) =
   481   let fun itr [] = e
   482         | itr (a::l) = f(a, itr l)
   483   in  itr l  end;
   484 
   485 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   486     for n > 0, operators that associate to the right (not tail recursive)*)
   487 fun foldr1 f l =
   488   let fun itr [x] = x
   489         | itr (x::l) = f(x, itr l)
   490   in  itr l  end;
   491 
   492 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   493 
   494 
   495 (* basic list functions *)
   496 
   497 (*take the first n elements from a list*)
   498 fun take (n, []) = []
   499   | take (n, x :: xs) =
   500       if n > 0 then x :: take (n - 1, xs) else [];
   501 
   502 (*drop the first n elements from a list*)
   503 fun drop (n, []) = []
   504   | drop (n, x :: xs) =
   505       if n > 0 then drop (n - 1, xs) else x :: xs;
   506 
   507 fun splitAt(n,[]) = ([],[])
   508   | splitAt(n,xs as x::ys) =
   509       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   510       else ([],xs)
   511 
   512 fun dropwhile P [] = []
   513   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   514 
   515 (*return nth element of a list, where 0 designates the first element;
   516   raise EXCEPTION if list too short*)
   517 fun nth_elem (i,xs) = List.nth(xs,i);
   518 
   519 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   520   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   521   | map_nth_elem _ _ [] = raise Subscript;
   522 
   523 (*last element of a list*)
   524 val last_elem = List.last;
   525 
   526 (*rear decomposition*)
   527 fun split_last [] = raise Empty
   528   | split_last [x] = ([], x)
   529   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   530 
   531 (*update nth element*)
   532 fun nth_update x n_xs =
   533     (case splitAt n_xs of
   534       (_,[]) => raise Subscript
   535     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   536 
   537 (*find the position of an element in a list*)
   538 fun find_index pred =
   539   let fun find _ [] = ~1
   540         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   541   in find 0 end;
   542 
   543 fun find_index_eq x = find_index (equal x);
   544 
   545 (*find first element satisfying predicate*)
   546 fun find_first _ [] = NONE
   547   | find_first pred (x :: xs) =
   548       if pred x then SOME x else find_first pred xs;
   549 
   550 (*get first element by lookup function*)
   551 fun get_first _ [] = NONE
   552   | get_first f (x :: xs) =
   553       (case f x of
   554         NONE => get_first f xs
   555       | some => some);
   556 
   557 (*flatten a list of lists to a list*)
   558 val flat = List.concat;
   559 
   560 fun unflat (xs :: xss) ys =
   561       let val (ps,qs) = splitAt(length xs,ys)
   562       in ps :: unflat xss qs end
   563   | unflat [] [] = []
   564   | unflat _ _ = raise UnequalLengths;
   565 
   566 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   567   (proc x1; ...; proc xn) for side effects*)
   568 val seq = List.app;
   569 
   570 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   571 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   572   | separate _ xs = xs;
   573 
   574 (*make the list [x, x, ..., x] of length n*)
   575 fun replicate n (x: 'a) : 'a list =
   576   let fun rep (0, xs) = xs
   577         | rep (n, xs) = rep (n - 1, x :: xs)
   578   in
   579     if n < 0 then raise Subscript
   580     else rep (n, [])
   581   end;
   582 
   583 fun translate_string f = String.translate (f o String.str);
   584 
   585 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   586 fun multiply ([], _) = []
   587   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   588 
   589 (*direct product*)
   590 fun product _ [] = []
   591   | product [] _ = []
   592   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   593 
   594 
   595 (* filter *)
   596 
   597 (*copy the list preserving elements that satisfy the predicate*)
   598 val filter = List.filter;
   599 fun filter_out f = filter (not o f);
   600 val mapfilter = List.mapPartial;
   601 
   602 
   603 (* lists of pairs *)
   604 
   605 exception UnequalLengths;
   606 
   607 fun map2 _ ([], []) = []
   608   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   609   | map2 _ _ = raise UnequalLengths;
   610 
   611 fun exists2 _ ([], []) = false
   612   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   613   | exists2 _ _ = raise UnequalLengths;
   614 
   615 fun forall2 _ ([], []) = true
   616   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   617   | forall2 _ _ = raise UnequalLengths;
   618 
   619 fun seq2 _ ([], []) = ()
   620   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   621   | seq2 _ _ = raise UnequalLengths;
   622 
   623 (*combine two lists forming a list of pairs:
   624   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   625 fun [] ~~ [] = []
   626   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   627   | _ ~~ _ = raise UnequalLengths;
   628 
   629 (*inverse of ~~; the old 'split':
   630   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   631 val split_list = ListPair.unzip;
   632 
   633 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   634 
   635 
   636 (* prefixes, suffixes *)
   637 
   638 fun [] prefix _ = true
   639   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   640   | _ prefix _ = false;
   641 
   642 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   643    where xi is the first element that does not satisfy the predicate*)
   644 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   645   let fun take (rxs, []) = (rev rxs, [])
   646         | take (rxs, x :: xs) =
   647             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   648   in  take([], xs)  end;
   649 
   650 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   651    where xi is the last element that does not satisfy the predicate*)
   652 fun take_suffix _ [] = ([], [])
   653   | take_suffix pred (x :: xs) =
   654       (case take_suffix pred xs of
   655         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   656       | (prfx, sffx) => (x :: prfx, sffx));
   657 
   658 fun prefixes1 [] = []
   659   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   660 
   661 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   662 
   663 
   664 
   665 (** integers **)
   666 
   667 fun gcd(x,y) =
   668   let fun gxd x y =
   669     if y = 0 then x else gxd y (x mod y)
   670   in if x < y then gxd y x else gxd x y end;
   671 
   672 fun lcm(x,y) = (x * y) div gcd(x,y);
   673 
   674 fun inc i = (i := ! i + 1; ! i);
   675 fun dec i = (i := ! i - 1; ! i);
   676 
   677 
   678 (* lists of integers *)
   679 
   680 (*make the list [from, from + 1, ..., to]*)
   681 fun (from upto to) =
   682   if from > to then [] else from :: ((from + 1) upto to);
   683 
   684 (*make the list [from, from - 1, ..., to]*)
   685 fun (from downto to) =
   686   if from < to then [] else from :: ((from - 1) downto to);
   687 
   688 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   689 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   690   | downto0 ([], n) = n = ~1;
   691 
   692 
   693 (* convert integers to strings *)
   694 
   695 (*expand the number in the given base;
   696   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   697 fun radixpand (base, num) : int list =
   698   let
   699     fun radix (n, tail) =
   700       if n < base then n :: tail
   701       else radix (n div base, (n mod base) :: tail)
   702   in radix (num, []) end;
   703 
   704 (*expands a number into a string of characters starting from "zerochar";
   705   example: radixstring (2, "0", 8) gives "1000"*)
   706 fun radixstring (base, zerochar, num) =
   707   let val offset = ord zerochar;
   708       fun chrof n = chr (offset + n)
   709   in implode (map chrof (radixpand (base, num))) end;
   710 
   711 
   712 val string_of_int = Int.toString;
   713 
   714 fun string_of_indexname (a,0) = a
   715   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   716 
   717 
   718 (* read integers *)
   719 
   720 fun read_radixint (radix: int, cs) : int * string list =
   721   let val zero = ord"0"
   722       val limit = zero+radix
   723       fun scan (num,[]) = (num,[])
   724         | scan (num, c::cs) =
   725               if  zero <= ord c  andalso  ord c < limit
   726               then scan(radix*num + ord c - zero, cs)
   727               else (num, c::cs)
   728   in  scan(0,cs)  end;
   729 
   730 fun read_int cs = read_radixint (10, cs);
   731 
   732 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   733 
   734 
   735 
   736 (** strings **)
   737 
   738 (*functions tuned for strings, avoiding explode*)
   739 
   740 fun nth_elem_string (i, str) =
   741   (case try String.substring (str, i, 1) of
   742     SOME s => s
   743   | NONE => raise Subscript);
   744 
   745 fun foldl_string f (x0, str) =
   746   let
   747     val n = size str;
   748     fun fold (x, i) =
   749       if i < n then fold (f (x, String.substring (str, i, 1)), i + 1) else x;
   750   in fold (x0, 0) end;
   751 
   752 fun exists_string pred str =
   753   let
   754     val n = size str;
   755     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   756   in ex 0 end;
   757 
   758 (*enclose in brackets*)
   759 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   760 fun unenclose str = String.substring (str, 1, size str - 2);
   761 
   762 (*simple quoting (does not escape special chars)*)
   763 val quote = enclose "\"" "\"";
   764 
   765 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   766 fun space_implode a bs = implode (separate a bs);
   767 
   768 val commas = space_implode ", ";
   769 val commas_quote = commas o map quote;
   770 
   771 (*concatenate messages, one per line, into a string*)
   772 val cat_lines = space_implode "\n";
   773 
   774 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   775 fun space_explode _ "" = []
   776   | space_explode sep str =
   777       let
   778         fun expl chs =
   779           (case take_prefix (not_equal sep) chs of
   780             (cs, []) => [implode cs]
   781           | (cs, _ :: cs') => implode cs :: expl cs');
   782       in expl (explode str) end;
   783 
   784 val split_lines = space_explode "\n";
   785 
   786 fun prefix_lines "" txt = txt
   787   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   788 
   789 (*untabify*)
   790 fun untabify chs =
   791   let
   792     val tab_width = 8;
   793 
   794     fun untab (_, "\n") = (0, ["\n"])
   795       | untab (pos, "\t") =
   796           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   797       | untab (pos, c) = (pos + 1, [c]);
   798   in
   799     if not (exists (equal "\t") chs) then chs
   800     else flat (#2 (foldl_map untab (0, chs)))
   801   end;
   802 
   803 (*append suffix*)
   804 fun suffix sfx s = s ^ sfx;
   805 
   806 (*remove suffix*)
   807 fun unsuffix sfx s =
   808   let
   809     val cs = explode s;
   810     val prfx_len = size s - size sfx;
   811   in
   812     if prfx_len >= 0 andalso implode (drop (prfx_len, cs)) = sfx then
   813       implode (take (prfx_len, cs))
   814     else raise Fail "unsuffix"
   815   end;
   816 
   817 (*remove prefix*)
   818 fun unprefix prfx s =
   819   let val (prfx', sfx) = splitAt (size prfx, explode s)
   820   in
   821     if implode prfx' = prfx then implode sfx
   822     else raise Fail "unprefix"
   823   end;
   824 
   825 fun replicate_string 0 _ = ""
   826   | replicate_string 1 a = a
   827   | replicate_string k a =
   828       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   829       else replicate_string (k div 2) (a ^ a) ^ a;
   830 
   831 
   832 
   833 (** lists as sets **)
   834 
   835 (*membership in a list*)
   836 fun x mem [] = false
   837   | x mem (y :: ys) = x = y orelse x mem ys;
   838 
   839 (*membership in a list, optimized version for ints*)
   840 fun (x:int) mem_int [] = false
   841   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   842 
   843 (*membership in a list, optimized version for strings*)
   844 fun (x:string) mem_string [] = false
   845   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   846 
   847 (*generalized membership test*)
   848 fun gen_mem eq (x, []) = false
   849   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   850 
   851 (*insert and remove*)
   852 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   853 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   854 
   855 (*insertion into list if not already there*)
   856 fun (x ins xs) = if x mem xs then xs else x :: xs;
   857 
   858 (*insertion into list, optimized version for ints*)
   859 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   860 
   861 (*insertion into list, optimized version for strings*)
   862 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   863 
   864 (*generalized insertion*)
   865 fun gen_ins eq (x, xs) = insert eq x xs;
   866 
   867 (*union of sets represented as lists: no repetitions*)
   868 fun xs union [] = xs
   869   | [] union ys = ys
   870   | (x :: xs) union ys = xs union (x ins ys);
   871 
   872 (*union of sets, optimized version for ints*)
   873 fun (xs:int list) union_int [] = xs
   874   | [] union_int ys = ys
   875   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   876 
   877 (*union of sets, optimized version for strings*)
   878 fun (xs:string list) union_string [] = xs
   879   | [] union_string ys = ys
   880   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   881 
   882 (*generalized union*)
   883 fun gen_union eq (xs, []) = xs
   884   | gen_union eq ([], ys) = ys
   885   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   886 
   887 
   888 (*intersection*)
   889 fun [] inter ys = []
   890   | (x :: xs) inter ys =
   891       if x mem ys then x :: (xs inter ys) else xs inter ys;
   892 
   893 (*intersection, optimized version for ints*)
   894 fun ([]:int list) inter_int ys = []
   895   | (x :: xs) inter_int ys =
   896       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   897 
   898 (*intersection, optimized version for strings *)
   899 fun ([]:string list) inter_string ys = []
   900   | (x :: xs) inter_string ys =
   901       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   902 
   903 (*generalized intersection*)
   904 fun gen_inter eq ([], ys) = []
   905   | gen_inter eq (x::xs, ys) =
   906       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   907                            else      gen_inter eq (xs, ys);
   908 
   909 
   910 (*subset*)
   911 fun [] subset ys = true
   912   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   913 
   914 (*subset, optimized version for ints*)
   915 fun ([]:int list) subset_int ys = true
   916   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   917 
   918 (*subset, optimized version for strings*)
   919 fun ([]:string list) subset_string ys = true
   920   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   921 
   922 (*set equality*)
   923 fun eq_set (xs, ys) =
   924   xs = ys orelse (xs subset ys andalso ys subset xs);
   925 
   926 (*set equality for strings*)
   927 fun eq_set_string ((xs:string list), ys) =
   928   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   929 
   930 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   931 
   932 
   933 (*removing an element from a list WITHOUT duplicates*)
   934 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   935   | [] \ x = [];
   936 
   937 fun ys \\ xs = foldl (op \) (ys,xs);
   938 
   939 (*removing an element from a list -- possibly WITH duplicates*)
   940 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   941 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   942 
   943 (*makes a list of the distinct members of the input; preserves order, takes
   944   first of equal elements*)
   945 fun gen_distinct eq lst =
   946   let
   947     val memb = gen_mem eq;
   948 
   949     fun dist (rev_seen, []) = rev rev_seen
   950       | dist (rev_seen, x :: xs) =
   951           if memb (x, rev_seen) then dist (rev_seen, xs)
   952           else dist (x :: rev_seen, xs);
   953   in
   954     dist ([], lst)
   955   end;
   956 
   957 fun distinct l = gen_distinct (op =) l;
   958 
   959 
   960 (*returns the tail beginning with the first repeated element, or []*)
   961 fun findrep [] = []
   962   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   963 
   964 
   965 (*returns a list containing all repeated elements exactly once; preserves
   966   order, takes first of equal elements*)
   967 fun gen_duplicates eq lst =
   968   let
   969     val memb = gen_mem eq;
   970 
   971     fun dups (rev_dups, []) = rev rev_dups
   972       | dups (rev_dups, x :: xs) =
   973           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   974             dups (rev_dups, xs)
   975           else dups (x :: rev_dups, xs);
   976   in
   977     dups ([], lst)
   978   end;
   979 
   980 fun duplicates l = gen_duplicates (op =) l;
   981 
   982 
   983 
   984 (** association lists **)
   985 
   986 (*association list lookup*)
   987 fun assoc ([], key) = NONE
   988   | assoc ((keyi, xi) :: pairs, key) =
   989       if key = keyi then SOME xi else assoc (pairs, key);
   990 
   991 (*association list lookup, optimized version for ints*)
   992 fun assoc_int ([], (key:int)) = NONE
   993   | assoc_int ((keyi, xi) :: pairs, key) =
   994       if key = keyi then SOME xi else assoc_int (pairs, key);
   995 
   996 (*association list lookup, optimized version for strings*)
   997 fun assoc_string ([], (key:string)) = NONE
   998   | assoc_string ((keyi, xi) :: pairs, key) =
   999       if key = keyi then SOME xi else assoc_string (pairs, key);
  1000 
  1001 (*association list lookup, optimized version for string*ints*)
  1002 fun assoc_string_int ([], (key:string*int)) = NONE
  1003   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1004       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1005 
  1006 fun assocs ps x =
  1007   (case assoc (ps, x) of
  1008     NONE => []
  1009   | SOME ys => ys);
  1010 
  1011 (*two-fold association list lookup*)
  1012 fun assoc2 (aal, (key1, key2)) =
  1013   (case assoc (aal, key1) of
  1014     SOME al => assoc (al, key2)
  1015   | NONE => NONE);
  1016 
  1017 (*generalized association list lookup*)
  1018 fun gen_assoc eq ([], key) = NONE
  1019   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1020       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1021 
  1022 (*association list update*)
  1023 fun overwrite (al, p as (key, _)) =
  1024   let fun over ((q as (keyi, _)) :: pairs) =
  1025             if keyi = key then p :: pairs else q :: (over pairs)
  1026         | over [] = [p]
  1027   in over al end;
  1028 
  1029 fun gen_overwrite eq (al, p as (key, _)) =
  1030   let fun over ((q as (keyi, _)) :: pairs) =
  1031             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1032         | over [] = [p]
  1033   in over al end;
  1034 
  1035 
  1036 (* lists as tables *)
  1037 
  1038 fun gen_merge_lists _ xs [] = xs
  1039   | gen_merge_lists _ [] ys = ys
  1040   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1041 
  1042 fun gen_merge_lists' _ xs [] = xs
  1043   | gen_merge_lists' _ [] ys = ys
  1044   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1045 
  1046 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1047 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1048 fun merge_alists al = gen_merge_lists eq_fst al;
  1049 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1050 
  1051 
  1052 
  1053 (** balanced trees **)
  1054 
  1055 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1056 
  1057 (*balanced folding; avoids deep nesting*)
  1058 fun fold_bal f [x] = x
  1059   | fold_bal f [] = raise Balance
  1060   | fold_bal f xs =
  1061       let val (ps,qs) = splitAt(length xs div 2, xs)
  1062       in  f (fold_bal f ps, fold_bal f qs)  end;
  1063 
  1064 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1065 fun access_bal (f, g, x) n i =
  1066   let fun acc n i =     (*1<=i<=n*)
  1067           if n=1 then x else
  1068           let val n2 = n div 2
  1069           in  if i<=n2 then f (acc n2 i)
  1070                        else g (acc (n-n2) (i-n2))
  1071           end
  1072   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1073 
  1074 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1075 fun accesses_bal (f, g, x) n =
  1076   let fun acc n =
  1077           if n=1 then [x] else
  1078           let val n2 = n div 2
  1079               val acc2 = acc n2
  1080           in  if n-n2=n2 then map f acc2 @ map g acc2
  1081                          else map f acc2 @ map g (acc (n-n2)) end
  1082   in  if 1<=n then acc n else raise Balance  end;
  1083 
  1084 
  1085 
  1086 (** orders **)
  1087 
  1088 fun rev_order LESS = GREATER
  1089   | rev_order EQUAL = EQUAL
  1090   | rev_order GREATER = LESS;
  1091 
  1092 (*assume rel is a linear strict order*)
  1093 fun make_ord rel (x, y) =
  1094   if rel (x, y) then LESS
  1095   else if rel (y, x) then GREATER
  1096   else EQUAL;
  1097 
  1098 val int_ord = Int.compare;
  1099 val string_ord = String.compare;
  1100 
  1101 (*lexicographic product*)
  1102 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1103   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1104 
  1105 (*dictionary order -- in general NOT well-founded!*)
  1106 fun dict_ord _ ([], []) = EQUAL
  1107   | dict_ord _ ([], _ :: _) = LESS
  1108   | dict_ord _ (_ :: _, []) = GREATER
  1109   | dict_ord elem_ord (x :: xs, y :: ys) =
  1110       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1111 
  1112 (*lexicographic product of lists*)
  1113 fun list_ord elem_ord (xs, ys) =
  1114   prod_ord int_ord (dict_ord elem_ord) ((length xs, xs), (length ys, ys));
  1115 
  1116 
  1117 (* sorting *)
  1118 
  1119 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1120 fun sort ord =
  1121   let
  1122     fun qsort xs =
  1123       let val len = length xs in
  1124         if len <= 1 then xs
  1125         else
  1126           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1127             qsort lts @ eqs @ qsort gts
  1128           end
  1129       end
  1130     and part _ [] = ([], [], [])
  1131       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1132     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1133       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1134       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1135   in qsort end;
  1136 
  1137 (*sort strings*)
  1138 val sort_strings = sort string_ord;
  1139 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1140 
  1141 fun unique_strings ([]: string list) = []
  1142   | unique_strings [x] = [x]
  1143   | unique_strings (x :: y :: ys) =
  1144       if x = y then unique_strings (y :: ys)
  1145       else x :: unique_strings (y :: ys);
  1146 
  1147 
  1148 (** random numbers **)
  1149 
  1150 exception RANDOM;
  1151 
  1152 fun rmod x y = x - y * Real.realFloor (x / y);
  1153 
  1154 local
  1155   val a = 16807.0;
  1156   val m = 2147483647.0;
  1157   val random_seed = ref 1.0;
  1158 in
  1159 
  1160 fun random () =
  1161   let val r = rmod (a * !random_seed) m
  1162   in (random_seed := r; r) end;
  1163 
  1164 end;
  1165 
  1166 fun random_range l h =
  1167   if h < l orelse l < 0 then raise RANDOM
  1168   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1169 
  1170 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1171 
  1172 fun frequency xs =
  1173   let
  1174     val sum = foldl op + (0, map fst xs);
  1175     fun pick n ((k, x) :: xs) =
  1176       if n <= k then x else pick (n - k) xs
  1177   in pick (random_range 1 sum) xs end;
  1178 
  1179 
  1180 (** current directory **)
  1181 
  1182 val cd = OS.FileSys.chDir;
  1183 val pwd = OS.FileSys.getDir;
  1184 
  1185 
  1186 
  1187 (** rational numbers **)
  1188 
  1189 datatype rat = Rat of bool * int * int
  1190 
  1191 exception RAT of string;
  1192 
  1193 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1194 
  1195 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1196   let val absp = abs p
  1197       val m = gcd(absp,q)
  1198   in Rat(a = (0 <= p), absp div m, q div m) end;
  1199 
  1200 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1201   let val den = lcm(q,s)
  1202       val p = p*(den div q) and r = r*(den div s)
  1203       val num = (if a then p else ~p) + (if b then r else ~r)
  1204   in ratnorm(true,num,den) end;
  1205 
  1206 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1207 
  1208 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1209 
  1210 fun int_ratdiv(p,q) =
  1211   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1212 
  1213 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1214 
  1215 fun rat_of_int i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1216 
  1217 
  1218 (** misc **)
  1219 
  1220 (*use the keyfun to make a list of (x, key) pairs*)
  1221 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1222   let fun keypair x = (x, keyfun x)
  1223   in map keypair end;
  1224 
  1225 (*given a list of (x, key) pairs and a searchkey
  1226   return the list of xs from each pair whose key equals searchkey*)
  1227 fun keyfilter [] searchkey = []
  1228   | keyfilter ((x, key) :: pairs) searchkey =
  1229       if key = searchkey then x :: keyfilter pairs searchkey
  1230       else keyfilter pairs searchkey;
  1231 
  1232 
  1233 (*Partition list into elements that satisfy predicate and those that don't.
  1234   Preserves order of elements in both lists.*)
  1235 val partition = List.partition;
  1236 
  1237 
  1238 fun partition_eq (eq:'a * 'a -> bool) =
  1239     let fun part [] = []
  1240           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1241                            in (x::xs)::(part xs') end
  1242     in part end;
  1243 
  1244 
  1245 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1246    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1247 fun partition_list p i j =
  1248   let fun part k xs =
  1249             if k>j then
  1250               (case xs of [] => []
  1251                          | _ => raise Fail "partition_list")
  1252             else
  1253             let val (ns, rest) = partition (p k) xs;
  1254             in  ns :: part(k+1)rest  end
  1255   in  part i end;
  1256 
  1257 
  1258 (* generating identifiers *)
  1259 
  1260 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1261 local
  1262 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1263 fun char i =      if i<26 then chr (ord "A" + i)
  1264              else if i<52 then chr (ord "a" + i - 26)
  1265              else if i<62 then chr (ord"0" + i - 52)
  1266              else if i=62 then "_"
  1267              else  (*i=63*)    "'";
  1268 
  1269 val charVec = Vector.tabulate (64, char);
  1270 
  1271 fun newid n =
  1272   let
  1273   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1274 
  1275 val seedr = ref 0;
  1276 
  1277 in
  1278 
  1279 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1280 
  1281 end;
  1282 
  1283 
  1284 (* lexical scanning *)
  1285 
  1286 (*scan a list of characters into "words" composed of "letters" (recognized by
  1287   is_let) and separated by any number of non-"letters"*)
  1288 fun scanwords is_let cs =
  1289   let fun scan1 [] = []
  1290         | scan1 cs =
  1291             let val (lets, rest) = take_prefix is_let cs
  1292             in implode lets :: scanwords is_let rest end;
  1293   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1294 
  1295 
  1296 end;
  1297 
  1298 structure BasicLibrary: BASIC_LIBRARY = Library;
  1299 open BasicLibrary;