src/HOL/Wellfounded.thy
author blanchet
Fri Jan 17 10:02:50 2014 +0100 (2014-01-17)
changeset 55027 a74ea6d75571
parent 54295 45a5523d4a63
child 55932 68c5104d2204
permissions -rw-r--r--
folded 'Wellfounded_More_FP' into 'Wellfounded'
     1 (*  Title:      HOL/Wellfounded.thy
     2     Author:     Tobias Nipkow
     3     Author:     Lawrence C Paulson
     4     Author:     Konrad Slind
     5     Author:     Alexander Krauss
     6     Author:     Andrei Popescu, TU Muenchen
     7 *)
     8 
     9 header {*Well-founded Recursion*}
    10 
    11 theory Wellfounded
    12 imports Transitive_Closure
    13 begin
    14 
    15 subsection {* Basic Definitions *}
    16 
    17 definition wf :: "('a * 'a) set => bool" where
    18   "wf r \<longleftrightarrow> (!P. (!x. (!y. (y,x):r --> P(y)) --> P(x)) --> (!x. P(x)))"
    19 
    20 definition wfP :: "('a => 'a => bool) => bool" where
    21   "wfP r \<longleftrightarrow> wf {(x, y). r x y}"
    22 
    23 lemma wfP_wf_eq [pred_set_conv]: "wfP (\<lambda>x y. (x, y) \<in> r) = wf r"
    24   by (simp add: wfP_def)
    25 
    26 lemma wfUNIVI: 
    27    "(!!P x. (ALL x. (ALL y. (y,x) : r --> P(y)) --> P(x)) ==> P(x)) ==> wf(r)"
    28   unfolding wf_def by blast
    29 
    30 lemmas wfPUNIVI = wfUNIVI [to_pred]
    31 
    32 text{*Restriction to domain @{term A} and range @{term B}.  If @{term r} is
    33     well-founded over their intersection, then @{term "wf r"}*}
    34 lemma wfI: 
    35  "[| r \<subseteq> A <*> B; 
    36      !!x P. [|\<forall>x. (\<forall>y. (y,x) : r --> P y) --> P x;  x : A; x : B |] ==> P x |]
    37   ==>  wf r"
    38   unfolding wf_def by blast
    39 
    40 lemma wf_induct: 
    41     "[| wf(r);           
    42         !!x.[| ALL y. (y,x): r --> P(y) |] ==> P(x)  
    43      |]  ==>  P(a)"
    44   unfolding wf_def by blast
    45 
    46 lemmas wfP_induct = wf_induct [to_pred]
    47 
    48 lemmas wf_induct_rule = wf_induct [rule_format, consumes 1, case_names less, induct set: wf]
    49 
    50 lemmas wfP_induct_rule = wf_induct_rule [to_pred, induct set: wfP]
    51 
    52 lemma wf_not_sym: "wf r ==> (a, x) : r ==> (x, a) ~: r"
    53   by (induct a arbitrary: x set: wf) blast
    54 
    55 lemma wf_asym:
    56   assumes "wf r" "(a, x) \<in> r"
    57   obtains "(x, a) \<notin> r"
    58   by (drule wf_not_sym[OF assms])
    59 
    60 lemma wf_not_refl [simp]: "wf r ==> (a, a) ~: r"
    61   by (blast elim: wf_asym)
    62 
    63 lemma wf_irrefl: assumes "wf r" obtains "(a, a) \<notin> r"
    64 by (drule wf_not_refl[OF assms])
    65 
    66 lemma wf_wellorderI:
    67   assumes wf: "wf {(x::'a::ord, y). x < y}"
    68   assumes lin: "OFCLASS('a::ord, linorder_class)"
    69   shows "OFCLASS('a::ord, wellorder_class)"
    70 using lin by (rule wellorder_class.intro)
    71   (blast intro: class.wellorder_axioms.intro wf_induct_rule [OF wf])
    72 
    73 lemma (in wellorder) wf:
    74   "wf {(x, y). x < y}"
    75 unfolding wf_def by (blast intro: less_induct)
    76 
    77 
    78 subsection {* Basic Results *}
    79 
    80 text {* Point-free characterization of well-foundedness *}
    81 
    82 lemma wfE_pf:
    83   assumes wf: "wf R"
    84   assumes a: "A \<subseteq> R `` A"
    85   shows "A = {}"
    86 proof -
    87   { fix x
    88     from wf have "x \<notin> A"
    89     proof induct
    90       fix x assume "\<And>y. (y, x) \<in> R \<Longrightarrow> y \<notin> A"
    91       then have "x \<notin> R `` A" by blast
    92       with a show "x \<notin> A" by blast
    93     qed
    94   } thus ?thesis by auto
    95 qed
    96 
    97 lemma wfI_pf:
    98   assumes a: "\<And>A. A \<subseteq> R `` A \<Longrightarrow> A = {}"
    99   shows "wf R"
   100 proof (rule wfUNIVI)
   101   fix P :: "'a \<Rightarrow> bool" and x
   102   let ?A = "{x. \<not> P x}"
   103   assume "\<forall>x. (\<forall>y. (y, x) \<in> R \<longrightarrow> P y) \<longrightarrow> P x"
   104   then have "?A \<subseteq> R `` ?A" by blast
   105   with a show "P x" by blast
   106 qed
   107 
   108 text{*Minimal-element characterization of well-foundedness*}
   109 
   110 lemma wfE_min:
   111   assumes wf: "wf R" and Q: "x \<in> Q"
   112   obtains z where "z \<in> Q" "\<And>y. (y, z) \<in> R \<Longrightarrow> y \<notin> Q"
   113   using Q wfE_pf[OF wf, of Q] by blast
   114 
   115 lemma wfI_min:
   116   assumes a: "\<And>x Q. x \<in> Q \<Longrightarrow> \<exists>z\<in>Q. \<forall>y. (y, z) \<in> R \<longrightarrow> y \<notin> Q"
   117   shows "wf R"
   118 proof (rule wfI_pf)
   119   fix A assume b: "A \<subseteq> R `` A"
   120   { fix x assume "x \<in> A"
   121     from a[OF this] b have "False" by blast
   122   }
   123   thus "A = {}" by blast
   124 qed
   125 
   126 lemma wf_eq_minimal: "wf r = (\<forall>Q x. x\<in>Q --> (\<exists>z\<in>Q. \<forall>y. (y,z)\<in>r --> y\<notin>Q))"
   127 apply auto
   128 apply (erule wfE_min, assumption, blast)
   129 apply (rule wfI_min, auto)
   130 done
   131 
   132 lemmas wfP_eq_minimal = wf_eq_minimal [to_pred]
   133 
   134 text{* Well-foundedness of transitive closure *}
   135 
   136 lemma wf_trancl:
   137   assumes "wf r"
   138   shows "wf (r^+)"
   139 proof -
   140   {
   141     fix P and x
   142     assume induct_step: "!!x. (!!y. (y, x) : r^+ ==> P y) ==> P x"
   143     have "P x"
   144     proof (rule induct_step)
   145       fix y assume "(y, x) : r^+"
   146       with `wf r` show "P y"
   147       proof (induct x arbitrary: y)
   148         case (less x)
   149         note hyp = `\<And>x' y'. (x', x) : r ==> (y', x') : r^+ ==> P y'`
   150         from `(y, x) : r^+` show "P y"
   151         proof cases
   152           case base
   153           show "P y"
   154           proof (rule induct_step)
   155             fix y' assume "(y', y) : r^+"
   156             with `(y, x) : r` show "P y'" by (rule hyp [of y y'])
   157           qed
   158         next
   159           case step
   160           then obtain x' where "(x', x) : r" and "(y, x') : r^+" by simp
   161           then show "P y" by (rule hyp [of x' y])
   162         qed
   163       qed
   164     qed
   165   } then show ?thesis unfolding wf_def by blast
   166 qed
   167 
   168 lemmas wfP_trancl = wf_trancl [to_pred]
   169 
   170 lemma wf_converse_trancl: "wf (r^-1) ==> wf ((r^+)^-1)"
   171   apply (subst trancl_converse [symmetric])
   172   apply (erule wf_trancl)
   173   done
   174 
   175 text {* Well-foundedness of subsets *}
   176 
   177 lemma wf_subset: "[| wf(r);  p<=r |] ==> wf(p)"
   178   apply (simp (no_asm_use) add: wf_eq_minimal)
   179   apply fast
   180   done
   181 
   182 lemmas wfP_subset = wf_subset [to_pred]
   183 
   184 text {* Well-foundedness of the empty relation *}
   185 
   186 lemma wf_empty [iff]: "wf {}"
   187   by (simp add: wf_def)
   188 
   189 lemma wfP_empty [iff]:
   190   "wfP (\<lambda>x y. False)"
   191 proof -
   192   have "wfP bot" by (fact wf_empty [to_pred bot_empty_eq2])
   193   then show ?thesis by (simp add: bot_fun_def)
   194 qed
   195 
   196 lemma wf_Int1: "wf r ==> wf (r Int r')"
   197   apply (erule wf_subset)
   198   apply (rule Int_lower1)
   199   done
   200 
   201 lemma wf_Int2: "wf r ==> wf (r' Int r)"
   202   apply (erule wf_subset)
   203   apply (rule Int_lower2)
   204   done  
   205 
   206 text {* Exponentiation *}
   207 
   208 lemma wf_exp:
   209   assumes "wf (R ^^ n)"
   210   shows "wf R"
   211 proof (rule wfI_pf)
   212   fix A assume "A \<subseteq> R `` A"
   213   then have "A \<subseteq> (R ^^ n) `` A" by (induct n) force+
   214   with `wf (R ^^ n)`
   215   show "A = {}" by (rule wfE_pf)
   216 qed
   217 
   218 text {* Well-foundedness of insert *}
   219 
   220 lemma wf_insert [iff]: "wf(insert (y,x) r) = (wf(r) & (x,y) ~: r^*)"
   221 apply (rule iffI)
   222  apply (blast elim: wf_trancl [THEN wf_irrefl]
   223               intro: rtrancl_into_trancl1 wf_subset 
   224                      rtrancl_mono [THEN [2] rev_subsetD])
   225 apply (simp add: wf_eq_minimal, safe)
   226 apply (rule allE, assumption, erule impE, blast) 
   227 apply (erule bexE)
   228 apply (rename_tac "a", case_tac "a = x")
   229  prefer 2
   230 apply blast 
   231 apply (case_tac "y:Q")
   232  prefer 2 apply blast
   233 apply (rule_tac x = "{z. z:Q & (z,y) : r^*}" in allE)
   234  apply assumption
   235 apply (erule_tac V = "ALL Q. (EX x. x : Q) --> ?P Q" in thin_rl) 
   236   --{*essential for speed*}
   237 txt{*Blast with new substOccur fails*}
   238 apply (fast intro: converse_rtrancl_into_rtrancl)
   239 done
   240 
   241 text{*Well-foundedness of image*}
   242 
   243 lemma wf_map_pair_image: "[| wf r; inj f |] ==> wf(map_pair f f ` r)"
   244 apply (simp only: wf_eq_minimal, clarify)
   245 apply (case_tac "EX p. f p : Q")
   246 apply (erule_tac x = "{p. f p : Q}" in allE)
   247 apply (fast dest: inj_onD, blast)
   248 done
   249 
   250 
   251 subsection {* Well-Foundedness Results for Unions *}
   252 
   253 lemma wf_union_compatible:
   254   assumes "wf R" "wf S"
   255   assumes "R O S \<subseteq> R"
   256   shows "wf (R \<union> S)"
   257 proof (rule wfI_min)
   258   fix x :: 'a and Q 
   259   let ?Q' = "{x \<in> Q. \<forall>y. (y, x) \<in> R \<longrightarrow> y \<notin> Q}"
   260   assume "x \<in> Q"
   261   obtain a where "a \<in> ?Q'"
   262     by (rule wfE_min [OF `wf R` `x \<in> Q`]) blast
   263   with `wf S`
   264   obtain z where "z \<in> ?Q'" and zmin: "\<And>y. (y, z) \<in> S \<Longrightarrow> y \<notin> ?Q'" by (erule wfE_min)
   265   { 
   266     fix y assume "(y, z) \<in> S"
   267     then have "y \<notin> ?Q'" by (rule zmin)
   268 
   269     have "y \<notin> Q"
   270     proof 
   271       assume "y \<in> Q"
   272       with `y \<notin> ?Q'` 
   273       obtain w where "(w, y) \<in> R" and "w \<in> Q" by auto
   274       from `(w, y) \<in> R` `(y, z) \<in> S` have "(w, z) \<in> R O S" by (rule relcompI)
   275       with `R O S \<subseteq> R` have "(w, z) \<in> R" ..
   276       with `z \<in> ?Q'` have "w \<notin> Q" by blast 
   277       with `w \<in> Q` show False by contradiction
   278     qed
   279   }
   280   with `z \<in> ?Q'` show "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> R \<union> S \<longrightarrow> y \<notin> Q" by blast
   281 qed
   282 
   283 
   284 text {* Well-foundedness of indexed union with disjoint domains and ranges *}
   285 
   286 lemma wf_UN: "[| ALL i:I. wf(r i);  
   287          ALL i:I. ALL j:I. r i ~= r j --> Domain(r i) Int Range(r j) = {}  
   288       |] ==> wf(UN i:I. r i)"
   289 apply (simp only: wf_eq_minimal, clarify)
   290 apply (rename_tac A a, case_tac "EX i:I. EX a:A. EX b:A. (b,a) : r i")
   291  prefer 2
   292  apply force 
   293 apply clarify
   294 apply (drule bspec, assumption)  
   295 apply (erule_tac x="{a. a:A & (EX b:A. (b,a) : r i) }" in allE)
   296 apply (blast elim!: allE)  
   297 done
   298 
   299 lemma wfP_SUP:
   300   "\<forall>i. wfP (r i) \<Longrightarrow> \<forall>i j. r i \<noteq> r j \<longrightarrow> inf (DomainP (r i)) (RangeP (r j)) = bot \<Longrightarrow> wfP (SUPR UNIV r)"
   301   apply (rule wf_UN[to_pred])
   302   apply simp_all
   303   done
   304 
   305 lemma wf_Union: 
   306  "[| ALL r:R. wf r;  
   307      ALL r:R. ALL s:R. r ~= s --> Domain r Int Range s = {}  
   308   |] ==> wf(Union R)"
   309   using wf_UN[of R "\<lambda>i. i"] by (simp add: SUP_def)
   310 
   311 (*Intuition: we find an (R u S)-min element of a nonempty subset A
   312              by case distinction.
   313   1. There is a step a -R-> b with a,b : A.
   314      Pick an R-min element z of the (nonempty) set {a:A | EX b:A. a -R-> b}.
   315      By definition, there is z':A s.t. z -R-> z'. Because z is R-min in the
   316      subset, z' must be R-min in A. Because z' has an R-predecessor, it cannot
   317      have an S-successor and is thus S-min in A as well.
   318   2. There is no such step.
   319      Pick an S-min element of A. In this case it must be an R-min
   320      element of A as well.
   321 
   322 *)
   323 lemma wf_Un:
   324      "[| wf r; wf s; Domain r Int Range s = {} |] ==> wf(r Un s)"
   325   using wf_union_compatible[of s r] 
   326   by (auto simp: Un_ac)
   327 
   328 lemma wf_union_merge: 
   329   "wf (R \<union> S) = wf (R O R \<union> S O R \<union> S)" (is "wf ?A = wf ?B")
   330 proof
   331   assume "wf ?A"
   332   with wf_trancl have wfT: "wf (?A^+)" .
   333   moreover have "?B \<subseteq> ?A^+"
   334     by (subst trancl_unfold, subst trancl_unfold) blast
   335   ultimately show "wf ?B" by (rule wf_subset)
   336 next
   337   assume "wf ?B"
   338 
   339   show "wf ?A"
   340   proof (rule wfI_min)
   341     fix Q :: "'a set" and x 
   342     assume "x \<in> Q"
   343 
   344     with `wf ?B`
   345     obtain z where "z \<in> Q" and "\<And>y. (y, z) \<in> ?B \<Longrightarrow> y \<notin> Q" 
   346       by (erule wfE_min)
   347     then have A1: "\<And>y. (y, z) \<in> R O R \<Longrightarrow> y \<notin> Q"
   348       and A2: "\<And>y. (y, z) \<in> S O R \<Longrightarrow> y \<notin> Q"
   349       and A3: "\<And>y. (y, z) \<in> S \<Longrightarrow> y \<notin> Q"
   350       by auto
   351     
   352     show "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> ?A \<longrightarrow> y \<notin> Q"
   353     proof (cases "\<forall>y. (y, z) \<in> R \<longrightarrow> y \<notin> Q")
   354       case True
   355       with `z \<in> Q` A3 show ?thesis by blast
   356     next
   357       case False 
   358       then obtain z' where "z'\<in>Q" "(z', z) \<in> R" by blast
   359 
   360       have "\<forall>y. (y, z') \<in> ?A \<longrightarrow> y \<notin> Q"
   361       proof (intro allI impI)
   362         fix y assume "(y, z') \<in> ?A"
   363         then show "y \<notin> Q"
   364         proof
   365           assume "(y, z') \<in> R" 
   366           then have "(y, z) \<in> R O R" using `(z', z) \<in> R` ..
   367           with A1 show "y \<notin> Q" .
   368         next
   369           assume "(y, z') \<in> S" 
   370           then have "(y, z) \<in> S O R" using  `(z', z) \<in> R` ..
   371           with A2 show "y \<notin> Q" .
   372         qed
   373       qed
   374       with `z' \<in> Q` show ?thesis ..
   375     qed
   376   qed
   377 qed
   378 
   379 lemma wf_comp_self: "wf R = wf (R O R)"  -- {* special case *}
   380   by (rule wf_union_merge [where S = "{}", simplified])
   381 
   382 
   383 subsection {* Acyclic relations *}
   384 
   385 lemma wf_acyclic: "wf r ==> acyclic r"
   386 apply (simp add: acyclic_def)
   387 apply (blast elim: wf_trancl [THEN wf_irrefl])
   388 done
   389 
   390 lemmas wfP_acyclicP = wf_acyclic [to_pred]
   391 
   392 text{* Wellfoundedness of finite acyclic relations*}
   393 
   394 lemma finite_acyclic_wf [rule_format]: "finite r ==> acyclic r --> wf r"
   395 apply (erule finite_induct, blast)
   396 apply (simp (no_asm_simp) only: split_tupled_all)
   397 apply simp
   398 done
   399 
   400 lemma finite_acyclic_wf_converse: "[|finite r; acyclic r|] ==> wf (r^-1)"
   401 apply (erule finite_converse [THEN iffD2, THEN finite_acyclic_wf])
   402 apply (erule acyclic_converse [THEN iffD2])
   403 done
   404 
   405 lemma wf_iff_acyclic_if_finite: "finite r ==> wf r = acyclic r"
   406 by (blast intro: finite_acyclic_wf wf_acyclic)
   407 
   408 
   409 subsection {* @{typ nat} is well-founded *}
   410 
   411 lemma less_nat_rel: "op < = (\<lambda>m n. n = Suc m)^++"
   412 proof (rule ext, rule ext, rule iffI)
   413   fix n m :: nat
   414   assume "m < n"
   415   then show "(\<lambda>m n. n = Suc m)^++ m n"
   416   proof (induct n)
   417     case 0 then show ?case by auto
   418   next
   419     case (Suc n) then show ?case
   420       by (auto simp add: less_Suc_eq_le le_less intro: tranclp.trancl_into_trancl)
   421   qed
   422 next
   423   fix n m :: nat
   424   assume "(\<lambda>m n. n = Suc m)^++ m n"
   425   then show "m < n"
   426     by (induct n)
   427       (simp_all add: less_Suc_eq_le reflexive le_less)
   428 qed
   429 
   430 definition
   431   pred_nat :: "(nat * nat) set" where
   432   "pred_nat = {(m, n). n = Suc m}"
   433 
   434 definition
   435   less_than :: "(nat * nat) set" where
   436   "less_than = pred_nat^+"
   437 
   438 lemma less_eq: "(m, n) \<in> pred_nat^+ \<longleftrightarrow> m < n"
   439   unfolding less_nat_rel pred_nat_def trancl_def by simp
   440 
   441 lemma pred_nat_trancl_eq_le:
   442   "(m, n) \<in> pred_nat^* \<longleftrightarrow> m \<le> n"
   443   unfolding less_eq rtrancl_eq_or_trancl by auto
   444 
   445 lemma wf_pred_nat: "wf pred_nat"
   446   apply (unfold wf_def pred_nat_def, clarify)
   447   apply (induct_tac x, blast+)
   448   done
   449 
   450 lemma wf_less_than [iff]: "wf less_than"
   451   by (simp add: less_than_def wf_pred_nat [THEN wf_trancl])
   452 
   453 lemma trans_less_than [iff]: "trans less_than"
   454   by (simp add: less_than_def)
   455 
   456 lemma less_than_iff [iff]: "((x,y): less_than) = (x<y)"
   457   by (simp add: less_than_def less_eq)
   458 
   459 lemma wf_less: "wf {(x, y::nat). x < y}"
   460   using wf_less_than by (simp add: less_than_def less_eq [symmetric])
   461 
   462 
   463 subsection {* Accessible Part *}
   464 
   465 text {*
   466  Inductive definition of the accessible part @{term "acc r"} of a
   467  relation; see also \cite{paulin-tlca}.
   468 *}
   469 
   470 inductive_set
   471   acc :: "('a * 'a) set => 'a set"
   472   for r :: "('a * 'a) set"
   473   where
   474     accI: "(!!y. (y, x) : r ==> y : acc r) ==> x : acc r"
   475 
   476 abbreviation
   477   termip :: "('a => 'a => bool) => 'a => bool" where
   478   "termip r \<equiv> accp (r\<inverse>\<inverse>)"
   479 
   480 abbreviation
   481   termi :: "('a * 'a) set => 'a set" where
   482   "termi r \<equiv> acc (r\<inverse>)"
   483 
   484 lemmas accpI = accp.accI
   485 
   486 lemma accp_eq_acc [code]:
   487   "accp r = (\<lambda>x. x \<in> Wellfounded.acc {(x, y). r x y})"
   488   by (simp add: acc_def)
   489 
   490 
   491 text {* Induction rules *}
   492 
   493 theorem accp_induct:
   494   assumes major: "accp r a"
   495   assumes hyp: "!!x. accp r x ==> \<forall>y. r y x --> P y ==> P x"
   496   shows "P a"
   497   apply (rule major [THEN accp.induct])
   498   apply (rule hyp)
   499    apply (rule accp.accI)
   500    apply fast
   501   apply fast
   502   done
   503 
   504 theorems accp_induct_rule = accp_induct [rule_format, induct set: accp]
   505 
   506 theorem accp_downward: "accp r b ==> r a b ==> accp r a"
   507   apply (erule accp.cases)
   508   apply fast
   509   done
   510 
   511 lemma not_accp_down:
   512   assumes na: "\<not> accp R x"
   513   obtains z where "R z x" and "\<not> accp R z"
   514 proof -
   515   assume a: "\<And>z. \<lbrakk>R z x; \<not> accp R z\<rbrakk> \<Longrightarrow> thesis"
   516 
   517   show thesis
   518   proof (cases "\<forall>z. R z x \<longrightarrow> accp R z")
   519     case True
   520     hence "\<And>z. R z x \<Longrightarrow> accp R z" by auto
   521     hence "accp R x"
   522       by (rule accp.accI)
   523     with na show thesis ..
   524   next
   525     case False then obtain z where "R z x" and "\<not> accp R z"
   526       by auto
   527     with a show thesis .
   528   qed
   529 qed
   530 
   531 lemma accp_downwards_aux: "r\<^sup>*\<^sup>* b a ==> accp r a --> accp r b"
   532   apply (erule rtranclp_induct)
   533    apply blast
   534   apply (blast dest: accp_downward)
   535   done
   536 
   537 theorem accp_downwards: "accp r a ==> r\<^sup>*\<^sup>* b a ==> accp r b"
   538   apply (blast dest: accp_downwards_aux)
   539   done
   540 
   541 theorem accp_wfPI: "\<forall>x. accp r x ==> wfP r"
   542   apply (rule wfPUNIVI)
   543   apply (rule_tac P=P in accp_induct)
   544    apply blast
   545   apply blast
   546   done
   547 
   548 theorem accp_wfPD: "wfP r ==> accp r x"
   549   apply (erule wfP_induct_rule)
   550   apply (rule accp.accI)
   551   apply blast
   552   done
   553 
   554 theorem wfP_accp_iff: "wfP r = (\<forall>x. accp r x)"
   555   apply (blast intro: accp_wfPI dest: accp_wfPD)
   556   done
   557 
   558 
   559 text {* Smaller relations have bigger accessible parts: *}
   560 
   561 lemma accp_subset:
   562   assumes sub: "R1 \<le> R2"
   563   shows "accp R2 \<le> accp R1"
   564 proof (rule predicate1I)
   565   fix x assume "accp R2 x"
   566   then show "accp R1 x"
   567   proof (induct x)
   568     fix x
   569     assume ih: "\<And>y. R2 y x \<Longrightarrow> accp R1 y"
   570     with sub show "accp R1 x"
   571       by (blast intro: accp.accI)
   572   qed
   573 qed
   574 
   575 
   576 text {* This is a generalized induction theorem that works on
   577   subsets of the accessible part. *}
   578 
   579 lemma accp_subset_induct:
   580   assumes subset: "D \<le> accp R"
   581     and dcl: "\<And>x z. \<lbrakk>D x; R z x\<rbrakk> \<Longrightarrow> D z"
   582     and "D x"
   583     and istep: "\<And>x. \<lbrakk>D x; (\<And>z. R z x \<Longrightarrow> P z)\<rbrakk> \<Longrightarrow> P x"
   584   shows "P x"
   585 proof -
   586   from subset and `D x`
   587   have "accp R x" ..
   588   then show "P x" using `D x`
   589   proof (induct x)
   590     fix x
   591     assume "D x"
   592       and "\<And>y. R y x \<Longrightarrow> D y \<Longrightarrow> P y"
   593     with dcl and istep show "P x" by blast
   594   qed
   595 qed
   596 
   597 
   598 text {* Set versions of the above theorems *}
   599 
   600 lemmas acc_induct = accp_induct [to_set]
   601 
   602 lemmas acc_induct_rule = acc_induct [rule_format, induct set: acc]
   603 
   604 lemmas acc_downward = accp_downward [to_set]
   605 
   606 lemmas not_acc_down = not_accp_down [to_set]
   607 
   608 lemmas acc_downwards_aux = accp_downwards_aux [to_set]
   609 
   610 lemmas acc_downwards = accp_downwards [to_set]
   611 
   612 lemmas acc_wfI = accp_wfPI [to_set]
   613 
   614 lemmas acc_wfD = accp_wfPD [to_set]
   615 
   616 lemmas wf_acc_iff = wfP_accp_iff [to_set]
   617 
   618 lemmas acc_subset = accp_subset [to_set]
   619 
   620 lemmas acc_subset_induct = accp_subset_induct [to_set]
   621 
   622 
   623 subsection {* Tools for building wellfounded relations *}
   624 
   625 text {* Inverse Image *}
   626 
   627 lemma wf_inv_image [simp,intro!]: "wf(r) ==> wf(inv_image r (f::'a=>'b))"
   628 apply (simp (no_asm_use) add: inv_image_def wf_eq_minimal)
   629 apply clarify
   630 apply (subgoal_tac "EX (w::'b) . w : {w. EX (x::'a) . x: Q & (f x = w) }")
   631 prefer 2 apply (blast del: allE)
   632 apply (erule allE)
   633 apply (erule (1) notE impE)
   634 apply blast
   635 done
   636 
   637 text {* Measure functions into @{typ nat} *}
   638 
   639 definition measure :: "('a => nat) => ('a * 'a)set"
   640 where "measure = inv_image less_than"
   641 
   642 lemma in_measure[simp, code_unfold]: "((x,y) : measure f) = (f x < f y)"
   643   by (simp add:measure_def)
   644 
   645 lemma wf_measure [iff]: "wf (measure f)"
   646 apply (unfold measure_def)
   647 apply (rule wf_less_than [THEN wf_inv_image])
   648 done
   649 
   650 lemma wf_if_measure: fixes f :: "'a \<Rightarrow> nat"
   651 shows "(!!x. P x \<Longrightarrow> f(g x) < f x) \<Longrightarrow> wf {(y,x). P x \<and> y = g x}"
   652 apply(insert wf_measure[of f])
   653 apply(simp only: measure_def inv_image_def less_than_def less_eq)
   654 apply(erule wf_subset)
   655 apply auto
   656 done
   657 
   658 
   659 text{* Lexicographic combinations *}
   660 
   661 definition lex_prod :: "('a \<times>'a) set \<Rightarrow> ('b \<times> 'b) set \<Rightarrow> (('a \<times> 'b) \<times> ('a \<times> 'b)) set" (infixr "<*lex*>" 80) where
   662   "ra <*lex*> rb = {((a, b), (a', b')). (a, a') \<in> ra \<or> a = a' \<and> (b, b') \<in> rb}"
   663 
   664 lemma wf_lex_prod [intro!]: "[| wf(ra); wf(rb) |] ==> wf(ra <*lex*> rb)"
   665 apply (unfold wf_def lex_prod_def) 
   666 apply (rule allI, rule impI)
   667 apply (simp (no_asm_use) only: split_paired_All)
   668 apply (drule spec, erule mp) 
   669 apply (rule allI, rule impI)
   670 apply (drule spec, erule mp, blast) 
   671 done
   672 
   673 lemma in_lex_prod[simp]: 
   674   "(((a,b),(a',b')): r <*lex*> s) = ((a,a'): r \<or> (a = a' \<and> (b, b') : s))"
   675   by (auto simp:lex_prod_def)
   676 
   677 text{* @{term "op <*lex*>"} preserves transitivity *}
   678 
   679 lemma trans_lex_prod [intro!]: 
   680     "[| trans R1; trans R2 |] ==> trans (R1 <*lex*> R2)"
   681 by (unfold trans_def lex_prod_def, blast) 
   682 
   683 text {* lexicographic combinations with measure functions *}
   684 
   685 definition 
   686   mlex_prod :: "('a \<Rightarrow> nat) \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" (infixr "<*mlex*>" 80)
   687 where
   688   "f <*mlex*> R = inv_image (less_than <*lex*> R) (%x. (f x, x))"
   689 
   690 lemma wf_mlex: "wf R \<Longrightarrow> wf (f <*mlex*> R)"
   691 unfolding mlex_prod_def
   692 by auto
   693 
   694 lemma mlex_less: "f x < f y \<Longrightarrow> (x, y) \<in> f <*mlex*> R"
   695 unfolding mlex_prod_def by simp
   696 
   697 lemma mlex_leq: "f x \<le> f y \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (x, y) \<in> f <*mlex*> R"
   698 unfolding mlex_prod_def by auto
   699 
   700 text {* proper subset relation on finite sets *}
   701 
   702 definition finite_psubset  :: "('a set * 'a set) set"
   703 where "finite_psubset = {(A,B). A < B & finite B}"
   704 
   705 lemma wf_finite_psubset[simp]: "wf(finite_psubset)"
   706 apply (unfold finite_psubset_def)
   707 apply (rule wf_measure [THEN wf_subset])
   708 apply (simp add: measure_def inv_image_def less_than_def less_eq)
   709 apply (fast elim!: psubset_card_mono)
   710 done
   711 
   712 lemma trans_finite_psubset: "trans finite_psubset"
   713 by (simp add: finite_psubset_def less_le trans_def, blast)
   714 
   715 lemma in_finite_psubset[simp]: "(A, B) \<in> finite_psubset = (A < B & finite B)"
   716 unfolding finite_psubset_def by auto
   717 
   718 text {* max- and min-extension of order to finite sets *}
   719 
   720 inductive_set max_ext :: "('a \<times> 'a) set \<Rightarrow> ('a set \<times> 'a set) set" 
   721 for R :: "('a \<times> 'a) set"
   722 where
   723   max_extI[intro]: "finite X \<Longrightarrow> finite Y \<Longrightarrow> Y \<noteq> {} \<Longrightarrow> (\<And>x. x \<in> X \<Longrightarrow> \<exists>y\<in>Y. (x, y) \<in> R) \<Longrightarrow> (X, Y) \<in> max_ext R"
   724 
   725 lemma max_ext_wf:
   726   assumes wf: "wf r"
   727   shows "wf (max_ext r)"
   728 proof (rule acc_wfI, intro allI)
   729   fix M show "M \<in> acc (max_ext r)" (is "_ \<in> ?W")
   730   proof cases
   731     assume "finite M"
   732     thus ?thesis
   733     proof (induct M)
   734       show "{} \<in> ?W"
   735         by (rule accI) (auto elim: max_ext.cases)
   736     next
   737       fix M a assume "M \<in> ?W" "finite M"
   738       with wf show "insert a M \<in> ?W"
   739       proof (induct arbitrary: M)
   740         fix M a
   741         assume "M \<in> ?W"  and  [intro]: "finite M"
   742         assume hyp: "\<And>b M. (b, a) \<in> r \<Longrightarrow> M \<in> ?W \<Longrightarrow> finite M \<Longrightarrow> insert b M \<in> ?W"
   743         {
   744           fix N M :: "'a set"
   745           assume "finite N" "finite M"
   746           then
   747           have "\<lbrakk>M \<in> ?W ; (\<And>y. y \<in> N \<Longrightarrow> (y, a) \<in> r)\<rbrakk> \<Longrightarrow>  N \<union> M \<in> ?W"
   748             by (induct N arbitrary: M) (auto simp: hyp)
   749         }
   750         note add_less = this
   751         
   752         show "insert a M \<in> ?W"
   753         proof (rule accI)
   754           fix N assume Nless: "(N, insert a M) \<in> max_ext r"
   755           hence asm1: "\<And>x. x \<in> N \<Longrightarrow> (x, a) \<in> r \<or> (\<exists>y \<in> M. (x, y) \<in> r)"
   756             by (auto elim!: max_ext.cases)
   757 
   758           let ?N1 = "{ n \<in> N. (n, a) \<in> r }"
   759           let ?N2 = "{ n \<in> N. (n, a) \<notin> r }"
   760           have N: "?N1 \<union> ?N2 = N" by (rule set_eqI) auto
   761           from Nless have "finite N" by (auto elim: max_ext.cases)
   762           then have finites: "finite ?N1" "finite ?N2" by auto
   763           
   764           have "?N2 \<in> ?W"
   765           proof cases
   766             assume [simp]: "M = {}"
   767             have Mw: "{} \<in> ?W" by (rule accI) (auto elim: max_ext.cases)
   768 
   769             from asm1 have "?N2 = {}" by auto
   770             with Mw show "?N2 \<in> ?W" by (simp only:)
   771           next
   772             assume "M \<noteq> {}"
   773             from asm1 finites have N2: "(?N2, M) \<in> max_ext r" 
   774               by (rule_tac max_extI[OF _ _ `M \<noteq> {}`]) auto
   775 
   776             with `M \<in> ?W` show "?N2 \<in> ?W" by (rule acc_downward)
   777           qed
   778           with finites have "?N1 \<union> ?N2 \<in> ?W" 
   779             by (rule add_less) simp
   780           then show "N \<in> ?W" by (simp only: N)
   781         qed
   782       qed
   783     qed
   784   next
   785     assume [simp]: "\<not> finite M"
   786     show ?thesis
   787       by (rule accI) (auto elim: max_ext.cases)
   788   qed
   789 qed
   790 
   791 lemma max_ext_additive: 
   792  "(A, B) \<in> max_ext R \<Longrightarrow> (C, D) \<in> max_ext R \<Longrightarrow>
   793   (A \<union> C, B \<union> D) \<in> max_ext R"
   794 by (force elim!: max_ext.cases)
   795 
   796 
   797 definition min_ext :: "('a \<times> 'a) set \<Rightarrow> ('a set \<times> 'a set) set"  where
   798   "min_ext r = {(X, Y) | X Y. X \<noteq> {} \<and> (\<forall>y \<in> Y. (\<exists>x \<in> X. (x, y) \<in> r))}"
   799 
   800 lemma min_ext_wf:
   801   assumes "wf r"
   802   shows "wf (min_ext r)"
   803 proof (rule wfI_min)
   804   fix Q :: "'a set set"
   805   fix x
   806   assume nonempty: "x \<in> Q"
   807   show "\<exists>m \<in> Q. (\<forall> n. (n, m) \<in> min_ext r \<longrightarrow> n \<notin> Q)"
   808   proof cases
   809     assume "Q = {{}}" thus ?thesis by (simp add: min_ext_def)
   810   next
   811     assume "Q \<noteq> {{}}"
   812     with nonempty
   813     obtain e x where "x \<in> Q" "e \<in> x" by force
   814     then have eU: "e \<in> \<Union>Q" by auto
   815     with `wf r` 
   816     obtain z where z: "z \<in> \<Union>Q" "\<And>y. (y, z) \<in> r \<Longrightarrow> y \<notin> \<Union>Q" 
   817       by (erule wfE_min)
   818     from z obtain m where "m \<in> Q" "z \<in> m" by auto
   819     from `m \<in> Q`
   820     show ?thesis
   821     proof (rule, intro bexI allI impI)
   822       fix n
   823       assume smaller: "(n, m) \<in> min_ext r"
   824       with `z \<in> m` obtain y where y: "y \<in> n" "(y, z) \<in> r" by (auto simp: min_ext_def)
   825       then show "n \<notin> Q" using z(2) by auto
   826     qed      
   827   qed
   828 qed
   829 
   830 text{* Bounded increase must terminate: *}
   831 
   832 lemma wf_bounded_measure:
   833 fixes ub :: "'a \<Rightarrow> nat" and f :: "'a \<Rightarrow> nat"
   834 assumes "!!a b. (b,a) : r \<Longrightarrow> ub b \<le> ub a & ub a \<ge> f b & f b > f a"
   835 shows "wf r"
   836 apply(rule wf_subset[OF wf_measure[of "%a. ub a - f a"]])
   837 apply (auto dest: assms)
   838 done
   839 
   840 lemma wf_bounded_set:
   841 fixes ub :: "'a \<Rightarrow> 'b set" and f :: "'a \<Rightarrow> 'b set"
   842 assumes "!!a b. (b,a) : r \<Longrightarrow>
   843   finite(ub a) & ub b \<subseteq> ub a & ub a \<supseteq> f b & f b \<supset> f a"
   844 shows "wf r"
   845 apply(rule wf_bounded_measure[of r "%a. card(ub a)" "%a. card(f a)"])
   846 apply(drule assms)
   847 apply (blast intro: card_mono finite_subset psubset_card_mono dest: psubset_eq[THEN iffD2])
   848 done
   849 
   850 
   851 subsection {* size of a datatype value *}
   852 
   853 ML_file "Tools/Function/size.ML"
   854 setup Size.setup
   855 
   856 lemma size_bool [code]:
   857   "size (b\<Colon>bool) = 0" by (cases b) auto
   858 
   859 lemma nat_size [simp, code]: "size (n\<Colon>nat) = n"
   860   by (induct n) simp_all
   861 
   862 declare "prod.size" [no_atp]
   863 
   864 
   865 hide_const (open) acc accp
   866 
   867 end