src/HOL/Library/Sublist.thy
author eberlm <eberlm@in.tum.de>
Thu May 18 12:02:21 2017 +0200 (2017-05-18)
changeset 65869 a6ed757b8585
parent 64886 cea327ecb8e3
child 65954 431024edc9cf
permissions -rw-r--r--
more on sublists
     1 (*  Title:      HOL/Library/Sublist.thy
     2     Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
     3     Author:     Christian Sternagel, JAIST
     4 *)
     5 
     6 section \<open>List prefixes, suffixes, and homeomorphic embedding\<close>
     7 
     8 theory Sublist
     9 imports Main
    10 begin
    11 
    12 subsection \<open>Prefix order on lists\<close>
    13 
    14 definition prefix :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool"
    15   where "prefix xs ys \<longleftrightarrow> (\<exists>zs. ys = xs @ zs)"
    16 
    17 definition strict_prefix :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool"
    18   where "strict_prefix xs ys \<longleftrightarrow> prefix xs ys \<and> xs \<noteq> ys"
    19 
    20 interpretation prefix_order: order prefix strict_prefix
    21   by standard (auto simp: prefix_def strict_prefix_def)
    22 
    23 interpretation prefix_bot: order_bot Nil prefix strict_prefix
    24   by standard (simp add: prefix_def)
    25 
    26 lemma prefixI [intro?]: "ys = xs @ zs \<Longrightarrow> prefix xs ys"
    27   unfolding prefix_def by blast
    28 
    29 lemma prefixE [elim?]:
    30   assumes "prefix xs ys"
    31   obtains zs where "ys = xs @ zs"
    32   using assms unfolding prefix_def by blast
    33 
    34 lemma strict_prefixI' [intro?]: "ys = xs @ z # zs \<Longrightarrow> strict_prefix xs ys"
    35   unfolding strict_prefix_def prefix_def by blast
    36 
    37 lemma strict_prefixE' [elim?]:
    38   assumes "strict_prefix xs ys"
    39   obtains z zs where "ys = xs @ z # zs"
    40 proof -
    41   from \<open>strict_prefix xs ys\<close> obtain us where "ys = xs @ us" and "xs \<noteq> ys"
    42     unfolding strict_prefix_def prefix_def by blast
    43   with that show ?thesis by (auto simp add: neq_Nil_conv)
    44 qed
    45 
    46 (* FIXME rm *)
    47 lemma strict_prefixI [intro?]: "prefix xs ys \<Longrightarrow> xs \<noteq> ys \<Longrightarrow> strict_prefix xs ys"
    48 by(fact prefix_order.le_neq_trans)
    49 
    50 lemma strict_prefixE [elim?]:
    51   fixes xs ys :: "'a list"
    52   assumes "strict_prefix xs ys"
    53   obtains "prefix xs ys" and "xs \<noteq> ys"
    54   using assms unfolding strict_prefix_def by blast
    55 
    56 
    57 subsection \<open>Basic properties of prefixes\<close>
    58 
    59 (* FIXME rm *)
    60 theorem Nil_prefix [simp]: "prefix [] xs"
    61   by (fact prefix_bot.bot_least)
    62 
    63 (* FIXME rm *)
    64 theorem prefix_Nil [simp]: "(prefix xs []) = (xs = [])"
    65   by (fact prefix_bot.bot_unique)
    66 
    67 lemma prefix_snoc [simp]: "prefix xs (ys @ [y]) \<longleftrightarrow> xs = ys @ [y] \<or> prefix xs ys"
    68 proof
    69   assume "prefix xs (ys @ [y])"
    70   then obtain zs where zs: "ys @ [y] = xs @ zs" ..
    71   show "xs = ys @ [y] \<or> prefix xs ys"
    72     by (metis append_Nil2 butlast_append butlast_snoc prefixI zs)
    73 next
    74   assume "xs = ys @ [y] \<or> prefix xs ys"
    75   then show "prefix xs (ys @ [y])"
    76     by (metis prefix_order.eq_iff prefix_order.order_trans prefixI)
    77 qed
    78 
    79 lemma Cons_prefix_Cons [simp]: "prefix (x # xs) (y # ys) = (x = y \<and> prefix xs ys)"
    80   by (auto simp add: prefix_def)
    81 
    82 lemma prefix_code [code]:
    83   "prefix [] xs \<longleftrightarrow> True"
    84   "prefix (x # xs) [] \<longleftrightarrow> False"
    85   "prefix (x # xs) (y # ys) \<longleftrightarrow> x = y \<and> prefix xs ys"
    86   by simp_all
    87 
    88 lemma same_prefix_prefix [simp]: "prefix (xs @ ys) (xs @ zs) = prefix ys zs"
    89   by (induct xs) simp_all
    90 
    91 lemma same_prefix_nil [simp]: "prefix (xs @ ys) xs = (ys = [])"
    92   by (metis append_Nil2 append_self_conv prefix_order.eq_iff prefixI)
    93 
    94 lemma prefix_prefix [simp]: "prefix xs ys \<Longrightarrow> prefix xs (ys @ zs)"
    95   unfolding prefix_def by fastforce
    96 
    97 lemma append_prefixD: "prefix (xs @ ys) zs \<Longrightarrow> prefix xs zs"
    98   by (auto simp add: prefix_def)
    99 
   100 theorem prefix_Cons: "prefix xs (y # ys) = (xs = [] \<or> (\<exists>zs. xs = y # zs \<and> prefix zs ys))"
   101   by (cases xs) (auto simp add: prefix_def)
   102 
   103 theorem prefix_append:
   104   "prefix xs (ys @ zs) = (prefix xs ys \<or> (\<exists>us. xs = ys @ us \<and> prefix us zs))"
   105   apply (induct zs rule: rev_induct)
   106    apply force
   107   apply (simp del: append_assoc add: append_assoc [symmetric])
   108   apply (metis append_eq_appendI)
   109   done
   110 
   111 lemma append_one_prefix:
   112   "prefix xs ys \<Longrightarrow> length xs < length ys \<Longrightarrow> prefix (xs @ [ys ! length xs]) ys"
   113   proof (unfold prefix_def)
   114     assume a1: "\<exists>zs. ys = xs @ zs"
   115     then obtain sk :: "'a list" where sk: "ys = xs @ sk" by fastforce
   116     assume a2: "length xs < length ys"
   117     have f1: "\<And>v. ([]::'a list) @ v = v" using append_Nil2 by simp
   118     have "[] \<noteq> sk" using a1 a2 sk less_not_refl by force
   119     hence "\<exists>v. xs @ hd sk # v = ys" using sk by (metis hd_Cons_tl)
   120     thus "\<exists>zs. ys = (xs @ [ys ! length xs]) @ zs" using f1 by fastforce
   121   qed
   122 
   123 theorem prefix_length_le: "prefix xs ys \<Longrightarrow> length xs \<le> length ys"
   124   by (auto simp add: prefix_def)
   125 
   126 lemma prefix_same_cases:
   127   "prefix (xs\<^sub>1::'a list) ys \<Longrightarrow> prefix xs\<^sub>2 ys \<Longrightarrow> prefix xs\<^sub>1 xs\<^sub>2 \<or> prefix xs\<^sub>2 xs\<^sub>1"
   128   unfolding prefix_def by (force simp: append_eq_append_conv2)
   129 
   130 lemma prefix_length_prefix:
   131   "prefix ps xs \<Longrightarrow> prefix qs xs \<Longrightarrow> length ps \<le> length qs \<Longrightarrow> prefix ps qs"
   132 by (auto simp: prefix_def) (metis append_Nil2 append_eq_append_conv_if)
   133 
   134 lemma set_mono_prefix: "prefix xs ys \<Longrightarrow> set xs \<subseteq> set ys"
   135   by (auto simp add: prefix_def)
   136 
   137 lemma take_is_prefix: "prefix (take n xs) xs"
   138   unfolding prefix_def by (metis append_take_drop_id)
   139 
   140 lemma prefixeq_butlast: "prefix (butlast xs) xs"
   141 by (simp add: butlast_conv_take take_is_prefix)
   142 
   143 lemma map_prefixI: "prefix xs ys \<Longrightarrow> prefix (map f xs) (map f ys)"
   144   by (auto simp: prefix_def)
   145 
   146 lemma prefix_length_less: "strict_prefix xs ys \<Longrightarrow> length xs < length ys"
   147   by (auto simp: strict_prefix_def prefix_def)
   148 
   149 lemma prefix_snocD: "prefix (xs@[x]) ys \<Longrightarrow> strict_prefix xs ys"
   150   by (simp add: strict_prefixI' prefix_order.dual_order.strict_trans1)
   151 
   152 lemma strict_prefix_simps [simp, code]:
   153   "strict_prefix xs [] \<longleftrightarrow> False"
   154   "strict_prefix [] (x # xs) \<longleftrightarrow> True"
   155   "strict_prefix (x # xs) (y # ys) \<longleftrightarrow> x = y \<and> strict_prefix xs ys"
   156   by (simp_all add: strict_prefix_def cong: conj_cong)
   157 
   158 lemma take_strict_prefix: "strict_prefix xs ys \<Longrightarrow> strict_prefix (take n xs) ys"
   159 proof (induct n arbitrary: xs ys)
   160   case 0
   161   then show ?case by (cases ys) simp_all
   162 next
   163   case (Suc n)
   164   then show ?case by (metis prefix_order.less_trans strict_prefixI take_is_prefix)
   165 qed
   166 
   167 lemma not_prefix_cases:
   168   assumes pfx: "\<not> prefix ps ls"
   169   obtains
   170     (c1) "ps \<noteq> []" and "ls = []"
   171   | (c2) a as x xs where "ps = a#as" and "ls = x#xs" and "x = a" and "\<not> prefix as xs"
   172   | (c3) a as x xs where "ps = a#as" and "ls = x#xs" and "x \<noteq> a"
   173 proof (cases ps)
   174   case Nil
   175   then show ?thesis using pfx by simp
   176 next
   177   case (Cons a as)
   178   note c = \<open>ps = a#as\<close>
   179   show ?thesis
   180   proof (cases ls)
   181     case Nil then show ?thesis by (metis append_Nil2 pfx c1 same_prefix_nil)
   182   next
   183     case (Cons x xs)
   184     show ?thesis
   185     proof (cases "x = a")
   186       case True
   187       have "\<not> prefix as xs" using pfx c Cons True by simp
   188       with c Cons True show ?thesis by (rule c2)
   189     next
   190       case False
   191       with c Cons show ?thesis by (rule c3)
   192     qed
   193   qed
   194 qed
   195 
   196 lemma not_prefix_induct [consumes 1, case_names Nil Neq Eq]:
   197   assumes np: "\<not> prefix ps ls"
   198     and base: "\<And>x xs. P (x#xs) []"
   199     and r1: "\<And>x xs y ys. x \<noteq> y \<Longrightarrow> P (x#xs) (y#ys)"
   200     and r2: "\<And>x xs y ys. \<lbrakk> x = y; \<not> prefix xs ys; P xs ys \<rbrakk> \<Longrightarrow> P (x#xs) (y#ys)"
   201   shows "P ps ls" using np
   202 proof (induct ls arbitrary: ps)
   203   case Nil
   204   then show ?case
   205     by (auto simp: neq_Nil_conv elim!: not_prefix_cases intro!: base)
   206 next
   207   case (Cons y ys)
   208   then have npfx: "\<not> prefix ps (y # ys)" by simp
   209   then obtain x xs where pv: "ps = x # xs"
   210     by (rule not_prefix_cases) auto
   211   show ?case by (metis Cons.hyps Cons_prefix_Cons npfx pv r1 r2)
   212 qed
   213 
   214 
   215 subsection \<open>Prefixes\<close>
   216 
   217 fun prefixes where
   218 "prefixes [] = [[]]" |
   219 "prefixes (x#xs) = [] # map (op # x) (prefixes xs)"
   220 
   221 lemma in_set_prefixes[simp]: "xs \<in> set (prefixes ys) \<longleftrightarrow> prefix xs ys"
   222 proof (induct xs arbitrary: ys)
   223   case Nil
   224   then show ?case by (cases ys) auto
   225 next
   226   case (Cons a xs)
   227   then show ?case by (cases ys) auto
   228 qed
   229 
   230 lemma length_prefixes[simp]: "length (prefixes xs) = length xs+1"
   231   by (induction xs) auto
   232     
   233 lemma distinct_prefixes [intro]: "distinct (prefixes xs)"
   234   by (induction xs) (auto simp: distinct_map)
   235 
   236 lemma prefixes_snoc [simp]: "prefixes (xs@[x]) = prefixes xs @ [xs@[x]]"
   237   by (induction xs) auto
   238 
   239 lemma prefixes_not_Nil [simp]: "prefixes xs \<noteq> []"
   240   by (cases xs) auto
   241 
   242 lemma hd_prefixes [simp]: "hd (prefixes xs) = []"
   243   by (cases xs) simp_all
   244 
   245 lemma last_prefixes [simp]: "last (prefixes xs) = xs"
   246   by (induction xs) (simp_all add: last_map)
   247     
   248 lemma prefixes_append: 
   249   "prefixes (xs @ ys) = prefixes xs @ map (\<lambda>ys'. xs @ ys') (tl (prefixes ys))"
   250 proof (induction xs)
   251   case Nil
   252   thus ?case by (cases ys) auto
   253 qed simp_all
   254 
   255 lemma prefixes_eq_snoc:
   256   "prefixes ys = xs @ [x] \<longleftrightarrow>
   257   (ys = [] \<and> xs = [] \<or> (\<exists>z zs. ys = zs@[z] \<and> xs = prefixes zs)) \<and> x = ys"
   258   by (cases ys rule: rev_cases) auto
   259 
   260 lemma prefixes_tailrec [code]: 
   261   "prefixes xs = rev (snd (foldl (\<lambda>(acc1, acc2) x. (x#acc1, rev (x#acc1)#acc2)) ([],[[]]) xs))"
   262 proof -
   263   have "foldl (\<lambda>(acc1, acc2) x. (x#acc1, rev (x#acc1)#acc2)) (ys, rev ys # zs) xs =
   264           (rev xs @ ys, rev (map (\<lambda>as. rev ys @ as) (prefixes xs)) @ zs)" for ys zs
   265   proof (induction xs arbitrary: ys zs)
   266     case (Cons x xs ys zs)
   267     from Cons.IH[of "x # ys" "rev ys # zs"]
   268       show ?case by (simp add: o_def)
   269   qed simp_all
   270   from this [of "[]" "[]"] show ?thesis by simp
   271 qed
   272   
   273 lemma set_prefixes_eq: "set (prefixes xs) = {ys. prefix ys xs}"
   274   by auto
   275 
   276 lemma card_set_prefixes [simp]: "card (set (prefixes xs)) = Suc (length xs)"
   277   by (subst distinct_card) auto
   278 
   279 lemma set_prefixes_append: 
   280   "set (prefixes (xs @ ys)) = set (prefixes xs) \<union> {xs @ ys' |ys'. ys' \<in> set (prefixes ys)}"
   281   by (subst prefixes_append, cases ys) auto
   282 
   283 
   284 subsection \<open>Longest Common Prefix\<close>
   285 
   286 definition Longest_common_prefix :: "'a list set \<Rightarrow> 'a list" where
   287 "Longest_common_prefix L = (GREATEST ps WRT length. \<forall>xs \<in> L. prefix ps xs)"
   288 
   289 lemma Longest_common_prefix_ex: "L \<noteq> {} \<Longrightarrow>
   290   \<exists>ps. (\<forall>xs \<in> L. prefix ps xs) \<and> (\<forall>qs. (\<forall>xs \<in> L. prefix qs xs) \<longrightarrow> size qs \<le> size ps)"
   291   (is "_ \<Longrightarrow> \<exists>ps. ?P L ps")
   292 proof(induction "LEAST n. \<exists>xs \<in>L. n = length xs" arbitrary: L)
   293   case 0
   294   have "[] : L" using "0.hyps" LeastI[of "\<lambda>n. \<exists>xs\<in>L. n = length xs"] \<open>L \<noteq> {}\<close>
   295     by auto
   296   hence "?P L []" by(auto)
   297   thus ?case ..
   298 next
   299   case (Suc n)
   300   let ?EX = "\<lambda>n. \<exists>xs\<in>L. n = length xs"
   301   obtain x xs where xxs: "x#xs \<in> L" "size xs = n" using Suc.prems Suc.hyps(2)
   302     by(metis LeastI_ex[of ?EX] Suc_length_conv ex_in_conv)
   303   hence "[] \<notin> L" using Suc.hyps(2) by auto
   304   show ?case
   305   proof (cases "\<forall>xs \<in> L. \<exists>ys. xs = x#ys")
   306     case True
   307     let ?L = "{ys. x#ys \<in> L}"
   308     have 1: "(LEAST n. \<exists>xs \<in> ?L. n = length xs) = n"
   309       using xxs Suc.prems Suc.hyps(2) Least_le[of "?EX"]
   310       by - (rule Least_equality, fastforce+)
   311     have 2: "?L \<noteq> {}" using \<open>x # xs \<in> L\<close> by auto
   312     from Suc.hyps(1)[OF 1[symmetric] 2] obtain ps where IH: "?P ?L ps" ..
   313     { fix qs
   314       assume "\<forall>qs. (\<forall>xa. x # xa \<in> L \<longrightarrow> prefix qs xa) \<longrightarrow> length qs \<le> length ps"
   315       and "\<forall>xs\<in>L. prefix qs xs"
   316       hence "length (tl qs) \<le> length ps"
   317         by (metis Cons_prefix_Cons hd_Cons_tl list.sel(2) Nil_prefix) 
   318       hence "length qs \<le> Suc (length ps)" by auto
   319     }
   320     hence "?P L (x#ps)" using True IH by auto
   321     thus ?thesis ..
   322   next
   323     case False
   324     then obtain y ys where yys: "x\<noteq>y" "y#ys \<in> L" using \<open>[] \<notin> L\<close>
   325       by (auto) (metis list.exhaust)
   326     have "\<forall>qs. (\<forall>xs\<in>L. prefix qs xs) \<longrightarrow> qs = []" using yys \<open>x#xs \<in> L\<close>
   327       by auto (metis Cons_prefix_Cons prefix_Cons)
   328     hence "?P L []" by auto
   329     thus ?thesis ..
   330   qed
   331 qed
   332 
   333 lemma Longest_common_prefix_unique: "L \<noteq> {} \<Longrightarrow>
   334   \<exists>! ps. (\<forall>xs \<in> L. prefix ps xs) \<and> (\<forall>qs. (\<forall>xs \<in> L. prefix qs xs) \<longrightarrow> size qs \<le> size ps)"
   335 by(rule ex_ex1I[OF Longest_common_prefix_ex];
   336    meson equals0I prefix_length_prefix prefix_order.antisym)
   337 
   338 lemma Longest_common_prefix_eq:
   339  "\<lbrakk> L \<noteq> {};  \<forall>xs \<in> L. prefix ps xs;
   340     \<forall>qs. (\<forall>xs \<in> L. prefix qs xs) \<longrightarrow> size qs \<le> size ps \<rbrakk>
   341   \<Longrightarrow> Longest_common_prefix L = ps"
   342 unfolding Longest_common_prefix_def GreatestM_def
   343 by(rule some1_equality[OF Longest_common_prefix_unique]) auto
   344 
   345 lemma Longest_common_prefix_prefix:
   346   "xs \<in> L \<Longrightarrow> prefix (Longest_common_prefix L) xs"
   347 unfolding Longest_common_prefix_def GreatestM_def
   348 by(rule someI2_ex[OF Longest_common_prefix_ex]) auto
   349 
   350 lemma Longest_common_prefix_longest:
   351   "L \<noteq> {} \<Longrightarrow> \<forall>xs\<in>L. prefix ps xs \<Longrightarrow> length ps \<le> length(Longest_common_prefix L)"
   352 unfolding Longest_common_prefix_def GreatestM_def
   353 by(rule someI2_ex[OF Longest_common_prefix_ex]) auto
   354 
   355 lemma Longest_common_prefix_max_prefix:
   356   "L \<noteq> {} \<Longrightarrow> \<forall>xs\<in>L. prefix ps xs \<Longrightarrow> prefix ps (Longest_common_prefix L)"
   357 by(metis Longest_common_prefix_prefix Longest_common_prefix_longest
   358      prefix_length_prefix ex_in_conv)
   359 
   360 lemma Longest_common_prefix_Nil: "[] \<in> L \<Longrightarrow> Longest_common_prefix L = []"
   361 using Longest_common_prefix_prefix prefix_Nil by blast
   362 
   363 lemma Longest_common_prefix_image_Cons: "L \<noteq> {} \<Longrightarrow>
   364   Longest_common_prefix (op # x ` L) = x # Longest_common_prefix L"
   365 apply(rule Longest_common_prefix_eq)
   366   apply(simp)
   367  apply (simp add: Longest_common_prefix_prefix)
   368 apply simp
   369 by(metis Longest_common_prefix_longest[of L] Cons_prefix_Cons Nitpick.size_list_simp(2)
   370      Suc_le_mono hd_Cons_tl order.strict_implies_order zero_less_Suc)
   371 
   372 lemma Longest_common_prefix_eq_Cons: assumes "L \<noteq> {}" "[] \<notin> L"  "\<forall>xs\<in>L. hd xs = x"
   373 shows "Longest_common_prefix L = x # Longest_common_prefix {ys. x#ys \<in> L}"
   374 proof -
   375   have "L = op # x ` {ys. x#ys \<in> L}" using assms(2,3)
   376     by (auto simp: image_def)(metis hd_Cons_tl)
   377   thus ?thesis
   378     by (metis Longest_common_prefix_image_Cons image_is_empty assms(1))
   379 qed
   380 
   381 lemma Longest_common_prefix_eq_Nil:
   382   "\<lbrakk>x#ys \<in> L; y#zs \<in> L; x \<noteq> y \<rbrakk> \<Longrightarrow> Longest_common_prefix L = []"
   383 by (metis Longest_common_prefix_prefix list.inject prefix_Cons)
   384 
   385 
   386 fun longest_common_prefix :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   387 "longest_common_prefix (x#xs) (y#ys) =
   388   (if x=y then x # longest_common_prefix xs ys else [])" |
   389 "longest_common_prefix _ _ = []"
   390 
   391 lemma longest_common_prefix_prefix1:
   392   "prefix (longest_common_prefix xs ys) xs"
   393 by(induction xs ys rule: longest_common_prefix.induct) auto
   394 
   395 lemma longest_common_prefix_prefix2:
   396   "prefix (longest_common_prefix xs ys) ys"
   397 by(induction xs ys rule: longest_common_prefix.induct) auto
   398 
   399 lemma longest_common_prefix_max_prefix:
   400   "\<lbrakk> prefix ps xs; prefix ps ys \<rbrakk>
   401    \<Longrightarrow> prefix ps (longest_common_prefix xs ys)"
   402 by(induction xs ys arbitrary: ps rule: longest_common_prefix.induct)
   403   (auto simp: prefix_Cons)
   404 
   405 
   406 subsection \<open>Parallel lists\<close>
   407 
   408 definition parallel :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool"  (infixl "\<parallel>" 50)
   409   where "(xs \<parallel> ys) = (\<not> prefix xs ys \<and> \<not> prefix ys xs)"
   410 
   411 lemma parallelI [intro]: "\<not> prefix xs ys \<Longrightarrow> \<not> prefix ys xs \<Longrightarrow> xs \<parallel> ys"
   412   unfolding parallel_def by blast
   413 
   414 lemma parallelE [elim]:
   415   assumes "xs \<parallel> ys"
   416   obtains "\<not> prefix xs ys \<and> \<not> prefix ys xs"
   417   using assms unfolding parallel_def by blast
   418 
   419 theorem prefix_cases:
   420   obtains "prefix xs ys" | "strict_prefix ys xs" | "xs \<parallel> ys"
   421   unfolding parallel_def strict_prefix_def by blast
   422 
   423 theorem parallel_decomp:
   424   "xs \<parallel> ys \<Longrightarrow> \<exists>as b bs c cs. b \<noteq> c \<and> xs = as @ b # bs \<and> ys = as @ c # cs"
   425 proof (induct xs rule: rev_induct)
   426   case Nil
   427   then have False by auto
   428   then show ?case ..
   429 next
   430   case (snoc x xs)
   431   show ?case
   432   proof (rule prefix_cases)
   433     assume le: "prefix xs ys"
   434     then obtain ys' where ys: "ys = xs @ ys'" ..
   435     show ?thesis
   436     proof (cases ys')
   437       assume "ys' = []"
   438       then show ?thesis by (metis append_Nil2 parallelE prefixI snoc.prems ys)
   439     next
   440       fix c cs assume ys': "ys' = c # cs"
   441       have "x \<noteq> c" using snoc.prems ys ys' by fastforce
   442       thus "\<exists>as b bs c cs. b \<noteq> c \<and> xs @ [x] = as @ b # bs \<and> ys = as @ c # cs"
   443         using ys ys' by blast
   444     qed
   445   next
   446     assume "strict_prefix ys xs"
   447     then have "prefix ys (xs @ [x])" by (simp add: strict_prefix_def)
   448     with snoc have False by blast
   449     then show ?thesis ..
   450   next
   451     assume "xs \<parallel> ys"
   452     with snoc obtain as b bs c cs where neq: "(b::'a) \<noteq> c"
   453       and xs: "xs = as @ b # bs" and ys: "ys = as @ c # cs"
   454       by blast
   455     from xs have "xs @ [x] = as @ b # (bs @ [x])" by simp
   456     with neq ys show ?thesis by blast
   457   qed
   458 qed
   459 
   460 lemma parallel_append: "a \<parallel> b \<Longrightarrow> a @ c \<parallel> b @ d"
   461   apply (rule parallelI)
   462     apply (erule parallelE, erule conjE,
   463       induct rule: not_prefix_induct, simp+)+
   464   done
   465 
   466 lemma parallel_appendI: "xs \<parallel> ys \<Longrightarrow> x = xs @ xs' \<Longrightarrow> y = ys @ ys' \<Longrightarrow> x \<parallel> y"
   467   by (simp add: parallel_append)
   468 
   469 lemma parallel_commute: "a \<parallel> b \<longleftrightarrow> b \<parallel> a"
   470   unfolding parallel_def by auto
   471 
   472 
   473 subsection \<open>Suffix order on lists\<close>
   474 
   475 definition suffix :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool"
   476   where "suffix xs ys = (\<exists>zs. ys = zs @ xs)"
   477 
   478 definition strict_suffix :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool"
   479   where "strict_suffix xs ys \<longleftrightarrow> suffix xs ys \<and> xs \<noteq> ys"
   480 
   481 interpretation suffix_order: order suffix strict_suffix
   482   by standard (auto simp: suffix_def strict_suffix_def)
   483 
   484 interpretation suffix_bot: order_bot Nil suffix strict_suffix
   485   by standard (simp add: suffix_def)
   486 
   487 lemma suffixI [intro?]: "ys = zs @ xs \<Longrightarrow> suffix xs ys"
   488   unfolding suffix_def by blast
   489 
   490 lemma suffixE [elim?]:
   491   assumes "suffix xs ys"
   492   obtains zs where "ys = zs @ xs"
   493   using assms unfolding suffix_def by blast
   494 
   495 lemma suffix_tl [simp]: "suffix (tl xs) xs"
   496   by (induct xs) (auto simp: suffix_def)
   497 
   498 lemma strict_suffix_tl [simp]: "xs \<noteq> [] \<Longrightarrow> strict_suffix (tl xs) xs"
   499   by (induct xs) (auto simp: strict_suffix_def suffix_def)
   500 
   501 lemma Nil_suffix [simp]: "suffix [] xs"
   502   by (simp add: suffix_def)
   503 
   504 lemma suffix_Nil [simp]: "(suffix xs []) = (xs = [])"
   505   by (auto simp add: suffix_def)
   506 
   507 lemma suffix_ConsI: "suffix xs ys \<Longrightarrow> suffix xs (y # ys)"
   508   by (auto simp add: suffix_def)
   509 
   510 lemma suffix_ConsD: "suffix (x # xs) ys \<Longrightarrow> suffix xs ys"
   511   by (auto simp add: suffix_def)
   512 
   513 lemma suffix_appendI: "suffix xs ys \<Longrightarrow> suffix xs (zs @ ys)"
   514   by (auto simp add: suffix_def)
   515 
   516 lemma suffix_appendD: "suffix (zs @ xs) ys \<Longrightarrow> suffix xs ys"
   517   by (auto simp add: suffix_def)
   518 
   519 lemma strict_suffix_set_subset: "strict_suffix xs ys \<Longrightarrow> set xs \<subseteq> set ys"
   520   by (auto simp: strict_suffix_def suffix_def)
   521 
   522 lemma suffix_set_subset: "suffix xs ys \<Longrightarrow> set xs \<subseteq> set ys"
   523   by (auto simp: suffix_def)
   524 
   525 lemma suffix_ConsD2: "suffix (x # xs) (y # ys) \<Longrightarrow> suffix xs ys"
   526 proof -
   527   assume "suffix (x # xs) (y # ys)"
   528   then obtain zs where "y # ys = zs @ x # xs" ..
   529   then show ?thesis
   530     by (induct zs) (auto intro!: suffix_appendI suffix_ConsI)
   531 qed
   532 
   533 lemma suffix_to_prefix [code]: "suffix xs ys \<longleftrightarrow> prefix (rev xs) (rev ys)"
   534 proof
   535   assume "suffix xs ys"
   536   then obtain zs where "ys = zs @ xs" ..
   537   then have "rev ys = rev xs @ rev zs" by simp
   538   then show "prefix (rev xs) (rev ys)" ..
   539 next
   540   assume "prefix (rev xs) (rev ys)"
   541   then obtain zs where "rev ys = rev xs @ zs" ..
   542   then have "rev (rev ys) = rev zs @ rev (rev xs)" by simp
   543   then have "ys = rev zs @ xs" by simp
   544   then show "suffix xs ys" ..
   545 qed
   546   
   547 lemma strict_suffix_to_prefix [code]: "strict_suffix xs ys \<longleftrightarrow> strict_prefix (rev xs) (rev ys)"
   548   by (auto simp: suffix_to_prefix strict_suffix_def strict_prefix_def)
   549 
   550 lemma distinct_suffix: "distinct ys \<Longrightarrow> suffix xs ys \<Longrightarrow> distinct xs"
   551   by (clarsimp elim!: suffixE)
   552 
   553 lemma suffix_map: "suffix xs ys \<Longrightarrow> suffix (map f xs) (map f ys)"
   554   by (auto elim!: suffixE intro: suffixI)
   555 
   556 lemma suffix_drop: "suffix (drop n as) as"
   557   unfolding suffix_def by (rule exI [where x = "take n as"]) simp
   558 
   559 lemma suffix_take: "suffix xs ys \<Longrightarrow> ys = take (length ys - length xs) ys @ xs"
   560   by (auto elim!: suffixE)
   561 
   562 lemma strict_suffix_reflclp_conv: "strict_suffix\<^sup>=\<^sup>= = suffix"
   563   by (intro ext) (auto simp: suffix_def strict_suffix_def)
   564 
   565 lemma suffix_lists: "suffix xs ys \<Longrightarrow> ys \<in> lists A \<Longrightarrow> xs \<in> lists A"
   566   unfolding suffix_def by auto
   567 
   568 lemma suffix_snoc [simp]: "suffix xs (ys @ [y]) \<longleftrightarrow> xs = [] \<or> (\<exists>zs. xs = zs @ [y] \<and> suffix zs ys)"
   569   by (cases xs rule: rev_cases) (auto simp: suffix_def)
   570 
   571 lemma snoc_suffix_snoc [simp]: "suffix (xs @ [x]) (ys @ [y]) = (x = y \<and> suffix xs ys)"
   572   by (auto simp add: suffix_def)
   573 
   574 lemma same_suffix_suffix [simp]: "suffix (ys @ xs) (zs @ xs) = suffix ys zs"
   575   by (simp add: suffix_to_prefix)
   576 
   577 lemma same_suffix_nil [simp]: "suffix (ys @ xs) xs = (ys = [])"
   578   by (simp add: suffix_to_prefix)
   579 
   580 theorem suffix_Cons: "suffix xs (y # ys) \<longleftrightarrow> xs = y # ys \<or> suffix xs ys"
   581   unfolding suffix_def by (auto simp: Cons_eq_append_conv)
   582 
   583 theorem suffix_append: 
   584   "suffix xs (ys @ zs) \<longleftrightarrow> suffix xs zs \<or> (\<exists>xs'. xs = xs' @ zs \<and> suffix xs' ys)"
   585   by (auto simp: suffix_def append_eq_append_conv2)
   586 
   587 theorem suffix_length_le: "suffix xs ys \<Longrightarrow> length xs \<le> length ys"
   588   by (auto simp add: suffix_def)
   589 
   590 lemma suffix_same_cases:
   591   "suffix (xs\<^sub>1::'a list) ys \<Longrightarrow> suffix xs\<^sub>2 ys \<Longrightarrow> suffix xs\<^sub>1 xs\<^sub>2 \<or> suffix xs\<^sub>2 xs\<^sub>1"
   592   unfolding suffix_def by (force simp: append_eq_append_conv2)
   593 
   594 lemma suffix_length_suffix:
   595   "suffix ps xs \<Longrightarrow> suffix qs xs \<Longrightarrow> length ps \<le> length qs \<Longrightarrow> suffix ps qs"
   596   by (auto simp: suffix_to_prefix intro: prefix_length_prefix)
   597 
   598 lemma suffix_length_less: "strict_suffix xs ys \<Longrightarrow> length xs < length ys"
   599   by (auto simp: strict_suffix_def suffix_def)
   600 
   601 lemma suffix_ConsD': "suffix (x#xs) ys \<Longrightarrow> strict_suffix xs ys"
   602   by (auto simp: strict_suffix_def suffix_def)
   603 
   604 lemma drop_strict_suffix: "strict_suffix xs ys \<Longrightarrow> strict_suffix (drop n xs) ys"
   605 proof (induct n arbitrary: xs ys)
   606   case 0
   607   then show ?case by (cases ys) simp_all
   608 next
   609   case (Suc n)
   610   then show ?case 
   611     by (cases xs) (auto intro: Suc dest: suffix_ConsD' suffix_order.less_imp_le)
   612 qed
   613 
   614 lemma not_suffix_cases:
   615   assumes pfx: "\<not> suffix ps ls"
   616   obtains
   617     (c1) "ps \<noteq> []" and "ls = []"
   618   | (c2) a as x xs where "ps = as@[a]" and "ls = xs@[x]" and "x = a" and "\<not> suffix as xs"
   619   | (c3) a as x xs where "ps = as@[a]" and "ls = xs@[x]" and "x \<noteq> a"
   620 proof (cases ps rule: rev_cases)
   621   case Nil
   622   then show ?thesis using pfx by simp
   623 next
   624   case (snoc as a)
   625   note c = \<open>ps = as@[a]\<close>
   626   show ?thesis
   627   proof (cases ls rule: rev_cases)
   628     case Nil then show ?thesis by (metis append_Nil2 pfx c1 same_suffix_nil)
   629   next
   630     case (snoc xs x)
   631     show ?thesis
   632     proof (cases "x = a")
   633       case True
   634       have "\<not> suffix as xs" using pfx c snoc True by simp
   635       with c snoc True show ?thesis by (rule c2)
   636     next
   637       case False
   638       with c snoc show ?thesis by (rule c3)
   639     qed
   640   qed
   641 qed
   642 
   643 lemma not_suffix_induct [consumes 1, case_names Nil Neq Eq]:
   644   assumes np: "\<not> suffix ps ls"
   645     and base: "\<And>x xs. P (xs@[x]) []"
   646     and r1: "\<And>x xs y ys. x \<noteq> y \<Longrightarrow> P (xs@[x]) (ys@[y])"
   647     and r2: "\<And>x xs y ys. \<lbrakk> x = y; \<not> suffix xs ys; P xs ys \<rbrakk> \<Longrightarrow> P (xs@[x]) (ys@[y])"
   648   shows "P ps ls" using np
   649 proof (induct ls arbitrary: ps rule: rev_induct)
   650   case Nil
   651   then show ?case by (cases ps rule: rev_cases) (auto intro: base)
   652 next
   653   case (snoc y ys ps)
   654   then have npfx: "\<not> suffix ps (ys @ [y])" by simp
   655   then obtain x xs where pv: "ps = xs @ [x]"
   656     by (rule not_suffix_cases) auto
   657   show ?case by (metis snoc.hyps snoc_suffix_snoc npfx pv r1 r2)
   658 qed
   659 
   660 
   661 lemma parallelD1: "x \<parallel> y \<Longrightarrow> \<not> prefix x y"
   662   by blast
   663 
   664 lemma parallelD2: "x \<parallel> y \<Longrightarrow> \<not> prefix y x"
   665   by blast
   666 
   667 lemma parallel_Nil1 [simp]: "\<not> x \<parallel> []"
   668   unfolding parallel_def by simp
   669 
   670 lemma parallel_Nil2 [simp]: "\<not> [] \<parallel> x"
   671   unfolding parallel_def by simp
   672 
   673 lemma Cons_parallelI1: "a \<noteq> b \<Longrightarrow> a # as \<parallel> b # bs"
   674   by auto
   675 
   676 lemma Cons_parallelI2: "\<lbrakk> a = b; as \<parallel> bs \<rbrakk> \<Longrightarrow> a # as \<parallel> b # bs"
   677   by (metis Cons_prefix_Cons parallelE parallelI)
   678 
   679 lemma not_equal_is_parallel:
   680   assumes neq: "xs \<noteq> ys"
   681     and len: "length xs = length ys"
   682   shows "xs \<parallel> ys"
   683   using len neq
   684 proof (induct rule: list_induct2)
   685   case Nil
   686   then show ?case by simp
   687 next
   688   case (Cons a as b bs)
   689   have ih: "as \<noteq> bs \<Longrightarrow> as \<parallel> bs" by fact
   690   show ?case
   691   proof (cases "a = b")
   692     case True
   693     then have "as \<noteq> bs" using Cons by simp
   694     then show ?thesis by (rule Cons_parallelI2 [OF True ih])
   695   next
   696     case False
   697     then show ?thesis by (rule Cons_parallelI1)
   698   qed
   699 qed
   700 
   701 subsection \<open>Suffixes\<close>
   702 
   703 fun suffixes where
   704   "suffixes [] = [[]]"
   705 | "suffixes (x#xs) = suffixes xs @ [x # xs]"
   706 
   707 lemma in_set_suffixes [simp]: "xs \<in> set (suffixes ys) \<longleftrightarrow> suffix xs ys"
   708   by (induction ys) (auto simp: suffix_def Cons_eq_append_conv)
   709 
   710 lemma distinct_suffixes [intro]: "distinct (suffixes xs)"
   711   by (induction xs) (auto simp: suffix_def)
   712 
   713 lemma length_suffixes [simp]: "length (suffixes xs) = Suc (length xs)"
   714   by (induction xs) auto
   715 
   716 lemma suffixes_snoc [simp]: "suffixes (xs @ [x]) = [] # map (\<lambda>ys. ys @ [x]) (suffixes xs)"
   717   by (induction xs) auto
   718 
   719 lemma suffixes_not_Nil [simp]: "suffixes xs \<noteq> []"
   720   by (cases xs) auto
   721 
   722 lemma hd_suffixes [simp]: "hd (suffixes xs) = []"
   723   by (induction xs) simp_all
   724 
   725 lemma last_suffixes [simp]: "last (suffixes xs) = xs"
   726   by (cases xs) simp_all
   727 
   728 lemma suffixes_append: 
   729   "suffixes (xs @ ys) = suffixes ys @ map (\<lambda>xs'. xs' @ ys) (tl (suffixes xs))"
   730 proof (induction ys rule: rev_induct)
   731   case Nil
   732   thus ?case by (cases xs rule: rev_cases) auto
   733 next
   734   case (snoc y ys)
   735   show ?case
   736     by (simp only: append.assoc [symmetric] suffixes_snoc snoc.IH) simp
   737 qed
   738 
   739 lemma suffixes_eq_snoc:
   740   "suffixes ys = xs @ [x] \<longleftrightarrow>
   741      (ys = [] \<and> xs = [] \<or> (\<exists>z zs. ys = z#zs \<and> xs = suffixes zs)) \<and> x = ys"
   742   by (cases ys) auto
   743 
   744 lemma suffixes_tailrec [code]: 
   745   "suffixes xs = rev (snd (foldl (\<lambda>(acc1, acc2) x. (x#acc1, (x#acc1)#acc2)) ([],[[]]) (rev xs)))"
   746 proof -
   747   have "foldl (\<lambda>(acc1, acc2) x. (x#acc1, (x#acc1)#acc2)) (ys, ys # zs) (rev xs) =
   748           (xs @ ys, rev (map (\<lambda>as. as @ ys) (suffixes xs)) @ zs)" for ys zs
   749   proof (induction xs arbitrary: ys zs)
   750     case (Cons x xs ys zs)
   751     from Cons.IH[of ys zs]
   752       show ?case by (simp add: o_def case_prod_unfold)
   753   qed simp_all
   754   from this [of "[]" "[]"] show ?thesis by simp
   755 qed
   756   
   757 lemma set_suffixes_eq: "set (suffixes xs) = {ys. suffix ys xs}"
   758   by auto
   759     
   760 lemma card_set_suffixes [simp]: "card (set (suffixes xs)) = Suc (length xs)"
   761   by (subst distinct_card) auto
   762   
   763 lemma set_suffixes_append: 
   764   "set (suffixes (xs @ ys)) = set (suffixes ys) \<union> {xs' @ ys |xs'. xs' \<in> set (suffixes xs)}"
   765   by (subst suffixes_append, cases xs rule: rev_cases) auto
   766 
   767 
   768 lemma suffixes_conv_prefixes: "suffixes xs = map rev (prefixes (rev xs))"
   769   by (induction xs) auto
   770 
   771 lemma prefixes_conv_suffixes: "prefixes xs = map rev (suffixes (rev xs))"
   772   by (induction xs) auto
   773     
   774 lemma prefixes_rev: "prefixes (rev xs) = map rev (suffixes xs)"
   775   by (induction xs) auto
   776     
   777 lemma suffixes_rev: "suffixes (rev xs) = map rev (prefixes xs)"
   778   by (induction xs) auto
   779 
   780 
   781 subsection \<open>Homeomorphic embedding on lists\<close>
   782 
   783 inductive list_emb :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list \<Rightarrow> bool"
   784   for P :: "('a \<Rightarrow> 'a \<Rightarrow> bool)"
   785 where
   786   list_emb_Nil [intro, simp]: "list_emb P [] ys"
   787 | list_emb_Cons [intro] : "list_emb P xs ys \<Longrightarrow> list_emb P xs (y#ys)"
   788 | list_emb_Cons2 [intro]: "P x y \<Longrightarrow> list_emb P xs ys \<Longrightarrow> list_emb P (x#xs) (y#ys)"
   789 
   790 lemma list_emb_mono:                         
   791   assumes "\<And>x y. P x y \<longrightarrow> Q x y"
   792   shows "list_emb P xs ys \<longrightarrow> list_emb Q xs ys"
   793 proof                                        
   794   assume "list_emb P xs ys"                    
   795   then show "list_emb Q xs ys" by (induct) (auto simp: assms)
   796 qed 
   797 
   798 lemma list_emb_Nil2 [simp]:
   799   assumes "list_emb P xs []" shows "xs = []"
   800   using assms by (cases rule: list_emb.cases) auto
   801 
   802 lemma list_emb_refl:
   803   assumes "\<And>x. x \<in> set xs \<Longrightarrow> P x x"
   804   shows "list_emb P xs xs"
   805   using assms by (induct xs) auto
   806 
   807 lemma list_emb_Cons_Nil [simp]: "list_emb P (x#xs) [] = False"
   808 proof -
   809   { assume "list_emb P (x#xs) []"
   810     from list_emb_Nil2 [OF this] have False by simp
   811   } moreover {
   812     assume False
   813     then have "list_emb P (x#xs) []" by simp
   814   } ultimately show ?thesis by blast
   815 qed
   816 
   817 lemma list_emb_append2 [intro]: "list_emb P xs ys \<Longrightarrow> list_emb P xs (zs @ ys)"
   818   by (induct zs) auto
   819 
   820 lemma list_emb_prefix [intro]:
   821   assumes "list_emb P xs ys" shows "list_emb P xs (ys @ zs)"
   822   using assms
   823   by (induct arbitrary: zs) auto
   824 
   825 lemma list_emb_ConsD:
   826   assumes "list_emb P (x#xs) ys"
   827   shows "\<exists>us v vs. ys = us @ v # vs \<and> P x v \<and> list_emb P xs vs"
   828 using assms
   829 proof (induct x \<equiv> "x # xs" ys arbitrary: x xs)
   830   case list_emb_Cons
   831   then show ?case by (metis append_Cons)
   832 next
   833   case (list_emb_Cons2 x y xs ys)
   834   then show ?case by blast
   835 qed
   836 
   837 lemma list_emb_appendD:
   838   assumes "list_emb P (xs @ ys) zs"
   839   shows "\<exists>us vs. zs = us @ vs \<and> list_emb P xs us \<and> list_emb P ys vs"
   840 using assms
   841 proof (induction xs arbitrary: ys zs)
   842   case Nil then show ?case by auto
   843 next
   844   case (Cons x xs)
   845   then obtain us v vs where
   846     zs: "zs = us @ v # vs" and p: "P x v" and lh: "list_emb P (xs @ ys) vs"
   847     by (auto dest: list_emb_ConsD)
   848   obtain sk\<^sub>0 :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list" and sk\<^sub>1 :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   849     sk: "\<forall>x\<^sub>0 x\<^sub>1. \<not> list_emb P (xs @ x\<^sub>0) x\<^sub>1 \<or> sk\<^sub>0 x\<^sub>0 x\<^sub>1 @ sk\<^sub>1 x\<^sub>0 x\<^sub>1 = x\<^sub>1 \<and> list_emb P xs (sk\<^sub>0 x\<^sub>0 x\<^sub>1) \<and> list_emb P x\<^sub>0 (sk\<^sub>1 x\<^sub>0 x\<^sub>1)"
   850     using Cons(1) by (metis (no_types))
   851   hence "\<forall>x\<^sub>2. list_emb P (x # xs) (x\<^sub>2 @ v # sk\<^sub>0 ys vs)" using p lh by auto
   852   thus ?case using lh zs sk by (metis (no_types) append_Cons append_assoc)
   853 qed
   854 
   855 lemma list_emb_strict_suffix:
   856   assumes "list_emb P xs ys" and "strict_suffix ys zs"
   857   shows "list_emb P xs zs"
   858   using assms(2) and list_emb_append2 [OF assms(1)] by (auto simp: strict_suffix_def suffix_def)
   859 
   860 lemma list_emb_suffix:
   861   assumes "list_emb P xs ys" and "suffix ys zs"
   862   shows "list_emb P xs zs"
   863 using assms and list_emb_strict_suffix
   864 unfolding strict_suffix_reflclp_conv[symmetric] by auto
   865 
   866 lemma list_emb_length: "list_emb P xs ys \<Longrightarrow> length xs \<le> length ys"
   867   by (induct rule: list_emb.induct) auto
   868 
   869 lemma list_emb_trans:
   870   assumes "\<And>x y z. \<lbrakk>x \<in> set xs; y \<in> set ys; z \<in> set zs; P x y; P y z\<rbrakk> \<Longrightarrow> P x z"
   871   shows "\<lbrakk>list_emb P xs ys; list_emb P ys zs\<rbrakk> \<Longrightarrow> list_emb P xs zs"
   872 proof -
   873   assume "list_emb P xs ys" and "list_emb P ys zs"
   874   then show "list_emb P xs zs" using assms
   875   proof (induction arbitrary: zs)
   876     case list_emb_Nil show ?case by blast
   877   next
   878     case (list_emb_Cons xs ys y)
   879     from list_emb_ConsD [OF \<open>list_emb P (y#ys) zs\<close>] obtain us v vs
   880       where zs: "zs = us @ v # vs" and "P\<^sup>=\<^sup>= y v" and "list_emb P ys vs" by blast
   881     then have "list_emb P ys (v#vs)" by blast
   882     then have "list_emb P ys zs" unfolding zs by (rule list_emb_append2)
   883     from list_emb_Cons.IH [OF this] and list_emb_Cons.prems show ?case by auto
   884   next
   885     case (list_emb_Cons2 x y xs ys)
   886     from list_emb_ConsD [OF \<open>list_emb P (y#ys) zs\<close>] obtain us v vs
   887       where zs: "zs = us @ v # vs" and "P y v" and "list_emb P ys vs" by blast
   888     with list_emb_Cons2 have "list_emb P xs vs" by auto
   889     moreover have "P x v"
   890     proof -
   891       from zs have "v \<in> set zs" by auto
   892       moreover have "x \<in> set (x#xs)" and "y \<in> set (y#ys)" by simp_all
   893       ultimately show ?thesis
   894         using \<open>P x y\<close> and \<open>P y v\<close> and list_emb_Cons2
   895         by blast
   896     qed
   897     ultimately have "list_emb P (x#xs) (v#vs)" by blast
   898     then show ?case unfolding zs by (rule list_emb_append2)
   899   qed
   900 qed
   901 
   902 lemma list_emb_set:
   903   assumes "list_emb P xs ys" and "x \<in> set xs"
   904   obtains y where "y \<in> set ys" and "P x y"
   905   using assms by (induct) auto
   906 
   907 lemma list_emb_Cons_iff1 [simp]:
   908   assumes "P x y"
   909   shows   "list_emb P (x#xs) (y#ys) \<longleftrightarrow> list_emb P xs ys"
   910   using assms by (subst list_emb.simps) (auto dest: list_emb_ConsD)
   911 
   912 lemma list_emb_Cons_iff2 [simp]:
   913   assumes "\<not>P x y"
   914   shows   "list_emb P (x#xs) (y#ys) \<longleftrightarrow> list_emb P (x#xs) ys"
   915   using assms by (subst list_emb.simps) auto
   916 
   917 lemma list_emb_code [code]:
   918   "list_emb P [] ys \<longleftrightarrow> True"
   919   "list_emb P (x#xs) [] \<longleftrightarrow> False"
   920   "list_emb P (x#xs) (y#ys) \<longleftrightarrow> (if P x y then list_emb P xs ys else list_emb P (x#xs) ys)"
   921   by simp_all
   922   
   923 
   924 
   925 subsection \<open>Sublists (special case of homeomorphic embedding)\<close>
   926 
   927 abbreviation sublisteq :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool"
   928   where "sublisteq xs ys \<equiv> list_emb (op =) xs ys"
   929   
   930 definition strict_sublist where "strict_sublist xs ys \<longleftrightarrow> xs \<noteq> ys \<and> sublisteq xs ys"
   931 
   932 lemma sublisteq_Cons2: "sublisteq xs ys \<Longrightarrow> sublisteq (x#xs) (x#ys)" by auto
   933 
   934 lemma sublisteq_same_length:
   935   assumes "sublisteq xs ys" and "length xs = length ys" shows "xs = ys"
   936   using assms by (induct) (auto dest: list_emb_length)
   937 
   938 lemma not_sublisteq_length [simp]: "length ys < length xs \<Longrightarrow> \<not> sublisteq xs ys"
   939   by (metis list_emb_length linorder_not_less)
   940 
   941 lemma sublisteq_Cons': "sublisteq (x#xs) ys \<Longrightarrow> sublisteq xs ys"
   942   by (induct xs, simp, blast dest: list_emb_ConsD)
   943 
   944 lemma sublisteq_Cons2':
   945   assumes "sublisteq (x#xs) (x#ys)" shows "sublisteq xs ys"
   946   using assms by (cases) (rule sublisteq_Cons')
   947 
   948 lemma sublisteq_Cons2_neq:
   949   assumes "sublisteq (x#xs) (y#ys)"
   950   shows "x \<noteq> y \<Longrightarrow> sublisteq (x#xs) ys"
   951   using assms by (cases) auto
   952 
   953 lemma sublisteq_Cons2_iff [simp]:
   954   "sublisteq (x#xs) (y#ys) = (if x = y then sublisteq xs ys else sublisteq (x#xs) ys)"
   955   by simp
   956 
   957 lemma sublisteq_append': "sublisteq (zs @ xs) (zs @ ys) \<longleftrightarrow> sublisteq xs ys"
   958   by (induct zs) simp_all
   959     
   960 interpretation sublist_order: order sublisteq strict_sublist
   961 proof
   962   fix xs ys :: "'a list"
   963   {
   964     assume "sublisteq xs ys" and "sublisteq ys xs"
   965     thus "xs = ys"
   966     proof (induct)
   967       case list_emb_Nil
   968       from list_emb_Nil2 [OF this] show ?case by simp
   969     next
   970       case list_emb_Cons2
   971       thus ?case by simp
   972     next
   973       case list_emb_Cons
   974       hence False using sublisteq_Cons' by fastforce
   975       thus ?case ..
   976     qed
   977   }
   978   thus "strict_sublist xs ys \<longleftrightarrow> (sublisteq xs ys \<and> \<not>sublisteq ys xs)"
   979     by (auto simp: strict_sublist_def)
   980 qed (auto simp: list_emb_refl intro: list_emb_trans)
   981 
   982 lemma in_set_sublists [simp]: "xs \<in> set (sublists ys) \<longleftrightarrow> sublisteq xs ys"
   983 proof
   984   assume "xs \<in> set (sublists ys)"
   985   thus "sublisteq xs ys"
   986     by (induction ys arbitrary: xs) (auto simp: Let_def)
   987 next
   988   have [simp]: "[] \<in> set (sublists ys)" for ys :: "'a list" 
   989     by (induction ys) (auto simp: Let_def)
   990   assume "sublisteq xs ys"
   991   thus "xs \<in> set (sublists ys)"
   992     by (induction xs ys rule: list_emb.induct) (auto simp: Let_def)
   993 qed
   994 
   995 lemma set_sublists_eq: "set (sublists ys) = {xs. sublisteq xs ys}"
   996   by auto
   997 
   998 lemma sublisteq_append_le_same_iff: "sublisteq (xs @ ys) ys \<longleftrightarrow> xs = []"
   999   by (auto dest: list_emb_length)
  1000 
  1001 lemma sublisteq_singleton_left: "sublisteq [x] ys \<longleftrightarrow> x \<in> set ys"
  1002   by (fastforce dest: list_emb_ConsD split_list_last)
  1003 
  1004 lemma list_emb_append_mono:
  1005   "\<lbrakk> list_emb P xs xs'; list_emb P ys ys' \<rbrakk> \<Longrightarrow> list_emb P (xs@ys) (xs'@ys')"
  1006   apply (induct rule: list_emb.induct)
  1007     apply (metis eq_Nil_appendI list_emb_append2)
  1008    apply (metis append_Cons list_emb_Cons)
  1009   apply (metis append_Cons list_emb_Cons2)
  1010   done
  1011 
  1012 
  1013 subsection \<open>Appending elements\<close>
  1014 
  1015 lemma sublisteq_append [simp]:
  1016   "sublisteq (xs @ zs) (ys @ zs) \<longleftrightarrow> sublisteq xs ys" (is "?l = ?r")
  1017 proof
  1018   { fix xs' ys' xs ys zs :: "'a list" assume "sublisteq xs' ys'"
  1019     then have "xs' = xs @ zs & ys' = ys @ zs \<longrightarrow> sublisteq xs ys"
  1020     proof (induct arbitrary: xs ys zs)
  1021       case list_emb_Nil show ?case by simp
  1022     next
  1023       case (list_emb_Cons xs' ys' x)
  1024       { assume "ys=[]" then have ?case using list_emb_Cons(1) by auto }
  1025       moreover
  1026       { fix us assume "ys = x#us"
  1027         then have ?case using list_emb_Cons(2) by(simp add: list_emb.list_emb_Cons) }
  1028       ultimately show ?case by (auto simp:Cons_eq_append_conv)
  1029     next
  1030       case (list_emb_Cons2 x y xs' ys')
  1031       { assume "xs=[]" then have ?case using list_emb_Cons2(1) by auto }
  1032       moreover
  1033       { fix us vs assume "xs=x#us" "ys=x#vs" then have ?case using list_emb_Cons2 by auto}
  1034       moreover
  1035       { fix us assume "xs=x#us" "ys=[]" then have ?case using list_emb_Cons2(2) by bestsimp }
  1036       ultimately show ?case using \<open>op = x y\<close> by (auto simp: Cons_eq_append_conv)
  1037     qed }
  1038   moreover assume ?l
  1039   ultimately show ?r by blast
  1040 next
  1041   assume ?r then show ?l by (metis list_emb_append_mono sublist_order.order_refl)
  1042 qed
  1043 
  1044 lemma sublisteq_append_iff: 
  1045   "sublisteq xs (ys @ zs) \<longleftrightarrow> (\<exists>xs1 xs2. xs = xs1 @ xs2 \<and> sublisteq xs1 ys \<and> sublisteq xs2 zs)"
  1046   (is "?lhs = ?rhs")
  1047 proof
  1048   assume ?lhs thus ?rhs
  1049   proof (induction xs "ys @ zs" arbitrary: ys zs rule: list_emb.induct)
  1050     case (list_emb_Cons xs ws y ys zs)
  1051     from list_emb_Cons(2)[of "tl ys" zs] and list_emb_Cons(2)[of "[]" "tl zs"] and list_emb_Cons(1,3)
  1052       show ?case by (cases ys) auto
  1053   next
  1054     case (list_emb_Cons2 x y xs ws ys zs)
  1055     from list_emb_Cons2(3)[of "tl ys" zs] and list_emb_Cons2(3)[of "[]" "tl zs"]
  1056        and list_emb_Cons2(1,2,4)
  1057     show ?case by (cases ys) (auto simp: Cons_eq_append_conv)
  1058   qed auto
  1059 qed (auto intro: list_emb_append_mono)
  1060 
  1061 lemma sublisteq_appendE [case_names append]: 
  1062   assumes "sublisteq xs (ys @ zs)"
  1063   obtains xs1 xs2 where "xs = xs1 @ xs2" "sublisteq xs1 ys" "sublisteq xs2 zs"
  1064   using assms by (subst (asm) sublisteq_append_iff) auto
  1065 
  1066 lemma sublisteq_drop_many: "sublisteq xs ys \<Longrightarrow> sublisteq xs (zs @ ys)"
  1067   by (induct zs) auto
  1068 
  1069 lemma sublisteq_rev_drop_many: "sublisteq xs ys \<Longrightarrow> sublisteq xs (ys @ zs)"
  1070   by (metis append_Nil2 list_emb_Nil list_emb_append_mono)
  1071 
  1072 
  1073 subsection \<open>Relation to standard list operations\<close>
  1074 
  1075 lemma sublisteq_map:
  1076   assumes "sublisteq xs ys" shows "sublisteq (map f xs) (map f ys)"
  1077   using assms by (induct) auto
  1078 
  1079 lemma sublisteq_filter_left [simp]: "sublisteq (filter P xs) xs"
  1080   by (induct xs) auto
  1081 
  1082 lemma sublisteq_filter [simp]:
  1083   assumes "sublisteq xs ys" shows "sublisteq (filter P xs) (filter P ys)"
  1084   using assms by induct auto
  1085 
  1086 lemma "sublisteq xs ys \<longleftrightarrow> (\<exists>N. xs = sublist ys N)" (is "?L = ?R")
  1087 proof
  1088   assume ?L
  1089   then show ?R
  1090   proof (induct)
  1091     case list_emb_Nil show ?case by (metis sublist_empty)
  1092   next
  1093     case (list_emb_Cons xs ys x)
  1094     then obtain N where "xs = sublist ys N" by blast
  1095     then have "xs = sublist (x#ys) (Suc ` N)"
  1096       by (clarsimp simp add:sublist_Cons inj_image_mem_iff)
  1097     then show ?case by blast
  1098   next
  1099     case (list_emb_Cons2 x y xs ys)
  1100     then obtain N where "xs = sublist ys N" by blast
  1101     then have "x#xs = sublist (x#ys) (insert 0 (Suc ` N))"
  1102       by (clarsimp simp add:sublist_Cons inj_image_mem_iff)
  1103     moreover from list_emb_Cons2 have "x = y" by simp
  1104     ultimately show ?case by blast
  1105   qed
  1106 next
  1107   assume ?R
  1108   then obtain N where "xs = sublist ys N" ..
  1109   moreover have "sublisteq (sublist ys N) ys"
  1110   proof (induct ys arbitrary: N)
  1111     case Nil show ?case by simp
  1112   next
  1113     case Cons then show ?case by (auto simp: sublist_Cons)
  1114   qed
  1115   ultimately show ?L by simp
  1116 qed
  1117 
  1118 end