src/HOL/Set.ML
author wenzelm
Fri Sep 01 00:28:27 2000 +0200 (2000-09-01)
changeset 9769 a73540153a73
parent 9687 772ac061bd76
child 9892 be0389a64ce8
permissions -rw-r--r--
fixed rulify_prems;
     1 (*  Title:      HOL/Set.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 section "Relating predicates and sets";
    10 
    11 Addsimps [Collect_mem_eq];
    12 AddIffs  [mem_Collect_eq];
    13 
    14 Goal "P(a) ==> a : {x. P(x)}";
    15 by (Asm_simp_tac 1);
    16 qed "CollectI";
    17 
    18 Goal "a : {x. P(x)} ==> P(a)";
    19 by (Asm_full_simp_tac 1);
    20 qed "CollectD";
    21 
    22 val [prem] = Goal "(!!x. (x:A) = (x:B)) ==> A = B";
    23 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    24 by (rtac Collect_mem_eq 1);
    25 by (rtac Collect_mem_eq 1);
    26 qed "set_ext";
    27 
    28 val [prem] = Goal "(!!x. P(x)=Q(x)) ==> {x. P(x)} = {x. Q(x)}";
    29 by (rtac (prem RS ext RS arg_cong) 1);
    30 qed "Collect_cong";
    31 
    32 bind_thm ("CollectE", make_elim CollectD);
    33 
    34 AddSIs [CollectI];
    35 AddSEs [CollectE];
    36 
    37 
    38 section "Bounded quantifiers";
    39 
    40 val prems = Goalw [Ball_def]
    41     "[| !!x. x:A ==> P(x) |] ==> ALL x:A. P(x)";
    42 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    43 qed "ballI";
    44 
    45 bind_thms ("strip", [impI, allI, ballI]);
    46 
    47 Goalw [Ball_def] "[| ALL x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ALL x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ALL x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 AddXDs [bspec];
    63 (* gives better instantiation for bound: *)
    64 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    65 			 (dtac bspec THEN' atac) APPEND' tac2);
    66 
    67 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    68 Goalw [Bex_def] "[| P(x);  x:A |] ==> EX x:A. P(x)";
    69 by (Blast_tac 1);
    70 qed "bexI";
    71 
    72 (*The best argument order when there is only one x:A*)
    73 Goalw [Bex_def] "[| x:A;  P(x) |] ==> EX x:A. P(x)";
    74 by (Blast_tac 1);
    75 qed "rev_bexI";
    76 
    77 val prems = Goal 
    78    "[| ALL x:A. ~P(x) ==> P(a);  a:A |] ==> EX x:A. P(x)";
    79 by (rtac classical 1);
    80 by (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ;
    81 qed "bexCI";
    82 
    83 val major::prems = Goalw [Bex_def]
    84     "[| EX x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    85 by (rtac (major RS exE) 1);
    86 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    87 qed "bexE";
    88 
    89 AddIs  [bexI];
    90 AddSEs [bexE];
    91 
    92 (*Trival rewrite rule*)
    93 Goal "(ALL x:A. P) = ((EX x. x:A) --> P)";
    94 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    95 qed "ball_triv";
    96 
    97 (*Dual form for existentials*)
    98 Goal "(EX x:A. P) = ((EX x. x:A) & P)";
    99 by (simp_tac (simpset() addsimps [Bex_def]) 1);
   100 qed "bex_triv";
   101 
   102 Addsimps [ball_triv, bex_triv];
   103 
   104 (** Congruence rules **)
   105 
   106 val prems = Goalw [Ball_def]
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (ALL x:A. P(x)) = (ALL x:B. Q(x))";
   109 by (asm_simp_tac (simpset() addsimps prems) 1);
   110 qed "ball_cong";
   111 
   112 val prems = Goalw [Bex_def]
   113     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   114 \    (EX x:A. P(x)) = (EX x:B. Q(x))";
   115 by (asm_simp_tac (simpset() addcongs [conj_cong] addsimps prems) 1);
   116 qed "bex_cong";
   117 
   118 Addcongs [ball_cong,bex_cong];
   119 
   120 section "Subsets";
   121 
   122 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   123 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   124 qed "subsetI";
   125 
   126 (*Map the type ('a set => anything) to just 'a.
   127   For overloading constants whose first argument has type "'a set" *)
   128 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   129 
   130 (*While (:) is not, its type must be kept
   131   for overloading of = to work.*)
   132 Blast.overloaded ("op :", domain_type);
   133 
   134 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   135 overload_1st_set "Bex";
   136 
   137 (*Image: retain the type of the set being expressed*)
   138 Blast.overloaded ("image", domain_type);
   139 
   140 (*Rule in Modus Ponens style*)
   141 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   142 by (Blast_tac 1);
   143 qed "subsetD";
   144 AddXIs [subsetD];
   145 
   146 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   147 Goal "[| c:A;  A <= B |] ==> c:B";
   148 by (REPEAT (ares_tac [subsetD] 1)) ;
   149 qed "rev_subsetD";
   150 AddXIs [rev_subsetD];
   151 
   152 (*Converts A<=B to x:A ==> x:B*)
   153 fun impOfSubs th = th RSN (2, rev_subsetD);
   154 
   155 Goal "[| A <= B; c ~: B |] ==> c ~: A";
   156 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   157 qed "contra_subsetD";
   158 
   159 Goal "[| c ~: B;  A <= B |] ==> c ~: A";
   160 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   161 qed "rev_contra_subsetD";
   162 
   163 (*Classical elimination rule*)
   164 val major::prems = Goalw [subset_def] 
   165     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   166 by (rtac (major RS ballE) 1);
   167 by (REPEAT (eresolve_tac prems 1));
   168 qed "subsetCE";
   169 
   170 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   171 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   172 
   173 AddSIs [subsetI];
   174 AddEs  [subsetD, subsetCE];
   175 
   176 Goal "A <= (A::'a set)";
   177 by (Fast_tac 1);
   178 qed "subset_refl";		(*Blast_tac would try order_refl and fail*)
   179 
   180 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   181 by (Blast_tac 1);
   182 qed "subset_trans";
   183 
   184 
   185 section "Equality";
   186 
   187 (*Anti-symmetry of the subset relation*)
   188 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   189 by (rtac set_ext 1);
   190 by (blast_tac (claset() addIs [subsetD]) 1);
   191 qed "subset_antisym";
   192 bind_thm ("equalityI", subset_antisym);
   193 
   194 AddSIs [equalityI];
   195 
   196 (* Equality rules from ZF set theory -- are they appropriate here? *)
   197 Goal "A = B ==> A<=(B::'a set)";
   198 by (etac ssubst 1);
   199 by (rtac subset_refl 1);
   200 qed "equalityD1";
   201 
   202 Goal "A = B ==> B<=(A::'a set)";
   203 by (etac ssubst 1);
   204 by (rtac subset_refl 1);
   205 qed "equalityD2";
   206 
   207 (*Be careful when adding this to the claset as subset_empty is in the simpset:
   208   A={} goes to {}<=A and A<={} and then back to A={} !*)
   209 val prems = Goal
   210     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   211 by (resolve_tac prems 1);
   212 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   213 qed "equalityE";
   214 
   215 val major::prems = Goal
   216     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   217 by (rtac (major RS equalityE) 1);
   218 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   219 qed "equalityCE";
   220 
   221 AddEs [equalityCE];
   222 
   223 (*Lemma for creating induction formulae -- for "pattern matching" on p
   224   To make the induction hypotheses usable, apply "spec" or "bspec" to
   225   put universal quantifiers over the free variables in p. *)
   226 val prems = Goal 
   227     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   228 by (rtac mp 1);
   229 by (REPEAT (resolve_tac (refl::prems) 1));
   230 qed "setup_induction";
   231 
   232 Goal "A = B ==> (x : A) = (x : B)";
   233 by (Asm_simp_tac 1);
   234 qed "eqset_imp_iff";
   235 
   236 
   237 section "The universal set -- UNIV";
   238 
   239 Goalw [UNIV_def] "x : UNIV";
   240 by (rtac CollectI 1);
   241 by (rtac TrueI 1);
   242 qed "UNIV_I";
   243 
   244 Addsimps [UNIV_I];
   245 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   246 
   247 Goal "A <= UNIV";
   248 by (rtac subsetI 1);
   249 by (rtac UNIV_I 1);
   250 qed "subset_UNIV";
   251 
   252 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   253     because of their interaction with congruence rules. **)
   254 
   255 Goalw [Ball_def] "Ball UNIV P = All P";
   256 by (Simp_tac 1);
   257 qed "ball_UNIV";
   258 
   259 Goalw [Bex_def] "Bex UNIV P = Ex P";
   260 by (Simp_tac 1);
   261 qed "bex_UNIV";
   262 Addsimps [ball_UNIV, bex_UNIV];
   263 
   264 
   265 section "The empty set -- {}";
   266 
   267 Goalw [empty_def] "(c : {}) = False";
   268 by (Blast_tac 1) ;
   269 qed "empty_iff";
   270 
   271 Addsimps [empty_iff];
   272 
   273 Goal "a:{} ==> P";
   274 by (Full_simp_tac 1);
   275 qed "emptyE";
   276 
   277 AddSEs [emptyE];
   278 
   279 Goal "{} <= A";
   280 by (Blast_tac 1) ;
   281 qed "empty_subsetI";
   282 
   283 (*One effect is to delete the ASSUMPTION {} <= A*)
   284 AddIffs [empty_subsetI];
   285 
   286 val [prem]= Goal "[| !!y. y:A ==> False |] ==> A={}";
   287 by (blast_tac (claset() addIs [prem RS FalseE]) 1) ;
   288 qed "equals0I";
   289 
   290 (*Use for reasoning about disjointness: A Int B = {} *)
   291 Goal "A={} ==> a ~: A";
   292 by (Blast_tac 1) ;
   293 qed "equals0D";
   294 
   295 Goalw [Ball_def] "Ball {} P = True";
   296 by (Simp_tac 1);
   297 qed "ball_empty";
   298 
   299 Goalw [Bex_def] "Bex {} P = False";
   300 by (Simp_tac 1);
   301 qed "bex_empty";
   302 Addsimps [ball_empty, bex_empty];
   303 
   304 Goal "UNIV ~= {}";
   305 by (blast_tac (claset() addEs [equalityE]) 1);
   306 qed "UNIV_not_empty";
   307 AddIffs [UNIV_not_empty];
   308 
   309 
   310 
   311 section "The Powerset operator -- Pow";
   312 
   313 Goalw [Pow_def] "(A : Pow(B)) = (A <= B)";
   314 by (Asm_simp_tac 1);
   315 qed "Pow_iff";
   316 
   317 AddIffs [Pow_iff]; 
   318 
   319 Goalw [Pow_def] "A <= B ==> A : Pow(B)";
   320 by (etac CollectI 1);
   321 qed "PowI";
   322 
   323 Goalw [Pow_def] "A : Pow(B)  ==>  A<=B";
   324 by (etac CollectD 1);
   325 qed "PowD";
   326 
   327 
   328 bind_thm ("Pow_bottom", empty_subsetI RS PowI);        (* {}: Pow(B) *)
   329 bind_thm ("Pow_top", subset_refl RS PowI);             (* A : Pow(A) *)
   330 
   331 
   332 section "Set complement";
   333 
   334 Goalw [Compl_def] "(c : -A) = (c~:A)";
   335 by (Blast_tac 1);
   336 qed "Compl_iff";
   337 
   338 Addsimps [Compl_iff];
   339 
   340 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   341 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   342 qed "ComplI";
   343 
   344 (*This form, with negated conclusion, works well with the Classical prover.
   345   Negated assumptions behave like formulae on the right side of the notional
   346   turnstile...*)
   347 Goalw [Compl_def] "c : -A ==> c~:A";
   348 by (etac CollectD 1);
   349 qed "ComplD";
   350 
   351 bind_thm ("ComplE", make_elim ComplD);
   352 
   353 AddSIs [ComplI];
   354 AddSEs [ComplE];
   355 
   356 
   357 section "Binary union -- Un";
   358 
   359 Goalw [Un_def] "(c : A Un B) = (c:A | c:B)";
   360 by (Blast_tac 1);
   361 qed "Un_iff";
   362 Addsimps [Un_iff];
   363 
   364 Goal "c:A ==> c : A Un B";
   365 by (Asm_simp_tac 1);
   366 qed "UnI1";
   367 
   368 Goal "c:B ==> c : A Un B";
   369 by (Asm_simp_tac 1);
   370 qed "UnI2";
   371 
   372 AddXIs [UnI1, UnI2];
   373 
   374 
   375 (*Classical introduction rule: no commitment to A vs B*)
   376 
   377 val prems = Goal "(c~:B ==> c:A) ==> c : A Un B";
   378 by (Simp_tac 1);
   379 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   380 qed "UnCI";
   381 
   382 val major::prems = Goalw [Un_def]
   383     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   384 by (rtac (major RS CollectD RS disjE) 1);
   385 by (REPEAT (eresolve_tac prems 1));
   386 qed "UnE";
   387 
   388 AddSIs [UnCI];
   389 AddSEs [UnE];
   390 
   391 
   392 section "Binary intersection -- Int";
   393 
   394 Goalw [Int_def] "(c : A Int B) = (c:A & c:B)";
   395 by (Blast_tac 1);
   396 qed "Int_iff";
   397 Addsimps [Int_iff];
   398 
   399 Goal "[| c:A;  c:B |] ==> c : A Int B";
   400 by (Asm_simp_tac 1);
   401 qed "IntI";
   402 
   403 Goal "c : A Int B ==> c:A";
   404 by (Asm_full_simp_tac 1);
   405 qed "IntD1";
   406 
   407 Goal "c : A Int B ==> c:B";
   408 by (Asm_full_simp_tac 1);
   409 qed "IntD2";
   410 
   411 val [major,minor] = Goal
   412     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   413 by (rtac minor 1);
   414 by (rtac (major RS IntD1) 1);
   415 by (rtac (major RS IntD2) 1);
   416 qed "IntE";
   417 
   418 AddSIs [IntI];
   419 AddSEs [IntE];
   420 
   421 section "Set difference";
   422 
   423 Goalw [set_diff_def] "(c : A-B) = (c:A & c~:B)";
   424 by (Blast_tac 1);
   425 qed "Diff_iff";
   426 Addsimps [Diff_iff];
   427 
   428 Goal "[| c : A;  c ~: B |] ==> c : A - B";
   429 by (Asm_simp_tac 1) ;
   430 qed "DiffI";
   431 
   432 Goal "c : A - B ==> c : A";
   433 by (Asm_full_simp_tac 1) ;
   434 qed "DiffD1";
   435 
   436 Goal "[| c : A - B;  c : B |] ==> P";
   437 by (Asm_full_simp_tac 1) ;
   438 qed "DiffD2";
   439 
   440 val prems = Goal "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P";
   441 by (resolve_tac prems 1);
   442 by (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ;
   443 qed "DiffE";
   444 
   445 AddSIs [DiffI];
   446 AddSEs [DiffE];
   447 
   448 
   449 section "Augmenting a set -- insert";
   450 
   451 Goalw [insert_def] "a : insert b A = (a=b | a:A)";
   452 by (Blast_tac 1);
   453 qed "insert_iff";
   454 Addsimps [insert_iff];
   455 
   456 Goal "a : insert a B";
   457 by (Simp_tac 1);
   458 qed "insertI1";
   459 
   460 Goal "!!a. a : B ==> a : insert b B";
   461 by (Asm_simp_tac 1);
   462 qed "insertI2";
   463 
   464 val major::prems = Goalw [insert_def]
   465     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P";
   466 by (rtac (major RS UnE) 1);
   467 by (REPEAT (eresolve_tac (prems @ [CollectE]) 1));
   468 qed "insertE";
   469 
   470 (*Classical introduction rule*)
   471 val prems = Goal "(a~:B ==> a=b) ==> a: insert b B";
   472 by (Simp_tac 1);
   473 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   474 qed "insertCI";
   475 
   476 AddSIs [insertCI]; 
   477 AddSEs [insertE];
   478 
   479 Goal "(A <= insert x B) = (if x:A then A-{x} <= B else A<=B)";
   480 by Auto_tac; 
   481 qed "subset_insert_iff";
   482 
   483 section "Singletons, using insert";
   484 
   485 Goal "a : {a}";
   486 by (rtac insertI1 1) ;
   487 qed "singletonI";
   488 
   489 Goal "b : {a} ==> b=a";
   490 by (Blast_tac 1);
   491 qed "singletonD";
   492 
   493 bind_thm ("singletonE", make_elim singletonD);
   494 
   495 Goal "(b : {a}) = (b=a)";
   496 by (Blast_tac 1);
   497 qed "singleton_iff";
   498 
   499 Goal "{a}={b} ==> a=b";
   500 by (blast_tac (claset() addEs [equalityE]) 1);
   501 qed "singleton_inject";
   502 
   503 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   504 AddSIs [singletonI];   
   505 AddSDs [singleton_inject];
   506 AddSEs [singletonE];
   507 
   508 Goal "{b} = insert a A = (a = b & A <= {b})";
   509 by (blast_tac (claset() addSEs [equalityE]) 1);
   510 qed "singleton_insert_inj_eq";
   511 
   512 Goal "(insert a A = {b}) = (a = b & A <= {b})";
   513 by (blast_tac (claset() addSEs [equalityE]) 1);
   514 qed "singleton_insert_inj_eq'";
   515 
   516 AddIffs [singleton_insert_inj_eq, singleton_insert_inj_eq'];
   517 
   518 Goal "A <= {x} ==> A={} | A = {x}";
   519 by (Fast_tac 1);
   520 qed "subset_singletonD";
   521 
   522 Goal "{x. x=a} = {a}";
   523 by (Blast_tac 1);
   524 qed "singleton_conv";
   525 Addsimps [singleton_conv];
   526 
   527 Goal "{x. a=x} = {a}";
   528 by (Blast_tac 1);
   529 qed "singleton_conv2";
   530 Addsimps [singleton_conv2];
   531 
   532 
   533 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   534 
   535 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   536 by (Blast_tac 1);
   537 qed "UN_iff";
   538 
   539 Addsimps [UN_iff];
   540 
   541 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   542 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   543 by Auto_tac;
   544 qed "UN_I";
   545 
   546 val major::prems = Goalw [UNION_def]
   547     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   548 by (rtac (major RS CollectD RS bexE) 1);
   549 by (REPEAT (ares_tac prems 1));
   550 qed "UN_E";
   551 
   552 AddIs  [UN_I];
   553 AddSEs [UN_E];
   554 
   555 val prems = Goalw [UNION_def]
   556     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   557 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   558 by (asm_simp_tac (simpset() addsimps prems) 1);
   559 qed "UN_cong";
   560 Addcongs [UN_cong];
   561 
   562 
   563 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   564 
   565 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   566 by Auto_tac;
   567 qed "INT_iff";
   568 
   569 Addsimps [INT_iff];
   570 
   571 val prems = Goalw [INTER_def]
   572     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   573 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   574 qed "INT_I";
   575 
   576 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   577 by Auto_tac;
   578 qed "INT_D";
   579 
   580 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   581 val major::prems = Goalw [INTER_def]
   582     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   583 by (rtac (major RS CollectD RS ballE) 1);
   584 by (REPEAT (eresolve_tac prems 1));
   585 qed "INT_E";
   586 
   587 AddSIs [INT_I];
   588 AddEs  [INT_D, INT_E];
   589 
   590 val prems = Goalw [INTER_def]
   591     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   592 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   593 by (asm_simp_tac (simpset() addsimps prems) 1);
   594 qed "INT_cong";
   595 Addcongs [INT_cong];
   596 
   597 
   598 section "Union";
   599 
   600 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   601 by (Blast_tac 1);
   602 qed "Union_iff";
   603 
   604 Addsimps [Union_iff];
   605 
   606 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   607 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   608 by Auto_tac;
   609 qed "UnionI";
   610 
   611 val major::prems = Goalw [Union_def]
   612     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   613 by (rtac (major RS UN_E) 1);
   614 by (REPEAT (ares_tac prems 1));
   615 qed "UnionE";
   616 
   617 AddIs  [UnionI];
   618 AddSEs [UnionE];
   619 
   620 
   621 section "Inter";
   622 
   623 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   624 by (Blast_tac 1);
   625 qed "Inter_iff";
   626 
   627 Addsimps [Inter_iff];
   628 
   629 val prems = Goalw [Inter_def]
   630     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   631 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   632 qed "InterI";
   633 
   634 (*A "destruct" rule -- every X in C contains A as an element, but
   635   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   636 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   637 by Auto_tac;
   638 qed "InterD";
   639 
   640 (*"Classical" elimination rule -- does not require proving X:C *)
   641 val major::prems = Goalw [Inter_def]
   642     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   643 by (rtac (major RS INT_E) 1);
   644 by (REPEAT (eresolve_tac prems 1));
   645 qed "InterE";
   646 
   647 AddSIs [InterI];
   648 AddEs  [InterD, InterE];
   649 
   650 
   651 (*** Image of a set under a function ***)
   652 
   653 (*Frequently b does not have the syntactic form of f(x).*)
   654 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   655 by (Blast_tac 1);
   656 qed "image_eqI";
   657 Addsimps [image_eqI];
   658 
   659 bind_thm ("imageI", refl RS image_eqI);
   660 
   661 (*This version's more effective when we already have the required x*)
   662 Goalw [image_def] "[| x:A;  b=f(x) |] ==> b : f``A";
   663 by (Blast_tac 1);
   664 qed "rev_image_eqI";
   665 
   666 (*The eta-expansion gives variable-name preservation.*)
   667 val major::prems = Goalw [image_def]
   668     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   669 by (rtac (major RS CollectD RS bexE) 1);
   670 by (REPEAT (ares_tac prems 1));
   671 qed "imageE";
   672 
   673 AddIs  [image_eqI];
   674 AddSEs [imageE]; 
   675 
   676 Goal "f``(A Un B) = f``A Un f``B";
   677 by (Blast_tac 1);
   678 qed "image_Un";
   679 
   680 Goal "(z : f``A) = (EX x:A. z = f x)";
   681 by (Blast_tac 1);
   682 qed "image_iff";
   683 
   684 (*This rewrite rule would confuse users if made default.*)
   685 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   686 by (Blast_tac 1);
   687 qed "image_subset_iff";
   688 
   689 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   690   many existing proofs.*)
   691 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   692 by (blast_tac (claset() addIs prems) 1);
   693 qed "image_subsetI";
   694 
   695 
   696 (*** Range of a function -- just a translation for image! ***)
   697 
   698 Goal "b=f(x) ==> b : range(f)";
   699 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   700 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   701 
   702 bind_thm ("rangeI", UNIV_I RS imageI);
   703 
   704 val [major,minor] = Goal 
   705     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   706 by (rtac (major RS imageE) 1);
   707 by (etac minor 1);
   708 qed "rangeE";
   709 
   710 
   711 (*** Set reasoning tools ***)
   712 
   713 
   714 (** Rewrite rules for boolean case-splitting: faster than 
   715 	addsplits[split_if]
   716 **)
   717 
   718 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   719 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   720 
   721 (*Split ifs on either side of the membership relation.
   722 	Not for Addsimps -- can cause goals to blow up!*)
   723 bind_thm ("split_if_mem1", 
   724     read_instantiate_sg (Theory.sign_of (the_context ())) [("P", "%x. x : ?b")] split_if);
   725 bind_thm ("split_if_mem2", 
   726     read_instantiate_sg (Theory.sign_of (the_context ())) [("P", "%x. ?a : x")] split_if);
   727 
   728 bind_thms ("split_ifs", [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   729 		  split_if_mem1, split_if_mem2]);
   730 
   731 
   732 (*Each of these has ALREADY been added to simpset() above.*)
   733 bind_thms ("mem_simps", [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   734                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff]);
   735 
   736 (*Would like to add these, but the existing code only searches for the 
   737   outer-level constant, which in this case is just "op :"; we instead need
   738   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   739   apply, then the formula should be kept.
   740   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]), 
   741    ("op Int", [IntD1,IntD2]),
   742    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   743  *)
   744 val mksimps_pairs =
   745   [("Ball",[bspec])] @ mksimps_pairs;
   746 
   747 simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   748 
   749 Addsimps[subset_UNIV, subset_refl];
   750 
   751 
   752 (*** The 'proper subset' relation (<) ***)
   753 
   754 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   755 by (Blast_tac 1);
   756 qed "psubsetI";
   757 AddSIs [psubsetI];
   758 
   759 Goalw [psubset_def]
   760   "(A < insert x B) = (if x:B then A<B else if x:A then A-{x} < B else A<=B)";
   761 by (asm_simp_tac (simpset() addsimps [subset_insert_iff]) 1);
   762 by (Blast_tac 1); 
   763 qed "psubset_insert_iff";
   764 
   765 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);
   766 
   767 bind_thm ("psubset_imp_subset", psubset_eq RS iffD1 RS conjunct1);
   768 
   769 Goal"[| (A::'a set) < B; B <= C |] ==> A < C";
   770 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   771 qed "psubset_subset_trans";
   772 
   773 Goal"[| (A::'a set) <= B; B < C|] ==> A < C";
   774 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   775 qed "subset_psubset_trans";
   776 
   777 Goalw [psubset_def] "A < B ==> EX b. b : (B - A)";
   778 by (Blast_tac 1);
   779 qed "psubset_imp_ex_mem";
   780 
   781 
   782 (* attributes *)
   783 
   784 local
   785 
   786 fun gen_rulify_prems x =
   787   Attrib.no_args (Drule.rule_attribute (fn _ => (standard o
   788     rule_by_tactic (REPEAT (FIRSTGOAL (resolve_tac [allI, ballI, impI])))))) x;
   789 
   790 in
   791 
   792 val rulify_prems_attrib_setup =
   793  [Attrib.add_attributes
   794   [("rulify_prems", (gen_rulify_prems, gen_rulify_prems), "put theorem into standard rule form")]];
   795 
   796 end;