src/HOL/Library/Formal_Power_Series.thy
author wenzelm
Wed Mar 08 10:50:59 2017 +0100 (2017-03-08)
changeset 65151 a7394aa4d21c
parent 64786 340db65fd2c1
child 65396 b42167902f57
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Library/Formal_Power_Series.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 section \<open>A formalization of formal power series\<close>
     6 
     7 theory Formal_Power_Series
     8 imports Complex_Main "~~/src/HOL/Number_Theory/Euclidean_Algorithm"
     9 begin
    10 
    11 
    12 subsection \<open>The type of formal power series\<close>
    13 
    14 typedef 'a fps = "{f :: nat \<Rightarrow> 'a. True}"
    15   morphisms fps_nth Abs_fps
    16   by simp
    17 
    18 notation fps_nth (infixl "$" 75)
    19 
    20 lemma expand_fps_eq: "p = q \<longleftrightarrow> (\<forall>n. p $ n = q $ n)"
    21   by (simp add: fps_nth_inject [symmetric] fun_eq_iff)
    22 
    23 lemma fps_ext: "(\<And>n. p $ n = q $ n) \<Longrightarrow> p = q"
    24   by (simp add: expand_fps_eq)
    25 
    26 lemma fps_nth_Abs_fps [simp]: "Abs_fps f $ n = f n"
    27   by (simp add: Abs_fps_inverse)
    28 
    29 text \<open>Definition of the basic elements 0 and 1 and the basic operations of addition,
    30   negation and multiplication.\<close>
    31 
    32 instantiation fps :: (zero) zero
    33 begin
    34   definition fps_zero_def: "0 = Abs_fps (\<lambda>n. 0)"
    35   instance ..
    36 end
    37 
    38 lemma fps_zero_nth [simp]: "0 $ n = 0"
    39   unfolding fps_zero_def by simp
    40 
    41 instantiation fps :: ("{one, zero}") one
    42 begin
    43   definition fps_one_def: "1 = Abs_fps (\<lambda>n. if n = 0 then 1 else 0)"
    44   instance ..
    45 end
    46 
    47 lemma fps_one_nth [simp]: "1 $ n = (if n = 0 then 1 else 0)"
    48   unfolding fps_one_def by simp
    49 
    50 instantiation fps :: (plus) plus
    51 begin
    52   definition fps_plus_def: "op + = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n + g $ n))"
    53   instance ..
    54 end
    55 
    56 lemma fps_add_nth [simp]: "(f + g) $ n = f $ n + g $ n"
    57   unfolding fps_plus_def by simp
    58 
    59 instantiation fps :: (minus) minus
    60 begin
    61   definition fps_minus_def: "op - = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n - g $ n))"
    62   instance ..
    63 end
    64 
    65 lemma fps_sub_nth [simp]: "(f - g) $ n = f $ n - g $ n"
    66   unfolding fps_minus_def by simp
    67 
    68 instantiation fps :: (uminus) uminus
    69 begin
    70   definition fps_uminus_def: "uminus = (\<lambda>f. Abs_fps (\<lambda>n. - (f $ n)))"
    71   instance ..
    72 end
    73 
    74 lemma fps_neg_nth [simp]: "(- f) $ n = - (f $ n)"
    75   unfolding fps_uminus_def by simp
    76 
    77 instantiation fps :: ("{comm_monoid_add, times}") times
    78 begin
    79   definition fps_times_def: "op * = (\<lambda>f g. Abs_fps (\<lambda>n. \<Sum>i=0..n. f $ i * g $ (n - i)))"
    80   instance ..
    81 end
    82 
    83 lemma fps_mult_nth: "(f * g) $ n = (\<Sum>i=0..n. f$i * g$(n - i))"
    84   unfolding fps_times_def by simp
    85 
    86 lemma fps_mult_nth_0 [simp]: "(f * g) $ 0 = f $ 0 * g $ 0"
    87   unfolding fps_times_def by simp
    88 
    89 declare atLeastAtMost_iff [presburger]
    90 declare Bex_def [presburger]
    91 declare Ball_def [presburger]
    92 
    93 lemma mult_delta_left:
    94   fixes x y :: "'a::mult_zero"
    95   shows "(if b then x else 0) * y = (if b then x * y else 0)"
    96   by simp
    97 
    98 lemma mult_delta_right:
    99   fixes x y :: "'a::mult_zero"
   100   shows "x * (if b then y else 0) = (if b then x * y else 0)"
   101   by simp
   102 
   103 lemma cond_value_iff: "f (if b then x else y) = (if b then f x else f y)"
   104   by auto
   105 
   106 lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
   107   by auto
   108 
   109 
   110 subsection \<open>Formal power series form a commutative ring with unity, if the range of sequences
   111   they represent is a commutative ring with unity\<close>
   112 
   113 instance fps :: (semigroup_add) semigroup_add
   114 proof
   115   fix a b c :: "'a fps"
   116   show "a + b + c = a + (b + c)"
   117     by (simp add: fps_ext add.assoc)
   118 qed
   119 
   120 instance fps :: (ab_semigroup_add) ab_semigroup_add
   121 proof
   122   fix a b :: "'a fps"
   123   show "a + b = b + a"
   124     by (simp add: fps_ext add.commute)
   125 qed
   126 
   127 lemma fps_mult_assoc_lemma:
   128   fixes k :: nat
   129     and f :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
   130   shows "(\<Sum>j=0..k. \<Sum>i=0..j. f i (j - i) (n - j)) =
   131          (\<Sum>j=0..k. \<Sum>i=0..k - j. f j i (n - j - i))"
   132   by (induct k) (simp_all add: Suc_diff_le sum.distrib add.assoc)
   133 
   134 instance fps :: (semiring_0) semigroup_mult
   135 proof
   136   fix a b c :: "'a fps"
   137   show "(a * b) * c = a * (b * c)"
   138   proof (rule fps_ext)
   139     fix n :: nat
   140     have "(\<Sum>j=0..n. \<Sum>i=0..j. a$i * b$(j - i) * c$(n - j)) =
   141           (\<Sum>j=0..n. \<Sum>i=0..n - j. a$j * b$i * c$(n - j - i))"
   142       by (rule fps_mult_assoc_lemma)
   143     then show "((a * b) * c) $ n = (a * (b * c)) $ n"
   144       by (simp add: fps_mult_nth sum_distrib_left sum_distrib_right mult.assoc)
   145   qed
   146 qed
   147 
   148 lemma fps_mult_commute_lemma:
   149   fixes n :: nat
   150     and f :: "nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
   151   shows "(\<Sum>i=0..n. f i (n - i)) = (\<Sum>i=0..n. f (n - i) i)"
   152   by (rule sum.reindex_bij_witness[where i="op - n" and j="op - n"]) auto
   153 
   154 instance fps :: (comm_semiring_0) ab_semigroup_mult
   155 proof
   156   fix a b :: "'a fps"
   157   show "a * b = b * a"
   158   proof (rule fps_ext)
   159     fix n :: nat
   160     have "(\<Sum>i=0..n. a$i * b$(n - i)) = (\<Sum>i=0..n. a$(n - i) * b$i)"
   161       by (rule fps_mult_commute_lemma)
   162     then show "(a * b) $ n = (b * a) $ n"
   163       by (simp add: fps_mult_nth mult.commute)
   164   qed
   165 qed
   166 
   167 instance fps :: (monoid_add) monoid_add
   168 proof
   169   fix a :: "'a fps"
   170   show "0 + a = a" by (simp add: fps_ext)
   171   show "a + 0 = a" by (simp add: fps_ext)
   172 qed
   173 
   174 instance fps :: (comm_monoid_add) comm_monoid_add
   175 proof
   176   fix a :: "'a fps"
   177   show "0 + a = a" by (simp add: fps_ext)
   178 qed
   179 
   180 instance fps :: (semiring_1) monoid_mult
   181 proof
   182   fix a :: "'a fps"
   183   show "1 * a = a"
   184     by (simp add: fps_ext fps_mult_nth mult_delta_left sum.delta)
   185   show "a * 1 = a"
   186     by (simp add: fps_ext fps_mult_nth mult_delta_right sum.delta')
   187 qed
   188 
   189 instance fps :: (cancel_semigroup_add) cancel_semigroup_add
   190 proof
   191   fix a b c :: "'a fps"
   192   show "b = c" if "a + b = a + c"
   193     using that by (simp add: expand_fps_eq)
   194   show "b = c" if "b + a = c + a"
   195     using that by (simp add: expand_fps_eq)
   196 qed
   197 
   198 instance fps :: (cancel_ab_semigroup_add) cancel_ab_semigroup_add
   199 proof
   200   fix a b c :: "'a fps"
   201   show "a + b - a = b"
   202     by (simp add: expand_fps_eq)
   203   show "a - b - c = a - (b + c)"
   204     by (simp add: expand_fps_eq diff_diff_eq)
   205 qed
   206 
   207 instance fps :: (cancel_comm_monoid_add) cancel_comm_monoid_add ..
   208 
   209 instance fps :: (group_add) group_add
   210 proof
   211   fix a b :: "'a fps"
   212   show "- a + a = 0" by (simp add: fps_ext)
   213   show "a + - b = a - b" by (simp add: fps_ext)
   214 qed
   215 
   216 instance fps :: (ab_group_add) ab_group_add
   217 proof
   218   fix a b :: "'a fps"
   219   show "- a + a = 0" by (simp add: fps_ext)
   220   show "a - b = a + - b" by (simp add: fps_ext)
   221 qed
   222 
   223 instance fps :: (zero_neq_one) zero_neq_one
   224   by standard (simp add: expand_fps_eq)
   225 
   226 instance fps :: (semiring_0) semiring
   227 proof
   228   fix a b c :: "'a fps"
   229   show "(a + b) * c = a * c + b * c"
   230     by (simp add: expand_fps_eq fps_mult_nth distrib_right sum.distrib)
   231   show "a * (b + c) = a * b + a * c"
   232     by (simp add: expand_fps_eq fps_mult_nth distrib_left sum.distrib)
   233 qed
   234 
   235 instance fps :: (semiring_0) semiring_0
   236 proof
   237   fix a :: "'a fps"
   238   show "0 * a = 0"
   239     by (simp add: fps_ext fps_mult_nth)
   240   show "a * 0 = 0"
   241     by (simp add: fps_ext fps_mult_nth)
   242 qed
   243 
   244 instance fps :: (semiring_0_cancel) semiring_0_cancel ..
   245 
   246 instance fps :: (semiring_1) semiring_1 ..
   247 
   248 
   249 subsection \<open>Selection of the nth power of the implicit variable in the infinite sum\<close>
   250 
   251 lemma fps_square_nth: "(f^2) $ n = (\<Sum>k\<le>n. f $ k * f $ (n - k))"
   252   by (simp add: power2_eq_square fps_mult_nth atLeast0AtMost)
   253 
   254 lemma fps_nonzero_nth: "f \<noteq> 0 \<longleftrightarrow> (\<exists> n. f $n \<noteq> 0)"
   255   by (simp add: expand_fps_eq)
   256 
   257 lemma fps_nonzero_nth_minimal: "f \<noteq> 0 \<longleftrightarrow> (\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m < n. f $ m = 0))"
   258   (is "?lhs \<longleftrightarrow> ?rhs")
   259 proof
   260   let ?n = "LEAST n. f $ n \<noteq> 0"
   261   show ?rhs if ?lhs
   262   proof -
   263     from that have "\<exists>n. f $ n \<noteq> 0"
   264       by (simp add: fps_nonzero_nth)
   265     then have "f $ ?n \<noteq> 0"
   266       by (rule LeastI_ex)
   267     moreover have "\<forall>m<?n. f $ m = 0"
   268       by (auto dest: not_less_Least)
   269     ultimately have "f $ ?n \<noteq> 0 \<and> (\<forall>m<?n. f $ m = 0)" ..
   270     then show ?thesis ..
   271   qed
   272   show ?lhs if ?rhs
   273     using that by (auto simp add: expand_fps_eq)
   274 qed
   275 
   276 lemma fps_eq_iff: "f = g \<longleftrightarrow> (\<forall>n. f $ n = g $n)"
   277   by (rule expand_fps_eq)
   278 
   279 lemma fps_sum_nth: "sum f S $ n = sum (\<lambda>k. (f k) $ n) S"
   280 proof (cases "finite S")
   281   case True
   282   then show ?thesis by (induct set: finite) auto
   283 next
   284   case False
   285   then show ?thesis by simp
   286 qed
   287 
   288 
   289 subsection \<open>Injection of the basic ring elements and multiplication by scalars\<close>
   290 
   291 definition "fps_const c = Abs_fps (\<lambda>n. if n = 0 then c else 0)"
   292 
   293 lemma fps_nth_fps_const [simp]: "fps_const c $ n = (if n = 0 then c else 0)"
   294   unfolding fps_const_def by simp
   295 
   296 lemma fps_const_0_eq_0 [simp]: "fps_const 0 = 0"
   297   by (simp add: fps_ext)
   298 
   299 lemma fps_const_1_eq_1 [simp]: "fps_const 1 = 1"
   300   by (simp add: fps_ext)
   301 
   302 lemma fps_const_neg [simp]: "- (fps_const (c::'a::ring)) = fps_const (- c)"
   303   by (simp add: fps_ext)
   304 
   305 lemma fps_const_add [simp]: "fps_const (c::'a::monoid_add) + fps_const d = fps_const (c + d)"
   306   by (simp add: fps_ext)
   307 
   308 lemma fps_const_sub [simp]: "fps_const (c::'a::group_add) - fps_const d = fps_const (c - d)"
   309   by (simp add: fps_ext)
   310 
   311 lemma fps_const_mult[simp]: "fps_const (c::'a::ring) * fps_const d = fps_const (c * d)"
   312   by (simp add: fps_eq_iff fps_mult_nth sum.neutral)
   313 
   314 lemma fps_const_add_left: "fps_const (c::'a::monoid_add) + f =
   315     Abs_fps (\<lambda>n. if n = 0 then c + f$0 else f$n)"
   316   by (simp add: fps_ext)
   317 
   318 lemma fps_const_add_right: "f + fps_const (c::'a::monoid_add) =
   319     Abs_fps (\<lambda>n. if n = 0 then f$0 + c else f$n)"
   320   by (simp add: fps_ext)
   321 
   322 lemma fps_const_mult_left: "fps_const (c::'a::semiring_0) * f = Abs_fps (\<lambda>n. c * f$n)"
   323   unfolding fps_eq_iff fps_mult_nth
   324   by (simp add: fps_const_def mult_delta_left sum.delta)
   325 
   326 lemma fps_const_mult_right: "f * fps_const (c::'a::semiring_0) = Abs_fps (\<lambda>n. f$n * c)"
   327   unfolding fps_eq_iff fps_mult_nth
   328   by (simp add: fps_const_def mult_delta_right sum.delta')
   329 
   330 lemma fps_mult_left_const_nth [simp]: "(fps_const (c::'a::semiring_1) * f)$n = c* f$n"
   331   by (simp add: fps_mult_nth mult_delta_left sum.delta)
   332 
   333 lemma fps_mult_right_const_nth [simp]: "(f * fps_const (c::'a::semiring_1))$n = f$n * c"
   334   by (simp add: fps_mult_nth mult_delta_right sum.delta')
   335 
   336 
   337 subsection \<open>Formal power series form an integral domain\<close>
   338 
   339 instance fps :: (ring) ring ..
   340 
   341 instance fps :: (ring_1) ring_1
   342   by (intro_classes, auto simp add: distrib_right)
   343 
   344 instance fps :: (comm_ring_1) comm_ring_1
   345   by (intro_classes, auto simp add: distrib_right)
   346 
   347 instance fps :: (ring_no_zero_divisors) ring_no_zero_divisors
   348 proof
   349   fix a b :: "'a fps"
   350   assume "a \<noteq> 0" and "b \<noteq> 0"
   351   then obtain i j where i: "a $ i \<noteq> 0" "\<forall>k<i. a $ k = 0" and j: "b $ j \<noteq> 0" "\<forall>k<j. b $ k =0"
   352     unfolding fps_nonzero_nth_minimal
   353     by blast+
   354   have "(a * b) $ (i + j) = (\<Sum>k=0..i+j. a $ k * b $ (i + j - k))"
   355     by (rule fps_mult_nth)
   356   also have "\<dots> = (a $ i * b $ (i + j - i)) + (\<Sum>k\<in>{0..i+j} - {i}. a $ k * b $ (i + j - k))"
   357     by (rule sum.remove) simp_all
   358   also have "(\<Sum>k\<in>{0..i+j}-{i}. a $ k * b $ (i + j - k)) = 0"
   359   proof (rule sum.neutral [rule_format])
   360     fix k assume "k \<in> {0..i+j} - {i}"
   361     then have "k < i \<or> i+j-k < j"
   362       by auto
   363     then show "a $ k * b $ (i + j - k) = 0"
   364       using i j by auto
   365   qed
   366   also have "a $ i * b $ (i + j - i) + 0 = a $ i * b $ j"
   367     by simp
   368   also have "a $ i * b $ j \<noteq> 0"
   369     using i j by simp
   370   finally have "(a*b) $ (i+j) \<noteq> 0" .
   371   then show "a * b \<noteq> 0"
   372     unfolding fps_nonzero_nth by blast
   373 qed
   374 
   375 instance fps :: (ring_1_no_zero_divisors) ring_1_no_zero_divisors ..
   376 
   377 instance fps :: (idom) idom ..
   378 
   379 lemma numeral_fps_const: "numeral k = fps_const (numeral k)"
   380   by (induct k) (simp_all only: numeral.simps fps_const_1_eq_1
   381     fps_const_add [symmetric])
   382 
   383 lemma neg_numeral_fps_const:
   384   "(- numeral k :: 'a :: ring_1 fps) = fps_const (- numeral k)"
   385   by (simp add: numeral_fps_const)
   386 
   387 lemma fps_numeral_nth: "numeral n $ i = (if i = 0 then numeral n else 0)"
   388   by (simp add: numeral_fps_const)
   389 
   390 lemma fps_numeral_nth_0 [simp]: "numeral n $ 0 = numeral n"
   391   by (simp add: numeral_fps_const)
   392 
   393 lemma fps_of_nat: "fps_const (of_nat c) = of_nat c"
   394   by (induction c) (simp_all add: fps_const_add [symmetric] del: fps_const_add)
   395 
   396 
   397 
   398 subsection \<open>The eXtractor series X\<close>
   399 
   400 lemma minus_one_power_iff: "(- (1::'a::comm_ring_1)) ^ n = (if even n then 1 else - 1)"
   401   by (induct n) auto
   402 
   403 definition "X = Abs_fps (\<lambda>n. if n = 1 then 1 else 0)"
   404 
   405 lemma X_mult_nth [simp]:
   406   "(X * (f :: 'a::semiring_1 fps)) $n = (if n = 0 then 0 else f $ (n - 1))"
   407 proof (cases "n = 0")
   408   case False
   409   have "(X * f) $n = (\<Sum>i = 0..n. X $ i * f $ (n - i))"
   410     by (simp add: fps_mult_nth)
   411   also have "\<dots> = f $ (n - 1)"
   412     using False by (simp add: X_def mult_delta_left sum.delta)
   413   finally show ?thesis
   414     using False by simp
   415 next
   416   case True
   417   then show ?thesis
   418     by (simp add: fps_mult_nth X_def)
   419 qed
   420 
   421 lemma X_mult_right_nth[simp]:
   422   "((a::'a::semiring_1 fps) * X) $ n = (if n = 0 then 0 else a $ (n - 1))"
   423 proof -
   424   have "(a * X) $ n = (\<Sum>i = 0..n. a $ i * (if n - i = Suc 0 then 1 else 0))"
   425     by (simp add: fps_times_def X_def)
   426   also have "\<dots> = (\<Sum>i = 0..n. if i = n - 1 then if n = 0 then 0 else a $ i else 0)"
   427     by (intro sum.cong) auto
   428   also have "\<dots> = (if n = 0 then 0 else a $ (n - 1))" by (simp add: sum.delta)
   429   finally show ?thesis .
   430 qed
   431 
   432 lemma fps_mult_X_commute: "X * (a :: 'a :: semiring_1 fps) = a * X" 
   433   by (simp add: fps_eq_iff)
   434 
   435 lemma X_power_iff: "X^k = Abs_fps (\<lambda>n. if n = k then 1::'a::comm_ring_1 else 0)"
   436 proof (induct k)
   437   case 0
   438   then show ?case by (simp add: X_def fps_eq_iff)
   439 next
   440   case (Suc k)
   441   have "(X^Suc k) $ m = (if m = Suc k then 1::'a else 0)" for m
   442   proof -
   443     have "(X^Suc k) $ m = (if m = 0 then 0 else (X^k) $ (m - 1))"
   444       by (simp del: One_nat_def)
   445     then show ?thesis
   446       using Suc.hyps by (auto cong del: if_weak_cong)
   447   qed
   448   then show ?case
   449     by (simp add: fps_eq_iff)
   450 qed
   451 
   452 lemma X_nth[simp]: "X$n = (if n = 1 then 1 else 0)"
   453   by (simp add: X_def)
   454 
   455 lemma X_power_nth[simp]: "(X^k) $n = (if n = k then 1 else 0::'a::comm_ring_1)"
   456   by (simp add: X_power_iff)
   457 
   458 lemma X_power_mult_nth: "(X^k * (f :: 'a::comm_ring_1 fps)) $n = (if n < k then 0 else f $ (n - k))"
   459   apply (induct k arbitrary: n)
   460   apply simp
   461   unfolding power_Suc mult.assoc
   462   apply (case_tac n)
   463   apply auto
   464   done
   465 
   466 lemma X_power_mult_right_nth:
   467     "((f :: 'a::comm_ring_1 fps) * X^k) $n = (if n < k then 0 else f $ (n - k))"
   468   by (metis X_power_mult_nth mult.commute)
   469 
   470 
   471 lemma X_neq_fps_const [simp]: "(X :: 'a :: zero_neq_one fps) \<noteq> fps_const c"
   472 proof
   473   assume "(X::'a fps) = fps_const (c::'a)"
   474   hence "X$1 = (fps_const (c::'a))$1" by (simp only:)
   475   thus False by auto
   476 qed
   477 
   478 lemma X_neq_zero [simp]: "(X :: 'a :: zero_neq_one fps) \<noteq> 0"
   479   by (simp only: fps_const_0_eq_0[symmetric] X_neq_fps_const) simp
   480 
   481 lemma X_neq_one [simp]: "(X :: 'a :: zero_neq_one fps) \<noteq> 1"
   482   by (simp only: fps_const_1_eq_1[symmetric] X_neq_fps_const) simp
   483 
   484 lemma X_neq_numeral [simp]: "(X :: 'a :: {semiring_1,zero_neq_one} fps) \<noteq> numeral c"
   485   by (simp only: numeral_fps_const X_neq_fps_const) simp
   486 
   487 lemma X_pow_eq_X_pow_iff [simp]:
   488   "(X :: ('a :: {comm_ring_1}) fps) ^ m = X ^ n \<longleftrightarrow> m = n"
   489 proof
   490   assume "(X :: 'a fps) ^ m = X ^ n"
   491   hence "(X :: 'a fps) ^ m $ m = X ^ n $ m" by (simp only:)
   492   thus "m = n" by (simp split: if_split_asm)
   493 qed simp_all
   494 
   495 
   496 subsection \<open>Subdegrees\<close>
   497 
   498 definition subdegree :: "('a::zero) fps \<Rightarrow> nat" where
   499   "subdegree f = (if f = 0 then 0 else LEAST n. f$n \<noteq> 0)"
   500 
   501 lemma subdegreeI:
   502   assumes "f $ d \<noteq> 0" and "\<And>i. i < d \<Longrightarrow> f $ i = 0"
   503   shows   "subdegree f = d"
   504 proof-
   505   from assms(1) have "f \<noteq> 0" by auto
   506   moreover from assms(1) have "(LEAST i. f $ i \<noteq> 0) = d"
   507   proof (rule Least_equality)
   508     fix e assume "f $ e \<noteq> 0"
   509     with assms(2) have "\<not>(e < d)" by blast
   510     thus "e \<ge> d" by simp
   511   qed
   512   ultimately show ?thesis unfolding subdegree_def by simp
   513 qed
   514 
   515 lemma nth_subdegree_nonzero [simp,intro]: "f \<noteq> 0 \<Longrightarrow> f $ subdegree f \<noteq> 0"
   516 proof-
   517   assume "f \<noteq> 0"
   518   hence "subdegree f = (LEAST n. f $ n \<noteq> 0)" by (simp add: subdegree_def)
   519   also from \<open>f \<noteq> 0\<close> have "\<exists>n. f$n \<noteq> 0" using fps_nonzero_nth by blast
   520   from LeastI_ex[OF this] have "f $ (LEAST n. f $ n \<noteq> 0) \<noteq> 0" .
   521   finally show ?thesis .
   522 qed
   523 
   524 lemma nth_less_subdegree_zero [dest]: "n < subdegree f \<Longrightarrow> f $ n = 0"
   525 proof (cases "f = 0")
   526   assume "f \<noteq> 0" and less: "n < subdegree f"
   527   note less
   528   also from \<open>f \<noteq> 0\<close> have "subdegree f = (LEAST n. f $ n \<noteq> 0)" by (simp add: subdegree_def)
   529   finally show "f $ n = 0" using not_less_Least by blast
   530 qed simp_all
   531 
   532 lemma subdegree_geI:
   533   assumes "f \<noteq> 0" "\<And>i. i < n \<Longrightarrow> f$i = 0"
   534   shows   "subdegree f \<ge> n"
   535 proof (rule ccontr)
   536   assume "\<not>(subdegree f \<ge> n)"
   537   with assms(2) have "f $ subdegree f = 0" by simp
   538   moreover from assms(1) have "f $ subdegree f \<noteq> 0" by simp
   539   ultimately show False by contradiction
   540 qed
   541 
   542 lemma subdegree_greaterI:
   543   assumes "f \<noteq> 0" "\<And>i. i \<le> n \<Longrightarrow> f$i = 0"
   544   shows   "subdegree f > n"
   545 proof (rule ccontr)
   546   assume "\<not>(subdegree f > n)"
   547   with assms(2) have "f $ subdegree f = 0" by simp
   548   moreover from assms(1) have "f $ subdegree f \<noteq> 0" by simp
   549   ultimately show False by contradiction
   550 qed
   551 
   552 lemma subdegree_leI:
   553   "f $ n \<noteq> 0 \<Longrightarrow> subdegree f \<le> n"
   554   by (rule leI) auto
   555 
   556 
   557 lemma subdegree_0 [simp]: "subdegree 0 = 0"
   558   by (simp add: subdegree_def)
   559 
   560 lemma subdegree_1 [simp]: "subdegree (1 :: ('a :: zero_neq_one) fps) = 0"
   561   by (auto intro!: subdegreeI)
   562 
   563 lemma subdegree_X [simp]: "subdegree (X :: ('a :: zero_neq_one) fps) = 1"
   564   by (auto intro!: subdegreeI simp: X_def)
   565 
   566 lemma subdegree_fps_const [simp]: "subdegree (fps_const c) = 0"
   567   by (cases "c = 0") (auto intro!: subdegreeI)
   568 
   569 lemma subdegree_numeral [simp]: "subdegree (numeral n) = 0"
   570   by (simp add: numeral_fps_const)
   571 
   572 lemma subdegree_eq_0_iff: "subdegree f = 0 \<longleftrightarrow> f = 0 \<or> f $ 0 \<noteq> 0"
   573 proof (cases "f = 0")
   574   assume "f \<noteq> 0"
   575   thus ?thesis
   576     using nth_subdegree_nonzero[OF \<open>f \<noteq> 0\<close>] by (fastforce intro!: subdegreeI)
   577 qed simp_all
   578 
   579 lemma subdegree_eq_0 [simp]: "f $ 0 \<noteq> 0 \<Longrightarrow> subdegree f = 0"
   580   by (simp add: subdegree_eq_0_iff)
   581 
   582 lemma nth_subdegree_mult [simp]:
   583   fixes f g :: "('a :: {mult_zero,comm_monoid_add}) fps"
   584   shows "(f * g) $ (subdegree f + subdegree g) = f $ subdegree f * g $ subdegree g"
   585 proof-
   586   let ?n = "subdegree f + subdegree g"
   587   have "(f * g) $ ?n = (\<Sum>i=0..?n. f$i * g$(?n-i))"
   588     by (simp add: fps_mult_nth)
   589   also have "... = (\<Sum>i=0..?n. if i = subdegree f then f$i * g$(?n-i) else 0)"
   590   proof (intro sum.cong)
   591     fix x assume x: "x \<in> {0..?n}"
   592     hence "x = subdegree f \<or> x < subdegree f \<or> ?n - x < subdegree g" by auto
   593     thus "f $ x * g $ (?n - x) = (if x = subdegree f then f $ x * g $ (?n - x) else 0)"
   594       by (elim disjE conjE) auto
   595   qed auto
   596   also have "... = f $ subdegree f * g $ subdegree g" by (simp add: sum.delta)
   597   finally show ?thesis .
   598 qed
   599 
   600 lemma subdegree_mult [simp]:
   601   assumes "f \<noteq> 0" "g \<noteq> 0"
   602   shows "subdegree ((f :: ('a :: {ring_no_zero_divisors}) fps) * g) = subdegree f + subdegree g"
   603 proof (rule subdegreeI)
   604   let ?n = "subdegree f + subdegree g"
   605   have "(f * g) $ ?n = (\<Sum>i=0..?n. f$i * g$(?n-i))" by (simp add: fps_mult_nth)
   606   also have "... = (\<Sum>i=0..?n. if i = subdegree f then f$i * g$(?n-i) else 0)"
   607   proof (intro sum.cong)
   608     fix x assume x: "x \<in> {0..?n}"
   609     hence "x = subdegree f \<or> x < subdegree f \<or> ?n - x < subdegree g" by auto
   610     thus "f $ x * g $ (?n - x) = (if x = subdegree f then f $ x * g $ (?n - x) else 0)"
   611       by (elim disjE conjE) auto
   612   qed auto
   613   also have "... = f $ subdegree f * g $ subdegree g" by (simp add: sum.delta)
   614   also from assms have "... \<noteq> 0" by auto
   615   finally show "(f * g) $ (subdegree f + subdegree g) \<noteq> 0" .
   616 next
   617   fix m assume m: "m < subdegree f + subdegree g"
   618   have "(f * g) $ m = (\<Sum>i=0..m. f$i * g$(m-i))" by (simp add: fps_mult_nth)
   619   also have "... = (\<Sum>i=0..m. 0)"
   620   proof (rule sum.cong)
   621     fix i assume "i \<in> {0..m}"
   622     with m have "i < subdegree f \<or> m - i < subdegree g" by auto
   623     thus "f$i * g$(m-i) = 0" by (elim disjE) auto
   624   qed auto
   625   finally show "(f * g) $ m = 0" by simp
   626 qed
   627 
   628 lemma subdegree_power [simp]:
   629   "subdegree ((f :: ('a :: ring_1_no_zero_divisors) fps) ^ n) = n * subdegree f"
   630   by (cases "f = 0"; induction n) simp_all
   631 
   632 lemma subdegree_uminus [simp]:
   633   "subdegree (-(f::('a::group_add) fps)) = subdegree f"
   634   by (simp add: subdegree_def)
   635 
   636 lemma subdegree_minus_commute [simp]:
   637   "subdegree (f-(g::('a::group_add) fps)) = subdegree (g - f)"
   638 proof -
   639   have "f - g = -(g - f)" by simp
   640   also have "subdegree ... = subdegree (g - f)" by (simp only: subdegree_uminus)
   641   finally show ?thesis .
   642 qed
   643 
   644 lemma subdegree_add_ge:
   645   assumes "f \<noteq> -(g :: ('a :: {group_add}) fps)"
   646   shows   "subdegree (f + g) \<ge> min (subdegree f) (subdegree g)"
   647 proof (rule subdegree_geI)
   648   from assms show "f + g \<noteq> 0" by (subst (asm) eq_neg_iff_add_eq_0)
   649 next
   650   fix i assume "i < min (subdegree f) (subdegree g)"
   651   hence "f $ i = 0" and "g $ i = 0" by auto
   652   thus "(f + g) $ i = 0" by force
   653 qed
   654 
   655 lemma subdegree_add_eq1:
   656   assumes "f \<noteq> 0"
   657   assumes "subdegree f < subdegree (g :: ('a :: {group_add}) fps)"
   658   shows   "subdegree (f + g) = subdegree f"
   659 proof (rule antisym[OF subdegree_leI])
   660   from assms show "subdegree (f + g) \<ge> subdegree f"
   661     by (intro order.trans[OF min.boundedI subdegree_add_ge]) auto
   662   from assms have "f $ subdegree f \<noteq> 0" "g $ subdegree f = 0" by auto
   663   thus "(f + g) $ subdegree f \<noteq> 0" by simp
   664 qed
   665 
   666 lemma subdegree_add_eq2:
   667   assumes "g \<noteq> 0"
   668   assumes "subdegree g < subdegree (f :: ('a :: {ab_group_add}) fps)"
   669   shows   "subdegree (f + g) = subdegree g"
   670   using subdegree_add_eq1[OF assms] by (simp add: add.commute)
   671 
   672 lemma subdegree_diff_eq1:
   673   assumes "f \<noteq> 0"
   674   assumes "subdegree f < subdegree (g :: ('a :: {ab_group_add}) fps)"
   675   shows   "subdegree (f - g) = subdegree f"
   676   using subdegree_add_eq1[of f "-g"] assms by (simp add: add.commute)
   677 
   678 lemma subdegree_diff_eq2:
   679   assumes "g \<noteq> 0"
   680   assumes "subdegree g < subdegree (f :: ('a :: {ab_group_add}) fps)"
   681   shows   "subdegree (f - g) = subdegree g"
   682   using subdegree_add_eq2[of "-g" f] assms by (simp add: add.commute)
   683 
   684 lemma subdegree_diff_ge [simp]:
   685   assumes "f \<noteq> (g :: ('a :: {group_add}) fps)"
   686   shows   "subdegree (f - g) \<ge> min (subdegree f) (subdegree g)"
   687   using assms subdegree_add_ge[of f "-g"] by simp
   688 
   689 
   690 
   691 
   692 subsection \<open>Shifting and slicing\<close>
   693 
   694 definition fps_shift :: "nat \<Rightarrow> 'a fps \<Rightarrow> 'a fps" where
   695   "fps_shift n f = Abs_fps (\<lambda>i. f $ (i + n))"
   696 
   697 lemma fps_shift_nth [simp]: "fps_shift n f $ i = f $ (i + n)"
   698   by (simp add: fps_shift_def)
   699 
   700 lemma fps_shift_0 [simp]: "fps_shift 0 f = f"
   701   by (intro fps_ext) (simp add: fps_shift_def)
   702 
   703 lemma fps_shift_zero [simp]: "fps_shift n 0 = 0"
   704   by (intro fps_ext) (simp add: fps_shift_def)
   705 
   706 lemma fps_shift_one: "fps_shift n 1 = (if n = 0 then 1 else 0)"
   707   by (intro fps_ext) (simp add: fps_shift_def)
   708 
   709 lemma fps_shift_fps_const: "fps_shift n (fps_const c) = (if n = 0 then fps_const c else 0)"
   710   by (intro fps_ext) (simp add: fps_shift_def)
   711 
   712 lemma fps_shift_numeral: "fps_shift n (numeral c) = (if n = 0 then numeral c else 0)"
   713   by (simp add: numeral_fps_const fps_shift_fps_const)
   714 
   715 lemma fps_shift_X_power [simp]:
   716   "n \<le> m \<Longrightarrow> fps_shift n (X ^ m) = (X ^ (m - n) ::'a::comm_ring_1 fps)"
   717   by (intro fps_ext) (auto simp: fps_shift_def )
   718 
   719 lemma fps_shift_times_X_power:
   720   "n \<le> subdegree f \<Longrightarrow> fps_shift n f * X ^ n = (f :: 'a :: comm_ring_1 fps)"
   721   by (intro fps_ext) (auto simp: X_power_mult_right_nth nth_less_subdegree_zero)
   722 
   723 lemma fps_shift_times_X_power' [simp]:
   724   "fps_shift n (f * X^n) = (f :: 'a :: comm_ring_1 fps)"
   725   by (intro fps_ext) (auto simp: X_power_mult_right_nth nth_less_subdegree_zero)
   726 
   727 lemma fps_shift_times_X_power'':
   728   "m \<le> n \<Longrightarrow> fps_shift n (f * X^m) = fps_shift (n - m) (f :: 'a :: comm_ring_1 fps)"
   729   by (intro fps_ext) (auto simp: X_power_mult_right_nth nth_less_subdegree_zero)
   730 
   731 lemma fps_shift_subdegree [simp]:
   732   "n \<le> subdegree f \<Longrightarrow> subdegree (fps_shift n f) = subdegree (f :: 'a :: comm_ring_1 fps) - n"
   733   by (cases "f = 0") (force intro: nth_less_subdegree_zero subdegreeI)+
   734 
   735 lemma subdegree_decompose:
   736   "f = fps_shift (subdegree f) f * X ^ subdegree (f :: ('a :: comm_ring_1) fps)"
   737   by (rule fps_ext) (auto simp: X_power_mult_right_nth)
   738 
   739 lemma subdegree_decompose':
   740   "n \<le> subdegree (f :: ('a :: comm_ring_1) fps) \<Longrightarrow> f = fps_shift n f * X^n"
   741   by (rule fps_ext) (auto simp: X_power_mult_right_nth intro!: nth_less_subdegree_zero)
   742 
   743 lemma fps_shift_fps_shift:
   744   "fps_shift (m + n) f = fps_shift m (fps_shift n f)"
   745   by (rule fps_ext) (simp add: add_ac)
   746 
   747 lemma fps_shift_add:
   748   "fps_shift n (f + g) = fps_shift n f + fps_shift n g"
   749   by (simp add: fps_eq_iff)
   750 
   751 lemma fps_shift_mult:
   752   assumes "n \<le> subdegree (g :: 'b :: {comm_ring_1} fps)"
   753   shows   "fps_shift n (h*g) = h * fps_shift n g"
   754 proof -
   755   from assms have "g = fps_shift n g * X^n" by (rule subdegree_decompose')
   756   also have "h * ... = (h * fps_shift n g) * X^n" by simp
   757   also have "fps_shift n ... = h * fps_shift n g" by simp
   758   finally show ?thesis .
   759 qed
   760 
   761 lemma fps_shift_mult_right:
   762   assumes "n \<le> subdegree (g :: 'b :: {comm_ring_1} fps)"
   763   shows   "fps_shift n (g*h) = h * fps_shift n g"
   764   by (subst mult.commute, subst fps_shift_mult) (simp_all add: assms)
   765 
   766 lemma nth_subdegree_zero_iff [simp]: "f $ subdegree f = 0 \<longleftrightarrow> f = 0"
   767   by (cases "f = 0") auto
   768 
   769 lemma fps_shift_subdegree_zero_iff [simp]:
   770   "fps_shift (subdegree f) f = 0 \<longleftrightarrow> f = 0"
   771   by (subst (1) nth_subdegree_zero_iff[symmetric], cases "f = 0")
   772      (simp_all del: nth_subdegree_zero_iff)
   773 
   774 
   775 definition "fps_cutoff n f = Abs_fps (\<lambda>i. if i < n then f$i else 0)"
   776 
   777 lemma fps_cutoff_nth [simp]: "fps_cutoff n f $ i = (if i < n then f$i else 0)"
   778   unfolding fps_cutoff_def by simp
   779 
   780 lemma fps_cutoff_zero_iff: "fps_cutoff n f = 0 \<longleftrightarrow> (f = 0 \<or> n \<le> subdegree f)"
   781 proof
   782   assume A: "fps_cutoff n f = 0"
   783   thus "f = 0 \<or> n \<le> subdegree f"
   784   proof (cases "f = 0")
   785     assume "f \<noteq> 0"
   786     with A have "n \<le> subdegree f"
   787       by (intro subdegree_geI) (auto simp: fps_eq_iff split: if_split_asm)
   788     thus ?thesis ..
   789   qed simp
   790 qed (auto simp: fps_eq_iff intro: nth_less_subdegree_zero)
   791 
   792 lemma fps_cutoff_0 [simp]: "fps_cutoff 0 f = 0"
   793   by (simp add: fps_eq_iff)
   794 
   795 lemma fps_cutoff_zero [simp]: "fps_cutoff n 0 = 0"
   796   by (simp add: fps_eq_iff)
   797 
   798 lemma fps_cutoff_one: "fps_cutoff n 1 = (if n = 0 then 0 else 1)"
   799   by (simp add: fps_eq_iff)
   800 
   801 lemma fps_cutoff_fps_const: "fps_cutoff n (fps_const c) = (if n = 0 then 0 else fps_const c)"
   802   by (simp add: fps_eq_iff)
   803 
   804 lemma fps_cutoff_numeral: "fps_cutoff n (numeral c) = (if n = 0 then 0 else numeral c)"
   805   by (simp add: numeral_fps_const fps_cutoff_fps_const)
   806 
   807 lemma fps_shift_cutoff:
   808   "fps_shift n (f :: ('a :: comm_ring_1) fps) * X^n + fps_cutoff n f = f"
   809   by (simp add: fps_eq_iff X_power_mult_right_nth)
   810 
   811 
   812 subsection \<open>Formal Power series form a metric space\<close>
   813 
   814 definition (in dist) "ball x r = {y. dist y x < r}"
   815 
   816 instantiation fps :: (comm_ring_1) dist
   817 begin
   818 
   819 definition
   820   dist_fps_def: "dist (a :: 'a fps) b = (if a = b then 0 else inverse (2 ^ subdegree (a - b)))"
   821 
   822 lemma dist_fps_ge0: "dist (a :: 'a fps) b \<ge> 0"
   823   by (simp add: dist_fps_def)
   824 
   825 lemma dist_fps_sym: "dist (a :: 'a fps) b = dist b a"
   826   by (simp add: dist_fps_def)
   827 
   828 instance ..
   829 
   830 end
   831 
   832 instantiation fps :: (comm_ring_1) metric_space
   833 begin
   834 
   835 definition uniformity_fps_def [code del]:
   836   "(uniformity :: ('a fps \<times> 'a fps) filter) = (INF e:{0 <..}. principal {(x, y). dist x y < e})"
   837 
   838 definition open_fps_def' [code del]:
   839   "open (U :: 'a fps set) \<longleftrightarrow> (\<forall>x\<in>U. eventually (\<lambda>(x', y). x' = x \<longrightarrow> y \<in> U) uniformity)"
   840 
   841 instance
   842 proof
   843   show th: "dist a b = 0 \<longleftrightarrow> a = b" for a b :: "'a fps"
   844     by (simp add: dist_fps_def split: if_split_asm)
   845   then have th'[simp]: "dist a a = 0" for a :: "'a fps" by simp
   846 
   847   fix a b c :: "'a fps"
   848   consider "a = b" | "c = a \<or> c = b" | "a \<noteq> b" "a \<noteq> c" "b \<noteq> c" by blast
   849   then show "dist a b \<le> dist a c + dist b c"
   850   proof cases
   851     case 1
   852     then show ?thesis by (simp add: dist_fps_def)
   853   next
   854     case 2
   855     then show ?thesis
   856       by (cases "c = a") (simp_all add: th dist_fps_sym)
   857   next
   858     case neq: 3
   859     have False if "dist a b > dist a c + dist b c"
   860     proof -
   861       let ?n = "subdegree (a - b)"
   862       from neq have "dist a b > 0" "dist b c > 0" and "dist a c > 0" by (simp_all add: dist_fps_def)
   863       with that have "dist a b > dist a c" and "dist a b > dist b c" by simp_all
   864       with neq have "?n < subdegree (a - c)" and "?n < subdegree (b - c)"
   865         by (simp_all add: dist_fps_def field_simps)
   866       hence "(a - c) $ ?n = 0" and "(b - c) $ ?n = 0"
   867         by (simp_all only: nth_less_subdegree_zero)
   868       hence "(a - b) $ ?n = 0" by simp
   869       moreover from neq have "(a - b) $ ?n \<noteq> 0" by (intro nth_subdegree_nonzero) simp_all
   870       ultimately show False by contradiction
   871     qed
   872     thus ?thesis by (auto simp add: not_le[symmetric])
   873   qed
   874 qed (rule open_fps_def' uniformity_fps_def)+
   875 
   876 end
   877 
   878 declare uniformity_Abort[where 'a="'a :: comm_ring_1 fps", code]
   879 
   880 lemma open_fps_def: "open (S :: 'a::comm_ring_1 fps set) = (\<forall>a \<in> S. \<exists>r. r >0 \<and> ball a r \<subseteq> S)"
   881   unfolding open_dist ball_def subset_eq by simp
   882 
   883 text \<open>The infinite sums and justification of the notation in textbooks.\<close>
   884 
   885 lemma reals_power_lt_ex:
   886   fixes x y :: real
   887   assumes xp: "x > 0"
   888     and y1: "y > 1"
   889   shows "\<exists>k>0. (1/y)^k < x"
   890 proof -
   891   have yp: "y > 0"
   892     using y1 by simp
   893   from reals_Archimedean2[of "max 0 (- log y x) + 1"]
   894   obtain k :: nat where k: "real k > max 0 (- log y x) + 1"
   895     by blast
   896   from k have kp: "k > 0"
   897     by simp
   898   from k have "real k > - log y x"
   899     by simp
   900   then have "ln y * real k > - ln x"
   901     unfolding log_def
   902     using ln_gt_zero_iff[OF yp] y1
   903     by (simp add: minus_divide_left field_simps del: minus_divide_left[symmetric])
   904   then have "ln y * real k + ln x > 0"
   905     by simp
   906   then have "exp (real k * ln y + ln x) > exp 0"
   907     by (simp add: ac_simps)
   908   then have "y ^ k * x > 1"
   909     unfolding exp_zero exp_add exp_real_of_nat_mult exp_ln [OF xp] exp_ln [OF yp]
   910     by simp
   911   then have "x > (1 / y)^k" using yp
   912     by (simp add: field_simps)
   913   then show ?thesis
   914     using kp by blast
   915 qed
   916 
   917 lemma fps_sum_rep_nth: "(sum (\<lambda>i. fps_const(a$i)*X^i) {0..m})$n =
   918     (if n \<le> m then a$n else 0::'a::comm_ring_1)"
   919   apply (auto simp add: fps_sum_nth cond_value_iff cong del: if_weak_cong)
   920   apply (simp add: sum.delta')
   921   done
   922 
   923 lemma fps_notation: "(\<lambda>n. sum (\<lambda>i. fps_const(a$i) * X^i) {0..n}) \<longlonglongrightarrow> a"
   924   (is "?s \<longlonglongrightarrow> a")
   925 proof -
   926   have "\<exists>n0. \<forall>n \<ge> n0. dist (?s n) a < r" if "r > 0" for r
   927   proof -
   928     obtain n0 where n0: "(1/2)^n0 < r" "n0 > 0"
   929       using reals_power_lt_ex[OF \<open>r > 0\<close>, of 2] by auto
   930     show ?thesis
   931     proof -
   932       have "dist (?s n) a < r" if nn0: "n \<ge> n0" for n
   933       proof -
   934         from that have thnn0: "(1/2)^n \<le> (1/2 :: real)^n0"
   935           by (simp add: divide_simps)
   936         show ?thesis
   937         proof (cases "?s n = a")
   938           case True
   939           then show ?thesis
   940             unfolding dist_eq_0_iff[of "?s n" a, symmetric]
   941             using \<open>r > 0\<close> by (simp del: dist_eq_0_iff)
   942         next
   943           case False
   944           from False have dth: "dist (?s n) a = (1/2)^subdegree (?s n - a)"
   945             by (simp add: dist_fps_def field_simps)
   946           from False have kn: "subdegree (?s n - a) > n"
   947             by (intro subdegree_greaterI) (simp_all add: fps_sum_rep_nth)
   948           then have "dist (?s n) a < (1/2)^n"
   949             by (simp add: field_simps dist_fps_def)
   950           also have "\<dots> \<le> (1/2)^n0"
   951             using nn0 by (simp add: divide_simps)
   952           also have "\<dots> < r"
   953             using n0 by simp
   954           finally show ?thesis .
   955         qed
   956       qed
   957       then show ?thesis by blast
   958     qed
   959   qed
   960   then show ?thesis
   961     unfolding lim_sequentially by blast
   962 qed
   963 
   964 
   965 subsection \<open>Inverses of formal power series\<close>
   966 
   967 declare sum.cong[fundef_cong]
   968 
   969 instantiation fps :: ("{comm_monoid_add,inverse,times,uminus}") inverse
   970 begin
   971 
   972 fun natfun_inverse:: "'a fps \<Rightarrow> nat \<Rightarrow> 'a"
   973 where
   974   "natfun_inverse f 0 = inverse (f$0)"
   975 | "natfun_inverse f n = - inverse (f$0) * sum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}"
   976 
   977 definition fps_inverse_def: "inverse f = (if f $ 0 = 0 then 0 else Abs_fps (natfun_inverse f))"
   978 
   979 definition fps_divide_def:
   980   "f div g = (if g = 0 then 0 else
   981      let n = subdegree g; h = fps_shift n g
   982      in  fps_shift n (f * inverse h))"
   983 
   984 instance ..
   985 
   986 end
   987 
   988 lemma fps_inverse_zero [simp]:
   989   "inverse (0 :: 'a::{comm_monoid_add,inverse,times,uminus} fps) = 0"
   990   by (simp add: fps_ext fps_inverse_def)
   991 
   992 lemma fps_inverse_one [simp]: "inverse (1 :: 'a::{division_ring,zero_neq_one} fps) = 1"
   993   apply (auto simp add: expand_fps_eq fps_inverse_def)
   994   apply (case_tac n)
   995   apply auto
   996   done
   997 
   998 lemma inverse_mult_eq_1 [intro]:
   999   assumes f0: "f$0 \<noteq> (0::'a::field)"
  1000   shows "inverse f * f = 1"
  1001 proof -
  1002   have c: "inverse f * f = f * inverse f"
  1003     by (simp add: mult.commute)
  1004   from f0 have ifn: "\<And>n. inverse f $ n = natfun_inverse f n"
  1005     by (simp add: fps_inverse_def)
  1006   from f0 have th0: "(inverse f * f) $ 0 = 1"
  1007     by (simp add: fps_mult_nth fps_inverse_def)
  1008   have "(inverse f * f)$n = 0" if np: "n > 0" for n
  1009   proof -
  1010     from np have eq: "{0..n} = {0} \<union> {1 .. n}"
  1011       by auto
  1012     have d: "{0} \<inter> {1 .. n} = {}"
  1013       by auto
  1014     from f0 np have th0: "- (inverse f $ n) =
  1015       (sum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}) / (f$0)"
  1016       by (cases n) (simp_all add: divide_inverse fps_inverse_def)
  1017     from th0[symmetric, unfolded nonzero_divide_eq_eq[OF f0]]
  1018     have th1: "sum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n} = - (f$0) * (inverse f)$n"
  1019       by (simp add: field_simps)
  1020     have "(f * inverse f) $ n = (\<Sum>i = 0..n. f $i * natfun_inverse f (n - i))"
  1021       unfolding fps_mult_nth ifn ..
  1022     also have "\<dots> = f$0 * natfun_inverse f n + (\<Sum>i = 1..n. f$i * natfun_inverse f (n-i))"
  1023       by (simp add: eq)
  1024     also have "\<dots> = 0"
  1025       unfolding th1 ifn by simp
  1026     finally show ?thesis unfolding c .
  1027   qed
  1028   with th0 show ?thesis
  1029     by (simp add: fps_eq_iff)
  1030 qed
  1031 
  1032 lemma fps_inverse_0_iff[simp]: "(inverse f) $ 0 = (0::'a::division_ring) \<longleftrightarrow> f $ 0 = 0"
  1033   by (simp add: fps_inverse_def nonzero_imp_inverse_nonzero)
  1034 
  1035 lemma fps_inverse_nth_0 [simp]: "inverse f $ 0 = inverse (f $ 0 :: 'a :: division_ring)"
  1036   by (simp add: fps_inverse_def)
  1037 
  1038 lemma fps_inverse_eq_0_iff[simp]: "inverse f = (0:: ('a::division_ring) fps) \<longleftrightarrow> f $ 0 = 0"
  1039 proof
  1040   assume A: "inverse f = 0"
  1041   have "0 = inverse f $ 0" by (subst A) simp
  1042   thus "f $ 0 = 0" by simp
  1043 qed (simp add: fps_inverse_def)
  1044 
  1045 lemma fps_inverse_idempotent[intro, simp]:
  1046   assumes f0: "f$0 \<noteq> (0::'a::field)"
  1047   shows "inverse (inverse f) = f"
  1048 proof -
  1049   from f0 have if0: "inverse f $ 0 \<noteq> 0" by simp
  1050   from inverse_mult_eq_1[OF f0] inverse_mult_eq_1[OF if0]
  1051   have "inverse f * f = inverse f * inverse (inverse f)"
  1052     by (simp add: ac_simps)
  1053   then show ?thesis
  1054     using f0 unfolding mult_cancel_left by simp
  1055 qed
  1056 
  1057 lemma fps_inverse_unique:
  1058   assumes fg: "(f :: 'a :: field fps) * g = 1"
  1059   shows   "inverse f = g"
  1060 proof -
  1061   have f0: "f $ 0 \<noteq> 0"
  1062   proof
  1063     assume "f $ 0 = 0"
  1064     hence "0 = (f * g) $ 0" by simp
  1065     also from fg have "(f * g) $ 0 = 1" by simp
  1066     finally show False by simp
  1067   qed
  1068   from inverse_mult_eq_1[OF this] fg
  1069   have th0: "inverse f * f = g * f"
  1070     by (simp add: ac_simps)
  1071   then show ?thesis
  1072     using f0
  1073     unfolding mult_cancel_right
  1074     by (auto simp add: expand_fps_eq)
  1075 qed
  1076 
  1077 lemma fps_inverse_eq_0: "f$0 = 0 \<Longrightarrow> inverse (f :: 'a :: division_ring fps) = 0"
  1078   by simp
  1079   
  1080 lemma sum_zero_lemma:
  1081   fixes n::nat
  1082   assumes "0 < n"
  1083   shows "(\<Sum>i = 0..n. if n = i then 1 else if n - i = 1 then - 1 else 0) = (0::'a::field)"
  1084 proof -
  1085   let ?f = "\<lambda>i. if n = i then 1 else if n - i = 1 then - 1 else 0"
  1086   let ?g = "\<lambda>i. if i = n then 1 else if i = n - 1 then - 1 else 0"
  1087   let ?h = "\<lambda>i. if i=n - 1 then - 1 else 0"
  1088   have th1: "sum ?f {0..n} = sum ?g {0..n}"
  1089     by (rule sum.cong) auto
  1090   have th2: "sum ?g {0..n - 1} = sum ?h {0..n - 1}"
  1091     apply (rule sum.cong)
  1092     using assms
  1093     apply auto
  1094     done
  1095   have eq: "{0 .. n} = {0.. n - 1} \<union> {n}"
  1096     by auto
  1097   from assms have d: "{0.. n - 1} \<inter> {n} = {}"
  1098     by auto
  1099   have f: "finite {0.. n - 1}" "finite {n}"
  1100     by auto
  1101   show ?thesis
  1102     unfolding th1
  1103     apply (simp add: sum.union_disjoint[OF f d, unfolded eq[symmetric]] del: One_nat_def)
  1104     unfolding th2
  1105     apply (simp add: sum.delta)
  1106     done
  1107 qed
  1108 
  1109 lemma fps_inverse_mult: "inverse (f * g :: 'a::field fps) = inverse f * inverse g"
  1110 proof (cases "f$0 = 0 \<or> g$0 = 0")
  1111   assume "\<not>(f$0 = 0 \<or> g$0 = 0)"
  1112   hence [simp]: "f$0 \<noteq> 0" "g$0 \<noteq> 0" by simp_all
  1113   show ?thesis
  1114   proof (rule fps_inverse_unique)
  1115     have "f * g * (inverse f * inverse g) = (inverse f * f) * (inverse g * g)" by simp
  1116     also have "... = 1" by (subst (1 2) inverse_mult_eq_1) simp_all
  1117     finally show "f * g * (inverse f * inverse g) = 1" .
  1118   qed
  1119 next
  1120   assume A: "f$0 = 0 \<or> g$0 = 0"
  1121   hence "inverse (f * g) = 0" by simp
  1122   also from A have "... = inverse f * inverse g" by auto
  1123   finally show "inverse (f * g) = inverse f * inverse g" .
  1124 qed
  1125 
  1126 
  1127 lemma fps_inverse_gp: "inverse (Abs_fps(\<lambda>n. (1::'a::field))) =
  1128     Abs_fps (\<lambda>n. if n= 0 then 1 else if n=1 then - 1 else 0)"
  1129   apply (rule fps_inverse_unique)
  1130   apply (simp_all add: fps_eq_iff fps_mult_nth sum_zero_lemma)
  1131   done
  1132 
  1133 lemma subdegree_inverse [simp]: "subdegree (inverse (f::'a::field fps)) = 0"
  1134 proof (cases "f$0 = 0")
  1135   assume nz: "f$0 \<noteq> 0"
  1136   hence "subdegree (inverse f) + subdegree f = subdegree (inverse f * f)"
  1137     by (subst subdegree_mult) auto
  1138   also from nz have "subdegree f = 0" by (simp add: subdegree_eq_0_iff)
  1139   also from nz have "inverse f * f = 1" by (rule inverse_mult_eq_1)
  1140   finally show "subdegree (inverse f) = 0" by simp
  1141 qed (simp_all add: fps_inverse_def)
  1142 
  1143 lemma fps_is_unit_iff [simp]: "(f :: 'a :: field fps) dvd 1 \<longleftrightarrow> f $ 0 \<noteq> 0"
  1144 proof
  1145   assume "f dvd 1"
  1146   then obtain g where "1 = f * g" by (elim dvdE)
  1147   from this[symmetric] have "(f*g) $ 0 = 1" by simp
  1148   thus "f $ 0 \<noteq> 0" by auto
  1149 next
  1150   assume A: "f $ 0 \<noteq> 0"
  1151   thus "f dvd 1" by (simp add: inverse_mult_eq_1[OF A, symmetric])
  1152 qed
  1153 
  1154 lemma subdegree_eq_0' [simp]: "(f :: 'a :: field fps) dvd 1 \<Longrightarrow> subdegree f = 0"
  1155   by simp
  1156 
  1157 lemma fps_unit_dvd [simp]: "(f $ 0 :: 'a :: field) \<noteq> 0 \<Longrightarrow> f dvd g"
  1158   by (rule dvd_trans, subst fps_is_unit_iff) simp_all
  1159 
  1160 instantiation fps :: (field) normalization_semidom
  1161 begin
  1162 
  1163 definition fps_unit_factor_def [simp]:
  1164   "unit_factor f = fps_shift (subdegree f) f"
  1165 
  1166 definition fps_normalize_def [simp]:
  1167   "normalize f = (if f = 0 then 0 else X ^ subdegree f)"
  1168 
  1169 instance proof
  1170   fix f :: "'a fps"
  1171   show "unit_factor f * normalize f = f"
  1172     by (simp add: fps_shift_times_X_power)
  1173 next
  1174   fix f g :: "'a fps"
  1175   show "unit_factor (f * g) = unit_factor f * unit_factor g"
  1176   proof (cases "f = 0 \<or> g = 0")
  1177     assume "\<not>(f = 0 \<or> g = 0)"
  1178     thus "unit_factor (f * g) = unit_factor f * unit_factor g"
  1179     unfolding fps_unit_factor_def
  1180       by (auto simp: fps_shift_fps_shift fps_shift_mult fps_shift_mult_right)
  1181   qed auto
  1182 next
  1183   fix f g :: "'a fps"
  1184   assume "g \<noteq> 0"
  1185   then have "f * (fps_shift (subdegree g) g * inverse (fps_shift (subdegree g) g)) = f"
  1186     by (metis add_cancel_right_left fps_shift_nth inverse_mult_eq_1 mult.commute mult_cancel_left2 nth_subdegree_nonzero)
  1187   then have "fps_shift (subdegree g) (g * (f * inverse (fps_shift (subdegree g) g))) = f"
  1188     by (simp add: fps_shift_mult_right mult.commute)
  1189   with \<open>g \<noteq> 0\<close> show "f * g / g = f"
  1190     by (simp add: fps_divide_def Let_def ac_simps)
  1191 qed (auto simp add: fps_divide_def Let_def)
  1192 
  1193 end
  1194 
  1195 instantiation fps :: (field) ring_div
  1196 begin
  1197 
  1198 definition fps_mod_def:
  1199   "f mod g = (if g = 0 then f else
  1200      let n = subdegree g; h = fps_shift n g
  1201      in  fps_cutoff n (f * inverse h) * h)"
  1202 
  1203 lemma fps_mod_eq_zero:
  1204   assumes "g \<noteq> 0" and "subdegree f \<ge> subdegree g"
  1205   shows   "f mod g = 0"
  1206   using assms by (cases "f = 0") (auto simp: fps_cutoff_zero_iff fps_mod_def Let_def)
  1207 
  1208 lemma fps_times_divide_eq:
  1209   assumes "g \<noteq> 0" and "subdegree f \<ge> subdegree (g :: 'a fps)"
  1210   shows   "f div g * g = f"
  1211 proof (cases "f = 0")
  1212   assume nz: "f \<noteq> 0"
  1213   define n where "n = subdegree g"
  1214   define h where "h = fps_shift n g"
  1215   from assms have [simp]: "h $ 0 \<noteq> 0" unfolding h_def by (simp add: n_def)
  1216 
  1217   from assms nz have "f div g * g = fps_shift n (f * inverse h) * g"
  1218     by (simp add: fps_divide_def Let_def h_def n_def)
  1219   also have "... = fps_shift n (f * inverse h) * X^n * h" unfolding h_def n_def
  1220     by (subst subdegree_decompose[of g]) simp
  1221   also have "fps_shift n (f * inverse h) * X^n = f * inverse h"
  1222     by (rule fps_shift_times_X_power) (simp_all add: nz assms n_def)
  1223   also have "... * h = f * (inverse h * h)" by simp
  1224   also have "inverse h * h = 1" by (rule inverse_mult_eq_1) simp
  1225   finally show ?thesis by simp
  1226 qed (simp_all add: fps_divide_def Let_def)
  1227 
  1228 lemma
  1229   assumes "g$0 \<noteq> 0"
  1230   shows   fps_divide_unit: "f div g = f * inverse g" and fps_mod_unit [simp]: "f mod g = 0"
  1231 proof -
  1232   from assms have [simp]: "subdegree g = 0" by (simp add: subdegree_eq_0_iff)
  1233   from assms show "f div g = f * inverse g"
  1234     by (auto simp: fps_divide_def Let_def subdegree_eq_0_iff)
  1235   from assms show "f mod g = 0" by (intro fps_mod_eq_zero) auto
  1236 qed
  1237 
  1238 context
  1239 begin
  1240 private lemma fps_divide_cancel_aux1:
  1241   assumes "h$0 \<noteq> (0 :: 'a :: field)"
  1242   shows   "(h * f) div (h * g) = f div g"
  1243 proof (cases "g = 0")
  1244   assume "g \<noteq> 0"
  1245   from assms have "h \<noteq> 0" by auto
  1246   note nz [simp] = \<open>g \<noteq> 0\<close> \<open>h \<noteq> 0\<close>
  1247   from assms have [simp]: "subdegree h = 0" by (simp add: subdegree_eq_0_iff)
  1248 
  1249   have "(h * f) div (h * g) =
  1250           fps_shift (subdegree g) (h * f * inverse (fps_shift (subdegree g) (h*g)))"
  1251     by (simp add: fps_divide_def Let_def)
  1252   also have "h * f * inverse (fps_shift (subdegree g) (h*g)) =
  1253                (inverse h * h) * f * inverse (fps_shift (subdegree g) g)"
  1254     by (subst fps_shift_mult) (simp_all add: algebra_simps fps_inverse_mult)
  1255   also from assms have "inverse h * h = 1" by (rule inverse_mult_eq_1)
  1256   finally show "(h * f) div (h * g) = f div g" by (simp_all add: fps_divide_def Let_def)
  1257 qed (simp_all add: fps_divide_def)
  1258 
  1259 private lemma fps_divide_cancel_aux2:
  1260   "(f * X^m) div (g * X^m) = f div (g :: 'a :: field fps)"
  1261 proof (cases "g = 0")
  1262   assume [simp]: "g \<noteq> 0"
  1263   have "(f * X^m) div (g * X^m) =
  1264           fps_shift (subdegree g + m) (f*inverse (fps_shift (subdegree g + m) (g*X^m))*X^m)"
  1265     by (simp add: fps_divide_def Let_def algebra_simps)
  1266   also have "... = f div g"
  1267     by (simp add: fps_shift_times_X_power'' fps_divide_def Let_def)
  1268   finally show ?thesis .
  1269 qed (simp_all add: fps_divide_def)
  1270 
  1271 instance proof
  1272   fix f g :: "'a fps"
  1273   define n where "n = subdegree g"
  1274   define h where "h = fps_shift n g"
  1275 
  1276   show "f div g * g + f mod g = f"
  1277   proof (cases "g = 0 \<or> f = 0")
  1278     assume "\<not>(g = 0 \<or> f = 0)"
  1279     hence nz [simp]: "f \<noteq> 0" "g \<noteq> 0" by simp_all
  1280     show ?thesis
  1281     proof (rule disjE[OF le_less_linear])
  1282       assume "subdegree f \<ge> subdegree g"
  1283       with nz show ?thesis by (simp add: fps_mod_eq_zero fps_times_divide_eq)
  1284     next
  1285       assume "subdegree f < subdegree g"
  1286       have g_decomp: "g = h * X^n" unfolding h_def n_def by (rule subdegree_decompose)
  1287       have "f div g * g + f mod g =
  1288               fps_shift n (f * inverse h) * g + fps_cutoff n (f * inverse h) * h"
  1289         by (simp add: fps_mod_def fps_divide_def Let_def n_def h_def)
  1290       also have "... = h * (fps_shift n (f * inverse h) * X^n + fps_cutoff n (f * inverse h))"
  1291         by (subst g_decomp) (simp add: algebra_simps)
  1292       also have "... = f * (inverse h * h)"
  1293         by (subst fps_shift_cutoff) simp
  1294       also have "inverse h * h = 1" by (rule inverse_mult_eq_1) (simp add: h_def n_def)
  1295       finally show ?thesis by simp
  1296     qed
  1297   qed (auto simp: fps_mod_def fps_divide_def Let_def)
  1298 next
  1299 
  1300   fix f g h :: "'a fps"
  1301   assume "h \<noteq> 0"
  1302   show "(h * f) div (h * g) = f div g"
  1303   proof -
  1304     define m where "m = subdegree h"
  1305     define h' where "h' = fps_shift m h"
  1306     have h_decomp: "h = h' * X ^ m" unfolding h'_def m_def by (rule subdegree_decompose)
  1307     from \<open>h \<noteq> 0\<close> have [simp]: "h'$0 \<noteq> 0" by (simp add: h'_def m_def)
  1308     have "(h * f) div (h * g) = (h' * f * X^m) div (h' * g * X^m)"
  1309       by (simp add: h_decomp algebra_simps)
  1310     also have "... = f div g" by (simp add: fps_divide_cancel_aux1 fps_divide_cancel_aux2)
  1311     finally show ?thesis .
  1312   qed
  1313 
  1314 next
  1315   fix f g h :: "'a fps"
  1316   assume [simp]: "h \<noteq> 0"
  1317   define n h' where dfs: "n = subdegree h" "h' = fps_shift n h"
  1318   have "(f + g * h) div h = fps_shift n (f * inverse h') + fps_shift n (g * (h * inverse h'))"
  1319     by (simp add: fps_divide_def Let_def dfs[symmetric] algebra_simps fps_shift_add)
  1320   also have "h * inverse h' = (inverse h' * h') * X^n"
  1321     by (subst subdegree_decompose) (simp_all add: dfs)
  1322   also have "... = X^n" by (subst inverse_mult_eq_1) (simp_all add: dfs)
  1323   also have "fps_shift n (g * X^n) = g" by simp
  1324   also have "fps_shift n (f * inverse h') = f div h"
  1325     by (simp add: fps_divide_def Let_def dfs)
  1326   finally show "(f + g * h) div h = g + f div h" by simp
  1327 qed
  1328 
  1329 end
  1330 end
  1331 
  1332 lemma subdegree_mod:
  1333   assumes "f \<noteq> 0" "subdegree f < subdegree g"
  1334   shows   "subdegree (f mod g) = subdegree f"
  1335 proof (cases "f div g * g = 0")
  1336   assume "f div g * g \<noteq> 0"
  1337   hence [simp]: "f div g \<noteq> 0" "g \<noteq> 0" by auto
  1338   from div_mult_mod_eq[of f g] have "f mod g = f - f div g * g" by (simp add: algebra_simps)
  1339   also from assms have "subdegree ... = subdegree f"
  1340     by (intro subdegree_diff_eq1) simp_all
  1341   finally show ?thesis .
  1342 next
  1343   assume zero: "f div g * g = 0"
  1344   from div_mult_mod_eq[of f g] have "f mod g = f - f div g * g" by (simp add: algebra_simps)
  1345   also note zero
  1346   finally show ?thesis by simp
  1347 qed
  1348 
  1349 lemma fps_divide_nth_0 [simp]: "g $ 0 \<noteq> 0 \<Longrightarrow> (f div g) $ 0 = f $ 0 / (g $ 0 :: _ :: field)"
  1350   by (simp add: fps_divide_unit divide_inverse)
  1351 
  1352 
  1353 lemma dvd_imp_subdegree_le:
  1354   "(f :: 'a :: idom fps) dvd g \<Longrightarrow> g \<noteq> 0 \<Longrightarrow> subdegree f \<le> subdegree g"
  1355   by (auto elim: dvdE)
  1356 
  1357 lemma fps_dvd_iff:
  1358   assumes "(f :: 'a :: field fps) \<noteq> 0" "g \<noteq> 0"
  1359   shows   "f dvd g \<longleftrightarrow> subdegree f \<le> subdegree g"
  1360 proof
  1361   assume "subdegree f \<le> subdegree g"
  1362   with assms have "g mod f = 0"
  1363     by (simp add: fps_mod_def Let_def fps_cutoff_zero_iff)
  1364   thus "f dvd g" by (simp add: dvd_eq_mod_eq_0)
  1365 qed (simp add: assms dvd_imp_subdegree_le)
  1366 
  1367 lemma fps_shift_altdef:
  1368   "fps_shift n f = (f :: 'a :: field fps) div X^n"
  1369   by (simp add: fps_divide_def)
  1370   
  1371 lemma fps_div_X_power_nth: "((f :: 'a :: field fps) div X^n) $ k = f $ (k + n)"
  1372   by (simp add: fps_shift_altdef [symmetric])
  1373 
  1374 lemma fps_div_X_nth: "((f :: 'a :: field fps) div X) $ k = f $ Suc k"
  1375   using fps_div_X_power_nth[of f 1] by simp
  1376 
  1377 lemma fps_const_inverse: "inverse (fps_const (a::'a::field)) = fps_const (inverse a)"
  1378   by (cases "a \<noteq> 0", rule fps_inverse_unique) (auto simp: fps_eq_iff)
  1379 
  1380 lemma fps_const_divide: "fps_const (x :: _ :: field) / fps_const y = fps_const (x / y)"
  1381   by (cases "y = 0") (simp_all add: fps_divide_unit fps_const_inverse divide_inverse)
  1382 
  1383 lemma inverse_fps_numeral:
  1384   "inverse (numeral n :: ('a :: field_char_0) fps) = fps_const (inverse (numeral n))"
  1385   by (intro fps_inverse_unique fps_ext) (simp_all add: fps_numeral_nth)
  1386 
  1387 lemma fps_numeral_divide_divide:
  1388   "x / numeral b / numeral c = (x / numeral (b * c) :: 'a :: field fps)"
  1389   by (cases "numeral b = (0::'a)"; cases "numeral c = (0::'a)")
  1390       (simp_all add: fps_divide_unit fps_inverse_mult [symmetric] numeral_fps_const numeral_mult 
  1391                 del: numeral_mult [symmetric])
  1392 
  1393 lemma fps_numeral_mult_divide:
  1394   "numeral b * x / numeral c = (numeral b / numeral c * x :: 'a :: field fps)"
  1395   by (cases "numeral c = (0::'a)") (simp_all add: fps_divide_unit numeral_fps_const)
  1396 
  1397 lemmas fps_numeral_simps = 
  1398   fps_numeral_divide_divide fps_numeral_mult_divide inverse_fps_numeral neg_numeral_fps_const
  1399 
  1400 
  1401 subsection \<open>Formal power series form a Euclidean ring\<close>
  1402 
  1403 instantiation fps :: (field) euclidean_ring_cancel
  1404 begin
  1405 
  1406 definition fps_euclidean_size_def:
  1407   "euclidean_size f = (if f = 0 then 0 else 2 ^ subdegree f)"
  1408 
  1409 instance proof
  1410   fix f g :: "'a fps" assume [simp]: "g \<noteq> 0"
  1411   show "euclidean_size f \<le> euclidean_size (f * g)"
  1412     by (cases "f = 0") (auto simp: fps_euclidean_size_def)
  1413   show "euclidean_size (f mod g) < euclidean_size g"
  1414     apply (cases "f = 0", simp add: fps_euclidean_size_def)
  1415     apply (rule disjE[OF le_less_linear[of "subdegree g" "subdegree f"]])
  1416     apply (simp_all add: fps_mod_eq_zero fps_euclidean_size_def subdegree_mod)
  1417     done
  1418 qed (simp_all add: fps_euclidean_size_def)
  1419 
  1420 end
  1421 
  1422 instantiation fps :: (field) euclidean_ring_gcd
  1423 begin
  1424 definition fps_gcd_def: "(gcd :: 'a fps \<Rightarrow> _) = Euclidean_Algorithm.gcd"
  1425 definition fps_lcm_def: "(lcm :: 'a fps \<Rightarrow> _) = Euclidean_Algorithm.lcm"
  1426 definition fps_Gcd_def: "(Gcd :: 'a fps set \<Rightarrow> _) = Euclidean_Algorithm.Gcd"
  1427 definition fps_Lcm_def: "(Lcm :: 'a fps set \<Rightarrow> _) = Euclidean_Algorithm.Lcm"
  1428 instance by standard (simp_all add: fps_gcd_def fps_lcm_def fps_Gcd_def fps_Lcm_def)
  1429 end
  1430 
  1431 lemma fps_gcd:
  1432   assumes [simp]: "f \<noteq> 0" "g \<noteq> 0"
  1433   shows   "gcd f g = X ^ min (subdegree f) (subdegree g)"
  1434 proof -
  1435   let ?m = "min (subdegree f) (subdegree g)"
  1436   show "gcd f g = X ^ ?m"
  1437   proof (rule sym, rule gcdI)
  1438     fix d assume "d dvd f" "d dvd g"
  1439     thus "d dvd X ^ ?m" by (cases "d = 0") (auto simp: fps_dvd_iff)
  1440   qed (simp_all add: fps_dvd_iff)
  1441 qed
  1442 
  1443 lemma fps_gcd_altdef: "gcd (f :: 'a :: field fps) g =
  1444   (if f = 0 \<and> g = 0 then 0 else
  1445    if f = 0 then X ^ subdegree g else
  1446    if g = 0 then X ^ subdegree f else
  1447      X ^ min (subdegree f) (subdegree g))"
  1448   by (simp add: fps_gcd)
  1449 
  1450 lemma fps_lcm:
  1451   assumes [simp]: "f \<noteq> 0" "g \<noteq> 0"
  1452   shows   "lcm f g = X ^ max (subdegree f) (subdegree g)"
  1453 proof -
  1454   let ?m = "max (subdegree f) (subdegree g)"
  1455   show "lcm f g = X ^ ?m"
  1456   proof (rule sym, rule lcmI)
  1457     fix d assume "f dvd d" "g dvd d"
  1458     thus "X ^ ?m dvd d" by (cases "d = 0") (auto simp: fps_dvd_iff)
  1459   qed (simp_all add: fps_dvd_iff)
  1460 qed
  1461 
  1462 lemma fps_lcm_altdef: "lcm (f :: 'a :: field fps) g =
  1463   (if f = 0 \<or> g = 0 then 0 else X ^ max (subdegree f) (subdegree g))"
  1464   by (simp add: fps_lcm)
  1465 
  1466 lemma fps_Gcd:
  1467   assumes "A - {0} \<noteq> {}"
  1468   shows   "Gcd A = X ^ (INF f:A-{0}. subdegree f)"
  1469 proof (rule sym, rule GcdI)
  1470   fix f assume "f \<in> A"
  1471   thus "X ^ (INF f:A - {0}. subdegree f) dvd f"
  1472     by (cases "f = 0") (auto simp: fps_dvd_iff intro!: cINF_lower)
  1473 next
  1474   fix d assume d: "\<And>f. f \<in> A \<Longrightarrow> d dvd f"
  1475   from assms obtain f where "f \<in> A - {0}" by auto
  1476   with d[of f] have [simp]: "d \<noteq> 0" by auto
  1477   from d assms have "subdegree d \<le> (INF f:A-{0}. subdegree f)"
  1478     by (intro cINF_greatest) (auto simp: fps_dvd_iff[symmetric])
  1479   with d assms show "d dvd X ^ (INF f:A-{0}. subdegree f)" by (simp add: fps_dvd_iff)
  1480 qed simp_all
  1481 
  1482 lemma fps_Gcd_altdef: "Gcd (A :: 'a :: field fps set) =
  1483   (if A \<subseteq> {0} then 0 else X ^ (INF f:A-{0}. subdegree f))"
  1484   using fps_Gcd by auto
  1485 
  1486 lemma fps_Lcm:
  1487   assumes "A \<noteq> {}" "0 \<notin> A" "bdd_above (subdegree`A)"
  1488   shows   "Lcm A = X ^ (SUP f:A. subdegree f)"
  1489 proof (rule sym, rule LcmI)
  1490   fix f assume "f \<in> A"
  1491   moreover from assms(3) have "bdd_above (subdegree ` A)" by auto
  1492   ultimately show "f dvd X ^ (SUP f:A. subdegree f)" using assms(2)
  1493     by (cases "f = 0") (auto simp: fps_dvd_iff intro!: cSUP_upper)
  1494 next
  1495   fix d assume d: "\<And>f. f \<in> A \<Longrightarrow> f dvd d"
  1496   from assms obtain f where f: "f \<in> A" "f \<noteq> 0" by auto
  1497   show "X ^ (SUP f:A. subdegree f) dvd d"
  1498   proof (cases "d = 0")
  1499     assume "d \<noteq> 0"
  1500     moreover from d have "\<And>f. f \<in> A \<Longrightarrow> f \<noteq> 0 \<Longrightarrow> f dvd d" by blast
  1501     ultimately have "subdegree d \<ge> (SUP f:A. subdegree f)" using assms
  1502       by (intro cSUP_least) (auto simp: fps_dvd_iff)
  1503     with \<open>d \<noteq> 0\<close> show ?thesis by (simp add: fps_dvd_iff)
  1504   qed simp_all
  1505 qed simp_all
  1506 
  1507 lemma fps_Lcm_altdef:
  1508   "Lcm (A :: 'a :: field fps set) =
  1509      (if 0 \<in> A \<or> \<not>bdd_above (subdegree`A) then 0 else
  1510       if A = {} then 1 else X ^ (SUP f:A. subdegree f))"
  1511 proof (cases "bdd_above (subdegree`A)")
  1512   assume unbounded: "\<not>bdd_above (subdegree`A)"
  1513   have "Lcm A = 0"
  1514   proof (rule ccontr)
  1515     assume "Lcm A \<noteq> 0"
  1516     from unbounded obtain f where f: "f \<in> A" "subdegree (Lcm A) < subdegree f"
  1517       unfolding bdd_above_def by (auto simp: not_le)
  1518     moreover from f and \<open>Lcm A \<noteq> 0\<close> have "subdegree f \<le> subdegree (Lcm A)"
  1519       by (intro dvd_imp_subdegree_le dvd_Lcm) simp_all
  1520     ultimately show False by simp
  1521   qed
  1522   with unbounded show ?thesis by simp
  1523 qed (simp_all add: fps_Lcm Lcm_eq_0_I)
  1524 
  1525 
  1526 
  1527 subsection \<open>Formal Derivatives, and the MacLaurin theorem around 0\<close>
  1528 
  1529 definition "fps_deriv f = Abs_fps (\<lambda>n. of_nat (n + 1) * f $ (n + 1))"
  1530 
  1531 lemma fps_deriv_nth[simp]: "fps_deriv f $ n = of_nat (n +1) * f $ (n + 1)"
  1532   by (simp add: fps_deriv_def)
  1533 
  1534 lemma fps_deriv_linear[simp]:
  1535   "fps_deriv (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) =
  1536     fps_const a * fps_deriv f + fps_const b * fps_deriv g"
  1537   unfolding fps_eq_iff fps_add_nth  fps_const_mult_left fps_deriv_nth by (simp add: field_simps)
  1538 
  1539 lemma fps_deriv_mult[simp]:
  1540   fixes f :: "'a::comm_ring_1 fps"
  1541   shows "fps_deriv (f * g) = f * fps_deriv g + fps_deriv f * g"
  1542 proof -
  1543   let ?D = "fps_deriv"
  1544   have "(f * ?D g + ?D f * g) $ n = ?D (f*g) $ n" for n
  1545   proof -
  1546     let ?Zn = "{0 ..n}"
  1547     let ?Zn1 = "{0 .. n + 1}"
  1548     let ?g = "\<lambda>i. of_nat (i+1) * g $ (i+1) * f $ (n - i) +
  1549         of_nat (i+1)* f $ (i+1) * g $ (n - i)"
  1550     let ?h = "\<lambda>i. of_nat i * g $ i * f $ ((n+1) - i) +
  1551         of_nat i* f $ i * g $ ((n + 1) - i)"
  1552     have s0: "sum (\<lambda>i. of_nat i * f $ i * g $ (n + 1 - i)) ?Zn1 =
  1553       sum (\<lambda>i. of_nat (n + 1 - i) * f $ (n + 1 - i) * g $ i) ?Zn1"
  1554        by (rule sum.reindex_bij_witness[where i="op - (n + 1)" and j="op - (n + 1)"]) auto
  1555     have s1: "sum (\<lambda>i. f $ i * g $ (n + 1 - i)) ?Zn1 =
  1556       sum (\<lambda>i. f $ (n + 1 - i) * g $ i) ?Zn1"
  1557        by (rule sum.reindex_bij_witness[where i="op - (n + 1)" and j="op - (n + 1)"]) auto
  1558     have "(f * ?D g + ?D f * g)$n = (?D g * f + ?D f * g)$n"
  1559       by (simp only: mult.commute)
  1560     also have "\<dots> = (\<Sum>i = 0..n. ?g i)"
  1561       by (simp add: fps_mult_nth sum.distrib[symmetric])
  1562     also have "\<dots> = sum ?h {0..n+1}"
  1563       by (rule sum.reindex_bij_witness_not_neutral
  1564             [where S'="{}" and T'="{0}" and j="Suc" and i="\<lambda>i. i - 1"]) auto
  1565     also have "\<dots> = (fps_deriv (f * g)) $ n"
  1566       apply (simp only: fps_deriv_nth fps_mult_nth sum.distrib)
  1567       unfolding s0 s1
  1568       unfolding sum.distrib[symmetric] sum_distrib_left
  1569       apply (rule sum.cong)
  1570       apply (auto simp add: of_nat_diff field_simps)
  1571       done
  1572     finally show ?thesis .
  1573   qed
  1574   then show ?thesis
  1575     unfolding fps_eq_iff by auto
  1576 qed
  1577 
  1578 lemma fps_deriv_X[simp]: "fps_deriv X = 1"
  1579   by (simp add: fps_deriv_def X_def fps_eq_iff)
  1580 
  1581 lemma fps_deriv_neg[simp]:
  1582   "fps_deriv (- (f:: 'a::comm_ring_1 fps)) = - (fps_deriv f)"
  1583   by (simp add: fps_eq_iff fps_deriv_def)
  1584 
  1585 lemma fps_deriv_add[simp]:
  1586   "fps_deriv ((f:: 'a::comm_ring_1 fps) + g) = fps_deriv f + fps_deriv g"
  1587   using fps_deriv_linear[of 1 f 1 g] by simp
  1588 
  1589 lemma fps_deriv_sub[simp]:
  1590   "fps_deriv ((f:: 'a::comm_ring_1 fps) - g) = fps_deriv f - fps_deriv g"
  1591   using fps_deriv_add [of f "- g"] by simp
  1592 
  1593 lemma fps_deriv_const[simp]: "fps_deriv (fps_const c) = 0"
  1594   by (simp add: fps_ext fps_deriv_def fps_const_def)
  1595 
  1596 lemma fps_deriv_mult_const_left[simp]:
  1597   "fps_deriv (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_deriv f"
  1598   by simp
  1599 
  1600 lemma fps_deriv_0[simp]: "fps_deriv 0 = 0"
  1601   by (simp add: fps_deriv_def fps_eq_iff)
  1602 
  1603 lemma fps_deriv_1[simp]: "fps_deriv 1 = 0"
  1604   by (simp add: fps_deriv_def fps_eq_iff )
  1605 
  1606 lemma fps_deriv_mult_const_right[simp]:
  1607   "fps_deriv (f * fps_const (c::'a::comm_ring_1)) = fps_deriv f * fps_const c"
  1608   by simp
  1609 
  1610 lemma fps_deriv_sum:
  1611   "fps_deriv (sum f S) = sum (\<lambda>i. fps_deriv (f i :: 'a::comm_ring_1 fps)) S"
  1612 proof (cases "finite S")
  1613   case False
  1614   then show ?thesis by simp
  1615 next
  1616   case True
  1617   show ?thesis by (induct rule: finite_induct [OF True]) simp_all
  1618 qed
  1619 
  1620 lemma fps_deriv_eq_0_iff [simp]:
  1621   "fps_deriv f = 0 \<longleftrightarrow> f = fps_const (f$0 :: 'a::{idom,semiring_char_0})"
  1622   (is "?lhs \<longleftrightarrow> ?rhs")
  1623 proof
  1624   show ?lhs if ?rhs
  1625   proof -
  1626     from that have "fps_deriv f = fps_deriv (fps_const (f$0))"
  1627       by simp
  1628     then show ?thesis
  1629       by simp
  1630   qed
  1631   show ?rhs if ?lhs
  1632   proof -
  1633     from that have "\<forall>n. (fps_deriv f)$n = 0"
  1634       by simp
  1635     then have "\<forall>n. f$(n+1) = 0"
  1636       by (simp del: of_nat_Suc of_nat_add One_nat_def)
  1637     then show ?thesis
  1638       apply (clarsimp simp add: fps_eq_iff fps_const_def)
  1639       apply (erule_tac x="n - 1" in allE)
  1640       apply simp
  1641       done
  1642   qed
  1643 qed
  1644 
  1645 lemma fps_deriv_eq_iff:
  1646   fixes f :: "'a::{idom,semiring_char_0} fps"
  1647   shows "fps_deriv f = fps_deriv g \<longleftrightarrow> (f = fps_const(f$0 - g$0) + g)"
  1648 proof -
  1649   have "fps_deriv f = fps_deriv g \<longleftrightarrow> fps_deriv (f - g) = 0"
  1650     by simp
  1651   also have "\<dots> \<longleftrightarrow> f - g = fps_const ((f - g) $ 0)"
  1652     unfolding fps_deriv_eq_0_iff ..
  1653   finally show ?thesis
  1654     by (simp add: field_simps)
  1655 qed
  1656 
  1657 lemma fps_deriv_eq_iff_ex:
  1658   "(fps_deriv f = fps_deriv g) \<longleftrightarrow> (\<exists>c::'a::{idom,semiring_char_0}. f = fps_const c + g)"
  1659   by (auto simp: fps_deriv_eq_iff)
  1660 
  1661 
  1662 fun fps_nth_deriv :: "nat \<Rightarrow> 'a::semiring_1 fps \<Rightarrow> 'a fps"
  1663 where
  1664   "fps_nth_deriv 0 f = f"
  1665 | "fps_nth_deriv (Suc n) f = fps_nth_deriv n (fps_deriv f)"
  1666 
  1667 lemma fps_nth_deriv_commute: "fps_nth_deriv (Suc n) f = fps_deriv (fps_nth_deriv n f)"
  1668   by (induct n arbitrary: f) auto
  1669 
  1670 lemma fps_nth_deriv_linear[simp]:
  1671   "fps_nth_deriv n (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) =
  1672     fps_const a * fps_nth_deriv n f + fps_const b * fps_nth_deriv n g"
  1673   by (induct n arbitrary: f g) (auto simp add: fps_nth_deriv_commute)
  1674 
  1675 lemma fps_nth_deriv_neg[simp]:
  1676   "fps_nth_deriv n (- (f :: 'a::comm_ring_1 fps)) = - (fps_nth_deriv n f)"
  1677   by (induct n arbitrary: f) simp_all
  1678 
  1679 lemma fps_nth_deriv_add[simp]:
  1680   "fps_nth_deriv n ((f :: 'a::comm_ring_1 fps) + g) = fps_nth_deriv n f + fps_nth_deriv n g"
  1681   using fps_nth_deriv_linear[of n 1 f 1 g] by simp
  1682 
  1683 lemma fps_nth_deriv_sub[simp]:
  1684   "fps_nth_deriv n ((f :: 'a::comm_ring_1 fps) - g) = fps_nth_deriv n f - fps_nth_deriv n g"
  1685   using fps_nth_deriv_add [of n f "- g"] by simp
  1686 
  1687 lemma fps_nth_deriv_0[simp]: "fps_nth_deriv n 0 = 0"
  1688   by (induct n) simp_all
  1689 
  1690 lemma fps_nth_deriv_1[simp]: "fps_nth_deriv n 1 = (if n = 0 then 1 else 0)"
  1691   by (induct n) simp_all
  1692 
  1693 lemma fps_nth_deriv_const[simp]:
  1694   "fps_nth_deriv n (fps_const c) = (if n = 0 then fps_const c else 0)"
  1695   by (cases n) simp_all
  1696 
  1697 lemma fps_nth_deriv_mult_const_left[simp]:
  1698   "fps_nth_deriv n (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_nth_deriv n f"
  1699   using fps_nth_deriv_linear[of n "c" f 0 0 ] by simp
  1700 
  1701 lemma fps_nth_deriv_mult_const_right[simp]:
  1702   "fps_nth_deriv n (f * fps_const (c::'a::comm_ring_1)) = fps_nth_deriv n f * fps_const c"
  1703   using fps_nth_deriv_linear[of n "c" f 0 0] by (simp add: mult.commute)
  1704 
  1705 lemma fps_nth_deriv_sum:
  1706   "fps_nth_deriv n (sum f S) = sum (\<lambda>i. fps_nth_deriv n (f i :: 'a::comm_ring_1 fps)) S"
  1707 proof (cases "finite S")
  1708   case True
  1709   show ?thesis by (induct rule: finite_induct [OF True]) simp_all
  1710 next
  1711   case False
  1712   then show ?thesis by simp
  1713 qed
  1714 
  1715 lemma fps_deriv_maclauren_0:
  1716   "(fps_nth_deriv k (f :: 'a::comm_semiring_1 fps)) $ 0 = of_nat (fact k) * f $ k"
  1717   by (induct k arbitrary: f) (auto simp add: field_simps)
  1718 
  1719 
  1720 subsection \<open>Powers\<close>
  1721 
  1722 lemma fps_power_zeroth_eq_one: "a$0 =1 \<Longrightarrow> a^n $ 0 = (1::'a::semiring_1)"
  1723   by (induct n) (auto simp add: expand_fps_eq fps_mult_nth)
  1724 
  1725 lemma fps_power_first_eq: "(a :: 'a::comm_ring_1 fps) $ 0 =1 \<Longrightarrow> a^n $ 1 = of_nat n * a$1"
  1726 proof (induct n)
  1727   case 0
  1728   then show ?case by simp
  1729 next
  1730   case (Suc n)
  1731   show ?case unfolding power_Suc fps_mult_nth
  1732     using Suc.hyps[OF \<open>a$0 = 1\<close>] \<open>a$0 = 1\<close> fps_power_zeroth_eq_one[OF \<open>a$0=1\<close>]
  1733     by (simp add: field_simps)
  1734 qed
  1735 
  1736 lemma startsby_one_power:"a $ 0 = (1::'a::comm_ring_1) \<Longrightarrow> a^n $ 0 = 1"
  1737   by (induct n) (auto simp add: fps_mult_nth)
  1738 
  1739 lemma startsby_zero_power:"a $0 = (0::'a::comm_ring_1) \<Longrightarrow> n > 0 \<Longrightarrow> a^n $0 = 0"
  1740   by (induct n) (auto simp add: fps_mult_nth)
  1741 
  1742 lemma startsby_power:"a $0 = (v::'a::comm_ring_1) \<Longrightarrow> a^n $0 = v^n"
  1743   by (induct n) (auto simp add: fps_mult_nth)
  1744 
  1745 lemma startsby_zero_power_iff[simp]: "a^n $0 = (0::'a::idom) \<longleftrightarrow> n \<noteq> 0 \<and> a$0 = 0"
  1746   apply (rule iffI)
  1747   apply (induct n)
  1748   apply (auto simp add: fps_mult_nth)
  1749   apply (rule startsby_zero_power, simp_all)
  1750   done
  1751 
  1752 lemma startsby_zero_power_prefix:
  1753   assumes a0: "a $ 0 = (0::'a::idom)"
  1754   shows "\<forall>n < k. a ^ k $ n = 0"
  1755   using a0
  1756 proof (induct k rule: nat_less_induct)
  1757   fix k
  1758   assume H: "\<forall>m<k. a $0 =  0 \<longrightarrow> (\<forall>n<m. a ^ m $ n = 0)" and a0: "a $ 0 = 0"
  1759   show "\<forall>m<k. a ^ k $ m = 0"
  1760   proof (cases k)
  1761     case 0
  1762     then show ?thesis by simp
  1763   next
  1764     case (Suc l)
  1765     have "a^k $ m = 0" if mk: "m < k" for m
  1766     proof (cases "m = 0")
  1767       case True
  1768       then show ?thesis
  1769         using startsby_zero_power[of a k] Suc a0 by simp
  1770     next
  1771       case False
  1772       have "a ^k $ m = (a^l * a) $m"
  1773         by (simp add: Suc mult.commute)
  1774       also have "\<dots> = (\<Sum>i = 0..m. a ^ l $ i * a $ (m - i))"
  1775         by (simp add: fps_mult_nth)
  1776       also have "\<dots> = 0"
  1777         apply (rule sum.neutral)
  1778         apply auto
  1779         apply (case_tac "x = m")
  1780         using a0 apply simp
  1781         apply (rule H[rule_format])
  1782         using a0 Suc mk apply auto
  1783         done
  1784       finally show ?thesis .
  1785     qed
  1786     then show ?thesis by blast
  1787   qed
  1788 qed
  1789 
  1790 lemma startsby_zero_sum_depends:
  1791   assumes a0: "a $0 = (0::'a::idom)"
  1792     and kn: "n \<ge> k"
  1793   shows "sum (\<lambda>i. (a ^ i)$k) {0 .. n} = sum (\<lambda>i. (a ^ i)$k) {0 .. k}"
  1794   apply (rule sum.mono_neutral_right)
  1795   using kn
  1796   apply auto
  1797   apply (rule startsby_zero_power_prefix[rule_format, OF a0])
  1798   apply arith
  1799   done
  1800 
  1801 lemma startsby_zero_power_nth_same:
  1802   assumes a0: "a$0 = (0::'a::idom)"
  1803   shows "a^n $ n = (a$1) ^ n"
  1804 proof (induct n)
  1805   case 0
  1806   then show ?case by simp
  1807 next
  1808   case (Suc n)
  1809   have "a ^ Suc n $ (Suc n) = (a^n * a)$(Suc n)"
  1810     by (simp add: field_simps)
  1811   also have "\<dots> = sum (\<lambda>i. a^n$i * a $ (Suc n - i)) {0.. Suc n}"
  1812     by (simp add: fps_mult_nth)
  1813   also have "\<dots> = sum (\<lambda>i. a^n$i * a $ (Suc n - i)) {n .. Suc n}"
  1814     apply (rule sum.mono_neutral_right)
  1815     apply simp
  1816     apply clarsimp
  1817     apply clarsimp
  1818     apply (rule startsby_zero_power_prefix[rule_format, OF a0])
  1819     apply arith
  1820     done
  1821   also have "\<dots> = a^n $ n * a$1"
  1822     using a0 by simp
  1823   finally show ?case
  1824     using Suc.hyps by simp
  1825 qed
  1826 
  1827 lemma fps_inverse_power:
  1828   fixes a :: "'a::field fps"
  1829   shows "inverse (a^n) = inverse a ^ n"
  1830   by (induction n) (simp_all add: fps_inverse_mult)
  1831 
  1832 lemma fps_deriv_power:
  1833   "fps_deriv (a ^ n) = fps_const (of_nat n :: 'a::comm_ring_1) * fps_deriv a * a ^ (n - 1)"
  1834   apply (induct n)
  1835   apply (auto simp add: field_simps fps_const_add[symmetric] simp del: fps_const_add)
  1836   apply (case_tac n)
  1837   apply (auto simp add: field_simps)
  1838   done
  1839 
  1840 lemma fps_inverse_deriv:
  1841   fixes a :: "'a::field fps"
  1842   assumes a0: "a$0 \<noteq> 0"
  1843   shows "fps_deriv (inverse a) = - fps_deriv a * (inverse a)\<^sup>2"
  1844 proof -
  1845   from inverse_mult_eq_1[OF a0]
  1846   have "fps_deriv (inverse a * a) = 0" by simp
  1847   then have "inverse a * fps_deriv a + fps_deriv (inverse a) * a = 0"
  1848     by simp
  1849   then have "inverse a * (inverse a * fps_deriv a + fps_deriv (inverse a) * a) = 0"
  1850     by simp
  1851   with inverse_mult_eq_1[OF a0]
  1852   have "(inverse a)\<^sup>2 * fps_deriv a + fps_deriv (inverse a) = 0"
  1853     unfolding power2_eq_square
  1854     apply (simp add: field_simps)
  1855     apply (simp add: mult.assoc[symmetric])
  1856     done
  1857   then have "(inverse a)\<^sup>2 * fps_deriv a + fps_deriv (inverse a) - fps_deriv a * (inverse a)\<^sup>2 =
  1858       0 - fps_deriv a * (inverse a)\<^sup>2"
  1859     by simp
  1860   then show "fps_deriv (inverse a) = - fps_deriv a * (inverse a)\<^sup>2"
  1861     by (simp add: field_simps)
  1862 qed
  1863 
  1864 lemma fps_inverse_deriv':
  1865   fixes a :: "'a::field fps"
  1866   assumes a0: "a $ 0 \<noteq> 0"
  1867   shows "fps_deriv (inverse a) = - fps_deriv a / a\<^sup>2"
  1868   using fps_inverse_deriv[OF a0] a0
  1869   by (simp add: fps_divide_unit power2_eq_square fps_inverse_mult)
  1870 
  1871 lemma inverse_mult_eq_1':
  1872   assumes f0: "f$0 \<noteq> (0::'a::field)"
  1873   shows "f * inverse f = 1"
  1874   by (metis mult.commute inverse_mult_eq_1 f0)
  1875 
  1876 lemma fps_inverse_minus [simp]: "inverse (-f) = -inverse (f :: 'a :: field fps)"
  1877   by (cases "f$0 = 0") (auto intro: fps_inverse_unique simp: inverse_mult_eq_1' fps_inverse_eq_0)
  1878   
  1879 lemma divide_fps_const [simp]: "f / fps_const (c :: 'a :: field) = fps_const (inverse c) * f"
  1880   by (cases "c = 0") (simp_all add: fps_divide_unit fps_const_inverse)
  1881 
  1882 (* FIXME: The last part of this proof should go through by simp once we have a proper
  1883    theorem collection for simplifying division on rings *)
  1884 lemma fps_divide_deriv:
  1885   assumes "b dvd (a :: 'a :: field fps)"
  1886   shows   "fps_deriv (a / b) = (fps_deriv a * b - a * fps_deriv b) / b^2"
  1887 proof -
  1888   have eq_divide_imp: "c \<noteq> 0 \<Longrightarrow> a * c = b \<Longrightarrow> a = b div c" for a b c :: "'a :: field fps"
  1889     by (drule sym) (simp add: mult.assoc)
  1890   from assms have "a = a / b * b" by simp
  1891   also have "fps_deriv (a / b * b) = fps_deriv (a / b) * b + a / b * fps_deriv b" by simp
  1892   finally have "fps_deriv (a / b) * b^2 = fps_deriv a * b - a * fps_deriv b" using assms
  1893     by (simp add: power2_eq_square algebra_simps)
  1894   thus ?thesis by (cases "b = 0") (auto simp: eq_divide_imp)
  1895 qed
  1896 
  1897 lemma fps_inverse_gp': "inverse (Abs_fps (\<lambda>n. 1::'a::field)) = 1 - X"
  1898   by (simp add: fps_inverse_gp fps_eq_iff X_def)
  1899 
  1900 lemma fps_one_over_one_minus_X_squared:
  1901   "inverse ((1 - X)^2 :: 'a :: field fps) = Abs_fps (\<lambda>n. of_nat (n+1))"
  1902 proof -
  1903   have "inverse ((1 - X)^2 :: 'a fps) = fps_deriv (inverse (1 - X))"
  1904     by (subst fps_inverse_deriv) (simp_all add: fps_inverse_power)
  1905   also have "inverse (1 - X :: 'a fps) = Abs_fps (\<lambda>_. 1)"
  1906     by (subst fps_inverse_gp' [symmetric]) simp
  1907   also have "fps_deriv \<dots> = Abs_fps (\<lambda>n. of_nat (n + 1))"
  1908     by (simp add: fps_deriv_def)
  1909   finally show ?thesis .
  1910 qed
  1911 
  1912 lemma fps_nth_deriv_X[simp]: "fps_nth_deriv n X = (if n = 0 then X else if n=1 then 1 else 0)"
  1913   by (cases n) simp_all
  1914 
  1915 lemma fps_inverse_X_plus1: "inverse (1 + X) = Abs_fps (\<lambda>n. (- (1::'a::field)) ^ n)"
  1916   (is "_ = ?r")
  1917 proof -
  1918   have eq: "(1 + X) * ?r = 1"
  1919     unfolding minus_one_power_iff
  1920     by (auto simp add: field_simps fps_eq_iff)
  1921   show ?thesis
  1922     by (auto simp add: eq intro: fps_inverse_unique)
  1923 qed
  1924 
  1925 
  1926 subsection \<open>Integration\<close>
  1927 
  1928 definition fps_integral :: "'a::field_char_0 fps \<Rightarrow> 'a \<Rightarrow> 'a fps"
  1929   where "fps_integral a a0 = Abs_fps (\<lambda>n. if n = 0 then a0 else (a$(n - 1) / of_nat n))"
  1930 
  1931 lemma fps_deriv_fps_integral: "fps_deriv (fps_integral a a0) = a"
  1932   unfolding fps_integral_def fps_deriv_def
  1933   by (simp add: fps_eq_iff del: of_nat_Suc)
  1934 
  1935 lemma fps_integral_linear:
  1936   "fps_integral (fps_const a * f + fps_const b * g) (a*a0 + b*b0) =
  1937     fps_const a * fps_integral f a0 + fps_const b * fps_integral g b0"
  1938   (is "?l = ?r")
  1939 proof -
  1940   have "fps_deriv ?l = fps_deriv ?r"
  1941     by (simp add: fps_deriv_fps_integral)
  1942   moreover have "?l$0 = ?r$0"
  1943     by (simp add: fps_integral_def)
  1944   ultimately show ?thesis
  1945     unfolding fps_deriv_eq_iff by auto
  1946 qed
  1947 
  1948 
  1949 subsection \<open>Composition of FPSs\<close>
  1950 
  1951 definition fps_compose :: "'a::semiring_1 fps \<Rightarrow> 'a fps \<Rightarrow> 'a fps"  (infixl "oo" 55)
  1952   where "a oo b = Abs_fps (\<lambda>n. sum (\<lambda>i. a$i * (b^i$n)) {0..n})"
  1953 
  1954 lemma fps_compose_nth: "(a oo b)$n = sum (\<lambda>i. a$i * (b^i$n)) {0..n}"
  1955   by (simp add: fps_compose_def)
  1956 
  1957 lemma fps_compose_nth_0 [simp]: "(f oo g) $ 0 = f $ 0"
  1958   by (simp add: fps_compose_nth)
  1959 
  1960 lemma fps_compose_X[simp]: "a oo X = (a :: 'a::comm_ring_1 fps)"
  1961   by (simp add: fps_ext fps_compose_def mult_delta_right sum.delta')
  1962 
  1963 lemma fps_const_compose[simp]: "fps_const (a::'a::comm_ring_1) oo b = fps_const a"
  1964   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left sum.delta)
  1965 
  1966 lemma numeral_compose[simp]: "(numeral k :: 'a::comm_ring_1 fps) oo b = numeral k"
  1967   unfolding numeral_fps_const by simp
  1968 
  1969 lemma neg_numeral_compose[simp]: "(- numeral k :: 'a::comm_ring_1 fps) oo b = - numeral k"
  1970   unfolding neg_numeral_fps_const by simp
  1971 
  1972 lemma X_fps_compose_startby0[simp]: "a$0 = 0 \<Longrightarrow> X oo a = (a :: 'a::comm_ring_1 fps)"
  1973   by (simp add: fps_eq_iff fps_compose_def mult_delta_left sum.delta not_le)
  1974 
  1975 
  1976 subsection \<open>Rules from Herbert Wilf's Generatingfunctionology\<close>
  1977 
  1978 subsubsection \<open>Rule 1\<close>
  1979   (* {a_{n+k}}_0^infty Corresponds to (f - sum (\<lambda>i. a_i * x^i))/x^h, for h>0*)
  1980 
  1981 lemma fps_power_mult_eq_shift:
  1982   "X^Suc k * Abs_fps (\<lambda>n. a (n + Suc k)) =
  1983     Abs_fps a - sum (\<lambda>i. fps_const (a i :: 'a::comm_ring_1) * X^i) {0 .. k}"
  1984   (is "?lhs = ?rhs")
  1985 proof -
  1986   have "?lhs $ n = ?rhs $ n" for n :: nat
  1987   proof -
  1988     have "?lhs $ n = (if n < Suc k then 0 else a n)"
  1989       unfolding X_power_mult_nth by auto
  1990     also have "\<dots> = ?rhs $ n"
  1991     proof (induct k)
  1992       case 0
  1993       then show ?case
  1994         by (simp add: fps_sum_nth)
  1995     next
  1996       case (Suc k)
  1997       have "(Abs_fps a - sum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. Suc k})$n =
  1998         (Abs_fps a - sum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. k} -
  1999           fps_const (a (Suc k)) * X^ Suc k) $ n"
  2000         by (simp add: field_simps)
  2001       also have "\<dots> = (if n < Suc k then 0 else a n) - (fps_const (a (Suc k)) * X^ Suc k)$n"
  2002         using Suc.hyps[symmetric] unfolding fps_sub_nth by simp
  2003       also have "\<dots> = (if n < Suc (Suc k) then 0 else a n)"
  2004         unfolding X_power_mult_right_nth
  2005         apply (auto simp add: not_less fps_const_def)
  2006         apply (rule cong[of a a, OF refl])
  2007         apply arith
  2008         done
  2009       finally show ?case
  2010         by simp
  2011     qed
  2012     finally show ?thesis .
  2013   qed
  2014   then show ?thesis
  2015     by (simp add: fps_eq_iff)
  2016 qed
  2017 
  2018 
  2019 subsubsection \<open>Rule 2\<close>
  2020 
  2021   (* We can not reach the form of Wilf, but still near to it using rewrite rules*)
  2022   (* If f reprents {a_n} and P is a polynomial, then
  2023         P(xD) f represents {P(n) a_n}*)
  2024 
  2025 definition "XD = op * X \<circ> fps_deriv"
  2026 
  2027 lemma XD_add[simp]:"XD (a + b) = XD a + XD (b :: 'a::comm_ring_1 fps)"
  2028   by (simp add: XD_def field_simps)
  2029 
  2030 lemma XD_mult_const[simp]:"XD (fps_const (c::'a::comm_ring_1) * a) = fps_const c * XD a"
  2031   by (simp add: XD_def field_simps)
  2032 
  2033 lemma XD_linear[simp]: "XD (fps_const c * a + fps_const d * b) =
  2034     fps_const c * XD a + fps_const d * XD (b :: 'a::comm_ring_1 fps)"
  2035   by simp
  2036 
  2037 lemma XDN_linear:
  2038   "(XD ^^ n) (fps_const c * a + fps_const d * b) =
  2039     fps_const c * (XD ^^ n) a + fps_const d * (XD ^^ n) (b :: 'a::comm_ring_1 fps)"
  2040   by (induct n) simp_all
  2041 
  2042 lemma fps_mult_X_deriv_shift: "X* fps_deriv a = Abs_fps (\<lambda>n. of_nat n* a$n)"
  2043   by (simp add: fps_eq_iff)
  2044 
  2045 lemma fps_mult_XD_shift:
  2046   "(XD ^^ k) (a :: 'a::comm_ring_1 fps) = Abs_fps (\<lambda>n. (of_nat n ^ k) * a$n)"
  2047   by (induct k arbitrary: a) (simp_all add: XD_def fps_eq_iff field_simps del: One_nat_def)
  2048 
  2049 
  2050 subsubsection \<open>Rule 3\<close>
  2051 
  2052 text \<open>Rule 3 is trivial and is given by \<open>fps_times_def\<close>.\<close>
  2053 
  2054 
  2055 subsubsection \<open>Rule 5 --- summation and "division" by (1 - X)\<close>
  2056 
  2057 lemma fps_divide_X_minus1_sum_lemma:
  2058   "a = ((1::'a::comm_ring_1 fps) - X) * Abs_fps (\<lambda>n. sum (\<lambda>i. a $ i) {0..n})"
  2059 proof -
  2060   let ?sa = "Abs_fps (\<lambda>n. sum (\<lambda>i. a $ i) {0..n})"
  2061   have th0: "\<And>i. (1 - (X::'a fps)) $ i = (if i = 0 then 1 else if i = 1 then - 1 else 0)"
  2062     by simp
  2063   have "a$n = ((1 - X) * ?sa) $ n" for n
  2064   proof (cases "n = 0")
  2065     case True
  2066     then show ?thesis
  2067       by (simp add: fps_mult_nth)
  2068   next
  2069     case False
  2070     then have u: "{0} \<union> ({1} \<union> {2..n}) = {0..n}" "{1} \<union> {2..n} = {1..n}"
  2071       "{0..n - 1} \<union> {n} = {0..n}"
  2072       by (auto simp: set_eq_iff)
  2073     have d: "{0} \<inter> ({1} \<union> {2..n}) = {}" "{1} \<inter> {2..n} = {}" "{0..n - 1} \<inter> {n} = {}"
  2074       using False by simp_all
  2075     have f: "finite {0}" "finite {1}" "finite {2 .. n}"
  2076       "finite {0 .. n - 1}" "finite {n}" by simp_all
  2077     have "((1 - X) * ?sa) $ n = sum (\<lambda>i. (1 - X)$ i * ?sa $ (n - i)) {0 .. n}"
  2078       by (simp add: fps_mult_nth)
  2079     also have "\<dots> = a$n"
  2080       unfolding th0
  2081       unfolding sum.union_disjoint[OF f(1) finite_UnI[OF f(2,3)] d(1), unfolded u(1)]
  2082       unfolding sum.union_disjoint[OF f(2) f(3) d(2)]
  2083       apply (simp)
  2084       unfolding sum.union_disjoint[OF f(4,5) d(3), unfolded u(3)]
  2085       apply simp
  2086       done
  2087     finally show ?thesis
  2088       by simp
  2089   qed
  2090   then show ?thesis
  2091     unfolding fps_eq_iff by blast
  2092 qed
  2093 
  2094 lemma fps_divide_X_minus1_sum:
  2095   "a /((1::'a::field fps) - X) = Abs_fps (\<lambda>n. sum (\<lambda>i. a $ i) {0..n})"
  2096 proof -
  2097   let ?X = "1 - (X::'a fps)"
  2098   have th0: "?X $ 0 \<noteq> 0"
  2099     by simp
  2100   have "a /?X = ?X *  Abs_fps (\<lambda>n::nat. sum (op $ a) {0..n}) * inverse ?X"
  2101     using fps_divide_X_minus1_sum_lemma[of a, symmetric] th0
  2102     by (simp add: fps_divide_def mult.assoc)
  2103   also have "\<dots> = (inverse ?X * ?X) * Abs_fps (\<lambda>n::nat. sum (op $ a) {0..n}) "
  2104     by (simp add: ac_simps)
  2105   finally show ?thesis
  2106     by (simp add: inverse_mult_eq_1[OF th0])
  2107 qed
  2108 
  2109 
  2110 subsubsection \<open>Rule 4 in its more general form: generalizes Rule 3 for an arbitrary
  2111   finite product of FPS, also the relvant instance of powers of a FPS\<close>
  2112 
  2113 definition "natpermute n k = {l :: nat list. length l = k \<and> sum_list l = n}"
  2114 
  2115 lemma natlist_trivial_1: "natpermute n 1 = {[n]}"
  2116   apply (auto simp add: natpermute_def)
  2117   apply (case_tac x)
  2118   apply auto
  2119   done
  2120 
  2121 lemma append_natpermute_less_eq:
  2122   assumes "xs @ ys \<in> natpermute n k"
  2123   shows "sum_list xs \<le> n"
  2124     and "sum_list ys \<le> n"
  2125 proof -
  2126   from assms have "sum_list (xs @ ys) = n"
  2127     by (simp add: natpermute_def)
  2128   then have "sum_list xs + sum_list ys = n"
  2129     by simp
  2130   then show "sum_list xs \<le> n" and "sum_list ys \<le> n"
  2131     by simp_all
  2132 qed
  2133 
  2134 lemma natpermute_split:
  2135   assumes "h \<le> k"
  2136   shows "natpermute n k =
  2137     (\<Union>m \<in>{0..n}. {l1 @ l2 |l1 l2. l1 \<in> natpermute m h \<and> l2 \<in> natpermute (n - m) (k - h)})"
  2138   (is "?L = ?R" is "_ = (\<Union>m \<in>{0..n}. ?S m)")
  2139 proof
  2140   show "?R \<subseteq> ?L"
  2141   proof
  2142     fix l
  2143     assume l: "l \<in> ?R"
  2144     from l obtain m xs ys where h: "m \<in> {0..n}"
  2145       and xs: "xs \<in> natpermute m h"
  2146       and ys: "ys \<in> natpermute (n - m) (k - h)"
  2147       and leq: "l = xs@ys" by blast
  2148     from xs have xs': "sum_list xs = m"
  2149       by (simp add: natpermute_def)
  2150     from ys have ys': "sum_list ys = n - m"
  2151       by (simp add: natpermute_def)
  2152     show "l \<in> ?L" using leq xs ys h
  2153       apply (clarsimp simp add: natpermute_def)
  2154       unfolding xs' ys'
  2155       using assms xs ys
  2156       unfolding natpermute_def
  2157       apply simp
  2158       done
  2159   qed
  2160   show "?L \<subseteq> ?R"
  2161   proof
  2162     fix l
  2163     assume l: "l \<in> natpermute n k"
  2164     let ?xs = "take h l"
  2165     let ?ys = "drop h l"
  2166     let ?m = "sum_list ?xs"
  2167     from l have ls: "sum_list (?xs @ ?ys) = n"
  2168       by (simp add: natpermute_def)
  2169     have xs: "?xs \<in> natpermute ?m h" using l assms
  2170       by (simp add: natpermute_def)
  2171     have l_take_drop: "sum_list l = sum_list (take h l @ drop h l)"
  2172       by simp
  2173     then have ys: "?ys \<in> natpermute (n - ?m) (k - h)"
  2174       using l assms ls by (auto simp add: natpermute_def simp del: append_take_drop_id)
  2175     from ls have m: "?m \<in> {0..n}"
  2176       by (simp add: l_take_drop del: append_take_drop_id)
  2177     from xs ys ls show "l \<in> ?R"
  2178       apply auto
  2179       apply (rule bexI [where x = "?m"])
  2180       apply (rule exI [where x = "?xs"])
  2181       apply (rule exI [where x = "?ys"])
  2182       using ls l
  2183       apply (auto simp add: natpermute_def l_take_drop simp del: append_take_drop_id)
  2184       apply simp
  2185       done
  2186   qed
  2187 qed
  2188 
  2189 lemma natpermute_0: "natpermute n 0 = (if n = 0 then {[]} else {})"
  2190   by (auto simp add: natpermute_def)
  2191 
  2192 lemma natpermute_0'[simp]: "natpermute 0 k = (if k = 0 then {[]} else {replicate k 0})"
  2193   apply (auto simp add: set_replicate_conv_if natpermute_def)
  2194   apply (rule nth_equalityI)
  2195   apply simp_all
  2196   done
  2197 
  2198 lemma natpermute_finite: "finite (natpermute n k)"
  2199 proof (induct k arbitrary: n)
  2200   case 0
  2201   then show ?case
  2202     apply (subst natpermute_split[of 0 0, simplified])
  2203     apply (simp add: natpermute_0)
  2204     done
  2205 next
  2206   case (Suc k)
  2207   then show ?case unfolding natpermute_split [of k "Suc k", simplified]
  2208     apply -
  2209     apply (rule finite_UN_I)
  2210     apply simp
  2211     unfolding One_nat_def[symmetric] natlist_trivial_1
  2212     apply simp
  2213     done
  2214 qed
  2215 
  2216 lemma natpermute_contain_maximal:
  2217   "{xs \<in> natpermute n (k + 1). n \<in> set xs} = (\<Union>i\<in>{0 .. k}. {(replicate (k + 1) 0) [i:=n]})"
  2218   (is "?A = ?B")
  2219 proof
  2220   show "?A \<subseteq> ?B"
  2221   proof
  2222     fix xs
  2223     assume "xs \<in> ?A"
  2224     then have H: "xs \<in> natpermute n (k + 1)" and n: "n \<in> set xs"
  2225       by blast+
  2226     then obtain i where i: "i \<in> {0.. k}" "xs!i = n"
  2227       unfolding in_set_conv_nth by (auto simp add: less_Suc_eq_le natpermute_def)
  2228     have eqs: "({0..k} - {i}) \<union> {i} = {0..k}"
  2229       using i by auto
  2230     have f: "finite({0..k} - {i})" "finite {i}"
  2231       by auto
  2232     have d: "({0..k} - {i}) \<inter> {i} = {}"
  2233       using i by auto
  2234     from H have "n = sum (nth xs) {0..k}"
  2235       apply (simp add: natpermute_def)
  2236       apply (auto simp add: atLeastLessThanSuc_atLeastAtMost sum_list_sum_nth)
  2237       done
  2238     also have "\<dots> = n + sum (nth xs) ({0..k} - {i})"
  2239       unfolding sum.union_disjoint[OF f d, unfolded eqs] using i by simp
  2240     finally have zxs: "\<forall> j\<in> {0..k} - {i}. xs!j = 0"
  2241       by auto
  2242     from H have xsl: "length xs = k+1"
  2243       by (simp add: natpermute_def)
  2244     from i have i': "i < length (replicate (k+1) 0)"   "i < k+1"
  2245       unfolding length_replicate by presburger+
  2246     have "xs = replicate (k+1) 0 [i := n]"
  2247       apply (rule nth_equalityI)
  2248       unfolding xsl length_list_update length_replicate
  2249       apply simp
  2250       apply clarify
  2251       unfolding nth_list_update[OF i'(1)]
  2252       using i zxs
  2253       apply (case_tac "ia = i")
  2254       apply (auto simp del: replicate.simps)
  2255       done
  2256     then show "xs \<in> ?B" using i by blast
  2257   qed
  2258   show "?B \<subseteq> ?A"
  2259   proof
  2260     fix xs
  2261     assume "xs \<in> ?B"
  2262     then obtain i where i: "i \<in> {0..k}" and xs: "xs = replicate (k + 1) 0 [i:=n]"
  2263       by auto
  2264     have nxs: "n \<in> set xs"
  2265       unfolding xs
  2266       apply (rule set_update_memI)
  2267       using i apply simp
  2268       done
  2269     have xsl: "length xs = k + 1"
  2270       by (simp only: xs length_replicate length_list_update)
  2271     have "sum_list xs = sum (nth xs) {0..<k+1}"
  2272       unfolding sum_list_sum_nth xsl ..
  2273     also have "\<dots> = sum (\<lambda>j. if j = i then n else 0) {0..< k+1}"
  2274       by (rule sum.cong) (simp_all add: xs del: replicate.simps)
  2275     also have "\<dots> = n" using i by (simp add: sum.delta)
  2276     finally have "xs \<in> natpermute n (k + 1)"
  2277       using xsl unfolding natpermute_def mem_Collect_eq by blast
  2278     then show "xs \<in> ?A"
  2279       using nxs by blast
  2280   qed
  2281 qed
  2282 
  2283 text \<open>The general form.\<close>
  2284 lemma fps_prod_nth:
  2285   fixes m :: nat
  2286     and a :: "nat \<Rightarrow> 'a::comm_ring_1 fps"
  2287   shows "(prod a {0 .. m}) $ n =
  2288     sum (\<lambda>v. prod (\<lambda>j. (a j) $ (v!j)) {0..m}) (natpermute n (m+1))"
  2289   (is "?P m n")
  2290 proof (induct m arbitrary: n rule: nat_less_induct)
  2291   fix m n assume H: "\<forall>m' < m. \<forall>n. ?P m' n"
  2292   show "?P m n"
  2293   proof (cases m)
  2294     case 0
  2295     then show ?thesis
  2296       apply simp
  2297       unfolding natlist_trivial_1[where n = n, unfolded One_nat_def]
  2298       apply simp
  2299       done
  2300   next
  2301     case (Suc k)
  2302     then have km: "k < m" by arith
  2303     have u0: "{0 .. k} \<union> {m} = {0..m}"
  2304       using Suc by (simp add: set_eq_iff) presburger
  2305     have f0: "finite {0 .. k}" "finite {m}" by auto
  2306     have d0: "{0 .. k} \<inter> {m} = {}" using Suc by auto
  2307     have "(prod a {0 .. m}) $ n = (prod a {0 .. k} * a m) $ n"
  2308       unfolding prod.union_disjoint[OF f0 d0, unfolded u0] by simp
  2309     also have "\<dots> = (\<Sum>i = 0..n. (\<Sum>v\<in>natpermute i (k + 1). \<Prod>j\<in>{0..k}. a j $ v ! j) * a m $ (n - i))"
  2310       unfolding fps_mult_nth H[rule_format, OF km] ..
  2311     also have "\<dots> = (\<Sum>v\<in>natpermute n (m + 1). \<Prod>j\<in>{0..m}. a j $ v ! j)"
  2312       apply (simp add: Suc)
  2313       unfolding natpermute_split[of m "m + 1", simplified, of n,
  2314         unfolded natlist_trivial_1[unfolded One_nat_def] Suc]
  2315       apply (subst sum.UNION_disjoint)
  2316       apply simp
  2317       apply simp
  2318       unfolding image_Collect[symmetric]
  2319       apply clarsimp
  2320       apply (rule finite_imageI)
  2321       apply (rule natpermute_finite)
  2322       apply (clarsimp simp add: set_eq_iff)
  2323       apply auto
  2324       apply (rule sum.cong)
  2325       apply (rule refl)
  2326       unfolding sum_distrib_right
  2327       apply (rule sym)
  2328       apply (rule_tac l = "\<lambda>xs. xs @ [n - x]" in sum.reindex_cong)
  2329       apply (simp add: inj_on_def)
  2330       apply auto
  2331       unfolding prod.union_disjoint[OF f0 d0, unfolded u0, unfolded Suc]
  2332       apply (clarsimp simp add: natpermute_def nth_append)
  2333       done
  2334     finally show ?thesis .
  2335   qed
  2336 qed
  2337 
  2338 text \<open>The special form for powers.\<close>
  2339 lemma fps_power_nth_Suc:
  2340   fixes m :: nat
  2341     and a :: "'a::comm_ring_1 fps"
  2342   shows "(a ^ Suc m)$n = sum (\<lambda>v. prod (\<lambda>j. a $ (v!j)) {0..m}) (natpermute n (m+1))"
  2343 proof -
  2344   have th0: "a^Suc m = prod (\<lambda>i. a) {0..m}"
  2345     by (simp add: prod_constant)
  2346   show ?thesis unfolding th0 fps_prod_nth ..
  2347 qed
  2348 
  2349 lemma fps_power_nth:
  2350   fixes m :: nat
  2351     and a :: "'a::comm_ring_1 fps"
  2352   shows "(a ^m)$n =
  2353     (if m=0 then 1$n else sum (\<lambda>v. prod (\<lambda>j. a $ (v!j)) {0..m - 1}) (natpermute n m))"
  2354   by (cases m) (simp_all add: fps_power_nth_Suc del: power_Suc)
  2355 
  2356 lemma fps_nth_power_0:
  2357   fixes m :: nat
  2358     and a :: "'a::comm_ring_1 fps"
  2359   shows "(a ^m)$0 = (a$0) ^ m"
  2360 proof (cases m)
  2361   case 0
  2362   then show ?thesis by simp
  2363 next
  2364   case (Suc n)
  2365   then have c: "m = card {0..n}" by simp
  2366   have "(a ^m)$0 = prod (\<lambda>i. a$0) {0..n}"
  2367     by (simp add: Suc fps_power_nth del: replicate.simps power_Suc)
  2368   also have "\<dots> = (a$0) ^ m"
  2369    unfolding c by (rule prod_constant)
  2370  finally show ?thesis .
  2371 qed
  2372 
  2373 lemma natpermute_max_card:
  2374   assumes n0: "n \<noteq> 0"
  2375   shows "card {xs \<in> natpermute n (k + 1). n \<in> set xs} = k + 1"
  2376   unfolding natpermute_contain_maximal
  2377 proof -
  2378   let ?A = "\<lambda>i. {replicate (k + 1) 0[i := n]}"
  2379   let ?K = "{0 ..k}"
  2380   have fK: "finite ?K"
  2381     by simp
  2382   have fAK: "\<forall>i\<in>?K. finite (?A i)"
  2383     by auto
  2384   have d: "\<forall>i\<in> ?K. \<forall>j\<in> ?K. i \<noteq> j \<longrightarrow>
  2385     {replicate (k + 1) 0[i := n]} \<inter> {replicate (k + 1) 0[j := n]} = {}"
  2386   proof clarify
  2387     fix i j
  2388     assume i: "i \<in> ?K" and j: "j \<in> ?K" and ij: "i \<noteq> j"
  2389     have False if eq: "replicate (k+1) 0 [i:=n] = replicate (k+1) 0 [j:= n]"
  2390     proof -
  2391       have "(replicate (k+1) 0 [i:=n] ! i) = n"
  2392         using i by (simp del: replicate.simps)
  2393       moreover
  2394       have "(replicate (k+1) 0 [j:=n] ! i) = 0"
  2395         using i ij by (simp del: replicate.simps)
  2396       ultimately show ?thesis
  2397         using eq n0 by (simp del: replicate.simps)
  2398     qed
  2399     then show "{replicate (k + 1) 0[i := n]} \<inter> {replicate (k + 1) 0[j := n]} = {}"
  2400       by auto
  2401   qed
  2402   from card_UN_disjoint[OF fK fAK d]
  2403   show "card (\<Union>i\<in>{0..k}. {replicate (k + 1) 0[i := n]}) = k + 1"
  2404     by simp
  2405 qed
  2406 
  2407 lemma fps_power_Suc_nth:
  2408   fixes f :: "'a :: comm_ring_1 fps"
  2409   assumes k: "k > 0"
  2410   shows "(f ^ Suc m) $ k = 
  2411            of_nat (Suc m) * (f $ k * (f $ 0) ^ m) +
  2412            (\<Sum>v\<in>{v\<in>natpermute k (m+1). k \<notin> set v}. \<Prod>j = 0..m. f $ v ! j)"
  2413 proof -
  2414   define A B 
  2415     where "A = {v\<in>natpermute k (m+1). k \<in> set v}" 
  2416       and  "B = {v\<in>natpermute k (m+1). k \<notin> set v}"
  2417   have [simp]: "finite A" "finite B" "A \<inter> B = {}" by (auto simp: A_def B_def natpermute_finite)
  2418 
  2419   from natpermute_max_card[of k m] k have card_A: "card A = m + 1" by (simp add: A_def)
  2420   {
  2421     fix v assume v: "v \<in> A"
  2422     from v have [simp]: "length v = Suc m" by (simp add: A_def natpermute_def)
  2423     from v have "\<exists>j. j \<le> m \<and> v ! j = k" 
  2424       by (auto simp: set_conv_nth A_def natpermute_def less_Suc_eq_le)
  2425     then guess j by (elim exE conjE) note j = this
  2426     
  2427     from v have "k = sum_list v" by (simp add: A_def natpermute_def)
  2428     also have "\<dots> = (\<Sum>i=0..m. v ! i)"
  2429       by (simp add: sum_list_sum_nth atLeastLessThanSuc_atLeastAtMost del: sum_op_ivl_Suc)
  2430     also from j have "{0..m} = insert j ({0..m}-{j})" by auto
  2431     also from j have "(\<Sum>i\<in>\<dots>. v ! i) = k + (\<Sum>i\<in>{0..m}-{j}. v ! i)"
  2432       by (subst sum.insert) simp_all
  2433     finally have "(\<Sum>i\<in>{0..m}-{j}. v ! i) = 0" by simp
  2434     hence zero: "v ! i = 0" if "i \<in> {0..m}-{j}" for i using that
  2435       by (subst (asm) sum_eq_0_iff) auto
  2436       
  2437     from j have "{0..m} = insert j ({0..m} - {j})" by auto
  2438     also from j have "(\<Prod>i\<in>\<dots>. f $ (v ! i)) = f $ k * (\<Prod>i\<in>{0..m} - {j}. f $ (v ! i))"
  2439       by (subst prod.insert) auto
  2440     also have "(\<Prod>i\<in>{0..m} - {j}. f $ (v ! i)) = (\<Prod>i\<in>{0..m} - {j}. f $ 0)"
  2441       by (intro prod.cong) (simp_all add: zero)
  2442     also from j have "\<dots> = (f $ 0) ^ m" by (subst prod_constant) simp_all
  2443     finally have "(\<Prod>j = 0..m. f $ (v ! j)) = f $ k * (f $ 0) ^ m" .
  2444   } note A = this
  2445   
  2446   have "(f ^ Suc m) $ k = (\<Sum>v\<in>natpermute k (m + 1). \<Prod>j = 0..m. f $ v ! j)"
  2447     by (rule fps_power_nth_Suc)
  2448   also have "natpermute k (m+1) = A \<union> B" unfolding A_def B_def by blast
  2449   also have "(\<Sum>v\<in>\<dots>. \<Prod>j = 0..m. f $ (v ! j)) = 
  2450                (\<Sum>v\<in>A. \<Prod>j = 0..m. f $ (v ! j)) + (\<Sum>v\<in>B. \<Prod>j = 0..m. f $ (v ! j))"
  2451     by (intro sum.union_disjoint) simp_all   
  2452   also have "(\<Sum>v\<in>A. \<Prod>j = 0..m. f $ (v ! j)) = of_nat (Suc m) * (f $ k * (f $ 0) ^ m)"
  2453     by (simp add: A card_A)
  2454   finally show ?thesis by (simp add: B_def)
  2455 qed 
  2456   
  2457 lemma fps_power_Suc_eqD:
  2458   fixes f g :: "'a :: {idom,semiring_char_0} fps"
  2459   assumes "f ^ Suc m = g ^ Suc m" "f $ 0 = g $ 0" "f $ 0 \<noteq> 0"
  2460   shows   "f = g"
  2461 proof (rule fps_ext)
  2462   fix k :: nat
  2463   show "f $ k = g $ k"
  2464   proof (induction k rule: less_induct)
  2465     case (less k)
  2466     show ?case
  2467     proof (cases "k = 0")
  2468       case False
  2469       let ?h = "\<lambda>f. (\<Sum>v | v \<in> natpermute k (m + 1) \<and> k \<notin> set v. \<Prod>j = 0..m. f $ v ! j)"
  2470       from False fps_power_Suc_nth[of k f m] fps_power_Suc_nth[of k g m]
  2471         have "f $ k * (of_nat (Suc m) * (f $ 0) ^ m) + ?h f =
  2472                 g $ k * (of_nat (Suc m) * (f $ 0) ^ m) + ?h g" using assms 
  2473         by (simp add: mult_ac del: power_Suc of_nat_Suc)
  2474       also have "v ! i < k" if "v \<in> {v\<in>natpermute k (m+1). k \<notin> set v}" "i \<le> m" for v i
  2475         using that elem_le_sum_list_nat[of i v] unfolding natpermute_def
  2476         by (auto simp: set_conv_nth dest!: spec[of _ i])
  2477       hence "?h f = ?h g"
  2478         by (intro sum.cong refl prod.cong less lessI) (auto simp: natpermute_def)
  2479       finally have "f $ k * (of_nat (Suc m) * (f $ 0) ^ m) = g $ k * (of_nat (Suc m) * (f $ 0) ^ m)"
  2480         by simp
  2481       with assms show "f $ k = g $ k" 
  2482         by (subst (asm) mult_right_cancel) (auto simp del: of_nat_Suc)
  2483     qed (simp_all add: assms)
  2484   qed
  2485 qed
  2486 
  2487 lemma fps_power_Suc_eqD':
  2488   fixes f g :: "'a :: {idom,semiring_char_0} fps"
  2489   assumes "f ^ Suc m = g ^ Suc m" "f $ subdegree f = g $ subdegree g"
  2490   shows   "f = g"
  2491 proof (cases "f = 0")
  2492   case False
  2493   have "Suc m * subdegree f = subdegree (f ^ Suc m)"
  2494     by (rule subdegree_power [symmetric])
  2495   also have "f ^ Suc m = g ^ Suc m" by fact
  2496   also have "subdegree \<dots> = Suc m * subdegree g" by (rule subdegree_power)
  2497   finally have [simp]: "subdegree f = subdegree g"
  2498     by (subst (asm) Suc_mult_cancel1)
  2499   have "fps_shift (subdegree f) f * X ^ subdegree f = f"
  2500     by (rule subdegree_decompose [symmetric])
  2501   also have "\<dots> ^ Suc m = g ^ Suc m" by fact
  2502   also have "g = fps_shift (subdegree g) g * X ^ subdegree g"
  2503     by (rule subdegree_decompose)
  2504   also have "subdegree f = subdegree g" by fact
  2505   finally have "fps_shift (subdegree g) f ^ Suc m = fps_shift (subdegree g) g ^ Suc m"
  2506     by (simp add: algebra_simps power_mult_distrib del: power_Suc)
  2507   hence "fps_shift (subdegree g) f = fps_shift (subdegree g) g"
  2508     by (rule fps_power_Suc_eqD) (insert assms False, auto)
  2509   with subdegree_decompose[of f] subdegree_decompose[of g] show ?thesis by simp
  2510 qed (insert assms, simp_all)
  2511 
  2512 lemma fps_power_eqD':
  2513   fixes f g :: "'a :: {idom,semiring_char_0} fps"
  2514   assumes "f ^ m = g ^ m" "f $ subdegree f = g $ subdegree g" "m > 0"
  2515   shows   "f = g"
  2516   using fps_power_Suc_eqD'[of f "m-1" g] assms by simp
  2517 
  2518 lemma fps_power_eqD:
  2519   fixes f g :: "'a :: {idom,semiring_char_0} fps"
  2520   assumes "f ^ m = g ^ m" "f $ 0 = g $ 0" "f $ 0 \<noteq> 0" "m > 0"
  2521   shows   "f = g"
  2522   by (rule fps_power_eqD'[of f m g]) (insert assms, simp_all)
  2523 
  2524 lemma fps_compose_inj_right:
  2525   assumes a0: "a$0 = (0::'a::idom)"
  2526     and a1: "a$1 \<noteq> 0"
  2527   shows "(b oo a = c oo a) \<longleftrightarrow> b = c"
  2528   (is "?lhs \<longleftrightarrow>?rhs")
  2529 proof
  2530   show ?lhs if ?rhs using that by simp
  2531   show ?rhs if ?lhs
  2532   proof -
  2533     have "b$n = c$n" for n
  2534     proof (induct n rule: nat_less_induct)
  2535       fix n
  2536       assume H: "\<forall>m<n. b$m = c$m"
  2537       show "b$n = c$n"
  2538       proof (cases n)
  2539         case 0
  2540         from \<open>?lhs\<close> have "(b oo a)$n = (c oo a)$n"
  2541           by simp
  2542         then show ?thesis
  2543           using 0 by (simp add: fps_compose_nth)
  2544       next
  2545         case (Suc n1)
  2546         have f: "finite {0 .. n1}" "finite {n}" by simp_all
  2547         have eq: "{0 .. n1} \<union> {n} = {0 .. n}" using Suc by auto
  2548         have d: "{0 .. n1} \<inter> {n} = {}" using Suc by auto
  2549         have seq: "(\<Sum>i = 0..n1. b $ i * a ^ i $ n) = (\<Sum>i = 0..n1. c $ i * a ^ i $ n)"
  2550           apply (rule sum.cong)
  2551           using H Suc
  2552           apply auto
  2553           done
  2554         have th0: "(b oo a) $n = (\<Sum>i = 0..n1. c $ i * a ^ i $ n) + b$n * (a$1)^n"
  2555           unfolding fps_compose_nth sum.union_disjoint[OF f d, unfolded eq] seq
  2556           using startsby_zero_power_nth_same[OF a0]
  2557           by simp
  2558         have th1: "(c oo a) $n = (\<Sum>i = 0..n1. c $ i * a ^ i $ n) + c$n * (a$1)^n"
  2559           unfolding fps_compose_nth sum.union_disjoint[OF f d, unfolded eq]
  2560           using startsby_zero_power_nth_same[OF a0]
  2561           by simp
  2562         from \<open>?lhs\<close>[unfolded fps_eq_iff, rule_format, of n] th0 th1 a1
  2563         show ?thesis by auto
  2564       qed
  2565     qed
  2566     then show ?rhs by (simp add: fps_eq_iff)
  2567   qed
  2568 qed
  2569 
  2570 
  2571 subsection \<open>Radicals\<close>
  2572 
  2573 declare prod.cong [fundef_cong]
  2574 
  2575 function radical :: "(nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a::field fps \<Rightarrow> nat \<Rightarrow> 'a"
  2576 where
  2577   "radical r 0 a 0 = 1"
  2578 | "radical r 0 a (Suc n) = 0"
  2579 | "radical r (Suc k) a 0 = r (Suc k) (a$0)"
  2580 | "radical r (Suc k) a (Suc n) =
  2581     (a$ Suc n - sum (\<lambda>xs. prod (\<lambda>j. radical r (Suc k) a (xs ! j)) {0..k})
  2582       {xs. xs \<in> natpermute (Suc n) (Suc k) \<and> Suc n \<notin> set xs}) /
  2583     (of_nat (Suc k) * (radical r (Suc k) a 0)^k)"
  2584   by pat_completeness auto
  2585 
  2586 termination radical
  2587 proof
  2588   let ?R = "measure (\<lambda>(r, k, a, n). n)"
  2589   {
  2590     show "wf ?R" by auto
  2591   next
  2592     fix r k a n xs i
  2593     assume xs: "xs \<in> {xs \<in> natpermute (Suc n) (Suc k). Suc n \<notin> set xs}" and i: "i \<in> {0..k}"
  2594     have False if c: "Suc n \<le> xs ! i"
  2595     proof -
  2596       from xs i have "xs !i \<noteq> Suc n"
  2597         by (auto simp add: in_set_conv_nth natpermute_def)
  2598       with c have c': "Suc n < xs!i" by arith
  2599       have fths: "finite {0 ..< i}" "finite {i}" "finite {i+1..<Suc k}"
  2600         by simp_all
  2601       have d: "{0 ..< i} \<inter> ({i} \<union> {i+1 ..< Suc k}) = {}" "{i} \<inter> {i+1..< Suc k} = {}"
  2602         by auto
  2603       have eqs: "{0..<Suc k} = {0 ..< i} \<union> ({i} \<union> {i+1 ..< Suc k})"
  2604         using i by auto
  2605       from xs have "Suc n = sum_list xs"
  2606         by (simp add: natpermute_def)
  2607       also have "\<dots> = sum (nth xs) {0..<Suc k}" using xs
  2608         by (simp add: natpermute_def sum_list_sum_nth)
  2609       also have "\<dots> = xs!i + sum (nth xs) {0..<i} + sum (nth xs) {i+1..<Suc k}"
  2610         unfolding eqs  sum.union_disjoint[OF fths(1) finite_UnI[OF fths(2,3)] d(1)]
  2611         unfolding sum.union_disjoint[OF fths(2) fths(3) d(2)]
  2612         by simp
  2613       finally show ?thesis using c' by simp
  2614     qed
  2615     then show "((r, Suc k, a, xs!i), r, Suc k, a, Suc n) \<in> ?R"
  2616       apply auto
  2617       apply (metis not_less)
  2618       done
  2619   next
  2620     fix r k a n
  2621     show "((r, Suc k, a, 0), r, Suc k, a, Suc n) \<in> ?R" by simp
  2622   }
  2623 qed
  2624 
  2625 definition "fps_radical r n a = Abs_fps (radical r n a)"
  2626 
  2627 lemma fps_radical0[simp]: "fps_radical r 0 a = 1"
  2628   apply (auto simp add: fps_eq_iff fps_radical_def)
  2629   apply (case_tac n)
  2630   apply auto
  2631   done
  2632 
  2633 lemma fps_radical_nth_0[simp]: "fps_radical r n a $ 0 = (if n = 0 then 1 else r n (a$0))"
  2634   by (cases n) (simp_all add: fps_radical_def)
  2635 
  2636 lemma fps_radical_power_nth[simp]:
  2637   assumes r: "(r k (a$0)) ^ k = a$0"
  2638   shows "fps_radical r k a ^ k $ 0 = (if k = 0 then 1 else a$0)"
  2639 proof (cases k)
  2640   case 0
  2641   then show ?thesis by simp
  2642 next
  2643   case (Suc h)
  2644   have eq1: "fps_radical r k a ^ k $ 0 = (\<Prod>j\<in>{0..h}. fps_radical r k a $ (replicate k 0) ! j)"
  2645     unfolding fps_power_nth Suc by simp
  2646   also have "\<dots> = (\<Prod>j\<in>{0..h}. r k (a$0))"
  2647     apply (rule prod.cong)
  2648     apply simp
  2649     using Suc
  2650     apply (subgoal_tac "replicate k 0 ! x = 0")
  2651     apply (auto intro: nth_replicate simp del: replicate.simps)
  2652     done
  2653   also have "\<dots> = a$0"
  2654     using r Suc by (simp add: prod_constant)
  2655   finally show ?thesis
  2656     using Suc by simp
  2657 qed
  2658 
  2659 lemma power_radical:
  2660   fixes a:: "'a::field_char_0 fps"
  2661   assumes a0: "a$0 \<noteq> 0"
  2662   shows "(r (Suc k) (a$0)) ^ Suc k = a$0 \<longleftrightarrow> (fps_radical r (Suc k) a) ^ (Suc k) = a"
  2663     (is "?lhs \<longleftrightarrow> ?rhs")
  2664 proof
  2665   let ?r = "fps_radical r (Suc k) a"
  2666   show ?rhs if r0: ?lhs
  2667   proof -
  2668     from a0 r0 have r00: "r (Suc k) (a$0) \<noteq> 0" by auto
  2669     have "?r ^ Suc k $ z = a$z" for z
  2670     proof (induct z rule: nat_less_induct)
  2671       fix n
  2672       assume H: "\<forall>m<n. ?r ^ Suc k $ m = a$m"
  2673       show "?r ^ Suc k $ n = a $n"
  2674       proof (cases n)
  2675         case 0
  2676         then show ?thesis
  2677           using fps_radical_power_nth[of r "Suc k" a, OF r0] by simp
  2678       next
  2679         case (Suc n1)
  2680         then have "n \<noteq> 0" by simp
  2681         let ?Pnk = "natpermute n (k + 1)"
  2682         let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  2683         let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  2684         have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  2685         have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  2686         have f: "finite ?Pnkn" "finite ?Pnknn"
  2687           using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  2688           by (metis natpermute_finite)+
  2689         let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  2690         have "sum ?f ?Pnkn = sum (\<lambda>v. ?r $ n * r (Suc k) (a $ 0) ^ k) ?Pnkn"
  2691         proof (rule sum.cong)
  2692           fix v assume v: "v \<in> {xs \<in> natpermute n (k + 1). n \<in> set xs}"
  2693           let ?ths = "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) =
  2694             fps_radical r (Suc k) a $ n * r (Suc k) (a $ 0) ^ k"
  2695           from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  2696             unfolding natpermute_contain_maximal by auto
  2697           have "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) =
  2698               (\<Prod>j\<in>{0..k}. if j = i then fps_radical r (Suc k) a $ n else r (Suc k) (a$0))"
  2699             apply (rule prod.cong, simp)
  2700             using i r0
  2701             apply (simp del: replicate.simps)
  2702             done
  2703           also have "\<dots> = (fps_radical r (Suc k) a $ n) * r (Suc k) (a$0) ^ k"
  2704             using i r0 by (simp add: prod_gen_delta)
  2705           finally show ?ths .
  2706         qed rule
  2707         then have "sum ?f ?Pnkn = of_nat (k+1) * ?r $ n * r (Suc k) (a $ 0) ^ k"
  2708           by (simp add: natpermute_max_card[OF \<open>n \<noteq> 0\<close>, simplified])
  2709         also have "\<dots> = a$n - sum ?f ?Pnknn"
  2710           unfolding Suc using r00 a0 by (simp add: field_simps fps_radical_def del: of_nat_Suc)
  2711         finally have fn: "sum ?f ?Pnkn = a$n - sum ?f ?Pnknn" .
  2712         have "(?r ^ Suc k)$n = sum ?f ?Pnkn + sum ?f ?Pnknn"
  2713           unfolding fps_power_nth_Suc sum.union_disjoint[OF f d, unfolded eq] ..
  2714         also have "\<dots> = a$n" unfolding fn by simp
  2715         finally show ?thesis .
  2716       qed
  2717     qed
  2718     then show ?thesis using r0 by (simp add: fps_eq_iff)
  2719   qed
  2720   show ?lhs if ?rhs
  2721   proof -
  2722     from that have "((fps_radical r (Suc k) a) ^ (Suc k))$0 = a$0"
  2723       by simp
  2724     then show ?thesis
  2725       unfolding fps_power_nth_Suc
  2726       by (simp add: prod_constant del: replicate.simps)
  2727   qed
  2728 qed
  2729 
  2730 (*
  2731 lemma power_radical:
  2732   fixes a:: "'a::field_char_0 fps"
  2733   assumes r0: "(r (Suc k) (a$0)) ^ Suc k = a$0" and a0: "a$0 \<noteq> 0"
  2734   shows "(fps_radical r (Suc k) a) ^ (Suc k) = a"
  2735 proof-
  2736   let ?r = "fps_radical r (Suc k) a"
  2737   from a0 r0 have r00: "r (Suc k) (a$0) \<noteq> 0" by auto
  2738   {fix z have "?r ^ Suc k $ z = a$z"
  2739     proof(induct z rule: nat_less_induct)
  2740       fix n assume H: "\<forall>m<n. ?r ^ Suc k $ m = a$m"
  2741       {assume "n = 0" then have "?r ^ Suc k $ n = a $n"
  2742           using fps_radical_power_nth[of r "Suc k" a, OF r0] by simp}
  2743       moreover
  2744       {fix n1 assume n1: "n = Suc n1"
  2745         have fK: "finite {0..k}" by simp
  2746         have nz: "n \<noteq> 0" using n1 by arith
  2747         let ?Pnk = "natpermute n (k + 1)"
  2748         let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  2749         let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  2750         have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  2751         have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  2752         have f: "finite ?Pnkn" "finite ?Pnknn"
  2753           using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  2754           by (metis natpermute_finite)+
  2755         let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  2756         have "sum ?f ?Pnkn = sum (\<lambda>v. ?r $ n * r (Suc k) (a $ 0) ^ k) ?Pnkn"
  2757         proof(rule sum.cong2)
  2758           fix v assume v: "v \<in> {xs \<in> natpermute n (k + 1). n \<in> set xs}"
  2759           let ?ths = "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = fps_radical r (Suc k) a $ n * r (Suc k) (a $ 0) ^ k"
  2760           from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  2761             unfolding natpermute_contain_maximal by auto
  2762           have "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then fps_radical r (Suc k) a $ n else r (Suc k) (a$0))"
  2763             apply (rule prod.cong, simp)
  2764             using i r0 by (simp del: replicate.simps)
  2765           also have "\<dots> = (fps_radical r (Suc k) a $ n) * r (Suc k) (a$0) ^ k"
  2766             unfolding prod_gen_delta[OF fK] using i r0 by simp
  2767           finally show ?ths .
  2768         qed
  2769         then have "sum ?f ?Pnkn = of_nat (k+1) * ?r $ n * r (Suc k) (a $ 0) ^ k"
  2770           by (simp add: natpermute_max_card[OF nz, simplified])
  2771         also have "\<dots> = a$n - sum ?f ?Pnknn"
  2772           unfolding n1 using r00 a0 by (simp add: field_simps fps_radical_def del: of_nat_Suc )
  2773         finally have fn: "sum ?f ?Pnkn = a$n - sum ?f ?Pnknn" .
  2774         have "(?r ^ Suc k)$n = sum ?f ?Pnkn + sum ?f ?Pnknn"
  2775           unfolding fps_power_nth_Suc sum.union_disjoint[OF f d, unfolded eq] ..
  2776         also have "\<dots> = a$n" unfolding fn by simp
  2777         finally have "?r ^ Suc k $ n = a $n" .}
  2778       ultimately  show "?r ^ Suc k $ n = a $n" by (cases n, auto)
  2779   qed }
  2780   then show ?thesis by (simp add: fps_eq_iff)
  2781 qed
  2782 
  2783 *)
  2784 lemma eq_divide_imp':
  2785   fixes c :: "'a::field"
  2786   shows "c \<noteq> 0 \<Longrightarrow> a * c = b \<Longrightarrow> a = b / c"
  2787   by (simp add: field_simps)
  2788 
  2789 lemma radical_unique:
  2790   assumes r0: "(r (Suc k) (b$0)) ^ Suc k = b$0"
  2791     and a0: "r (Suc k) (b$0 ::'a::field_char_0) = a$0"
  2792     and b0: "b$0 \<noteq> 0"
  2793   shows "a^(Suc k) = b \<longleftrightarrow> a = fps_radical r (Suc k) b"
  2794     (is "?lhs \<longleftrightarrow> ?rhs" is "_ \<longleftrightarrow> a = ?r")
  2795 proof
  2796   show ?lhs if ?rhs
  2797     using that using power_radical[OF b0, of r k, unfolded r0] by simp
  2798   show ?rhs if ?lhs
  2799   proof -
  2800     have r00: "r (Suc k) (b$0) \<noteq> 0" using b0 r0 by auto
  2801     have ceq: "card {0..k} = Suc k" by simp
  2802     from a0 have a0r0: "a$0 = ?r$0" by simp
  2803     have "a $ n = ?r $ n" for n
  2804     proof (induct n rule: nat_less_induct)
  2805       fix n
  2806       assume h: "\<forall>m<n. a$m = ?r $m"
  2807       show "a$n = ?r $ n"
  2808       proof (cases n)
  2809         case 0
  2810         then show ?thesis using a0 by simp
  2811       next
  2812         case (Suc n1)
  2813         have fK: "finite {0..k}" by simp
  2814         have nz: "n \<noteq> 0" using Suc by simp
  2815         let ?Pnk = "natpermute n (Suc k)"
  2816         let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  2817         let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  2818         have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  2819         have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  2820         have f: "finite ?Pnkn" "finite ?Pnknn"
  2821           using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  2822           by (metis natpermute_finite)+
  2823         let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  2824         let ?g = "\<lambda>v. \<Prod>j\<in>{0..k}. a $ v ! j"
  2825         have "sum ?g ?Pnkn = sum (\<lambda>v. a $ n * (?r$0)^k) ?Pnkn"
  2826         proof (rule sum.cong)
  2827           fix v
  2828           assume v: "v \<in> {xs \<in> natpermute n (Suc k). n \<in> set xs}"
  2829           let ?ths = "(\<Prod>j\<in>{0..k}. a $ v ! j) = a $ n * (?r$0)^k"
  2830           from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  2831             unfolding Suc_eq_plus1 natpermute_contain_maximal
  2832             by (auto simp del: replicate.simps)
  2833           have "(\<Prod>j\<in>{0..k}. a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then a $ n else r (Suc k) (b$0))"
  2834             apply (rule prod.cong, simp)
  2835             using i a0
  2836             apply (simp del: replicate.simps)
  2837             done
  2838           also have "\<dots> = a $ n * (?r $ 0)^k"
  2839             using i by (simp add: prod_gen_delta)
  2840           finally show ?ths .
  2841         qed rule
  2842         then have th0: "sum ?g ?Pnkn = of_nat (k+1) * a $ n * (?r $ 0)^k"
  2843           by (simp add: natpermute_max_card[OF nz, simplified])
  2844         have th1: "sum ?g ?Pnknn = sum ?f ?Pnknn"
  2845         proof (rule sum.cong, rule refl, rule prod.cong, simp)
  2846           fix xs i
  2847           assume xs: "xs \<in> ?Pnknn" and i: "i \<in> {0..k}"
  2848           have False if c: "n \<le> xs ! i"
  2849           proof -
  2850             from xs i have "xs ! i \<noteq> n"
  2851               by (auto simp add: in_set_conv_nth natpermute_def)
  2852             with c have c': "n < xs!i" by arith
  2853             have fths: "finite {0 ..< i}" "finite {i}" "finite {i+1..<Suc k}"
  2854               by simp_all
  2855             have d: "{0 ..< i} \<inter> ({i} \<union> {i+1 ..< Suc k}) = {}" "{i} \<inter> {i+1..< Suc k} = {}"
  2856               by auto
  2857             have eqs: "{0..<Suc k} = {0 ..< i} \<union> ({i} \<union> {i+1 ..< Suc k})"
  2858               using i by auto
  2859             from xs have "n = sum_list xs"
  2860               by (simp add: natpermute_def)
  2861             also have "\<dots> = sum (nth xs) {0..<Suc k}"
  2862               using xs by (simp add: natpermute_def sum_list_sum_nth)
  2863             also have "\<dots> = xs!i + sum (nth xs) {0..<i} + sum (nth xs) {i+1..<Suc k}"
  2864               unfolding eqs  sum.union_disjoint[OF fths(1) finite_UnI[OF fths(2,3)] d(1)]
  2865               unfolding sum.union_disjoint[OF fths(2) fths(3) d(2)]
  2866               by simp
  2867             finally show ?thesis using c' by simp
  2868           qed
  2869           then have thn: "xs!i < n" by presburger
  2870           from h[rule_format, OF thn] show "a$(xs !i) = ?r$(xs!i)" .
  2871         qed
  2872         have th00: "\<And>x::'a. of_nat (Suc k) * (x * inverse (of_nat (Suc k))) = x"
  2873           by (simp add: field_simps del: of_nat_Suc)
  2874         from \<open>?lhs\<close> have "b$n = a^Suc k $ n"
  2875           by (simp add: fps_eq_iff)
  2876         also have "a ^ Suc k$n = sum ?g ?Pnkn + sum ?g ?Pnknn"
  2877           unfolding fps_power_nth_Suc
  2878           using sum.union_disjoint[OF f d, unfolded Suc_eq_plus1[symmetric],
  2879             unfolded eq, of ?g] by simp
  2880         also have "\<dots> = of_nat (k+1) * a $ n * (?r $ 0)^k + sum ?f ?Pnknn"
  2881           unfolding th0 th1 ..
  2882         finally have "of_nat (k+1) * a $ n * (?r $ 0)^k = b$n - sum ?f ?Pnknn"
  2883           by simp
  2884         then have "a$n = (b$n - sum ?f ?Pnknn) / (of_nat (k+1) * (?r $ 0)^k)"
  2885           apply -
  2886           apply (rule eq_divide_imp')
  2887           using r00
  2888           apply (simp del: of_nat_Suc)
  2889           apply (simp add: ac_simps)
  2890           done
  2891         then show ?thesis
  2892           apply (simp del: of_nat_Suc)
  2893           unfolding fps_radical_def Suc
  2894           apply (simp add: field_simps Suc th00 del: of_nat_Suc)
  2895           done
  2896       qed
  2897     qed
  2898     then show ?rhs by (simp add: fps_eq_iff)
  2899   qed
  2900 qed
  2901 
  2902 
  2903 lemma radical_power:
  2904   assumes r0: "r (Suc k) ((a$0) ^ Suc k) = a$0"
  2905     and a0: "(a$0 :: 'a::field_char_0) \<noteq> 0"
  2906   shows "(fps_radical r (Suc k) (a ^ Suc k)) = a"
  2907 proof -
  2908   let ?ak = "a^ Suc k"
  2909   have ak0: "?ak $ 0 = (a$0) ^ Suc k"
  2910     by (simp add: fps_nth_power_0 del: power_Suc)
  2911   from r0 have th0: "r (Suc k) (a ^ Suc k $ 0) ^ Suc k = a ^ Suc k $ 0"
  2912     using ak0 by auto
  2913   from r0 ak0 have th1: "r (Suc k) (a ^ Suc k $ 0) = a $ 0"
  2914     by auto
  2915   from ak0 a0 have ak00: "?ak $ 0 \<noteq>0 "
  2916     by auto
  2917   from radical_unique[of r k ?ak a, OF th0 th1 ak00] show ?thesis
  2918     by metis
  2919 qed
  2920 
  2921 lemma fps_deriv_radical:
  2922   fixes a :: "'a::field_char_0 fps"
  2923   assumes r0: "(r (Suc k) (a$0)) ^ Suc k = a$0"
  2924     and a0: "a$0 \<noteq> 0"
  2925   shows "fps_deriv (fps_radical r (Suc k) a) =
  2926     fps_deriv a / (fps_const (of_nat (Suc k)) * (fps_radical r (Suc k) a) ^ k)"
  2927 proof -
  2928   let ?r = "fps_radical r (Suc k) a"
  2929   let ?w = "(fps_const (of_nat (Suc k)) * ?r ^ k)"
  2930   from a0 r0 have r0': "r (Suc k) (a$0) \<noteq> 0"
  2931     by auto
  2932   from r0' have w0: "?w $ 0 \<noteq> 0"
  2933     by (simp del: of_nat_Suc)
  2934   note th0 = inverse_mult_eq_1[OF w0]
  2935   let ?iw = "inverse ?w"
  2936   from iffD1[OF power_radical[of a r], OF a0 r0]
  2937   have "fps_deriv (?r ^ Suc k) = fps_deriv a"
  2938     by simp
  2939   then have "fps_deriv ?r * ?w = fps_deriv a"
  2940     by (simp add: fps_deriv_power ac_simps del: power_Suc)
  2941   then have "?iw * fps_deriv ?r * ?w = ?iw * fps_deriv a"
  2942     by simp
  2943   with a0 r0 have "fps_deriv ?r * (?iw * ?w) = fps_deriv a / ?w"
  2944     by (subst fps_divide_unit) (auto simp del: of_nat_Suc)
  2945   then show ?thesis unfolding th0 by simp
  2946 qed
  2947 
  2948 lemma radical_mult_distrib:
  2949   fixes a :: "'a::field_char_0 fps"
  2950   assumes k: "k > 0"
  2951     and ra0: "r k (a $ 0) ^ k = a $ 0"
  2952     and rb0: "r k (b $ 0) ^ k = b $ 0"
  2953     and a0: "a $ 0 \<noteq> 0"
  2954     and b0: "b $ 0 \<noteq> 0"
  2955   shows "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0) \<longleftrightarrow>
  2956     fps_radical r k (a * b) = fps_radical r k a * fps_radical r k b"
  2957     (is "?lhs \<longleftrightarrow> ?rhs")
  2958 proof
  2959   show ?rhs if r0': ?lhs
  2960   proof -
  2961     from r0' have r0: "(r k ((a * b) $ 0)) ^ k = (a * b) $ 0"
  2962       by (simp add: fps_mult_nth ra0 rb0 power_mult_distrib)
  2963     show ?thesis
  2964     proof (cases k)
  2965       case 0
  2966       then show ?thesis using r0' by simp
  2967     next
  2968       case (Suc h)
  2969       let ?ra = "fps_radical r (Suc h) a"
  2970       let ?rb = "fps_radical r (Suc h) b"
  2971       have th0: "r (Suc h) ((a * b) $ 0) = (fps_radical r (Suc h) a * fps_radical r (Suc h) b) $ 0"
  2972         using r0' Suc by (simp add: fps_mult_nth)
  2973       have ab0: "(a*b) $ 0 \<noteq> 0"
  2974         using a0 b0 by (simp add: fps_mult_nth)
  2975       from radical_unique[of r h "a*b" "fps_radical r (Suc h) a * fps_radical r (Suc h) b", OF r0[unfolded Suc] th0 ab0, symmetric]
  2976         iffD1[OF power_radical[of _ r], OF a0 ra0[unfolded Suc]] iffD1[OF power_radical[of _ r], OF b0 rb0[unfolded Suc]] Suc r0'
  2977       show ?thesis
  2978         by (auto simp add: power_mult_distrib simp del: power_Suc)
  2979     qed
  2980   qed
  2981   show ?lhs if ?rhs
  2982   proof -
  2983     from that have "(fps_radical r k (a * b)) $ 0 = (fps_radical r k a * fps_radical r k b) $ 0"
  2984       by simp
  2985     then show ?thesis
  2986       using k by (simp add: fps_mult_nth)
  2987   qed
  2988 qed
  2989 
  2990 (*
  2991 lemma radical_mult_distrib:
  2992   fixes a:: "'a::field_char_0 fps"
  2993   assumes
  2994   ra0: "r k (a $ 0) ^ k = a $ 0"
  2995   and rb0: "r k (b $ 0) ^ k = b $ 0"
  2996   and r0': "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0)"
  2997   and a0: "a$0 \<noteq> 0"
  2998   and b0: "b$0 \<noteq> 0"
  2999   shows "fps_radical r (k) (a*b) = fps_radical r (k) a * fps_radical r (k) (b)"
  3000 proof-
  3001   from r0' have r0: "(r (k) ((a*b)$0)) ^ k = (a*b)$0"
  3002     by (simp add: fps_mult_nth ra0 rb0 power_mult_distrib)
  3003   {assume "k=0" then have ?thesis by simp}
  3004   moreover
  3005   {fix h assume k: "k = Suc h"
  3006   let ?ra = "fps_radical r (Suc h) a"
  3007   let ?rb = "fps_radical r (Suc h) b"
  3008   have th0: "r (Suc h) ((a * b) $ 0) = (fps_radical r (Suc h) a * fps_radical r (Suc h) b) $ 0"
  3009     using r0' k by (simp add: fps_mult_nth)
  3010   have ab0: "(a*b) $ 0 \<noteq> 0" using a0 b0 by (simp add: fps_mult_nth)
  3011   from radical_unique[of r h "a*b" "fps_radical r (Suc h) a * fps_radical r (Suc h) b", OF r0[unfolded k] th0 ab0, symmetric]
  3012     power_radical[of r, OF ra0[unfolded k] a0] power_radical[of r, OF rb0[unfolded k] b0] k
  3013   have ?thesis by (auto simp add: power_mult_distrib simp del: power_Suc)}
  3014 ultimately show ?thesis by (cases k, auto)
  3015 qed
  3016 *)
  3017 
  3018 lemma fps_divide_1 [simp]: "(a :: 'a::field fps) / 1 = a"
  3019   by (fact div_by_1)
  3020 
  3021 lemma radical_divide:
  3022   fixes a :: "'a::field_char_0 fps"
  3023   assumes kp: "k > 0"
  3024     and ra0: "(r k (a $ 0)) ^ k = a $ 0"
  3025     and rb0: "(r k (b $ 0)) ^ k = b $ 0"
  3026     and a0: "a$0 \<noteq> 0"
  3027     and b0: "b$0 \<noteq> 0"
  3028   shows "r k ((a $ 0) / (b$0)) = r k (a$0) / r k (b $ 0) \<longleftrightarrow>
  3029     fps_radical r k (a/b) = fps_radical r k a / fps_radical r k b"
  3030   (is "?lhs = ?rhs")
  3031 proof
  3032   let ?r = "fps_radical r k"
  3033   from kp obtain h where k: "k = Suc h"
  3034     by (cases k) auto
  3035   have ra0': "r k (a$0) \<noteq> 0" using a0 ra0 k by auto
  3036   have rb0': "r k (b$0) \<noteq> 0" using b0 rb0 k by auto
  3037 
  3038   show ?lhs if ?rhs
  3039   proof -
  3040     from that have "?r (a/b) $ 0 = (?r a / ?r b)$0"
  3041       by simp
  3042     then show ?thesis
  3043       using k a0 b0 rb0' by (simp add: fps_divide_unit fps_mult_nth fps_inverse_def divide_inverse)
  3044   qed
  3045   show ?rhs if ?lhs
  3046   proof -
  3047     from a0 b0 have ab0[simp]: "(a/b)$0 = a$0 / b$0"
  3048       by (simp add: fps_divide_def fps_mult_nth divide_inverse fps_inverse_def)
  3049     have th0: "r k ((a/b)$0) ^ k = (a/b)$0"
  3050       by (simp add: \<open>?lhs\<close> power_divide ra0 rb0)
  3051     from a0 b0 ra0' rb0' kp \<open>?lhs\<close>
  3052     have th1: "r k ((a / b) $ 0) = (fps_radical r k a / fps_radical r k b) $ 0"
  3053       by (simp add: fps_divide_unit fps_mult_nth fps_inverse_def divide_inverse)
  3054     from a0 b0 ra0' rb0' kp have ab0': "(a / b) $ 0 \<noteq> 0"
  3055       by (simp add: fps_divide_unit fps_mult_nth fps_inverse_def nonzero_imp_inverse_nonzero)
  3056     note tha[simp] = iffD1[OF power_radical[where r=r and k=h], OF a0 ra0[unfolded k], unfolded k[symmetric]]
  3057     note thb[simp] = iffD1[OF power_radical[where r=r and k=h], OF b0 rb0[unfolded k], unfolded k[symmetric]]
  3058     from b0 rb0' have th2: "(?r a / ?r b)^k = a/b"
  3059       by (simp add: fps_divide_unit power_mult_distrib fps_inverse_power[symmetric])
  3060 
  3061     from iffD1[OF radical_unique[where r=r and a="?r a / ?r b" and b="a/b" and k=h], symmetric, unfolded k[symmetric], OF th0 th1 ab0' th2]
  3062     show ?thesis .
  3063   qed
  3064 qed
  3065 
  3066 lemma radical_inverse:
  3067   fixes a :: "'a::field_char_0 fps"
  3068   assumes k: "k > 0"
  3069     and ra0: "r k (a $ 0) ^ k = a $ 0"
  3070     and r1: "(r k 1)^k = 1"
  3071     and a0: "a$0 \<noteq> 0"
  3072   shows "r k (inverse (a $ 0)) = r k 1 / (r k (a $ 0)) \<longleftrightarrow>
  3073     fps_radical r k (inverse a) = fps_radical r k 1 / fps_radical r k a"
  3074   using radical_divide[where k=k and r=r and a=1 and b=a, OF k ] ra0 r1 a0
  3075   by (simp add: divide_inverse fps_divide_def)
  3076 
  3077 
  3078 subsection \<open>Derivative of composition\<close>
  3079 
  3080 lemma fps_compose_deriv:
  3081   fixes a :: "'a::idom fps"
  3082   assumes b0: "b$0 = 0"
  3083   shows "fps_deriv (a oo b) = ((fps_deriv a) oo b) * fps_deriv b"
  3084 proof -
  3085   have "(fps_deriv (a oo b))$n = (((fps_deriv a) oo b) * (fps_deriv b)) $n" for n
  3086   proof -
  3087     have "(fps_deriv (a oo b))$n = sum (\<lambda>i. a $ i * (fps_deriv (b^i))$n) {0.. Suc n}"
  3088       by (simp add: fps_compose_def field_simps sum_distrib_left del: of_nat_Suc)
  3089     also have "\<dots> = sum (\<lambda>i. a$i * ((fps_const (of_nat i)) * (fps_deriv b * (b^(i - 1))))$n) {0.. Suc n}"
  3090       by (simp add: field_simps fps_deriv_power del: fps_mult_left_const_nth of_nat_Suc)
  3091     also have "\<dots> = sum (\<lambda>i. of_nat i * a$i * (((b^(i - 1)) * fps_deriv b))$n) {0.. Suc n}"
  3092       unfolding fps_mult_left_const_nth  by (simp add: field_simps)
  3093     also have "\<dots> = sum (\<lambda>i. of_nat i * a$i * (sum (\<lambda>j. (b^ (i - 1))$j * (fps_deriv b)$(n - j)) {0..n})) {0.. Suc n}"
  3094       unfolding fps_mult_nth ..
  3095     also have "\<dots> = sum (\<lambda>i. of_nat i * a$i * (sum (\<lambda>j. (b^ (i - 1))$j * (fps_deriv b)$(n - j)) {0..n})) {1.. Suc n}"
  3096       apply (rule sum.mono_neutral_right)
  3097       apply (auto simp add: mult_delta_left sum.delta not_le)
  3098       done
  3099     also have "\<dots> = sum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (sum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}"
  3100       unfolding fps_deriv_nth
  3101       by (rule sum.reindex_cong [of Suc]) (auto simp add: mult.assoc)
  3102     finally have th0: "(fps_deriv (a oo b))$n =
  3103       sum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (sum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}" .
  3104 
  3105     have "(((fps_deriv a) oo b) * (fps_deriv b))$n = sum (\<lambda>i. (fps_deriv b)$ (n - i) * ((fps_deriv a) oo b)$i) {0..n}"
  3106       unfolding fps_mult_nth by (simp add: ac_simps)
  3107     also have "\<dots> = sum (\<lambda>i. sum (\<lambda>j. of_nat (n - i +1) * b$(n - i + 1) * of_nat (j + 1) * a$(j+1) * (b^j)$i) {0..n}) {0..n}"
  3108       unfolding fps_deriv_nth fps_compose_nth sum_distrib_left mult.assoc
  3109       apply (rule sum.cong)
  3110       apply (rule refl)
  3111       apply (rule sum.mono_neutral_left)
  3112       apply (simp_all add: subset_eq)
  3113       apply clarify
  3114       apply (subgoal_tac "b^i$x = 0")
  3115       apply simp
  3116       apply (rule startsby_zero_power_prefix[OF b0, rule_format])
  3117       apply simp
  3118       done
  3119     also have "\<dots> = sum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (sum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}"
  3120       unfolding sum_distrib_left
  3121       apply (subst sum.commute)
  3122       apply (rule sum.cong, rule refl)+
  3123       apply simp
  3124       done
  3125     finally show ?thesis
  3126       unfolding th0 by simp
  3127   qed
  3128   then show ?thesis by (simp add: fps_eq_iff)
  3129 qed
  3130 
  3131 lemma fps_mult_X_plus_1_nth:
  3132   "((1+X)*a) $n = (if n = 0 then (a$n :: 'a::comm_ring_1) else a$n + a$(n - 1))"
  3133 proof (cases n)
  3134   case 0
  3135   then show ?thesis
  3136     by (simp add: fps_mult_nth)
  3137 next
  3138   case (Suc m)
  3139   have "((1 + X)*a) $ n = sum (\<lambda>i. (1 + X) $ i * a $ (n - i)) {0..n}"
  3140     by (simp add: fps_mult_nth)
  3141   also have "\<dots> = sum (\<lambda>i. (1+X)$i * a$(n-i)) {0.. 1}"
  3142     unfolding Suc by (rule sum.mono_neutral_right) auto
  3143   also have "\<dots> = (if n = 0 then (a$n :: 'a::comm_ring_1) else a$n + a$(n - 1))"
  3144     by (simp add: Suc)
  3145   finally show ?thesis .
  3146 qed
  3147 
  3148 
  3149 subsection \<open>Finite FPS (i.e. polynomials) and X\<close>
  3150 
  3151 lemma fps_poly_sum_X:
  3152   assumes "\<forall>i > n. a$i = (0::'a::comm_ring_1)"
  3153   shows "a = sum (\<lambda>i. fps_const (a$i) * X^i) {0..n}" (is "a = ?r")
  3154 proof -
  3155   have "a$i = ?r$i" for i
  3156     unfolding fps_sum_nth fps_mult_left_const_nth X_power_nth
  3157     by (simp add: mult_delta_right sum.delta' assms)
  3158   then show ?thesis
  3159     unfolding fps_eq_iff by blast
  3160 qed
  3161 
  3162 
  3163 subsection \<open>Compositional inverses\<close>
  3164 
  3165 fun compinv :: "'a fps \<Rightarrow> nat \<Rightarrow> 'a::field"
  3166 where
  3167   "compinv a 0 = X$0"
  3168 | "compinv a (Suc n) =
  3169     (X$ Suc n - sum (\<lambda>i. (compinv a i) * (a^i)$Suc n) {0 .. n}) / (a$1) ^ Suc n"
  3170 
  3171 definition "fps_inv a = Abs_fps (compinv a)"
  3172 
  3173 lemma fps_inv:
  3174   assumes a0: "a$0 = 0"
  3175     and a1: "a$1 \<noteq> 0"
  3176   shows "fps_inv a oo a = X"
  3177 proof -
  3178   let ?i = "fps_inv a oo a"
  3179   have "?i $n = X$n" for n
  3180   proof (induct n rule: nat_less_induct)
  3181     fix n
  3182     assume h: "\<forall>m<n. ?i$m = X$m"
  3183     show "?i $ n = X$n"
  3184     proof (cases n)
  3185       case 0
  3186       then show ?thesis using a0
  3187         by (simp add: fps_compose_nth fps_inv_def)
  3188     next
  3189       case (Suc n1)
  3190       have "?i $ n = sum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1} + fps_inv a $ Suc n1 * (a $ 1)^ Suc n1"
  3191         by (simp only: fps_compose_nth) (simp add: Suc startsby_zero_power_nth_same [OF a0] del: power_Suc)
  3192       also have "\<dots> = sum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1} +
  3193         (X$ Suc n1 - sum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1})"
  3194         using a0 a1 Suc by (simp add: fps_inv_def)
  3195       also have "\<dots> = X$n" using Suc by simp
  3196       finally show ?thesis .
  3197     qed
  3198   qed
  3199   then show ?thesis
  3200     by (simp add: fps_eq_iff)
  3201 qed
  3202 
  3203 
  3204 fun gcompinv :: "'a fps \<Rightarrow> 'a fps \<Rightarrow> nat \<Rightarrow> 'a::field"
  3205 where
  3206   "gcompinv b a 0 = b$0"
  3207 | "gcompinv b a (Suc n) =
  3208     (b$ Suc n - sum (\<lambda>i. (gcompinv b a i) * (a^i)$Suc n) {0 .. n}) / (a$1) ^ Suc n"
  3209 
  3210 definition "fps_ginv b a = Abs_fps (gcompinv b a)"
  3211 
  3212 lemma fps_ginv:
  3213   assumes a0: "a$0 = 0"
  3214     and a1: "a$1 \<noteq> 0"
  3215   shows "fps_ginv b a oo a = b"
  3216 proof -
  3217   let ?i = "fps_ginv b a oo a"
  3218   have "?i $n = b$n" for n
  3219   proof (induct n rule: nat_less_induct)
  3220     fix n
  3221     assume h: "\<forall>m<n. ?i$m = b$m"
  3222     show "?i $ n = b$n"
  3223     proof (cases n)
  3224       case 0
  3225       then show ?thesis using a0
  3226         by (simp add: fps_compose_nth fps_ginv_def)
  3227     next
  3228       case (Suc n1)
  3229       have "?i $ n = sum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1} + fps_ginv b a $ Suc n1 * (a $ 1)^ Suc n1"
  3230         by (simp only: fps_compose_nth) (simp add: Suc startsby_zero_power_nth_same [OF a0] del: power_Suc)
  3231       also have "\<dots> = sum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1} +
  3232         (b$ Suc n1 - sum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1})"
  3233         using a0 a1 Suc by (simp add: fps_ginv_def)
  3234       also have "\<dots> = b$n" using Suc by simp
  3235       finally show ?thesis .
  3236     qed
  3237   qed
  3238   then show ?thesis
  3239     by (simp add: fps_eq_iff)
  3240 qed
  3241 
  3242 lemma fps_inv_ginv: "fps_inv = fps_ginv X"
  3243   apply (auto simp add: fun_eq_iff fps_eq_iff fps_inv_def fps_ginv_def)
  3244   apply (induct_tac n rule: nat_less_induct)
  3245   apply auto
  3246   apply (case_tac na)
  3247   apply simp
  3248   apply simp
  3249   done
  3250 
  3251 lemma fps_compose_1[simp]: "1 oo a = 1"
  3252   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left sum.delta)
  3253 
  3254 lemma fps_compose_0[simp]: "0 oo a = 0"
  3255   by (simp add: fps_eq_iff fps_compose_nth)
  3256 
  3257 lemma fps_compose_0_right[simp]: "a oo 0 = fps_const (a $ 0)"
  3258   by (auto simp add: fps_eq_iff fps_compose_nth power_0_left sum.neutral)
  3259 
  3260 lemma fps_compose_add_distrib: "(a + b) oo c = (a oo c) + (b oo c)"
  3261   by (simp add: fps_eq_iff fps_compose_nth field_simps sum.distrib)
  3262 
  3263 lemma fps_compose_sum_distrib: "(sum f S) oo a = sum (\<lambda>i. f i oo a) S"
  3264 proof (cases "finite S")
  3265   case True
  3266   show ?thesis
  3267   proof (rule finite_induct[OF True])
  3268     show "sum f {} oo a = (\<Sum>i\<in>{}. f i oo a)"
  3269       by simp
  3270   next
  3271     fix x F
  3272     assume fF: "finite F"
  3273       and xF: "x \<notin> F"
  3274       and h: "sum f F oo a = sum (\<lambda>i. f i oo a) F"
  3275     show "sum f (insert x F) oo a  = sum (\<lambda>i. f i oo a) (insert x F)"
  3276       using fF xF h by (simp add: fps_compose_add_distrib)
  3277   qed
  3278 next
  3279   case False
  3280   then show ?thesis by simp
  3281 qed
  3282 
  3283 lemma convolution_eq:
  3284   "sum (\<lambda>i. a (i :: nat) * b (n - i)) {0 .. n} =
  3285     sum (\<lambda>(i,j). a i * b j) {(i,j). i \<le> n \<and> j \<le> n \<and> i + j = n}"
  3286   by (rule sum.reindex_bij_witness[where i=fst and j="\<lambda>i. (i, n - i)"]) auto
  3287 
  3288 lemma product_composition_lemma:
  3289   assumes c0: "c$0 = (0::'a::idom)"
  3290     and d0: "d$0 = 0"
  3291   shows "((a oo c) * (b oo d))$n =
  3292     sum (\<lambda>(k,m). a$k * b$m * (c^k * d^m) $ n) {(k,m). k + m \<le> n}"  (is "?l = ?r")
  3293 proof -
  3294   let ?S = "{(k::nat, m::nat). k + m \<le> n}"
  3295   have s: "?S \<subseteq> {0..n} \<times> {0..n}" by (auto simp add: subset_eq)
  3296   have f: "finite {(k::nat, m::nat). k + m \<le> n}"
  3297     apply (rule finite_subset[OF s])
  3298     apply auto
  3299     done
  3300   have "?r =  sum (\<lambda>i. sum (\<lambda>(k,m). a$k * (c^k)$i * b$m * (d^m) $ (n - i)) {(k,m). k + m \<le> n}) {0..n}"
  3301     apply (simp add: fps_mult_nth sum_distrib_left)
  3302     apply (subst sum.commute)
  3303     apply (rule sum.cong)
  3304     apply (auto simp add: field_simps)
  3305     done
  3306   also have "\<dots> = ?l"
  3307     apply (simp add: fps_mult_nth fps_compose_nth sum_product)
  3308     apply (rule sum.cong)
  3309     apply (rule refl)
  3310     apply (simp add: sum.cartesian_product mult.assoc)
  3311     apply (rule sum.mono_neutral_right[OF f])
  3312     apply (simp add: subset_eq)
  3313     apply presburger
  3314     apply clarsimp
  3315     apply (rule ccontr)
  3316     apply (clarsimp simp add: not_le)
  3317     apply (case_tac "x < aa")
  3318     apply simp
  3319     apply (frule_tac startsby_zero_power_prefix[rule_format, OF c0])
  3320     apply blast
  3321     apply simp
  3322     apply (frule_tac startsby_zero_power_prefix[rule_format, OF d0])
  3323     apply blast
  3324     done
  3325   finally show ?thesis by simp
  3326 qed
  3327 
  3328 lemma product_composition_lemma':
  3329   assumes c0: "c$0 = (0::'a::idom)"
  3330     and d0: "d$0 = 0"
  3331   shows "((a oo c) * (b oo d))$n =
  3332     sum (\<lambda>k. sum (\<lambda>m. a$k * b$m * (c^k * d^m) $ n) {0..n}) {0..n}"  (is "?l = ?r")
  3333   unfolding product_composition_lemma[OF c0 d0]
  3334   unfolding sum.cartesian_product
  3335   apply (rule sum.mono_neutral_left)
  3336   apply simp
  3337   apply (clarsimp simp add: subset_eq)
  3338   apply clarsimp
  3339   apply (rule ccontr)
  3340   apply (subgoal_tac "(c^aa * d^ba) $ n = 0")
  3341   apply simp
  3342   unfolding fps_mult_nth
  3343   apply (rule sum.neutral)
  3344   apply (clarsimp simp add: not_le)
  3345   apply (case_tac "x < aa")
  3346   apply (rule startsby_zero_power_prefix[OF c0, rule_format])
  3347   apply simp
  3348   apply (subgoal_tac "n - x < ba")
  3349   apply (frule_tac k = "ba" in startsby_zero_power_prefix[OF d0, rule_format])
  3350   apply simp
  3351   apply arith
  3352   done
  3353 
  3354 
  3355 lemma sum_pair_less_iff:
  3356   "sum (\<lambda>((k::nat),m). a k * b m * c (k + m)) {(k,m). k + m \<le> n} =
  3357     sum (\<lambda>s. sum (\<lambda>i. a i * b (s - i) * c s) {0..s}) {0..n}"
  3358   (is "?l = ?r")
  3359 proof -
  3360   let ?KM = "{(k,m). k + m \<le> n}"
  3361   let ?f = "\<lambda>s. UNION {(0::nat)..s} (\<lambda>i. {(i,s - i)})"
  3362   have th0: "?KM = UNION {0..n} ?f"
  3363     by auto
  3364   show "?l = ?r "
  3365     unfolding th0
  3366     apply (subst sum.UNION_disjoint)
  3367     apply auto
  3368     apply (subst sum.UNION_disjoint)
  3369     apply auto
  3370     done
  3371 qed
  3372 
  3373 lemma fps_compose_mult_distrib_lemma:
  3374   assumes c0: "c$0 = (0::'a::idom)"
  3375   shows "((a oo c) * (b oo c))$n = sum (\<lambda>s. sum (\<lambda>i. a$i * b$(s - i) * (c^s) $ n) {0..s}) {0..n}"
  3376   unfolding product_composition_lemma[OF c0 c0] power_add[symmetric]
  3377   unfolding sum_pair_less_iff[where a = "\<lambda>k. a$k" and b="\<lambda>m. b$m" and c="\<lambda>s. (c ^ s)$n" and n = n] ..
  3378 
  3379 lemma fps_compose_mult_distrib:
  3380   assumes c0: "c $ 0 = (0::'a::idom)"
  3381   shows "(a * b) oo c = (a oo c) * (b oo c)"
  3382   apply (simp add: fps_eq_iff fps_compose_mult_distrib_lemma [OF c0])
  3383   apply (simp add: fps_compose_nth fps_mult_nth sum_distrib_right)
  3384   done
  3385 
  3386 lemma fps_compose_prod_distrib:
  3387   assumes c0: "c$0 = (0::'a::idom)"
  3388   shows "prod a S oo c = prod (\<lambda>k. a k oo c) S"
  3389   apply (cases "finite S")
  3390   apply simp_all
  3391   apply (induct S rule: finite_induct)
  3392   apply simp
  3393   apply (simp add: fps_compose_mult_distrib[OF c0])
  3394   done
  3395 
  3396 lemma fps_compose_divide:
  3397   assumes [simp]: "g dvd f" "h $ 0 = 0"
  3398   shows   "fps_compose f h = fps_compose (f / g :: 'a :: field fps) h * fps_compose g h"
  3399 proof -
  3400   have "f = (f / g) * g" by simp
  3401   also have "fps_compose \<dots> h = fps_compose (f / g) h * fps_compose g h"
  3402     by (subst fps_compose_mult_distrib) simp_all
  3403   finally show ?thesis .
  3404 qed
  3405 
  3406 lemma fps_compose_divide_distrib:
  3407   assumes "g dvd f" "h $ 0 = 0" "fps_compose g h \<noteq> 0"
  3408   shows   "fps_compose (f / g :: 'a :: field fps) h = fps_compose f h / fps_compose g h"
  3409   using fps_compose_divide[OF assms(1,2)] assms(3) by simp
  3410 
  3411 lemma fps_compose_power:
  3412   assumes c0: "c$0 = (0::'a::idom)"
  3413   shows "(a oo c)^n = a^n oo c"
  3414 proof (cases n)
  3415   case 0
  3416   then show ?thesis by simp
  3417 next
  3418   case (Suc m)
  3419   have th0: "a^n = prod (\<lambda>k. a) {0..m}" "(a oo c) ^ n = prod (\<lambda>k. a oo c) {0..m}"
  3420     by (simp_all add: prod_constant Suc)
  3421   then show ?thesis
  3422     by (simp add: fps_compose_prod_distrib[OF c0])
  3423 qed
  3424 
  3425 lemma fps_compose_uminus: "- (a::'a::ring_1 fps) oo c = - (a oo c)"
  3426   by (simp add: fps_eq_iff fps_compose_nth field_simps sum_negf[symmetric])
  3427 
  3428 lemma fps_compose_sub_distrib: "(a - b) oo (c::'a::ring_1 fps) = (a oo c) - (b oo c)"
  3429   using fps_compose_add_distrib [of a "- b" c] by (simp add: fps_compose_uminus)
  3430 
  3431 lemma X_fps_compose: "X oo a = Abs_fps (\<lambda>n. if n = 0 then (0::'a::comm_ring_1) else a$n)"
  3432   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left sum.delta)
  3433 
  3434 lemma fps_inverse_compose:
  3435   assumes b0: "(b$0 :: 'a::field) = 0"
  3436     and a0: "a$0 \<noteq> 0"
  3437   shows "inverse a oo b = inverse (a oo b)"
  3438 proof -
  3439   let ?ia = "inverse a"
  3440   let ?ab = "a oo b"
  3441   let ?iab = "inverse ?ab"
  3442 
  3443   from a0 have ia0: "?ia $ 0 \<noteq> 0" by simp
  3444   from a0 have ab0: "?ab $ 0 \<noteq> 0" by (simp add: fps_compose_def)
  3445   have "(?ia oo b) *  (a oo b) = 1"
  3446     unfolding fps_compose_mult_distrib[OF b0, symmetric]
  3447     unfolding inverse_mult_eq_1[OF a0]
  3448     fps_compose_1 ..
  3449 
  3450   then have "(?ia oo b) *  (a oo b) * ?iab  = 1 * ?iab" by simp
  3451   then have "(?ia oo b) *  (?iab * (a oo b))  = ?iab" by simp
  3452   then show ?thesis unfolding inverse_mult_eq_1[OF ab0] by simp
  3453 qed
  3454 
  3455 lemma fps_divide_compose:
  3456   assumes c0: "(c$0 :: 'a::field) = 0"
  3457     and b0: "b$0 \<noteq> 0"
  3458   shows "(a/b) oo c = (a oo c) / (b oo c)"
  3459     using b0 c0 by (simp add: fps_divide_unit fps_inverse_compose fps_compose_mult_distrib)
  3460 
  3461 lemma gp:
  3462   assumes a0: "a$0 = (0::'a::field)"
  3463   shows "(Abs_fps (\<lambda>n. 1)) oo a = 1/(1 - a)"
  3464     (is "?one oo a = _")
  3465 proof -
  3466   have o0: "?one $ 0 \<noteq> 0" by simp
  3467   have th0: "(1 - X) $ 0 \<noteq> (0::'a)" by simp
  3468   from fps_inverse_gp[where ?'a = 'a]
  3469   have "inverse ?one = 1 - X" by (simp add: fps_eq_iff)
  3470   then have "inverse (inverse ?one) = inverse (1 - X)" by simp
  3471   then have th: "?one = 1/(1 - X)" unfolding fps_inverse_idempotent[OF o0]
  3472     by (simp add: fps_divide_def)
  3473   show ?thesis
  3474     unfolding th
  3475     unfolding fps_divide_compose[OF a0 th0]
  3476     fps_compose_1 fps_compose_sub_distrib X_fps_compose_startby0[OF a0] ..
  3477 qed
  3478 
  3479 lemma fps_const_power [simp]: "fps_const (c::'a::ring_1) ^ n = fps_const (c^n)"
  3480   by (induct n) auto
  3481 
  3482 lemma fps_compose_radical:
  3483   assumes b0: "b$0 = (0::'a::field_char_0)"
  3484     and ra0: "r (Suc k) (a$0) ^ Suc k = a$0"
  3485     and a0: "a$0 \<noteq> 0"
  3486   shows "fps_radical r (Suc k)  a oo b = fps_radical r (Suc k) (a oo b)"
  3487 proof -
  3488   let ?r = "fps_radical r (Suc k)"
  3489   let ?ab = "a oo b"
  3490   have ab0: "?ab $ 0 = a$0"
  3491     by (simp add: fps_compose_def)
  3492   from ab0 a0 ra0 have rab0: "?ab $ 0 \<noteq> 0" "r (Suc k) (?ab $ 0) ^ Suc k = ?ab $ 0"
  3493     by simp_all
  3494   have th00: "r (Suc k) ((a oo b) $ 0) = (fps_radical r (Suc k) a oo b) $ 0"
  3495     by (simp add: ab0 fps_compose_def)
  3496   have th0: "(?r a oo b) ^ (Suc k) = a  oo b"
  3497     unfolding fps_compose_power[OF b0]
  3498     unfolding iffD1[OF power_radical[of a r k], OF a0 ra0]  ..
  3499   from iffD1[OF radical_unique[where r=r and k=k and b= ?ab and a = "?r a oo b", OF rab0(2) th00 rab0(1)], OF th0]
  3500   show ?thesis  .
  3501 qed
  3502 
  3503 lemma fps_const_mult_apply_left: "fps_const c * (a oo b) = (fps_const c * a) oo b"
  3504   by (simp add: fps_eq_iff fps_compose_nth sum_distrib_left mult.assoc)
  3505 
  3506 lemma fps_const_mult_apply_right:
  3507   "(a oo b) * fps_const (c::'a::comm_semiring_1) = (fps_const c * a) oo b"
  3508   by (auto simp add: fps_const_mult_apply_left mult.commute)
  3509 
  3510 lemma fps_compose_assoc:
  3511   assumes c0: "c$0 = (0::'a::idom)"
  3512     and b0: "b$0 = 0"
  3513   shows "a oo (b oo c) = a oo b oo c" (is "?l = ?r")
  3514 proof -
  3515   have "?l$n = ?r$n" for n
  3516   proof -
  3517     have "?l$n = (sum (\<lambda>i. (fps_const (a$i) * b^i) oo c) {0..n})$n"
  3518       by (simp add: fps_compose_nth fps_compose_power[OF c0] fps_const_mult_apply_left
  3519         sum_distrib_left mult.assoc fps_sum_nth)
  3520     also have "\<dots> = ((sum (\<lambda>i. fps_const (a$i) * b^i) {0..n}) oo c)$n"
  3521       by (simp add: fps_compose_sum_distrib)
  3522     also have "\<dots> = ?r$n"
  3523       apply (simp add: fps_compose_nth fps_sum_nth sum_distrib_right mult.assoc)
  3524       apply (rule sum.cong)
  3525       apply (rule refl)
  3526       apply (rule sum.mono_neutral_right)
  3527       apply (auto simp add: not_le)
  3528       apply (erule startsby_zero_power_prefix[OF b0, rule_format])
  3529       done
  3530     finally show ?thesis .
  3531   qed
  3532   then show ?thesis
  3533     by (simp add: fps_eq_iff)
  3534 qed
  3535 
  3536 
  3537 lemma fps_X_power_compose:
  3538   assumes a0: "a$0=0"
  3539   shows "X^k oo a = (a::'a::idom fps)^k"
  3540   (is "?l = ?r")
  3541 proof (cases k)
  3542   case 0
  3543   then show ?thesis by simp
  3544 next
  3545   case (Suc h)
  3546   have "?l $ n = ?r $n" for n
  3547   proof -
  3548     consider "k > n" | "k \<le> n" by arith
  3549     then show ?thesis
  3550     proof cases
  3551       case 1
  3552       then show ?thesis
  3553         using a0 startsby_zero_power_prefix[OF a0] Suc
  3554         by (simp add: fps_compose_nth del: power_Suc)
  3555     next
  3556       case 2
  3557       then show ?thesis
  3558         by (simp add: fps_compose_nth mult_delta_left sum.delta)
  3559     qed
  3560   qed
  3561   then show ?thesis
  3562     unfolding fps_eq_iff by blast
  3563 qed
  3564 
  3565 lemma fps_inv_right:
  3566   assumes a0: "a$0 = 0"
  3567     and a1: "a$1 \<noteq> 0"
  3568   shows "a oo fps_inv a = X"
  3569 proof -
  3570   let ?ia = "fps_inv a"
  3571   let ?iaa = "a oo fps_inv a"
  3572   have th0: "?ia $ 0 = 0"
  3573     by (simp add: fps_inv_def)
  3574   have th1: "?iaa $ 0 = 0"
  3575     using a0 a1 by (simp add: fps_inv_def fps_compose_nth)
  3576   have th2: "X$0 = 0"
  3577     by simp
  3578   from fps_inv[OF a0 a1] have "a oo (fps_inv a oo a) = a oo X"
  3579     by simp
  3580   then have "(a oo fps_inv a) oo a = X oo a"
  3581     by (simp add: fps_compose_assoc[OF a0 th0] X_fps_compose_startby0[OF a0])
  3582   with fps_compose_inj_right[OF a0 a1] show ?thesis
  3583     by simp
  3584 qed
  3585 
  3586 lemma fps_inv_deriv:
  3587   assumes a0: "a$0 = (0::'a::field)"
  3588     and a1: "a$1 \<noteq> 0"
  3589   shows "fps_deriv (fps_inv a) = inverse (fps_deriv a oo fps_inv a)"
  3590 proof -
  3591   let ?ia = "fps_inv a"
  3592   let ?d = "fps_deriv a oo ?ia"
  3593   let ?dia = "fps_deriv ?ia"
  3594   have ia0: "?ia$0 = 0"
  3595     by (simp add: fps_inv_def)
  3596   have th0: "?d$0 \<noteq> 0"
  3597     using a1 by (simp add: fps_compose_nth)
  3598   from fps_inv_right[OF a0 a1] have "?d * ?dia = 1"
  3599     by (simp add: fps_compose_deriv[OF ia0, of a, symmetric] )
  3600   then have "inverse ?d * ?d * ?dia = inverse ?d * 1"
  3601     by simp
  3602   with inverse_mult_eq_1 [OF th0] show "?dia = inverse ?d"
  3603     by simp
  3604 qed
  3605 
  3606 lemma fps_inv_idempotent:
  3607   assumes a0: "a$0 = 0"
  3608     and a1: "a$1 \<noteq> 0"
  3609   shows "fps_inv (fps_inv a) = a"
  3610 proof -
  3611   let ?r = "fps_inv"
  3612   have ra0: "?r a $ 0 = 0"
  3613     by (simp add: fps_inv_def)
  3614   from a1 have ra1: "?r a $ 1 \<noteq> 0"
  3615     by (simp add: fps_inv_def field_simps)
  3616   have X0: "X$0 = 0"
  3617     by simp
  3618   from fps_inv[OF ra0 ra1] have "?r (?r a) oo ?r a = X" .
  3619   then have "?r (?r a) oo ?r a oo a = X oo a"
  3620     by simp
  3621   then have "?r (?r a) oo (?r a oo a) = a"
  3622     unfolding X_fps_compose_startby0[OF a0]
  3623     unfolding fps_compose_assoc[OF a0 ra0, symmetric] .
  3624   then show ?thesis
  3625     unfolding fps_inv[OF a0 a1] by simp
  3626 qed
  3627 
  3628 lemma fps_ginv_ginv:
  3629   assumes a0: "a$0 = 0"
  3630     and a1: "a$1 \<noteq> 0"
  3631     and c0: "c$0 = 0"
  3632     and  c1: "c$1 \<noteq> 0"
  3633   shows "fps_ginv b (fps_ginv c a) = b oo a oo fps_inv c"
  3634 proof -
  3635   let ?r = "fps_ginv"
  3636   from c0 have rca0: "?r c a $0 = 0"
  3637     by (simp add: fps_ginv_def)
  3638   from a1 c1 have rca1: "?r c a $ 1 \<noteq> 0"
  3639     by (simp add: fps_ginv_def field_simps)
  3640   from fps_ginv[OF rca0 rca1]
  3641   have "?r b (?r c a) oo ?r c a = b" .
  3642   then have "?r b (?r c a) oo ?r c a oo a = b oo a"
  3643     by simp
  3644   then have "?r b (?r c a) oo (?r c a oo a) = b oo a"
  3645     apply (subst fps_compose_assoc)
  3646     using a0 c0
  3647     apply (auto simp add: fps_ginv_def)
  3648     done
  3649   then have "?r b (?r c a) oo c = b oo a"
  3650     unfolding fps_ginv[OF a0 a1] .
  3651   then have "?r b (?r c a) oo c oo fps_inv c= b oo a oo fps_inv c"
  3652     by simp
  3653   then have "?r b (?r c a) oo (c oo fps_inv c) = b oo a oo fps_inv c"
  3654     apply (subst fps_compose_assoc)
  3655     using a0 c0
  3656     apply (auto simp add: fps_inv_def)
  3657     done
  3658   then show ?thesis
  3659     unfolding fps_inv_right[OF c0 c1] by simp
  3660 qed
  3661 
  3662 lemma fps_ginv_deriv:
  3663   assumes a0:"a$0 = (0::'a::field)"
  3664     and a1: "a$1 \<noteq> 0"
  3665   shows "fps_deriv (fps_ginv b a) = (fps_deriv b / fps_deriv a) oo fps_ginv X a"
  3666 proof -
  3667   let ?ia = "fps_ginv b a"
  3668   let ?iXa = "fps_ginv X a"
  3669   let ?d = "fps_deriv"
  3670   let ?dia = "?d ?ia"
  3671   have iXa0: "?iXa $ 0 = 0"
  3672     by (simp add: fps_ginv_def)
  3673   have da0: "?d a $ 0 \<noteq> 0"
  3674     using a1 by simp
  3675   from fps_ginv[OF a0 a1, of b] have "?d (?ia oo a) = fps_deriv b"
  3676     by simp
  3677   then have "(?d ?ia oo a) * ?d a = ?d b"
  3678     unfolding fps_compose_deriv[OF a0] .
  3679   then have "(?d ?ia oo a) * ?d a * inverse (?d a) = ?d b * inverse (?d a)"
  3680     by simp
  3681   with a1 have "(?d ?ia oo a) * (inverse (?d a) * ?d a) = ?d b / ?d a"
  3682     by (simp add: fps_divide_unit)
  3683   then have "(?d ?ia oo a) oo ?iXa =  (?d b / ?d a) oo ?iXa"
  3684     unfolding inverse_mult_eq_1[OF da0] by simp
  3685   then have "?d ?ia oo (a oo ?iXa) =  (?d b / ?d a) oo ?iXa"
  3686     unfolding fps_compose_assoc[OF iXa0 a0] .
  3687   then show ?thesis unfolding fps_inv_ginv[symmetric]
  3688     unfolding fps_inv_right[OF a0 a1] by simp
  3689 qed
  3690 
  3691 lemma fps_compose_linear:
  3692   "fps_compose (f :: 'a :: comm_ring_1 fps) (fps_const c * X) = Abs_fps (\<lambda>n. c^n * f $ n)"
  3693   by (simp add: fps_eq_iff fps_compose_def power_mult_distrib
  3694                 if_distrib sum.delta' cong: if_cong)
  3695 
  3696 subsection \<open>Elementary series\<close>
  3697 
  3698 subsubsection \<open>Exponential series\<close>
  3699 
  3700 definition "E x = Abs_fps (\<lambda>n. x^n / of_nat (fact n))"
  3701 
  3702 lemma E_deriv[simp]: "fps_deriv (E a) = fps_const (a::'a::field_char_0) * E a" (is "?l = ?r")
  3703 proof -
  3704   have "?l$n = ?r $ n" for n
  3705     apply (auto simp add: E_def field_simps power_Suc[symmetric]
  3706       simp del: fact_Suc of_nat_Suc power_Suc)
  3707     apply (simp add: field_simps)
  3708     done
  3709   then show ?thesis
  3710     by (simp add: fps_eq_iff)
  3711 qed
  3712 
  3713 lemma E_unique_ODE:
  3714   "fps_deriv a = fps_const c * a \<longleftrightarrow> a = fps_const (a$0) * E (c::'a::field_char_0)"
  3715   (is "?lhs \<longleftrightarrow> ?rhs")
  3716 proof
  3717   show ?rhs if ?lhs
  3718   proof -
  3719     from that have th: "\<And>n. a $ Suc n = c * a$n / of_nat (Suc n)"
  3720       by (simp add: fps_deriv_def fps_eq_iff field_simps del: of_nat_Suc)
  3721     have th': "a$n = a$0 * c ^ n/ (fact n)" for n
  3722     proof (induct n)
  3723       case 0
  3724       then show ?case by simp
  3725     next
  3726       case Suc
  3727       then show ?case
  3728         unfolding th
  3729         using fact_gt_zero
  3730         apply (simp add: field_simps del: of_nat_Suc fact_Suc)
  3731         apply simp
  3732         done
  3733     qed
  3734     show ?thesis
  3735       by (auto simp add: fps_eq_iff fps_const_mult_left E_def intro: th')
  3736   qed
  3737   show ?lhs if ?rhs
  3738     using that by (metis E_deriv fps_deriv_mult_const_left mult.left_commute)
  3739 qed
  3740 
  3741 lemma E_add_mult: "E (a + b) = E (a::'a::field_char_0) * E b" (is "?l = ?r")
  3742 proof -
  3743   have "fps_deriv ?r = fps_const (a + b) * ?r"
  3744     by (simp add: fps_const_add[symmetric] field_simps del: fps_const_add)
  3745   then have "?r = ?l"
  3746     by (simp only: E_unique_ODE) (simp add: fps_mult_nth E_def)
  3747   then show ?thesis ..
  3748 qed
  3749 
  3750 lemma E_nth[simp]: "E a $ n = a^n / of_nat (fact n)"
  3751   by (simp add: E_def)
  3752 
  3753 lemma E0[simp]: "E (0::'a::field) = 1"
  3754   by (simp add: fps_eq_iff power_0_left)
  3755 
  3756 lemma E_neg: "E (- a) = inverse (E (a::'a::field_char_0))"
  3757 proof -
  3758   from E_add_mult[of a "- a"] have th0: "E a * E (- a) = 1" by simp
  3759   from fps_inverse_unique[OF th0] show ?thesis by simp
  3760 qed
  3761 
  3762 lemma E_nth_deriv[simp]: "fps_nth_deriv n (E (a::'a::field_char_0)) = (fps_const a)^n * (E a)"
  3763   by (induct n) auto
  3764 
  3765 lemma X_compose_E[simp]: "X oo E (a::'a::field) = E a - 1"
  3766   by (simp add: fps_eq_iff X_fps_compose)
  3767 
  3768 lemma LE_compose:
  3769   assumes a: "a \<noteq> 0"
  3770   shows "fps_inv (E a - 1) oo (E a - 1) = X"
  3771     and "(E a - 1) oo fps_inv (E a - 1) = X"
  3772 proof -
  3773   let ?b = "E a - 1"
  3774   have b0: "?b $ 0 = 0"
  3775     by simp
  3776   have b1: "?b $ 1 \<noteq> 0"
  3777     by (simp add: a)
  3778   from fps_inv[OF b0 b1] show "fps_inv (E a - 1) oo (E a - 1) = X" .
  3779   from fps_inv_right[OF b0 b1] show "(E a - 1) oo fps_inv (E a - 1) = X" .
  3780 qed
  3781 
  3782 lemma E_power_mult: "(E (c::'a::field_char_0))^n = E (of_nat n * c)"
  3783   by (induct n) (auto simp add: field_simps E_add_mult)
  3784 
  3785 lemma radical_E:
  3786   assumes r: "r (Suc k) 1 = 1"
  3787   shows "fps_radical r (Suc k) (E (c::'a::field_char_0)) = E (c / of_nat (Suc k))"
  3788 proof -
  3789   let ?ck = "(c / of_nat (Suc k))"
  3790   let ?r = "fps_radical r (Suc k)"
  3791   have eq0[simp]: "?ck * of_nat (Suc k) = c" "of_nat (Suc k) * ?ck = c"
  3792     by (simp_all del: of_nat_Suc)
  3793   have th0: "E ?ck ^ (Suc k) = E c" unfolding E_power_mult eq0 ..
  3794   have th: "r (Suc k) (E c $0) ^ Suc k = E c $ 0"
  3795     "r (Suc k) (E c $ 0) = E ?ck $ 0" "E c $ 0 \<noteq> 0" using r by simp_all
  3796   from th0 radical_unique[where r=r and k=k, OF th] show ?thesis
  3797     by auto
  3798 qed
  3799 
  3800 lemma Ec_E1_eq: "E (1::'a::field_char_0) oo (fps_const c * X) = E c"
  3801   apply (auto simp add: fps_eq_iff E_def fps_compose_def power_mult_distrib)
  3802   apply (simp add: cond_value_iff cond_application_beta sum.delta' cong del: if_weak_cong)
  3803   done
  3804 
  3805 
  3806 subsubsection \<open>Logarithmic series\<close>
  3807 
  3808 lemma Abs_fps_if_0:
  3809   "Abs_fps (\<lambda>n. if n = 0 then (v::'a::ring_1) else f n) =
  3810     fps_const v + X * Abs_fps (\<lambda>n. f (Suc n))"
  3811   by (auto simp add: fps_eq_iff)
  3812 
  3813 definition L :: "'a::field_char_0 \<Rightarrow> 'a fps"
  3814   where "L c = fps_const (1/c) * Abs_fps (\<lambda>n. if n = 0 then 0 else (- 1) ^ (n - 1) / of_nat n)"
  3815 
  3816 lemma fps_deriv_L: "fps_deriv (L c) = fps_const (1/c) * inverse (1 + X)"
  3817   unfolding fps_inverse_X_plus1
  3818   by (simp add: L_def fps_eq_iff del: of_nat_Suc)
  3819 
  3820 lemma L_nth: "L c $ n = (if n = 0 then 0 else 1/c * ((- 1) ^ (n - 1) / of_nat n))"
  3821   by (simp add: L_def field_simps)
  3822 
  3823 lemma L_0[simp]: "L c $ 0 = 0" by (simp add: L_def)
  3824 
  3825 lemma L_E_inv:
  3826   fixes a :: "'a::field_char_0"
  3827   assumes a: "a \<noteq> 0"
  3828   shows "L a = fps_inv (E a - 1)"  (is "?l = ?r")
  3829 proof -
  3830   let ?b = "E a - 1"
  3831   have b0: "?b $ 0 = 0" by simp
  3832   have b1: "?b $ 1 \<noteq> 0" by (simp add: a)
  3833   have "fps_deriv (E a - 1) oo fps_inv (E a - 1) =
  3834     (fps_const a * (E a - 1) + fps_const a) oo fps_inv (E a - 1)"
  3835     by (simp add: field_simps)
  3836   also have "\<dots> = fps_const a * (X + 1)"
  3837     apply (simp add: fps_compose_add_distrib fps_const_mult_apply_left[symmetric] fps_inv_right[OF b0 b1])
  3838     apply (simp add: field_simps)
  3839     done
  3840   finally have eq: "fps_deriv (E a - 1) oo fps_inv (E a - 1) = fps_const a * (X + 1)" .
  3841   from fps_inv_deriv[OF b0 b1, unfolded eq]
  3842   have "fps_deriv (fps_inv ?b) = fps_const (inverse a) / (X + 1)"
  3843     using a
  3844     by (simp add: fps_const_inverse eq fps_divide_def fps_inverse_mult)
  3845   then have "fps_deriv ?l = fps_deriv ?r"
  3846     by (simp add: fps_deriv_L add.commute fps_divide_def divide_inverse)
  3847   then show ?thesis unfolding fps_deriv_eq_iff
  3848     by (simp add: L_nth fps_inv_def)
  3849 qed
  3850 
  3851 lemma L_mult_add:
  3852   assumes c0: "c\<noteq>0"
  3853     and d0: "d\<noteq>0"
  3854   shows "L c + L d = fps_const (c+d) * L (c*d)"
  3855   (is "?r = ?l")
  3856 proof-
  3857   from c0 d0 have eq: "1/c + 1/d = (c+d)/(c*d)" by (simp add: field_simps)
  3858   have "fps_deriv ?r = fps_const (1/c + 1/d) * inverse (1 + X)"
  3859     by (simp add: fps_deriv_L fps_const_add[symmetric] algebra_simps del: fps_const_add)
  3860   also have "\<dots> = fps_deriv ?l"
  3861     apply (simp add: fps_deriv_L)
  3862     apply (simp add: fps_eq_iff eq)
  3863     done
  3864   finally show ?thesis
  3865     unfolding fps_deriv_eq_iff by simp
  3866 qed
  3867 
  3868 
  3869 subsubsection \<open>Binomial series\<close>
  3870 
  3871 definition "fps_binomial a = Abs_fps (\<lambda>n. a gchoose n)"
  3872 
  3873 lemma fps_binomial_nth[simp]: "fps_binomial a $ n = a gchoose n"
  3874   by (simp add: fps_binomial_def)
  3875 
  3876 lemma fps_binomial_ODE_unique:
  3877   fixes c :: "'a::field_char_0"
  3878   shows "fps_deriv a = (fps_const c * a) / (1 + X) \<longleftrightarrow> a = fps_const (a$0) * fps_binomial c"
  3879   (is "?lhs \<longleftrightarrow> ?rhs")
  3880 proof
  3881   let ?da = "fps_deriv a"
  3882   let ?x1 = "(1 + X):: 'a fps"
  3883   let ?l = "?x1 * ?da"
  3884   let ?r = "fps_const c * a"
  3885 
  3886   have eq: "?l = ?r \<longleftrightarrow> ?lhs"
  3887   proof -
  3888     have x10: "?x1 $ 0 \<noteq> 0" by simp
  3889     have "?l = ?r \<longleftrightarrow> inverse ?x1 * ?l = inverse ?x1 * ?r" by simp
  3890     also have "\<dots> \<longleftrightarrow> ?da = (fps_const c * a) / ?x1"
  3891       apply (simp only: fps_divide_def  mult.assoc[symmetric] inverse_mult_eq_1[OF x10])
  3892       apply (simp add: field_simps)
  3893       done
  3894     finally show ?thesis .
  3895   qed
  3896 
  3897   show ?rhs if ?lhs
  3898   proof -
  3899     from eq that have h: "?l = ?r" ..
  3900     have th0: "a$ Suc n = ((c - of_nat n) / of_nat (Suc n)) * a $n" for n
  3901     proof -
  3902       from h have "?l $ n = ?r $ n" by simp
  3903       then show ?thesis
  3904         apply (simp add: field_simps del: of_nat_Suc)
  3905         apply (cases n)
  3906         apply (simp_all add: field_simps del: of_nat_Suc)
  3907         done
  3908     qed
  3909     have th1: "a $ n = (c gchoose n) * a $ 0" for n
  3910     proof (induct n)
  3911       case 0
  3912       then show ?case by simp
  3913     next
  3914       case (Suc m)
  3915       then show ?case
  3916         unfolding th0
  3917         apply (simp add: field_simps del: of_nat_Suc)
  3918         unfolding mult.assoc[symmetric] gbinomial_mult_1
  3919         apply (simp add: field_simps)
  3920         done
  3921     qed
  3922     show ?thesis
  3923       apply (simp add: fps_eq_iff)
  3924       apply (subst th1)
  3925       apply (simp add: field_simps)
  3926       done
  3927   qed
  3928 
  3929   show ?lhs if ?rhs
  3930   proof -
  3931     have th00: "x * (a $ 0 * y) = a $ 0 * (x * y)" for x y
  3932       by (simp add: mult.commute)
  3933     have "?l = ?r"
  3934       apply (subst \<open>?rhs\<close>)
  3935       apply (subst (2) \<open>?rhs\<close>)
  3936       apply (clarsimp simp add: fps_eq_iff field_simps)
  3937       unfolding mult.assoc[symmetric] th00 gbinomial_mult_1
  3938       apply (simp add: field_simps gbinomial_mult_1)
  3939       done
  3940     with eq show ?thesis ..
  3941   qed
  3942 qed
  3943 
  3944 lemma fps_binomial_ODE_unique':
  3945   "(fps_deriv a = fps_const c * a / (1 + X) \<and> a $ 0 = 1) \<longleftrightarrow> (a = fps_binomial c)"
  3946   by (subst fps_binomial_ODE_unique) auto
  3947 
  3948 lemma fps_binomial_deriv: "fps_deriv (fps_binomial c) = fps_const c * fps_binomial c / (1 + X)"
  3949 proof -
  3950   let ?a = "fps_binomial c"
  3951   have th0: "?a = fps_const (?a$0) * ?a" by (simp)
  3952   from iffD2[OF fps_binomial_ODE_unique, OF th0] show ?thesis .
  3953 qed
  3954 
  3955 lemma fps_binomial_add_mult: "fps_binomial (c+d) = fps_binomial c * fps_binomial d" (is "?l = ?r")
  3956 proof -
  3957   let ?P = "?r - ?l"
  3958   let ?b = "fps_binomial"
  3959   let ?db = "\<lambda>x. fps_deriv (?b x)"
  3960   have "fps_deriv ?P = ?db c * ?b d + ?b c * ?db d - ?db (c + d)"  by simp
  3961   also have "\<dots> = inverse (1 + X) *
  3962       (fps_const c * ?b c * ?b d + fps_const d * ?b c * ?b d - fps_const (c+d) * ?b (c + d))"
  3963     unfolding fps_binomial_deriv
  3964     by (simp add: fps_divide_def field_simps)
  3965   also have "\<dots> = (fps_const (c + d)/ (1 + X)) * ?P"
  3966     by (simp add: field_simps fps_divide_unit fps_const_add[symmetric] del: fps_const_add)
  3967   finally have th0: "fps_deriv ?P = fps_const (c+d) * ?P / (1 + X)"
  3968     by (simp add: fps_divide_def)
  3969   have "?P = fps_const (?P$0) * ?b (c + d)"
  3970     unfolding fps_binomial_ODE_unique[symmetric]
  3971     using th0 by simp
  3972   then have "?P = 0" by (simp add: fps_mult_nth)
  3973   then show ?thesis by simp
  3974 qed
  3975 
  3976 lemma fps_binomial_minus_one: "fps_binomial (- 1) = inverse (1 + X)"
  3977   (is "?l = inverse ?r")
  3978 proof-
  3979   have th: "?r$0 \<noteq> 0" by simp
  3980   have th': "fps_deriv (inverse ?r) = fps_const (- 1) * inverse ?r / (1 + X)"
  3981     by (simp add: fps_inverse_deriv[OF th] fps_divide_def
  3982       power2_eq_square mult.commute fps_const_neg[symmetric] del: fps_const_neg)
  3983   have eq: "inverse ?r $ 0 = 1"
  3984     by (simp add: fps_inverse_def)
  3985   from iffD1[OF fps_binomial_ODE_unique[of "inverse (1 + X)" "- 1"] th'] eq
  3986   show ?thesis by (simp add: fps_inverse_def)
  3987 qed
  3988 
  3989 lemma fps_binomial_of_nat: "fps_binomial (of_nat n) = (1 + X :: 'a :: field_char_0 fps) ^ n"
  3990 proof (cases "n = 0")
  3991   case [simp]: True
  3992   have "fps_deriv ((1 + X) ^ n :: 'a fps) = 0" by simp
  3993   also have "\<dots> = fps_const (of_nat n) * (1 + X) ^ n / (1 + X)" by (simp add: fps_binomial_def)
  3994   finally show ?thesis by (subst sym, subst fps_binomial_ODE_unique' [symmetric]) simp_all
  3995 next
  3996   case False
  3997   have "fps_deriv ((1 + X) ^ n :: 'a fps) = fps_const (of_nat n) * (1 + X) ^ (n - 1)"
  3998     by (simp add: fps_deriv_power)
  3999   also have "(1 + X :: 'a fps) $ 0 \<noteq> 0" by simp
  4000   hence "(1 + X :: 'a fps) \<noteq> 0" by (intro notI) (simp only: , simp)
  4001   with False have "(1 + X :: 'a fps) ^ (n - 1) = (1 + X) ^ n / (1 + X)"
  4002     by (cases n) (simp_all )
  4003   also have "fps_const (of_nat n :: 'a) * ((1 + X) ^ n / (1 + X)) =
  4004                fps_const (of_nat n) * (1 + X) ^ n / (1 + X)"
  4005     by (simp add: unit_div_mult_swap)
  4006   finally show ?thesis
  4007     by (subst sym, subst fps_binomial_ODE_unique' [symmetric]) (simp_all add: fps_power_nth)
  4008 qed
  4009 
  4010 lemma fps_binomial_0 [simp]: "fps_binomial 0 = 1"
  4011   using fps_binomial_of_nat[of 0] by simp
  4012   
  4013 lemma fps_binomial_power: "fps_binomial a ^ n = fps_binomial (of_nat n * a)"
  4014   by (induction n) (simp_all add: fps_binomial_add_mult ring_distribs)
  4015 
  4016 lemma fps_binomial_1: "fps_binomial 1 = 1 + X"
  4017   using fps_binomial_of_nat[of 1] by simp
  4018 
  4019 lemma fps_binomial_minus_of_nat:
  4020   "fps_binomial (- of_nat n) = inverse ((1 + X :: 'a :: field_char_0 fps) ^ n)"
  4021   by (rule sym, rule fps_inverse_unique)
  4022      (simp add: fps_binomial_of_nat [symmetric] fps_binomial_add_mult [symmetric])
  4023 
  4024 lemma one_minus_const_X_power:
  4025   "c \<noteq> 0 \<Longrightarrow> (1 - fps_const c * X) ^ n =
  4026      fps_compose (fps_binomial (of_nat n)) (-fps_const c * X)"
  4027   by (subst fps_binomial_of_nat)
  4028      (simp add: fps_compose_power [symmetric] fps_compose_add_distrib fps_const_neg [symmetric] 
  4029            del: fps_const_neg)
  4030 
  4031 lemma one_minus_X_const_neg_power:
  4032   "inverse ((1 - fps_const c * X) ^ n) = 
  4033        fps_compose (fps_binomial (-of_nat n)) (-fps_const c * X)"
  4034 proof (cases "c = 0")
  4035   case False
  4036   thus ?thesis
  4037   by (subst fps_binomial_minus_of_nat)
  4038      (simp add: fps_compose_power [symmetric] fps_inverse_compose fps_compose_add_distrib
  4039                 fps_const_neg [symmetric] del: fps_const_neg)
  4040 qed simp
  4041 
  4042 lemma X_plus_const_power:
  4043   "c \<noteq> 0 \<Longrightarrow> (X + fps_const c) ^ n =
  4044      fps_const (c^n) * fps_compose (fps_binomial (of_nat n)) (fps_const (inverse c) * X)"
  4045   by (subst fps_binomial_of_nat)
  4046      (simp add: fps_compose_power [symmetric] fps_binomial_of_nat fps_compose_add_distrib
  4047                 fps_const_power [symmetric] power_mult_distrib [symmetric] 
  4048                 algebra_simps inverse_mult_eq_1' del: fps_const_power)
  4049 
  4050 lemma X_plus_const_neg_power:
  4051   "c \<noteq> 0 \<Longrightarrow> inverse ((X + fps_const c) ^ n) =
  4052      fps_const (inverse c^n) * fps_compose (fps_binomial (-of_nat n)) (fps_const (inverse c) * X)"
  4053   by (subst fps_binomial_minus_of_nat)
  4054      (simp add: fps_compose_power [symmetric] fps_binomial_of_nat fps_compose_add_distrib
  4055                 fps_const_power [symmetric] power_mult_distrib [symmetric] fps_inverse_compose 
  4056                 algebra_simps fps_const_inverse [symmetric] fps_inverse_mult [symmetric]
  4057                 fps_inverse_power [symmetric] inverse_mult_eq_1'
  4058            del: fps_const_power)
  4059 
  4060 
  4061 lemma one_minus_const_X_neg_power':
  4062   "n > 0 \<Longrightarrow> inverse ((1 - fps_const (c :: 'a :: field_char_0) * X) ^ n) =
  4063        Abs_fps (\<lambda>k. of_nat ((n + k - 1) choose k) * c^k)"
  4064   apply (rule fps_ext)
  4065   apply (subst one_minus_X_const_neg_power, subst fps_const_neg, subst fps_compose_linear)
  4066   apply (simp add: power_mult_distrib [symmetric] mult.assoc [symmetric] 
  4067                    gbinomial_minus binomial_gbinomial of_nat_diff)
  4068   done
  4069 
  4070 text \<open>Vandermonde's Identity as a consequence.\<close>
  4071 lemma gbinomial_Vandermonde:
  4072   "sum (\<lambda>k. (a gchoose k) * (b gchoose (n - k))) {0..n} = (a + b) gchoose n"
  4073 proof -
  4074   let ?ba = "fps_binomial a"
  4075   let ?bb = "fps_binomial b"
  4076   let ?bab = "fps_binomial (a + b)"
  4077   from fps_binomial_add_mult[of a b] have "?bab $ n = (?ba * ?bb)$n" by simp
  4078   then show ?thesis by (simp add: fps_mult_nth)
  4079 qed
  4080 
  4081 lemma binomial_Vandermonde:
  4082   "sum (\<lambda>k. (a choose k) * (b choose (n - k))) {0..n} = (a + b) choose n"
  4083   using gbinomial_Vandermonde[of "(of_nat a)" "of_nat b" n]
  4084   by (simp only: binomial_gbinomial[symmetric] of_nat_mult[symmetric]
  4085                  of_nat_sum[symmetric] of_nat_add[symmetric] of_nat_eq_iff)
  4086 
  4087 lemma binomial_Vandermonde_same: "sum (\<lambda>k. (n choose k)\<^sup>2) {0..n} = (2 * n) choose n"
  4088   using binomial_Vandermonde[of n n n, symmetric]
  4089   unfolding mult_2
  4090   apply (simp add: power2_eq_square)
  4091   apply (rule sum.cong)
  4092   apply (auto intro:  binomial_symmetric)
  4093   done
  4094 
  4095 lemma Vandermonde_pochhammer_lemma:
  4096   fixes a :: "'a::field_char_0"
  4097   assumes b: "\<forall>j\<in>{0 ..<n}. b \<noteq> of_nat j"
  4098   shows "sum (\<lambda>k. (pochhammer (- a) k * pochhammer (- (of_nat n)) k) /
  4099       (of_nat (fact k) * pochhammer (b - of_nat n + 1) k)) {0..n} =
  4100     pochhammer (- (a + b)) n / pochhammer (- b) n"
  4101   (is "?l = ?r")
  4102 proof -
  4103   let ?m1 = "\<lambda>m. (- 1 :: 'a) ^ m"
  4104   let ?f = "\<lambda>m. of_nat (fact m)"
  4105   let ?p = "\<lambda>(x::'a). pochhammer (- x)"
  4106   from b have bn0: "?p b n \<noteq> 0"
  4107     unfolding pochhammer_eq_0_iff by simp
  4108   have th00:
  4109     "b gchoose (n - k) =
  4110         (?m1 n * ?p b n * ?m1 k * ?p (of_nat n) k) / (?f n * pochhammer (b - of_nat n + 1) k)"
  4111       (is ?gchoose)
  4112     "pochhammer (1 + b - of_nat n) k \<noteq> 0"
  4113       (is ?pochhammer)
  4114     if kn: "k \<in> {0..n}" for k
  4115   proof -
  4116     from kn have "k \<le> n" by simp
  4117     have nz: "pochhammer (1 + b - of_nat n) n \<noteq> 0"
  4118     proof
  4119       assume "pochhammer (1 + b - of_nat n) n = 0"
  4120       then have c: "pochhammer (b - of_nat n + 1) n = 0"
  4121         by (simp add: algebra_simps)
  4122       then obtain j where j: "j < n" "b - of_nat n + 1 = - of_nat j"
  4123         unfolding pochhammer_eq_0_iff by blast
  4124       from j have "b = of_nat n - of_nat j - of_nat 1"
  4125         by (simp add: algebra_simps)
  4126       then have "b = of_nat (n - j - 1)"
  4127         using j kn by (simp add: of_nat_diff)
  4128       with b show False using j by auto
  4129     qed
  4130 
  4131     from nz kn [simplified] have nz': "pochhammer (1 + b - of_nat n) k \<noteq> 0"
  4132       by (rule pochhammer_neq_0_mono)
  4133 
  4134     consider "k = 0 \<or> n = 0" | "k \<noteq> 0" "n \<noteq> 0"
  4135       by blast
  4136     then have "b gchoose (n - k) =
  4137       (?m1 n * ?p b n * ?m1 k * ?p (of_nat n) k) / (?f n * pochhammer (b - of_nat n + 1) k)"
  4138     proof cases
  4139       case 1
  4140       then show ?thesis
  4141         using kn by (cases "k = 0") (simp_all add: gbinomial_pochhammer)
  4142     next
  4143       case neq: 2
  4144       then obtain m where m: "n = Suc m"
  4145         by (cases n) auto
  4146       from neq(1) obtain h where h: "k = Suc h"
  4147         by (cases k) auto
  4148       show ?thesis
  4149       proof (cases "k = n")
  4150         case True
  4151         then show ?thesis
  4152           using pochhammer_minus'[where k=k and b=b]
  4153           apply (simp add: pochhammer_same)
  4154           using bn0
  4155           apply (simp add: field_simps power_add[symmetric])
  4156           done
  4157       next
  4158         case False
  4159         with kn have kn': "k < n"
  4160           by simp
  4161         have m1nk: "?m1 n = prod (\<lambda>i. - 1) {..m}" "?m1 k = prod (\<lambda>i. - 1) {0..h}"
  4162           by (simp_all add: prod_constant m h)
  4163         have bnz0: "pochhammer (b - of_nat n + 1) k \<noteq> 0"
  4164           using bn0 kn
  4165           unfolding pochhammer_eq_0_iff
  4166           apply auto
  4167           apply (erule_tac x= "n - ka - 1" in allE)
  4168           apply (auto simp add: algebra_simps of_nat_diff)
  4169           done
  4170         have eq1: "prod (\<lambda>k. (1::'a) + of_nat m - of_nat k) {..h} =
  4171           prod of_nat {Suc (m - h) .. Suc m}"
  4172           using kn' h m
  4173           by (intro prod.reindex_bij_witness[where i="\<lambda>k. Suc m - k" and j="\<lambda>k. Suc m - k"])
  4174              (auto simp: of_nat_diff)
  4175         have th1: "(?m1 k * ?p (of_nat n) k) / ?f n = 1 / of_nat(fact (n - k))"
  4176           apply (simp add: pochhammer_minus field_simps)
  4177           using \<open>k \<le> n\<close> apply (simp add: fact_split [of k n])
  4178           apply (simp add: pochhammer_prod)
  4179           using prod.atLeast_lessThan_shift_bounds [where ?'a = 'a, of "\<lambda>i. 1 + of_nat i" 0 "n - k" k]
  4180           apply (auto simp add: of_nat_diff field_simps)
  4181           done
  4182         have th20: "?m1 n * ?p b n = prod (\<lambda>i. b - of_nat i) {0..m}"
  4183           apply (simp add: pochhammer_minus field_simps m)
  4184           apply (auto simp add: pochhammer_prod_rev of_nat_diff prod.atLeast_Suc_atMost_Suc_shift)
  4185           done
  4186         have th21:"pochhammer (b - of_nat n + 1) k = prod (\<lambda>i. b - of_nat i) {n - k .. n - 1}"
  4187           using kn apply (simp add: pochhammer_prod_rev m h prod.atLeast_Suc_atMost_Suc_shift)
  4188           using prod.atLeast_atMost_shift_0 [of "m - h" m, where ?'a = 'a]
  4189           apply (auto simp add: of_nat_diff field_simps)
  4190           done
  4191         have "?m1 n * ?p b n =
  4192           prod (\<lambda>i. b - of_nat i) {0.. n - k - 1} * pochhammer (b - of_nat n + 1) k"
  4193           using kn' m h unfolding th20 th21 apply simp
  4194           apply (subst prod.union_disjoint [symmetric])
  4195           apply auto
  4196           apply (rule prod.cong)
  4197           apply auto
  4198           done
  4199         then have th2: "(?m1 n * ?p b n)/pochhammer (b - of_nat n + 1) k =
  4200           prod (\<lambda>i. b - of_nat i) {0.. n - k - 1}"
  4201           using nz' by (simp add: field_simps)
  4202         have "(?m1 n * ?p b n * ?m1 k * ?p (of_nat n) k) / (?f n * pochhammer (b - of_nat n + 1) k) =
  4203           ((?m1 k * ?p (of_nat n) k) / ?f n) * ((?m1 n * ?p b n)/pochhammer (b - of_nat n + 1) k)"
  4204           using bnz0
  4205           by (simp add: field_simps)
  4206         also have "\<dots> = b gchoose (n - k)"
  4207           unfolding th1 th2
  4208           using kn' m h
  4209           apply (simp add: field_simps gbinomial_mult_fact)
  4210           apply (rule prod.cong)
  4211           apply auto
  4212           done
  4213         finally show ?thesis by simp
  4214       qed
  4215     qed
  4216     then show ?gchoose and ?pochhammer
  4217       apply (cases "n = 0")
  4218       using nz'
  4219       apply auto
  4220       done
  4221   qed
  4222   have "?r = ((a + b) gchoose n) * (of_nat (fact n) / (?m1 n * pochhammer (- b) n))"
  4223     unfolding gbinomial_pochhammer
  4224     using bn0 by (auto simp add: field_simps)
  4225   also have "\<dots> = ?l"
  4226     unfolding gbinomial_Vandermonde[symmetric]
  4227     apply (simp add: th00)
  4228     unfolding gbinomial_pochhammer
  4229     using bn0
  4230     apply (simp add: sum_distrib_right sum_distrib_left field_simps)
  4231     done
  4232   finally show ?thesis by simp
  4233 qed
  4234 
  4235 lemma Vandermonde_pochhammer:
  4236   fixes a :: "'a::field_char_0"
  4237   assumes c: "\<forall>i \<in> {0..< n}. c \<noteq> - of_nat i"
  4238   shows "sum (\<lambda>k. (pochhammer a k * pochhammer (- (of_nat n)) k) /
  4239     (of_nat (fact k) * pochhammer c k)) {0..n} = pochhammer (c - a) n / pochhammer c n"
  4240 proof -
  4241   let ?a = "- a"
  4242   let ?b = "c + of_nat n - 1"
  4243   have h: "\<forall> j \<in>{0..< n}. ?b \<noteq> of_nat j"
  4244     using c
  4245     apply (auto simp add: algebra_simps of_nat_diff)
  4246     apply (erule_tac x = "n - j - 1" in ballE)
  4247     apply (auto simp add: of_nat_diff algebra_simps)
  4248     done
  4249   have th0: "pochhammer (- (?a + ?b)) n = (- 1)^n * pochhammer (c - a) n"
  4250     unfolding pochhammer_minus
  4251     by (simp add: algebra_simps)
  4252   have th1: "pochhammer (- ?b) n = (- 1)^n * pochhammer c n"
  4253     unfolding pochhammer_minus
  4254     by simp
  4255   have nz: "pochhammer c n \<noteq> 0" using c
  4256     by (simp add: pochhammer_eq_0_iff)
  4257   from Vandermonde_pochhammer_lemma[where a = "?a" and b="?b" and n=n, OF h, unfolded th0 th1]
  4258   show ?thesis
  4259     using nz by (simp add: field_simps sum_distrib_left)
  4260 qed
  4261 
  4262 
  4263 subsubsection \<open>Formal trigonometric functions\<close>
  4264 
  4265 definition "fps_sin (c::'a::field_char_0) =
  4266   Abs_fps (\<lambda>n. if even n then 0 else (- 1) ^((n - 1) div 2) * c^n /(of_nat (fact n)))"
  4267 
  4268 definition "fps_cos (c::'a::field_char_0) =
  4269   Abs_fps (\<lambda>n. if even n then (- 1) ^ (n div 2) * c^n / (of_nat (fact n)) else 0)"
  4270 
  4271 lemma fps_sin_deriv:
  4272   "fps_deriv (fps_sin c) = fps_const c * fps_cos c"
  4273   (is "?lhs = ?rhs")
  4274 proof (rule fps_ext)
  4275   fix n :: nat
  4276   show "?lhs $ n = ?rhs $ n"
  4277   proof (cases "even n")
  4278     case True
  4279     have "?lhs$n = of_nat (n+1) * (fps_sin c $ (n+1))" by simp
  4280     also have "\<dots> = of_nat (n+1) * ((- 1)^(n div 2) * c^Suc n / of_nat (fact (Suc n)))"
  4281       using True by (simp add: fps_sin_def)
  4282     also have "\<dots> = (- 1)^(n div 2) * c^Suc n * (of_nat (n+1) / (of_nat (Suc n) * of_nat (fact n)))"
  4283       unfolding fact_Suc of_nat_mult
  4284       by (simp add: field_simps del: of_nat_add of_nat_Suc)
  4285     also have "\<dots> = (- 1)^(n div 2) *c^Suc n / of_nat (fact n)"
  4286       by (simp add: field_simps del: of_nat_add of_nat_Suc)
  4287     finally show ?thesis
  4288       using True by (simp add: fps_cos_def field_simps)
  4289   next
  4290     case False
  4291     then show ?thesis
  4292       by (simp_all add: fps_deriv_def fps_sin_def fps_cos_def)
  4293   qed
  4294 qed
  4295 
  4296 lemma fps_cos_deriv: "fps_deriv (fps_cos c) = fps_const (- c)* (fps_sin c)"
  4297   (is "?lhs = ?rhs")
  4298 proof (rule fps_ext)
  4299   have th0: "- ((- 1::'a) ^ n) = (- 1)^Suc n" for n
  4300     by simp
  4301   show "?lhs $ n = ?rhs $ n" for n
  4302   proof (cases "even n")
  4303     case False
  4304     then have n0: "n \<noteq> 0" by presburger
  4305     from False have th1: "Suc ((n - 1) div 2) = Suc n div 2"
  4306       by (cases n) simp_all
  4307     have "?lhs$n = of_nat (n+1) * (fps_cos c $ (n+1))" by simp
  4308     also have "\<dots> = of_nat (n+1) * ((- 1)^((n + 1) div 2) * c^Suc n / of_nat (fact (Suc n)))"
  4309       using False by (simp add: fps_cos_def)
  4310     also have "\<dots> = (- 1)^((n + 1) div 2)*c^Suc n * (of_nat (n+1) / (of_nat (Suc n) * of_nat (fact n)))"
  4311       unfolding fact_Suc of_nat_mult
  4312       by (simp add: field_simps del: of_nat_add of_nat_Suc)
  4313     also have "\<dots> = (- 1)^((n + 1) div 2) * c^Suc n / of_nat (fact n)"
  4314       by (simp add: field_simps del: of_nat_add of_nat_Suc)
  4315     also have "\<dots> = (- ((- 1)^((n - 1) div 2))) * c^Suc n / of_nat (fact n)"
  4316       unfolding th0 unfolding th1 by simp
  4317     finally show ?thesis
  4318       using False by (simp add: fps_sin_def field_simps)
  4319   next
  4320     case True
  4321     then show ?thesis
  4322       by (simp_all add: fps_deriv_def fps_sin_def fps_cos_def)
  4323   qed
  4324 qed
  4325 
  4326 lemma fps_sin_cos_sum_of_squares: "(fps_cos c)\<^sup>2 + (fps_sin c)\<^sup>2 = 1"
  4327   (is "?lhs = _")
  4328 proof -
  4329   have "fps_deriv ?lhs = 0"
  4330     apply (simp add:  fps_deriv_power fps_sin_deriv fps_cos_deriv)
  4331     apply (simp add: field_simps fps_const_neg[symmetric] del: fps_const_neg)
  4332     done
  4333   then have "?lhs = fps_const (?lhs $ 0)"
  4334     unfolding fps_deriv_eq_0_iff .
  4335   also have "\<dots> = 1"
  4336     by (auto simp add: fps_eq_iff numeral_2_eq_2 fps_mult_nth fps_cos_def fps_sin_def)
  4337   finally show ?thesis .
  4338 qed
  4339 
  4340 lemma fps_sin_nth_0 [simp]: "fps_sin c $ 0 = 0"
  4341   unfolding fps_sin_def by simp
  4342 
  4343 lemma fps_sin_nth_1 [simp]: "fps_sin c $ 1 = c"
  4344   unfolding fps_sin_def by simp
  4345 
  4346 lemma fps_sin_nth_add_2:
  4347     "fps_sin c $ (n + 2) = - (c * c * fps_sin c $ n / (of_nat (n + 1) * of_nat (n + 2)))"
  4348   unfolding fps_sin_def
  4349   apply (cases n)
  4350   apply simp
  4351   apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq del: of_nat_Suc fact_Suc)
  4352   apply simp
  4353   done
  4354 
  4355 lemma fps_cos_nth_0 [simp]: "fps_cos c $ 0 = 1"
  4356   unfolding fps_cos_def by simp
  4357 
  4358 lemma fps_cos_nth_1 [simp]: "fps_cos c $ 1 = 0"
  4359   unfolding fps_cos_def by simp
  4360 
  4361 lemma fps_cos_nth_add_2:
  4362   "fps_cos c $ (n + 2) = - (c * c * fps_cos c $ n / (of_nat (n + 1) * of_nat (n + 2)))"
  4363   unfolding fps_cos_def
  4364   apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq del: of_nat_Suc fact_Suc)
  4365   apply simp
  4366   done
  4367 
  4368 lemma nat_induct2: "P 0 \<Longrightarrow> P 1 \<Longrightarrow> (\<And>n. P n \<Longrightarrow> P (n + 2)) \<Longrightarrow> P (n::nat)"
  4369   unfolding One_nat_def numeral_2_eq_2
  4370   apply (induct n rule: nat_less_induct)
  4371   apply (case_tac n)
  4372   apply simp
  4373   apply (rename_tac m)
  4374   apply (case_tac m)
  4375   apply simp
  4376   apply (rename_tac k)
  4377   apply (case_tac k)
  4378   apply simp_all
  4379   done
  4380 
  4381 lemma nat_add_1_add_1: "(n::nat) + 1 + 1 = n + 2"
  4382   by simp
  4383 
  4384 lemma eq_fps_sin:
  4385   assumes 0: "a $ 0 = 0"
  4386     and 1: "a $ 1 = c"
  4387     and 2: "fps_deriv (fps_deriv a) = - (fps_const c * fps_const c * a)"
  4388   shows "a = fps_sin c"
  4389   apply (rule fps_ext)
  4390   apply (induct_tac n rule: nat_induct2)
  4391   apply (simp add: 0)
  4392   apply (simp add: 1 del: One_nat_def)
  4393   apply (rename_tac m, cut_tac f="\<lambda>a. a $ m" in arg_cong [OF 2])
  4394   apply (simp add: nat_add_1_add_1 fps_sin_nth_add_2
  4395               del: One_nat_def of_nat_Suc of_nat_add add_2_eq_Suc')
  4396   apply (subst minus_divide_left)
  4397   apply (subst nonzero_eq_divide_eq)
  4398   apply (simp del: of_nat_add of_nat_Suc)
  4399   apply (simp only: ac_simps)
  4400   done
  4401 
  4402 lemma eq_fps_cos:
  4403   assumes 0: "a $ 0 = 1"
  4404     and 1: "a $ 1 = 0"
  4405     and 2: "fps_deriv (fps_deriv a) = - (fps_const c * fps_const c * a)"
  4406   shows "a = fps_cos c"
  4407   apply (rule fps_ext)
  4408   apply (induct_tac n rule: nat_induct2)
  4409   apply (simp add: 0)
  4410   apply (simp add: 1 del: One_nat_def)
  4411   apply (rename_tac m, cut_tac f="\<lambda>a. a $ m" in arg_cong [OF 2])
  4412   apply (simp add: nat_add_1_add_1 fps_cos_nth_add_2
  4413               del: One_nat_def of_nat_Suc of_nat_add add_2_eq_Suc')
  4414   apply (subst minus_divide_left)
  4415   apply (subst nonzero_eq_divide_eq)
  4416   apply (simp del: of_nat_add of_nat_Suc)
  4417   apply (simp only: ac_simps)
  4418   done
  4419 
  4420 lemma mult_nth_0 [simp]: "(a * b) $ 0 = a $ 0 * b $ 0"
  4421   by (simp add: fps_mult_nth)
  4422 
  4423 lemma mult_nth_1 [simp]: "(a * b) $ 1 = a $ 0 * b $ 1 + a $ 1 * b $ 0"
  4424   by (simp add: fps_mult_nth)
  4425 
  4426 lemma fps_sin_add: "fps_sin (a + b) = fps_sin a * fps_cos b + fps_cos a * fps_sin b"
  4427   apply (rule eq_fps_sin [symmetric], simp, simp del: One_nat_def)
  4428   apply (simp del: fps_const_neg fps_const_add fps_const_mult
  4429               add: fps_const_add [symmetric] fps_const_neg [symmetric]
  4430                    fps_sin_deriv fps_cos_deriv algebra_simps)
  4431   done
  4432 
  4433 lemma fps_cos_add: "fps_cos (a + b) = fps_cos a * fps_cos b - fps_sin a * fps_sin b"
  4434   apply (rule eq_fps_cos [symmetric], simp, simp del: One_nat_def)
  4435   apply (simp del: fps_const_neg fps_const_add fps_const_mult
  4436               add: fps_const_add [symmetric] fps_const_neg [symmetric]
  4437                    fps_sin_deriv fps_cos_deriv algebra_simps)
  4438   done
  4439 
  4440 lemma fps_sin_even: "fps_sin (- c) = - fps_sin c"
  4441   by (auto simp add: fps_eq_iff fps_sin_def)
  4442 
  4443 lemma fps_cos_odd: "fps_cos (- c) = fps_cos c"
  4444   by (auto simp add: fps_eq_iff fps_cos_def)
  4445 
  4446 definition "fps_tan c = fps_sin c / fps_cos c"
  4447 
  4448 lemma fps_tan_deriv: "fps_deriv (fps_tan c) = fps_const c / (fps_cos c)\<^sup>2"
  4449 proof -
  4450   have th0: "fps_cos c $ 0 \<noteq> 0" by (simp add: fps_cos_def)
  4451   from this have "fps_cos c \<noteq> 0" by (intro notI) simp
  4452   hence "fps_deriv (fps_tan c) =
  4453            fps_const c * (fps_cos c^2 + fps_sin c^2) / (fps_cos c^2)"
  4454     by (simp add: fps_tan_def fps_divide_deriv power2_eq_square algebra_simps
  4455                   fps_sin_deriv fps_cos_deriv fps_const_neg[symmetric] div_mult_swap
  4456              del: fps_const_neg)
  4457   also note fps_sin_cos_sum_of_squares
  4458   finally show ?thesis by simp
  4459 qed
  4460 
  4461 text \<open>Connection to E c over the complex numbers --- Euler and de Moivre.\<close>
  4462 
  4463 lemma Eii_sin_cos: "E (\<i> * c) = fps_cos c + fps_const \<i> * fps_sin c"
  4464   (is "?l = ?r")
  4465 proof -
  4466   have "?l $ n = ?r $ n" for n
  4467   proof (cases "even n")
  4468     case True
  4469     then obtain m where m: "n = 2 * m" ..
  4470     show ?thesis
  4471       by (simp add: m fps_sin_def fps_cos_def power_mult_distrib power_mult power_minus [of "c ^ 2"])
  4472   next
  4473     case False
  4474     then obtain m where m: "n = 2 * m + 1" ..
  4475     show ?thesis
  4476       by (simp add: m fps_sin_def fps_cos_def power_mult_distrib
  4477         power_mult power_minus [of "c ^ 2"])
  4478   qed
  4479   then show ?thesis
  4480     by (simp add: fps_eq_iff)
  4481 qed
  4482 
  4483 lemma E_minus_ii_sin_cos: "E (- (\<i> * c)) = fps_cos c - fps_const \<i> * fps_sin c"
  4484   unfolding minus_mult_right Eii_sin_cos by (simp add: fps_sin_even fps_cos_odd)
  4485 
  4486 lemma fps_const_minus: "fps_const (c::'a::group_add) - fps_const d = fps_const (c - d)"
  4487   by (fact fps_const_sub)
  4488 
  4489 lemma fps_of_int: "fps_const (of_int c) = of_int c"
  4490   by (induction c) (simp_all add: fps_const_minus [symmetric] fps_of_nat fps_const_neg [symmetric] 
  4491                              del: fps_const_minus fps_const_neg)
  4492 
  4493 lemma fps_numeral_fps_const: "numeral i = fps_const (numeral i :: 'a::comm_ring_1)"
  4494   by (fact numeral_fps_const) (* FIXME: duplicate *)
  4495 
  4496 lemma fps_cos_Eii: "fps_cos c = (E (\<i> * c) + E (- \<i> * c)) / fps_const 2"
  4497 proof -
  4498   have th: "fps_cos c + fps_cos c = fps_cos c * fps_const 2"
  4499     by (simp add: numeral_fps_const)
  4500   show ?thesis
  4501     unfolding Eii_sin_cos minus_mult_commute
  4502     by (simp add: fps_sin_even fps_cos_odd numeral_fps_const fps_divide_unit fps_const_inverse th)
  4503 qed
  4504 
  4505 lemma fps_sin_Eii: "fps_sin c = (E (\<i> * c) - E (- \<i> * c)) / fps_const (2*\<i>)"
  4506 proof -
  4507   have th: "fps_const \<i> * fps_sin c + fps_const \<i> * fps_sin c = fps_sin c * fps_const (2 * \<i>)"
  4508     by (simp add: fps_eq_iff numeral_fps_const)
  4509   show ?thesis
  4510     unfolding Eii_sin_cos minus_mult_commute
  4511     by (simp add: fps_sin_even fps_cos_odd fps_divide_unit fps_const_inverse th)
  4512 qed
  4513 
  4514 lemma fps_tan_Eii:
  4515   "fps_tan c = (E (\<i> * c) - E (- \<i> * c)) / (fps_const \<i> * (E (\<i> * c) + E (- \<i> * c)))"
  4516   unfolding fps_tan_def fps_sin_Eii fps_cos_Eii mult_minus_left E_neg
  4517   apply (simp add: fps_divide_unit fps_inverse_mult fps_const_mult[symmetric] fps_const_inverse del: fps_const_mult)
  4518   apply simp
  4519   done
  4520 
  4521 lemma fps_demoivre:
  4522   "(fps_cos a + fps_const \<i> * fps_sin a)^n =
  4523     fps_cos (of_nat n * a) + fps_const \<i> * fps_sin (of_nat n * a)"
  4524   unfolding Eii_sin_cos[symmetric] E_power_mult
  4525   by (simp add: ac_simps)
  4526 
  4527 
  4528 subsection \<open>Hypergeometric series\<close>
  4529 
  4530 (* TODO: Rename this *)
  4531 definition "F as bs (c::'a::{field_char_0,field}) =
  4532   Abs_fps (\<lambda>n. (foldl (\<lambda>r a. r* pochhammer a n) 1 as * c^n) /
  4533     (foldl (\<lambda>r b. r * pochhammer b n) 1 bs * of_nat (fact n)))"
  4534 
  4535 lemma F_nth[simp]: "F as bs c $ n =
  4536   (foldl (\<lambda>r a. r* pochhammer a n) 1 as * c^n) /
  4537     (foldl (\<lambda>r b. r * pochhammer b n) 1 bs * of_nat (fact n))"
  4538   by (simp add: F_def)
  4539 
  4540 lemma foldl_mult_start:
  4541   fixes v :: "'a::comm_ring_1"
  4542   shows "foldl (\<lambda>r x. r * f x) v as * x = foldl (\<lambda>r x. r * f x) (v * x) as "
  4543   by (induct as arbitrary: x v) (auto simp add: algebra_simps)
  4544 
  4545 lemma foldr_mult_foldl:
  4546   fixes v :: "'a::comm_ring_1"
  4547   shows "foldr (\<lambda>x r. r * f x) as v = foldl (\<lambda>r x. r * f x) v as"
  4548   by (induct as arbitrary: v) (auto simp add: foldl_mult_start)
  4549 
  4550 lemma F_nth_alt:
  4551   "F as bs c $ n = foldr (\<lambda>a r. r * pochhammer a n) as (c ^ n) /
  4552     foldr (\<lambda>b r. r * pochhammer b n) bs (of_nat (fact n))"
  4553   by (simp add: foldl_mult_start foldr_mult_foldl)
  4554 
  4555 lemma F_E[simp]: "F [] [] c = E c"
  4556   by (simp add: fps_eq_iff)
  4557 
  4558 lemma F_1_0[simp]: "F [1] [] c = 1/(1 - fps_const c * X)"
  4559 proof -
  4560   let ?a = "(Abs_fps (\<lambda>n. 1)) oo (fps_const c * X)"
  4561   have th0: "(fps_const c * X) $ 0 = 0" by simp
  4562   show ?thesis unfolding gp[OF th0, symmetric]
  4563     by (auto simp add: fps_eq_iff pochhammer_fact[symmetric]
  4564       fps_compose_nth power_mult_distrib cond_value_iff sum.delta' cong del: if_weak_cong)
  4565 qed
  4566 
  4567 lemma F_B[simp]: "F [-a] [] (- 1) = fps_binomial a"
  4568   by (simp add: fps_eq_iff gbinomial_pochhammer algebra_simps)
  4569 
  4570 lemma F_0[simp]: "F as bs c $ 0 = 1"
  4571   apply simp
  4572   apply (subgoal_tac "\<forall>as. foldl (\<lambda>(r::'a) (a::'a). r) 1 as = 1")
  4573   apply auto
  4574   apply (induct_tac as)
  4575   apply auto
  4576   done
  4577 
  4578 lemma foldl_prod_prod:
  4579   "foldl (\<lambda>(r::'b::comm_ring_1) (x::'a::comm_ring_1). r * f x) v as * foldl (\<lambda>r x. r * g x) w as =
  4580     foldl (\<lambda>r x. r * f x * g x) (v * w) as"
  4581   by (induct as arbitrary: v w) (auto simp add: algebra_simps)
  4582 
  4583 
  4584 lemma F_rec:
  4585   "F as bs c $ Suc n = ((foldl (\<lambda>r a. r* (a + of_nat n)) c as) /
  4586     (foldl (\<lambda>r b. r * (b + of_nat n)) (of_nat (Suc n)) bs )) * F as bs c $ n"
  4587   apply (simp del: of_nat_Suc of_nat_add fact_Suc)
  4588   apply (simp add: foldl_mult_start del: fact_Suc of_nat_Suc)
  4589   unfolding foldl_prod_prod[unfolded foldl_mult_start] pochhammer_Suc
  4590   apply (simp add: algebra_simps)
  4591   done
  4592 
  4593 lemma XD_nth[simp]: "XD a $ n = (if n = 0 then 0 else of_nat n * a$n)"
  4594   by (simp add: XD_def)
  4595 
  4596 lemma XD_0th[simp]: "XD a $ 0 = 0"
  4597   by simp
  4598 lemma XD_Suc[simp]:" XD a $ Suc n = of_nat (Suc n) * a $ Suc n"
  4599   by simp
  4600 
  4601 definition "XDp c a = XD a + fps_const c * a"
  4602 
  4603 lemma XDp_nth[simp]: "XDp c a $ n = (c + of_nat n) * a$n"
  4604   by (simp add: XDp_def algebra_simps)
  4605 
  4606 lemma XDp_commute: "XDp b \<circ> XDp (c::'a::comm_ring_1) = XDp c \<circ> XDp b"
  4607   by (auto simp add: XDp_def fun_eq_iff fps_eq_iff algebra_simps)
  4608 
  4609 lemma XDp0 [simp]: "XDp 0 = XD"
  4610   by (simp add: fun_eq_iff fps_eq_iff)
  4611 
  4612 lemma XDp_fps_integral [simp]: "XDp 0 (fps_integral a c) = X * a"
  4613   by (simp add: fps_eq_iff fps_integral_def)
  4614 
  4615 lemma F_minus_nat:
  4616   "F [- of_nat n] [- of_nat (n + m)] (c::'a::{field_char_0,field}) $ k =
  4617     (if k \<le> n then
  4618       pochhammer (- of_nat n) k * c ^ k / (pochhammer (- of_nat (n + m)) k * of_nat (fact k))
  4619      else 0)"
  4620   "F [- of_nat m] [- of_nat (m + n)] (c::'a::{field_char_0,field}) $ k =
  4621     (if k \<le> m then
  4622       pochhammer (- of_nat m) k * c ^ k / (pochhammer (- of_nat (m + n)) k * of_nat (fact k))
  4623      else 0)"
  4624   by (auto simp add: pochhammer_eq_0_iff)
  4625 
  4626 lemma sum_eq_if: "sum f {(n::nat) .. m} = (if m < n then 0 else f n + sum f {n+1 .. m})"
  4627   apply simp
  4628   apply (subst sum.insert[symmetric])
  4629   apply (auto simp add: not_less sum_head_Suc)
  4630   done
  4631 
  4632 lemma pochhammer_rec_if: "pochhammer a n = (if n = 0 then 1 else a * pochhammer (a + 1) (n - 1))"
  4633   by (cases n) (simp_all add: pochhammer_rec)
  4634 
  4635 lemma XDp_foldr_nth [simp]: "foldr (\<lambda>c r. XDp c \<circ> r) cs (\<lambda>c. XDp c a) c0 $ n =
  4636     foldr (\<lambda>c r. (c + of_nat n) * r) cs (c0 + of_nat n) * a$n"
  4637   by (induct cs arbitrary: c0) (auto simp add: algebra_simps)
  4638 
  4639 lemma genric_XDp_foldr_nth:
  4640   assumes f: "\<forall>n c a. f c a $ n = (of_nat n + k c) * a$n"
  4641   shows "foldr (\<lambda>c r. f c \<circ> r) cs (\<lambda>c. g c a) c0 $ n =
  4642     foldr (\<lambda>c r. (k c + of_nat n) * r) cs (g c0 a $ n)"
  4643   by (induct cs arbitrary: c0) (auto simp add: algebra_simps f)
  4644 
  4645 lemma dist_less_imp_nth_equal:
  4646   assumes "dist f g < inverse (2 ^ i)"
  4647     and"j \<le> i"
  4648   shows "f $ j = g $ j"
  4649 proof (rule ccontr)
  4650   assume "f $ j \<noteq> g $ j"
  4651   hence "f \<noteq> g" by auto
  4652   with assms have "i < subdegree (f - g)"
  4653     by (simp add: if_split_asm dist_fps_def)
  4654   also have "\<dots> \<le> j"
  4655     using \<open>f $ j \<noteq> g $ j\<close> by (intro subdegree_leI) simp_all
  4656   finally show False using \<open>j \<le> i\<close> by simp
  4657 qed
  4658 
  4659 lemma nth_equal_imp_dist_less:
  4660   assumes "\<And>j. j \<le> i \<Longrightarrow> f $ j = g $ j"
  4661   shows "dist f g < inverse (2 ^ i)"
  4662 proof (cases "f = g")
  4663   case True
  4664   then show ?thesis by simp
  4665 next
  4666   case False
  4667   with assms have "dist f g = inverse (2 ^ subdegree (f - g))"
  4668     by (simp add: if_split_asm dist_fps_def)
  4669   moreover
  4670   from assms and False have "i < subdegree (f - g)"
  4671     by (intro subdegree_greaterI) simp_all
  4672   ultimately show ?thesis by simp
  4673 qed
  4674 
  4675 lemma dist_less_eq_nth_equal: "dist f g < inverse (2 ^ i) \<longleftrightarrow> (\<forall>j \<le> i. f $ j = g $ j)"
  4676   using dist_less_imp_nth_equal nth_equal_imp_dist_less by blast
  4677 
  4678 instance fps :: (comm_ring_1) complete_space
  4679 proof
  4680   fix X :: "nat \<Rightarrow> 'a fps"
  4681   assume "Cauchy X"
  4682   obtain M where M: "\<forall>i. \<forall>m \<ge> M i. \<forall>j \<le> i. X (M i) $ j = X m $ j"
  4683   proof -
  4684     have "\<exists>M. \<forall>m \<ge> M. \<forall>j\<le>i. X M $ j = X m $ j" for i
  4685     proof -
  4686       have "0 < inverse ((2::real)^i)" by simp
  4687       from metric_CauchyD[OF \<open>Cauchy X\<close> this] dist_less_imp_nth_equal
  4688       show ?thesis by blast
  4689     qed
  4690     then show ?thesis using that by metis
  4691   qed
  4692 
  4693   show "convergent X"
  4694   proof (rule convergentI)
  4695     show "X \<longlonglongrightarrow> Abs_fps (\<lambda>i. X (M i) $ i)"
  4696       unfolding tendsto_iff
  4697     proof safe
  4698       fix e::real assume e: "0 < e"
  4699       have "(\<lambda>n. inverse (2 ^ n) :: real) \<longlonglongrightarrow> 0" by (rule LIMSEQ_inverse_realpow_zero) simp_all
  4700       from this and e have "eventually (\<lambda>i. inverse (2 ^ i) < e) sequentially"
  4701         by (rule order_tendstoD)
  4702       then obtain i where "inverse (2 ^ i) < e"
  4703         by (auto simp: eventually_sequentially)
  4704       have "eventually (\<lambda>x. M i \<le> x) sequentially"
  4705         by (auto simp: eventually_sequentially)
  4706       then show "eventually (\<lambda>x. dist (X x) (Abs_fps (\<lambda>i. X (M i) $ i)) < e) sequentially"
  4707       proof eventually_elim
  4708         fix x
  4709         assume x: "M i \<le> x"
  4710         have "X (M i) $ j = X (M j) $ j" if "j \<le> i" for j
  4711           using M that by (metis nat_le_linear)
  4712         with x have "dist (X x) (Abs_fps (\<lambda>j. X (M j) $ j)) < inverse (2 ^ i)"
  4713           using M by (force simp: dist_less_eq_nth_equal)
  4714         also note \<open>inverse (2 ^ i) < e\<close>
  4715         finally show "dist (X x) (Abs_fps (\<lambda>j. X (M j) $ j)) < e" .
  4716       qed
  4717     qed
  4718   qed
  4719 qed
  4720 
  4721 end