src/HOL/Library/Complete_Partial_Order2.thy
author wenzelm
Wed Mar 08 10:50:59 2017 +0100 (2017-03-08)
changeset 65151 a7394aa4d21c
parent 63649 e690d6f2185b
child 65366 10ca63a18e56
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Library/Complete_Partial_Order2.thy
     2     Author:     Andreas Lochbihler, ETH Zurich
     3 *)
     4 
     5 section \<open>Formalisation of chain-complete partial orders, continuity and admissibility\<close>
     6 
     7 theory Complete_Partial_Order2 imports 
     8   Main
     9   "~~/src/HOL/Library/Lattice_Syntax"
    10 begin
    11 
    12 lemma chain_transfer [transfer_rule]:
    13   includes lifting_syntax
    14   shows "((A ===> A ===> op =) ===> rel_set A ===> op =) Complete_Partial_Order.chain Complete_Partial_Order.chain"
    15 unfolding chain_def[abs_def] by transfer_prover
    16 
    17 lemma linorder_chain [simp, intro!]:
    18   fixes Y :: "_ :: linorder set"
    19   shows "Complete_Partial_Order.chain op \<le> Y"
    20 by(auto intro: chainI)
    21 
    22 lemma fun_lub_apply: "\<And>Sup. fun_lub Sup Y x = Sup ((\<lambda>f. f x) ` Y)"
    23 by(simp add: fun_lub_def image_def)
    24 
    25 lemma fun_lub_empty [simp]: "fun_lub lub {} = (\<lambda>_. lub {})"
    26 by(rule ext)(simp add: fun_lub_apply)
    27 
    28 lemma chain_fun_ordD: 
    29   assumes "Complete_Partial_Order.chain (fun_ord le) Y"
    30   shows "Complete_Partial_Order.chain le ((\<lambda>f. f x) ` Y)"
    31 by(rule chainI)(auto dest: chainD[OF assms] simp add: fun_ord_def)
    32 
    33 lemma chain_Diff:
    34   "Complete_Partial_Order.chain ord A
    35   \<Longrightarrow> Complete_Partial_Order.chain ord (A - B)"
    36 by(erule chain_subset) blast
    37 
    38 lemma chain_rel_prodD1:
    39   "Complete_Partial_Order.chain (rel_prod orda ordb) Y
    40   \<Longrightarrow> Complete_Partial_Order.chain orda (fst ` Y)"
    41 by(auto 4 3 simp add: chain_def)
    42 
    43 lemma chain_rel_prodD2:
    44   "Complete_Partial_Order.chain (rel_prod orda ordb) Y
    45   \<Longrightarrow> Complete_Partial_Order.chain ordb (snd ` Y)"
    46 by(auto 4 3 simp add: chain_def)
    47 
    48 
    49 context ccpo begin
    50 
    51 lemma ccpo_fun: "class.ccpo (fun_lub Sup) (fun_ord op \<le>) (mk_less (fun_ord op \<le>))"
    52   by standard (auto 4 3 simp add: mk_less_def fun_ord_def fun_lub_apply
    53     intro: order.trans antisym chain_imageI ccpo_Sup_upper ccpo_Sup_least)
    54 
    55 lemma ccpo_Sup_below_iff: "Complete_Partial_Order.chain op \<le> Y \<Longrightarrow> Sup Y \<le> x \<longleftrightarrow> (\<forall>y\<in>Y. y \<le> x)"
    56 by(fast intro: order_trans[OF ccpo_Sup_upper] ccpo_Sup_least)
    57 
    58 lemma Sup_minus_bot: 
    59   assumes chain: "Complete_Partial_Order.chain op \<le> A"
    60   shows "\<Squnion>(A - {\<Squnion>{}}) = \<Squnion>A"
    61     (is "?lhs = ?rhs")
    62 proof (rule antisym)
    63   show "?lhs \<le> ?rhs"
    64     by (blast intro: ccpo_Sup_least chain_Diff[OF chain] ccpo_Sup_upper[OF chain])
    65   show "?rhs \<le> ?lhs"
    66   proof (rule ccpo_Sup_least [OF chain])
    67     show "x \<in> A \<Longrightarrow> x \<le> ?lhs" for x
    68       by (cases "x = \<Squnion>{}")
    69         (blast intro: ccpo_Sup_least chain_empty ccpo_Sup_upper[OF chain_Diff[OF chain]])+
    70   qed
    71 qed
    72 
    73 lemma mono_lub:
    74   fixes le_b (infix "\<sqsubseteq>" 60)
    75   assumes chain: "Complete_Partial_Order.chain (fun_ord op \<le>) Y"
    76   and mono: "\<And>f. f \<in> Y \<Longrightarrow> monotone le_b op \<le> f"
    77   shows "monotone op \<sqsubseteq> op \<le> (fun_lub Sup Y)"
    78 proof(rule monotoneI)
    79   fix x y
    80   assume "x \<sqsubseteq> y"
    81 
    82   have chain'': "\<And>x. Complete_Partial_Order.chain op \<le> ((\<lambda>f. f x) ` Y)"
    83     using chain by(rule chain_imageI)(simp add: fun_ord_def)
    84   then show "fun_lub Sup Y x \<le> fun_lub Sup Y y" unfolding fun_lub_apply
    85   proof(rule ccpo_Sup_least)
    86     fix x'
    87     assume "x' \<in> (\<lambda>f. f x) ` Y"
    88     then obtain f where "f \<in> Y" "x' = f x" by blast
    89     note \<open>x' = f x\<close> also
    90     from \<open>f \<in> Y\<close> \<open>x \<sqsubseteq> y\<close> have "f x \<le> f y" by(blast dest: mono monotoneD)
    91     also have "\<dots> \<le> \<Squnion>((\<lambda>f. f y) ` Y)" using chain''
    92       by(rule ccpo_Sup_upper)(simp add: \<open>f \<in> Y\<close>)
    93     finally show "x' \<le> \<Squnion>((\<lambda>f. f y) ` Y)" .
    94   qed
    95 qed
    96 
    97 context
    98   fixes le_b (infix "\<sqsubseteq>" 60) and Y f
    99   assumes chain: "Complete_Partial_Order.chain le_b Y" 
   100   and mono1: "\<And>y. y \<in> Y \<Longrightarrow> monotone le_b op \<le> (\<lambda>x. f x y)"
   101   and mono2: "\<And>x a b. \<lbrakk> x \<in> Y; a \<sqsubseteq> b; a \<in> Y; b \<in> Y \<rbrakk> \<Longrightarrow> f x a \<le> f x b"
   102 begin
   103 
   104 lemma Sup_mono: 
   105   assumes le: "x \<sqsubseteq> y" and x: "x \<in> Y" and y: "y \<in> Y"
   106   shows "\<Squnion>(f x ` Y) \<le> \<Squnion>(f y ` Y)" (is "_ \<le> ?rhs")
   107 proof(rule ccpo_Sup_least)
   108   from chain show chain': "Complete_Partial_Order.chain op \<le> (f x ` Y)" when "x \<in> Y" for x
   109     by(rule chain_imageI) (insert that, auto dest: mono2)
   110 
   111   fix x'
   112   assume "x' \<in> f x ` Y"
   113   then obtain y' where "y' \<in> Y" "x' = f x y'" by blast note this(2)
   114   also from mono1[OF \<open>y' \<in> Y\<close>] le have "\<dots> \<le> f y y'" by(rule monotoneD)
   115   also have "\<dots> \<le> ?rhs" using chain'[OF y]
   116     by (auto intro!: ccpo_Sup_upper simp add: \<open>y' \<in> Y\<close>)
   117   finally show "x' \<le> ?rhs" .
   118 qed(rule x)
   119 
   120 lemma diag_Sup: "\<Squnion>((\<lambda>x. \<Squnion>(f x ` Y)) ` Y) = \<Squnion>((\<lambda>x. f x x) ` Y)" (is "?lhs = ?rhs")
   121 proof(rule antisym)
   122   have chain1: "Complete_Partial_Order.chain op \<le> ((\<lambda>x. \<Squnion>(f x ` Y)) ` Y)"
   123     using chain by(rule chain_imageI)(rule Sup_mono)
   124   have chain2: "\<And>y'. y' \<in> Y \<Longrightarrow> Complete_Partial_Order.chain op \<le> (f y' ` Y)" using chain
   125     by(rule chain_imageI)(auto dest: mono2)
   126   have chain3: "Complete_Partial_Order.chain op \<le> ((\<lambda>x. f x x) ` Y)"
   127     using chain by(rule chain_imageI)(auto intro: monotoneD[OF mono1] mono2 order.trans)
   128 
   129   show "?lhs \<le> ?rhs" using chain1
   130   proof(rule ccpo_Sup_least)
   131     fix x'
   132     assume "x' \<in> (\<lambda>x. \<Squnion>(f x ` Y)) ` Y"
   133     then obtain y' where "y' \<in> Y" "x' = \<Squnion>(f y' ` Y)" by blast note this(2)
   134     also have "\<dots> \<le> ?rhs" using chain2[OF \<open>y' \<in> Y\<close>]
   135     proof(rule ccpo_Sup_least)
   136       fix x
   137       assume "x \<in> f y' ` Y"
   138       then obtain y where "y \<in> Y" and x: "x = f y' y" by blast
   139       define y'' where "y'' = (if y \<sqsubseteq> y' then y' else y)"
   140       from chain \<open>y \<in> Y\<close> \<open>y' \<in> Y\<close> have "y \<sqsubseteq> y' \<or> y' \<sqsubseteq> y" by(rule chainD)
   141       hence "f y' y \<le> f y'' y''" using \<open>y \<in> Y\<close> \<open>y' \<in> Y\<close>
   142         by(auto simp add: y''_def intro: mono2 monotoneD[OF mono1])
   143       also from \<open>y \<in> Y\<close> \<open>y' \<in> Y\<close> have "y'' \<in> Y" by(simp add: y''_def)
   144       from chain3 have "f y'' y'' \<le> ?rhs" by(rule ccpo_Sup_upper)(simp add: \<open>y'' \<in> Y\<close>)
   145       finally show "x \<le> ?rhs" by(simp add: x)
   146     qed
   147     finally show "x' \<le> ?rhs" .
   148   qed
   149 
   150   show "?rhs \<le> ?lhs" using chain3
   151   proof(rule ccpo_Sup_least)
   152     fix y
   153     assume "y \<in> (\<lambda>x. f x x) ` Y"
   154     then obtain x where "x \<in> Y" and "y = f x x" by blast note this(2)
   155     also from chain2[OF \<open>x \<in> Y\<close>] have "\<dots> \<le> \<Squnion>(f x ` Y)"
   156       by(rule ccpo_Sup_upper)(simp add: \<open>x \<in> Y\<close>)
   157     also have "\<dots> \<le> ?lhs" by(rule ccpo_Sup_upper[OF chain1])(simp add: \<open>x \<in> Y\<close>)
   158     finally show "y \<le> ?lhs" .
   159   qed
   160 qed
   161 
   162 end
   163 
   164 lemma Sup_image_mono_le:
   165   fixes le_b (infix "\<sqsubseteq>" 60) and Sup_b ("\<Or>_" [900] 900)
   166   assumes ccpo: "class.ccpo Sup_b op \<sqsubseteq> lt_b"
   167   assumes chain: "Complete_Partial_Order.chain op \<sqsubseteq> Y"
   168   and mono: "\<And>x y. \<lbrakk> x \<sqsubseteq> y; x \<in> Y \<rbrakk> \<Longrightarrow> f x \<le> f y"
   169   shows "Sup (f ` Y) \<le> f (\<Or>Y)"
   170 proof(rule ccpo_Sup_least)
   171   show "Complete_Partial_Order.chain op \<le> (f ` Y)"
   172     using chain by(rule chain_imageI)(rule mono)
   173 
   174   fix x
   175   assume "x \<in> f ` Y"
   176   then obtain y where "y \<in> Y" and "x = f y" by blast note this(2)
   177   also have "y \<sqsubseteq> \<Or>Y" using ccpo chain \<open>y \<in> Y\<close> by(rule ccpo.ccpo_Sup_upper)
   178   hence "f y \<le> f (\<Or>Y)" using \<open>y \<in> Y\<close> by(rule mono)
   179   finally show "x \<le> \<dots>" .
   180 qed
   181 
   182 lemma swap_Sup:
   183   fixes le_b (infix "\<sqsubseteq>" 60)
   184   assumes Y: "Complete_Partial_Order.chain op \<sqsubseteq> Y"
   185   and Z: "Complete_Partial_Order.chain (fun_ord op \<le>) Z"
   186   and mono: "\<And>f. f \<in> Z \<Longrightarrow> monotone op \<sqsubseteq> op \<le> f"
   187   shows "\<Squnion>((\<lambda>x. \<Squnion>(x ` Y)) ` Z) = \<Squnion>((\<lambda>x. \<Squnion>((\<lambda>f. f x) ` Z)) ` Y)"
   188   (is "?lhs = ?rhs")
   189 proof(cases "Y = {}")
   190   case True
   191   then show ?thesis
   192     by (simp add: image_constant_conv cong del: strong_SUP_cong)
   193 next
   194   case False
   195   have chain1: "\<And>f. f \<in> Z \<Longrightarrow> Complete_Partial_Order.chain op \<le> (f ` Y)"
   196     by(rule chain_imageI[OF Y])(rule monotoneD[OF mono])
   197   have chain2: "Complete_Partial_Order.chain op \<le> ((\<lambda>x. \<Squnion>(x ` Y)) ` Z)" using Z
   198   proof(rule chain_imageI)
   199     fix f g
   200     assume "f \<in> Z" "g \<in> Z"
   201       and "fun_ord op \<le> f g"
   202     from chain1[OF \<open>f \<in> Z\<close>] show "\<Squnion>(f ` Y) \<le> \<Squnion>(g ` Y)"
   203     proof(rule ccpo_Sup_least)
   204       fix x
   205       assume "x \<in> f ` Y"
   206       then obtain y where "y \<in> Y" "x = f y" by blast note this(2)
   207       also have "\<dots> \<le> g y" using \<open>fun_ord op \<le> f g\<close> by(simp add: fun_ord_def)
   208       also have "\<dots> \<le> \<Squnion>(g ` Y)" using chain1[OF \<open>g \<in> Z\<close>]
   209         by(rule ccpo_Sup_upper)(simp add: \<open>y \<in> Y\<close>)
   210       finally show "x \<le> \<Squnion>(g ` Y)" .
   211     qed
   212   qed
   213   have chain3: "\<And>x. Complete_Partial_Order.chain op \<le> ((\<lambda>f. f x) ` Z)"
   214     using Z by(rule chain_imageI)(simp add: fun_ord_def)
   215   have chain4: "Complete_Partial_Order.chain op \<le> ((\<lambda>x. \<Squnion>((\<lambda>f. f x) ` Z)) ` Y)"
   216     using Y
   217   proof(rule chain_imageI)
   218     fix f x y
   219     assume "x \<sqsubseteq> y"
   220     show "\<Squnion>((\<lambda>f. f x) ` Z) \<le> \<Squnion>((\<lambda>f. f y) ` Z)" (is "_ \<le> ?rhs") using chain3
   221     proof(rule ccpo_Sup_least)
   222       fix x'
   223       assume "x' \<in> (\<lambda>f. f x) ` Z"
   224       then obtain f where "f \<in> Z" "x' = f x" by blast note this(2)
   225       also have "f x \<le> f y" using \<open>f \<in> Z\<close> \<open>x \<sqsubseteq> y\<close> by(rule monotoneD[OF mono])
   226       also have "f y \<le> ?rhs" using chain3
   227         by(rule ccpo_Sup_upper)(simp add: \<open>f \<in> Z\<close>)
   228       finally show "x' \<le> ?rhs" .
   229     qed
   230   qed
   231 
   232   from chain2 have "?lhs \<le> ?rhs"
   233   proof(rule ccpo_Sup_least)
   234     fix x
   235     assume "x \<in> (\<lambda>x. \<Squnion>(x ` Y)) ` Z"
   236     then obtain f where "f \<in> Z" "x = \<Squnion>(f ` Y)" by blast note this(2)
   237     also have "\<dots> \<le> ?rhs" using chain1[OF \<open>f \<in> Z\<close>]
   238     proof(rule ccpo_Sup_least)
   239       fix x'
   240       assume "x' \<in> f ` Y"
   241       then obtain y where "y \<in> Y" "x' = f y" by blast note this(2)
   242       also have "f y \<le> \<Squnion>((\<lambda>f. f y) ` Z)" using chain3
   243         by(rule ccpo_Sup_upper)(simp add: \<open>f \<in> Z\<close>)
   244       also have "\<dots> \<le> ?rhs" using chain4 by(rule ccpo_Sup_upper)(simp add: \<open>y \<in> Y\<close>)
   245       finally show "x' \<le> ?rhs" .
   246     qed
   247     finally show "x \<le> ?rhs" .
   248   qed
   249   moreover
   250   have "?rhs \<le> ?lhs" using chain4
   251   proof(rule ccpo_Sup_least)
   252     fix x
   253     assume "x \<in> (\<lambda>x. \<Squnion>((\<lambda>f. f x) ` Z)) ` Y"
   254     then obtain y where "y \<in> Y" "x = \<Squnion>((\<lambda>f. f y) ` Z)" by blast note this(2)
   255     also have "\<dots> \<le> ?lhs" using chain3
   256     proof(rule ccpo_Sup_least)
   257       fix x'
   258       assume "x' \<in> (\<lambda>f. f y) ` Z"
   259       then obtain f where "f \<in> Z" "x' = f y" by blast note this(2)
   260       also have "f y \<le> \<Squnion>(f ` Y)" using chain1[OF \<open>f \<in> Z\<close>]
   261         by(rule ccpo_Sup_upper)(simp add: \<open>y \<in> Y\<close>)
   262       also have "\<dots> \<le> ?lhs" using chain2
   263         by(rule ccpo_Sup_upper)(simp add: \<open>f \<in> Z\<close>)
   264       finally show "x' \<le> ?lhs" .
   265     qed
   266     finally show "x \<le> ?lhs" .
   267   qed
   268   ultimately show "?lhs = ?rhs" by(rule antisym)
   269 qed
   270 
   271 lemma fixp_mono:
   272   assumes fg: "fun_ord op \<le> f g"
   273   and f: "monotone op \<le> op \<le> f"
   274   and g: "monotone op \<le> op \<le> g"
   275   shows "ccpo_class.fixp f \<le> ccpo_class.fixp g"
   276 unfolding fixp_def
   277 proof(rule ccpo_Sup_least)
   278   fix x
   279   assume "x \<in> ccpo_class.iterates f"
   280   thus "x \<le> \<Squnion>ccpo_class.iterates g"
   281   proof induction
   282     case (step x)
   283     from f step.IH have "f x \<le> f (\<Squnion>ccpo_class.iterates g)" by(rule monotoneD)
   284     also have "\<dots> \<le> g (\<Squnion>ccpo_class.iterates g)" using fg by(simp add: fun_ord_def)
   285     also have "\<dots> = \<Squnion>ccpo_class.iterates g" by(fold fixp_def fixp_unfold[OF g]) simp
   286     finally show ?case .
   287   qed(blast intro: ccpo_Sup_least)
   288 qed(rule chain_iterates[OF f])
   289 
   290 context fixes ordb :: "'b \<Rightarrow> 'b \<Rightarrow> bool" (infix "\<sqsubseteq>" 60) begin
   291 
   292 lemma iterates_mono:
   293   assumes f: "f \<in> ccpo.iterates (fun_lub Sup) (fun_ord op \<le>) F"
   294   and mono: "\<And>f. monotone op \<sqsubseteq> op \<le> f \<Longrightarrow> monotone op \<sqsubseteq> op \<le> (F f)"
   295   shows "monotone op \<sqsubseteq> op \<le> f"
   296 using f
   297 by(induction rule: ccpo.iterates.induct[OF ccpo_fun, consumes 1, case_names step Sup])(blast intro: mono mono_lub)+
   298 
   299 lemma fixp_preserves_mono:
   300   assumes mono: "\<And>x. monotone (fun_ord op \<le>) op \<le> (\<lambda>f. F f x)"
   301   and mono2: "\<And>f. monotone op \<sqsubseteq> op \<le> f \<Longrightarrow> monotone op \<sqsubseteq> op \<le> (F f)"
   302   shows "monotone op \<sqsubseteq> op \<le> (ccpo.fixp (fun_lub Sup) (fun_ord op \<le>) F)"
   303   (is "monotone _ _ ?fixp")
   304 proof(rule monotoneI)
   305   have mono: "monotone (fun_ord op \<le>) (fun_ord op \<le>) F"
   306     by(rule monotoneI)(auto simp add: fun_ord_def intro: monotoneD[OF mono])
   307   let ?iter = "ccpo.iterates (fun_lub Sup) (fun_ord op \<le>) F"
   308   have chain: "\<And>x. Complete_Partial_Order.chain op \<le> ((\<lambda>f. f x) ` ?iter)"
   309     by(rule chain_imageI[OF ccpo.chain_iterates[OF ccpo_fun mono]])(simp add: fun_ord_def)
   310 
   311   fix x y
   312   assume "x \<sqsubseteq> y"
   313   show "?fixp x \<le> ?fixp y"
   314     apply (simp only: ccpo.fixp_def[OF ccpo_fun] fun_lub_apply)
   315     using chain
   316   proof(rule ccpo_Sup_least)
   317     fix x'
   318     assume "x' \<in> (\<lambda>f. f x) ` ?iter"
   319     then obtain f where "f \<in> ?iter" "x' = f x" by blast note this(2)
   320     also have "f x \<le> f y"
   321       by(rule monotoneD[OF iterates_mono[OF \<open>f \<in> ?iter\<close> mono2]])(blast intro: \<open>x \<sqsubseteq> y\<close>)+
   322     also have "f y \<le> \<Squnion>((\<lambda>f. f y) ` ?iter)" using chain
   323       by(rule ccpo_Sup_upper)(simp add: \<open>f \<in> ?iter\<close>)
   324     finally show "x' \<le> \<dots>" .
   325   qed
   326 qed
   327 
   328 end
   329 
   330 end
   331 
   332 lemma monotone2monotone:
   333   assumes 2: "\<And>x. monotone ordb ordc (\<lambda>y. f x y)"
   334   and t: "monotone orda ordb (\<lambda>x. t x)"
   335   and 1: "\<And>y. monotone orda ordc (\<lambda>x. f x y)"
   336   and trans: "transp ordc"
   337   shows "monotone orda ordc (\<lambda>x. f x (t x))"
   338 by(blast intro: monotoneI transpD[OF trans] monotoneD[OF t] monotoneD[OF 2] monotoneD[OF 1])
   339 
   340 subsection \<open>Continuity\<close>
   341 
   342 definition cont :: "('a set \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('b set \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> bool"
   343 where
   344   "cont luba orda lubb ordb f \<longleftrightarrow> 
   345   (\<forall>Y. Complete_Partial_Order.chain orda Y \<longrightarrow> Y \<noteq> {} \<longrightarrow> f (luba Y) = lubb (f ` Y))"
   346 
   347 definition mcont :: "('a set \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('b set \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> bool"
   348 where
   349   "mcont luba orda lubb ordb f \<longleftrightarrow>
   350    monotone orda ordb f \<and> cont luba orda lubb ordb f"
   351 
   352 subsubsection \<open>Theorem collection \<open>cont_intro\<close>\<close>
   353 
   354 named_theorems cont_intro "continuity and admissibility intro rules"
   355 ML \<open>
   356 (* apply cont_intro rules as intro and try to solve 
   357    the remaining of the emerging subgoals with simp *)
   358 fun cont_intro_tac ctxt =
   359   REPEAT_ALL_NEW (resolve_tac ctxt (rev (Named_Theorems.get ctxt @{named_theorems cont_intro})))
   360   THEN_ALL_NEW (SOLVED' (simp_tac ctxt))
   361 
   362 fun cont_intro_simproc ctxt ct =
   363   let
   364     fun mk_stmt t = t
   365       |> HOLogic.mk_Trueprop
   366       |> Thm.cterm_of ctxt
   367       |> Goal.init
   368     fun mk_thm t =
   369       case SINGLE (cont_intro_tac ctxt 1) (mk_stmt t) of
   370         SOME thm => SOME (Goal.finish ctxt thm RS @{thm Eq_TrueI})
   371       | NONE => NONE
   372   in
   373     case Thm.term_of ct of
   374       t as Const (@{const_name ccpo.admissible}, _) $ _ $ _ $ _ => mk_thm t
   375     | t as Const (@{const_name mcont}, _) $ _ $ _ $ _ $ _ $ _ => mk_thm t
   376     | t as Const (@{const_name monotone}, _) $ _ $ _ $ _ => mk_thm t
   377     | _ => NONE
   378   end
   379   handle THM _ => NONE 
   380   | TYPE _ => NONE
   381 \<close>
   382 
   383 simproc_setup "cont_intro"
   384   ( "ccpo.admissible lub ord P"
   385   | "mcont lub ord lub' ord' f"
   386   | "monotone ord ord' f"
   387   ) = \<open>K cont_intro_simproc\<close>
   388 
   389 lemmas [cont_intro] =
   390   call_mono
   391   let_mono
   392   if_mono
   393   option.const_mono
   394   tailrec.const_mono
   395   bind_mono
   396 
   397 declare if_mono[simp]
   398 
   399 lemma monotone_id' [cont_intro]: "monotone ord ord (\<lambda>x. x)"
   400 by(simp add: monotone_def)
   401 
   402 lemma monotone_applyI:
   403   "monotone orda ordb F \<Longrightarrow> monotone (fun_ord orda) ordb (\<lambda>f. F (f x))"
   404 by(rule monotoneI)(auto simp add: fun_ord_def dest: monotoneD)
   405 
   406 lemma monotone_if_fun [partial_function_mono]:
   407   "\<lbrakk> monotone (fun_ord orda) (fun_ord ordb) F; monotone (fun_ord orda) (fun_ord ordb) G \<rbrakk>
   408   \<Longrightarrow> monotone (fun_ord orda) (fun_ord ordb) (\<lambda>f n. if c n then F f n else G f n)"
   409 by(simp add: monotone_def fun_ord_def)
   410 
   411 lemma monotone_fun_apply_fun [partial_function_mono]: 
   412   "monotone (fun_ord (fun_ord ord)) (fun_ord ord) (\<lambda>f n. f t (g n))"
   413 by(rule monotoneI)(simp add: fun_ord_def)
   414 
   415 lemma monotone_fun_ord_apply: 
   416   "monotone orda (fun_ord ordb) f \<longleftrightarrow> (\<forall>x. monotone orda ordb (\<lambda>y. f y x))"
   417 by(auto simp add: monotone_def fun_ord_def)
   418 
   419 context preorder begin
   420 
   421 lemma transp_le [simp, cont_intro]: "transp op \<le>"
   422 by(rule transpI)(rule order_trans)
   423 
   424 lemma monotone_const [simp, cont_intro]: "monotone ord op \<le> (\<lambda>_. c)"
   425 by(rule monotoneI) simp
   426 
   427 end
   428 
   429 lemma transp_le [cont_intro, simp]:
   430   "class.preorder ord (mk_less ord) \<Longrightarrow> transp ord"
   431 by(rule preorder.transp_le)
   432 
   433 context partial_function_definitions begin
   434 
   435 declare const_mono [cont_intro, simp]
   436 
   437 lemma transp_le [cont_intro, simp]: "transp leq"
   438 by(rule transpI)(rule leq_trans)
   439 
   440 lemma preorder [cont_intro, simp]: "class.preorder leq (mk_less leq)"
   441 by(unfold_locales)(auto simp add: mk_less_def intro: leq_refl leq_trans)
   442 
   443 declare ccpo[cont_intro, simp]
   444 
   445 end
   446 
   447 lemma contI [intro?]:
   448   "(\<And>Y. \<lbrakk> Complete_Partial_Order.chain orda Y; Y \<noteq> {} \<rbrakk> \<Longrightarrow> f (luba Y) = lubb (f ` Y)) 
   449   \<Longrightarrow> cont luba orda lubb ordb f"
   450 unfolding cont_def by blast
   451 
   452 lemma contD:
   453   "\<lbrakk> cont luba orda lubb ordb f; Complete_Partial_Order.chain orda Y; Y \<noteq> {} \<rbrakk> 
   454   \<Longrightarrow> f (luba Y) = lubb (f ` Y)"
   455 unfolding cont_def by blast
   456 
   457 lemma cont_id [simp, cont_intro]: "\<And>Sup. cont Sup ord Sup ord id"
   458 by(rule contI) simp
   459 
   460 lemma cont_id' [simp, cont_intro]: "\<And>Sup. cont Sup ord Sup ord (\<lambda>x. x)"
   461 using cont_id[unfolded id_def] .
   462 
   463 lemma cont_applyI [cont_intro]:
   464   assumes cont: "cont luba orda lubb ordb g"
   465   shows "cont (fun_lub luba) (fun_ord orda) lubb ordb (\<lambda>f. g (f x))"
   466 by(rule contI)(drule chain_fun_ordD[where x=x], simp add: fun_lub_apply image_image contD[OF cont])
   467 
   468 lemma call_cont: "cont (fun_lub lub) (fun_ord ord) lub ord (\<lambda>f. f t)"
   469 by(simp add: cont_def fun_lub_apply)
   470 
   471 lemma cont_if [cont_intro]:
   472   "\<lbrakk> cont luba orda lubb ordb f; cont luba orda lubb ordb g \<rbrakk>
   473   \<Longrightarrow> cont luba orda lubb ordb (\<lambda>x. if c then f x else g x)"
   474 by(cases c) simp_all
   475 
   476 lemma mcontI [intro?]:
   477    "\<lbrakk> monotone orda ordb f; cont luba orda lubb ordb f \<rbrakk> \<Longrightarrow> mcont luba orda lubb ordb f"
   478 by(simp add: mcont_def)
   479 
   480 lemma mcont_mono: "mcont luba orda lubb ordb f \<Longrightarrow> monotone orda ordb f"
   481 by(simp add: mcont_def)
   482 
   483 lemma mcont_cont [simp]: "mcont luba orda lubb ordb f \<Longrightarrow> cont luba orda lubb ordb f"
   484 by(simp add: mcont_def)
   485 
   486 lemma mcont_monoD:
   487   "\<lbrakk> mcont luba orda lubb ordb f; orda x y \<rbrakk> \<Longrightarrow> ordb (f x) (f y)"
   488 by(auto simp add: mcont_def dest: monotoneD)
   489 
   490 lemma mcont_contD:
   491   "\<lbrakk> mcont luba orda lubb ordb f; Complete_Partial_Order.chain orda Y; Y \<noteq> {} \<rbrakk>
   492   \<Longrightarrow> f (luba Y) = lubb (f ` Y)"
   493 by(auto simp add: mcont_def dest: contD)
   494 
   495 lemma mcont_call [cont_intro, simp]:
   496   "mcont (fun_lub lub) (fun_ord ord) lub ord (\<lambda>f. f t)"
   497 by(simp add: mcont_def call_mono call_cont)
   498 
   499 lemma mcont_id' [cont_intro, simp]: "mcont lub ord lub ord (\<lambda>x. x)"
   500 by(simp add: mcont_def monotone_id')
   501 
   502 lemma mcont_applyI:
   503   "mcont luba orda lubb ordb (\<lambda>x. F x) \<Longrightarrow> mcont (fun_lub luba) (fun_ord orda) lubb ordb (\<lambda>f. F (f x))"
   504 by(simp add: mcont_def monotone_applyI cont_applyI)
   505 
   506 lemma mcont_if [cont_intro, simp]:
   507   "\<lbrakk> mcont luba orda lubb ordb (\<lambda>x. f x); mcont luba orda lubb ordb (\<lambda>x. g x) \<rbrakk>
   508   \<Longrightarrow> mcont luba orda lubb ordb (\<lambda>x. if c then f x else g x)"
   509 by(simp add: mcont_def cont_if)
   510 
   511 lemma cont_fun_lub_apply: 
   512   "cont luba orda (fun_lub lubb) (fun_ord ordb) f \<longleftrightarrow> (\<forall>x. cont luba orda lubb ordb (\<lambda>y. f y x))"
   513 by(simp add: cont_def fun_lub_def fun_eq_iff)(auto simp add: image_def)
   514 
   515 lemma mcont_fun_lub_apply: 
   516   "mcont luba orda (fun_lub lubb) (fun_ord ordb) f \<longleftrightarrow> (\<forall>x. mcont luba orda lubb ordb (\<lambda>y. f y x))"
   517 by(auto simp add: monotone_fun_ord_apply cont_fun_lub_apply mcont_def)
   518 
   519 context ccpo begin
   520 
   521 lemma cont_const [simp, cont_intro]: "cont luba orda Sup op \<le> (\<lambda>x. c)"
   522 by (rule contI) (simp add: image_constant_conv cong del: strong_SUP_cong)
   523 
   524 lemma mcont_const [cont_intro, simp]:
   525   "mcont luba orda Sup op \<le> (\<lambda>x. c)"
   526 by(simp add: mcont_def)
   527 
   528 lemma cont_apply:
   529   assumes 2: "\<And>x. cont lubb ordb Sup op \<le> (\<lambda>y. f x y)"
   530   and t: "cont luba orda lubb ordb (\<lambda>x. t x)"
   531   and 1: "\<And>y. cont luba orda Sup op \<le> (\<lambda>x. f x y)"
   532   and mono: "monotone orda ordb (\<lambda>x. t x)"
   533   and mono2: "\<And>x. monotone ordb op \<le> (\<lambda>y. f x y)"
   534   and mono1: "\<And>y. monotone orda op \<le> (\<lambda>x. f x y)"
   535   shows "cont luba orda Sup op \<le> (\<lambda>x. f x (t x))"
   536 proof
   537   fix Y
   538   assume chain: "Complete_Partial_Order.chain orda Y" and "Y \<noteq> {}"
   539   moreover from chain have chain': "Complete_Partial_Order.chain ordb (t ` Y)"
   540     by(rule chain_imageI)(rule monotoneD[OF mono])
   541   ultimately show "f (luba Y) (t (luba Y)) = \<Squnion>((\<lambda>x. f x (t x)) ` Y)"
   542     by(simp add: contD[OF 1] contD[OF t] contD[OF 2] image_image)
   543       (rule diag_Sup[OF chain], auto intro: monotone2monotone[OF mono2 mono monotone_const transpI] monotoneD[OF mono1])
   544 qed
   545 
   546 lemma mcont2mcont':
   547   "\<lbrakk> \<And>x. mcont lub' ord' Sup op \<le> (\<lambda>y. f x y);
   548      \<And>y. mcont lub ord Sup op \<le> (\<lambda>x. f x y);
   549      mcont lub ord lub' ord' (\<lambda>y. t y) \<rbrakk>
   550   \<Longrightarrow> mcont lub ord Sup op \<le> (\<lambda>x. f x (t x))"
   551 unfolding mcont_def by(blast intro: transp_le monotone2monotone cont_apply)
   552 
   553 lemma mcont2mcont:
   554   "\<lbrakk>mcont lub' ord' Sup op \<le> (\<lambda>x. f x); mcont lub ord lub' ord' (\<lambda>x. t x)\<rbrakk> 
   555   \<Longrightarrow> mcont lub ord Sup op \<le> (\<lambda>x. f (t x))"
   556 by(rule mcont2mcont'[OF _ mcont_const]) 
   557 
   558 context
   559   fixes ord :: "'b \<Rightarrow> 'b \<Rightarrow> bool" (infix "\<sqsubseteq>" 60) 
   560   and lub :: "'b set \<Rightarrow> 'b" ("\<Or>_" [900] 900)
   561 begin
   562 
   563 lemma cont_fun_lub_Sup:
   564   assumes chainM: "Complete_Partial_Order.chain (fun_ord op \<le>) M"
   565   and mcont [rule_format]: "\<forall>f\<in>M. mcont lub op \<sqsubseteq> Sup op \<le> f"
   566   shows "cont lub op \<sqsubseteq> Sup op \<le> (fun_lub Sup M)"
   567 proof(rule contI)
   568   fix Y
   569   assume chain: "Complete_Partial_Order.chain op \<sqsubseteq> Y"
   570     and Y: "Y \<noteq> {}"
   571   from swap_Sup[OF chain chainM mcont[THEN mcont_mono]]
   572   show "fun_lub Sup M (\<Or>Y) = \<Squnion>(fun_lub Sup M ` Y)"
   573     by(simp add: mcont_contD[OF mcont chain Y] fun_lub_apply cong: image_cong)
   574 qed
   575 
   576 lemma mcont_fun_lub_Sup:
   577   "\<lbrakk> Complete_Partial_Order.chain (fun_ord op \<le>) M;
   578     \<forall>f\<in>M. mcont lub ord Sup op \<le> f \<rbrakk>
   579   \<Longrightarrow> mcont lub op \<sqsubseteq> Sup op \<le> (fun_lub Sup M)"
   580 by(simp add: mcont_def cont_fun_lub_Sup mono_lub)
   581 
   582 lemma iterates_mcont:
   583   assumes f: "f \<in> ccpo.iterates (fun_lub Sup) (fun_ord op \<le>) F"
   584   and mono: "\<And>f. mcont lub op \<sqsubseteq> Sup op \<le> f \<Longrightarrow> mcont lub op \<sqsubseteq> Sup op \<le> (F f)"
   585   shows "mcont lub op \<sqsubseteq> Sup op \<le> f"
   586 using f
   587 by(induction rule: ccpo.iterates.induct[OF ccpo_fun, consumes 1, case_names step Sup])(blast intro: mono mcont_fun_lub_Sup)+
   588 
   589 lemma fixp_preserves_mcont:
   590   assumes mono: "\<And>x. monotone (fun_ord op \<le>) op \<le> (\<lambda>f. F f x)"
   591   and mcont: "\<And>f. mcont lub op \<sqsubseteq> Sup op \<le> f \<Longrightarrow> mcont lub op \<sqsubseteq> Sup op \<le> (F f)"
   592   shows "mcont lub op \<sqsubseteq> Sup op \<le> (ccpo.fixp (fun_lub Sup) (fun_ord op \<le>) F)"
   593   (is "mcont _ _ _ _ ?fixp")
   594 unfolding mcont_def
   595 proof(intro conjI monotoneI contI)
   596   have mono: "monotone (fun_ord op \<le>) (fun_ord op \<le>) F"
   597     by(rule monotoneI)(auto simp add: fun_ord_def intro: monotoneD[OF mono])
   598   let ?iter = "ccpo.iterates (fun_lub Sup) (fun_ord op \<le>) F"
   599   have chain: "\<And>x. Complete_Partial_Order.chain op \<le> ((\<lambda>f. f x) ` ?iter)"
   600     by(rule chain_imageI[OF ccpo.chain_iterates[OF ccpo_fun mono]])(simp add: fun_ord_def)
   601 
   602   {
   603     fix x y
   604     assume "x \<sqsubseteq> y"
   605     show "?fixp x \<le> ?fixp y"
   606       apply (simp only: ccpo.fixp_def[OF ccpo_fun] fun_lub_apply)
   607       using chain
   608     proof(rule ccpo_Sup_least)
   609       fix x'
   610       assume "x' \<in> (\<lambda>f. f x) ` ?iter"
   611       then obtain f where "f \<in> ?iter" "x' = f x" by blast note this(2)
   612       also from _ \<open>x \<sqsubseteq> y\<close> have "f x \<le> f y"
   613         by(rule mcont_monoD[OF iterates_mcont[OF \<open>f \<in> ?iter\<close> mcont]])
   614       also have "f y \<le> \<Squnion>((\<lambda>f. f y) ` ?iter)" using chain
   615         by(rule ccpo_Sup_upper)(simp add: \<open>f \<in> ?iter\<close>)
   616       finally show "x' \<le> \<dots>" .
   617     qed
   618   next
   619     fix Y
   620     assume chain: "Complete_Partial_Order.chain op \<sqsubseteq> Y"
   621       and Y: "Y \<noteq> {}"
   622     { fix f
   623       assume "f \<in> ?iter"
   624       hence "f (\<Or>Y) = \<Squnion>(f ` Y)"
   625         using mcont chain Y by(rule mcont_contD[OF iterates_mcont]) }
   626     moreover have "\<Squnion>((\<lambda>f. \<Squnion>(f ` Y)) ` ?iter) = \<Squnion>((\<lambda>x. \<Squnion>((\<lambda>f. f x) ` ?iter)) ` Y)"
   627       using chain ccpo.chain_iterates[OF ccpo_fun mono]
   628       by(rule swap_Sup)(rule mcont_mono[OF iterates_mcont[OF _ mcont]])
   629     ultimately show "?fixp (\<Or>Y) = \<Squnion>(?fixp ` Y)" unfolding ccpo.fixp_def[OF ccpo_fun]
   630       by(simp add: fun_lub_apply cong: image_cong)
   631   }
   632 qed
   633 
   634 end
   635 
   636 context
   637   fixes F :: "'c \<Rightarrow> 'c" and U :: "'c \<Rightarrow> 'b \<Rightarrow> 'a" and C :: "('b \<Rightarrow> 'a) \<Rightarrow> 'c" and f
   638   assumes mono: "\<And>x. monotone (fun_ord op \<le>) op \<le> (\<lambda>f. U (F (C f)) x)"
   639   and eq: "f \<equiv> C (ccpo.fixp (fun_lub Sup) (fun_ord op \<le>) (\<lambda>f. U (F (C f))))"
   640   and inverse: "\<And>f. U (C f) = f"
   641 begin
   642 
   643 lemma fixp_preserves_mono_uc:
   644   assumes mono2: "\<And>f. monotone ord op \<le> (U f) \<Longrightarrow> monotone ord op \<le> (U (F f))"
   645   shows "monotone ord op \<le> (U f)"
   646 using fixp_preserves_mono[OF mono mono2] by(subst eq)(simp add: inverse)
   647 
   648 lemma fixp_preserves_mcont_uc:
   649   assumes mcont: "\<And>f. mcont lubb ordb Sup op \<le> (U f) \<Longrightarrow> mcont lubb ordb Sup op \<le> (U (F f))"
   650   shows "mcont lubb ordb Sup op \<le> (U f)"
   651 using fixp_preserves_mcont[OF mono mcont] by(subst eq)(simp add: inverse)
   652 
   653 end
   654 
   655 lemmas fixp_preserves_mono1 = fixp_preserves_mono_uc[of "\<lambda>x. x" _ "\<lambda>x. x", OF _ _ refl]
   656 lemmas fixp_preserves_mono2 =
   657   fixp_preserves_mono_uc[of "case_prod" _ "curry", unfolded case_prod_curry curry_case_prod, OF _ _ refl]
   658 lemmas fixp_preserves_mono3 =
   659   fixp_preserves_mono_uc[of "\<lambda>f. case_prod (case_prod f)" _ "\<lambda>f. curry (curry f)", unfolded case_prod_curry curry_case_prod, OF _ _ refl]
   660 lemmas fixp_preserves_mono4 =
   661   fixp_preserves_mono_uc[of "\<lambda>f. case_prod (case_prod (case_prod f))" _ "\<lambda>f. curry (curry (curry f))", unfolded case_prod_curry curry_case_prod, OF _ _ refl]
   662 
   663 lemmas fixp_preserves_mcont1 = fixp_preserves_mcont_uc[of "\<lambda>x. x" _ "\<lambda>x. x", OF _ _ refl]
   664 lemmas fixp_preserves_mcont2 =
   665   fixp_preserves_mcont_uc[of "case_prod" _ "curry", unfolded case_prod_curry curry_case_prod, OF _ _ refl]
   666 lemmas fixp_preserves_mcont3 =
   667   fixp_preserves_mcont_uc[of "\<lambda>f. case_prod (case_prod f)" _ "\<lambda>f. curry (curry f)", unfolded case_prod_curry curry_case_prod, OF _ _ refl]
   668 lemmas fixp_preserves_mcont4 =
   669   fixp_preserves_mcont_uc[of "\<lambda>f. case_prod (case_prod (case_prod f))" _ "\<lambda>f. curry (curry (curry f))", unfolded case_prod_curry curry_case_prod, OF _ _ refl]
   670 
   671 end
   672 
   673 lemma (in preorder) monotone_if_bot:
   674   fixes bot
   675   assumes mono: "\<And>x y. \<lbrakk> x \<le> y; \<not> (x \<le> bound) \<rbrakk> \<Longrightarrow> ord (f x) (f y)"
   676   and bot: "\<And>x. \<not> x \<le> bound \<Longrightarrow> ord bot (f x)" "ord bot bot"
   677   shows "monotone op \<le> ord (\<lambda>x. if x \<le> bound then bot else f x)"
   678 by(rule monotoneI)(auto intro: bot intro: mono order_trans)
   679 
   680 lemma (in ccpo) mcont_if_bot:
   681   fixes bot and lub ("\<Or>_" [900] 900) and ord (infix "\<sqsubseteq>" 60)
   682   assumes ccpo: "class.ccpo lub op \<sqsubseteq> lt"
   683   and mono: "\<And>x y. \<lbrakk> x \<le> y; \<not> x \<le> bound \<rbrakk> \<Longrightarrow> f x \<sqsubseteq> f y"
   684   and cont: "\<And>Y. \<lbrakk> Complete_Partial_Order.chain op \<le> Y; Y \<noteq> {}; \<And>x. x \<in> Y \<Longrightarrow> \<not> x \<le> bound \<rbrakk> \<Longrightarrow> f (\<Squnion>Y) = \<Or>(f ` Y)"
   685   and bot: "\<And>x. \<not> x \<le> bound \<Longrightarrow> bot \<sqsubseteq> f x"
   686   shows "mcont Sup op \<le> lub op \<sqsubseteq> (\<lambda>x. if x \<le> bound then bot else f x)" (is "mcont _ _ _ _ ?g")
   687 proof(intro mcontI contI)
   688   interpret c: ccpo lub "op \<sqsubseteq>" lt by(fact ccpo)
   689   show "monotone op \<le> op \<sqsubseteq> ?g" by(rule monotone_if_bot)(simp_all add: mono bot)
   690 
   691   fix Y
   692   assume chain: "Complete_Partial_Order.chain op \<le> Y" and Y: "Y \<noteq> {}"
   693   show "?g (\<Squnion>Y) = \<Or>(?g ` Y)"
   694   proof(cases "Y \<subseteq> {x. x \<le> bound}")
   695     case True
   696     hence "\<Squnion>Y \<le> bound" using chain by(auto intro: ccpo_Sup_least)
   697     moreover have "Y \<inter> {x. \<not> x \<le> bound} = {}" using True by auto
   698     ultimately show ?thesis using True Y
   699       by (auto simp add: image_constant_conv cong del: c.strong_SUP_cong)
   700   next
   701     case False
   702     let ?Y = "Y \<inter> {x. \<not> x \<le> bound}"
   703     have chain': "Complete_Partial_Order.chain op \<le> ?Y"
   704       using chain by(rule chain_subset) simp
   705 
   706     from False obtain y where ybound: "\<not> y \<le> bound" and y: "y \<in> Y" by blast
   707     hence "\<not> \<Squnion>Y \<le> bound" by (metis ccpo_Sup_upper chain order.trans)
   708     hence "?g (\<Squnion>Y) = f (\<Squnion>Y)" by simp
   709     also have "\<Squnion>Y \<le> \<Squnion>?Y" using chain
   710     proof(rule ccpo_Sup_least)
   711       fix x
   712       assume x: "x \<in> Y"
   713       show "x \<le> \<Squnion>?Y"
   714       proof(cases "x \<le> bound")
   715         case True
   716         with chainD[OF chain x y] have "x \<le> y" using ybound by(auto intro: order_trans)
   717         thus ?thesis by(rule order_trans)(auto intro: ccpo_Sup_upper[OF chain'] simp add: y ybound)
   718       qed(auto intro: ccpo_Sup_upper[OF chain'] simp add: x)
   719     qed
   720     hence "\<Squnion>Y = \<Squnion>?Y" by(rule antisym)(blast intro: ccpo_Sup_least[OF chain'] ccpo_Sup_upper[OF chain])
   721     hence "f (\<Squnion>Y) = f (\<Squnion>?Y)" by simp
   722     also have "f (\<Squnion>?Y) = \<Or>(f ` ?Y)" using chain' by(rule cont)(insert y ybound, auto)
   723     also have "\<Or>(f ` ?Y) = \<Or>(?g ` Y)"
   724     proof(cases "Y \<inter> {x. x \<le> bound} = {}")
   725       case True
   726       hence "f ` ?Y = ?g ` Y" by auto
   727       thus ?thesis by(rule arg_cong)
   728     next
   729       case False
   730       have chain'': "Complete_Partial_Order.chain op \<sqsubseteq> (insert bot (f ` ?Y))"
   731         using chain by(auto intro!: chainI bot dest: chainD intro: mono)
   732       hence chain''': "Complete_Partial_Order.chain op \<sqsubseteq> (f ` ?Y)" by(rule chain_subset) blast
   733       have "bot \<sqsubseteq> \<Or>(f ` ?Y)" using y ybound by(blast intro: c.order_trans[OF bot] c.ccpo_Sup_upper[OF chain'''])
   734       hence "\<Or>(insert bot (f ` ?Y)) \<sqsubseteq> \<Or>(f ` ?Y)" using chain''
   735         by(auto intro: c.ccpo_Sup_least c.ccpo_Sup_upper[OF chain''']) 
   736       with _ have "\<dots> = \<Or>(insert bot (f ` ?Y))"
   737         by(rule c.antisym)(blast intro: c.ccpo_Sup_least[OF chain'''] c.ccpo_Sup_upper[OF chain''])
   738       also have "insert bot (f ` ?Y) = ?g ` Y" using False by auto
   739       finally show ?thesis .
   740     qed
   741     finally show ?thesis .
   742   qed
   743 qed
   744 
   745 context partial_function_definitions begin
   746 
   747 lemma mcont_const [cont_intro, simp]:
   748   "mcont luba orda lub leq (\<lambda>x. c)"
   749 by(rule ccpo.mcont_const)(rule Partial_Function.ccpo[OF partial_function_definitions_axioms])
   750 
   751 lemmas [cont_intro, simp] =
   752   ccpo.cont_const[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   753 
   754 lemma mono2mono:
   755   assumes "monotone ordb leq (\<lambda>y. f y)" "monotone orda ordb (\<lambda>x. t x)"
   756   shows "monotone orda leq (\<lambda>x. f (t x))"
   757 using assms by(rule monotone2monotone) simp_all
   758 
   759 lemmas mcont2mcont' = ccpo.mcont2mcont'[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   760 lemmas mcont2mcont = ccpo.mcont2mcont[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   761 
   762 lemmas fixp_preserves_mono1 = ccpo.fixp_preserves_mono1[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   763 lemmas fixp_preserves_mono2 = ccpo.fixp_preserves_mono2[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   764 lemmas fixp_preserves_mono3 = ccpo.fixp_preserves_mono3[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   765 lemmas fixp_preserves_mono4 = ccpo.fixp_preserves_mono4[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   766 lemmas fixp_preserves_mcont1 = ccpo.fixp_preserves_mcont1[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   767 lemmas fixp_preserves_mcont2 = ccpo.fixp_preserves_mcont2[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   768 lemmas fixp_preserves_mcont3 = ccpo.fixp_preserves_mcont3[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   769 lemmas fixp_preserves_mcont4 = ccpo.fixp_preserves_mcont4[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   770 
   771 lemma monotone_if_bot:
   772   fixes bot
   773   assumes g: "\<And>x. g x = (if leq x bound then bot else f x)"
   774   and mono: "\<And>x y. \<lbrakk> leq x y; \<not> leq x bound \<rbrakk> \<Longrightarrow> ord (f x) (f y)"
   775   and bot: "\<And>x. \<not> leq x bound \<Longrightarrow> ord bot (f x)" "ord bot bot"
   776   shows "monotone leq ord g"
   777 unfolding g[abs_def] using preorder mono bot by(rule preorder.monotone_if_bot)
   778 
   779 lemma mcont_if_bot:
   780   fixes bot
   781   assumes ccpo: "class.ccpo lub' ord (mk_less ord)"
   782   and bot: "\<And>x. \<not> leq x bound \<Longrightarrow> ord bot (f x)"
   783   and g: "\<And>x. g x = (if leq x bound then bot else f x)"
   784   and mono: "\<And>x y. \<lbrakk> leq x y; \<not> leq x bound \<rbrakk> \<Longrightarrow> ord (f x) (f y)"
   785   and cont: "\<And>Y. \<lbrakk> Complete_Partial_Order.chain leq Y; Y \<noteq> {}; \<And>x. x \<in> Y \<Longrightarrow> \<not> leq x bound \<rbrakk> \<Longrightarrow> f (lub Y) = lub' (f ` Y)"
   786   shows "mcont lub leq lub' ord g"
   787 unfolding g[abs_def] using ccpo mono cont bot by(rule ccpo.mcont_if_bot[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]])
   788 
   789 end
   790 
   791 subsection \<open>Admissibility\<close>
   792 
   793 lemma admissible_subst:
   794   assumes adm: "ccpo.admissible luba orda (\<lambda>x. P x)"
   795   and mcont: "mcont lubb ordb luba orda f"
   796   shows "ccpo.admissible lubb ordb (\<lambda>x. P (f x))"
   797 apply(rule ccpo.admissibleI)
   798 apply(frule (1) mcont_contD[OF mcont])
   799 apply(auto intro: ccpo.admissibleD[OF adm] chain_imageI dest: mcont_monoD[OF mcont])
   800 done
   801 
   802 lemmas [simp, cont_intro] = 
   803   admissible_all
   804   admissible_ball
   805   admissible_const
   806   admissible_conj
   807 
   808 lemma admissible_disj' [simp, cont_intro]:
   809   "\<lbrakk> class.ccpo lub ord (mk_less ord); ccpo.admissible lub ord P; ccpo.admissible lub ord Q \<rbrakk>
   810   \<Longrightarrow> ccpo.admissible lub ord (\<lambda>x. P x \<or> Q x)"
   811 by(rule ccpo.admissible_disj)
   812 
   813 lemma admissible_imp' [cont_intro]:
   814   "\<lbrakk> class.ccpo lub ord (mk_less ord);
   815      ccpo.admissible lub ord (\<lambda>x. \<not> P x);
   816      ccpo.admissible lub ord (\<lambda>x. Q x) \<rbrakk>
   817   \<Longrightarrow> ccpo.admissible lub ord (\<lambda>x. P x \<longrightarrow> Q x)"
   818 unfolding imp_conv_disj by(rule ccpo.admissible_disj)
   819 
   820 lemma admissible_imp [cont_intro]:
   821   "(Q \<Longrightarrow> ccpo.admissible lub ord (\<lambda>x. P x))
   822   \<Longrightarrow> ccpo.admissible lub ord (\<lambda>x. Q \<longrightarrow> P x)"
   823 by(rule ccpo.admissibleI)(auto dest: ccpo.admissibleD)
   824 
   825 lemma admissible_not_mem' [THEN admissible_subst, cont_intro, simp]:
   826   shows admissible_not_mem: "ccpo.admissible Union op \<subseteq> (\<lambda>A. x \<notin> A)"
   827 by(rule ccpo.admissibleI) auto
   828 
   829 lemma admissible_eqI:
   830   assumes f: "cont luba orda lub ord (\<lambda>x. f x)"
   831   and g: "cont luba orda lub ord (\<lambda>x. g x)"
   832   shows "ccpo.admissible luba orda (\<lambda>x. f x = g x)"
   833 apply(rule ccpo.admissibleI)
   834 apply(simp_all add: contD[OF f] contD[OF g] cong: image_cong)
   835 done
   836 
   837 corollary admissible_eq_mcontI [cont_intro]:
   838   "\<lbrakk> mcont luba orda lub ord (\<lambda>x. f x); 
   839     mcont luba orda lub ord (\<lambda>x. g x) \<rbrakk>
   840   \<Longrightarrow> ccpo.admissible luba orda (\<lambda>x. f x = g x)"
   841 by(rule admissible_eqI)(auto simp add: mcont_def)
   842 
   843 lemma admissible_iff [cont_intro, simp]:
   844   "\<lbrakk> ccpo.admissible lub ord (\<lambda>x. P x \<longrightarrow> Q x); ccpo.admissible lub ord (\<lambda>x. Q x \<longrightarrow> P x) \<rbrakk>
   845   \<Longrightarrow> ccpo.admissible lub ord (\<lambda>x. P x \<longleftrightarrow> Q x)"
   846 by(subst iff_conv_conj_imp)(rule admissible_conj)
   847 
   848 context ccpo begin
   849 
   850 lemma admissible_leI:
   851   assumes f: "mcont luba orda Sup op \<le> (\<lambda>x. f x)"
   852   and g: "mcont luba orda Sup op \<le> (\<lambda>x. g x)"
   853   shows "ccpo.admissible luba orda (\<lambda>x. f x \<le> g x)"
   854 proof(rule ccpo.admissibleI)
   855   fix A
   856   assume chain: "Complete_Partial_Order.chain orda A"
   857     and le: "\<forall>x\<in>A. f x \<le> g x"
   858     and False: "A \<noteq> {}"
   859   have "f (luba A) = \<Squnion>(f ` A)" by(simp add: mcont_contD[OF f] chain False)
   860   also have "\<dots> \<le> \<Squnion>(g ` A)"
   861   proof(rule ccpo_Sup_least)
   862     from chain show "Complete_Partial_Order.chain op \<le> (f ` A)"
   863       by(rule chain_imageI)(rule mcont_monoD[OF f])
   864     
   865     fix x
   866     assume "x \<in> f ` A"
   867     then obtain y where "y \<in> A" "x = f y" by blast note this(2)
   868     also have "f y \<le> g y" using le \<open>y \<in> A\<close> by simp
   869     also have "Complete_Partial_Order.chain op \<le> (g ` A)"
   870       using chain by(rule chain_imageI)(rule mcont_monoD[OF g])
   871     hence "g y \<le> \<Squnion>(g ` A)" by(rule ccpo_Sup_upper)(simp add: \<open>y \<in> A\<close>)
   872     finally show "x \<le> \<dots>" .
   873   qed
   874   also have "\<dots> = g (luba A)" by(simp add: mcont_contD[OF g] chain False)
   875   finally show "f (luba A) \<le> g (luba A)" .
   876 qed
   877 
   878 end
   879 
   880 lemma admissible_leI:
   881   fixes ord (infix "\<sqsubseteq>" 60) and lub ("\<Or>_" [900] 900)
   882   assumes "class.ccpo lub op \<sqsubseteq> (mk_less op \<sqsubseteq>)"
   883   and "mcont luba orda lub op \<sqsubseteq> (\<lambda>x. f x)"
   884   and "mcont luba orda lub op \<sqsubseteq> (\<lambda>x. g x)"
   885   shows "ccpo.admissible luba orda (\<lambda>x. f x \<sqsubseteq> g x)"
   886 using assms by(rule ccpo.admissible_leI)
   887 
   888 declare ccpo_class.admissible_leI[cont_intro]
   889 
   890 context ccpo begin
   891 
   892 lemma admissible_not_below: "ccpo.admissible Sup op \<le> (\<lambda>x. \<not> op \<le> x y)"
   893 by(rule ccpo.admissibleI)(simp add: ccpo_Sup_below_iff)
   894 
   895 end
   896 
   897 lemma (in preorder) preorder [cont_intro, simp]: "class.preorder op \<le> (mk_less op \<le>)"
   898 by(unfold_locales)(auto simp add: mk_less_def intro: order_trans)
   899 
   900 context partial_function_definitions begin
   901 
   902 lemmas [cont_intro, simp] =
   903   admissible_leI[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   904   ccpo.admissible_not_below[THEN admissible_subst, OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   905 
   906 end
   907 
   908 
   909 inductive compact :: "('a set \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a \<Rightarrow> bool"
   910   for lub ord x 
   911 where compact:
   912   "\<lbrakk> ccpo.admissible lub ord (\<lambda>y. \<not> ord x y);
   913      ccpo.admissible lub ord (\<lambda>y. x \<noteq> y) \<rbrakk>
   914   \<Longrightarrow> compact lub ord x"
   915 
   916 hide_fact (open) compact
   917 
   918 context ccpo begin
   919 
   920 lemma compactI:
   921   assumes "ccpo.admissible Sup op \<le> (\<lambda>y. \<not> x \<le> y)"
   922   shows "compact Sup op \<le> x"
   923 using assms
   924 proof(rule compact.intros)
   925   have neq: "(\<lambda>y. x \<noteq> y) = (\<lambda>y. \<not> x \<le> y \<or> \<not> y \<le> x)" by(auto)
   926   show "ccpo.admissible Sup op \<le> (\<lambda>y. x \<noteq> y)"
   927     by(subst neq)(rule admissible_disj admissible_not_below assms)+
   928 qed
   929 
   930 lemma compact_bot:
   931   assumes "x = Sup {}"
   932   shows "compact Sup op \<le> x"
   933 proof(rule compactI)
   934   show "ccpo.admissible Sup op \<le> (\<lambda>y. \<not> x \<le> y)" using assms
   935     by(auto intro!: ccpo.admissibleI intro: ccpo_Sup_least chain_empty)
   936 qed
   937 
   938 end
   939 
   940 lemma admissible_compact_neq' [THEN admissible_subst, cont_intro, simp]:
   941   shows admissible_compact_neq: "compact lub ord k \<Longrightarrow> ccpo.admissible lub ord (\<lambda>x. k \<noteq> x)"
   942 by(simp add: compact.simps)
   943 
   944 lemma admissible_neq_compact' [THEN admissible_subst, cont_intro, simp]:
   945   shows admissible_neq_compact: "compact lub ord k \<Longrightarrow> ccpo.admissible lub ord (\<lambda>x. x \<noteq> k)"
   946 by(subst eq_commute)(rule admissible_compact_neq)
   947 
   948 context partial_function_definitions begin
   949 
   950 lemmas [cont_intro, simp] = ccpo.compact_bot[OF Partial_Function.ccpo[OF partial_function_definitions_axioms]]
   951 
   952 end
   953 
   954 context ccpo begin
   955 
   956 lemma fixp_strong_induct:
   957   assumes [cont_intro]: "ccpo.admissible Sup op \<le> P"
   958   and mono: "monotone op \<le> op \<le> f"
   959   and bot: "P (\<Squnion>{})"
   960   and step: "\<And>x. \<lbrakk> x \<le> ccpo_class.fixp f; P x \<rbrakk> \<Longrightarrow> P (f x)"
   961   shows "P (ccpo_class.fixp f)"
   962 proof(rule fixp_induct[where P="\<lambda>x. x \<le> ccpo_class.fixp f \<and> P x", THEN conjunct2])
   963   note [cont_intro] = admissible_leI
   964   show "ccpo.admissible Sup op \<le> (\<lambda>x. x \<le> ccpo_class.fixp f \<and> P x)" by simp
   965 next
   966   show "\<Squnion>{} \<le> ccpo_class.fixp f \<and> P (\<Squnion>{})"
   967     by(auto simp add: bot intro: ccpo_Sup_least chain_empty)
   968 next
   969   fix x
   970   assume "x \<le> ccpo_class.fixp f \<and> P x"
   971   thus "f x \<le> ccpo_class.fixp f \<and> P (f x)"
   972     by(subst fixp_unfold[OF mono])(auto dest: monotoneD[OF mono] intro: step)
   973 qed(rule mono)
   974 
   975 end
   976 
   977 context partial_function_definitions begin
   978 
   979 lemma fixp_strong_induct_uc:
   980   fixes F :: "'c \<Rightarrow> 'c"
   981     and U :: "'c \<Rightarrow> 'b \<Rightarrow> 'a"
   982     and C :: "('b \<Rightarrow> 'a) \<Rightarrow> 'c"
   983     and P :: "('b \<Rightarrow> 'a) \<Rightarrow> bool"
   984   assumes mono: "\<And>x. mono_body (\<lambda>f. U (F (C f)) x)"
   985     and eq: "f \<equiv> C (fixp_fun (\<lambda>f. U (F (C f))))"
   986     and inverse: "\<And>f. U (C f) = f"
   987     and adm: "ccpo.admissible lub_fun le_fun P"
   988     and bot: "P (\<lambda>_. lub {})"
   989     and step: "\<And>f'. \<lbrakk> P (U f'); le_fun (U f') (U f) \<rbrakk> \<Longrightarrow> P (U (F f'))"
   990   shows "P (U f)"
   991 unfolding eq inverse
   992 apply (rule ccpo.fixp_strong_induct[OF ccpo adm])
   993 apply (insert mono, auto simp: monotone_def fun_ord_def bot fun_lub_def)[2]
   994 apply (rule_tac f'5="C x" in step)
   995 apply (simp_all add: inverse eq)
   996 done
   997 
   998 end
   999 
  1000 subsection \<open>@{term "op ="} as order\<close>
  1001 
  1002 definition lub_singleton :: "('a set \<Rightarrow> 'a) \<Rightarrow> bool"
  1003 where "lub_singleton lub \<longleftrightarrow> (\<forall>a. lub {a} = a)"
  1004 
  1005 definition the_Sup :: "'a set \<Rightarrow> 'a"
  1006 where "the_Sup A = (THE a. a \<in> A)"
  1007 
  1008 lemma lub_singleton_the_Sup [cont_intro, simp]: "lub_singleton the_Sup"
  1009 by(simp add: lub_singleton_def the_Sup_def)
  1010 
  1011 lemma (in ccpo) lub_singleton: "lub_singleton Sup"
  1012 by(simp add: lub_singleton_def)
  1013 
  1014 lemma (in partial_function_definitions) lub_singleton [cont_intro, simp]: "lub_singleton lub"
  1015 by(rule ccpo.lub_singleton)(rule Partial_Function.ccpo[OF partial_function_definitions_axioms])
  1016 
  1017 lemma preorder_eq [cont_intro, simp]:
  1018   "class.preorder op = (mk_less op =)"
  1019 by(unfold_locales)(simp_all add: mk_less_def)
  1020 
  1021 lemma monotone_eqI [cont_intro]:
  1022   assumes "class.preorder ord (mk_less ord)"
  1023   shows "monotone op = ord f"
  1024 proof -
  1025   interpret preorder ord "mk_less ord" by fact
  1026   show ?thesis by(simp add: monotone_def)
  1027 qed
  1028 
  1029 lemma cont_eqI [cont_intro]: 
  1030   fixes f :: "'a \<Rightarrow> 'b"
  1031   assumes "lub_singleton lub"
  1032   shows "cont the_Sup op = lub ord f"
  1033 proof(rule contI)
  1034   fix Y :: "'a set"
  1035   assume "Complete_Partial_Order.chain op = Y" "Y \<noteq> {}"
  1036   then obtain a where "Y = {a}" by(auto simp add: chain_def)
  1037   thus "f (the_Sup Y) = lub (f ` Y)" using assms
  1038     by(simp add: the_Sup_def lub_singleton_def)
  1039 qed
  1040 
  1041 lemma mcont_eqI [cont_intro, simp]:
  1042   "\<lbrakk> class.preorder ord (mk_less ord); lub_singleton lub \<rbrakk>
  1043   \<Longrightarrow> mcont the_Sup op = lub ord f"
  1044 by(simp add: mcont_def cont_eqI monotone_eqI)
  1045 
  1046 subsection \<open>ccpo for products\<close>
  1047 
  1048 definition prod_lub :: "('a set \<Rightarrow> 'a) \<Rightarrow> ('b set \<Rightarrow> 'b) \<Rightarrow> ('a \<times> 'b) set \<Rightarrow> 'a \<times> 'b"
  1049 where "prod_lub Sup_a Sup_b Y = (Sup_a (fst ` Y), Sup_b (snd ` Y))"
  1050 
  1051 lemma lub_singleton_prod_lub [cont_intro, simp]:
  1052   "\<lbrakk> lub_singleton luba; lub_singleton lubb \<rbrakk> \<Longrightarrow> lub_singleton (prod_lub luba lubb)"
  1053 by(simp add: lub_singleton_def prod_lub_def)
  1054 
  1055 lemma prod_lub_empty [simp]: "prod_lub luba lubb {} = (luba {}, lubb {})"
  1056 by(simp add: prod_lub_def)
  1057 
  1058 lemma preorder_rel_prodI [cont_intro, simp]:
  1059   assumes "class.preorder orda (mk_less orda)"
  1060   and "class.preorder ordb (mk_less ordb)"
  1061   shows "class.preorder (rel_prod orda ordb) (mk_less (rel_prod orda ordb))"
  1062 proof -
  1063   interpret a: preorder orda "mk_less orda" by fact
  1064   interpret b: preorder ordb "mk_less ordb" by fact
  1065   show ?thesis by(unfold_locales)(auto simp add: mk_less_def intro: a.order_trans b.order_trans)
  1066 qed
  1067 
  1068 lemma order_rel_prodI:
  1069   assumes a: "class.order orda (mk_less orda)"
  1070   and b: "class.order ordb (mk_less ordb)"
  1071   shows "class.order (rel_prod orda ordb) (mk_less (rel_prod orda ordb))"
  1072   (is "class.order ?ord ?ord'")
  1073 proof(intro class.order.intro class.order_axioms.intro)
  1074   interpret a: order orda "mk_less orda" by(fact a)
  1075   interpret b: order ordb "mk_less ordb" by(fact b)
  1076   show "class.preorder ?ord ?ord'" by(rule preorder_rel_prodI) unfold_locales
  1077 
  1078   fix x y
  1079   assume "?ord x y" "?ord y x"
  1080   thus "x = y" by(cases x y rule: prod.exhaust[case_product prod.exhaust]) auto
  1081 qed
  1082 
  1083 lemma monotone_rel_prodI:
  1084   assumes mono2: "\<And>a. monotone ordb ordc (\<lambda>b. f (a, b))"
  1085   and mono1: "\<And>b. monotone orda ordc (\<lambda>a. f (a, b))"
  1086   and a: "class.preorder orda (mk_less orda)"
  1087   and b: "class.preorder ordb (mk_less ordb)"
  1088   and c: "class.preorder ordc (mk_less ordc)"
  1089   shows "monotone (rel_prod orda ordb) ordc f"
  1090 proof -
  1091   interpret a: preorder orda "mk_less orda" by(rule a)
  1092   interpret b: preorder ordb "mk_less ordb" by(rule b)
  1093   interpret c: preorder ordc "mk_less ordc" by(rule c)
  1094   show ?thesis using mono2 mono1
  1095     by(auto 7 2 simp add: monotone_def intro: c.order_trans)
  1096 qed
  1097 
  1098 lemma monotone_rel_prodD1:
  1099   assumes mono: "monotone (rel_prod orda ordb) ordc f"
  1100   and preorder: "class.preorder ordb (mk_less ordb)"
  1101   shows "monotone orda ordc (\<lambda>a. f (a, b))"
  1102 proof -
  1103   interpret preorder ordb "mk_less ordb" by(rule preorder)
  1104   show ?thesis using mono by(simp add: monotone_def)
  1105 qed
  1106 
  1107 lemma monotone_rel_prodD2:
  1108   assumes mono: "monotone (rel_prod orda ordb) ordc f"
  1109   and preorder: "class.preorder orda (mk_less orda)"
  1110   shows "monotone ordb ordc (\<lambda>b. f (a, b))"
  1111 proof -
  1112   interpret preorder orda "mk_less orda" by(rule preorder)
  1113   show ?thesis using mono by(simp add: monotone_def)
  1114 qed
  1115 
  1116 lemma monotone_case_prodI:
  1117   "\<lbrakk> \<And>a. monotone ordb ordc (f a); \<And>b. monotone orda ordc (\<lambda>a. f a b);
  1118     class.preorder orda (mk_less orda); class.preorder ordb (mk_less ordb);
  1119     class.preorder ordc (mk_less ordc) \<rbrakk>
  1120   \<Longrightarrow> monotone (rel_prod orda ordb) ordc (case_prod f)"
  1121 by(rule monotone_rel_prodI) simp_all
  1122 
  1123 lemma monotone_case_prodD1:
  1124   assumes mono: "monotone (rel_prod orda ordb) ordc (case_prod f)"
  1125   and preorder: "class.preorder ordb (mk_less ordb)"
  1126   shows "monotone orda ordc (\<lambda>a. f a b)"
  1127 using monotone_rel_prodD1[OF assms] by simp
  1128 
  1129 lemma monotone_case_prodD2:
  1130   assumes mono: "monotone (rel_prod orda ordb) ordc (case_prod f)"
  1131   and preorder: "class.preorder orda (mk_less orda)"
  1132   shows "monotone ordb ordc (f a)"
  1133 using monotone_rel_prodD2[OF assms] by simp
  1134 
  1135 context 
  1136   fixes orda ordb ordc
  1137   assumes a: "class.preorder orda (mk_less orda)"
  1138   and b: "class.preorder ordb (mk_less ordb)"
  1139   and c: "class.preorder ordc (mk_less ordc)"
  1140 begin
  1141 
  1142 lemma monotone_rel_prod_iff:
  1143   "monotone (rel_prod orda ordb) ordc f \<longleftrightarrow>
  1144    (\<forall>a. monotone ordb ordc (\<lambda>b. f (a, b))) \<and> 
  1145    (\<forall>b. monotone orda ordc (\<lambda>a. f (a, b)))"
  1146 using a b c by(blast intro: monotone_rel_prodI dest: monotone_rel_prodD1 monotone_rel_prodD2)
  1147 
  1148 lemma monotone_case_prod_iff [simp]:
  1149   "monotone (rel_prod orda ordb) ordc (case_prod f) \<longleftrightarrow>
  1150    (\<forall>a. monotone ordb ordc (f a)) \<and> (\<forall>b. monotone orda ordc (\<lambda>a. f a b))"
  1151 by(simp add: monotone_rel_prod_iff)
  1152 
  1153 end
  1154 
  1155 lemma monotone_case_prod_apply_iff:
  1156   "monotone orda ordb (\<lambda>x. (case_prod f x) y) \<longleftrightarrow> monotone orda ordb (case_prod (\<lambda>a b. f a b y))"
  1157 by(simp add: monotone_def)
  1158 
  1159 lemma monotone_case_prod_applyD:
  1160   "monotone orda ordb (\<lambda>x. (case_prod f x) y)
  1161   \<Longrightarrow> monotone orda ordb (case_prod (\<lambda>a b. f a b y))"
  1162 by(simp add: monotone_case_prod_apply_iff)
  1163 
  1164 lemma monotone_case_prod_applyI:
  1165   "monotone orda ordb (case_prod (\<lambda>a b. f a b y))
  1166   \<Longrightarrow> monotone orda ordb (\<lambda>x. (case_prod f x) y)"
  1167 by(simp add: monotone_case_prod_apply_iff)
  1168 
  1169 
  1170 lemma cont_case_prod_apply_iff:
  1171   "cont luba orda lubb ordb (\<lambda>x. (case_prod f x) y) \<longleftrightarrow> cont luba orda lubb ordb (case_prod (\<lambda>a b. f a b y))"
  1172 by(simp add: cont_def split_def)
  1173 
  1174 lemma cont_case_prod_applyI:
  1175   "cont luba orda lubb ordb (case_prod (\<lambda>a b. f a b y))
  1176   \<Longrightarrow> cont luba orda lubb ordb (\<lambda>x. (case_prod f x) y)"
  1177 by(simp add: cont_case_prod_apply_iff)
  1178 
  1179 lemma cont_case_prod_applyD:
  1180   "cont luba orda lubb ordb (\<lambda>x. (case_prod f x) y)
  1181   \<Longrightarrow> cont luba orda lubb ordb (case_prod (\<lambda>a b. f a b y))"
  1182 by(simp add: cont_case_prod_apply_iff)
  1183 
  1184 lemma mcont_case_prod_apply_iff [simp]:
  1185   "mcont luba orda lubb ordb (\<lambda>x. (case_prod f x) y) \<longleftrightarrow> 
  1186    mcont luba orda lubb ordb (case_prod (\<lambda>a b. f a b y))"
  1187 by(simp add: mcont_def monotone_case_prod_apply_iff cont_case_prod_apply_iff)
  1188 
  1189 lemma cont_prodD1: 
  1190   assumes cont: "cont (prod_lub luba lubb) (rel_prod orda ordb) lubc ordc f"
  1191   and "class.preorder orda (mk_less orda)"
  1192   and luba: "lub_singleton luba"
  1193   shows "cont lubb ordb lubc ordc (\<lambda>y. f (x, y))"
  1194 proof(rule contI)
  1195   interpret preorder orda "mk_less orda" by fact
  1196 
  1197   fix Y :: "'b set"
  1198   let ?Y = "{x} \<times> Y"
  1199   assume "Complete_Partial_Order.chain ordb Y" "Y \<noteq> {}"
  1200   hence "Complete_Partial_Order.chain (rel_prod orda ordb) ?Y" "?Y \<noteq> {}" 
  1201     by(simp_all add: chain_def)
  1202   with cont have "f (prod_lub luba lubb ?Y) = lubc (f ` ?Y)" by(rule contD)
  1203   moreover have "f ` ?Y = (\<lambda>y. f (x, y)) ` Y" by auto
  1204   ultimately show "f (x, lubb Y) = lubc ((\<lambda>y. f (x, y)) ` Y)" using luba
  1205     by(simp add: prod_lub_def \<open>Y \<noteq> {}\<close> lub_singleton_def)
  1206 qed
  1207 
  1208 lemma cont_prodD2: 
  1209   assumes cont: "cont (prod_lub luba lubb) (rel_prod orda ordb) lubc ordc f"
  1210   and "class.preorder ordb (mk_less ordb)"
  1211   and lubb: "lub_singleton lubb"
  1212   shows "cont luba orda lubc ordc (\<lambda>x. f (x, y))"
  1213 proof(rule contI)
  1214   interpret preorder ordb "mk_less ordb" by fact
  1215 
  1216   fix Y
  1217   assume Y: "Complete_Partial_Order.chain orda Y" "Y \<noteq> {}"
  1218   let ?Y = "Y \<times> {y}"
  1219   have "f (luba Y, y) = f (prod_lub luba lubb ?Y)"
  1220     using lubb by(simp add: prod_lub_def Y lub_singleton_def)
  1221   also from Y have "Complete_Partial_Order.chain (rel_prod orda ordb) ?Y" "?Y \<noteq> {}"
  1222     by(simp_all add: chain_def)
  1223   with cont have "f (prod_lub luba lubb ?Y) = lubc (f ` ?Y)" by(rule contD)
  1224   also have "f ` ?Y = (\<lambda>x. f (x, y)) ` Y" by auto
  1225   finally show "f (luba Y, y) = lubc \<dots>" .
  1226 qed
  1227 
  1228 lemma cont_case_prodD1:
  1229   assumes "cont (prod_lub luba lubb) (rel_prod orda ordb) lubc ordc (case_prod f)"
  1230   and "class.preorder orda (mk_less orda)"
  1231   and "lub_singleton luba"
  1232   shows "cont lubb ordb lubc ordc (f x)"
  1233 using cont_prodD1[OF assms] by simp
  1234 
  1235 lemma cont_case_prodD2:
  1236   assumes "cont (prod_lub luba lubb) (rel_prod orda ordb) lubc ordc (case_prod f)"
  1237   and "class.preorder ordb (mk_less ordb)"
  1238   and "lub_singleton lubb"
  1239   shows "cont luba orda lubc ordc (\<lambda>x. f x y)"
  1240 using cont_prodD2[OF assms] by simp
  1241 
  1242 context ccpo begin
  1243 
  1244 lemma cont_prodI: 
  1245   assumes mono: "monotone (rel_prod orda ordb) op \<le> f"
  1246   and cont1: "\<And>x. cont lubb ordb Sup op \<le> (\<lambda>y. f (x, y))"
  1247   and cont2: "\<And>y. cont luba orda Sup op \<le> (\<lambda>x. f (x, y))"
  1248   and "class.preorder orda (mk_less orda)"
  1249   and "class.preorder ordb (mk_less ordb)"
  1250   shows "cont (prod_lub luba lubb) (rel_prod orda ordb) Sup op \<le> f"
  1251 proof(rule contI)
  1252   interpret a: preorder orda "mk_less orda" by fact 
  1253   interpret b: preorder ordb "mk_less ordb" by fact
  1254   
  1255   fix Y
  1256   assume chain: "Complete_Partial_Order.chain (rel_prod orda ordb) Y"
  1257     and "Y \<noteq> {}"
  1258   have "f (prod_lub luba lubb Y) = f (luba (fst ` Y), lubb (snd ` Y))"
  1259     by(simp add: prod_lub_def)
  1260   also from cont2 have "f (luba (fst ` Y), lubb (snd ` Y)) = \<Squnion>((\<lambda>x. f (x, lubb (snd ` Y))) ` fst ` Y)"
  1261     by(rule contD)(simp_all add: chain_rel_prodD1[OF chain] \<open>Y \<noteq> {}\<close>)
  1262   also from cont1 have "\<And>x. f (x, lubb (snd ` Y)) = \<Squnion>((\<lambda>y. f (x, y)) ` snd ` Y)"
  1263     by(rule contD)(simp_all add: chain_rel_prodD2[OF chain] \<open>Y \<noteq> {}\<close>)
  1264   hence "\<Squnion>((\<lambda>x. f (x, lubb (snd ` Y))) ` fst ` Y) = \<Squnion>((\<lambda>x. \<dots> x) ` fst ` Y)" by simp
  1265   also have "\<dots> = \<Squnion>((\<lambda>x. f (fst x, snd x)) ` Y)"
  1266     unfolding image_image split_def using chain
  1267     apply(rule diag_Sup)
  1268     using monotoneD[OF mono]
  1269     by(auto intro: monotoneI)
  1270   finally show "f (prod_lub luba lubb Y) = \<Squnion>(f ` Y)" by simp
  1271 qed
  1272 
  1273 lemma cont_case_prodI:
  1274   assumes "monotone (rel_prod orda ordb) op \<le> (case_prod f)"
  1275   and "\<And>x. cont lubb ordb Sup op \<le> (\<lambda>y. f x y)"
  1276   and "\<And>y. cont luba orda Sup op \<le> (\<lambda>x. f x y)"
  1277   and "class.preorder orda (mk_less orda)"
  1278   and "class.preorder ordb (mk_less ordb)"
  1279   shows "cont (prod_lub luba lubb) (rel_prod orda ordb) Sup op \<le> (case_prod f)"
  1280 by(rule cont_prodI)(simp_all add: assms)
  1281 
  1282 lemma cont_case_prod_iff:
  1283   "\<lbrakk> monotone (rel_prod orda ordb) op \<le> (case_prod f);
  1284      class.preorder orda (mk_less orda); lub_singleton luba;
  1285      class.preorder ordb (mk_less ordb); lub_singleton lubb \<rbrakk>
  1286   \<Longrightarrow> cont (prod_lub luba lubb) (rel_prod orda ordb) Sup op \<le> (case_prod f) \<longleftrightarrow>
  1287    (\<forall>x. cont lubb ordb Sup op \<le> (\<lambda>y. f x y)) \<and> (\<forall>y. cont luba orda Sup op \<le> (\<lambda>x. f x y))"
  1288 by(blast dest: cont_case_prodD1 cont_case_prodD2 intro: cont_case_prodI)
  1289 
  1290 end
  1291 
  1292 context partial_function_definitions begin
  1293 
  1294 lemma mono2mono2:
  1295   assumes f: "monotone (rel_prod ordb ordc) leq (\<lambda>(x, y). f x y)"
  1296   and t: "monotone orda ordb (\<lambda>x. t x)"
  1297   and t': "monotone orda ordc (\<lambda>x. t' x)"
  1298   shows "monotone orda leq (\<lambda>x. f (t x) (t' x))"
  1299 proof(rule monotoneI)
  1300   fix x y
  1301   assume "orda x y"
  1302   hence "rel_prod ordb ordc (t x, t' x) (t y, t' y)"
  1303     using t t' by(auto dest: monotoneD)
  1304   from monotoneD[OF f this] show "leq (f (t x) (t' x)) (f (t y) (t' y))" by simp
  1305 qed
  1306 
  1307 lemma cont_case_prodI [cont_intro]:
  1308   "\<lbrakk> monotone (rel_prod orda ordb) leq (case_prod f);
  1309     \<And>x. cont lubb ordb lub leq (\<lambda>y. f x y);
  1310     \<And>y. cont luba orda lub leq (\<lambda>x. f x y);
  1311     class.preorder orda (mk_less orda);
  1312     class.preorder ordb (mk_less ordb) \<rbrakk>
  1313   \<Longrightarrow> cont (prod_lub luba lubb) (rel_prod orda ordb) lub leq (case_prod f)"
  1314 by(rule ccpo.cont_case_prodI)(rule Partial_Function.ccpo[OF partial_function_definitions_axioms])
  1315 
  1316 lemma cont_case_prod_iff:
  1317   "\<lbrakk> monotone (rel_prod orda ordb) leq (case_prod f);
  1318      class.preorder orda (mk_less orda); lub_singleton luba;
  1319      class.preorder ordb (mk_less ordb); lub_singleton lubb \<rbrakk>
  1320   \<Longrightarrow> cont (prod_lub luba lubb) (rel_prod orda ordb) lub leq (case_prod f) \<longleftrightarrow>
  1321    (\<forall>x. cont lubb ordb lub leq (\<lambda>y. f x y)) \<and> (\<forall>y. cont luba orda lub leq (\<lambda>x. f x y))"
  1322 by(blast dest: cont_case_prodD1 cont_case_prodD2 intro: cont_case_prodI)
  1323 
  1324 lemma mcont_case_prod_iff [simp]:
  1325   "\<lbrakk> class.preorder orda (mk_less orda); lub_singleton luba;
  1326      class.preorder ordb (mk_less ordb); lub_singleton lubb \<rbrakk>
  1327   \<Longrightarrow> mcont (prod_lub luba lubb) (rel_prod orda ordb) lub leq (case_prod f) \<longleftrightarrow>
  1328    (\<forall>x. mcont lubb ordb lub leq (\<lambda>y. f x y)) \<and> (\<forall>y. mcont luba orda lub leq (\<lambda>x. f x y))"
  1329 unfolding mcont_def by(auto simp add: cont_case_prod_iff)
  1330 
  1331 end
  1332 
  1333 lemma mono2mono_case_prod [cont_intro]:
  1334   assumes "\<And>x y. monotone orda ordb (\<lambda>f. pair f x y)"
  1335   shows "monotone orda ordb (\<lambda>f. case_prod (pair f) x)"
  1336 by(rule monotoneI)(auto split: prod.split dest: monotoneD[OF assms])
  1337 
  1338 subsection \<open>Complete lattices as ccpo\<close>
  1339 
  1340 context complete_lattice begin
  1341 
  1342 lemma complete_lattice_ccpo: "class.ccpo Sup op \<le> op <"
  1343 by(unfold_locales)(fast intro: Sup_upper Sup_least)+
  1344 
  1345 lemma complete_lattice_ccpo': "class.ccpo Sup op \<le> (mk_less op \<le>)"
  1346 by(unfold_locales)(auto simp add: mk_less_def intro: Sup_upper Sup_least)
  1347 
  1348 lemma complete_lattice_partial_function_definitions: 
  1349   "partial_function_definitions op \<le> Sup"
  1350 by(unfold_locales)(auto intro: Sup_least Sup_upper)
  1351 
  1352 lemma complete_lattice_partial_function_definitions_dual:
  1353   "partial_function_definitions op \<ge> Inf"
  1354 by(unfold_locales)(auto intro: Inf_lower Inf_greatest)
  1355 
  1356 lemmas [cont_intro, simp] =
  1357   Partial_Function.ccpo[OF complete_lattice_partial_function_definitions]
  1358   Partial_Function.ccpo[OF complete_lattice_partial_function_definitions_dual]
  1359 
  1360 lemma mono2mono_inf:
  1361   assumes f: "monotone ord op \<le> (\<lambda>x. f x)" 
  1362   and g: "monotone ord op \<le> (\<lambda>x. g x)"
  1363   shows "monotone ord op \<le> (\<lambda>x. f x \<sqinter> g x)"
  1364 by(auto 4 3 dest: monotoneD[OF f] monotoneD[OF g] intro: le_infI1 le_infI2 intro!: monotoneI)
  1365 
  1366 lemma mcont_const [simp]: "mcont lub ord Sup op \<le> (\<lambda>_. c)"
  1367 by(rule ccpo.mcont_const[OF complete_lattice_ccpo])
  1368 
  1369 lemma mono2mono_sup:
  1370   assumes f: "monotone ord op \<le> (\<lambda>x. f x)"
  1371   and g: "monotone ord op \<le> (\<lambda>x. g x)"
  1372   shows "monotone ord op \<le> (\<lambda>x. f x \<squnion> g x)"
  1373 by(auto 4 3 intro!: monotoneI intro: sup.coboundedI1 sup.coboundedI2 dest: monotoneD[OF f] monotoneD[OF g])
  1374 
  1375 lemma Sup_image_sup: 
  1376   assumes "Y \<noteq> {}"
  1377   shows "\<Squnion>(op \<squnion> x ` Y) = x \<squnion> \<Squnion>Y"
  1378 proof(rule Sup_eqI)
  1379   fix y
  1380   assume "y \<in> op \<squnion> x ` Y"
  1381   then obtain z where "y = x \<squnion> z" and "z \<in> Y" by blast
  1382   from \<open>z \<in> Y\<close> have "z \<le> \<Squnion>Y" by(rule Sup_upper)
  1383   with _ show "y \<le> x \<squnion> \<Squnion>Y" unfolding \<open>y = x \<squnion> z\<close> by(rule sup_mono) simp
  1384 next
  1385   fix y
  1386   assume upper: "\<And>z. z \<in> op \<squnion> x ` Y \<Longrightarrow> z \<le> y"
  1387   show "x \<squnion> \<Squnion>Y \<le> y" unfolding Sup_insert[symmetric]
  1388   proof(rule Sup_least)
  1389     fix z
  1390     assume "z \<in> insert x Y"
  1391     from assms obtain z' where "z' \<in> Y" by blast
  1392     let ?z = "if z \<in> Y then x \<squnion> z else x \<squnion> z'"
  1393     have "z \<le> x \<squnion> ?z" using \<open>z' \<in> Y\<close> \<open>z \<in> insert x Y\<close> by auto
  1394     also have "\<dots> \<le> y" by(rule upper)(auto split: if_split_asm intro: \<open>z' \<in> Y\<close>)
  1395     finally show "z \<le> y" .
  1396   qed
  1397 qed
  1398 
  1399 lemma mcont_sup1: "mcont Sup op \<le> Sup op \<le> (\<lambda>y. x \<squnion> y)"
  1400 by(auto 4 3 simp add: mcont_def sup.coboundedI1 sup.coboundedI2 intro!: monotoneI contI intro: Sup_image_sup[symmetric])
  1401 
  1402 lemma mcont_sup2: "mcont Sup op \<le> Sup op \<le> (\<lambda>x. x \<squnion> y)"
  1403 by(subst sup_commute)(rule mcont_sup1)
  1404 
  1405 lemma mcont2mcont_sup [cont_intro, simp]:
  1406   "\<lbrakk> mcont lub ord Sup op \<le> (\<lambda>x. f x);
  1407      mcont lub ord Sup op \<le> (\<lambda>x. g x) \<rbrakk>
  1408   \<Longrightarrow> mcont lub ord Sup op \<le> (\<lambda>x. f x \<squnion> g x)"
  1409 by(best intro: ccpo.mcont2mcont'[OF complete_lattice_ccpo] mcont_sup1 mcont_sup2 ccpo.mcont_const[OF complete_lattice_ccpo])
  1410 
  1411 end
  1412 
  1413 lemmas [cont_intro] = admissible_leI[OF complete_lattice_ccpo']
  1414 
  1415 context complete_distrib_lattice begin
  1416 
  1417 lemma mcont_inf1: "mcont Sup op \<le> Sup op \<le> (\<lambda>y. x \<sqinter> y)"
  1418 by(auto intro: monotoneI contI simp add: le_infI2 inf_Sup mcont_def)
  1419 
  1420 lemma mcont_inf2: "mcont Sup op \<le> Sup op \<le> (\<lambda>x. x \<sqinter> y)"
  1421 by(auto intro: monotoneI contI simp add: le_infI1 Sup_inf mcont_def)
  1422 
  1423 lemma mcont2mcont_inf [cont_intro, simp]:
  1424   "\<lbrakk> mcont lub ord Sup op \<le> (\<lambda>x. f x);
  1425     mcont lub ord Sup op \<le> (\<lambda>x. g x) \<rbrakk>
  1426   \<Longrightarrow> mcont lub ord Sup op \<le> (\<lambda>x. f x \<sqinter> g x)"
  1427 by(best intro: ccpo.mcont2mcont'[OF complete_lattice_ccpo] mcont_inf1 mcont_inf2 ccpo.mcont_const[OF complete_lattice_ccpo])
  1428 
  1429 end
  1430 
  1431 interpretation lfp: partial_function_definitions "op \<le> :: _ :: complete_lattice \<Rightarrow> _" Sup
  1432 by(rule complete_lattice_partial_function_definitions)
  1433 
  1434 declaration \<open>Partial_Function.init "lfp" @{term lfp.fixp_fun} @{term lfp.mono_body}
  1435   @{thm lfp.fixp_rule_uc} @{thm lfp.fixp_induct_uc} NONE\<close>
  1436 
  1437 interpretation gfp: partial_function_definitions "op \<ge> :: _ :: complete_lattice \<Rightarrow> _" Inf
  1438 by(rule complete_lattice_partial_function_definitions_dual)
  1439 
  1440 declaration \<open>Partial_Function.init "gfp" @{term gfp.fixp_fun} @{term gfp.mono_body}
  1441   @{thm gfp.fixp_rule_uc} @{thm gfp.fixp_induct_uc} NONE\<close>
  1442 
  1443 lemma insert_mono [partial_function_mono]:
  1444    "monotone (fun_ord op \<subseteq>) op \<subseteq> A \<Longrightarrow> monotone (fun_ord op \<subseteq>) op \<subseteq> (\<lambda>y. insert x (A y))"
  1445 by(rule monotoneI)(auto simp add: fun_ord_def dest: monotoneD)
  1446 
  1447 lemma mono2mono_insert [THEN lfp.mono2mono, cont_intro, simp]:
  1448   shows monotone_insert: "monotone op \<subseteq> op \<subseteq> (insert x)"
  1449 by(rule monotoneI) blast
  1450 
  1451 lemma mcont2mcont_insert[THEN lfp.mcont2mcont, cont_intro, simp]:
  1452   shows mcont_insert: "mcont Union op \<subseteq> Union op \<subseteq> (insert x)"
  1453 by(blast intro: mcontI contI monotone_insert)
  1454 
  1455 lemma mono2mono_image [THEN lfp.mono2mono, cont_intro, simp]:
  1456   shows monotone_image: "monotone op \<subseteq> op \<subseteq> (op ` f)"
  1457 by(rule monotoneI) blast
  1458 
  1459 lemma cont_image: "cont Union op \<subseteq> Union op \<subseteq> (op ` f)"
  1460 by(rule contI)(auto)
  1461 
  1462 lemma mcont2mcont_image [THEN lfp.mcont2mcont, cont_intro, simp]:
  1463   shows mcont_image: "mcont Union op \<subseteq> Union op \<subseteq> (op ` f)"
  1464 by(blast intro: mcontI monotone_image cont_image)
  1465 
  1466 context complete_lattice begin
  1467 
  1468 lemma monotone_Sup [cont_intro, simp]:
  1469   "monotone ord op \<subseteq> f \<Longrightarrow> monotone ord op \<le> (\<lambda>x. \<Squnion>f x)"
  1470 by(blast intro: monotoneI Sup_least Sup_upper dest: monotoneD)
  1471 
  1472 lemma cont_Sup:
  1473   assumes "cont lub ord Union op \<subseteq> f"
  1474   shows "cont lub ord Sup op \<le> (\<lambda>x. \<Squnion>f x)"
  1475 apply(rule contI)
  1476 apply(simp add: contD[OF assms])
  1477 apply(blast intro: Sup_least Sup_upper order_trans antisym)
  1478 done
  1479 
  1480 lemma mcont_Sup: "mcont lub ord Union op \<subseteq> f \<Longrightarrow> mcont lub ord Sup op \<le> (\<lambda>x. \<Squnion>f x)"
  1481 unfolding mcont_def by(blast intro: monotone_Sup cont_Sup)
  1482 
  1483 lemma monotone_SUP:
  1484   "\<lbrakk> monotone ord op \<subseteq> f; \<And>y. monotone ord op \<le> (\<lambda>x. g x y) \<rbrakk> \<Longrightarrow> monotone ord op \<le> (\<lambda>x. \<Squnion>y\<in>f x. g x y)"
  1485 by(rule monotoneI)(blast dest: monotoneD intro: Sup_upper order_trans intro!: Sup_least)
  1486 
  1487 lemma monotone_SUP2:
  1488   "(\<And>y. y \<in> A \<Longrightarrow> monotone ord op \<le> (\<lambda>x. g x y)) \<Longrightarrow> monotone ord op \<le> (\<lambda>x. \<Squnion>y\<in>A. g x y)"
  1489 by(rule monotoneI)(blast intro: Sup_upper order_trans dest: monotoneD intro!: Sup_least)
  1490 
  1491 lemma cont_SUP:
  1492   assumes f: "mcont lub ord Union op \<subseteq> f"
  1493   and g: "\<And>y. mcont lub ord Sup op \<le> (\<lambda>x. g x y)"
  1494   shows "cont lub ord Sup op \<le> (\<lambda>x. \<Squnion>y\<in>f x. g x y)"
  1495 proof(rule contI)
  1496   fix Y
  1497   assume chain: "Complete_Partial_Order.chain ord Y"
  1498     and Y: "Y \<noteq> {}"
  1499   show "\<Squnion>(g (lub Y) ` f (lub Y)) = \<Squnion>((\<lambda>x. \<Squnion>(g x ` f x)) ` Y)" (is "?lhs = ?rhs")
  1500   proof(rule antisym)
  1501     show "?lhs \<le> ?rhs"
  1502     proof(rule Sup_least)
  1503       fix x
  1504       assume "x \<in> g (lub Y) ` f (lub Y)"
  1505       with mcont_contD[OF f chain Y] mcont_contD[OF g chain Y]
  1506       obtain y z where "y \<in> Y" "z \<in> f y"
  1507         and x: "x = \<Squnion>((\<lambda>x. g x z) ` Y)" by auto
  1508       show "x \<le> ?rhs" unfolding x
  1509       proof(rule Sup_least)
  1510         fix u
  1511         assume "u \<in> (\<lambda>x. g x z) ` Y"
  1512         then obtain y' where "u = g y' z" "y' \<in> Y" by auto
  1513         from chain \<open>y \<in> Y\<close> \<open>y' \<in> Y\<close> have "ord y y' \<or> ord y' y" by(rule chainD)
  1514         thus "u \<le> ?rhs"
  1515         proof
  1516           note \<open>u = g y' z\<close> also
  1517           assume "ord y y'"
  1518           with f have "f y \<subseteq> f y'" by(rule mcont_monoD)
  1519           with \<open>z \<in> f y\<close>
  1520           have "g y' z \<le> \<Squnion>(g y' ` f y')" by(auto intro: Sup_upper)
  1521           also have "\<dots> \<le> ?rhs" using \<open>y' \<in> Y\<close> by(auto intro: Sup_upper)
  1522           finally show ?thesis .
  1523         next
  1524           note \<open>u = g y' z\<close> also
  1525           assume "ord y' y"
  1526           with g have "g y' z \<le> g y z" by(rule mcont_monoD)
  1527           also have "\<dots> \<le> \<Squnion>(g y ` f y)" using \<open>z \<in> f y\<close>
  1528             by(auto intro: Sup_upper)
  1529           also have "\<dots> \<le> ?rhs" using \<open>y \<in> Y\<close> by(auto intro: Sup_upper)
  1530           finally show ?thesis .
  1531         qed
  1532       qed
  1533     qed
  1534   next
  1535     show "?rhs \<le> ?lhs"
  1536     proof(rule Sup_least)
  1537       fix x
  1538       assume "x \<in> (\<lambda>x. \<Squnion>(g x ` f x)) ` Y"
  1539       then obtain y where x: "x = \<Squnion>(g y ` f y)" and "y \<in> Y" by auto
  1540       show "x \<le> ?lhs" unfolding x
  1541       proof(rule Sup_least)
  1542         fix u
  1543         assume "u \<in> g y ` f y"
  1544         then obtain z where "u = g y z" "z \<in> f y" by auto
  1545         note \<open>u = g y z\<close>
  1546         also have "g y z \<le> \<Squnion>((\<lambda>x. g x z) ` Y)"
  1547           using \<open>y \<in> Y\<close> by(auto intro: Sup_upper)
  1548         also have "\<dots> = g (lub Y) z" by(simp add: mcont_contD[OF g chain Y])
  1549         also have "\<dots> \<le> ?lhs" using \<open>z \<in> f y\<close> \<open>y \<in> Y\<close>
  1550           by(auto intro: Sup_upper simp add: mcont_contD[OF f chain Y])
  1551         finally show "u \<le> ?lhs" .
  1552       qed
  1553     qed
  1554   qed
  1555 qed
  1556 
  1557 lemma mcont_SUP [cont_intro, simp]:
  1558   "\<lbrakk> mcont lub ord Union op \<subseteq> f; \<And>y. mcont lub ord Sup op \<le> (\<lambda>x. g x y) \<rbrakk>
  1559   \<Longrightarrow> mcont lub ord Sup op \<le> (\<lambda>x. \<Squnion>y\<in>f x. g x y)"
  1560 by(blast intro: mcontI cont_SUP monotone_SUP mcont_mono)
  1561 
  1562 end
  1563 
  1564 lemma admissible_Ball [cont_intro, simp]:
  1565   "\<lbrakk> \<And>x. ccpo.admissible lub ord (\<lambda>A. P A x);
  1566      mcont lub ord Union op \<subseteq> f;
  1567      class.ccpo lub ord (mk_less ord) \<rbrakk>
  1568   \<Longrightarrow> ccpo.admissible lub ord (\<lambda>A. \<forall>x\<in>f A. P A x)"
  1569 unfolding Ball_def by simp
  1570 
  1571 lemma admissible_Bex'[THEN admissible_subst, cont_intro, simp]:
  1572   shows admissible_Bex: "ccpo.admissible Union op \<subseteq> (\<lambda>A. \<exists>x\<in>A. P x)"
  1573 by(rule ccpo.admissibleI)(auto)
  1574 
  1575 subsection \<open>Parallel fixpoint induction\<close>
  1576 
  1577 context
  1578   fixes luba :: "'a set \<Rightarrow> 'a"
  1579   and orda :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1580   and lubb :: "'b set \<Rightarrow> 'b"
  1581   and ordb :: "'b \<Rightarrow> 'b \<Rightarrow> bool"
  1582   assumes a: "class.ccpo luba orda (mk_less orda)"
  1583   and b: "class.ccpo lubb ordb (mk_less ordb)"
  1584 begin
  1585 
  1586 interpretation a: ccpo luba orda "mk_less orda" by(rule a)
  1587 interpretation b: ccpo lubb ordb "mk_less ordb" by(rule b)
  1588 
  1589 lemma ccpo_rel_prodI:
  1590   "class.ccpo (prod_lub luba lubb) (rel_prod orda ordb) (mk_less (rel_prod orda ordb))"
  1591   (is "class.ccpo ?lub ?ord ?ord'")
  1592 proof(intro class.ccpo.intro class.ccpo_axioms.intro)
  1593   show "class.order ?ord ?ord'" by(rule order_rel_prodI) intro_locales
  1594 qed(auto 4 4 simp add: prod_lub_def intro: a.ccpo_Sup_upper b.ccpo_Sup_upper a.ccpo_Sup_least b.ccpo_Sup_least rev_image_eqI dest: chain_rel_prodD1 chain_rel_prodD2)
  1595 
  1596 interpretation ab: ccpo "prod_lub luba lubb" "rel_prod orda ordb" "mk_less (rel_prod orda ordb)"
  1597 by(rule ccpo_rel_prodI)
  1598 
  1599 lemma monotone_map_prod [simp]:
  1600   "monotone (rel_prod orda ordb) (rel_prod ordc ordd) (map_prod f g) \<longleftrightarrow>
  1601    monotone orda ordc f \<and> monotone ordb ordd g"
  1602 by(auto simp add: monotone_def)
  1603 
  1604 lemma parallel_fixp_induct:
  1605   assumes adm: "ccpo.admissible (prod_lub luba lubb) (rel_prod orda ordb) (\<lambda>x. P (fst x) (snd x))"
  1606   and f: "monotone orda orda f"
  1607   and g: "monotone ordb ordb g"
  1608   and bot: "P (luba {}) (lubb {})"
  1609   and step: "\<And>x y. P x y \<Longrightarrow> P (f x) (g y)"
  1610   shows "P (ccpo.fixp luba orda f) (ccpo.fixp lubb ordb g)"
  1611 proof -
  1612   let ?lub = "prod_lub luba lubb"
  1613     and ?ord = "rel_prod orda ordb"
  1614     and ?P = "\<lambda>(x, y). P x y"
  1615   from adm have adm': "ccpo.admissible ?lub ?ord ?P" by(simp add: split_def)
  1616   hence "?P (ccpo.fixp (prod_lub luba lubb) (rel_prod orda ordb) (map_prod f g))"
  1617     by(rule ab.fixp_induct)(auto simp add: f g step bot)
  1618   also have "ccpo.fixp (prod_lub luba lubb) (rel_prod orda ordb) (map_prod f g) = 
  1619             (ccpo.fixp luba orda f, ccpo.fixp lubb ordb g)" (is "?lhs = (?rhs1, ?rhs2)")
  1620   proof(rule ab.antisym)
  1621     have "ccpo.admissible ?lub ?ord (\<lambda>xy. ?ord xy (?rhs1, ?rhs2))"
  1622       by(rule admissible_leI[OF ccpo_rel_prodI])(auto simp add: prod_lub_def chain_empty intro: a.ccpo_Sup_least b.ccpo_Sup_least)
  1623     thus "?ord ?lhs (?rhs1, ?rhs2)"
  1624       by(rule ab.fixp_induct)(auto 4 3 dest: monotoneD[OF f] monotoneD[OF g] simp add: b.fixp_unfold[OF g, symmetric] a.fixp_unfold[OF f, symmetric] f g intro: a.ccpo_Sup_least b.ccpo_Sup_least chain_empty)
  1625   next
  1626     have "ccpo.admissible luba orda (\<lambda>x. orda x (fst ?lhs))"
  1627       by(rule admissible_leI[OF a])(auto intro: a.ccpo_Sup_least simp add: chain_empty)
  1628     hence "orda ?rhs1 (fst ?lhs)" using f
  1629     proof(rule a.fixp_induct)
  1630       fix x
  1631       assume "orda x (fst ?lhs)"
  1632       thus "orda (f x) (fst ?lhs)"
  1633         by(subst ab.fixp_unfold)(auto simp add: f g dest: monotoneD[OF f])
  1634     qed(auto intro: a.ccpo_Sup_least chain_empty)
  1635     moreover
  1636     have "ccpo.admissible lubb ordb (\<lambda>y. ordb y (snd ?lhs))"
  1637       by(rule admissible_leI[OF b])(auto intro: b.ccpo_Sup_least simp add: chain_empty)
  1638     hence "ordb ?rhs2 (snd ?lhs)" using g
  1639     proof(rule b.fixp_induct)
  1640       fix y
  1641       assume "ordb y (snd ?lhs)"
  1642       thus "ordb (g y) (snd ?lhs)"
  1643         by(subst ab.fixp_unfold)(auto simp add: f g dest: monotoneD[OF g])
  1644     qed(auto intro: b.ccpo_Sup_least chain_empty)
  1645     ultimately show "?ord (?rhs1, ?rhs2) ?lhs"
  1646       by(simp add: rel_prod_conv split_beta)
  1647   qed
  1648   finally show ?thesis by simp
  1649 qed
  1650 
  1651 end
  1652 
  1653 lemma parallel_fixp_induct_uc:
  1654   assumes a: "partial_function_definitions orda luba"
  1655   and b: "partial_function_definitions ordb lubb"
  1656   and F: "\<And>x. monotone (fun_ord orda) orda (\<lambda>f. U1 (F (C1 f)) x)"
  1657   and G: "\<And>y. monotone (fun_ord ordb) ordb (\<lambda>g. U2 (G (C2 g)) y)"
  1658   and eq1: "f \<equiv> C1 (ccpo.fixp (fun_lub luba) (fun_ord orda) (\<lambda>f. U1 (F (C1 f))))"
  1659   and eq2: "g \<equiv> C2 (ccpo.fixp (fun_lub lubb) (fun_ord ordb) (\<lambda>g. U2 (G (C2 g))))"
  1660   and inverse: "\<And>f. U1 (C1 f) = f"
  1661   and inverse2: "\<And>g. U2 (C2 g) = g"
  1662   and adm: "ccpo.admissible (prod_lub (fun_lub luba) (fun_lub lubb)) (rel_prod (fun_ord orda) (fun_ord ordb)) (\<lambda>x. P (fst x) (snd x))"
  1663   and bot: "P (\<lambda>_. luba {}) (\<lambda>_. lubb {})"
  1664   and step: "\<And>f g. P (U1 f) (U2 g) \<Longrightarrow> P (U1 (F f)) (U2 (G g))"
  1665   shows "P (U1 f) (U2 g)"
  1666 apply(unfold eq1 eq2 inverse inverse2)
  1667 apply(rule parallel_fixp_induct[OF partial_function_definitions.ccpo[OF a] partial_function_definitions.ccpo[OF b] adm])
  1668 using F apply(simp add: monotone_def fun_ord_def)
  1669 using G apply(simp add: monotone_def fun_ord_def)
  1670 apply(simp add: fun_lub_def bot)
  1671 apply(rule step, simp add: inverse inverse2)
  1672 done
  1673 
  1674 lemmas parallel_fixp_induct_1_1 = parallel_fixp_induct_uc[
  1675   of _ _ _ _ "\<lambda>x. x" _ "\<lambda>x. x" "\<lambda>x. x" _ "\<lambda>x. x",
  1676   OF _ _ _ _ _ _ refl refl]
  1677 
  1678 lemmas parallel_fixp_induct_2_2 = parallel_fixp_induct_uc[
  1679   of _ _ _ _ "case_prod" _ "curry" "case_prod" _ "curry",
  1680   where P="\<lambda>f g. P (curry f) (curry g)",
  1681   unfolded case_prod_curry curry_case_prod curry_K,
  1682   OF _ _ _ _ _ _ refl refl]
  1683   for P
  1684 
  1685 lemma monotone_fst: "monotone (rel_prod orda ordb) orda fst"
  1686 by(auto intro: monotoneI)
  1687 
  1688 lemma mcont_fst: "mcont (prod_lub luba lubb) (rel_prod orda ordb) luba orda fst"
  1689 by(auto intro!: mcontI monotoneI contI simp add: prod_lub_def)
  1690 
  1691 lemma mcont2mcont_fst [cont_intro, simp]:
  1692   "mcont lub ord (prod_lub luba lubb) (rel_prod orda ordb) t
  1693   \<Longrightarrow> mcont lub ord luba orda (\<lambda>x. fst (t x))"
  1694 by(auto intro!: mcontI monotoneI contI dest: mcont_monoD mcont_contD simp add: rel_prod_sel split_beta prod_lub_def image_image)
  1695 
  1696 lemma monotone_snd: "monotone (rel_prod orda ordb) ordb snd"
  1697 by(auto intro: monotoneI)
  1698 
  1699 lemma mcont_snd: "mcont (prod_lub luba lubb) (rel_prod orda ordb) lubb ordb snd"
  1700 by(auto intro!: mcontI monotoneI contI simp add: prod_lub_def)
  1701 
  1702 lemma mcont2mcont_snd [cont_intro, simp]:
  1703   "mcont lub ord (prod_lub luba lubb) (rel_prod orda ordb) t
  1704   \<Longrightarrow> mcont lub ord lubb ordb (\<lambda>x. snd (t x))"
  1705 by(auto intro!: mcontI monotoneI contI dest: mcont_monoD mcont_contD simp add: rel_prod_sel split_beta prod_lub_def image_image)
  1706 
  1707 lemma monotone_Pair:
  1708   "\<lbrakk> monotone ord orda f; monotone ord ordb g \<rbrakk>
  1709   \<Longrightarrow> monotone ord (rel_prod orda ordb) (\<lambda>x. (f x, g x))"
  1710 by(simp add: monotone_def)
  1711 
  1712 lemma cont_Pair:
  1713   "\<lbrakk> cont lub ord luba orda f; cont lub ord lubb ordb g \<rbrakk>
  1714   \<Longrightarrow> cont lub ord (prod_lub luba lubb) (rel_prod orda ordb) (\<lambda>x. (f x, g x))"
  1715 by(rule contI)(auto simp add: prod_lub_def image_image dest!: contD)
  1716 
  1717 lemma mcont_Pair:
  1718   "\<lbrakk> mcont lub ord luba orda f; mcont lub ord lubb ordb g \<rbrakk>
  1719   \<Longrightarrow> mcont lub ord (prod_lub luba lubb) (rel_prod orda ordb) (\<lambda>x. (f x, g x))"
  1720 by(rule mcontI)(simp_all add: monotone_Pair mcont_mono cont_Pair)
  1721 
  1722 context partial_function_definitions begin
  1723 text \<open>Specialised versions of @{thm [source] mcont_call} for admissibility proofs for parallel fixpoint inductions\<close>
  1724 lemmas mcont_call_fst [cont_intro] = mcont_call[THEN mcont2mcont, OF mcont_fst]
  1725 lemmas mcont_call_snd [cont_intro] = mcont_call[THEN mcont2mcont, OF mcont_snd]
  1726 end
  1727 
  1728 lemma map_option_mono [partial_function_mono]:
  1729   "mono_option B \<Longrightarrow> mono_option (\<lambda>f. map_option g (B f))"
  1730 unfolding map_conv_bind_option by(rule bind_mono) simp_all
  1731 
  1732 lemma compact_flat_lub [cont_intro]: "compact (flat_lub x) (flat_ord x) y"
  1733 using flat_interpretation[THEN ccpo]
  1734 proof(rule ccpo.compactI[OF _ ccpo.admissibleI])
  1735   fix A
  1736   assume chain: "Complete_Partial_Order.chain (flat_ord x) A"
  1737     and A: "A \<noteq> {}"
  1738     and *: "\<forall>z\<in>A. \<not> flat_ord x y z"
  1739   from A obtain z where "z \<in> A" by blast
  1740   with * have z: "\<not> flat_ord x y z" ..
  1741   hence y: "x \<noteq> y" "y \<noteq> z" by(auto simp add: flat_ord_def)
  1742   { assume "\<not> A \<subseteq> {x}"
  1743     then obtain z' where "z' \<in> A" "z' \<noteq> x" by auto
  1744     then have "(THE z. z \<in> A - {x}) = z'"
  1745       by(intro the_equality)(auto dest: chainD[OF chain] simp add: flat_ord_def)
  1746     moreover have "z' \<noteq> y" using \<open>z' \<in> A\<close> * by(auto simp add: flat_ord_def)
  1747     ultimately have "y \<noteq> (THE z. z \<in> A - {x})" by simp }
  1748   with z show "\<not> flat_ord x y (flat_lub x A)" by(simp add: flat_ord_def flat_lub_def)
  1749 qed
  1750 
  1751 end