src/Pure/variable.ML
author wenzelm
Wed Nov 26 20:05:34 2014 +0100 (2014-11-26)
changeset 59058 a78612c67ec0
parent 58668 1891f17c6124
child 59150 71b416020f42
permissions -rw-r--r--
renamed "pairself" to "apply2", in accordance to @{apply 2};
     1 (*  Title:      Pure/variable.ML
     2     Author:     Makarius
     3 
     4 Fixed type/term variables and polymorphic term abbreviations.
     5 *)
     6 
     7 signature VARIABLE =
     8 sig
     9   val is_body: Proof.context -> bool
    10   val set_body: bool -> Proof.context -> Proof.context
    11   val restore_body: Proof.context -> Proof.context -> Proof.context
    12   val names_of: Proof.context -> Name.context
    13   val binds_of: Proof.context -> (typ * term) Vartab.table
    14   val maxidx_of: Proof.context -> int
    15   val sorts_of: Proof.context -> sort list
    16   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Proof.context -> string -> bool
    18   val check_name: binding -> string
    19   val default_type: Proof.context -> string -> typ option
    20   val def_type: Proof.context -> bool -> indexname -> typ option
    21   val def_sort: Proof.context -> indexname -> sort option
    22   val declare_names: term -> Proof.context -> Proof.context
    23   val declare_constraints: term -> Proof.context -> Proof.context
    24   val declare_term: term -> Proof.context -> Proof.context
    25   val declare_typ: typ -> Proof.context -> Proof.context
    26   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    27   val declare_thm: thm -> Proof.context -> Proof.context
    28   val global_thm_context: thm -> Proof.context
    29   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    30   val bind_term: indexname * term option -> Proof.context -> Proof.context
    31   val expand_binds: Proof.context -> term -> term
    32   val lookup_const: Proof.context -> string -> string option
    33   val is_const: Proof.context -> string -> bool
    34   val declare_const: string * string -> Proof.context -> Proof.context
    35   val next_bound: string * typ -> Proof.context -> term * Proof.context
    36   val revert_bounds: Proof.context -> term -> term
    37   val is_fixed: Proof.context -> string -> bool
    38   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    39   val fixed_ord: Proof.context -> string * string -> order
    40   val intern_fixed: Proof.context -> string -> string
    41   val markup_fixed: Proof.context -> string -> Markup.T
    42   val lookup_fixed: Proof.context -> string -> string option
    43   val revert_fixed: Proof.context -> string -> string
    44   val add_fixed_names: Proof.context -> term -> string list -> string list
    45   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    46   val add_free_names: Proof.context -> term -> string list -> string list
    47   val add_frees: Proof.context -> term -> (string * typ) list -> (string * typ) list
    48   val add_fixes_binding: binding list -> Proof.context -> string list * Proof.context
    49   val add_fixes: string list -> Proof.context -> string list * Proof.context
    50   val add_fixes_direct: string list -> Proof.context -> Proof.context
    51   val auto_fixes: term -> Proof.context -> Proof.context
    52   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    53   val dest_fixes: Proof.context -> (string * string) list
    54   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    55   val export_terms: Proof.context -> Proof.context -> term list -> term list
    56   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    57   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    58   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    59   val export: Proof.context -> Proof.context -> thm list -> thm list
    60   val export_morphism: Proof.context -> Proof.context -> morphism
    61   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    62   val import_inst: bool -> term list -> Proof.context ->
    63     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    64   val importT_terms: term list -> Proof.context -> term list * Proof.context
    65   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    66   val importT: thm list -> Proof.context -> ((ctyp * ctyp) list * thm list) * Proof.context
    67   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    68   val import: bool -> thm list -> Proof.context ->
    69     (((ctyp * ctyp) list * (cterm * cterm) list) * thm list) * Proof.context
    70   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    71   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    72   val focus: term -> Proof.context -> ((string * (string * typ)) list * term) * Proof.context
    73   val focus_cterm: cterm -> Proof.context -> ((string * cterm) list * cterm) * Proof.context
    74   val focus_subgoal: int -> thm -> Proof.context -> ((string * cterm) list * cterm) * Proof.context
    75   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    76   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    77   val polymorphic: Proof.context -> term list -> term list
    78 end;
    79 
    80 structure Variable: VARIABLE =
    81 struct
    82 
    83 (** local context data **)
    84 
    85 type fixes = string Name_Space.table;
    86 val empty_fixes: fixes = Name_Space.empty_table Markup.fixedN;
    87 
    88 datatype data = Data of
    89  {is_body: bool,                        (*inner body mode*)
    90   names: Name.context,                  (*type/term variable names*)
    91   consts: string Symtab.table,          (*consts within the local scope*)
    92   bounds: int * ((string * typ) * string) list,  (*next index, internal name, type, external name*)
    93   fixes: fixes,                         (*term fixes -- global name space, intern ~> extern*)
    94   binds: (typ * term) Vartab.table,     (*term bindings*)
    95   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    96   maxidx: int,                          (*maximum var index*)
    97   sorts: sort Ord_List.T,               (*declared sort occurrences*)
    98   constraints:
    99     typ Vartab.table *                  (*type constraints*)
   100     sort Vartab.table};                 (*default sorts*)
   101 
   102 fun make_data
   103     (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =
   104   Data {is_body = is_body, names = names, consts = consts, bounds = bounds, fixes = fixes,
   105     binds = binds, type_occs = type_occs, maxidx = maxidx, sorts = sorts, constraints = constraints};
   106 
   107 structure Data = Proof_Data
   108 (
   109   type T = data;
   110   fun init _ =
   111     make_data (false, Name.context, Symtab.empty, (0, []), empty_fixes, Vartab.empty,
   112       Symtab.empty, ~1, [], (Vartab.empty, Vartab.empty));
   113 );
   114 
   115 fun map_data f =
   116   Data.map (fn
   117       Data {is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints} =>
   118     make_data
   119       (f (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints)));
   120 
   121 fun map_names f =
   122   map_data (fn
   123       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   124     (is_body, f names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints));
   125 
   126 fun map_consts f =
   127   map_data (fn
   128       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   129     (is_body, names, f consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints));
   130 
   131 fun map_bounds f =
   132   map_data (fn
   133       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   134     (is_body, names, consts, f bounds, fixes, binds, type_occs, maxidx, sorts, constraints));
   135 
   136 fun map_fixes f =
   137   map_data (fn
   138       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   139     (is_body, names, consts, bounds, f fixes, binds, type_occs, maxidx, sorts, constraints));
   140 
   141 fun map_binds f =
   142   map_data (fn
   143       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   144     (is_body, names, consts, bounds, fixes, f binds, type_occs, maxidx, sorts, constraints));
   145 
   146 fun map_type_occs f =
   147   map_data (fn
   148       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   149     (is_body, names, consts, bounds, fixes, binds, f type_occs, maxidx, sorts, constraints));
   150 
   151 fun map_maxidx f =
   152   map_data (fn
   153       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   154     (is_body, names, consts, bounds, fixes, binds, type_occs, f maxidx, sorts, constraints));
   155 
   156 fun map_sorts f =
   157   map_data (fn
   158       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   159     (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, f sorts, constraints));
   160 
   161 fun map_constraints f =
   162   map_data (fn
   163       (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   164     (is_body, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, f constraints));
   165 
   166 fun rep_data ctxt = Data.get ctxt |> (fn Data rep => rep);
   167 
   168 val is_body = #is_body o rep_data;
   169 
   170 fun set_body b =
   171   map_data (fn (_, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   172     (b, names, consts, bounds, fixes, binds, type_occs, maxidx, sorts, constraints));
   173 
   174 fun restore_body ctxt = set_body (is_body ctxt);
   175 
   176 val names_of = #names o rep_data;
   177 val fixes_of = #fixes o rep_data;
   178 val fixes_space = Name_Space.space_of_table o fixes_of;
   179 val binds_of = #binds o rep_data;
   180 val type_occs_of = #type_occs o rep_data;
   181 val maxidx_of = #maxidx o rep_data;
   182 val sorts_of = #sorts o rep_data;
   183 val constraints_of = #constraints o rep_data;
   184 
   185 val is_declared = Name.is_declared o names_of;
   186 
   187 val check_name = Name_Space.base_name o tap Binding.check;
   188 
   189 
   190 
   191 (** declarations **)
   192 
   193 (* default sorts and types *)
   194 
   195 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   196 
   197 fun def_type ctxt pattern xi =
   198   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   199     (case Vartab.lookup types xi of
   200       NONE =>
   201         if pattern then NONE
   202         else Vartab.lookup binds xi |> Option.map (Type.mark_polymorphic o #1)
   203     | some => some)
   204   end;
   205 
   206 val def_sort = Vartab.lookup o #2 o constraints_of;
   207 
   208 
   209 (* names *)
   210 
   211 fun declare_type_names t =
   212   map_names (fold_types (fold_atyps Term.declare_typ_names) t) #>
   213   map_maxidx (fold_types Term.maxidx_typ t);
   214 
   215 fun declare_names t =
   216   declare_type_names t #>
   217   map_names (fold_aterms Term.declare_term_frees t) #>
   218   map_maxidx (Term.maxidx_term t);
   219 
   220 
   221 (* type occurrences *)
   222 
   223 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   224 
   225 val decl_type_occs = fold_term_types
   226   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   227     | _ => decl_type_occsT);
   228 
   229 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   230 val declare_type_occs = map_type_occs o decl_type_occs;
   231 
   232 
   233 (* constraints *)
   234 
   235 fun constrain_tvar (xi, raw_S) =
   236   let val S = #2 (Term_Position.decode_positionS raw_S)
   237   in if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S) end;
   238 
   239 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   240   let
   241     val types' = fold_aterms
   242       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   243         | Var v => Vartab.update v
   244         | _ => I) t types;
   245     val sorts' = (fold_types o fold_atyps)
   246       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   247         | TVar v => constrain_tvar v
   248         | _ => I) t sorts;
   249   in (types', sorts') end)
   250   #> declare_type_occsT t
   251   #> declare_type_names t;
   252 
   253 
   254 (* common declarations *)
   255 
   256 fun declare_internal t =
   257   declare_names t #>
   258   declare_type_occs t #>
   259   map_sorts (Sorts.insert_term t);
   260 
   261 fun declare_term t =
   262   declare_internal t #>
   263   declare_constraints t;
   264 
   265 val declare_typ = declare_term o Logic.mk_type;
   266 
   267 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   268 
   269 val declare_thm = Thm.fold_terms declare_internal;
   270 fun global_thm_context th = declare_thm th (Proof_Context.init_global (Thm.theory_of_thm th));
   271 
   272 
   273 (* renaming term/type frees *)
   274 
   275 fun variant_frees ctxt ts frees =
   276   let
   277     val names = names_of (fold declare_names ts ctxt);
   278     val xs = fst (fold_map Name.variant (map #1 frees) names);
   279   in xs ~~ map snd frees end;
   280 
   281 
   282 
   283 (** term bindings **)
   284 
   285 fun bind_term (xi, NONE) = map_binds (Vartab.delete_safe xi)
   286   | bind_term ((x, i), SOME t) =
   287       let
   288         val u = Term.close_schematic_term t;
   289         val U = Term.fastype_of u;
   290       in declare_term u #> map_binds (Vartab.update ((x, i), (U, u))) end;
   291 
   292 fun expand_binds ctxt =
   293   let
   294     val binds = binds_of ctxt;
   295     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   296   in Envir.beta_norm o Envir.expand_term get end;
   297 
   298 
   299 
   300 (** consts **)
   301 
   302 val lookup_const = Symtab.lookup o #consts o rep_data;
   303 val is_const = is_some oo lookup_const;
   304 
   305 val declare_fixed = map_consts o Symtab.delete_safe;
   306 val declare_const = map_consts o Symtab.update;
   307 
   308 
   309 
   310 (** bounds **)
   311 
   312 fun next_bound (a, T) ctxt =
   313   let
   314     val b = Name.bound (#1 (#bounds (rep_data ctxt)));
   315     val ctxt' = ctxt |> map_bounds (fn (next, bounds) => (next + 1, ((b, T), a) :: bounds));
   316   in (Free (b, T), ctxt') end;
   317 
   318 fun revert_bounds ctxt t =
   319   (case #2 (#bounds (rep_data ctxt)) of
   320     [] => t
   321   | bounds =>
   322       let
   323         val names = Term.declare_term_names t (names_of ctxt);
   324         val xs = rev (#1 (fold_map Name.variant (rev (map #2 bounds)) names));
   325         fun subst ((b, T), _) x' = (Free (b, T), Syntax_Trans.mark_bound_abs (x', T));
   326       in Term.subst_atomic (map2 subst bounds xs) t end);
   327 
   328 
   329 
   330 (** fixes **)
   331 
   332 (* specialized name space *)
   333 
   334 val is_fixed = Name_Space.defined_entry o fixes_space;
   335 fun newly_fixed inner outer = is_fixed inner andf (not o is_fixed outer);
   336 
   337 val fixed_ord = Name_Space.entry_ord o fixes_space;
   338 val intern_fixed = Name_Space.intern o fixes_space;
   339 
   340 fun lookup_fixed ctxt x =
   341   let val x' = intern_fixed ctxt x
   342   in if is_fixed ctxt x' then SOME x' else NONE end;
   343 
   344 fun revert_fixed ctxt x =
   345   (case Name_Space.lookup_key (fixes_of ctxt) x of
   346     SOME (_, x') => if intern_fixed ctxt x' = x then x' else x
   347   | NONE => x);
   348 
   349 fun markup_fixed ctxt x =
   350   Name_Space.markup (fixes_space ctxt) x
   351   |> Markup.name (revert_fixed ctxt x);
   352 
   353 fun dest_fixes ctxt =
   354   Name_Space.fold_table (fn (x, y) => cons (y, x)) (fixes_of ctxt) []
   355   |> sort (Name_Space.entry_ord (fixes_space ctxt) o apply2 #2);
   356 
   357 
   358 (* collect variables *)
   359 
   360 fun add_free_names ctxt =
   361   fold_aterms (fn Free (x, _) => not (is_fixed ctxt x) ? insert (op =) x | _ => I);
   362 
   363 fun add_frees ctxt =
   364   fold_aterms (fn Free (x, T) => not (is_fixed ctxt x) ? insert (op =) (x, T) | _ => I);
   365 
   366 fun add_fixed_names ctxt =
   367   fold_aterms (fn Free (x, _) => is_fixed ctxt x ? insert (op =) x | _ => I);
   368 
   369 fun add_fixed ctxt =
   370   fold_aterms (fn Free (x, T) => is_fixed ctxt x ? insert (op =) (x, T) | _ => I);
   371 
   372 
   373 (* declarations *)
   374 
   375 local
   376 
   377 fun err_dups dups =
   378   error ("Duplicate fixed variable(s): " ^ commas (map Binding.print dups));
   379 
   380 fun new_fixed ((x, x'), pos) ctxt =
   381   if is_some (lookup_fixed ctxt x') then err_dups [Binding.make (x, pos)]
   382   else
   383     let val context = Context.Proof ctxt |> Name_Space.map_naming (K Name_Space.global_naming) in
   384       ctxt
   385       |> map_fixes
   386         (Name_Space.define context true (Binding.make (x', pos), x) #> snd #>
   387           Name_Space.alias_table Name_Space.global_naming (Binding.make (x, pos)) x')
   388       |> declare_fixed x
   389       |> declare_constraints (Syntax.free x')
   390   end;
   391 
   392 fun new_fixes names' xs xs' ps =
   393   map_names (K names') #>
   394   fold new_fixed ((xs ~~ xs') ~~ ps) #>
   395   pair xs';
   396 
   397 in
   398 
   399 fun add_fixes_binding bs ctxt =
   400   let
   401     val _ =
   402       (case filter (Name.is_skolem o Binding.name_of) bs of
   403         [] => ()
   404       | bads => error ("Illegal internal Skolem constant(s): " ^ commas (map Binding.print bads)));
   405     val _ =
   406       (case duplicates (op = o apply2 Binding.name_of) bs of
   407         [] => ()
   408       | dups => err_dups dups);
   409 
   410     val xs = map check_name bs;
   411     val names = names_of ctxt;
   412     val (xs', names') =
   413       if is_body ctxt then fold_map Name.variant xs names |>> map Name.skolem
   414       else (xs, fold Name.declare xs names);
   415   in ctxt |> new_fixes names' xs xs' (map Binding.pos_of bs) end;
   416 
   417 fun variant_fixes raw_xs ctxt =
   418   let
   419     val names = names_of ctxt;
   420     val xs = map (fn x => Name.clean x |> Name.is_internal x ? Name.internal) raw_xs;
   421     val (xs', names') = fold_map Name.variant xs names |>> (is_body ctxt ? map Name.skolem);
   422   in ctxt |> new_fixes names' xs xs' (replicate (length xs) Position.none) end;
   423 
   424 end;
   425 
   426 val add_fixes = add_fixes_binding o map Binding.name;
   427 
   428 fun add_fixes_direct xs ctxt = ctxt
   429   |> set_body false
   430   |> (snd o add_fixes xs)
   431   |> restore_body ctxt;
   432 
   433 fun auto_fixes t ctxt = ctxt
   434   |> not (is_body ctxt) ? add_fixes_direct (rev (add_free_names ctxt t []))
   435   |> declare_term t;
   436 
   437 fun invent_types Ss ctxt =
   438   let
   439     val tfrees = Name.invent (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   440     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   441   in (tfrees, ctxt') end;
   442 
   443 
   444 
   445 (** export -- generalize type/term variables (beware of closure sizes) **)
   446 
   447 fun export_inst inner outer =
   448   let
   449     val declared_outer = is_declared outer;
   450     val still_fixed = not o newly_fixed inner outer;
   451 
   452     val gen_fixes =
   453       Name_Space.fold_table (fn (y, _) => not (is_fixed outer y) ? cons y)
   454         (fixes_of inner) [];
   455 
   456     val type_occs_inner = type_occs_of inner;
   457     fun gen_fixesT ts =
   458       Symtab.fold (fn (a, xs) =>
   459         if declared_outer a orelse exists still_fixed xs
   460         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   461   in (gen_fixesT, gen_fixes) end;
   462 
   463 fun exportT_inst inner outer = #1 (export_inst inner outer);
   464 
   465 fun exportT_terms inner outer =
   466   let val mk_tfrees = exportT_inst inner outer in
   467     fn ts => ts |> map
   468       (Term_Subst.generalize (mk_tfrees ts, [])
   469         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   470   end;
   471 
   472 fun export_terms inner outer =
   473   let val (mk_tfrees, tfrees) = export_inst inner outer in
   474     fn ts => ts |> map
   475       (Term_Subst.generalize (mk_tfrees ts, tfrees)
   476         (fold Term.maxidx_term ts ~1 + 1))
   477   end;
   478 
   479 fun export_prf inner outer prf =
   480   let
   481     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   482     val tfrees = mk_tfrees [];
   483     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   484     val gen_term = Term_Subst.generalize_same (tfrees, frees) idx;
   485     val gen_typ = Term_Subst.generalizeT_same tfrees idx;
   486   in Same.commit (Proofterm.map_proof_terms_same gen_term gen_typ) prf end;
   487 
   488 
   489 fun gen_export (mk_tfrees, frees) ths =
   490   let
   491     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   492     val maxidx = fold Thm.maxidx_thm ths ~1;
   493   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   494 
   495 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   496 fun export inner outer = gen_export (export_inst inner outer);
   497 
   498 fun export_morphism inner outer =
   499   let
   500     val fact = export inner outer;
   501     val term = singleton (export_terms inner outer);
   502     val typ = Logic.type_map term;
   503   in
   504     Morphism.morphism "Variable.export" {binding = [], typ = [typ], term = [term], fact = [fact]}
   505   end;
   506 
   507 
   508 
   509 (** import -- fix schematic type/term variables **)
   510 
   511 fun importT_inst ts ctxt =
   512   let
   513     val tvars = rev (fold Term.add_tvars ts []);
   514     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   515   in (tvars ~~ map TFree tfrees, ctxt') end;
   516 
   517 fun import_inst is_open ts ctxt =
   518   let
   519     val ren = Name.clean #> (if is_open then I else Name.internal);
   520     val (instT, ctxt') = importT_inst ts ctxt;
   521     val vars = map (apsnd (Term_Subst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   522     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   523     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   524   in ((instT, inst), ctxt'') end;
   525 
   526 fun importT_terms ts ctxt =
   527   let val (instT, ctxt') = importT_inst ts ctxt
   528   in (map (Term_Subst.instantiate (instT, [])) ts, ctxt') end;
   529 
   530 fun import_terms is_open ts ctxt =
   531   let val (inst, ctxt') = import_inst is_open ts ctxt
   532   in (map (Term_Subst.instantiate inst) ts, ctxt') end;
   533 
   534 fun importT ths ctxt =
   535   let
   536     val thy = Proof_Context.theory_of ctxt;
   537     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   538     val insts' as (instT', _) = Thm.certify_inst thy (instT, []);
   539     val ths' = map (Thm.instantiate insts') ths;
   540   in ((instT', ths'), ctxt') end;
   541 
   542 fun import_prf is_open prf ctxt =
   543   let
   544     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   545     val (insts, ctxt') = import_inst is_open ts ctxt;
   546   in (Proofterm.instantiate insts prf, ctxt') end;
   547 
   548 fun import is_open ths ctxt =
   549   let
   550     val thy = Proof_Context.theory_of ctxt;
   551     val (insts, ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   552     val insts' = Thm.certify_inst thy insts;
   553     val ths' = map (Thm.instantiate insts') ths;
   554   in ((insts', ths'), ctxt') end;
   555 
   556 
   557 (* import/export *)
   558 
   559 fun gen_trade imp exp f ctxt ths =
   560   let val ((_, ths'), ctxt') = imp ths ctxt
   561   in exp ctxt' ctxt (f ctxt' ths') end;
   562 
   563 val tradeT = gen_trade importT exportT;
   564 val trade = gen_trade (import true) export;
   565 
   566 
   567 (* focus on outermost parameters: !!x y z. B *)
   568 
   569 fun focus_params t ctxt =
   570   let
   571     val (xs, Ts) =
   572       split_list (Term.variant_frees t (Term.strip_all_vars t));  (*as they are printed :-*)
   573     val (xs', ctxt') = variant_fixes xs ctxt;
   574     val ps = xs' ~~ Ts;
   575     val ctxt'' = ctxt' |> fold (declare_constraints o Free) ps;
   576   in ((xs, ps), ctxt'') end;
   577 
   578 fun focus t ctxt =
   579   let
   580     val ((xs, ps), ctxt') = focus_params t ctxt;
   581     val t' = Term.subst_bounds (rev (map Free ps), Term.strip_all_body t);
   582   in (((xs ~~ ps), t'), ctxt') end;
   583 
   584 fun forall_elim_prop t prop =
   585   Thm.beta_conversion false (Thm.apply (Thm.dest_arg prop) t)
   586   |> Thm.cprop_of |> Thm.dest_arg;
   587 
   588 fun focus_cterm goal ctxt =
   589   let
   590     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   591     val ((xs, ps), ctxt') = focus_params (Thm.term_of goal) ctxt;
   592     val ps' = map (cert o Free) ps;
   593     val goal' = fold forall_elim_prop ps' goal;
   594   in ((xs ~~ ps', goal'), ctxt') end;
   595 
   596 fun focus_subgoal i st =
   597   let
   598     val all_vars = Thm.fold_terms Term.add_vars st [];
   599     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   600   in
   601     fold bind_term no_binds #>
   602     fold (declare_constraints o Var) all_vars #>
   603     focus_cterm (Thm.cprem_of st i)
   604   end;
   605 
   606 
   607 
   608 (** implicit polymorphism **)
   609 
   610 (* warn_extra_tfrees *)
   611 
   612 fun warn_extra_tfrees ctxt1 ctxt2 =
   613   let
   614     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   615     fun occs_free a x =
   616       (case def_type ctxt1 false (x, ~1) of
   617         SOME T => if occs_typ a T then I else cons (a, x)
   618       | NONE => cons (a, x));
   619 
   620     val occs1 = type_occs_of ctxt1;
   621     val occs2 = type_occs_of ctxt2;
   622     val extras = Symtab.fold (fn (a, xs) =>
   623       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   624     val tfrees = map #1 extras |> sort_distinct string_ord;
   625     val frees = map #2 extras |> sort_distinct string_ord;
   626   in
   627     if null extras orelse not (Context_Position.is_visible ctxt2) then ()
   628     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   629       space_implode " or " (map quote frees))
   630   end;
   631 
   632 
   633 (* polymorphic terms *)
   634 
   635 fun polymorphic_types ctxt ts =
   636   let
   637     val ctxt' = fold declare_term ts ctxt;
   638     val occs = type_occs_of ctxt;
   639     val occs' = type_occs_of ctxt';
   640     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   641     val idx = maxidx_of ctxt' + 1;
   642     val Ts' = (fold o fold_types o fold_atyps)
   643       (fn T as TFree _ =>
   644           (case Term_Subst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   645         | _ => I) ts [];
   646     val ts' = map (Term_Subst.generalize (types, []) idx) ts;
   647   in (rev Ts', ts') end;
   648 
   649 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   650 
   651 end;