src/Pure/library.ML
author wenzelm
Mon May 25 21:10:45 1998 +0200 (1998-05-25)
changeset 4956 a7538e43896e
parent 4945 d8c809afafb8
child 4995 905cd6f73429
permissions -rw-r--r--
added foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list;
added seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit;
tuned 'beginning';
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic tables, balanced
     8 trees, orders, I/O and diagnostics, timing, misc.
     9 *)
    10 
    11 infix |> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 signature LIBRARY =
    16 sig
    17   (*functions*)
    18   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    19   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val |> : 'a * ('a -> 'b) -> 'b
    23   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    24   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    25   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    26 
    27   (*stamps*)
    28   type stamp
    29   val stamp: unit -> stamp
    30 
    31   (*options*)
    32   datatype 'a option = None | Some of 'a
    33   exception OPTION
    34   val the: 'a option -> 'a
    35   val if_none: 'a option -> 'a -> 'a
    36   val is_some: 'a option -> bool
    37   val is_none: 'a option -> bool
    38   val apsome: ('a -> 'b) -> 'a option -> 'b option
    39   val can: ('a -> 'b) -> 'a -> bool
    40   val try: ('a -> 'b) -> 'a -> 'b option
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    48   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    49   val swap: 'a * 'b -> 'b * 'a
    50   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    51   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    52   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    53 
    54   (*booleans*)
    55   val equal: ''a -> ''a -> bool
    56   val not_equal: ''a -> ''a -> bool
    57   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    58   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val exists: ('a -> bool) -> 'a list -> bool
    60   val forall: ('a -> bool) -> 'a list -> bool
    61   val set: bool ref -> bool
    62   val reset: bool ref -> bool
    63   val toggle: bool ref -> bool
    64   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    65 
    66   (*lists*)
    67   exception LIST of string
    68   val null: 'a list -> bool
    69   val hd: 'a list -> 'a
    70   val tl: 'a list -> 'a list
    71   val cons: 'a -> 'a list -> 'a list
    72   val append: 'a list -> 'a list -> 'a list
    73   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
    74   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
    75   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    76   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    77   val length: 'a list -> int
    78   val take: int * 'a list -> 'a list
    79   val drop: int * 'a list -> 'a list
    80   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    81   val nth_elem: int * 'a list -> 'a
    82   val last_elem: 'a list -> 'a
    83   val split_last: 'a list -> 'a list * 'a
    84   val nth_update: 'a -> int * 'a list -> 'a list
    85   val find_index: ('a -> bool) -> 'a list -> int
    86   val find_index_eq: ''a -> ''a list -> int
    87   val find_first: ('a -> bool) -> 'a list -> 'a option
    88   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    89   val flat: 'a list list -> 'a list
    90   val seq: ('a -> unit) -> 'a list -> unit
    91   val separate: 'a -> 'a list -> 'a list
    92   val replicate: int -> 'a -> 'a list
    93   val multiply: 'a list * 'a list list -> 'a list list
    94   val filter: ('a -> bool) -> 'a list -> 'a list
    95   val filter_out: ('a -> bool) -> 'a list -> 'a list
    96   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
    97   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
    98   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    99   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   100   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   101   val ~~ : 'a list * 'b list -> ('a * 'b) list
   102   val split_list: ('a * 'b) list -> 'a list * 'b list
   103   val prefix: ''a list * ''a list -> bool
   104   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   105   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   106 
   107   (*integers*)
   108   val inc: int ref -> int
   109   val dec: int ref -> int
   110   val upto: int * int -> int list
   111   val downto: int * int -> int list
   112   val downto0: int list * int -> bool
   113   val radixpand: int * int -> int list
   114   val radixstring: int * string * int -> string
   115   val string_of_int: int -> string
   116   val string_of_indexname: string * int -> string
   117 
   118   (*strings*)
   119   val beginning: string list -> string
   120   val enclose: string -> string -> string -> string
   121   val quote: string -> string
   122   val space_implode: string -> string list -> string
   123   val commas: string list -> string
   124   val commas_quote: string list -> string
   125   val cat_lines: string list -> string
   126   val space_explode: string -> string -> string list
   127   val split_lines: string -> string list
   128 
   129   (*lists as sets*)
   130   val mem: ''a * ''a list -> bool
   131   val mem_int: int * int list -> bool
   132   val mem_string: string * string list -> bool
   133   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   134   val ins: ''a * ''a list -> ''a list
   135   val ins_int: int * int list -> int list
   136   val ins_string: string * string list -> string list
   137   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   138   val union: ''a list * ''a list -> ''a list
   139   val union_int: int list * int list -> int list
   140   val union_string: string list * string list -> string list
   141   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   142   val inter: ''a list * ''a list -> ''a list
   143   val inter_int: int list * int list -> int list
   144   val inter_string: string list * string list -> string list
   145   val subset: ''a list * ''a list -> bool
   146   val subset_int: int list * int list -> bool
   147   val subset_string: string list * string list -> bool
   148   val eq_set: ''a list * ''a list -> bool
   149   val eq_set_string: string list * string list -> bool
   150   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   151   val \ : ''a list * ''a -> ''a list
   152   val \\ : ''a list * ''a list -> ''a list
   153   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   154   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   155   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   156   val distinct: ''a list -> ''a list
   157   val findrep: ''a list -> ''a list
   158   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   159   val duplicates: ''a list -> ''a list
   160 
   161   (*association lists*)
   162   val assoc: (''a * 'b) list * ''a -> 'b option
   163   val assoc_int: (int * 'a) list * int -> 'a option
   164   val assoc_string: (string * 'a) list * string -> 'a option
   165   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   166   val assocs: (''a * 'b list) list -> ''a -> 'b list
   167   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   168   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   169   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   170   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   171 
   172   (*generic tables*)
   173   val generic_extend: ('a * 'a -> bool)
   174     -> ('b -> 'a list) -> ('a list -> 'b) -> 'b -> 'a list -> 'b
   175   val generic_merge: ('a * 'a -> bool) -> ('b -> 'a list) -> ('a list -> 'b) -> 'b -> 'b -> 'b
   176   val extend_list: ''a list -> ''a list -> ''a list
   177   val merge_lists: ''a list -> ''a list -> ''a list
   178   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   179   val merge_rev_lists: ''a list -> ''a list -> ''a list
   180 
   181   (*balanced trees*)
   182   exception Balance
   183   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   184   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   185   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   186 
   187   (*orders*)
   188   datatype order = EQUAL | GREATER | LESS
   189   val rev_order: order -> order
   190   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   191   val int_ord: int * int -> order
   192   val string_ord: string * string -> order
   193   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   194   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   195   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   196   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   197   val sort_strings: string list -> string list
   198   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   199 
   200   (*I/O and diagnostics*)
   201   val cd: string -> unit
   202   val pwd: unit -> string
   203   val prs_fn: (string -> unit) ref
   204   val warning_fn: (string -> unit) ref
   205   val error_fn: (string -> unit) ref
   206   val prs: string -> unit
   207   val writeln: string -> unit
   208   val warning: string -> unit
   209   exception ERROR
   210   val error_msg: string -> unit
   211   val error: string -> 'a
   212   val sys_error: string -> 'a
   213   val assert: bool -> string -> unit
   214   val deny: bool -> string -> unit
   215   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
   216   datatype 'a error = Error of string | OK of 'a
   217   val get_error: 'a error -> string option
   218   val get_ok: 'a error -> 'a option
   219   val handle_error: ('a -> 'b) -> 'a -> 'b error
   220   exception ERROR_MESSAGE of string
   221   val transform_error: ('a -> 'b) -> 'a -> 'b
   222 
   223   (*timing*)
   224   val cond_timeit: bool -> (unit -> 'a) -> 'a
   225   val timeit: (unit -> 'a) -> 'a
   226   val timeap: ('a -> 'b) -> 'a -> 'b
   227 
   228   (*misc*)
   229   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   230   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   231   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   232   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   233   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   234   val transitive_closure: (string * string list) list -> (string * string list) list
   235   val init_gensym: unit -> unit
   236   val gensym: string -> string
   237   val bump_int_list: string list -> string list
   238   val bump_list: string list * string -> string list
   239   val bump_string: string -> string
   240   val scanwords: (string -> bool) -> string list -> string list
   241   datatype 'a mtree = Join of 'a * 'a mtree list
   242   type object
   243   val type_error: string -> 'a
   244 end;
   245 
   246 structure Library: LIBRARY =
   247 struct
   248 
   249 (** functions **)
   250 
   251 (*handy combinators*)
   252 fun curry f x y = f (x, y);
   253 fun uncurry f (x, y) = f x y;
   254 fun I x = x;
   255 fun K x y = x;
   256 
   257 (*reverse apply*)
   258 fun (x |> f) = f x;
   259 
   260 (*application of (infix) operator to its left or right argument*)
   261 fun apl (x, f) y = f (x, y);
   262 fun apr (f, y) x = f (x, y);
   263 
   264 (*function exponentiation: f(...(f x)...) with n applications of f*)
   265 fun funpow n f x =
   266   let fun rep (0, x) = x
   267         | rep (n, x) = rep (n - 1, f x)
   268   in rep (n, x) end;
   269 
   270 
   271 
   272 (** stamps **)
   273 
   274 type stamp = unit ref;
   275 val stamp: unit -> stamp = ref;
   276 
   277 
   278 
   279 (** options **)
   280 
   281 datatype 'a option = None | Some of 'a;
   282 
   283 exception OPTION;
   284 
   285 fun the (Some x) = x
   286   | the None = raise OPTION;
   287 
   288 (*strict!*)
   289 fun if_none None y = y
   290   | if_none (Some x) _ = x;
   291 
   292 fun is_some (Some _) = true
   293   | is_some None = false;
   294 
   295 fun is_none (Some _) = false
   296   | is_none None = true;
   297 
   298 fun apsome f (Some x) = Some (f x)
   299   | apsome _ None = None;
   300 
   301 (*handle partial functions*)
   302 fun can f x = (f x; true) handle _ => false;
   303 fun try f x = Some (f x) handle _ => None;
   304 
   305 
   306 
   307 (** pairs **)
   308 
   309 fun pair x y = (x, y);
   310 fun rpair x y = (y, x);
   311 
   312 fun fst (x, y) = x;
   313 fun snd (x, y) = y;
   314 
   315 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   316 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   317 
   318 fun swap (x, y) = (y, x);
   319 
   320 (*apply function to components*)
   321 fun apfst f (x, y) = (f x, y);
   322 fun apsnd f (x, y) = (x, f y);
   323 fun pairself f (x, y) = (f x, f y);
   324 
   325 
   326 
   327 (** booleans **)
   328 
   329 (* equality *)
   330 
   331 fun equal x y = x = y;
   332 fun not_equal x y = x <> y;
   333 
   334 
   335 (* operators for combining predicates *)
   336 
   337 fun (p orf q) = fn x => p x orelse q x;
   338 fun (p andf q) = fn x => p x andalso q x;
   339 
   340 
   341 (* predicates on lists *)
   342 
   343 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   344 fun exists (pred: 'a -> bool) : 'a list -> bool =
   345   let fun boolf [] = false
   346         | boolf (x :: xs) = pred x orelse boolf xs
   347   in boolf end;
   348 
   349 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   350 fun forall (pred: 'a -> bool) : 'a list -> bool =
   351   let fun boolf [] = true
   352         | boolf (x :: xs) = pred x andalso boolf xs
   353   in boolf end;
   354 
   355 
   356 (* flags *)
   357 
   358 fun set flag = (flag := true; true);
   359 fun reset flag = (flag := false; false);
   360 fun toggle flag = (flag := not (! flag); ! flag);
   361 
   362 (*temporarily set flag, handling errors*)
   363 fun setmp flag value f x =
   364   let
   365     val orig_value = ! flag;
   366     fun return y = (flag := orig_value; y);
   367   in
   368     flag := value;
   369     return (f x handle exn => (return (); raise exn))
   370   end;
   371 
   372 
   373 
   374 (** lists **)
   375 
   376 exception LIST of string;
   377 
   378 fun null [] = true
   379   | null (_ :: _) = false;
   380 
   381 fun hd [] = raise LIST "hd"
   382   | hd (x :: _) = x;
   383 
   384 fun tl [] = raise LIST "tl"
   385   | tl (_ :: xs) = xs;
   386 
   387 fun cons x xs = x :: xs;
   388 
   389 fun append xs ys = xs @ ys;
   390 
   391 
   392 (* fold *)
   393 
   394 (*the following versions of fold are designed to fit nicely with infixes*)
   395 
   396 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   397     for operators that associate to the left (TAIL RECURSIVE)*)
   398 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   399   let fun itl (e, [])  = e
   400         | itl (e, a::l) = itl (f(e, a), l)
   401   in  itl end;
   402 
   403 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   404     for operators that associate to the right (not tail recursive)*)
   405 fun foldr f (l, e) =
   406   let fun itr [] = e
   407         | itr (a::l) = f(a, itr l)
   408   in  itr l  end;
   409 
   410 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   411     for n > 0, operators that associate to the right (not tail recursive)*)
   412 fun foldr1 f l =
   413   let fun itr [x] = x
   414         | itr (x::l) = f(x, itr l)
   415   in  itr l  end;
   416 
   417 fun foldl_map _ (x, []) = (x, [])
   418   | foldl_map f (x, y :: ys) =
   419       let
   420         val (x', y') = f (x, y);
   421         val (x'', ys') = foldl_map f (x', ys);
   422       in (x'', y' :: ys') end;
   423 
   424 
   425 (* basic list functions *)
   426 
   427 (*length of a list, should unquestionably be a standard function*)
   428 local fun length1 (n, [])  = n   (*TAIL RECURSIVE*)
   429         | length1 (n, x :: xs) = length1 (n + 1, xs)
   430 in  fun length l = length1 (0, l) end;
   431 
   432 (*take the first n elements from a list*)
   433 fun take (n, []) = []
   434   | take (n, x :: xs) =
   435       if n > 0 then x :: take (n - 1, xs) else [];
   436 
   437 (*drop the first n elements from a list*)
   438 fun drop (n, []) = []
   439   | drop (n, x :: xs) =
   440       if n > 0 then drop (n - 1, xs) else x :: xs;
   441 
   442 fun dropwhile P [] = []
   443   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   444 
   445 (*return nth element of a list, where 0 designates the first element;
   446   raise EXCEPTION if list too short*)
   447 fun nth_elem NL =
   448   (case drop NL of
   449     [] => raise LIST "nth_elem"
   450   | x :: _ => x);
   451 
   452 (*last element of a list*)
   453 fun last_elem [] = raise LIST "last_elem"
   454   | last_elem [x] = x
   455   | last_elem (_ :: xs) = last_elem xs;
   456 
   457 (*rear decomposition*)
   458 fun split_last [] = raise LIST "split_last"
   459   | split_last [x] = ([], x)
   460   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   461 
   462 (*update nth element*)
   463 fun nth_update x (n, xs) =
   464   let
   465     val prfx = take (n, xs);
   466     val sffx = drop (n, xs);
   467   in
   468     (case sffx of
   469       [] => raise LIST "nth_update"
   470     | _ :: sffx' => prfx @ (x :: sffx'))
   471   end;
   472 
   473 (*find the position of an element in a list*)
   474 fun find_index pred =
   475   let fun find _ [] = ~1
   476         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   477   in find 0 end;
   478 
   479 fun find_index_eq x = find_index (equal x);
   480 
   481 (*find first element satisfying predicate*)
   482 fun find_first _ [] = None
   483   | find_first pred (x :: xs) =
   484       if pred x then Some x else find_first pred xs;
   485 
   486 (*get first element by lookup function*)
   487 fun get_first _ [] = None
   488   | get_first f (x :: xs) =
   489       (case f x of
   490         None => get_first f xs
   491       | some => some);
   492 
   493 (*flatten a list of lists to a list*)
   494 fun flat (ls: 'c list list) : 'c list = foldr (op @) (ls, []);
   495 
   496 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   497   (proc x1; ...; proc xn) for side effects*)
   498 fun seq (proc: 'a -> unit) : 'a list -> unit =
   499   let fun seqf [] = ()
   500         | seqf (x :: xs) = (proc x; seqf xs)
   501   in seqf end;
   502 
   503 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   504 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   505   | separate _ xs = xs;
   506 
   507 (*make the list [x, x, ..., x] of length n*)
   508 fun replicate n (x: 'a) : 'a list =
   509   let fun rep (0, xs) = xs
   510         | rep (n, xs) = rep (n - 1, x :: xs)
   511   in
   512     if n < 0 then raise LIST "replicate"
   513     else rep (n, [])
   514   end;
   515 
   516 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   517 fun multiply ([], _) = []
   518   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   519 
   520 
   521 (* filter *)
   522 
   523 (*copy the list preserving elements that satisfy the predicate*)
   524 fun filter (pred: 'a->bool) : 'a list -> 'a list =
   525   let fun filt [] = []
   526         | filt (x :: xs) = if pred x then x :: filt xs else filt xs
   527   in filt end;
   528 
   529 fun filter_out f = filter (not o f);
   530 
   531 fun mapfilter (f: 'a -> 'b option) ([]: 'a list) = [] : 'b list
   532   | mapfilter f (x :: xs) =
   533       (case f x of
   534         None => mapfilter f xs
   535       | Some y => y :: mapfilter f xs);
   536 
   537 
   538 (* lists of pairs *)
   539 
   540 fun map2 _ ([], []) = []
   541   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   542   | map2 _ _ = raise LIST "map2";
   543 
   544 fun exists2 _ ([], []) = false
   545   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   546   | exists2 _ _ = raise LIST "exists2";
   547 
   548 fun forall2 _ ([], []) = true
   549   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   550   | forall2 _ _ = raise LIST "forall2";
   551 
   552 fun seq2 _ ([], []) = ()
   553   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   554   | seq2 _ _ = raise LIST "seq2";
   555 
   556 (*combine two lists forming a list of pairs:
   557   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   558 fun [] ~~ [] = []
   559   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   560   | _ ~~ _ = raise LIST "~~";
   561 
   562 (*inverse of ~~; the old 'split':
   563   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   564 fun split_list (l: ('a * 'b) list) = (map #1 l, map #2 l);
   565 
   566 
   567 (* prefixes, suffixes *)
   568 
   569 fun [] prefix _ = true
   570   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   571   | _ prefix _ = false;
   572 
   573 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   574    where xi is the first element that does not satisfy the predicate*)
   575 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   576   let fun take (rxs, []) = (rev rxs, [])
   577         | take (rxs, x :: xs) =
   578             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   579   in  take([], xs)  end;
   580 
   581 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   582    where xi is the last element that does not satisfy the predicate*)
   583 fun take_suffix _ [] = ([], [])
   584   | take_suffix pred (x :: xs) =
   585       (case take_suffix pred xs of
   586         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   587       | (prfx, sffx) => (x :: prfx, sffx));
   588 
   589 
   590 
   591 (** integers **)
   592 
   593 fun inc i = (i := ! i + 1; ! i);
   594 fun dec i = (i := ! i - 1; ! i);
   595 
   596 
   597 (* lists of integers *)
   598 
   599 (*make the list [from, from + 1, ..., to]*)
   600 fun (from upto to) =
   601   if from > to then [] else from :: ((from + 1) upto to);
   602 
   603 (*make the list [from, from - 1, ..., to]*)
   604 fun (from downto to) =
   605   if from < to then [] else from :: ((from - 1) downto to);
   606 
   607 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   608 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   609   | downto0 ([], n) = n = ~1;
   610 
   611 
   612 (* convert integers to strings *)
   613 
   614 (*expand the number in the given base;
   615   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   616 fun radixpand (base, num) : int list =
   617   let
   618     fun radix (n, tail) =
   619       if n < base then n :: tail
   620       else radix (n div base, (n mod base) :: tail)
   621   in radix (num, []) end;
   622 
   623 (*expands a number into a string of characters starting from "zerochar";
   624   example: radixstring (2, "0", 8) gives "1000"*)
   625 fun radixstring (base, zerochar, num) =
   626   let val offset = ord zerochar;
   627       fun chrof n = chr (offset + n)
   628   in implode (map chrof (radixpand (base, num))) end;
   629 
   630 
   631 val string_of_int = Int.toString;
   632 
   633 fun string_of_indexname (a,0) = a
   634   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   635 
   636 
   637 
   638 (** strings **)
   639 
   640 (*beginning of text*)
   641 fun beginning cs =
   642   implode (map (fn c => if ord c < ord " " then " " else c) (take (10, cs))) ^ " ...";
   643 
   644 (*enclose in brackets*)
   645 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   646 
   647 (*simple quoting (does not escape special chars)*)
   648 val quote = enclose "\"" "\"";
   649 
   650 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   651 fun space_implode a bs = implode (separate a bs);
   652 
   653 val commas = space_implode ", ";
   654 val commas_quote = commas o map quote;
   655 
   656 (*concatenate messages, one per line, into a string*)
   657 val cat_lines = space_implode "\n";
   658 
   659 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   660 fun space_explode _ "" = []
   661   | space_explode sep str =
   662       let
   663         fun expl chs =
   664           (case take_prefix (not_equal sep) chs of
   665             (cs, []) => [implode cs]
   666           | (cs, _ :: cs') => implode cs :: expl cs');
   667       in expl (explode str) end;
   668 
   669 val split_lines = space_explode "\n";
   670 
   671 
   672 
   673 (** lists as sets **)
   674 
   675 (*membership in a list*)
   676 fun x mem [] = false
   677   | x mem (y :: ys) = x = y orelse x mem ys;
   678 
   679 (*membership in a list, optimized version for ints*)
   680 fun (x:int) mem_int [] = false
   681   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   682 
   683 (*membership in a list, optimized version for strings*)
   684 fun (x:string) mem_string [] = false
   685   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   686 
   687 (*generalized membership test*)
   688 fun gen_mem eq (x, []) = false
   689   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   690 
   691 
   692 (*insertion into list if not already there*)
   693 fun (x ins xs) = if x mem xs then xs else x :: xs;
   694 
   695 (*insertion into list, optimized version for ints*)
   696 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   697 
   698 (*insertion into list, optimized version for strings*)
   699 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   700 
   701 (*generalized insertion*)
   702 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   703 
   704 
   705 (*union of sets represented as lists: no repetitions*)
   706 fun xs union [] = xs
   707   | [] union ys = ys
   708   | (x :: xs) union ys = xs union (x ins ys);
   709 
   710 (*union of sets, optimized version for ints*)
   711 fun (xs:int list) union_int [] = xs
   712   | [] union_int ys = ys
   713   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   714 
   715 (*union of sets, optimized version for strings*)
   716 fun (xs:string list) union_string [] = xs
   717   | [] union_string ys = ys
   718   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   719 
   720 (*generalized union*)
   721 fun gen_union eq (xs, []) = xs
   722   | gen_union eq ([], ys) = ys
   723   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   724 
   725 
   726 (*intersection*)
   727 fun [] inter ys = []
   728   | (x :: xs) inter ys =
   729       if x mem ys then x :: (xs inter ys) else xs inter ys;
   730 
   731 (*intersection, optimized version for ints*)
   732 fun ([]:int list) inter_int ys = []
   733   | (x :: xs) inter_int ys =
   734       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   735 
   736 (*intersection, optimized version for strings *)
   737 fun ([]:string list) inter_string ys = []
   738   | (x :: xs) inter_string ys =
   739       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   740 
   741 
   742 (*subset*)
   743 fun [] subset ys = true
   744   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   745 
   746 (*subset, optimized version for ints*)
   747 fun ([]:int list) subset_int ys = true
   748   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   749 
   750 (*subset, optimized version for strings*)
   751 fun ([]:string list) subset_string ys = true
   752   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   753 
   754 (*set equality*)
   755 fun eq_set (xs, ys) =
   756   xs = ys orelse (xs subset ys andalso ys subset xs);
   757 
   758 (*set equality for strings*)
   759 fun eq_set_string ((xs:string list), ys) =
   760   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   761 
   762 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   763 
   764 
   765 (*removing an element from a list WITHOUT duplicates*)
   766 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   767   | [] \ x = [];
   768 
   769 fun ys \\ xs = foldl (op \) (ys,xs);
   770 
   771 (*removing an element from a list -- possibly WITH duplicates*)
   772 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   773 
   774 fun gen_rems eq = foldl (gen_rem eq);
   775 
   776 
   777 (*makes a list of the distinct members of the input; preserves order, takes
   778   first of equal elements*)
   779 fun gen_distinct eq lst =
   780   let
   781     val memb = gen_mem eq;
   782 
   783     fun dist (rev_seen, []) = rev rev_seen
   784       | dist (rev_seen, x :: xs) =
   785           if memb (x, rev_seen) then dist (rev_seen, xs)
   786           else dist (x :: rev_seen, xs);
   787   in
   788     dist ([], lst)
   789   end;
   790 
   791 fun distinct l = gen_distinct (op =) l;
   792 
   793 
   794 (*returns the tail beginning with the first repeated element, or []*)
   795 fun findrep [] = []
   796   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   797 
   798 
   799 (*returns a list containing all repeated elements exactly once; preserves
   800   order, takes first of equal elements*)
   801 fun gen_duplicates eq lst =
   802   let
   803     val memb = gen_mem eq;
   804 
   805     fun dups (rev_dups, []) = rev rev_dups
   806       | dups (rev_dups, x :: xs) =
   807           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   808             dups (rev_dups, xs)
   809           else dups (x :: rev_dups, xs);
   810   in
   811     dups ([], lst)
   812   end;
   813 
   814 fun duplicates l = gen_duplicates (op =) l;
   815 
   816 
   817 
   818 (** association lists **)
   819 
   820 (*association list lookup*)
   821 fun assoc ([], key) = None
   822   | assoc ((keyi, xi) :: pairs, key) =
   823       if key = keyi then Some xi else assoc (pairs, key);
   824 
   825 (*association list lookup, optimized version for ints*)
   826 fun assoc_int ([], (key:int)) = None
   827   | assoc_int ((keyi, xi) :: pairs, key) =
   828       if key = keyi then Some xi else assoc_int (pairs, key);
   829 
   830 (*association list lookup, optimized version for strings*)
   831 fun assoc_string ([], (key:string)) = None
   832   | assoc_string ((keyi, xi) :: pairs, key) =
   833       if key = keyi then Some xi else assoc_string (pairs, key);
   834 
   835 (*association list lookup, optimized version for string*ints*)
   836 fun assoc_string_int ([], (key:string*int)) = None
   837   | assoc_string_int ((keyi, xi) :: pairs, key) =
   838       if key = keyi then Some xi else assoc_string_int (pairs, key);
   839 
   840 fun assocs ps x =
   841   (case assoc (ps, x) of
   842     None => []
   843   | Some ys => ys);
   844 
   845 (*two-fold association list lookup*)
   846 fun assoc2 (aal, (key1, key2)) =
   847   (case assoc (aal, key1) of
   848     Some al => assoc (al, key2)
   849   | None => None);
   850 
   851 (*generalized association list lookup*)
   852 fun gen_assoc eq ([], key) = None
   853   | gen_assoc eq ((keyi, xi) :: pairs, key) =
   854       if eq (key, keyi) then Some xi else gen_assoc eq (pairs, key);
   855 
   856 (*association list update*)
   857 fun overwrite (al, p as (key, _)) =
   858   let fun over ((q as (keyi, _)) :: pairs) =
   859             if keyi = key then p :: pairs else q :: (over pairs)
   860         | over [] = [p]
   861   in over al end;
   862 
   863 fun gen_overwrite eq (al, p as (key, _)) =
   864   let fun over ((q as (keyi, _)) :: pairs) =
   865             if eq (keyi, key) then p :: pairs else q :: (over pairs)
   866         | over [] = [p]
   867   in over al end;
   868 
   869 
   870 
   871 (** generic tables **)
   872 
   873 (*Tables are supposed to be 'efficient' encodings of lists of elements distinct
   874   wrt. an equality "eq". The extend and merge operations below are optimized
   875   for long-term space efficiency.*)
   876 
   877 (*append (new) elements to a table*)
   878 fun generic_extend _ _ _ tab [] = tab
   879   | generic_extend eq dest_tab mk_tab tab1 lst2 =
   880       let
   881         val lst1 = dest_tab tab1;
   882         val new_lst2 = gen_rems eq (lst2, lst1);
   883       in
   884         if null new_lst2 then tab1
   885         else mk_tab (lst1 @ new_lst2)
   886       end;
   887 
   888 (*append (new) elements of 2nd table to 1st table*)
   889 fun generic_merge eq dest_tab mk_tab tab1 tab2 =
   890   let
   891     val lst1 = dest_tab tab1;
   892     val lst2 = dest_tab tab2;
   893     val new_lst2 = gen_rems eq (lst2, lst1);
   894   in
   895     if null new_lst2 then tab1
   896     else if gen_subset eq (lst1, lst2) then tab2
   897     else mk_tab (lst1 @ new_lst2)
   898   end;
   899 
   900 
   901 (*lists as tables*)
   902 fun extend_list tab = generic_extend (op =) I I tab;
   903 fun merge_lists tab = generic_merge (op =) I I tab;
   904 fun merge_alists tab = generic_merge eq_fst I I tab;
   905 
   906 fun merge_rev_lists xs [] = xs
   907   | merge_rev_lists [] ys = ys
   908   | merge_rev_lists xs (y :: ys) =
   909       (if y mem xs then I else cons y) (merge_rev_lists xs ys);
   910 
   911 
   912 
   913 (** balanced trees **)
   914 
   915 exception Balance;      (*indicates non-positive argument to balancing fun*)
   916 
   917 (*balanced folding; avoids deep nesting*)
   918 fun fold_bal f [x] = x
   919   | fold_bal f [] = raise Balance
   920   | fold_bal f xs =
   921       let val k = length xs div 2
   922       in  f (fold_bal f (take(k, xs)),
   923              fold_bal f (drop(k, xs)))
   924       end;
   925 
   926 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   927 fun access_bal (f, g, x) n i =
   928   let fun acc n i =     (*1<=i<=n*)
   929           if n=1 then x else
   930           let val n2 = n div 2
   931           in  if i<=n2 then f (acc n2 i)
   932                        else g (acc (n-n2) (i-n2))
   933           end
   934   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   935 
   936 (*construct ALL such accesses; could try harder to share recursive calls!*)
   937 fun accesses_bal (f, g, x) n =
   938   let fun acc n =
   939           if n=1 then [x] else
   940           let val n2 = n div 2
   941               val acc2 = acc n2
   942           in  if n-n2=n2 then map f acc2 @ map g acc2
   943                          else map f acc2 @ map g (acc (n-n2)) end
   944   in  if 1<=n then acc n else raise Balance  end;
   945 
   946 
   947 
   948 (** orders **)
   949 
   950 datatype order = LESS | EQUAL | GREATER;
   951 
   952 fun rev_order LESS = GREATER
   953   | rev_order EQUAL = EQUAL
   954   | rev_order GREATER = LESS;
   955 
   956 (*assume rel is a linear strict order*)
   957 fun make_ord rel (x, y) =
   958   if rel (x, y) then LESS
   959   else if rel (y, x) then GREATER
   960   else EQUAL;
   961 
   962 fun int_ord (i, j: int) =
   963   if i < j then LESS
   964   else if i = j then EQUAL
   965   else GREATER;
   966 
   967 fun string_ord (a, b: string) =
   968   if a < b then LESS
   969   else if a = b then EQUAL
   970   else GREATER;
   971 
   972 (*lexicographic product*)
   973 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   974   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   975 
   976 (*dictionary order -- in general NOT well-founded!*)
   977 fun dict_ord _ ([], []) = EQUAL
   978   | dict_ord _ ([], _ :: _) = LESS
   979   | dict_ord _ (_ :: _, []) = GREATER
   980   | dict_ord elem_ord (x :: xs, y :: ys) =
   981       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   982 
   983 (*lexicographic product of lists*)
   984 fun list_ord elem_ord (xs, ys) =
   985   prod_ord int_ord (dict_ord elem_ord) ((length xs, xs), (length ys, ys));
   986 
   987 
   988 (* sorting *)
   989 
   990 (*quicksort (stable, i.e. does not reorder equal elements)*)
   991 fun sort ord =
   992   let
   993     fun qsort xs =
   994       let val len = length xs in
   995         if len <= 1 then xs
   996         else
   997           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
   998             qsort lts @ eqs @ qsort gts
   999           end
  1000       end
  1001     and part _ [] = ([], [], [])
  1002       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1003     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1004       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1005       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1006   in qsort end;
  1007 
  1008 (*sort strings*)
  1009 val sort_strings = sort string_ord;
  1010 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1011 
  1012 
  1013 
  1014 (** input / output and diagnostics **)
  1015 
  1016 val cd = OS.FileSys.chDir;
  1017 val pwd = OS.FileSys.getDir;
  1018 
  1019 
  1020 local
  1021   fun out s =
  1022     (TextIO.output (TextIO.stdOut, s); TextIO.flushOut TextIO.stdOut);
  1023 
  1024   fun prefix_lines prfx txt =
  1025     txt |> split_lines |> map (fn s => prfx ^ s ^ "\n") |> implode;
  1026 in
  1027 
  1028 (*hooks for output channels: normal, warning, error*)
  1029 val prs_fn = ref (fn s => out s);
  1030 val warning_fn = ref (fn s => out (prefix_lines "### " s));
  1031 val error_fn = ref (fn s => out (prefix_lines "*** " s));
  1032 
  1033 end;
  1034 
  1035 fun prs s = !prs_fn s;
  1036 fun writeln s = prs (s ^ "\n");
  1037 
  1038 fun warning s = !warning_fn s;
  1039 
  1040 (*print error message and abort to top level*)
  1041 exception ERROR;
  1042 fun error_msg s = !error_fn s;	  (*promise to raise ERROR later!*)
  1043 fun error s = (error_msg s; raise ERROR);
  1044 fun sys_error msg = error ("## SYSTEM ERROR ##\n" ^ msg);
  1045 
  1046 fun assert p msg = if p then () else error msg;
  1047 fun deny p msg = if p then error msg else ();
  1048 
  1049 (*Assert pred for every member of l, generating a message if pred fails*)
  1050 fun assert_all pred l msg_fn =
  1051   let fun asl [] = ()
  1052         | asl (x::xs) = if pred x then asl xs else error (msg_fn x)
  1053   in asl l end;
  1054 
  1055 
  1056 (* handle errors capturing messages *)
  1057 
  1058 datatype 'a error =
  1059   Error of string |
  1060   OK of 'a;
  1061 
  1062 fun get_error (Error msg) = Some msg
  1063   | get_error _ = None;
  1064 
  1065 fun get_ok (OK x) = Some x
  1066   | get_ok _ = None;
  1067 
  1068 fun handle_error f x =
  1069   let
  1070     val buffer = ref ([]: string list);
  1071     fun capture s = buffer := ! buffer @ [s];
  1072     val result = Some (setmp error_fn capture f x) handle ERROR => None;
  1073   in
  1074     (case result of
  1075       None => Error (cat_lines (! buffer))
  1076     | Some y => OK y)
  1077   end;
  1078 
  1079 
  1080 (* transform ERROR into ERROR_MESSAGE, capturing the side-effect *)
  1081 
  1082 exception ERROR_MESSAGE of string;
  1083 
  1084 fun transform_error f x =
  1085   (case handle_error f x of
  1086     OK y => y
  1087   | Error msg => raise ERROR_MESSAGE msg);
  1088 
  1089 
  1090 
  1091 (** timing **)
  1092 
  1093 (*a conditional timing function: applies f to () and, if the flag is true,
  1094   prints its runtime*)
  1095 fun cond_timeit flag f =
  1096   if flag then
  1097     let val start = startTiming()
  1098         val result = f ()
  1099     in
  1100 	writeln (endTiming start);  result
  1101     end
  1102   else f ();
  1103 
  1104 (*unconditional timing function*)
  1105 fun timeit x = cond_timeit true x;
  1106 
  1107 (*timed application function*)
  1108 fun timeap f x = timeit (fn () => f x);
  1109 
  1110 
  1111 
  1112 (** misc **)
  1113 
  1114 (*use the keyfun to make a list of (x, key) pairs*)
  1115 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1116   let fun keypair x = (x, keyfun x)
  1117   in map keypair end;
  1118 
  1119 (*given a list of (x, key) pairs and a searchkey
  1120   return the list of xs from each pair whose key equals searchkey*)
  1121 fun keyfilter [] searchkey = []
  1122   | keyfilter ((x, key) :: pairs) searchkey =
  1123       if key = searchkey then x :: keyfilter pairs searchkey
  1124       else keyfilter pairs searchkey;
  1125 
  1126 
  1127 (*Partition list into elements that satisfy predicate and those that don't.
  1128   Preserves order of elements in both lists.*)
  1129 fun partition (pred: 'a->bool) (ys: 'a list) : ('a list * 'a list) =
  1130     let fun part ([], answer) = answer
  1131           | part (x::xs, (ys, ns)) = if pred(x)
  1132             then  part (xs, (x::ys, ns))
  1133             else  part (xs, (ys, x::ns))
  1134     in  part (rev ys, ([], []))  end;
  1135 
  1136 
  1137 fun partition_eq (eq:'a * 'a -> bool) =
  1138     let fun part [] = []
  1139           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1140                            in (x::xs)::(part xs') end
  1141     in part end;
  1142 
  1143 
  1144 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1145    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1146 fun partition_list p i j =
  1147   let fun part k xs =
  1148             if k>j then
  1149               (case xs of [] => []
  1150                          | _ => raise LIST "partition_list")
  1151             else
  1152             let val (ns, rest) = partition (p k) xs;
  1153             in  ns :: part(k+1)rest  end
  1154   in  part i end;
  1155 
  1156 
  1157 (* transitive closure (not Warshall's algorithm) *)
  1158 
  1159 fun transitive_closure [] = []
  1160   | transitive_closure ((x, ys)::ps) =
  1161       let val qs = transitive_closure ps
  1162           val zs = foldl (fn (zs, y) => assocs qs y union_string zs) (ys, ys)
  1163           fun step(u, us) = (u, if x mem_string us then zs union_string us 
  1164                                 else us)
  1165       in (x, zs) :: map step qs end;
  1166 
  1167 
  1168 (* generating identifiers *)
  1169 
  1170 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1171 local
  1172 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1173 fun char i =      if i<26 then chr (ord "A" + i)
  1174 	     else if i<52 then chr (ord "a" + i - 26)
  1175 	     else if i<62 then chr (ord"0" + i - 52)
  1176 	     else if i=62 then "_"
  1177 	     else  (*i=63*)    "'";
  1178 
  1179 val charVec = Vector.tabulate (64, char);
  1180 
  1181 fun newid n = 
  1182   let 
  1183   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1184 
  1185 val seedr = ref 0;
  1186 
  1187 in
  1188 
  1189 fun init_gensym() = (seedr := 0);
  1190 
  1191 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1192 end;
  1193 
  1194 
  1195 local
  1196 (*Identifies those character codes legal in identifiers.
  1197   chould use Basis Library character functions if Poly/ML provided characters*)
  1198 fun idCode k = (ord "a" <= k andalso k < ord "z") orelse 
  1199                (ord "A" <= k andalso k < ord "Z") orelse
  1200                (ord "0" <= k andalso k < ord "9");
  1201 
  1202 val idCodeVec = Vector.tabulate (256, idCode);
  1203 
  1204 in
  1205 
  1206 (*Increment a list of letters like a reversed base 26 number.
  1207   If head is "z", bumps chars in tail.
  1208   Digits are incremented as if they were integers.
  1209   "_" and "'" are not changed.
  1210   For making variants of identifiers.*)
  1211 
  1212 fun bump_int_list(c::cs) = 
  1213 	if c="9" then "0" :: bump_int_list cs 
  1214 	else
  1215         if "0" <= c andalso c < "9" then chr(ord(c)+1) :: cs
  1216         else "1" :: c :: cs
  1217   | bump_int_list([]) = error("bump_int_list: not an identifier");
  1218 
  1219 fun bump_list([], d) = [d]
  1220   | bump_list(["'"], d) = [d, "'"]
  1221   | bump_list("z"::cs, _) = "a" :: bump_list(cs, "a")
  1222   | bump_list("Z"::cs, _) = "A" :: bump_list(cs, "A")
  1223   | bump_list("9"::cs, _) = "0" :: bump_int_list cs
  1224   | bump_list(c::cs, _) = 
  1225         let val k = ord(c)
  1226         in if Vector.sub(idCodeVec,k) then chr(k+1) :: cs 
  1227 	   else
  1228            if c="'" orelse c="_" then c :: bump_list(cs, "") 
  1229 	   else error("bump_list: not legal in identifier: " ^
  1230 		      implode(rev(c::cs)))
  1231         end;
  1232 
  1233 end;
  1234 
  1235 fun bump_string s : string = implode (rev (bump_list(rev(explode s), "")));
  1236 
  1237 
  1238 (* lexical scanning *)
  1239 
  1240 (*scan a list of characters into "words" composed of "letters" (recognized by
  1241   is_let) and separated by any number of non-"letters"*)
  1242 fun scanwords is_let cs =
  1243   let fun scan1 [] = []
  1244         | scan1 cs =
  1245             let val (lets, rest) = take_prefix is_let cs
  1246             in implode lets :: scanwords is_let rest end;
  1247   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1248 
  1249 
  1250 
  1251 (* Variable-branching trees: for proof terms etc. *)
  1252 datatype 'a mtree = Join of 'a * 'a mtree list;
  1253 
  1254 
  1255 (* generic objects -- fool the ML type system via exception constructors *)
  1256 
  1257 type object = exn;
  1258 
  1259 fun type_error name =
  1260   error ("## RUNTIME TYPE ERROR ##\nFailed to access " ^ quote name ^ " data");
  1261 
  1262 
  1263 end;
  1264 
  1265 open Library;