src/HOL/Nat.thy
author haftmann
Wed Feb 20 14:52:38 2008 +0100 (2008-02-20)
changeset 26101 a657683e902a
parent 26072 f65a7fa2da6c
child 26143 314c0bcb7df7
permissions -rw-r--r--
tuned structures in arith_data.ML
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Inductive Ring_and_Field
    13 uses
    14   "~~/src/Tools/rat.ML"
    15   "~~/src/Provers/Arith/cancel_sums.ML"
    16   ("arith_data.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = "Collect Nat"
    47   by (rule exI, rule CollectI, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc :: "nat => nat"
    51   Suc_def:      "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code func del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma nat_induct: "P 0 ==> (!!n. P n ==> P (Suc n)) ==> P n"
    66   apply (unfold Zero_nat_def Suc_def)
    67   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    68   apply (erule Rep_Nat [THEN CollectD, THEN Nat.induct])
    69   apply (iprover elim: Abs_Nat_inverse [OF CollectI, THEN subst])
    70   done
    71 
    72 lemma Suc_not_Zero [iff]: "Suc m \<noteq> 0"
    73   by (simp add: Zero_nat_def Suc_def
    74     Abs_Nat_inject Rep_Nat [THEN CollectD] Suc_RepI Zero_RepI
    75       Suc_Rep_not_Zero_Rep)
    76 
    77 lemma Zero_not_Suc [iff]: "0 \<noteq> Suc m"
    78   by (rule not_sym, rule Suc_not_Zero not_sym)
    79 
    80 lemma inj_Suc[simp]: "inj_on Suc N"
    81   by (simp add: Suc_def inj_on_def Abs_Nat_inject Rep_Nat [THEN CollectD] Suc_RepI
    82                 inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    83 
    84 lemma Suc_Suc_eq [iff]: "Suc m = Suc n \<longleftrightarrow> m = n"
    85   by (rule inj_Suc [THEN inj_eq])
    86 
    87 rep_datatype nat
    88   distinct  Suc_not_Zero Zero_not_Suc
    89   inject    Suc_Suc_eq
    90   induction nat_induct
    91 
    92 declare nat.induct [case_names 0 Suc, induct type: nat]
    93 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    94 
    95 lemmas nat_rec_0 = nat.recs(1)
    96   and nat_rec_Suc = nat.recs(2)
    97 
    98 lemmas nat_case_0 = nat.cases(1)
    99   and nat_case_Suc = nat.cases(2)
   100 
   101 
   102 text {* Injectiveness and distinctness lemmas *}
   103 
   104 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   105 by (rule notE, rule Suc_not_Zero)
   106 
   107 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   108 by (rule Suc_neq_Zero, erule sym)
   109 
   110 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   111 by (rule inj_Suc [THEN injD])
   112 
   113 lemma n_not_Suc_n: "n \<noteq> Suc n"
   114 by (induct n) simp_all
   115 
   116 lemma Suc_n_not_n: "Suc n \<noteq> n"
   117 by (rule not_sym, rule n_not_Suc_n)
   118 
   119 text {* A special form of induction for reasoning
   120   about @{term "m < n"} and @{term "m - n"} *}
   121 
   122 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   123     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   124   apply (rule_tac x = m in spec)
   125   apply (induct n)
   126   prefer 2
   127   apply (rule allI)
   128   apply (induct_tac x, iprover+)
   129   done
   130 
   131 
   132 subsection {* Arithmetic operators *}
   133 
   134 instantiation nat :: "{minus, comm_monoid_add}"
   135 begin
   136 
   137 primrec plus_nat
   138 where
   139   add_0:      "0 + n = (n\<Colon>nat)"
   140   | add_Suc:  "Suc m + n = Suc (m + n)"
   141 
   142 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   143   by (induct m) simp_all
   144 
   145 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   146   by (induct m) simp_all
   147 
   148 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   149   by simp
   150 
   151 primrec minus_nat
   152 where
   153   diff_0:     "m - 0 = (m\<Colon>nat)"
   154   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   155 
   156 declare diff_Suc [simp del, code del]
   157 
   158 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   159   by (induct n) (simp_all add: diff_Suc)
   160 
   161 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   162   by (induct n) (simp_all add: diff_Suc)
   163 
   164 instance proof
   165   fix n m q :: nat
   166   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   167   show "n + m = m + n" by (induct n) simp_all
   168   show "0 + n = n" by simp
   169 qed
   170 
   171 end
   172 
   173 instantiation nat :: comm_semiring_1_cancel
   174 begin
   175 
   176 definition
   177   One_nat_def [simp]: "1 = Suc 0"
   178 
   179 primrec times_nat
   180 where
   181   mult_0:     "0 * n = (0\<Colon>nat)"
   182   | mult_Suc: "Suc m * n = n + (m * n)"
   183 
   184 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   185   by (induct m) simp_all
   186 
   187 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   188   by (induct m) (simp_all add: add_left_commute)
   189 
   190 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   191   by (induct m) (simp_all add: add_assoc)
   192 
   193 instance proof
   194   fix n m q :: nat
   195   show "0 \<noteq> (1::nat)" by simp
   196   show "1 * n = n" by simp
   197   show "n * m = m * n" by (induct n) simp_all
   198   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   199   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   200   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   201 qed
   202 
   203 end
   204 
   205 subsubsection {* Addition *}
   206 
   207 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   208   by (rule add_assoc)
   209 
   210 lemma nat_add_commute: "m + n = n + (m::nat)"
   211   by (rule add_commute)
   212 
   213 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   214   by (rule add_left_commute)
   215 
   216 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   217   by (rule add_left_cancel)
   218 
   219 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   220   by (rule add_right_cancel)
   221 
   222 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   223 
   224 lemma add_is_0 [iff]:
   225   fixes m n :: nat
   226   shows "(m + n = 0) = (m = 0 & n = 0)"
   227   by (cases m) simp_all
   228 
   229 lemma add_is_1:
   230   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   231   by (cases m) simp_all
   232 
   233 lemma one_is_add:
   234   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   235   by (rule trans, rule eq_commute, rule add_is_1)
   236 
   237 lemma add_eq_self_zero:
   238   fixes m n :: nat
   239   shows "m + n = m \<Longrightarrow> n = 0"
   240   by (induct m) simp_all
   241 
   242 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   243   apply (induct k)
   244    apply simp
   245   apply(drule comp_inj_on[OF _ inj_Suc])
   246   apply (simp add:o_def)
   247   done
   248 
   249 
   250 subsubsection {* Difference *}
   251 
   252 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   253   by (induct m) simp_all
   254 
   255 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   256   by (induct i j rule: diff_induct) simp_all
   257 
   258 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   259   by (simp add: diff_diff_left)
   260 
   261 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   262   by (simp add: diff_diff_left add_commute)
   263 
   264 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   265   by (induct n) simp_all
   266 
   267 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   268   by (simp add: diff_add_inverse add_commute [of m n])
   269 
   270 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   271   by (induct k) simp_all
   272 
   273 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   274   by (simp add: diff_cancel add_commute)
   275 
   276 lemma diff_add_0: "n - (n + m) = (0::nat)"
   277   by (induct n) simp_all
   278 
   279 text {* Difference distributes over multiplication *}
   280 
   281 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   282 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   283 
   284 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   285 by (simp add: diff_mult_distrib mult_commute [of k])
   286   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   287 
   288 
   289 subsubsection {* Multiplication *}
   290 
   291 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   292   by (rule mult_assoc)
   293 
   294 lemma nat_mult_commute: "m * n = n * (m::nat)"
   295   by (rule mult_commute)
   296 
   297 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   298   by (rule right_distrib)
   299 
   300 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   301   by (induct m) auto
   302 
   303 lemmas nat_distrib =
   304   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   305 
   306 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   307   apply (induct m)
   308    apply simp
   309   apply (induct n)
   310    apply auto
   311   done
   312 
   313 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   314   apply (rule trans)
   315   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   316   done
   317 
   318 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   319 proof -
   320   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   321   proof (induct n arbitrary: m)
   322     case 0 then show "m = 0" by simp
   323   next
   324     case (Suc n) then show "m = Suc n"
   325       by (cases m) (simp_all add: eq_commute [of "0"])
   326   qed
   327   then show ?thesis by auto
   328 qed
   329 
   330 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   331   by (simp add: mult_commute)
   332 
   333 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   334   by (subst mult_cancel1) simp
   335 
   336 
   337 subsection {* Orders on @{typ nat} *}
   338 
   339 subsubsection {* Operation definition *}
   340 
   341 instantiation nat :: linorder
   342 begin
   343 
   344 primrec less_eq_nat where
   345   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   346   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   347 
   348 declare less_eq_nat.simps [simp del, code del]
   349 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   350 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   351 
   352 definition less_nat where
   353   less_eq_Suc_le [code func del]: "n < m \<longleftrightarrow> Suc n \<le> m"
   354 
   355 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   356   by (simp add: less_eq_nat.simps(2))
   357 
   358 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   359   unfolding less_eq_Suc_le ..
   360 
   361 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   362   by (induct n) (simp_all add: less_eq_nat.simps(2))
   363 
   364 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   365   by (simp add: less_eq_Suc_le)
   366 
   367 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   368   by simp
   369 
   370 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   371   by (simp add: less_eq_Suc_le)
   372 
   373 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   374   by (simp add: less_eq_Suc_le)
   375 
   376 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   377   by (induct m arbitrary: n)
   378     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   379 
   380 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   381   by (cases n) (auto intro: le_SucI)
   382 
   383 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   384   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   385 
   386 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   387   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   388 
   389 instance proof
   390   fix n m :: nat
   391   have less_imp_le: "n < m \<Longrightarrow> n \<le> m"
   392     unfolding less_eq_Suc_le by (erule Suc_leD)
   393   have irrefl: "\<not> m < m" by (induct m) auto
   394   have strict: "n \<le> m \<Longrightarrow> n \<noteq> m \<Longrightarrow> n < m"
   395   proof (induct n arbitrary: m)
   396     case 0 then show ?case
   397       by (cases m) (simp_all add: less_eq_Suc_le)
   398   next
   399     case (Suc n) then show ?case
   400       by (cases m) (simp_all add: less_eq_Suc_le)
   401   qed
   402   show "n < m \<longleftrightarrow> n \<le> m \<and> n \<noteq> m"
   403     by (auto simp add: irrefl intro: less_imp_le strict)
   404 next
   405   fix n :: nat show "n \<le> n" by (induct n) simp_all
   406 next
   407   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   408   then show "n = m"
   409     by (induct n arbitrary: m)
   410       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   411 next
   412   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   413   then show "n \<le> q"
   414   proof (induct n arbitrary: m q)
   415     case 0 show ?case by simp
   416   next
   417     case (Suc n) then show ?case
   418       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   419         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   420         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   421   qed
   422 next
   423   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   424     by (induct n arbitrary: m)
   425       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   426 qed
   427 
   428 end
   429 
   430 subsubsection {* Introduction properties *}
   431 
   432 lemma lessI [iff]: "n < Suc n"
   433   by (simp add: less_Suc_eq_le)
   434 
   435 lemma zero_less_Suc [iff]: "0 < Suc n"
   436   by (simp add: less_Suc_eq_le)
   437 
   438 lemma less_trans: "i < j ==> j < k ==> i < (k::nat)"
   439   by (rule order_less_trans)
   440 
   441 subsubsection {* Elimination properties *}
   442 
   443 lemma less_not_sym: "n < m ==> ~ m < (n::nat)"
   444   by (rule order_less_not_sym)
   445 
   446 lemma less_asym:
   447   assumes h1: "(n::nat) < m" and h2: "~ P ==> m < n" shows P
   448   apply (rule contrapos_np)
   449   apply (rule less_not_sym)
   450   apply (rule h1)
   451   apply (erule h2)
   452   done
   453 
   454 lemma less_not_refl: "~ n < (n::nat)"
   455   by (rule order_less_irrefl)
   456 
   457 lemma less_irrefl [elim!]: "(n::nat) < n ==> R"
   458   by (rule notE, rule less_not_refl)
   459 
   460 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   461   by (rule less_imp_neq)
   462 
   463 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   464   by (rule not_sym) (rule less_imp_neq) 
   465 
   466 lemma less_zeroE: "(n::nat) < 0 ==> R"
   467   by (rule notE) (rule not_less0)
   468 
   469 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   470   unfolding less_Suc_eq_le le_less ..
   471 
   472 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   473   by (simp add: less_Suc_eq)
   474 
   475 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   476   by (simp add: less_Suc_eq)
   477 
   478 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   479   by simp
   480 
   481 lemma less_linear: "m < n | m = n | n < (m::nat)"
   482   by (rule less_linear)
   483 
   484 text {* "Less than" is antisymmetric, sort of *}
   485 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   486   unfolding not_less less_Suc_eq_le by (rule antisym)
   487 
   488 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   489   by (rule linorder_neq_iff)
   490 
   491 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   492   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   493   shows "P n m"
   494   apply (rule less_linear [THEN disjE])
   495   apply (erule_tac [2] disjE)
   496   apply (erule lessCase)
   497   apply (erule sym [THEN eqCase])
   498   apply (erule major)
   499   done
   500 
   501 
   502 subsubsection {* Inductive (?) properties *}
   503 
   504 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   505   unfolding less_eq_Suc_le [of m] le_less by simp 
   506 
   507 lemma lessE:
   508   assumes major: "i < k"
   509   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   510   shows P
   511 proof -
   512   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   513     unfolding less_eq_Suc_le by (induct k) simp_all
   514   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   515     by (clarsimp simp add: less_le)
   516   with p1 p2 show P by auto
   517 qed
   518 
   519 lemma less_SucE: assumes major: "m < Suc n"
   520   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   521   apply (rule major [THEN lessE])
   522   apply (rule eq, blast)
   523   apply (rule less, blast)
   524   done
   525 
   526 lemma Suc_lessE: assumes major: "Suc i < k"
   527   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   528   apply (rule major [THEN lessE])
   529   apply (erule lessI [THEN minor])
   530   apply (erule Suc_lessD [THEN minor], assumption)
   531   done
   532 
   533 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   534   by simp
   535 
   536 lemma less_trans_Suc:
   537   assumes le: "i < j" shows "j < k ==> Suc i < k"
   538   apply (induct k, simp_all)
   539   apply (insert le)
   540   apply (simp add: less_Suc_eq)
   541   apply (blast dest: Suc_lessD)
   542   done
   543 
   544 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   545 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   546   unfolding not_less less_Suc_eq_le ..
   547 
   548 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   549   unfolding not_le Suc_le_eq ..
   550 
   551 text {* Properties of "less than or equal" *}
   552 
   553 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   554   unfolding less_Suc_eq_le .
   555 
   556 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   557   unfolding not_le less_Suc_eq_le ..
   558 
   559 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   560   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   561 
   562 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   563   by (drule le_Suc_eq [THEN iffD1], iprover+)
   564 
   565 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   566   unfolding Suc_le_eq .
   567 
   568 text {* Stronger version of @{text Suc_leD} *}
   569 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   570   unfolding Suc_le_eq .
   571 
   572 lemma less_imp_le: "m < n ==> m \<le> (n::nat)"
   573   unfolding less_eq_Suc_le by (rule Suc_leD)
   574 
   575 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   576 lemmas le_simps = less_imp_le less_Suc_eq_le Suc_le_eq
   577 
   578 
   579 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   580 
   581 lemma le_imp_less_or_eq: "m \<le> n ==> m < n | m = (n::nat)"
   582   unfolding le_less .
   583 
   584 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   585   unfolding le_less .
   586 
   587 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   588   by (rule le_less)
   589 
   590 text {* Useful with @{text blast}. *}
   591 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   592   by auto
   593 
   594 lemma le_refl: "n \<le> (n::nat)"
   595   by simp
   596 
   597 lemma le_less_trans: "[| i \<le> j; j < k |] ==> i < (k::nat)"
   598   by (rule order_le_less_trans)
   599 
   600 lemma less_le_trans: "[| i < j; j \<le> k |] ==> i < (k::nat)"
   601   by (rule order_less_le_trans)
   602 
   603 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   604   by (rule order_trans)
   605 
   606 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   607   by (rule antisym)
   608 
   609 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   610   by (rule less_le)
   611 
   612 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   613   unfolding less_le ..
   614 
   615 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   616   by (rule linear)
   617 
   618 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   619 
   620 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   621   unfolding less_Suc_eq_le by auto
   622 
   623 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   624   unfolding not_less by (rule le_less_Suc_eq)
   625 
   626 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   627 
   628 text {* These two rules ease the use of primitive recursion.
   629 NOTE USE OF @{text "=="} *}
   630 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   631 by simp
   632 
   633 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   634 by simp
   635 
   636 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   637 by (cases n) simp_all
   638 
   639 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   640 by (cases n) simp_all
   641 
   642 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   643 by (cases n) simp_all
   644 
   645 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   646 by (cases n) simp_all
   647 
   648 text {* This theorem is useful with @{text blast} *}
   649 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   650 by (rule neq0_conv[THEN iffD1], iprover)
   651 
   652 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   653 by (fast intro: not0_implies_Suc)
   654 
   655 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   656 using neq0_conv by blast
   657 
   658 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   659 by (induct m') simp_all
   660 
   661 text {* Useful in certain inductive arguments *}
   662 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   663 by (cases m) simp_all
   664 
   665 
   666 subsubsection {* @{term min} and @{term max} *}
   667 
   668 lemma mono_Suc: "mono Suc"
   669 by (rule monoI) simp
   670 
   671 lemma min_0L [simp]: "min 0 n = (0::nat)"
   672 by (rule min_leastL) simp
   673 
   674 lemma min_0R [simp]: "min n 0 = (0::nat)"
   675 by (rule min_leastR) simp
   676 
   677 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   678 by (simp add: mono_Suc min_of_mono)
   679 
   680 lemma min_Suc1:
   681    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   682 by (simp split: nat.split)
   683 
   684 lemma min_Suc2:
   685    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   686 by (simp split: nat.split)
   687 
   688 lemma max_0L [simp]: "max 0 n = (n::nat)"
   689 by (rule max_leastL) simp
   690 
   691 lemma max_0R [simp]: "max n 0 = (n::nat)"
   692 by (rule max_leastR) simp
   693 
   694 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   695 by (simp add: mono_Suc max_of_mono)
   696 
   697 lemma max_Suc1:
   698    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   699 by (simp split: nat.split)
   700 
   701 lemma max_Suc2:
   702    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   703 by (simp split: nat.split)
   704 
   705 
   706 subsubsection {* Monotonicity of Addition *}
   707 
   708 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   709 by (simp add: diff_Suc split: nat.split)
   710 
   711 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   712 by (induct k) simp_all
   713 
   714 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   715 by (induct k) simp_all
   716 
   717 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   718 by(auto dest:gr0_implies_Suc)
   719 
   720 text {* strict, in 1st argument *}
   721 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   722 by (induct k) simp_all
   723 
   724 text {* strict, in both arguments *}
   725 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   726   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   727   apply (induct j, simp_all)
   728   done
   729 
   730 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   731 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   732   apply (induct n)
   733   apply (simp_all add: order_le_less)
   734   apply (blast elim!: less_SucE
   735                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   736   done
   737 
   738 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   739 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   740 apply(auto simp: gr0_conv_Suc)
   741 apply (induct_tac m)
   742 apply (simp_all add: add_less_mono)
   743 done
   744 
   745 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   746 instance nat :: ordered_semidom
   747 proof
   748   fix i j k :: nat
   749   show "0 < (1::nat)" by simp
   750   show "i \<le> j ==> k + i \<le> k + j" by simp
   751   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   752 qed
   753 
   754 lemma nat_mult_1: "(1::nat) * n = n"
   755 by simp
   756 
   757 lemma nat_mult_1_right: "n * (1::nat) = n"
   758 by simp
   759 
   760 
   761 subsubsection {* Additional theorems about "less than" *}
   762 
   763 text{*An induction rule for estabilishing binary relations*}
   764 lemma less_Suc_induct:
   765   assumes less:  "i < j"
   766      and  step:  "!!i. P i (Suc i)"
   767      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   768   shows "P i j"
   769 proof -
   770   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add)
   771   have "P i (Suc (i + k))"
   772   proof (induct k)
   773     case 0
   774     show ?case by (simp add: step)
   775   next
   776     case (Suc k)
   777     thus ?case by (auto intro: assms)
   778   qed
   779   thus "P i j" by (simp add: j)
   780 qed
   781 
   782 text {* A [clumsy] way of lifting @{text "<"}
   783   monotonicity to @{text "\<le>"} monotonicity *}
   784 lemma less_mono_imp_le_mono:
   785   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   786 by (simp add: order_le_less) (blast)
   787 
   788 
   789 text {* non-strict, in 1st argument *}
   790 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   791 by (rule add_right_mono)
   792 
   793 text {* non-strict, in both arguments *}
   794 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   795 by (rule add_mono)
   796 
   797 lemma le_add2: "n \<le> ((m + n)::nat)"
   798 by (insert add_right_mono [of 0 m n], simp)
   799 
   800 lemma le_add1: "n \<le> ((n + m)::nat)"
   801 by (simp add: add_commute, rule le_add2)
   802 
   803 lemma less_add_Suc1: "i < Suc (i + m)"
   804 by (rule le_less_trans, rule le_add1, rule lessI)
   805 
   806 lemma less_add_Suc2: "i < Suc (m + i)"
   807 by (rule le_less_trans, rule le_add2, rule lessI)
   808 
   809 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   810 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   811 
   812 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   813 by (rule le_trans, assumption, rule le_add1)
   814 
   815 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   816 by (rule le_trans, assumption, rule le_add2)
   817 
   818 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   819 by (rule less_le_trans, assumption, rule le_add1)
   820 
   821 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   822 by (rule less_le_trans, assumption, rule le_add2)
   823 
   824 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   825 apply (rule le_less_trans [of _ "i+j"])
   826 apply (simp_all add: le_add1)
   827 done
   828 
   829 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   830 apply (rule notI)
   831 apply (erule add_lessD1 [THEN less_irrefl])
   832 done
   833 
   834 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   835 by (simp add: add_commute not_add_less1)
   836 
   837 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   838 apply (rule order_trans [of _ "m+k"])
   839 apply (simp_all add: le_add1)
   840 done
   841 
   842 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   843 apply (simp add: add_commute)
   844 apply (erule add_leD1)
   845 done
   846 
   847 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   848 by (blast dest: add_leD1 add_leD2)
   849 
   850 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   851 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   852 by (force simp del: add_Suc_right
   853     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   854 
   855 
   856 subsubsection {* More results about difference *}
   857 
   858 lemma diff_self_eq_0 [simp]: "(m::nat) - m = 0"
   859 by (induct m) simp_all
   860 
   861 text {* Addition is the inverse of subtraction:
   862   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   863 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   864 by (induct m n rule: diff_induct) simp_all
   865 
   866 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   867 by (simp add: add_diff_inverse linorder_not_less)
   868 
   869 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   870 by (simp add: le_add_diff_inverse add_commute)
   871 
   872 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   873 by (induct m n rule: diff_induct) simp_all
   874 
   875 lemma diff_less_Suc: "m - n < Suc m"
   876 apply (induct m n rule: diff_induct)
   877 apply (erule_tac [3] less_SucE)
   878 apply (simp_all add: less_Suc_eq)
   879 done
   880 
   881 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   882 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   883 
   884 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
   885   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
   886 
   887 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   888 by (rule le_less_trans, rule diff_le_self)
   889 
   890 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   891 by (cases n) (auto simp add: le_simps)
   892 
   893 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   894 by (induct j k rule: diff_induct) simp_all
   895 
   896 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   897 by (simp add: add_commute diff_add_assoc)
   898 
   899 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   900 by (auto simp add: diff_add_inverse2)
   901 
   902 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   903 by (induct m n rule: diff_induct) simp_all
   904 
   905 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
   906 by (rule iffD2, rule diff_is_0_eq)
   907 
   908 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
   909 by (induct m n rule: diff_induct) simp_all
   910 
   911 lemma less_imp_add_positive:
   912   assumes "i < j"
   913   shows "\<exists>k::nat. 0 < k & i + k = j"
   914 proof
   915   from assms show "0 < j - i & i + (j - i) = j"
   916     by (simp add: order_less_imp_le)
   917 qed
   918 
   919 text {* a nice rewrite for bounded subtraction *}
   920 lemma nat_minus_add_max:
   921   fixes n m :: nat
   922   shows "n - m + m = max n m"
   923     by (simp add: max_def not_le order_less_imp_le)
   924 
   925 lemma nat_diff_split:
   926   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
   927     -- {* elimination of @{text -} on @{text nat} *}
   928 by (cases "a < b")
   929   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
   930     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
   931 
   932 lemma nat_diff_split_asm:
   933   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
   934     -- {* elimination of @{text -} on @{text nat} in assumptions *}
   935 by (auto split: nat_diff_split)
   936 
   937 
   938 subsubsection {* Monotonicity of Multiplication *}
   939 
   940 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
   941 by (simp add: mult_right_mono)
   942 
   943 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
   944 by (simp add: mult_left_mono)
   945 
   946 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
   947 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
   948 by (simp add: mult_mono)
   949 
   950 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
   951 by (simp add: mult_strict_right_mono)
   952 
   953 text{*Differs from the standard @{text zero_less_mult_iff} in that
   954       there are no negative numbers.*}
   955 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
   956   apply (induct m)
   957    apply simp
   958   apply (case_tac n)
   959    apply simp_all
   960   done
   961 
   962 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
   963   apply (induct m)
   964    apply simp
   965   apply (case_tac n)
   966    apply simp_all
   967   done
   968 
   969 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
   970   apply (safe intro!: mult_less_mono1)
   971   apply (case_tac k, auto)
   972   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
   973   apply (blast intro: mult_le_mono1)
   974   done
   975 
   976 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
   977 by (simp add: mult_commute [of k])
   978 
   979 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
   980 by (simp add: linorder_not_less [symmetric], auto)
   981 
   982 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
   983 by (simp add: linorder_not_less [symmetric], auto)
   984 
   985 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
   986 by (subst mult_less_cancel1) simp
   987 
   988 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
   989 by (subst mult_le_cancel1) simp
   990 
   991 lemma le_square: "m \<le> m * (m::nat)"
   992   by (cases m) (auto intro: le_add1)
   993 
   994 lemma le_cube: "(m::nat) \<le> m * (m * m)"
   995   by (cases m) (auto intro: le_add1)
   996 
   997 text {* Lemma for @{text gcd} *}
   998 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
   999   apply (drule sym)
  1000   apply (rule disjCI)
  1001   apply (rule nat_less_cases, erule_tac [2] _)
  1002    apply (drule_tac [2] mult_less_mono2)
  1003     apply (auto)
  1004   done
  1005 
  1006 text {* the lattice order on @{typ nat} *}
  1007 
  1008 instantiation nat :: distrib_lattice
  1009 begin
  1010 
  1011 definition
  1012   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1013 
  1014 definition
  1015   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1016 
  1017 instance by intro_classes
  1018   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1019     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1020 
  1021 end
  1022 
  1023 
  1024 subsection {* Embedding of the Naturals into any
  1025   @{text semiring_1}: @{term of_nat} *}
  1026 
  1027 context semiring_1
  1028 begin
  1029 
  1030 primrec
  1031   of_nat :: "nat \<Rightarrow> 'a"
  1032 where
  1033   of_nat_0:     "of_nat 0 = 0"
  1034   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1035 
  1036 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1037   by simp
  1038 
  1039 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1040   by (induct m) (simp_all add: add_ac)
  1041 
  1042 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1043   by (induct m) (simp_all add: add_ac left_distrib)
  1044 
  1045 definition
  1046   of_nat_aux :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1047 where
  1048   [code func del]: "of_nat_aux n i = of_nat n + i"
  1049 
  1050 lemma of_nat_aux_code [code]:
  1051   "of_nat_aux 0 i = i"
  1052   "of_nat_aux (Suc n) i = of_nat_aux n (i + 1)" -- {* tail recursive *}
  1053   by (simp_all add: of_nat_aux_def add_ac)
  1054 
  1055 lemma of_nat_code [code]:
  1056   "of_nat n = of_nat_aux n 0"
  1057   by (simp add: of_nat_aux_def)
  1058 
  1059 end
  1060 
  1061 text{*Class for unital semirings with characteristic zero.
  1062  Includes non-ordered rings like the complex numbers.*}
  1063 
  1064 class semiring_char_0 = semiring_1 +
  1065   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1066 begin
  1067 
  1068 text{*Special cases where either operand is zero*}
  1069 
  1070 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1071   by (rule of_nat_eq_iff [of 0, simplified])
  1072 
  1073 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1074   by (rule of_nat_eq_iff [of _ 0, simplified])
  1075 
  1076 lemma inj_of_nat: "inj of_nat"
  1077   by (simp add: inj_on_def)
  1078 
  1079 end
  1080 
  1081 context ordered_semidom
  1082 begin
  1083 
  1084 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1085   apply (induct m, simp_all)
  1086   apply (erule order_trans)
  1087   apply (rule ord_le_eq_trans [OF _ add_commute])
  1088   apply (rule less_add_one [THEN less_imp_le])
  1089   done
  1090 
  1091 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1092   apply (induct m n rule: diff_induct, simp_all)
  1093   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1094   done
  1095 
  1096 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1097   apply (induct m n rule: diff_induct, simp_all)
  1098   apply (insert zero_le_imp_of_nat)
  1099   apply (force simp add: not_less [symmetric])
  1100   done
  1101 
  1102 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1103   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1104 
  1105 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1106   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1107 
  1108 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1109 
  1110 subclass semiring_char_0
  1111   by unfold_locales (simp add: eq_iff order_eq_iff)
  1112 
  1113 text{*Special cases where either operand is zero*}
  1114 
  1115 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1116   by (rule of_nat_le_iff [of 0, simplified])
  1117 
  1118 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1119   by (rule of_nat_le_iff [of _ 0, simplified])
  1120 
  1121 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1122   by (rule of_nat_less_iff [of 0, simplified])
  1123 
  1124 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1125   by (rule of_nat_less_iff [of _ 0, simplified])
  1126 
  1127 end
  1128 
  1129 context ring_1
  1130 begin
  1131 
  1132 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1133   by (simp add: compare_rls of_nat_add [symmetric])
  1134 
  1135 end
  1136 
  1137 context ordered_idom
  1138 begin
  1139 
  1140 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1141   unfolding abs_if by auto
  1142 
  1143 end
  1144 
  1145 lemma of_nat_id [simp]: "of_nat n = n"
  1146   by (induct n) auto
  1147 
  1148 lemma of_nat_eq_id [simp]: "of_nat = id"
  1149   by (auto simp add: expand_fun_eq)
  1150 
  1151 
  1152 subsection {*The Set of Natural Numbers*}
  1153 
  1154 context semiring_1
  1155 begin
  1156 
  1157 definition
  1158   Nats  :: "'a set" where
  1159   "Nats = range of_nat"
  1160 
  1161 notation (xsymbols)
  1162   Nats  ("\<nat>")
  1163 
  1164 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1165   by (simp add: Nats_def)
  1166 
  1167 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1168 apply (simp add: Nats_def)
  1169 apply (rule range_eqI)
  1170 apply (rule of_nat_0 [symmetric])
  1171 done
  1172 
  1173 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1174 apply (simp add: Nats_def)
  1175 apply (rule range_eqI)
  1176 apply (rule of_nat_1 [symmetric])
  1177 done
  1178 
  1179 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1180 apply (auto simp add: Nats_def)
  1181 apply (rule range_eqI)
  1182 apply (rule of_nat_add [symmetric])
  1183 done
  1184 
  1185 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1186 apply (auto simp add: Nats_def)
  1187 apply (rule range_eqI)
  1188 apply (rule of_nat_mult [symmetric])
  1189 done
  1190 
  1191 end
  1192 
  1193 
  1194 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1195 
  1196 lemma subst_equals:
  1197   assumes 1: "t = s" and 2: "u = t"
  1198   shows "u = s"
  1199   using 2 1 by (rule trans)
  1200 
  1201 use "arith_data.ML"
  1202 declaration {* K ArithData.setup *}
  1203 
  1204 use "Tools/lin_arith.ML"
  1205 declaration {* K LinArith.setup *}
  1206 
  1207 lemmas [arith_split] = nat_diff_split split_min split_max
  1208 
  1209 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1210 
  1211 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1212 by arith
  1213 
  1214 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1215 by arith
  1216 
  1217 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1218 by arith
  1219 
  1220 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1221 by arith
  1222 
  1223 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1224 by arith
  1225 
  1226 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1227 by arith
  1228 
  1229 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1230   second premise n\<le>m*)
  1231 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1232 by arith
  1233 
  1234 text {* Simplification of relational expressions involving subtraction *}
  1235 
  1236 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1237 by (simp split add: nat_diff_split)
  1238 
  1239 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1240 by (auto split add: nat_diff_split)
  1241 
  1242 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1243 by (auto split add: nat_diff_split)
  1244 
  1245 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1246 by (auto split add: nat_diff_split)
  1247 
  1248 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1249 
  1250 (* Monotonicity of subtraction in first argument *)
  1251 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1252 by (simp split add: nat_diff_split)
  1253 
  1254 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1255 by (simp split add: nat_diff_split)
  1256 
  1257 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1258 by (simp split add: nat_diff_split)
  1259 
  1260 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1261 by (simp split add: nat_diff_split)
  1262 
  1263 text{*Rewriting to pull differences out*}
  1264 
  1265 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1266 by arith
  1267 
  1268 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1269 by arith
  1270 
  1271 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1272 by arith
  1273 
  1274 text{*Lemmas for ex/Factorization*}
  1275 
  1276 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1277 by (cases m) auto
  1278 
  1279 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1280 by (cases m) auto
  1281 
  1282 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1283 by (cases m) auto
  1284 
  1285 text {* Specialized induction principles that work "backwards": *}
  1286 
  1287 lemma inc_induct[consumes 1, case_names base step]:
  1288   assumes less: "i <= j"
  1289   assumes base: "P j"
  1290   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1291   shows "P i"
  1292   using less
  1293 proof (induct d=="j - i" arbitrary: i)
  1294   case (0 i)
  1295   hence "i = j" by simp
  1296   with base show ?case by simp
  1297 next
  1298   case (Suc d i)
  1299   hence "i < j" "P (Suc i)"
  1300     by simp_all
  1301   thus "P i" by (rule step)
  1302 qed
  1303 
  1304 lemma strict_inc_induct[consumes 1, case_names base step]:
  1305   assumes less: "i < j"
  1306   assumes base: "!!i. j = Suc i ==> P i"
  1307   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1308   shows "P i"
  1309   using less
  1310 proof (induct d=="j - i - 1" arbitrary: i)
  1311   case (0 i)
  1312   with `i < j` have "j = Suc i" by simp
  1313   with base show ?case by simp
  1314 next
  1315   case (Suc d i)
  1316   hence "i < j" "P (Suc i)"
  1317     by simp_all
  1318   thus "P i" by (rule step)
  1319 qed
  1320 
  1321 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1322   using inc_induct[of "k - i" k P, simplified] by blast
  1323 
  1324 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1325   using inc_induct[of 0 k P] by blast
  1326 
  1327 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1328   by auto
  1329 
  1330 (*The others are
  1331       i - j - k = i - (j + k),
  1332       k \<le> j ==> j - k + i = j + i - k,
  1333       k \<le> j ==> i + (j - k) = i + j - k *)
  1334 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1335 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1336 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1337 
  1338 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1339 Least_Suc}, since there appears to be no need.*}
  1340 
  1341 subsection {* size of a datatype value *}
  1342 
  1343 class size = type +
  1344   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded_Recursion} *}
  1345 
  1346 end