src/HOL/Fun.thy
author haftmann
Mon Dec 06 09:19:10 2010 +0100 (2010-12-06)
changeset 40968 a6fcd305f7dc
parent 40719 acb830207103
child 40969 fb2d3ccda5a7
permissions -rw-r--r--
replace `type_mapper` by the more adequate `type_lifting`
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattice
    10 begin
    11 
    12 text{*As a simplification rule, it replaces all function equalities by
    13   first-order equalities.*}
    14 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    15 apply (rule iffI)
    16 apply (simp (no_asm_simp))
    17 apply (rule ext)
    18 apply (simp (no_asm_simp))
    19 done
    20 
    21 lemma apply_inverse:
    22   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    23   by auto
    24 
    25 
    26 subsection {* The Identity Function @{text id} *}
    27 
    28 definition
    29   id :: "'a \<Rightarrow> 'a"
    30 where
    31   "id = (\<lambda>x. x)"
    32 
    33 lemma id_apply [simp]: "id x = x"
    34   by (simp add: id_def)
    35 
    36 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    37 by blast
    38 
    39 lemma image_id [simp]: "id ` Y = Y"
    40 by (simp add: id_def)
    41 
    42 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    43 by blast
    44 
    45 lemma vimage_id [simp]: "id -` A = A"
    46 by (simp add: id_def)
    47 
    48 
    49 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    50 
    51 definition
    52   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    53 where
    54   "f o g = (\<lambda>x. f (g x))"
    55 
    56 notation (xsymbols)
    57   comp  (infixl "\<circ>" 55)
    58 
    59 notation (HTML output)
    60   comp  (infixl "\<circ>" 55)
    61 
    62 text{*compatibility*}
    63 lemmas o_def = comp_def
    64 
    65 lemma o_apply [simp]: "(f o g) x = f (g x)"
    66 by (simp add: comp_def)
    67 
    68 lemma o_assoc: "f o (g o h) = f o g o h"
    69 by (simp add: comp_def)
    70 
    71 lemma id_o [simp]: "id o g = g"
    72 by (simp add: comp_def)
    73 
    74 lemma o_id [simp]: "f o id = f"
    75 by (simp add: comp_def)
    76 
    77 lemma o_eq_dest:
    78   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    79   by (simp only: o_def) (fact fun_cong)
    80 
    81 lemma o_eq_elim:
    82   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    83   by (erule meta_mp) (fact o_eq_dest) 
    84 
    85 lemma image_compose: "(f o g) ` r = f`(g`r)"
    86 by (simp add: comp_def, blast)
    87 
    88 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
    89   by auto
    90 
    91 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    92 by (unfold comp_def, blast)
    93 
    94 
    95 subsection {* The Forward Composition Operator @{text fcomp} *}
    96 
    97 definition
    98   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60)
    99 where
   100   "f \<circ>> g = (\<lambda>x. g (f x))"
   101 
   102 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   103   by (simp add: fcomp_def)
   104 
   105 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   106   by (simp add: fcomp_def)
   107 
   108 lemma id_fcomp [simp]: "id \<circ>> g = g"
   109   by (simp add: fcomp_def)
   110 
   111 lemma fcomp_id [simp]: "f \<circ>> id = f"
   112   by (simp add: fcomp_def)
   113 
   114 code_const fcomp
   115   (Eval infixl 1 "#>")
   116 
   117 no_notation fcomp (infixl "\<circ>>" 60)
   118 
   119 
   120 subsection {* Mapping functions *}
   121 
   122 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   123   "map_fun f g h = g \<circ> h \<circ> f"
   124 
   125 lemma map_fun_apply [simp]:
   126   "map_fun f g h x = g (h (f x))"
   127   by (simp add: map_fun_def)
   128 
   129 type_lifting map_fun
   130   by (simp_all add: fun_eq_iff)
   131 
   132 
   133 subsection {* Injectivity and Bijectivity *}
   134 
   135 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   136   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   137 
   138 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   139   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   140 
   141 text{*A common special case: functions injective, surjective or bijective over
   142 the entire domain type.*}
   143 
   144 abbreviation
   145   "inj f \<equiv> inj_on f UNIV"
   146 
   147 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   148   "surj f \<equiv> (range f = UNIV)"
   149 
   150 abbreviation
   151   "bij f \<equiv> bij_betw f UNIV UNIV"
   152 
   153 lemma injI:
   154   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   155   shows "inj f"
   156   using assms unfolding inj_on_def by auto
   157 
   158 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   159   by (unfold inj_on_def, blast)
   160 
   161 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   162 by (simp add: inj_on_def)
   163 
   164 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   165 by (force simp add: inj_on_def)
   166 
   167 lemma inj_on_cong:
   168   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   169 unfolding inj_on_def by auto
   170 
   171 lemma inj_on_strict_subset:
   172   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
   173 unfolding inj_on_def unfolding image_def by blast
   174 
   175 lemma inj_comp:
   176   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   177   by (simp add: inj_on_def)
   178 
   179 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   180   by (simp add: inj_on_def fun_eq_iff)
   181 
   182 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   183 by (simp add: inj_on_eq_iff)
   184 
   185 lemma inj_on_id[simp]: "inj_on id A"
   186   by (simp add: inj_on_def)
   187 
   188 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   189 by (simp add: inj_on_def)
   190 
   191 lemma inj_on_Int: "\<lbrakk>inj_on f A; inj_on f B\<rbrakk> \<Longrightarrow> inj_on f (A \<inter> B)"
   192 unfolding inj_on_def by blast
   193 
   194 lemma inj_on_INTER:
   195   "\<lbrakk>I \<noteq> {}; \<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)\<rbrakk> \<Longrightarrow> inj_on f (\<Inter> i \<in> I. A i)"
   196 unfolding inj_on_def by blast
   197 
   198 lemma inj_on_Inter:
   199   "\<lbrakk>S \<noteq> {}; \<And> A. A \<in> S \<Longrightarrow> inj_on f A\<rbrakk> \<Longrightarrow> inj_on f (Inter S)"
   200 unfolding inj_on_def by blast
   201 
   202 lemma inj_on_UNION_chain:
   203   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   204          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   205   shows "inj_on f (\<Union> i \<in> I. A i)"
   206 proof(unfold inj_on_def UNION_def, auto)
   207   fix i j x y
   208   assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
   209          and ***: "f x = f y"
   210   show "x = y"
   211   proof-
   212     {assume "A i \<le> A j"
   213      with ** have "x \<in> A j" by auto
   214      with INJ * ** *** have ?thesis
   215      by(auto simp add: inj_on_def)
   216     }
   217     moreover
   218     {assume "A j \<le> A i"
   219      with ** have "y \<in> A i" by auto
   220      with INJ * ** *** have ?thesis
   221      by(auto simp add: inj_on_def)
   222     }
   223     ultimately show ?thesis using  CH * by blast
   224   qed
   225 qed
   226 
   227 lemma surj_id: "surj id"
   228 by simp
   229 
   230 lemma bij_id[simp]: "bij id"
   231 by (simp add: bij_betw_def)
   232 
   233 lemma inj_onI:
   234     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   235 by (simp add: inj_on_def)
   236 
   237 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   238 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   239 
   240 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   241 by (unfold inj_on_def, blast)
   242 
   243 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   244 by (blast dest!: inj_onD)
   245 
   246 lemma comp_inj_on:
   247      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   248 by (simp add: comp_def inj_on_def)
   249 
   250 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   251 apply(simp add:inj_on_def image_def)
   252 apply blast
   253 done
   254 
   255 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   256   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   257 apply(unfold inj_on_def)
   258 apply blast
   259 done
   260 
   261 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   262 by (unfold inj_on_def, blast)
   263 
   264 lemma inj_singleton: "inj (%s. {s})"
   265 by (simp add: inj_on_def)
   266 
   267 lemma inj_on_empty[iff]: "inj_on f {}"
   268 by(simp add: inj_on_def)
   269 
   270 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   271 by (unfold inj_on_def, blast)
   272 
   273 lemma inj_on_Un:
   274  "inj_on f (A Un B) =
   275   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   276 apply(unfold inj_on_def)
   277 apply (blast intro:sym)
   278 done
   279 
   280 lemma inj_on_insert[iff]:
   281   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   282 apply(unfold inj_on_def)
   283 apply (blast intro:sym)
   284 done
   285 
   286 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   287 apply(unfold inj_on_def)
   288 apply (blast)
   289 done
   290 
   291 lemma comp_inj_on_iff:
   292   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   293 by(auto simp add: comp_inj_on inj_on_def)
   294 
   295 lemma inj_on_imageI2:
   296   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   297 by(auto simp add: comp_inj_on inj_on_def)
   298 
   299 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   300   by auto
   301 
   302 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   303   using *[symmetric] by auto
   304 
   305 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   306   by (simp add: surj_def)
   307 
   308 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   309   by (simp add: surj_def, blast)
   310 
   311 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   312 apply (simp add: comp_def surj_def, clarify)
   313 apply (drule_tac x = y in spec, clarify)
   314 apply (drule_tac x = x in spec, blast)
   315 done
   316 
   317 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   318   unfolding bij_betw_def by auto
   319 
   320 lemma bij_betw_empty1:
   321   assumes "bij_betw f {} A"
   322   shows "A = {}"
   323 using assms unfolding bij_betw_def by blast
   324 
   325 lemma bij_betw_empty2:
   326   assumes "bij_betw f A {}"
   327   shows "A = {}"
   328 using assms unfolding bij_betw_def by blast
   329 
   330 lemma inj_on_imp_bij_betw:
   331   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   332 unfolding bij_betw_def by simp
   333 
   334 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   335   unfolding bij_betw_def ..
   336 
   337 lemma bijI: "[| inj f; surj f |] ==> bij f"
   338 by (simp add: bij_def)
   339 
   340 lemma bij_is_inj: "bij f ==> inj f"
   341 by (simp add: bij_def)
   342 
   343 lemma bij_is_surj: "bij f ==> surj f"
   344 by (simp add: bij_def)
   345 
   346 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   347 by (simp add: bij_betw_def)
   348 
   349 lemma bij_betw_trans:
   350   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   351 by(auto simp add:bij_betw_def comp_inj_on)
   352 
   353 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   354   by (rule bij_betw_trans)
   355 
   356 lemma bij_betw_comp_iff:
   357   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   358 by(auto simp add: bij_betw_def inj_on_def)
   359 
   360 lemma bij_betw_comp_iff2:
   361   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   362   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   363 using assms
   364 proof(auto simp add: bij_betw_comp_iff)
   365   assume *: "bij_betw (f' \<circ> f) A A''"
   366   thus "bij_betw f A A'"
   367   using IM
   368   proof(auto simp add: bij_betw_def)
   369     assume "inj_on (f' \<circ> f) A"
   370     thus "inj_on f A" using inj_on_imageI2 by blast
   371   next
   372     fix a' assume **: "a' \<in> A'"
   373     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   374     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   375     unfolding bij_betw_def by force
   376     hence "f a \<in> A'" using IM by auto
   377     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   378     thus "a' \<in> f ` A" using 1 by auto
   379   qed
   380 qed
   381 
   382 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   383 proof -
   384   have i: "inj_on f A" and s: "f ` A = B"
   385     using assms by(auto simp:bij_betw_def)
   386   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   387   { fix a b assume P: "?P b a"
   388     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   389     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   390     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   391   } note g = this
   392   have "inj_on ?g B"
   393   proof(rule inj_onI)
   394     fix x y assume "x:B" "y:B" "?g x = ?g y"
   395     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   396     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   397     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   398   qed
   399   moreover have "?g ` B = A"
   400   proof(auto simp:image_def)
   401     fix b assume "b:B"
   402     with s obtain a where P: "?P b a" unfolding image_def by blast
   403     thus "?g b \<in> A" using g[OF P] by auto
   404   next
   405     fix a assume "a:A"
   406     then obtain b where P: "?P b a" using s unfolding image_def by blast
   407     then have "b:B" using s unfolding image_def by blast
   408     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   409   qed
   410   ultimately show ?thesis by(auto simp:bij_betw_def)
   411 qed
   412 
   413 lemma bij_betw_cong:
   414   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   415 unfolding bij_betw_def inj_on_def by force
   416 
   417 lemma bij_betw_id[intro, simp]:
   418   "bij_betw id A A"
   419 unfolding bij_betw_def id_def by auto
   420 
   421 lemma bij_betw_id_iff:
   422   "bij_betw id A B \<longleftrightarrow> A = B"
   423 by(auto simp add: bij_betw_def)
   424 
   425 lemma bij_betw_combine:
   426   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   427   shows "bij_betw f (A \<union> C) (B \<union> D)"
   428   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   429 
   430 lemma bij_betw_UNION_chain:
   431   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   432          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
   433   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
   434 proof(unfold bij_betw_def, auto simp add: image_def)
   435   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   436   using BIJ bij_betw_def[of f] by auto
   437   thus "inj_on f (\<Union> i \<in> I. A i)"
   438   using CH inj_on_UNION_chain[of I A f] by auto
   439 next
   440   fix i x
   441   assume *: "i \<in> I" "x \<in> A i"
   442   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
   443   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
   444 next
   445   fix i x'
   446   assume *: "i \<in> I" "x' \<in> A' i"
   447   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
   448   thus "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
   449   using * by blast
   450 qed
   451 
   452 lemma bij_betw_Disj_Un:
   453   assumes DISJ: "A \<inter> B = {}" and DISJ': "A' \<inter> B' = {}" and
   454           B1: "bij_betw f A A'" and B2: "bij_betw f B B'"
   455   shows "bij_betw f (A \<union> B) (A' \<union> B')"
   456 proof-
   457   have 1: "inj_on f A \<and> inj_on f B"
   458   using B1 B2 by (auto simp add: bij_betw_def)
   459   have 2: "f`A = A' \<and> f`B = B'"
   460   using B1 B2 by (auto simp add: bij_betw_def)
   461   hence "f`(A - B) \<inter> f`(B - A) = {}"
   462   using DISJ DISJ' by blast
   463   hence "inj_on f (A \<union> B)"
   464   using 1 by (auto simp add: inj_on_Un)
   465   (*  *)
   466   moreover
   467   have "f`(A \<union> B) = A' \<union> B'"
   468   using 2 by auto
   469   ultimately show ?thesis
   470   unfolding bij_betw_def by auto
   471 qed
   472 
   473 lemma bij_betw_subset:
   474   assumes BIJ: "bij_betw f A A'" and
   475           SUB: "B \<le> A" and IM: "f ` B = B'"
   476   shows "bij_betw f B B'"
   477 using assms
   478 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   479 
   480 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   481 by simp
   482 
   483 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   484 by (simp add: inj_on_def, blast)
   485 
   486 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   487 by (blast intro: sym)
   488 
   489 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   490 by (unfold inj_on_def, blast)
   491 
   492 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   493 apply (unfold bij_def)
   494 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   495 done
   496 
   497 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   498 by(blast dest: inj_onD)
   499 
   500 lemma inj_on_image_Int:
   501    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   502 apply (simp add: inj_on_def, blast)
   503 done
   504 
   505 lemma inj_on_image_set_diff:
   506    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   507 apply (simp add: inj_on_def, blast)
   508 done
   509 
   510 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   511 by (simp add: inj_on_def, blast)
   512 
   513 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   514 by (simp add: inj_on_def, blast)
   515 
   516 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   517 by (blast dest: injD)
   518 
   519 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   520 by (simp add: inj_on_def, blast)
   521 
   522 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   523 by (blast dest: injD)
   524 
   525 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   526 lemma image_INT:
   527    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   528     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   529 apply (simp add: inj_on_def, blast)
   530 done
   531 
   532 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   533   it doesn't matter whether A is empty*)
   534 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   535 apply (simp add: bij_def)
   536 apply (simp add: inj_on_def surj_def, blast)
   537 done
   538 
   539 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   540 by auto
   541 
   542 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   543 by (auto simp add: inj_on_def)
   544 
   545 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   546 apply (simp add: bij_def)
   547 apply (rule equalityI)
   548 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   549 done
   550 
   551 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   552   by (auto intro!: inj_onI)
   553 
   554 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   555   by (auto intro!: inj_onI dest: strict_mono_eq)
   556 
   557 subsection{*Function Updating*}
   558 
   559 definition
   560   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   561   "fun_upd f a b == % x. if x=a then b else f x"
   562 
   563 nonterminals
   564   updbinds updbind
   565 syntax
   566   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   567   ""         :: "updbind => updbinds"             ("_")
   568   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   569   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   570 
   571 translations
   572   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   573   "f(x:=y)" == "CONST fun_upd f x y"
   574 
   575 (* Hint: to define the sum of two functions (or maps), use sum_case.
   576          A nice infix syntax could be defined (in Datatype.thy or below) by
   577 notation
   578   sum_case  (infixr "'(+')"80)
   579 *)
   580 
   581 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   582 apply (simp add: fun_upd_def, safe)
   583 apply (erule subst)
   584 apply (rule_tac [2] ext, auto)
   585 done
   586 
   587 (* f x = y ==> f(x:=y) = f *)
   588 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   589 
   590 (* f(x := f x) = f *)
   591 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   592 declare fun_upd_triv [iff]
   593 
   594 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   595 by (simp add: fun_upd_def)
   596 
   597 (* fun_upd_apply supersedes these two,   but they are useful
   598    if fun_upd_apply is intentionally removed from the simpset *)
   599 lemma fun_upd_same: "(f(x:=y)) x = y"
   600 by simp
   601 
   602 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   603 by simp
   604 
   605 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   606 by (simp add: fun_eq_iff)
   607 
   608 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   609 by (rule ext, auto)
   610 
   611 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   612 by (fastsimp simp:inj_on_def image_def)
   613 
   614 lemma fun_upd_image:
   615      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   616 by auto
   617 
   618 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   619 by (auto intro: ext)
   620 
   621 
   622 subsection {* @{text override_on} *}
   623 
   624 definition
   625   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   626 where
   627   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   628 
   629 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   630 by(simp add:override_on_def)
   631 
   632 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   633 by(simp add:override_on_def)
   634 
   635 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   636 by(simp add:override_on_def)
   637 
   638 
   639 subsection {* @{text swap} *}
   640 
   641 definition
   642   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   643 where
   644   "swap a b f = f (a := f b, b:= f a)"
   645 
   646 lemma swap_self [simp]: "swap a a f = f"
   647 by (simp add: swap_def)
   648 
   649 lemma swap_commute: "swap a b f = swap b a f"
   650 by (rule ext, simp add: fun_upd_def swap_def)
   651 
   652 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   653 by (rule ext, simp add: fun_upd_def swap_def)
   654 
   655 lemma swap_triple:
   656   assumes "a \<noteq> c" and "b \<noteq> c"
   657   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   658   using assms by (simp add: fun_eq_iff swap_def)
   659 
   660 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   661 by (rule ext, simp add: fun_upd_def swap_def)
   662 
   663 lemma swap_image_eq [simp]:
   664   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   665 proof -
   666   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   667     using assms by (auto simp: image_iff swap_def)
   668   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   669   with subset[of f] show ?thesis by auto
   670 qed
   671 
   672 lemma inj_on_imp_inj_on_swap:
   673   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   674   by (simp add: inj_on_def swap_def, blast)
   675 
   676 lemma inj_on_swap_iff [simp]:
   677   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   678 proof
   679   assume "inj_on (swap a b f) A"
   680   with A have "inj_on (swap a b (swap a b f)) A"
   681     by (iprover intro: inj_on_imp_inj_on_swap)
   682   thus "inj_on f A" by simp
   683 next
   684   assume "inj_on f A"
   685   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   686 qed
   687 
   688 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   689   by simp
   690 
   691 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   692   by simp
   693 
   694 lemma bij_betw_swap_iff [simp]:
   695   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   696   by (auto simp: bij_betw_def)
   697 
   698 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   699   by simp
   700 
   701 hide_const (open) swap
   702 
   703 subsection {* Inversion of injective functions *}
   704 
   705 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   706 "the_inv_into A f == %x. THE y. y : A & f y = x"
   707 
   708 lemma the_inv_into_f_f:
   709   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   710 apply (simp add: the_inv_into_def inj_on_def)
   711 apply blast
   712 done
   713 
   714 lemma f_the_inv_into_f:
   715   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   716 apply (simp add: the_inv_into_def)
   717 apply (rule the1I2)
   718  apply(blast dest: inj_onD)
   719 apply blast
   720 done
   721 
   722 lemma the_inv_into_into:
   723   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   724 apply (simp add: the_inv_into_def)
   725 apply (rule the1I2)
   726  apply(blast dest: inj_onD)
   727 apply blast
   728 done
   729 
   730 lemma the_inv_into_onto[simp]:
   731   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   732 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   733 
   734 lemma the_inv_into_f_eq:
   735   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   736   apply (erule subst)
   737   apply (erule the_inv_into_f_f, assumption)
   738   done
   739 
   740 lemma the_inv_into_comp:
   741   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   742   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   743 apply (rule the_inv_into_f_eq)
   744   apply (fast intro: comp_inj_on)
   745  apply (simp add: f_the_inv_into_f the_inv_into_into)
   746 apply (simp add: the_inv_into_into)
   747 done
   748 
   749 lemma inj_on_the_inv_into:
   750   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   751 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   752 
   753 lemma bij_betw_the_inv_into:
   754   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   755 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   756 
   757 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   758   "the_inv f \<equiv> the_inv_into UNIV f"
   759 
   760 lemma the_inv_f_f:
   761   assumes "inj f"
   762   shows "the_inv f (f x) = x" using assms UNIV_I
   763   by (rule the_inv_into_f_f)
   764 
   765 subsection {* Cantor's Paradox *}
   766 
   767 lemma Cantors_paradox:
   768   "\<not>(\<exists>f. f ` A = Pow A)"
   769 proof clarify
   770   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   771   let ?X = "{a \<in> A. a \<notin> f a}"
   772   have "?X \<in> Pow A" unfolding Pow_def by auto
   773   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   774   thus False by best
   775 qed
   776 
   777 subsection {* Proof tool setup *} 
   778 
   779 text {* simplifies terms of the form
   780   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   781 
   782 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   783 let
   784   fun gen_fun_upd NONE T _ _ = NONE
   785     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   786   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   787   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   788     let
   789       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   790             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   791         | find t = NONE
   792     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   793 
   794   fun proc ss ct =
   795     let
   796       val ctxt = Simplifier.the_context ss
   797       val t = Thm.term_of ct
   798     in
   799       case find_double t of
   800         (T, NONE) => NONE
   801       | (T, SOME rhs) =>
   802           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   803             (fn _ =>
   804               rtac eq_reflection 1 THEN
   805               rtac ext 1 THEN
   806               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   807     end
   808 in proc end
   809 *}
   810 
   811 
   812 subsection {* Code generator setup *}
   813 
   814 types_code
   815   "fun"  ("(_ ->/ _)")
   816 attach (term_of) {*
   817 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   818 *}
   819 attach (test) {*
   820 fun gen_fun_type aF aT bG bT i =
   821   let
   822     val tab = Unsynchronized.ref [];
   823     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   824       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   825   in
   826     (fn x =>
   827        case AList.lookup op = (!tab) x of
   828          NONE =>
   829            let val p as (y, _) = bG i
   830            in (tab := (x, p) :: !tab; y) end
   831        | SOME (y, _) => y,
   832      fn () => Basics.fold mk_upd (!tab) (Const ("HOL.undefined", aT --> bT)))
   833   end;
   834 *}
   835 
   836 code_const "op \<circ>"
   837   (SML infixl 5 "o")
   838   (Haskell infixr 9 ".")
   839 
   840 code_const "id"
   841   (Haskell "id")
   842 
   843 end