src/HOL/Library/Extended_Nonnegative_Real.thy
author wenzelm
Wed Mar 08 10:50:59 2017 +0100 (2017-03-08)
changeset 65151 a7394aa4d21c
parent 64425 b17acc1834e3
child 65680 378a2f11bec9
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Library/Extended_Nonnegative_Real.thy
     2     Author:     Johannes Hölzl
     3 *)
     4 
     5 subsection \<open>The type of non-negative extended real numbers\<close>
     6 
     7 theory Extended_Nonnegative_Real
     8   imports Extended_Real Indicator_Function
     9 begin
    10 
    11 lemma ereal_ineq_diff_add:
    12   assumes "b \<noteq> (-\<infinity>::ereal)" "a \<ge> b"
    13   shows "a = b + (a-b)"
    14 by (metis add.commute assms(1) assms(2) ereal_eq_minus_iff ereal_minus_le_iff ereal_plus_eq_PInfty)
    15 
    16 lemma Limsup_const_add:
    17   fixes c :: "'a::{complete_linorder, linorder_topology, topological_monoid_add, ordered_ab_semigroup_add}"
    18   shows "F \<noteq> bot \<Longrightarrow> Limsup F (\<lambda>x. c + f x) = c + Limsup F f"
    19   by (rule Limsup_compose_continuous_mono)
    20      (auto intro!: monoI add_mono continuous_on_add continuous_on_id continuous_on_const)
    21 
    22 lemma Liminf_const_add:
    23   fixes c :: "'a::{complete_linorder, linorder_topology, topological_monoid_add, ordered_ab_semigroup_add}"
    24   shows "F \<noteq> bot \<Longrightarrow> Liminf F (\<lambda>x. c + f x) = c + Liminf F f"
    25   by (rule Liminf_compose_continuous_mono)
    26      (auto intro!: monoI add_mono continuous_on_add continuous_on_id continuous_on_const)
    27 
    28 lemma Liminf_add_const:
    29   fixes c :: "'a::{complete_linorder, linorder_topology, topological_monoid_add, ordered_ab_semigroup_add}"
    30   shows "F \<noteq> bot \<Longrightarrow> Liminf F (\<lambda>x. f x + c) = Liminf F f + c"
    31   by (rule Liminf_compose_continuous_mono)
    32      (auto intro!: monoI add_mono continuous_on_add continuous_on_id continuous_on_const)
    33 
    34 lemma sums_offset:
    35   fixes f g :: "nat \<Rightarrow> 'a :: {t2_space, topological_comm_monoid_add}"
    36   assumes "(\<lambda>n. f (n + i)) sums l" shows "f sums (l + (\<Sum>j<i. f j))"
    37 proof  -
    38   have "(\<lambda>k. (\<Sum>n<k. f (n + i)) + (\<Sum>j<i. f j)) \<longlonglongrightarrow> l + (\<Sum>j<i. f j)"
    39     using assms by (auto intro!: tendsto_add simp: sums_def)
    40   moreover
    41   { fix k :: nat
    42     have "(\<Sum>j<k + i. f j) = (\<Sum>j=i..<k + i. f j) + (\<Sum>j=0..<i. f j)"
    43       by (subst sum.union_disjoint[symmetric]) (auto intro!: sum.cong)
    44     also have "(\<Sum>j=i..<k + i. f j) = (\<Sum>j\<in>(\<lambda>n. n + i)`{0..<k}. f j)"
    45       unfolding image_add_atLeastLessThan by simp
    46     finally have "(\<Sum>j<k + i. f j) = (\<Sum>n<k. f (n + i)) + (\<Sum>j<i. f j)"
    47       by (auto simp: inj_on_def atLeast0LessThan sum.reindex) }
    48   ultimately have "(\<lambda>k. (\<Sum>n<k + i. f n)) \<longlonglongrightarrow> l + (\<Sum>j<i. f j)"
    49     by simp
    50   then show ?thesis
    51     unfolding sums_def by (rule LIMSEQ_offset)
    52 qed
    53 
    54 lemma suminf_offset:
    55   fixes f g :: "nat \<Rightarrow> 'a :: {t2_space, topological_comm_monoid_add}"
    56   shows "summable (\<lambda>j. f (j + i)) \<Longrightarrow> suminf f = (\<Sum>j. f (j + i)) + (\<Sum>j<i. f j)"
    57   by (intro sums_unique[symmetric] sums_offset summable_sums)
    58 
    59 lemma eventually_at_left_1: "(\<And>z::real. 0 < z \<Longrightarrow> z < 1 \<Longrightarrow> P z) \<Longrightarrow> eventually P (at_left 1)"
    60   by (subst eventually_at_left[of 0]) (auto intro: exI[of _ 0])
    61 
    62 lemma mult_eq_1:
    63   fixes a b :: "'a :: {ordered_semiring, comm_monoid_mult}"
    64   shows "0 \<le> a \<Longrightarrow> a \<le> 1 \<Longrightarrow> b \<le> 1 \<Longrightarrow> a * b = 1 \<longleftrightarrow> (a = 1 \<and> b = 1)"
    65   by (metis mult.left_neutral eq_iff mult.commute mult_right_mono)
    66 
    67 lemma ereal_add_diff_cancel:
    68   fixes a b :: ereal
    69   shows "\<bar>b\<bar> \<noteq> \<infinity> \<Longrightarrow> (a + b) - b = a"
    70   by (cases a b rule: ereal2_cases) auto
    71 
    72 lemma add_top:
    73   fixes x :: "'a::{order_top, ordered_comm_monoid_add}"
    74   shows "0 \<le> x \<Longrightarrow> x + top = top"
    75   by (intro top_le add_increasing order_refl)
    76 
    77 lemma top_add:
    78   fixes x :: "'a::{order_top, ordered_comm_monoid_add}"
    79   shows "0 \<le> x \<Longrightarrow> top + x = top"
    80   by (intro top_le add_increasing2 order_refl)
    81 
    82 lemma le_lfp: "mono f \<Longrightarrow> x \<le> lfp f \<Longrightarrow> f x \<le> lfp f"
    83   by (subst lfp_unfold) (auto dest: monoD)
    84 
    85 lemma lfp_transfer:
    86   assumes \<alpha>: "sup_continuous \<alpha>" and f: "sup_continuous f" and mg: "mono g"
    87   assumes bot: "\<alpha> bot \<le> lfp g" and eq: "\<And>x. x \<le> lfp f \<Longrightarrow> \<alpha> (f x) = g (\<alpha> x)"
    88   shows "\<alpha> (lfp f) = lfp g"
    89 proof (rule antisym)
    90   note mf = sup_continuous_mono[OF f]
    91   have f_le_lfp: "(f ^^ i) bot \<le> lfp f" for i
    92     by (induction i) (auto intro: le_lfp mf)
    93 
    94   have "\<alpha> ((f ^^ i) bot) \<le> lfp g" for i
    95     by (induction i) (auto simp: bot eq f_le_lfp intro!: le_lfp mg)
    96   then show "\<alpha> (lfp f) \<le> lfp g"
    97     unfolding sup_continuous_lfp[OF f]
    98     by (subst \<alpha>[THEN sup_continuousD])
    99        (auto intro!: mono_funpow sup_continuous_mono[OF f] SUP_least)
   100 
   101   show "lfp g \<le> \<alpha> (lfp f)"
   102     by (rule lfp_lowerbound) (simp add: eq[symmetric] lfp_fixpoint[OF mf])
   103 qed
   104 
   105 lemma sup_continuous_applyD: "sup_continuous f \<Longrightarrow> sup_continuous (\<lambda>x. f x h)"
   106   using sup_continuous_apply[THEN sup_continuous_compose] .
   107 
   108 lemma sup_continuous_SUP[order_continuous_intros]:
   109   fixes M :: "_ \<Rightarrow> _ \<Rightarrow> 'a::complete_lattice"
   110   assumes M: "\<And>i. i \<in> I \<Longrightarrow> sup_continuous (M i)"
   111   shows  "sup_continuous (SUP i:I. M i)"
   112   unfolding sup_continuous_def by (auto simp add: sup_continuousD[OF M] intro: SUP_commute)
   113 
   114 lemma sup_continuous_apply_SUP[order_continuous_intros]:
   115   fixes M :: "_ \<Rightarrow> _ \<Rightarrow> 'a::complete_lattice"
   116   shows "(\<And>i. i \<in> I \<Longrightarrow> sup_continuous (M i)) \<Longrightarrow> sup_continuous (\<lambda>x. SUP i:I. M i x)"
   117   unfolding SUP_apply[symmetric] by (rule sup_continuous_SUP)
   118 
   119 lemma sup_continuous_lfp'[order_continuous_intros]:
   120   assumes 1: "sup_continuous f"
   121   assumes 2: "\<And>g. sup_continuous g \<Longrightarrow> sup_continuous (f g)"
   122   shows "sup_continuous (lfp f)"
   123 proof -
   124   have "sup_continuous ((f ^^ i) bot)" for i
   125   proof (induction i)
   126     case (Suc i) then show ?case
   127       by (auto intro!: 2)
   128   qed (simp add: bot_fun_def sup_continuous_const)
   129   then show ?thesis
   130     unfolding sup_continuous_lfp[OF 1] by (intro order_continuous_intros)
   131 qed
   132 
   133 lemma sup_continuous_lfp''[order_continuous_intros]:
   134   assumes 1: "\<And>s. sup_continuous (f s)"
   135   assumes 2: "\<And>g. sup_continuous g \<Longrightarrow> sup_continuous (\<lambda>s. f s (g s))"
   136   shows "sup_continuous (\<lambda>x. lfp (f x))"
   137 proof -
   138   have "sup_continuous (\<lambda>x. (f x ^^ i) bot)" for i
   139   proof (induction i)
   140     case (Suc i) then show ?case
   141       by (auto intro!: 2)
   142   qed (simp add: bot_fun_def sup_continuous_const)
   143   then show ?thesis
   144     unfolding sup_continuous_lfp[OF 1] by (intro order_continuous_intros)
   145 qed
   146 
   147 lemma mono_INF_fun:
   148     "(\<And>x y. mono (F x y)) \<Longrightarrow> mono (\<lambda>z x. INF y : X x. F x y z :: 'a :: complete_lattice)"
   149   by (auto intro!: INF_mono[OF bexI] simp: le_fun_def mono_def)
   150 
   151 lemma continuous_on_max:
   152   fixes f g :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
   153   shows "continuous_on A f \<Longrightarrow> continuous_on A g \<Longrightarrow> continuous_on A (\<lambda>x. max (f x) (g x))"
   154   by (auto simp: continuous_on_def intro!: tendsto_max)
   155 
   156 lemma continuous_on_cmult_ereal:
   157   "\<bar>c::ereal\<bar> \<noteq> \<infinity> \<Longrightarrow> continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. c * f x)"
   158   using tendsto_cmult_ereal[of c f "f x" "at x within A" for x]
   159   by (auto simp: continuous_on_def simp del: tendsto_cmult_ereal)
   160 
   161 context linordered_nonzero_semiring
   162 begin
   163 
   164 lemma of_nat_nonneg [simp]: "0 \<le> of_nat n"
   165   by (induct n) simp_all
   166 
   167 lemma of_nat_mono[simp]: "i \<le> j \<Longrightarrow> of_nat i \<le> of_nat j"
   168   by (auto simp add: le_iff_add intro!: add_increasing2)
   169 
   170 end
   171 
   172 lemma real_of_nat_Sup:
   173   assumes "A \<noteq> {}" "bdd_above A"
   174   shows "of_nat (Sup A) = (SUP a:A. of_nat a :: real)"
   175 proof (intro antisym)
   176   show "(SUP a:A. of_nat a::real) \<le> of_nat (Sup A)"
   177     using assms by (intro cSUP_least of_nat_mono) (auto intro: cSup_upper)
   178   have "Sup A \<in> A"
   179     unfolding Sup_nat_def using assms by (intro Max_in) (auto simp: bdd_above_nat)
   180   then show "of_nat (Sup A) \<le> (SUP a:A. of_nat a::real)"
   181     by (intro cSUP_upper bdd_above_image_mono assms) (auto simp: mono_def)
   182 qed
   183 
   184 lemma of_nat_less[simp]:
   185   "i < j \<Longrightarrow> of_nat i < (of_nat j::'a::{linordered_nonzero_semiring, semiring_char_0})"
   186   by (auto simp: less_le)
   187 
   188 lemma of_nat_le_iff[simp]:
   189   "of_nat i \<le> (of_nat j::'a::{linordered_nonzero_semiring, semiring_char_0}) \<longleftrightarrow> i \<le> j"
   190 proof (safe intro!: of_nat_mono)
   191   assume "of_nat i \<le> (of_nat j::'a)" then show "i \<le> j"
   192   proof (intro leI notI)
   193     assume "j < i" from less_le_trans[OF of_nat_less[OF this] \<open>of_nat i \<le> of_nat j\<close>] show False
   194       by blast
   195   qed
   196 qed
   197 
   198 lemma (in complete_lattice) SUP_sup_const1:
   199   "I \<noteq> {} \<Longrightarrow> (SUP i:I. sup c (f i)) = sup c (SUP i:I. f i)"
   200   using SUP_sup_distrib[of "\<lambda>_. c" I f] by simp
   201 
   202 lemma (in complete_lattice) SUP_sup_const2:
   203   "I \<noteq> {} \<Longrightarrow> (SUP i:I. sup (f i) c) = sup (SUP i:I. f i) c"
   204   using SUP_sup_distrib[of f I "\<lambda>_. c"] by simp
   205 
   206 lemma one_less_of_natD:
   207   "(1::'a::linordered_semidom) < of_nat n \<Longrightarrow> 1 < n"
   208   using zero_le_one[where 'a='a]
   209   apply (cases n)
   210   apply simp
   211   subgoal for n'
   212     apply (cases n')
   213     apply simp
   214     apply simp
   215     done
   216   done
   217 
   218 lemma sum_le_suminf:
   219   fixes f :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   220   shows "summable f \<Longrightarrow> finite I \<Longrightarrow> \<forall>m\<in>- I. 0 \<le> f m \<Longrightarrow> sum f I \<le> suminf f"
   221   by (rule sums_le[OF _ sums_If_finite_set summable_sums]) auto
   222 
   223 lemma suminf_eq_SUP_real:
   224   assumes X: "summable X" "\<And>i. 0 \<le> X i" shows "suminf X = (SUP i. \<Sum>n<i. X n::real)"
   225   by (intro LIMSEQ_unique[OF summable_LIMSEQ] X LIMSEQ_incseq_SUP)
   226      (auto intro!: bdd_aboveI2[where M="\<Sum>i. X i"] sum_le_suminf X monoI sum_mono3)
   227 
   228 subsection \<open>Defining the extended non-negative reals\<close>
   229 
   230 text \<open>Basic definitions and type class setup\<close>
   231 
   232 typedef ennreal = "{x :: ereal. 0 \<le> x}"
   233   morphisms enn2ereal e2ennreal'
   234   by auto
   235 
   236 definition "e2ennreal x = e2ennreal' (max 0 x)"
   237 
   238 lemma enn2ereal_range: "e2ennreal ` {0..} = UNIV"
   239 proof -
   240   have "\<exists>y\<ge>0. x = e2ennreal y" for x
   241     by (cases x) (auto simp: e2ennreal_def max_absorb2)
   242   then show ?thesis
   243     by (auto simp: image_iff Bex_def)
   244 qed
   245 
   246 lemma type_definition_ennreal': "type_definition enn2ereal e2ennreal {x. 0 \<le> x}"
   247   using type_definition_ennreal
   248   by (auto simp: type_definition_def e2ennreal_def max_absorb2)
   249 
   250 setup_lifting type_definition_ennreal'
   251 
   252 declare [[coercion e2ennreal]]
   253 
   254 instantiation ennreal :: complete_linorder
   255 begin
   256 
   257 lift_definition top_ennreal :: ennreal is top by (rule top_greatest)
   258 lift_definition bot_ennreal :: ennreal is 0 by (rule order_refl)
   259 lift_definition sup_ennreal :: "ennreal \<Rightarrow> ennreal \<Rightarrow> ennreal" is sup by (rule le_supI1)
   260 lift_definition inf_ennreal :: "ennreal \<Rightarrow> ennreal \<Rightarrow> ennreal" is inf by (rule le_infI)
   261 
   262 lift_definition Inf_ennreal :: "ennreal set \<Rightarrow> ennreal" is "Inf"
   263   by (rule Inf_greatest)
   264 
   265 lift_definition Sup_ennreal :: "ennreal set \<Rightarrow> ennreal" is "sup 0 \<circ> Sup"
   266   by auto
   267 
   268 lift_definition less_eq_ennreal :: "ennreal \<Rightarrow> ennreal \<Rightarrow> bool" is "op \<le>" .
   269 lift_definition less_ennreal :: "ennreal \<Rightarrow> ennreal \<Rightarrow> bool" is "op <" .
   270 
   271 instance
   272   by standard
   273      (transfer ; auto simp: Inf_lower Inf_greatest Sup_upper Sup_least le_max_iff_disj max.absorb1)+
   274 
   275 end
   276 
   277 lemma pcr_ennreal_enn2ereal[simp]: "pcr_ennreal (enn2ereal x) x"
   278   by (simp add: ennreal.pcr_cr_eq cr_ennreal_def)
   279 
   280 lemma rel_fun_eq_pcr_ennreal: "rel_fun op = pcr_ennreal f g \<longleftrightarrow> f = enn2ereal \<circ> g"
   281   by (auto simp: rel_fun_def ennreal.pcr_cr_eq cr_ennreal_def)
   282 
   283 instantiation ennreal :: infinity
   284 begin
   285 
   286 definition infinity_ennreal :: ennreal
   287 where
   288   [simp]: "\<infinity> = (top::ennreal)"
   289 
   290 instance ..
   291 
   292 end
   293 
   294 instantiation ennreal :: "{semiring_1_no_zero_divisors, comm_semiring_1}"
   295 begin
   296 
   297 lift_definition one_ennreal :: ennreal is 1 by simp
   298 lift_definition zero_ennreal :: ennreal is 0 by simp
   299 lift_definition plus_ennreal :: "ennreal \<Rightarrow> ennreal \<Rightarrow> ennreal" is "op +" by simp
   300 lift_definition times_ennreal :: "ennreal \<Rightarrow> ennreal \<Rightarrow> ennreal" is "op *" by simp
   301 
   302 instance
   303   by standard (transfer; auto simp: field_simps ereal_right_distrib)+
   304 
   305 end
   306 
   307 instantiation ennreal :: minus
   308 begin
   309 
   310 lift_definition minus_ennreal :: "ennreal \<Rightarrow> ennreal \<Rightarrow> ennreal" is "\<lambda>a b. max 0 (a - b)"
   311   by simp
   312 
   313 instance ..
   314 
   315 end
   316 
   317 instance ennreal :: numeral ..
   318 
   319 instantiation ennreal :: inverse
   320 begin
   321 
   322 lift_definition inverse_ennreal :: "ennreal \<Rightarrow> ennreal" is inverse
   323   by (rule inverse_ereal_ge0I)
   324 
   325 definition divide_ennreal :: "ennreal \<Rightarrow> ennreal \<Rightarrow> ennreal"
   326   where "x div y = x * inverse (y :: ennreal)"
   327 
   328 instance ..
   329 
   330 end
   331 
   332 lemma ennreal_zero_less_one: "0 < (1::ennreal)" \<comment> \<open>TODO: remove \<close>
   333   by transfer auto
   334 
   335 instance ennreal :: dioid
   336 proof (standard; transfer)
   337   fix a b :: ereal assume "0 \<le> a" "0 \<le> b" then show "(a \<le> b) = (\<exists>c\<in>Collect (op \<le> 0). b = a + c)"
   338     unfolding ereal_ex_split Bex_def
   339     by (cases a b rule: ereal2_cases) (auto intro!: exI[of _ "real_of_ereal (b - a)"])
   340 qed
   341 
   342 instance ennreal :: ordered_comm_semiring
   343   by standard
   344      (transfer ; auto intro: add_mono mult_mono mult_ac ereal_left_distrib ereal_mult_left_mono)+
   345 
   346 instance ennreal :: linordered_nonzero_semiring
   347   proof qed (transfer; simp)
   348 
   349 instance ennreal :: strict_ordered_ab_semigroup_add
   350 proof
   351   fix a b c d :: ennreal show "a < b \<Longrightarrow> c < d \<Longrightarrow> a + c < b + d"
   352     by transfer (auto intro!: ereal_add_strict_mono)
   353 qed
   354 
   355 declare [[coercion "of_nat :: nat \<Rightarrow> ennreal"]]
   356 
   357 lemma e2ennreal_neg: "x \<le> 0 \<Longrightarrow> e2ennreal x = 0"
   358   unfolding zero_ennreal_def e2ennreal_def by (simp add: max_absorb1)
   359 
   360 lemma e2ennreal_mono: "x \<le> y \<Longrightarrow> e2ennreal x \<le> e2ennreal y"
   361   by (cases "0 \<le> x" "0 \<le> y" rule: bool.exhaust[case_product bool.exhaust])
   362      (auto simp: e2ennreal_neg less_eq_ennreal.abs_eq eq_onp_def)
   363 
   364 lemma enn2ereal_nonneg[simp]: "0 \<le> enn2ereal x"
   365   using ennreal.enn2ereal[of x] by simp
   366 
   367 lemma ereal_ennreal_cases:
   368   obtains b where "0 \<le> a" "a = enn2ereal b" | "a < 0"
   369   using e2ennreal'_inverse[of a, symmetric] by (cases "0 \<le> a") (auto intro: enn2ereal_nonneg)
   370 
   371 lemma rel_fun_liminf[transfer_rule]: "rel_fun (rel_fun op = pcr_ennreal) pcr_ennreal liminf liminf"
   372 proof -
   373   have "rel_fun (rel_fun op = pcr_ennreal) pcr_ennreal (\<lambda>x. sup 0 (liminf x)) liminf"
   374     unfolding liminf_SUP_INF[abs_def] by (transfer_prover_start, transfer_step+; simp)
   375   then show ?thesis
   376     apply (subst (asm) (2) rel_fun_def)
   377     apply (subst (2) rel_fun_def)
   378     apply (auto simp: comp_def max.absorb2 Liminf_bounded rel_fun_eq_pcr_ennreal)
   379     done
   380 qed
   381 
   382 lemma rel_fun_limsup[transfer_rule]: "rel_fun (rel_fun op = pcr_ennreal) pcr_ennreal limsup limsup"
   383 proof -
   384   have "rel_fun (rel_fun op = pcr_ennreal) pcr_ennreal (\<lambda>x. INF n. sup 0 (SUP i:{n..}. x i)) limsup"
   385     unfolding limsup_INF_SUP[abs_def] by (transfer_prover_start, transfer_step+; simp)
   386   then show ?thesis
   387     unfolding limsup_INF_SUP[abs_def]
   388     apply (subst (asm) (2) rel_fun_def)
   389     apply (subst (2) rel_fun_def)
   390     apply (auto simp: comp_def max.absorb2 Sup_upper2 rel_fun_eq_pcr_ennreal)
   391     apply (subst (asm) max.absorb2)
   392     apply (rule SUP_upper2)
   393     apply auto
   394     done
   395 qed
   396 
   397 lemma sum_enn2ereal[simp]: "(\<And>i. i \<in> I \<Longrightarrow> 0 \<le> f i) \<Longrightarrow> (\<Sum>i\<in>I. enn2ereal (f i)) = enn2ereal (sum f I)"
   398   by (induction I rule: infinite_finite_induct) (auto simp: sum_nonneg zero_ennreal.rep_eq plus_ennreal.rep_eq)
   399 
   400 lemma transfer_e2ennreal_sum [transfer_rule]:
   401   "rel_fun (rel_fun op = pcr_ennreal) (rel_fun op = pcr_ennreal) sum sum"
   402   by (auto intro!: rel_funI simp: rel_fun_eq_pcr_ennreal comp_def)
   403 
   404 lemma enn2ereal_of_nat[simp]: "enn2ereal (of_nat n) = ereal n"
   405   by (induction n) (auto simp: zero_ennreal.rep_eq one_ennreal.rep_eq plus_ennreal.rep_eq)
   406 
   407 lemma enn2ereal_numeral[simp]: "enn2ereal (numeral a) = numeral a"
   408   apply (subst of_nat_numeral[of a, symmetric])
   409   apply (subst enn2ereal_of_nat)
   410   apply simp
   411   done
   412 
   413 lemma transfer_numeral[transfer_rule]: "pcr_ennreal (numeral a) (numeral a)"
   414   unfolding cr_ennreal_def pcr_ennreal_def by auto
   415 
   416 subsection \<open>Cancellation simprocs\<close>
   417 
   418 lemma ennreal_add_left_cancel: "a + b = a + c \<longleftrightarrow> a = (\<infinity>::ennreal) \<or> b = c"
   419   unfolding infinity_ennreal_def by transfer (simp add: top_ereal_def ereal_add_cancel_left)
   420 
   421 lemma ennreal_add_left_cancel_le: "a + b \<le> a + c \<longleftrightarrow> a = (\<infinity>::ennreal) \<or> b \<le> c"
   422   unfolding infinity_ennreal_def by transfer (simp add: ereal_add_le_add_iff top_ereal_def disj_commute)
   423 
   424 lemma ereal_add_left_cancel_less:
   425   fixes a b c :: ereal
   426   shows "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a + b < a + c \<longleftrightarrow> a \<noteq> \<infinity> \<and> b < c"
   427   by (cases a b c rule: ereal3_cases) auto
   428 
   429 lemma ennreal_add_left_cancel_less: "a + b < a + c \<longleftrightarrow> a \<noteq> (\<infinity>::ennreal) \<and> b < c"
   430   unfolding infinity_ennreal_def
   431   by transfer (simp add: top_ereal_def ereal_add_left_cancel_less)
   432 
   433 ML \<open>
   434 structure Cancel_Ennreal_Common =
   435 struct
   436   (* copied from src/HOL/Tools/nat_numeral_simprocs.ML *)
   437   fun find_first_t _    _ []         = raise TERM("find_first_t", [])
   438     | find_first_t past u (t::terms) =
   439           if u aconv t then (rev past @ terms)
   440           else find_first_t (t::past) u terms
   441 
   442   fun dest_summing (Const (@{const_name Groups.plus}, _) $ t $ u, ts) =
   443         dest_summing (t, dest_summing (u, ts))
   444     | dest_summing (t, ts) = t :: ts
   445 
   446   val mk_sum = Arith_Data.long_mk_sum
   447   fun dest_sum t = dest_summing (t, [])
   448   val find_first = find_first_t []
   449   val trans_tac = Numeral_Simprocs.trans_tac
   450   val norm_ss =
   451     simpset_of (put_simpset HOL_basic_ss @{context}
   452       addsimps @{thms ac_simps add_0_left add_0_right})
   453   fun norm_tac ctxt = ALLGOALS (simp_tac (put_simpset norm_ss ctxt))
   454   fun simplify_meta_eq ctxt cancel_th th =
   455     Arith_Data.simplify_meta_eq [] ctxt
   456       ([th, cancel_th] MRS trans)
   457   fun mk_eq (a, b) = HOLogic.mk_Trueprop (HOLogic.mk_eq (a, b))
   458 end
   459 
   460 structure Eq_Ennreal_Cancel = ExtractCommonTermFun
   461 (open Cancel_Ennreal_Common
   462   val mk_bal = HOLogic.mk_eq
   463   val dest_bal = HOLogic.dest_bin @{const_name HOL.eq} @{typ ennreal}
   464   fun simp_conv _ _ = SOME @{thm ennreal_add_left_cancel}
   465 )
   466 
   467 structure Le_Ennreal_Cancel = ExtractCommonTermFun
   468 (open Cancel_Ennreal_Common
   469   val mk_bal = HOLogic.mk_binrel @{const_name Orderings.less_eq}
   470   val dest_bal = HOLogic.dest_bin @{const_name Orderings.less_eq} @{typ ennreal}
   471   fun simp_conv _ _ = SOME @{thm ennreal_add_left_cancel_le}
   472 )
   473 
   474 structure Less_Ennreal_Cancel = ExtractCommonTermFun
   475 (open Cancel_Ennreal_Common
   476   val mk_bal = HOLogic.mk_binrel @{const_name Orderings.less}
   477   val dest_bal = HOLogic.dest_bin @{const_name Orderings.less} @{typ ennreal}
   478   fun simp_conv _ _ = SOME @{thm ennreal_add_left_cancel_less}
   479 )
   480 \<close>
   481 
   482 simproc_setup ennreal_eq_cancel
   483   ("(l::ennreal) + m = n" | "(l::ennreal) = m + n") =
   484   \<open>fn phi => fn ctxt => fn ct => Eq_Ennreal_Cancel.proc ctxt (Thm.term_of ct)\<close>
   485 
   486 simproc_setup ennreal_le_cancel
   487   ("(l::ennreal) + m \<le> n" | "(l::ennreal) \<le> m + n") =
   488   \<open>fn phi => fn ctxt => fn ct => Le_Ennreal_Cancel.proc ctxt (Thm.term_of ct)\<close>
   489 
   490 simproc_setup ennreal_less_cancel
   491   ("(l::ennreal) + m < n" | "(l::ennreal) < m + n") =
   492   \<open>fn phi => fn ctxt => fn ct => Less_Ennreal_Cancel.proc ctxt (Thm.term_of ct)\<close>
   493 
   494 
   495 subsection \<open>Order with top\<close>
   496 
   497 lemma ennreal_zero_less_top[simp]: "0 < (top::ennreal)"
   498   by transfer (simp add: top_ereal_def)
   499 
   500 lemma ennreal_one_less_top[simp]: "1 < (top::ennreal)"
   501   by transfer (simp add: top_ereal_def)
   502 
   503 lemma ennreal_zero_neq_top[simp]: "0 \<noteq> (top::ennreal)"
   504   by transfer (simp add: top_ereal_def)
   505 
   506 lemma ennreal_top_neq_zero[simp]: "(top::ennreal) \<noteq> 0"
   507   by transfer (simp add: top_ereal_def)
   508 
   509 lemma ennreal_top_neq_one[simp]: "top \<noteq> (1::ennreal)"
   510   by transfer (simp add: top_ereal_def one_ereal_def ereal_max[symmetric] del: ereal_max)
   511 
   512 lemma ennreal_one_neq_top[simp]: "1 \<noteq> (top::ennreal)"
   513   by transfer (simp add: top_ereal_def one_ereal_def ereal_max[symmetric] del: ereal_max)
   514 
   515 lemma ennreal_add_less_top[simp]:
   516   fixes a b :: ennreal
   517   shows "a + b < top \<longleftrightarrow> a < top \<and> b < top"
   518   by transfer (auto simp: top_ereal_def)
   519 
   520 lemma ennreal_add_eq_top[simp]:
   521   fixes a b :: ennreal
   522   shows "a + b = top \<longleftrightarrow> a = top \<or> b = top"
   523   by transfer (auto simp: top_ereal_def)
   524 
   525 lemma ennreal_sum_less_top[simp]:
   526   fixes f :: "'a \<Rightarrow> ennreal"
   527   shows "finite I \<Longrightarrow> (\<Sum>i\<in>I. f i) < top \<longleftrightarrow> (\<forall>i\<in>I. f i < top)"
   528   by (induction I rule: finite_induct) auto
   529 
   530 lemma ennreal_sum_eq_top[simp]:
   531   fixes f :: "'a \<Rightarrow> ennreal"
   532   shows "finite I \<Longrightarrow> (\<Sum>i\<in>I. f i) = top \<longleftrightarrow> (\<exists>i\<in>I. f i = top)"
   533   by (induction I rule: finite_induct) auto
   534 
   535 lemma ennreal_mult_eq_top_iff:
   536   fixes a b :: ennreal
   537   shows "a * b = top \<longleftrightarrow> (a = top \<and> b \<noteq> 0) \<or> (b = top \<and> a \<noteq> 0)"
   538   by transfer (auto simp: top_ereal_def)
   539 
   540 lemma ennreal_top_eq_mult_iff:
   541   fixes a b :: ennreal
   542   shows "top = a * b \<longleftrightarrow> (a = top \<and> b \<noteq> 0) \<or> (b = top \<and> a \<noteq> 0)"
   543   using ennreal_mult_eq_top_iff[of a b] by auto
   544 
   545 lemma ennreal_mult_less_top:
   546   fixes a b :: ennreal
   547   shows "a * b < top \<longleftrightarrow> (a = 0 \<or> b = 0 \<or> (a < top \<and> b < top))"
   548   by transfer (auto simp add: top_ereal_def)
   549 
   550 lemma top_power_ennreal: "top ^ n = (if n = 0 then 1 else top :: ennreal)"
   551   by (induction n) (simp_all add: ennreal_mult_eq_top_iff)
   552 
   553 lemma ennreal_prod_eq_0[simp]:
   554   fixes f :: "'a \<Rightarrow> ennreal"
   555   shows "(prod f A = 0) = (finite A \<and> (\<exists>i\<in>A. f i = 0))"
   556   by (induction A rule: infinite_finite_induct) auto
   557 
   558 lemma ennreal_prod_eq_top:
   559   fixes f :: "'a \<Rightarrow> ennreal"
   560   shows "(\<Prod>i\<in>I. f i) = top \<longleftrightarrow> (finite I \<and> ((\<forall>i\<in>I. f i \<noteq> 0) \<and> (\<exists>i\<in>I. f i = top)))"
   561   by (induction I rule: infinite_finite_induct) (auto simp: ennreal_mult_eq_top_iff)
   562 
   563 lemma ennreal_top_mult: "top * a = (if a = 0 then 0 else top :: ennreal)"
   564   by (simp add: ennreal_mult_eq_top_iff)
   565 
   566 lemma ennreal_mult_top: "a * top = (if a = 0 then 0 else top :: ennreal)"
   567   by (simp add: ennreal_mult_eq_top_iff)
   568 
   569 lemma enn2ereal_eq_top_iff[simp]: "enn2ereal x = \<infinity> \<longleftrightarrow> x = top"
   570   by transfer (simp add: top_ereal_def)
   571 
   572 lemma enn2ereal_top: "enn2ereal top = \<infinity>"
   573   by transfer (simp add: top_ereal_def)
   574 
   575 lemma e2ennreal_infty: "e2ennreal \<infinity> = top"
   576   by (simp add: top_ennreal.abs_eq top_ereal_def)
   577 
   578 lemma ennreal_top_minus[simp]: "top - x = (top::ennreal)"
   579   by transfer (auto simp: top_ereal_def max_def)
   580 
   581 lemma minus_top_ennreal: "x - top = (if x = top then top else 0:: ennreal)"
   582   apply transfer
   583   subgoal for x
   584     by (cases x) (auto simp: top_ereal_def max_def)
   585   done
   586 
   587 lemma bot_ennreal: "bot = (0::ennreal)"
   588   by transfer rule
   589 
   590 lemma ennreal_of_nat_neq_top[simp]: "of_nat i \<noteq> (top::ennreal)"
   591   by (induction i) auto
   592 
   593 lemma numeral_eq_of_nat: "(numeral a::ennreal) = of_nat (numeral a)"
   594   by simp
   595 
   596 lemma of_nat_less_top: "of_nat i < (top::ennreal)"
   597   using less_le_trans[of "of_nat i" "of_nat (Suc i)" "top::ennreal"]
   598   by simp
   599 
   600 lemma top_neq_numeral[simp]: "top \<noteq> (numeral i::ennreal)"
   601   using of_nat_less_top[of "numeral i"] by simp
   602 
   603 lemma ennreal_numeral_less_top[simp]: "numeral i < (top::ennreal)"
   604   using of_nat_less_top[of "numeral i"] by simp
   605 
   606 lemma ennreal_add_bot[simp]: "bot + x = (x::ennreal)"
   607   by transfer simp
   608 
   609 instance ennreal :: semiring_char_0
   610 proof (standard, safe intro!: linorder_injI)
   611   have *: "1 + of_nat k \<noteq> (0::ennreal)" for k
   612     using add_pos_nonneg[OF zero_less_one, of "of_nat k :: ennreal"] by auto
   613   fix x y :: nat assume "x < y" "of_nat x = (of_nat y::ennreal)" then show False
   614     by (auto simp add: less_iff_Suc_add *)
   615 qed
   616 
   617 subsection \<open>Arithmetic\<close>
   618 
   619 lemma ennreal_minus_zero[simp]: "a - (0::ennreal) = a"
   620   by transfer (auto simp: max_def)
   621 
   622 lemma ennreal_add_diff_cancel_right[simp]:
   623   fixes x y z :: ennreal shows "y \<noteq> top \<Longrightarrow> (x + y) - y = x"
   624   apply transfer
   625   subgoal for x y
   626     apply (cases x y rule: ereal2_cases)
   627     apply (auto split: split_max simp: top_ereal_def)
   628     done
   629   done
   630 
   631 lemma ennreal_add_diff_cancel_left[simp]:
   632   fixes x y z :: ennreal shows "y \<noteq> top \<Longrightarrow> (y + x) - y = x"
   633   by (simp add: add.commute)
   634 
   635 lemma
   636   fixes a b :: ennreal
   637   shows "a - b = 0 \<Longrightarrow> a \<le> b"
   638   apply transfer
   639   subgoal for a b
   640     apply (cases a b rule: ereal2_cases)
   641     apply (auto simp: not_le max_def split: if_splits)
   642     done
   643   done
   644 
   645 lemma ennreal_minus_cancel:
   646   fixes a b c :: ennreal
   647   shows "c \<noteq> top \<Longrightarrow> a \<le> c \<Longrightarrow> b \<le> c \<Longrightarrow> c - a = c - b \<Longrightarrow> a = b"
   648   apply transfer
   649   subgoal for a b c
   650     by (cases a b c rule: ereal3_cases)
   651        (auto simp: top_ereal_def max_def split: if_splits)
   652   done
   653 
   654 lemma sup_const_add_ennreal:
   655   fixes a b c :: "ennreal"
   656   shows "sup (c + a) (c + b) = c + sup a b"
   657   apply transfer
   658   subgoal for a b c
   659     apply (cases a b c rule: ereal3_cases)
   660     apply (auto simp: ereal_max[symmetric] simp del: ereal_max)
   661     apply (auto simp: top_ereal_def[symmetric] sup_ereal_def[symmetric]
   662                 simp del: sup_ereal_def)
   663     apply (auto simp add: top_ereal_def)
   664     done
   665   done
   666 
   667 lemma ennreal_diff_add_assoc:
   668   fixes a b c :: ennreal
   669   shows "a \<le> b \<Longrightarrow> c + b - a = c + (b - a)"
   670   apply transfer
   671   subgoal for a b c
   672     by (cases a b c rule: ereal3_cases) (auto simp: field_simps max_absorb2)
   673   done
   674 
   675 lemma mult_divide_eq_ennreal:
   676   fixes a b :: ennreal
   677   shows "b \<noteq> 0 \<Longrightarrow> b \<noteq> top \<Longrightarrow> (a * b) / b = a"
   678   unfolding divide_ennreal_def
   679   apply transfer
   680   apply (subst mult.assoc)
   681   apply (simp add: top_ereal_def divide_ereal_def[symmetric])
   682   done
   683 
   684 lemma divide_mult_eq: "a \<noteq> 0 \<Longrightarrow> a \<noteq> \<infinity> \<Longrightarrow> x * a / (b * a) = x / (b::ennreal)"
   685   unfolding divide_ennreal_def infinity_ennreal_def
   686   apply transfer
   687   subgoal for a b c
   688     apply (cases a b c rule: ereal3_cases)
   689     apply (auto simp: top_ereal_def)
   690     done
   691   done
   692 
   693 lemma ennreal_mult_divide_eq:
   694   fixes a b :: ennreal
   695   shows "b \<noteq> 0 \<Longrightarrow> b \<noteq> top \<Longrightarrow> (a * b) / b = a"
   696   unfolding divide_ennreal_def
   697   apply transfer
   698   apply (subst mult.assoc)
   699   apply (simp add: top_ereal_def divide_ereal_def[symmetric])
   700   done
   701 
   702 lemma ennreal_add_diff_cancel:
   703   fixes a b :: ennreal
   704   shows "b \<noteq> \<infinity> \<Longrightarrow> (a + b) - b = a"
   705   unfolding infinity_ennreal_def
   706   by transfer (simp add: max_absorb2 top_ereal_def ereal_add_diff_cancel)
   707 
   708 lemma ennreal_minus_eq_0:
   709   "a - b = 0 \<Longrightarrow> a \<le> (b::ennreal)"
   710   apply transfer
   711   subgoal for a b
   712     apply (cases a b rule: ereal2_cases)
   713     apply (auto simp: zero_ereal_def ereal_max[symmetric] max.absorb2 simp del: ereal_max)
   714     done
   715   done
   716 
   717 lemma ennreal_mono_minus_cancel:
   718   fixes a b c :: ennreal
   719   shows "a - b \<le> a - c \<Longrightarrow> a < top \<Longrightarrow> b \<le> a \<Longrightarrow> c \<le> a \<Longrightarrow> c \<le> b"
   720   by transfer
   721      (auto simp add: max.absorb2 ereal_diff_positive top_ereal_def dest: ereal_mono_minus_cancel)
   722 
   723 lemma ennreal_mono_minus:
   724   fixes a b c :: ennreal
   725   shows "c \<le> b \<Longrightarrow> a - b \<le> a - c"
   726   apply transfer
   727   apply (rule max.mono)
   728   apply simp
   729   subgoal for a b c
   730     by (cases a b c rule: ereal3_cases) auto
   731   done
   732 
   733 lemma ennreal_minus_pos_iff:
   734   fixes a b :: ennreal
   735   shows "a < top \<or> b < top \<Longrightarrow> 0 < a - b \<Longrightarrow> b < a"
   736   apply transfer
   737   subgoal for a b
   738     by (cases a b rule: ereal2_cases) (auto simp: less_max_iff_disj)
   739   done
   740 
   741 lemma ennreal_inverse_top[simp]: "inverse top = (0::ennreal)"
   742   by transfer (simp add: top_ereal_def ereal_inverse_eq_0)
   743 
   744 lemma ennreal_inverse_zero[simp]: "inverse 0 = (top::ennreal)"
   745   by transfer (simp add: top_ereal_def ereal_inverse_eq_0)
   746 
   747 lemma ennreal_top_divide: "top / (x::ennreal) = (if x = top then 0 else top)"
   748   unfolding divide_ennreal_def
   749   by transfer (simp add: top_ereal_def ereal_inverse_eq_0 ereal_0_gt_inverse)
   750 
   751 lemma ennreal_zero_divide[simp]: "0 / (x::ennreal) = 0"
   752   by (simp add: divide_ennreal_def)
   753 
   754 lemma ennreal_divide_zero[simp]: "x / (0::ennreal) = (if x = 0 then 0 else top)"
   755   by (simp add: divide_ennreal_def ennreal_mult_top)
   756 
   757 lemma ennreal_divide_top[simp]: "x / (top::ennreal) = 0"
   758   by (simp add: divide_ennreal_def ennreal_top_mult)
   759 
   760 lemma ennreal_times_divide: "a * (b / c) = a * b / (c::ennreal)"
   761   unfolding divide_ennreal_def
   762   by transfer (simp add: divide_ereal_def[symmetric] ereal_times_divide_eq)
   763 
   764 lemma ennreal_zero_less_divide: "0 < a / b \<longleftrightarrow> (0 < a \<and> b < (top::ennreal))"
   765   unfolding divide_ennreal_def
   766   by transfer (auto simp: ereal_zero_less_0_iff top_ereal_def ereal_0_gt_inverse)
   767 
   768 lemma divide_right_mono_ennreal:
   769   fixes a b c :: ennreal
   770   shows "a \<le> b \<Longrightarrow> a / c \<le> b / c"
   771   unfolding divide_ennreal_def by (intro mult_mono) auto
   772 
   773 lemma ennreal_mult_strict_right_mono: "(a::ennreal) < c \<Longrightarrow> 0 < b \<Longrightarrow> b < top \<Longrightarrow> a * b < c * b"
   774   by transfer (auto intro!: ereal_mult_strict_right_mono)
   775 
   776 lemma ennreal_indicator_less[simp]:
   777   "indicator A x \<le> (indicator B x::ennreal) \<longleftrightarrow> (x \<in> A \<longrightarrow> x \<in> B)"
   778   by (simp add: indicator_def not_le)
   779 
   780 lemma ennreal_inverse_positive: "0 < inverse x \<longleftrightarrow> (x::ennreal) \<noteq> top"
   781   by transfer (simp add: ereal_0_gt_inverse top_ereal_def)
   782 
   783 lemma ennreal_inverse_mult': "((0 < b \<or> a < top) \<and> (0 < a \<or> b < top)) \<Longrightarrow> inverse (a * b::ennreal) = inverse a * inverse b"
   784   apply transfer
   785   subgoal for a b
   786     by (cases a b rule: ereal2_cases) (auto simp: top_ereal_def)
   787   done
   788 
   789 lemma ennreal_inverse_mult: "a < top \<Longrightarrow> b < top \<Longrightarrow> inverse (a * b::ennreal) = inverse a * inverse b"
   790   apply transfer
   791   subgoal for a b
   792     by (cases a b rule: ereal2_cases) (auto simp: top_ereal_def)
   793   done
   794 
   795 lemma ennreal_inverse_1[simp]: "inverse (1::ennreal) = 1"
   796   by transfer simp
   797 
   798 lemma ennreal_inverse_eq_0_iff[simp]: "inverse (a::ennreal) = 0 \<longleftrightarrow> a = top"
   799   by transfer (simp add: ereal_inverse_eq_0 top_ereal_def)
   800 
   801 lemma ennreal_inverse_eq_top_iff[simp]: "inverse (a::ennreal) = top \<longleftrightarrow> a = 0"
   802   by transfer (simp add: top_ereal_def)
   803 
   804 lemma ennreal_divide_eq_0_iff[simp]: "(a::ennreal) / b = 0 \<longleftrightarrow> (a = 0 \<or> b = top)"
   805   by (simp add: divide_ennreal_def)
   806 
   807 lemma ennreal_divide_eq_top_iff: "(a::ennreal) / b = top \<longleftrightarrow> ((a \<noteq> 0 \<and> b = 0) \<or> (a = top \<and> b \<noteq> top))"
   808   by (auto simp add: divide_ennreal_def ennreal_mult_eq_top_iff)
   809 
   810 lemma one_divide_one_divide_ennreal[simp]: "1 / (1 / c) = (c::ennreal)"
   811   including ennreal.lifting
   812   unfolding divide_ennreal_def
   813   by transfer auto
   814 
   815 lemma ennreal_mult_left_cong:
   816   "((a::ennreal) \<noteq> 0 \<Longrightarrow> b = c) \<Longrightarrow> a * b = a * c"
   817   by (cases "a = 0") simp_all
   818 
   819 lemma ennreal_mult_right_cong:
   820   "((a::ennreal) \<noteq> 0 \<Longrightarrow> b = c) \<Longrightarrow> b * a = c * a"
   821   by (cases "a = 0") simp_all
   822 
   823 lemma ennreal_zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < (b::ennreal)"
   824   by transfer (auto simp add: ereal_zero_less_0_iff le_less)
   825 
   826 lemma less_diff_eq_ennreal:
   827   fixes a b c :: ennreal
   828   shows "b < top \<or> c < top \<Longrightarrow> a < b - c \<longleftrightarrow> a + c < b"
   829   apply transfer
   830   subgoal for a b c
   831     by (cases a b c rule: ereal3_cases) (auto split: split_max)
   832   done
   833 
   834 lemma diff_add_cancel_ennreal:
   835   fixes a b :: ennreal shows "a \<le> b \<Longrightarrow> b - a + a = b"
   836   unfolding infinity_ennreal_def
   837   apply transfer
   838   subgoal for a b
   839     by (cases a b rule: ereal2_cases) (auto simp: max_absorb2)
   840   done
   841 
   842 lemma ennreal_diff_self[simp]: "a \<noteq> top \<Longrightarrow> a - a = (0::ennreal)"
   843   by transfer (simp add: top_ereal_def)
   844 
   845 lemma ennreal_minus_mono:
   846   fixes a b c :: ennreal
   847   shows "a \<le> c \<Longrightarrow> d \<le> b \<Longrightarrow> a - b \<le> c - d"
   848   apply transfer
   849   apply (rule max.mono)
   850   apply simp
   851   subgoal for a b c d
   852     by (cases a b c d rule: ereal3_cases[case_product ereal_cases]) auto
   853   done
   854 
   855 lemma ennreal_minus_eq_top[simp]: "a - (b::ennreal) = top \<longleftrightarrow> a = top"
   856   by transfer (auto simp: top_ereal_def max.absorb2 ereal_minus_eq_PInfty_iff split: split_max)
   857 
   858 lemma ennreal_divide_self[simp]: "a \<noteq> 0 \<Longrightarrow> a < top \<Longrightarrow> a / a = (1::ennreal)"
   859   unfolding divide_ennreal_def
   860   apply transfer
   861   subgoal for a
   862     by (cases a) (auto simp: top_ereal_def)
   863   done
   864 
   865 subsection \<open>Coercion from @{typ real} to @{typ ennreal}\<close>
   866 
   867 lift_definition ennreal :: "real \<Rightarrow> ennreal" is "sup 0 \<circ> ereal"
   868   by simp
   869 
   870 declare [[coercion ennreal]]
   871 
   872 lemma ennreal_cong: "x = y \<Longrightarrow> ennreal x = ennreal y" by simp
   873 
   874 lemma ennreal_cases[cases type: ennreal]:
   875   fixes x :: ennreal
   876   obtains (real) r :: real where "0 \<le> r" "x = ennreal r" | (top) "x = top"
   877   apply transfer
   878   subgoal for x thesis
   879     by (cases x) (auto simp: max.absorb2 top_ereal_def)
   880   done
   881 
   882 lemmas ennreal2_cases = ennreal_cases[case_product ennreal_cases]
   883 lemmas ennreal3_cases = ennreal_cases[case_product ennreal2_cases]
   884 
   885 lemma ennreal_neq_top[simp]: "ennreal r \<noteq> top"
   886   by transfer (simp add: top_ereal_def zero_ereal_def ereal_max[symmetric] del: ereal_max)
   887 
   888 lemma top_neq_ennreal[simp]: "top \<noteq> ennreal r"
   889   using ennreal_neq_top[of r] by (auto simp del: ennreal_neq_top)
   890 
   891 lemma ennreal_less_top[simp]: "ennreal x < top"
   892   by transfer (simp add: top_ereal_def max_def)
   893 
   894 lemma ennreal_neg: "x \<le> 0 \<Longrightarrow> ennreal x = 0"
   895   by transfer (simp add: max.absorb1)
   896 
   897 lemma ennreal_inj[simp]:
   898   "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> ennreal a = ennreal b \<longleftrightarrow> a = b"
   899   by (transfer fixing: a b) (auto simp: max_absorb2)
   900 
   901 lemma ennreal_le_iff[simp]: "0 \<le> y \<Longrightarrow> ennreal x \<le> ennreal y \<longleftrightarrow> x \<le> y"
   902   by (auto simp: ennreal_def zero_ereal_def less_eq_ennreal.abs_eq eq_onp_def split: split_max)
   903 
   904 lemma le_ennreal_iff: "0 \<le> r \<Longrightarrow> x \<le> ennreal r \<longleftrightarrow> (\<exists>q\<ge>0. x = ennreal q \<and> q \<le> r)"
   905   by (cases x) (auto simp: top_unique)
   906 
   907 lemma ennreal_less_iff: "0 \<le> r \<Longrightarrow> ennreal r < ennreal q \<longleftrightarrow> r < q"
   908   unfolding not_le[symmetric] by auto
   909 
   910 lemma ennreal_eq_zero_iff[simp]: "0 \<le> x \<Longrightarrow> ennreal x = 0 \<longleftrightarrow> x = 0"
   911   by transfer (auto simp: max_absorb2)
   912 
   913 lemma ennreal_less_zero_iff[simp]: "0 < ennreal x \<longleftrightarrow> 0 < x"
   914   by transfer (auto simp: max_def)
   915 
   916 lemma ennreal_lessI: "0 < q \<Longrightarrow> r < q \<Longrightarrow> ennreal r < ennreal q"
   917   by (cases "0 \<le> r") (auto simp: ennreal_less_iff ennreal_neg)
   918 
   919 lemma ennreal_leI: "x \<le> y \<Longrightarrow> ennreal x \<le> ennreal y"
   920   by (cases "0 \<le> y") (auto simp: ennreal_neg)
   921 
   922 lemma enn2ereal_ennreal[simp]: "0 \<le> x \<Longrightarrow> enn2ereal (ennreal x) = x"
   923   by transfer (simp add: max_absorb2)
   924 
   925 lemma e2ennreal_enn2ereal[simp]: "e2ennreal (enn2ereal x) = x"
   926   by (simp add: e2ennreal_def max_absorb2 ennreal.enn2ereal_inverse)
   927 
   928 lemma ennreal_0[simp]: "ennreal 0 = 0"
   929   by (simp add: ennreal_def max.absorb1 zero_ennreal.abs_eq)
   930 
   931 lemma ennreal_1[simp]: "ennreal 1 = 1"
   932   by transfer (simp add: max_absorb2)
   933 
   934 lemma ennreal_eq_0_iff: "ennreal x = 0 \<longleftrightarrow> x \<le> 0"
   935   by (cases "0 \<le> x") (auto simp: ennreal_neg)
   936 
   937 lemma ennreal_le_iff2: "ennreal x \<le> ennreal y \<longleftrightarrow> ((0 \<le> y \<and> x \<le> y) \<or> (x \<le> 0 \<and> y \<le> 0))"
   938   by (cases "0 \<le> y") (auto simp: ennreal_eq_0_iff ennreal_neg)
   939 
   940 lemma ennreal_eq_1[simp]: "ennreal x = 1 \<longleftrightarrow> x = 1"
   941   by (cases "0 \<le> x")
   942      (auto simp: ennreal_neg ennreal_1[symmetric] simp del: ennreal_1)
   943 
   944 lemma ennreal_le_1[simp]: "ennreal x \<le> 1 \<longleftrightarrow> x \<le> 1"
   945   by (cases "0 \<le> x")
   946      (auto simp: ennreal_neg ennreal_1[symmetric] simp del: ennreal_1)
   947 
   948 lemma ennreal_ge_1[simp]: "ennreal x \<ge> 1 \<longleftrightarrow> x \<ge> 1"
   949   by (cases "0 \<le> x")
   950      (auto simp: ennreal_neg ennreal_1[symmetric] simp del: ennreal_1)
   951 
   952 lemma one_less_ennreal[simp]: "1 < ennreal x \<longleftrightarrow> 1 < x"
   953   by transfer (auto simp: max.absorb2 less_max_iff_disj)
   954 
   955 lemma ennreal_plus[simp]:
   956   "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> ennreal (a + b) = ennreal a + ennreal b"
   957   by (transfer fixing: a b) (auto simp: max_absorb2)
   958 
   959 lemma sum_ennreal[simp]: "(\<And>i. i \<in> I \<Longrightarrow> 0 \<le> f i) \<Longrightarrow> (\<Sum>i\<in>I. ennreal (f i)) = ennreal (sum f I)"
   960   by (induction I rule: infinite_finite_induct) (auto simp: sum_nonneg)
   961 
   962 lemma sum_list_ennreal[simp]:
   963   assumes "\<And>x. x \<in> set xs \<Longrightarrow> f x \<ge> 0"
   964   shows   "sum_list (map (\<lambda>x. ennreal (f x)) xs) = ennreal (sum_list (map f xs))"
   965 using assms
   966 proof (induction xs)
   967   case (Cons x xs)
   968   from Cons have "(\<Sum>x\<leftarrow>x # xs. ennreal (f x)) = ennreal (f x) + ennreal (sum_list (map f xs))"
   969     by simp
   970   also from Cons.prems have "\<dots> = ennreal (f x + sum_list (map f xs))"
   971     by (intro ennreal_plus [symmetric] sum_list_nonneg) auto
   972   finally show ?case by simp
   973 qed simp_all
   974 
   975 lemma ennreal_of_nat_eq_real_of_nat: "of_nat i = ennreal (of_nat i)"
   976   by (induction i) simp_all
   977 
   978 lemma of_nat_le_ennreal_iff[simp]: "0 \<le> r \<Longrightarrow> of_nat i \<le> ennreal r \<longleftrightarrow> of_nat i \<le> r"
   979   by (simp add: ennreal_of_nat_eq_real_of_nat)
   980 
   981 lemma ennreal_le_of_nat_iff[simp]: "ennreal r \<le> of_nat i \<longleftrightarrow> r \<le> of_nat i"
   982   by (simp add: ennreal_of_nat_eq_real_of_nat)
   983 
   984 lemma ennreal_indicator: "ennreal (indicator A x) = indicator A x"
   985   by (auto split: split_indicator)
   986 
   987 lemma ennreal_numeral[simp]: "ennreal (numeral n) = numeral n"
   988   using ennreal_of_nat_eq_real_of_nat[of "numeral n"] by simp
   989 
   990 lemma min_ennreal: "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> min (ennreal x) (ennreal y) = ennreal (min x y)"
   991   by (auto split: split_min)
   992 
   993 lemma ennreal_half[simp]: "ennreal (1/2) = inverse 2"
   994   by transfer (simp add: max.absorb2)
   995 
   996 lemma ennreal_minus: "0 \<le> q \<Longrightarrow> ennreal r - ennreal q = ennreal (r - q)"
   997   by transfer
   998      (simp add: max.absorb2 zero_ereal_def ereal_max[symmetric] del: ereal_max)
   999 
  1000 lemma ennreal_minus_top[simp]: "ennreal a - top = 0"
  1001   by (simp add: minus_top_ennreal)
  1002 
  1003 lemma ennreal_mult: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> ennreal (a * b) = ennreal a * ennreal b"
  1004   by transfer (simp add: max_absorb2)
  1005 
  1006 lemma ennreal_mult': "0 \<le> a \<Longrightarrow> ennreal (a * b) = ennreal a * ennreal b"
  1007   by (cases "0 \<le> b") (auto simp: ennreal_mult ennreal_neg mult_nonneg_nonpos)
  1008 
  1009 lemma indicator_mult_ennreal: "indicator A x * ennreal r = ennreal (indicator A x * r)"
  1010   by (simp split: split_indicator)
  1011 
  1012 lemma ennreal_mult'': "0 \<le> b \<Longrightarrow> ennreal (a * b) = ennreal a * ennreal b"
  1013   by (cases "0 \<le> a") (auto simp: ennreal_mult ennreal_neg mult_nonpos_nonneg)
  1014 
  1015 lemma numeral_mult_ennreal: "0 \<le> x \<Longrightarrow> numeral b * ennreal x = ennreal (numeral b * x)"
  1016   by (simp add: ennreal_mult)
  1017 
  1018 lemma ennreal_power: "0 \<le> r \<Longrightarrow> ennreal r ^ n = ennreal (r ^ n)"
  1019   by (induction n) (auto simp: ennreal_mult)
  1020 
  1021 lemma power_eq_top_ennreal: "x ^ n = top \<longleftrightarrow> (n \<noteq> 0 \<and> (x::ennreal) = top)"
  1022   by (cases x rule: ennreal_cases)
  1023      (auto simp: ennreal_power top_power_ennreal)
  1024 
  1025 lemma inverse_ennreal: "0 < r \<Longrightarrow> inverse (ennreal r) = ennreal (inverse r)"
  1026   by transfer (simp add: max.absorb2)
  1027 
  1028 lemma divide_ennreal: "0 \<le> r \<Longrightarrow> 0 < q \<Longrightarrow> ennreal r / ennreal q = ennreal (r / q)"
  1029   by (simp add: divide_ennreal_def inverse_ennreal ennreal_mult[symmetric] inverse_eq_divide)
  1030 
  1031 lemma ennreal_inverse_power: "inverse (x ^ n :: ennreal) = inverse x ^ n"
  1032 proof (cases x rule: ennreal_cases)
  1033   case top with power_eq_top_ennreal[of x n] show ?thesis
  1034     by (cases "n = 0") auto
  1035 next
  1036   case (real r) then show ?thesis
  1037   proof cases
  1038     assume "x = 0" then show ?thesis
  1039       using power_eq_top_ennreal[of top "n - 1"]
  1040       by (cases n) (auto simp: ennreal_top_mult)
  1041   next
  1042     assume "x \<noteq> 0"
  1043     with real have "0 < r" by auto
  1044     with real show ?thesis
  1045       by (induction n)
  1046          (auto simp add: ennreal_power ennreal_mult[symmetric] inverse_ennreal)
  1047   qed
  1048 qed
  1049 
  1050 lemma ennreal_divide_numeral: "0 \<le> x \<Longrightarrow> ennreal x / numeral b = ennreal (x / numeral b)"
  1051   by (subst divide_ennreal[symmetric]) auto
  1052 
  1053 lemma prod_ennreal: "(\<And>i. i \<in> A \<Longrightarrow> 0 \<le> f i) \<Longrightarrow> (\<Prod>i\<in>A. ennreal (f i)) = ennreal (prod f A)"
  1054   by (induction A rule: infinite_finite_induct)
  1055      (auto simp: ennreal_mult prod_nonneg)
  1056 
  1057 lemma mult_right_ennreal_cancel: "a * ennreal c = b * ennreal c \<longleftrightarrow> (a = b \<or> c \<le> 0)"
  1058   apply (cases "0 \<le> c")
  1059   apply (cases a b rule: ennreal2_cases)
  1060   apply (auto simp: ennreal_mult[symmetric] ennreal_neg ennreal_top_mult)
  1061   done
  1062 
  1063 lemma ennreal_le_epsilon:
  1064   "(\<And>e::real. y < top \<Longrightarrow> 0 < e \<Longrightarrow> x \<le> y + ennreal e) \<Longrightarrow> x \<le> y"
  1065   apply (cases y rule: ennreal_cases)
  1066   apply (cases x rule: ennreal_cases)
  1067   apply (auto simp del: ennreal_plus simp add: top_unique ennreal_plus[symmetric]
  1068     intro: zero_less_one field_le_epsilon)
  1069   done
  1070 
  1071 lemma ennreal_rat_dense:
  1072   fixes x y :: ennreal
  1073   shows "x < y \<Longrightarrow> \<exists>r::rat. x < real_of_rat r \<and> real_of_rat r < y"
  1074 proof transfer
  1075   fix x y :: ereal assume xy: "0 \<le> x" "0 \<le> y" "x < y"
  1076   moreover
  1077   from ereal_dense3[OF \<open>x < y\<close>]
  1078   obtain r where r: "x < ereal (real_of_rat r)" "ereal (real_of_rat r) < y"
  1079     by auto
  1080   then have "0 \<le> r"
  1081     using le_less_trans[OF \<open>0 \<le> x\<close> \<open>x < ereal (real_of_rat r)\<close>] by auto
  1082   with r show "\<exists>r. x < (sup 0 \<circ> ereal) (real_of_rat r) \<and> (sup 0 \<circ> ereal) (real_of_rat r) < y"
  1083     by (intro exI[of _ r]) (auto simp: max_absorb2)
  1084 qed
  1085 
  1086 lemma ennreal_Ex_less_of_nat: "(x::ennreal) < top \<Longrightarrow> \<exists>n. x < of_nat n"
  1087   by (cases x rule: ennreal_cases)
  1088      (auto simp: ennreal_of_nat_eq_real_of_nat ennreal_less_iff reals_Archimedean2)
  1089 
  1090 subsection \<open>Coercion from @{typ ennreal} to @{typ real}\<close>
  1091 
  1092 definition "enn2real x = real_of_ereal (enn2ereal x)"
  1093 
  1094 lemma enn2real_nonneg[simp]: "0 \<le> enn2real x"
  1095   by (auto simp: enn2real_def intro!: real_of_ereal_pos enn2ereal_nonneg)
  1096 
  1097 lemma enn2real_mono: "a \<le> b \<Longrightarrow> b < top \<Longrightarrow> enn2real a \<le> enn2real b"
  1098   by (auto simp add: enn2real_def less_eq_ennreal.rep_eq intro!: real_of_ereal_positive_mono enn2ereal_nonneg)
  1099 
  1100 lemma enn2real_of_nat[simp]: "enn2real (of_nat n) = n"
  1101   by (auto simp: enn2real_def)
  1102 
  1103 lemma enn2real_ennreal[simp]: "0 \<le> r \<Longrightarrow> enn2real (ennreal r) = r"
  1104   by (simp add: enn2real_def)
  1105 
  1106 lemma ennreal_enn2real[simp]: "r < top \<Longrightarrow> ennreal (enn2real r) = r"
  1107   by (cases r rule: ennreal_cases) auto
  1108 
  1109 lemma real_of_ereal_enn2ereal[simp]: "real_of_ereal (enn2ereal x) = enn2real x"
  1110   by (simp add: enn2real_def)
  1111 
  1112 lemma enn2real_top[simp]: "enn2real top = 0"
  1113   unfolding enn2real_def top_ennreal.rep_eq top_ereal_def by simp
  1114 
  1115 lemma enn2real_0[simp]: "enn2real 0 = 0"
  1116   unfolding enn2real_def zero_ennreal.rep_eq by simp
  1117 
  1118 lemma enn2real_1[simp]: "enn2real 1 = 1"
  1119   unfolding enn2real_def one_ennreal.rep_eq by simp
  1120 
  1121 lemma enn2real_numeral[simp]: "enn2real (numeral n) = (numeral n)"
  1122   unfolding enn2real_def by simp
  1123 
  1124 lemma enn2real_mult: "enn2real (a * b) = enn2real a * enn2real b"
  1125   unfolding enn2real_def
  1126   by (simp del: real_of_ereal_enn2ereal add: times_ennreal.rep_eq)
  1127 
  1128 lemma enn2real_leI: "0 \<le> B \<Longrightarrow> x \<le> ennreal B \<Longrightarrow> enn2real x \<le> B"
  1129   by (cases x rule: ennreal_cases) (auto simp: top_unique)
  1130 
  1131 lemma enn2real_positive_iff: "0 < enn2real x \<longleftrightarrow> (0 < x \<and> x < top)"
  1132   by (cases x rule: ennreal_cases) auto
  1133 
  1134 lemma enn2real_eq_1_iff[simp]: "enn2real x = 1 \<longleftrightarrow> x = 1"
  1135   by (cases x) auto
  1136 
  1137 subsection \<open>Coercion from @{typ enat} to @{typ ennreal}\<close>
  1138 
  1139 
  1140 definition ennreal_of_enat :: "enat \<Rightarrow> ennreal"
  1141 where
  1142   "ennreal_of_enat n = (case n of \<infinity> \<Rightarrow> top | enat n \<Rightarrow> of_nat n)"
  1143 
  1144 declare [[coercion ennreal_of_enat]]
  1145 declare [[coercion "of_nat :: nat \<Rightarrow> ennreal"]]
  1146 
  1147 lemma ennreal_of_enat_infty[simp]: "ennreal_of_enat \<infinity> = \<infinity>"
  1148   by (simp add: ennreal_of_enat_def)
  1149 
  1150 lemma ennreal_of_enat_enat[simp]: "ennreal_of_enat (enat n) = of_nat n"
  1151   by (simp add: ennreal_of_enat_def)
  1152 
  1153 lemma ennreal_of_enat_0[simp]: "ennreal_of_enat 0 = 0"
  1154   using ennreal_of_enat_enat[of 0] unfolding enat_0 by simp
  1155 
  1156 lemma ennreal_of_enat_1[simp]: "ennreal_of_enat 1 = 1"
  1157   using ennreal_of_enat_enat[of 1] unfolding enat_1 by simp
  1158 
  1159 lemma ennreal_top_neq_of_nat[simp]: "(top::ennreal) \<noteq> of_nat i"
  1160   using ennreal_of_nat_neq_top[of i] by metis
  1161 
  1162 lemma ennreal_of_enat_inj[simp]: "ennreal_of_enat i = ennreal_of_enat j \<longleftrightarrow> i = j"
  1163   by (cases i j rule: enat.exhaust[case_product enat.exhaust]) auto
  1164 
  1165 lemma ennreal_of_enat_le_iff[simp]: "ennreal_of_enat m \<le> ennreal_of_enat n \<longleftrightarrow> m \<le> n"
  1166   by (auto simp: ennreal_of_enat_def top_unique split: enat.split)
  1167 
  1168 lemma of_nat_less_ennreal_of_nat[simp]: "of_nat n \<le> ennreal_of_enat x \<longleftrightarrow> of_nat n \<le> x"
  1169   by (cases x) (auto simp: of_nat_eq_enat)
  1170 
  1171 lemma ennreal_of_enat_Sup: "ennreal_of_enat (Sup X) = (SUP x:X. ennreal_of_enat x)"
  1172 proof -
  1173   have "ennreal_of_enat (Sup X) \<le> (SUP x : X. ennreal_of_enat x)"
  1174     unfolding Sup_enat_def
  1175   proof (clarsimp, intro conjI impI)
  1176     fix x assume "finite X" "X \<noteq> {}"
  1177     then show "ennreal_of_enat (Max X) \<le> (SUP x : X. ennreal_of_enat x)"
  1178       by (intro SUP_upper Max_in)
  1179   next
  1180     assume "infinite X" "X \<noteq> {}"
  1181     have "\<exists>y\<in>X. r < ennreal_of_enat y" if r: "r < top" for r
  1182     proof -
  1183       from ennreal_Ex_less_of_nat[OF r] guess n .. note n = this
  1184       have "\<not> (X \<subseteq> enat ` {.. n})"
  1185         using \<open>infinite X\<close> by (auto dest: finite_subset)
  1186       then obtain x where x: "x \<in> X" "x \<notin> enat ` {..n}"
  1187         by blast
  1188       then have "of_nat n \<le> x"
  1189         by (cases x) (auto simp: of_nat_eq_enat)
  1190       with x show ?thesis
  1191         by (auto intro!: bexI[of _ x] less_le_trans[OF n])
  1192     qed
  1193     then have "(SUP x : X. ennreal_of_enat x) = top"
  1194       by simp
  1195     then show "top \<le> (SUP x : X. ennreal_of_enat x)"
  1196       unfolding top_unique by simp
  1197   qed
  1198   then show ?thesis
  1199     by (auto intro!: antisym Sup_least intro: Sup_upper)
  1200 qed
  1201 
  1202 lemma ennreal_of_enat_eSuc[simp]: "ennreal_of_enat (eSuc x) = 1 + ennreal_of_enat x"
  1203   by (cases x) (auto simp: eSuc_enat)
  1204 
  1205 subsection \<open>Topology on @{typ ennreal}\<close>
  1206 
  1207 lemma enn2ereal_Iio: "enn2ereal -` {..<a} = (if 0 \<le> a then {..< e2ennreal a} else {})"
  1208   using enn2ereal_nonneg
  1209   by (cases a rule: ereal_ennreal_cases)
  1210      (auto simp add: vimage_def set_eq_iff ennreal.enn2ereal_inverse less_ennreal.rep_eq e2ennreal_def max_absorb2
  1211            simp del: enn2ereal_nonneg
  1212            intro: le_less_trans less_imp_le)
  1213 
  1214 lemma enn2ereal_Ioi: "enn2ereal -` {a <..} = (if 0 \<le> a then {e2ennreal a <..} else UNIV)"
  1215   by (cases a rule: ereal_ennreal_cases)
  1216      (auto simp add: vimage_def set_eq_iff ennreal.enn2ereal_inverse less_ennreal.rep_eq e2ennreal_def max_absorb2
  1217            intro: less_le_trans)
  1218 
  1219 instantiation ennreal :: linear_continuum_topology
  1220 begin
  1221 
  1222 definition open_ennreal :: "ennreal set \<Rightarrow> bool"
  1223   where "(open :: ennreal set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
  1224 
  1225 instance
  1226 proof
  1227   show "\<exists>a b::ennreal. a \<noteq> b"
  1228     using zero_neq_one by (intro exI)
  1229   show "\<And>x y::ennreal. x < y \<Longrightarrow> \<exists>z>x. z < y"
  1230   proof transfer
  1231     fix x y :: ereal assume "0 \<le> x" and *: "x < y"
  1232     moreover from dense[OF *] guess z ..
  1233     ultimately show "\<exists>z\<in>Collect (op \<le> 0). x < z \<and> z < y"
  1234       by (intro bexI[of _ z]) auto
  1235   qed
  1236 qed (rule open_ennreal_def)
  1237 
  1238 end
  1239 
  1240 lemma continuous_on_e2ennreal: "continuous_on A e2ennreal"
  1241 proof (rule continuous_on_subset)
  1242   show "continuous_on ({0..} \<union> {..0}) e2ennreal"
  1243   proof (rule continuous_on_closed_Un)
  1244     show "continuous_on {0 ..} e2ennreal"
  1245       by (rule continuous_onI_mono)
  1246          (auto simp add: less_eq_ennreal.abs_eq eq_onp_def enn2ereal_range)
  1247     show "continuous_on {.. 0} e2ennreal"
  1248       by (subst continuous_on_cong[OF refl, of _ _ "\<lambda>_. 0"])
  1249          (auto simp add: e2ennreal_neg continuous_on_const)
  1250   qed auto
  1251   show "A \<subseteq> {0..} \<union> {..0::ereal}"
  1252     by auto
  1253 qed
  1254 
  1255 lemma continuous_at_e2ennreal: "continuous (at x within A) e2ennreal"
  1256   by (rule continuous_on_imp_continuous_within[OF continuous_on_e2ennreal, of _ UNIV]) auto
  1257 
  1258 lemma continuous_on_enn2ereal: "continuous_on UNIV enn2ereal"
  1259   by (rule continuous_on_generate_topology[OF open_generated_order])
  1260      (auto simp add: enn2ereal_Iio enn2ereal_Ioi)
  1261 
  1262 lemma continuous_at_enn2ereal: "continuous (at x within A) enn2ereal"
  1263   by (rule continuous_on_imp_continuous_within[OF continuous_on_enn2ereal]) auto
  1264 
  1265 lemma sup_continuous_e2ennreal[order_continuous_intros]:
  1266   assumes f: "sup_continuous f" shows "sup_continuous (\<lambda>x. e2ennreal (f x))"
  1267   apply (rule sup_continuous_compose[OF _ f])
  1268   apply (rule continuous_at_left_imp_sup_continuous)
  1269   apply (auto simp: mono_def e2ennreal_mono continuous_at_e2ennreal)
  1270   done
  1271 
  1272 lemma sup_continuous_enn2ereal[order_continuous_intros]:
  1273   assumes f: "sup_continuous f" shows "sup_continuous (\<lambda>x. enn2ereal (f x))"
  1274   apply (rule sup_continuous_compose[OF _ f])
  1275   apply (rule continuous_at_left_imp_sup_continuous)
  1276   apply (simp_all add: mono_def less_eq_ennreal.rep_eq continuous_at_enn2ereal)
  1277   done
  1278 
  1279 lemma sup_continuous_mult_left_ennreal':
  1280   fixes c :: "ennreal"
  1281   shows "sup_continuous (\<lambda>x. c * x)"
  1282   unfolding sup_continuous_def
  1283   by transfer (auto simp: SUP_ereal_mult_left max.absorb2 SUP_upper2)
  1284 
  1285 lemma sup_continuous_mult_left_ennreal[order_continuous_intros]:
  1286   "sup_continuous f \<Longrightarrow> sup_continuous (\<lambda>x. c * f x :: ennreal)"
  1287   by (rule sup_continuous_compose[OF sup_continuous_mult_left_ennreal'])
  1288 
  1289 lemma sup_continuous_mult_right_ennreal[order_continuous_intros]:
  1290   "sup_continuous f \<Longrightarrow> sup_continuous (\<lambda>x. f x * c :: ennreal)"
  1291   using sup_continuous_mult_left_ennreal[of f c] by (simp add: mult.commute)
  1292 
  1293 lemma sup_continuous_divide_ennreal[order_continuous_intros]:
  1294   fixes f g :: "'a::complete_lattice \<Rightarrow> ennreal"
  1295   shows "sup_continuous f \<Longrightarrow> sup_continuous (\<lambda>x. f x / c)"
  1296   unfolding divide_ennreal_def by (rule sup_continuous_mult_right_ennreal)
  1297 
  1298 lemma transfer_enn2ereal_continuous_on [transfer_rule]:
  1299   "rel_fun (op =) (rel_fun (rel_fun op = pcr_ennreal) op =) continuous_on continuous_on"
  1300 proof -
  1301   have "continuous_on A f" if "continuous_on A (\<lambda>x. enn2ereal (f x))" for A and f :: "'a \<Rightarrow> ennreal"
  1302     using continuous_on_compose2[OF continuous_on_e2ennreal[of "{0..}"] that]
  1303     by (auto simp: ennreal.enn2ereal_inverse subset_eq e2ennreal_def max_absorb2)
  1304   moreover
  1305   have "continuous_on A (\<lambda>x. enn2ereal (f x))" if "continuous_on A f" for A and f :: "'a \<Rightarrow> ennreal"
  1306     using continuous_on_compose2[OF continuous_on_enn2ereal that] by auto
  1307   ultimately
  1308   show ?thesis
  1309     by (auto simp add: rel_fun_def ennreal.pcr_cr_eq cr_ennreal_def)
  1310 qed
  1311 
  1312 lemma transfer_sup_continuous[transfer_rule]:
  1313   "(rel_fun (rel_fun (op =) pcr_ennreal) op =) sup_continuous sup_continuous"
  1314 proof (safe intro!: rel_funI dest!: rel_fun_eq_pcr_ennreal[THEN iffD1])
  1315   show "sup_continuous (enn2ereal \<circ> f) \<Longrightarrow> sup_continuous f" for f :: "'a \<Rightarrow> _"
  1316     using sup_continuous_e2ennreal[of "enn2ereal \<circ> f"] by simp
  1317   show "sup_continuous f \<Longrightarrow> sup_continuous (enn2ereal \<circ> f)" for f :: "'a \<Rightarrow> _"
  1318     using sup_continuous_enn2ereal[of f] by (simp add: comp_def)
  1319 qed
  1320 
  1321 lemma continuous_on_ennreal[tendsto_intros]:
  1322   "continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. ennreal (f x))"
  1323   by transfer (auto intro!: continuous_on_max continuous_on_const continuous_on_ereal)
  1324 
  1325 lemma tendsto_ennrealD:
  1326   assumes lim: "((\<lambda>x. ennreal (f x)) \<longlongrightarrow> ennreal x) F"
  1327   assumes *: "\<forall>\<^sub>F x in F. 0 \<le> f x" and x: "0 \<le> x"
  1328   shows "(f \<longlongrightarrow> x) F"
  1329   using continuous_on_tendsto_compose[OF continuous_on_enn2ereal lim]
  1330   apply simp
  1331   apply (subst (asm) tendsto_cong)
  1332   using *
  1333   apply eventually_elim
  1334   apply (auto simp: max_absorb2 \<open>0 \<le> x\<close>)
  1335   done
  1336 
  1337 lemma tendsto_ennreal_iff[simp]:
  1338   "\<forall>\<^sub>F x in F. 0 \<le> f x \<Longrightarrow> 0 \<le> x \<Longrightarrow> ((\<lambda>x. ennreal (f x)) \<longlongrightarrow> ennreal x) F \<longleftrightarrow> (f \<longlongrightarrow> x) F"
  1339   by (auto dest: tendsto_ennrealD)
  1340      (auto simp: ennreal_def
  1341            intro!: continuous_on_tendsto_compose[OF continuous_on_e2ennreal[of UNIV]] tendsto_max)
  1342 
  1343 lemma tendsto_enn2ereal_iff[simp]: "((\<lambda>i. enn2ereal (f i)) \<longlongrightarrow> enn2ereal x) F \<longleftrightarrow> (f \<longlongrightarrow> x) F"
  1344   using continuous_on_enn2ereal[THEN continuous_on_tendsto_compose, of f x F]
  1345     continuous_on_e2ennreal[THEN continuous_on_tendsto_compose, of "\<lambda>x. enn2ereal (f x)" "enn2ereal x" F UNIV]
  1346   by auto
  1347 
  1348 lemma continuous_on_add_ennreal:
  1349   fixes f g :: "'a::topological_space \<Rightarrow> ennreal"
  1350   shows "continuous_on A f \<Longrightarrow> continuous_on A g \<Longrightarrow> continuous_on A (\<lambda>x. f x + g x)"
  1351   by (transfer fixing: A) (auto intro!: tendsto_add_ereal_nonneg simp: continuous_on_def)
  1352 
  1353 lemma continuous_on_inverse_ennreal[continuous_intros]:
  1354   fixes f :: "'a::topological_space \<Rightarrow> ennreal"
  1355   shows "continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. inverse (f x))"
  1356 proof (transfer fixing: A)
  1357   show "pred_fun top  (op \<le> 0) f \<Longrightarrow> continuous_on A (\<lambda>x. inverse (f x))" if "continuous_on A f"
  1358     for f :: "'a \<Rightarrow> ereal"
  1359     using continuous_on_compose2[OF continuous_on_inverse_ereal that] by (auto simp: subset_eq)
  1360 qed
  1361 
  1362 instance ennreal :: topological_comm_monoid_add
  1363 proof
  1364   show "((\<lambda>x. fst x + snd x) \<longlongrightarrow> a + b) (nhds a \<times>\<^sub>F nhds b)" for a b :: ennreal
  1365     using continuous_on_add_ennreal[of UNIV fst snd]
  1366     using tendsto_at_iff_tendsto_nhds[symmetric, of "\<lambda>x::(ennreal \<times> ennreal). fst x + snd x"]
  1367     by (auto simp: continuous_on_eq_continuous_at)
  1368        (simp add: isCont_def nhds_prod[symmetric])
  1369 qed
  1370 
  1371 lemma sup_continuous_add_ennreal[order_continuous_intros]:
  1372   fixes f g :: "'a::complete_lattice \<Rightarrow> ennreal"
  1373   shows "sup_continuous f \<Longrightarrow> sup_continuous g \<Longrightarrow> sup_continuous (\<lambda>x. f x + g x)"
  1374   by transfer (auto intro!: sup_continuous_add)
  1375 
  1376 lemma ennreal_suminf_lessD: "(\<Sum>i. f i :: ennreal) < x \<Longrightarrow> f i < x"
  1377   using le_less_trans[OF sum_le_suminf[OF summableI, of "{i}" f]] by simp
  1378 
  1379 lemma sums_ennreal[simp]: "(\<And>i. 0 \<le> f i) \<Longrightarrow> 0 \<le> x \<Longrightarrow> (\<lambda>i. ennreal (f i)) sums ennreal x \<longleftrightarrow> f sums x"
  1380   unfolding sums_def by (simp add: always_eventually sum_nonneg)
  1381 
  1382 lemma summable_suminf_not_top: "(\<And>i. 0 \<le> f i) \<Longrightarrow> (\<Sum>i. ennreal (f i)) \<noteq> top \<Longrightarrow> summable f"
  1383   using summable_sums[OF summableI, of "\<lambda>i. ennreal (f i)"]
  1384   by (cases "\<Sum>i. ennreal (f i)" rule: ennreal_cases)
  1385      (auto simp: summable_def)
  1386 
  1387 lemma suminf_ennreal[simp]:
  1388   "(\<And>i. 0 \<le> f i) \<Longrightarrow> (\<Sum>i. ennreal (f i)) \<noteq> top \<Longrightarrow> (\<Sum>i. ennreal (f i)) = ennreal (\<Sum>i. f i)"
  1389   by (rule sums_unique[symmetric]) (simp add: summable_suminf_not_top suminf_nonneg summable_sums)
  1390 
  1391 lemma sums_enn2ereal[simp]: "(\<lambda>i. enn2ereal (f i)) sums enn2ereal x \<longleftrightarrow> f sums x"
  1392   unfolding sums_def by (simp add: always_eventually sum_nonneg)
  1393 
  1394 lemma suminf_enn2ereal[simp]: "(\<Sum>i. enn2ereal (f i)) = enn2ereal (suminf f)"
  1395   by (rule sums_unique[symmetric]) (simp add: summable_sums)
  1396 
  1397 lemma transfer_e2ennreal_suminf [transfer_rule]: "rel_fun (rel_fun op = pcr_ennreal) pcr_ennreal suminf suminf"
  1398   by (auto simp: rel_funI rel_fun_eq_pcr_ennreal comp_def)
  1399 
  1400 lemma ennreal_suminf_cmult[simp]: "(\<Sum>i. r * f i) = r * (\<Sum>i. f i::ennreal)"
  1401   by transfer (auto intro!: suminf_cmult_ereal)
  1402 
  1403 lemma ennreal_suminf_multc[simp]: "(\<Sum>i. f i * r) = (\<Sum>i. f i::ennreal) * r"
  1404   using ennreal_suminf_cmult[of r f] by (simp add: ac_simps)
  1405 
  1406 lemma ennreal_suminf_divide[simp]: "(\<Sum>i. f i / r) = (\<Sum>i. f i::ennreal) / r"
  1407   by (simp add: divide_ennreal_def)
  1408 
  1409 lemma ennreal_suminf_neq_top: "summable f \<Longrightarrow> (\<And>i. 0 \<le> f i) \<Longrightarrow> (\<Sum>i. ennreal (f i)) \<noteq> top"
  1410   using sums_ennreal[of f "suminf f"]
  1411   by (simp add: suminf_nonneg sums_unique[symmetric] summable_sums_iff[symmetric] del: sums_ennreal)
  1412 
  1413 lemma suminf_ennreal_eq:
  1414   "(\<And>i. 0 \<le> f i) \<Longrightarrow> f sums x \<Longrightarrow> (\<Sum>i. ennreal (f i)) = ennreal x"
  1415   using suminf_nonneg[of f] sums_unique[of f x]
  1416   by (intro sums_unique[symmetric]) (auto simp: summable_sums_iff)
  1417 
  1418 lemma ennreal_suminf_bound_add:
  1419   fixes f :: "nat \<Rightarrow> ennreal"
  1420   shows "(\<And>N. (\<Sum>n<N. f n) + y \<le> x) \<Longrightarrow> suminf f + y \<le> x"
  1421   by transfer (auto intro!: suminf_bound_add)
  1422 
  1423 lemma ennreal_suminf_SUP_eq_directed:
  1424   fixes f :: "'a \<Rightarrow> nat \<Rightarrow> ennreal"
  1425   assumes *: "\<And>N i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> finite N \<Longrightarrow> \<exists>k\<in>I. \<forall>n\<in>N. f i n \<le> f k n \<and> f j n \<le> f k n"
  1426   shows "(\<Sum>n. SUP i:I. f i n) = (SUP i:I. \<Sum>n. f i n)"
  1427 proof cases
  1428   assume "I \<noteq> {}"
  1429   then obtain i where "i \<in> I" by auto
  1430   from * show ?thesis
  1431     by (transfer fixing: I)
  1432        (auto simp: max_absorb2 SUP_upper2[OF \<open>i \<in> I\<close>] suminf_nonneg summable_ereal_pos \<open>I \<noteq> {}\<close>
  1433              intro!: suminf_SUP_eq_directed)
  1434 qed (simp add: bot_ennreal)
  1435 
  1436 lemma INF_ennreal_add_const:
  1437   fixes f g :: "nat \<Rightarrow> ennreal"
  1438   shows "(INF i. f i + c) = (INF i. f i) + c"
  1439   using continuous_at_Inf_mono[of "\<lambda>x. x + c" "f`UNIV"]
  1440   using continuous_add[of "at_right (Inf (range f))", of "\<lambda>x. x" "\<lambda>x. c"]
  1441   by (auto simp: mono_def)
  1442 
  1443 lemma INF_ennreal_const_add:
  1444   fixes f g :: "nat \<Rightarrow> ennreal"
  1445   shows "(INF i. c + f i) = c + (INF i. f i)"
  1446   using INF_ennreal_add_const[of f c] by (simp add: ac_simps)
  1447 
  1448 lemma SUP_mult_left_ennreal: "c * (SUP i:I. f i) = (SUP i:I. c * f i ::ennreal)"
  1449 proof cases
  1450   assume "I \<noteq> {}" then show ?thesis
  1451     by transfer (auto simp add: SUP_ereal_mult_left max_absorb2 SUP_upper2)
  1452 qed (simp add: bot_ennreal)
  1453 
  1454 lemma SUP_mult_right_ennreal: "(SUP i:I. f i) * c = (SUP i:I. f i * c ::ennreal)"
  1455   using SUP_mult_left_ennreal by (simp add: mult.commute)
  1456 
  1457 lemma SUP_divide_ennreal: "(SUP i:I. f i) / c = (SUP i:I. f i / c ::ennreal)"
  1458   using SUP_mult_right_ennreal by (simp add: divide_ennreal_def)
  1459 
  1460 lemma ennreal_SUP_of_nat_eq_top: "(SUP x. of_nat x :: ennreal) = top"
  1461 proof (intro antisym top_greatest le_SUP_iff[THEN iffD2] allI impI)
  1462   fix y :: ennreal assume "y < top"
  1463   then obtain r where "y = ennreal r"
  1464     by (cases y rule: ennreal_cases) auto
  1465   then show "\<exists>i\<in>UNIV. y < of_nat i"
  1466     using reals_Archimedean2[of "max 1 r"] zero_less_one
  1467     by (auto simp: ennreal_of_nat_eq_real_of_nat ennreal_def less_ennreal.abs_eq eq_onp_def max.absorb2
  1468              dest!: one_less_of_natD intro: less_trans)
  1469 qed
  1470 
  1471 lemma ennreal_SUP_eq_top:
  1472   fixes f :: "'a \<Rightarrow> ennreal"
  1473   assumes "\<And>n. \<exists>i\<in>I. of_nat n \<le> f i"
  1474   shows "(SUP i : I. f i) = top"
  1475 proof -
  1476   have "(SUP x. of_nat x :: ennreal) \<le> (SUP i : I. f i)"
  1477     using assms by (auto intro!: SUP_least intro: SUP_upper2)
  1478   then show ?thesis
  1479     by (auto simp: ennreal_SUP_of_nat_eq_top top_unique)
  1480 qed
  1481 
  1482 lemma ennreal_INF_const_minus:
  1483   fixes f :: "'a \<Rightarrow> ennreal"
  1484   shows "I \<noteq> {} \<Longrightarrow> (SUP x:I. c - f x) = c - (INF x:I. f x)"
  1485   by (transfer fixing: I)
  1486      (simp add: sup_max[symmetric] SUP_sup_const1 SUP_ereal_minus_right del: sup_ereal_def)
  1487 
  1488 lemma of_nat_Sup_ennreal:
  1489   assumes "A \<noteq> {}" "bdd_above A"
  1490   shows "of_nat (Sup A) = (SUP a:A. of_nat a :: ennreal)"
  1491 proof (intro antisym)
  1492   show "(SUP a:A. of_nat a::ennreal) \<le> of_nat (Sup A)"
  1493     by (intro SUP_least of_nat_mono) (auto intro: cSup_upper assms)
  1494   have "Sup A \<in> A"
  1495     unfolding Sup_nat_def using assms by (intro Max_in) (auto simp: bdd_above_nat)
  1496   then show "of_nat (Sup A) \<le> (SUP a:A. of_nat a::ennreal)"
  1497     by (intro SUP_upper)
  1498 qed
  1499 
  1500 lemma ennreal_tendsto_const_minus:
  1501   fixes g :: "'a \<Rightarrow> ennreal"
  1502   assumes ae: "\<forall>\<^sub>F x in F. g x \<le> c"
  1503   assumes g: "((\<lambda>x. c - g x) \<longlongrightarrow> 0) F"
  1504   shows "(g \<longlongrightarrow> c) F"
  1505 proof (cases c rule: ennreal_cases)
  1506   case top with tendsto_unique[OF _ g, of "top"] show ?thesis
  1507     by (cases "F = bot") auto
  1508 next
  1509   case (real r)
  1510   then have "\<forall>x. \<exists>q\<ge>0. g x \<le> c \<longrightarrow> (g x = ennreal q \<and> q \<le> r)"
  1511     by (auto simp: le_ennreal_iff)
  1512   then obtain f where *: "0 \<le> f x" "g x = ennreal (f x)" "f x \<le> r" if "g x \<le> c" for x
  1513     by metis
  1514   from ae have ae2: "\<forall>\<^sub>F x in F. c - g x = ennreal (r - f x) \<and> f x \<le> r \<and> g x = ennreal (f x) \<and> 0 \<le> f x"
  1515   proof eventually_elim
  1516     fix x assume "g x \<le> c" with *[of x] \<open>0 \<le> r\<close> show "c - g x = ennreal (r - f x) \<and> f x \<le> r \<and> g x = ennreal (f x) \<and> 0 \<le> f x"
  1517       by (auto simp: real ennreal_minus)
  1518   qed
  1519   with g have "((\<lambda>x. ennreal (r - f x)) \<longlongrightarrow> ennreal 0) F"
  1520     by (auto simp add: tendsto_cong eventually_conj_iff)
  1521   with ae2 have "((\<lambda>x. r - f x) \<longlongrightarrow> 0) F"
  1522     by (subst (asm) tendsto_ennreal_iff) (auto elim: eventually_mono)
  1523   then have "(f \<longlongrightarrow> r) F"
  1524     by (rule Lim_transform2[OF tendsto_const])
  1525   with ae2 have "((\<lambda>x. ennreal (f x)) \<longlongrightarrow> ennreal r) F"
  1526     by (subst tendsto_ennreal_iff) (auto elim: eventually_mono simp: real)
  1527   with ae2 show ?thesis
  1528     by (auto simp: real tendsto_cong eventually_conj_iff)
  1529 qed
  1530 
  1531 lemma ennreal_SUP_add:
  1532   fixes f g :: "nat \<Rightarrow> ennreal"
  1533   shows "incseq f \<Longrightarrow> incseq g \<Longrightarrow> (SUP i. f i + g i) = SUPREMUM UNIV f + SUPREMUM UNIV g"
  1534   unfolding incseq_def le_fun_def
  1535   by transfer
  1536      (simp add: SUP_ereal_add incseq_def le_fun_def max_absorb2 SUP_upper2)
  1537 
  1538 lemma ennreal_SUP_sum:
  1539   fixes f :: "'a \<Rightarrow> nat \<Rightarrow> ennreal"
  1540   shows "(\<And>i. i \<in> I \<Longrightarrow> incseq (f i)) \<Longrightarrow> (SUP n. \<Sum>i\<in>I. f i n) = (\<Sum>i\<in>I. SUP n. f i n)"
  1541   unfolding incseq_def
  1542   by transfer
  1543      (simp add: SUP_ereal_sum incseq_def SUP_upper2 max_absorb2 sum_nonneg)
  1544 
  1545 lemma ennreal_liminf_minus:
  1546   fixes f :: "nat \<Rightarrow> ennreal"
  1547   shows "(\<And>n. f n \<le> c) \<Longrightarrow> liminf (\<lambda>n. c - f n) = c - limsup f"
  1548   apply transfer
  1549   apply (simp add: ereal_diff_positive max.absorb2 liminf_ereal_cminus)
  1550   apply (subst max.absorb2)
  1551   apply (rule ereal_diff_positive)
  1552   apply (rule Limsup_bounded)
  1553   apply auto
  1554   done
  1555 
  1556 lemma ennreal_continuous_on_cmult:
  1557   "(c::ennreal) < top \<Longrightarrow> continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. c * f x)"
  1558   by (transfer fixing: A) (auto intro: continuous_on_cmult_ereal)
  1559 
  1560 lemma ennreal_tendsto_cmult:
  1561   "(c::ennreal) < top \<Longrightarrow> (f \<longlongrightarrow> x) F \<Longrightarrow> ((\<lambda>x. c * f x) \<longlongrightarrow> c * x) F"
  1562   by (rule continuous_on_tendsto_compose[where g=f, OF ennreal_continuous_on_cmult, where s=UNIV])
  1563      (auto simp: continuous_on_id)
  1564 
  1565 lemma tendsto_ennrealI[intro, simp]:
  1566   "(f \<longlongrightarrow> x) F \<Longrightarrow> ((\<lambda>x. ennreal (f x)) \<longlongrightarrow> ennreal x) F"
  1567   by (auto simp: ennreal_def
  1568            intro!: continuous_on_tendsto_compose[OF continuous_on_e2ennreal[of UNIV]] tendsto_max)
  1569 
  1570 lemma ennreal_suminf_minus:
  1571   fixes f g :: "nat \<Rightarrow> ennreal"
  1572   shows "(\<And>i. g i \<le> f i) \<Longrightarrow> suminf f \<noteq> top \<Longrightarrow> suminf g \<noteq> top \<Longrightarrow> (\<Sum>i. f i - g i) = suminf f - suminf g"
  1573   by transfer
  1574      (auto simp add: max.absorb2 ereal_diff_positive suminf_le_pos top_ereal_def intro!: suminf_ereal_minus)
  1575 
  1576 lemma ennreal_Sup_countable_SUP:
  1577   "A \<noteq> {} \<Longrightarrow> \<exists>f::nat \<Rightarrow> ennreal. incseq f \<and> range f \<subseteq> A \<and> Sup A = (SUP i. f i)"
  1578   unfolding incseq_def
  1579   apply transfer
  1580   subgoal for A
  1581     using Sup_countable_SUP[of A]
  1582     apply (clarsimp simp add: incseq_def[symmetric] SUP_upper2 max.absorb2 image_subset_iff Sup_upper2 cong: conj_cong)
  1583     subgoal for f
  1584       by (intro exI[of _ f]) auto
  1585     done
  1586   done
  1587 
  1588 lemma ennreal_Inf_countable_INF:
  1589   "A \<noteq> {} \<Longrightarrow> \<exists>f::nat \<Rightarrow> ennreal. decseq f \<and> range f \<subseteq> A \<and> Inf A = (INF i. f i)"
  1590   including ennreal.lifting
  1591   unfolding decseq_def
  1592   apply transfer
  1593   subgoal for A
  1594     using Inf_countable_INF[of A]
  1595     apply (clarsimp simp add: decseq_def[symmetric])
  1596     subgoal for f
  1597       by (intro exI[of _ f]) auto
  1598     done
  1599   done
  1600 
  1601 lemma ennreal_SUP_countable_SUP:
  1602   "A \<noteq> {} \<Longrightarrow> \<exists>f::nat \<Rightarrow> ennreal. range f \<subseteq> g`A \<and> SUPREMUM A g = SUPREMUM UNIV f"
  1603   using ennreal_Sup_countable_SUP [of "g`A"] by auto
  1604 
  1605 lemma of_nat_tendsto_top_ennreal: "(\<lambda>n::nat. of_nat n :: ennreal) \<longlonglongrightarrow> top"
  1606   using LIMSEQ_SUP[of "of_nat :: nat \<Rightarrow> ennreal"]
  1607   by (simp add: ennreal_SUP_of_nat_eq_top incseq_def)
  1608 
  1609 lemma SUP_sup_continuous_ennreal:
  1610   fixes f :: "ennreal \<Rightarrow> 'a::complete_lattice"
  1611   assumes f: "sup_continuous f" and "I \<noteq> {}"
  1612   shows "(SUP i:I. f (g i)) = f (SUP i:I. g i)"
  1613 proof (rule antisym)
  1614   show "(SUP i:I. f (g i)) \<le> f (SUP i:I. g i)"
  1615     by (rule mono_SUP[OF sup_continuous_mono[OF f]])
  1616   from ennreal_Sup_countable_SUP[of "g`I"] \<open>I \<noteq> {}\<close>
  1617   obtain M :: "nat \<Rightarrow> ennreal" where "incseq M" and M: "range M \<subseteq> g ` I" and eq: "(SUP i : I. g i) = (SUP i. M i)"
  1618     by auto
  1619   have "f (SUP i : I. g i) = (SUP i : range M. f i)"
  1620     unfolding eq sup_continuousD[OF f \<open>mono M\<close>] by simp
  1621   also have "\<dots> \<le> (SUP i : I. f (g i))"
  1622     by (insert M, drule SUP_subset_mono) auto
  1623   finally show "f (SUP i : I. g i) \<le> (SUP i : I. f (g i))" .
  1624 qed
  1625 
  1626 lemma ennreal_suminf_SUP_eq:
  1627   fixes f :: "nat \<Rightarrow> nat \<Rightarrow> ennreal"
  1628   shows "(\<And>i. incseq (\<lambda>n. f n i)) \<Longrightarrow> (\<Sum>i. SUP n. f n i) = (SUP n. \<Sum>i. f n i)"
  1629   apply (rule ennreal_suminf_SUP_eq_directed)
  1630   subgoal for N n j
  1631     by (auto simp: incseq_def intro!:exI[of _ "max n j"])
  1632   done
  1633 
  1634 lemma ennreal_SUP_add_left:
  1635   fixes c :: ennreal
  1636   shows "I \<noteq> {} \<Longrightarrow> (SUP i:I. f i + c) = (SUP i:I. f i) + c"
  1637   apply transfer
  1638   apply (simp add: SUP_ereal_add_left)
  1639   apply (subst (1 2) max.absorb2)
  1640   apply (auto intro: SUP_upper2 ereal_add_nonneg_nonneg)
  1641   done
  1642 
  1643 lemma ennreal_SUP_const_minus: (* TODO: rename: ennreal_SUP_const_minus *)
  1644   fixes f :: "'a \<Rightarrow> ennreal"
  1645   shows "I \<noteq> {} \<Longrightarrow> c < top \<Longrightarrow> (INF x:I. c - f x) = c - (SUP x:I. f x)"
  1646   apply (transfer fixing: I)
  1647   unfolding ex_in_conv[symmetric]
  1648   apply (auto simp add: sup_max[symmetric] SUP_upper2 sup_absorb2
  1649               simp del: sup_ereal_def)
  1650   apply (subst INF_ereal_minus_right[symmetric])
  1651   apply (auto simp del: sup_ereal_def simp add: sup_INF)
  1652   done
  1653 
  1654 subsection \<open>Approximation lemmas\<close>
  1655 
  1656 lemma INF_approx_ennreal:
  1657   fixes x::ennreal and e::real
  1658   assumes "e > 0"
  1659   assumes INF: "x = (INF i : A. f i)"
  1660   assumes "x \<noteq> \<infinity>"
  1661   shows "\<exists>i \<in> A. f i < x + e"
  1662 proof -
  1663   have "(INF i : A. f i) < x + e"
  1664     unfolding INF[symmetric] using \<open>0<e\<close> \<open>x \<noteq> \<infinity>\<close> by (cases x) auto
  1665   then show ?thesis
  1666     unfolding INF_less_iff .
  1667 qed
  1668 
  1669 lemma SUP_approx_ennreal:
  1670   fixes x::ennreal and e::real
  1671   assumes "e > 0" "A \<noteq> {}"
  1672   assumes SUP: "x = (SUP i : A. f i)"
  1673   assumes "x \<noteq> \<infinity>"
  1674   shows "\<exists>i \<in> A. x < f i + e"
  1675 proof -
  1676   have "x < x + e"
  1677     using \<open>0<e\<close> \<open>x \<noteq> \<infinity>\<close> by (cases x) auto
  1678   also have "x + e = (SUP i : A. f i + e)"
  1679     unfolding SUP ennreal_SUP_add_left[OF \<open>A \<noteq> {}\<close>] ..
  1680   finally show ?thesis
  1681     unfolding less_SUP_iff .
  1682 qed
  1683 
  1684 lemma ennreal_approx_SUP:
  1685   fixes x::ennreal
  1686   assumes f_bound: "\<And>i. i \<in> A \<Longrightarrow> f i \<le> x"
  1687   assumes approx: "\<And>e. (e::real) > 0 \<Longrightarrow> \<exists>i \<in> A. x \<le> f i + e"
  1688   shows "x = (SUP i : A. f i)"
  1689 proof (rule antisym)
  1690   show "x \<le> (SUP i:A. f i)"
  1691   proof (rule ennreal_le_epsilon)
  1692     fix e :: real assume "0 < e"
  1693     from approx[OF this] guess i ..
  1694     then have "x \<le> f i + e"
  1695       by simp
  1696     also have "\<dots> \<le> (SUP i:A. f i) + e"
  1697       by (intro add_mono \<open>i \<in> A\<close> SUP_upper order_refl)
  1698     finally show "x \<le> (SUP i:A. f i) + e" .
  1699   qed
  1700 qed (intro SUP_least f_bound)
  1701 
  1702 lemma ennreal_approx_INF:
  1703   fixes x::ennreal
  1704   assumes f_bound: "\<And>i. i \<in> A \<Longrightarrow> x \<le> f i"
  1705   assumes approx: "\<And>e. (e::real) > 0 \<Longrightarrow> \<exists>i \<in> A. f i \<le> x + e"
  1706   shows "x = (INF i : A. f i)"
  1707 proof (rule antisym)
  1708   show "(INF i:A. f i) \<le> x"
  1709   proof (rule ennreal_le_epsilon)
  1710     fix e :: real assume "0 < e"
  1711     from approx[OF this] guess i .. note i = this
  1712     then have "(INF i:A. f i) \<le> f i"
  1713       by (intro INF_lower)
  1714     also have "\<dots> \<le> x + e"
  1715       by fact
  1716     finally show "(INF i:A. f i) \<le> x + e" .
  1717   qed
  1718 qed (intro INF_greatest f_bound)
  1719 
  1720 lemma ennreal_approx_unit:
  1721   "(\<And>a::ennreal. 0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * z \<le> y) \<Longrightarrow> z \<le> y"
  1722   apply (subst SUP_mult_right_ennreal[of "\<lambda>x. x" "{0 <..< 1}" z, simplified])
  1723   apply (rule SUP_least)
  1724   apply auto
  1725   done
  1726 
  1727 lemma suminf_ennreal2:
  1728   "(\<And>i. 0 \<le> f i) \<Longrightarrow> summable f \<Longrightarrow> (\<Sum>i. ennreal (f i)) = ennreal (\<Sum>i. f i)"
  1729   using suminf_ennreal_eq by blast
  1730 
  1731 lemma less_top_ennreal: "x < top \<longleftrightarrow> (\<exists>r\<ge>0. x = ennreal r)"
  1732   by (cases x) auto
  1733 
  1734 lemma tendsto_top_iff_ennreal:
  1735   fixes f :: "'a \<Rightarrow> ennreal"
  1736   shows "(f \<longlongrightarrow> top) F \<longleftrightarrow> (\<forall>l\<ge>0. eventually (\<lambda>x. ennreal l < f x) F)"
  1737   by (auto simp: less_top_ennreal order_tendsto_iff )
  1738 
  1739 lemma ennreal_tendsto_top_eq_at_top:
  1740   "((\<lambda>z. ennreal (f z)) \<longlongrightarrow> top) F \<longleftrightarrow> (LIM z F. f z :> at_top)"
  1741   unfolding filterlim_at_top_dense tendsto_top_iff_ennreal
  1742   apply (auto simp: ennreal_less_iff)
  1743   subgoal for y
  1744     by (auto elim!: eventually_mono allE[of _ "max 0 y"])
  1745   done
  1746 
  1747 lemma tendsto_0_if_Limsup_eq_0_ennreal:
  1748   fixes f :: "_ \<Rightarrow> ennreal"
  1749   shows "Limsup F f = 0 \<Longrightarrow> (f \<longlongrightarrow> 0) F"
  1750   using Liminf_le_Limsup[of F f] tendsto_iff_Liminf_eq_Limsup[of F f 0]
  1751   by (cases "F = bot") auto
  1752 
  1753 lemma diff_le_self_ennreal[simp]: "a - b \<le> (a::ennreal)"
  1754   by (cases a b rule: ennreal2_cases) (auto simp: ennreal_minus)
  1755 
  1756 lemma ennreal_ineq_diff_add: "b \<le> a \<Longrightarrow> a = b + (a - b::ennreal)"
  1757   by transfer (auto simp: ereal_diff_positive max.absorb2 ereal_ineq_diff_add)
  1758 
  1759 lemma ennreal_mult_strict_left_mono: "(a::ennreal) < c \<Longrightarrow> 0 < b \<Longrightarrow> b < top \<Longrightarrow> b * a < b * c"
  1760   by transfer (auto intro!: ereal_mult_strict_left_mono)
  1761 
  1762 lemma ennreal_between: "0 < e \<Longrightarrow> 0 < x \<Longrightarrow> x < top \<Longrightarrow> x - e < (x::ennreal)"
  1763   by transfer (auto intro!: ereal_between)
  1764 
  1765 lemma minus_less_iff_ennreal: "b < top \<Longrightarrow> b \<le> a \<Longrightarrow> a - b < c \<longleftrightarrow> a < c + (b::ennreal)"
  1766   by transfer
  1767      (auto simp: top_ereal_def ereal_minus_less le_less)
  1768 
  1769 lemma tendsto_zero_ennreal:
  1770   assumes ev: "\<And>r. 0 < r \<Longrightarrow> \<forall>\<^sub>F x in F. f x < ennreal r"
  1771   shows "(f \<longlongrightarrow> 0) F"
  1772 proof (rule order_tendstoI)
  1773   fix e::ennreal assume "e > 0"
  1774   obtain e'::real where "e' > 0" "ennreal e' < e"
  1775     using \<open>0 < e\<close> dense[of 0 "if e = top then 1 else (enn2real e)"]
  1776     by (cases e) (auto simp: ennreal_less_iff)
  1777   from ev[OF \<open>e' > 0\<close>] show "\<forall>\<^sub>F x in F. f x < e"
  1778     by eventually_elim (insert \<open>ennreal e' < e\<close>, auto)
  1779 qed simp
  1780 
  1781 lifting_update ennreal.lifting
  1782 lifting_forget ennreal.lifting
  1783 
  1784 
  1785 subsection \<open>@{typ ennreal} theorems\<close>
  1786 
  1787 lemma neq_top_trans: fixes x y :: ennreal shows "\<lbrakk> y \<noteq> top; x \<le> y \<rbrakk> \<Longrightarrow> x \<noteq> top"
  1788 by (auto simp: top_unique)
  1789 
  1790 lemma diff_diff_ennreal: fixes a b :: ennreal shows "a \<le> b \<Longrightarrow> b \<noteq> \<infinity> \<Longrightarrow> b - (b - a) = a"
  1791   by (cases a b rule: ennreal2_cases)
  1792      (auto simp: ennreal_minus top_unique)
  1793 
  1794 lemma ennreal_less_one_iff[simp]: "ennreal x < 1 \<longleftrightarrow> x < 1"
  1795   by (cases "0 \<le> x")
  1796      (auto simp: ennreal_neg ennreal_1[symmetric] ennreal_less_iff simp del: ennreal_1)
  1797 
  1798 lemma SUP_const_minus_ennreal:
  1799   fixes f :: "'a \<Rightarrow> ennreal" shows "I \<noteq> {} \<Longrightarrow> (SUP x:I. c - f x) = c - (INF x:I. f x)"
  1800   including ennreal.lifting
  1801   by (transfer fixing: I)
  1802      (simp add: sup_ereal_def[symmetric] SUP_sup_distrib[symmetric] SUP_ereal_minus_right
  1803            del: sup_ereal_def)
  1804 
  1805 lemma zero_minus_ennreal[simp]: "0 - (a::ennreal) = 0"
  1806   including ennreal.lifting
  1807   by transfer (simp split: split_max)
  1808 
  1809 lemma diff_diff_commute_ennreal:
  1810   fixes a b c :: ennreal shows "a - b - c = a - c - b"
  1811   by (cases a b c rule: ennreal3_cases) (simp_all add: ennreal_minus field_simps)
  1812 
  1813 lemma diff_gr0_ennreal: "b < (a::ennreal) \<Longrightarrow> 0 < a - b"
  1814   including ennreal.lifting by transfer (auto simp: ereal_diff_gr0 ereal_diff_positive split: split_max)
  1815 
  1816 lemma divide_le_posI_ennreal:
  1817   fixes x y z :: ennreal
  1818   shows "x > 0 \<Longrightarrow> z \<le> x * y \<Longrightarrow> z / x \<le> y"
  1819   by (cases x y z rule: ennreal3_cases)
  1820      (auto simp: divide_ennreal ennreal_mult[symmetric] field_simps top_unique)
  1821 
  1822 lemma add_diff_eq_ennreal:
  1823   fixes x y z :: ennreal
  1824   shows "z \<le> y \<Longrightarrow> x + (y - z) = x + y - z"
  1825   including ennreal.lifting
  1826   by transfer
  1827      (insert ereal_add_mono[of 0], auto simp add: ereal_diff_positive max.absorb2 add_diff_eq_ereal)
  1828 
  1829 lemma add_diff_inverse_ennreal:
  1830   fixes x y :: ennreal shows "x \<le> y \<Longrightarrow> x + (y - x) = y"
  1831   by (cases x) (simp_all add: top_unique add_diff_eq_ennreal)
  1832 
  1833 lemma add_diff_eq_iff_ennreal[simp]:
  1834   fixes x y :: ennreal shows "x + (y - x) = y \<longleftrightarrow> x \<le> y"
  1835 proof
  1836   assume *: "x + (y - x) = y" show "x \<le> y"
  1837     by (subst *[symmetric]) simp
  1838 qed (simp add: add_diff_inverse_ennreal)
  1839 
  1840 lemma add_diff_le_ennreal: "a + b - c \<le> a + (b - c::ennreal)"
  1841   apply (cases a b c rule: ennreal3_cases)
  1842   subgoal for a' b' c'
  1843     by (cases "0 \<le> b' - c'")
  1844        (simp_all add: ennreal_minus ennreal_plus[symmetric] top_add ennreal_neg
  1845                  del: ennreal_plus)
  1846   apply (simp_all add: top_add ennreal_plus[symmetric] del: ennreal_plus)
  1847   done
  1848 
  1849 lemma diff_eq_0_ennreal: "a < top \<Longrightarrow> a \<le> b \<Longrightarrow> a - b = (0::ennreal)"
  1850   using ennreal_minus_pos_iff gr_zeroI not_less by blast
  1851 
  1852 lemma diff_diff_ennreal': fixes x y z :: ennreal shows "z \<le> y \<Longrightarrow> y - z \<le> x \<Longrightarrow> x - (y - z) = x + z - y"
  1853   by (cases x; cases y; cases z)
  1854      (auto simp add: top_add add_top minus_top_ennreal ennreal_minus ennreal_plus[symmetric] top_unique
  1855            simp del: ennreal_plus)
  1856 
  1857 lemma diff_diff_ennreal'': fixes x y z :: ennreal
  1858   shows "z \<le> y \<Longrightarrow> x - (y - z) = (if y - z \<le> x then x + z - y else 0)"
  1859   by (cases x; cases y; cases z)
  1860      (auto simp add: top_add add_top minus_top_ennreal ennreal_minus ennreal_plus[symmetric] top_unique ennreal_neg
  1861            simp del: ennreal_plus)
  1862 
  1863 lemma power_less_top_ennreal: fixes x :: ennreal shows "x ^ n < top \<longleftrightarrow> x < top \<or> n = 0"
  1864   using power_eq_top_ennreal[of x n] by (auto simp: less_top)
  1865 
  1866 lemma ennreal_divide_times: "(a / b) * c = a * (c / b :: ennreal)"
  1867   by (simp add: mult.commute ennreal_times_divide)
  1868 
  1869 lemma diff_less_top_ennreal: "a - b < top \<longleftrightarrow>  a < (top :: ennreal)"
  1870   by (cases a; cases b) (auto simp: ennreal_minus)
  1871 
  1872 lemma divide_less_ennreal: "b \<noteq> 0 \<Longrightarrow> b < top \<Longrightarrow> a / b < c \<longleftrightarrow> a < (c * b :: ennreal)"
  1873   by (cases a; cases b; cases c)
  1874      (auto simp: divide_ennreal ennreal_mult[symmetric] ennreal_less_iff field_simps ennreal_top_mult ennreal_top_divide)
  1875 
  1876 lemma one_less_numeral[simp]: "1 < (numeral n::ennreal) \<longleftrightarrow> (num.One < n)"
  1877   by (simp del: ennreal_1 ennreal_numeral add: ennreal_1[symmetric] ennreal_numeral[symmetric] ennreal_less_iff)
  1878 
  1879 lemma divide_eq_1_ennreal: "a / b = (1::ennreal) \<longleftrightarrow> (b \<noteq> top \<and> b \<noteq> 0 \<and> b = a)"
  1880   by (cases a ; cases b; cases "b = 0") (auto simp: ennreal_top_divide divide_ennreal split: if_split_asm)
  1881 
  1882 lemma ennreal_mult_cancel_left: "(a * b = a * c) = (a = top \<and> b \<noteq> 0 \<and> c \<noteq> 0 \<or> a = 0 \<or> b = (c::ennreal))"
  1883   by (cases a; cases b; cases c) (auto simp: ennreal_mult[symmetric] ennreal_mult_top ennreal_top_mult)
  1884 
  1885 lemma ennreal_minus_if: "ennreal a - ennreal b = ennreal (if 0 \<le> b then (if b \<le> a then a - b else 0) else a)"
  1886   by (auto simp: ennreal_minus ennreal_neg)
  1887 
  1888 lemma ennreal_plus_if: "ennreal a + ennreal b = ennreal (if 0 \<le> a then (if 0 \<le> b then a + b else a) else b)"
  1889   by (auto simp: ennreal_neg)
  1890 
  1891 lemma power_le_one_iff: "0 \<le> (a::real) \<Longrightarrow> a ^ n \<le> 1 \<longleftrightarrow> (n = 0 \<or> a \<le> 1)"
  1892   by (metis (mono_tags, hide_lams) le_less neq0_conv not_le one_le_power power_0 power_eq_imp_eq_base power_le_one zero_le_one)
  1893 
  1894 lemma ennreal_diff_le_mono_left: "a \<le> b \<Longrightarrow> a - c \<le> (b::ennreal)"
  1895   using ennreal_mono_minus[of 0 c a, THEN order_trans, of b] by simp
  1896 
  1897 lemma ennreal_minus_le_iff: "a - b \<le> c \<longleftrightarrow> (a \<le> b + (c::ennreal) \<and> (a = top \<and> b = top \<longrightarrow> c = top))"
  1898   by (cases a; cases b; cases c)
  1899      (auto simp: top_unique top_add add_top ennreal_minus ennreal_plus[symmetric]
  1900            simp del: ennreal_plus)
  1901 
  1902 lemma ennreal_le_minus_iff: "a \<le> b - c \<longleftrightarrow> (a + c \<le> (b::ennreal) \<or> (a = 0 \<and> b \<le> c))"
  1903   by (cases a; cases b; cases c)
  1904      (auto simp: top_unique top_add add_top ennreal_minus ennreal_plus[symmetric] ennreal_le_iff2
  1905            simp del: ennreal_plus)
  1906 
  1907 lemma diff_add_eq_diff_diff_swap_ennreal: "x - (y + z :: ennreal) = x - y - z"
  1908   by (cases x; cases y; cases z)
  1909      (auto simp: ennreal_plus[symmetric] ennreal_minus_if add_top top_add simp del: ennreal_plus)
  1910 
  1911 lemma diff_add_assoc2_ennreal: "b \<le> a \<Longrightarrow> (a - b + c::ennreal) = a + c - b"
  1912   by (cases a; cases b; cases c)
  1913      (auto simp add: ennreal_minus_if ennreal_plus_if add_top top_add top_unique simp del: ennreal_plus)
  1914 
  1915 lemma diff_gt_0_iff_gt_ennreal: "0 < a - b \<longleftrightarrow> (a = top \<and> b = top \<or> b < (a::ennreal))"
  1916   by (cases a; cases b) (auto simp: ennreal_minus_if ennreal_less_iff)
  1917 
  1918 lemma diff_eq_0_iff_ennreal: "(a - b::ennreal) = 0 \<longleftrightarrow> (a < top \<and> a \<le> b)"
  1919   by (cases a) (auto simp: ennreal_minus_eq_0 diff_eq_0_ennreal)
  1920 
  1921 lemma add_diff_self_ennreal: "a + (b - a::ennreal) = (if a \<le> b then b else a)"
  1922   by (auto simp: diff_eq_0_iff_ennreal less_top)
  1923 
  1924 lemma diff_add_self_ennreal: "(b - a + a::ennreal) = (if a \<le> b then b else a)"
  1925   by (auto simp: diff_add_cancel_ennreal diff_eq_0_iff_ennreal less_top)
  1926 
  1927 lemma ennreal_minus_cancel_iff:
  1928   fixes a b c :: ennreal
  1929   shows "a - b = a - c \<longleftrightarrow> (b = c \<or> (a \<le> b \<and> a \<le> c) \<or> a = top)"
  1930   by (cases a; cases b; cases c) (auto simp: ennreal_minus_if)
  1931 
  1932 lemma SUP_diff_ennreal:
  1933   "c < top \<Longrightarrow> (SUP i:I. f i - c :: ennreal) = (SUP i:I. f i) - c"
  1934   by (auto intro!: SUP_eqI ennreal_minus_mono SUP_least intro: SUP_upper
  1935            simp: ennreal_minus_cancel_iff ennreal_minus_le_iff less_top[symmetric])
  1936 
  1937 lemma ennreal_SUP_add_right:
  1938   fixes c :: ennreal shows "I \<noteq> {} \<Longrightarrow> c + (SUP i:I. f i) = (SUP i:I. c + f i)"
  1939   using ennreal_SUP_add_left[of I f c] by (simp add: add.commute)
  1940 
  1941 lemma SUP_add_directed_ennreal:
  1942   fixes f g :: "_ \<Rightarrow> ennreal"
  1943   assumes directed: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> \<exists>k\<in>I. f i + g j \<le> f k + g k"
  1944   shows "(SUP i:I. f i + g i) = (SUP i:I. f i) + (SUP i:I. g i)"
  1945 proof cases
  1946   assume "I = {}" then show ?thesis
  1947     by (simp add: bot_ereal_def)
  1948 next
  1949   assume "I \<noteq> {}"
  1950   show ?thesis
  1951   proof (rule antisym)
  1952     show "(SUP i:I. f i + g i) \<le> (SUP i:I. f i) + (SUP i:I. g i)"
  1953       by (rule SUP_least; intro add_mono SUP_upper)
  1954   next
  1955     have "(SUP i:I. f i) + (SUP i:I. g i) = (SUP i:I. f i + (SUP i:I. g i))"
  1956       by (intro ennreal_SUP_add_left[symmetric] \<open>I \<noteq> {}\<close>)
  1957     also have "\<dots> = (SUP i:I. (SUP j:I. f i + g j))"
  1958       by (intro SUP_cong refl ennreal_SUP_add_right \<open>I \<noteq> {}\<close>)
  1959     also have "\<dots> \<le> (SUP i:I. f i + g i)"
  1960       using directed by (intro SUP_least) (blast intro: SUP_upper2)
  1961     finally show "(SUP i:I. f i) + (SUP i:I. g i) \<le> (SUP i:I. f i + g i)" .
  1962   qed
  1963 qed
  1964 
  1965 lemma enn2real_eq_0_iff: "enn2real x = 0 \<longleftrightarrow> x = 0 \<or> x = top"
  1966   by (cases x) auto
  1967 
  1968 lemma (in -) continuous_on_diff_ereal:
  1969   "continuous_on A f \<Longrightarrow> continuous_on A g \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> \<bar>f x\<bar> \<noteq> \<infinity>) \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> \<bar>g x\<bar> \<noteq> \<infinity>) \<Longrightarrow> continuous_on A (\<lambda>z. f z - g z::ereal)"
  1970   apply (auto simp: continuous_on_def)
  1971   apply (intro tendsto_diff_ereal)
  1972   apply metis+
  1973   done
  1974 
  1975 lemma (in -) continuous_on_diff_ennreal:
  1976   "continuous_on A f \<Longrightarrow> continuous_on A g \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<noteq> top) \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> g x \<noteq> top) \<Longrightarrow> continuous_on A (\<lambda>z. f z - g z::ennreal)"
  1977   including ennreal.lifting
  1978 proof (transfer fixing: A, simp add: top_ereal_def)
  1979   fix f g :: "'a \<Rightarrow> ereal" assume "\<forall>x. 0 \<le> f x" "\<forall>x. 0 \<le> g x" "continuous_on A f" "continuous_on A g"
  1980   moreover assume "f x \<noteq> \<infinity>" "g x \<noteq> \<infinity>" if "x \<in> A" for x
  1981   ultimately show "continuous_on A (\<lambda>z. max 0 (f z - g z))"
  1982     by (intro continuous_on_max continuous_on_const continuous_on_diff_ereal) auto
  1983 qed
  1984 
  1985 lemma (in -) tendsto_diff_ennreal:
  1986   "(f \<longlongrightarrow> x) F \<Longrightarrow> (g \<longlongrightarrow> y) F \<Longrightarrow> x \<noteq> top \<Longrightarrow> y \<noteq> top \<Longrightarrow> ((\<lambda>z. f z - g z::ennreal) \<longlongrightarrow> x - y) F"
  1987   using continuous_on_tendsto_compose[where f="\<lambda>x. fst x - snd x::ennreal" and s="{(x, y). x \<noteq> top \<and> y \<noteq> top}" and g="\<lambda>x. (f x, g x)" and l="(x, y)" and F="F",
  1988     OF continuous_on_diff_ennreal]
  1989   by (auto simp: tendsto_Pair eventually_conj_iff less_top order_tendstoD continuous_on_fst continuous_on_snd continuous_on_id)
  1990 
  1991 end