src/Pure/variable.ML
author wenzelm
Thu Jul 27 23:28:25 2006 +0200 (2006-07-27)
changeset 20240 a7b027328d6e
parent 20220 5dc68e9ecd9a
child 20251 6379135f21c2
permissions -rw-r--r--
added fix_frees (from Isar/proof_context.ML);
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Context.proof -> bool
    11   val set_body: bool -> Context.proof -> Context.proof
    12   val restore_body: Context.proof -> Context.proof -> Context.proof
    13   val names_of: Context.proof -> Name.context
    14   val fixes_of: Context.proof -> (string * string) list
    15   val binds_of: Context.proof -> (typ * term) Vartab.table
    16   val constraints_of: Context.proof -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Context.proof -> string -> bool
    18   val is_fixed: Context.proof -> string -> bool
    19   val newly_fixed: Context.proof -> Context.proof -> string -> bool
    20   val default_type: Context.proof -> string -> typ option
    21   val def_type: Context.proof -> bool -> indexname -> typ option
    22   val def_sort: Context.proof -> indexname -> sort option
    23   val declare_constraints: term -> Context.proof -> Context.proof
    24   val declare_internal: term -> Context.proof -> Context.proof
    25   val declare_term: term -> Context.proof -> Context.proof
    26   val declare_thm: thm -> Context.proof -> Context.proof
    27   val thm_context: thm -> Context.proof
    28   val variant_frees: Context.proof -> term list -> (string * 'a) list -> (string * 'a) list
    29   val add_fixes: string list -> Context.proof -> string list * Context.proof
    30   val fix_frees: term -> Context.proof -> Context.proof
    31   val invent_fixes: string list -> Context.proof -> string list * Context.proof
    32   val invent_types: sort list -> Context.proof -> (string * sort) list * Context.proof
    33   val export_inst: Context.proof -> Context.proof -> string list * string list
    34   val exportT_inst: Context.proof -> Context.proof -> string list
    35   val export_terms: Context.proof -> Context.proof -> term list -> term list
    36   val exportT_terms: Context.proof -> Context.proof -> term list -> term list
    37   val exportT: Context.proof -> Context.proof -> thm list -> thm list
    38   val export: Context.proof -> Context.proof -> thm list -> thm list
    39   val importT_inst: term list -> Context.proof -> ((indexname * sort) * typ) list * Context.proof
    40   val import_inst: bool -> term list -> Context.proof ->
    41     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Context.proof
    42   val importT_terms: term list -> Context.proof -> term list * Context.proof
    43   val import_terms: bool -> term list -> Context.proof -> term list * Context.proof
    44   val importT: thm list -> Context.proof -> (ctyp list * thm list) * Context.proof
    45   val import: bool -> thm list -> Context.proof ->
    46     ((ctyp list * cterm list) * thm list) * Context.proof
    47   val tradeT: Context.proof -> (thm list -> thm list) -> thm list -> thm list
    48   val trade: Context.proof -> (thm list -> thm list) -> thm list -> thm list
    49   val focus: cterm -> Context.proof -> (cterm list * cterm) * Context.proof
    50   val warn_extra_tfrees: Context.proof -> Context.proof -> unit
    51   val polymorphic: Context.proof -> term list -> term list
    52   val hidden_polymorphism: term -> typ -> (indexname * sort) list
    53   val add_binds: (indexname * term option) list -> Context.proof -> Context.proof
    54   val expand_binds: Context.proof -> term -> term
    55 end;
    56 
    57 structure Variable: VARIABLE =
    58 struct
    59 
    60 (** local context data **)
    61 
    62 datatype data = Data of
    63  {is_body: bool,                        (*inner body mode*)
    64   names: Name.context,                  (*type/term variable names*)
    65   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    66   binds: (typ * term) Vartab.table,     (*term bindings*)
    67   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    68   constraints:
    69     typ Vartab.table *                  (*type constraints*)
    70     sort Vartab.table};                 (*default sorts*)
    71 
    72 fun make_data (is_body, names, fixes, binds, type_occs, constraints) =
    73   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    74     type_occs = type_occs, constraints = constraints};
    75 
    76 structure Data = ProofDataFun
    77 (
    78   val name = "Pure/variable";
    79   type T = data;
    80   fun init thy =
    81     make_data (false, Name.context, [], Vartab.empty, Symtab.empty, (Vartab.empty, Vartab.empty));
    82   fun print _ _ = ();
    83 );
    84 
    85 val _ = Context.add_setup Data.init;
    86 
    87 fun map_data f =
    88   Data.map (fn Data {is_body, names, fixes, binds, type_occs, constraints} =>
    89     make_data (f (is_body, names, fixes, binds, type_occs, constraints)));
    90 
    91 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    92   (is_body, f names, fixes, binds, type_occs, constraints));
    93 
    94 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    95   (is_body, names, f fixes, binds, type_occs, constraints));
    96 
    97 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    98   (is_body, names, fixes, f binds, type_occs, constraints));
    99 
   100 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   101   (is_body, names, fixes, binds, f type_occs, constraints));
   102 
   103 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   104   (is_body, names, fixes, binds, type_occs, f constraints));
   105 
   106 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   107 
   108 val is_body = #is_body o rep_data;
   109 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, constraints) =>
   110   (b, names, fixes, binds, type_occs, constraints));
   111 fun restore_body ctxt = set_body (is_body ctxt);
   112 
   113 val names_of = #names o rep_data;
   114 val fixes_of = #fixes o rep_data;
   115 val binds_of = #binds o rep_data;
   116 val type_occs_of = #type_occs o rep_data;
   117 val constraints_of = #constraints o rep_data;
   118 
   119 val is_declared = Name.is_declared o names_of;
   120 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   121 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   122 
   123 
   124 
   125 (** declarations **)
   126 
   127 (* default sorts and types *)
   128 
   129 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   130 
   131 fun def_type ctxt pattern xi =
   132   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   133     (case Vartab.lookup types xi of
   134       NONE =>
   135         if pattern then NONE
   136         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   137     | some => some)
   138   end;
   139 
   140 val def_sort = Vartab.lookup o #2 o constraints_of;
   141 
   142 
   143 (* names *)
   144 
   145 val declare_type_names = map_names o
   146   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I));
   147 
   148 fun declare_names t =
   149   declare_type_names t #>
   150   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t);
   151 
   152 
   153 (* type occurrences *)
   154 
   155 val declare_type_occs = map_type_occs o fold_term_types
   156   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   157     | _ => fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I));
   158 
   159 
   160 (* constraints *)
   161 
   162 fun redeclare_skolems ctxt = ctxt |> map_constraints (apfst (fn types =>
   163   let
   164     fun decl (x, x') =
   165       (case default_type ctxt x' of
   166         SOME T => Vartab.update ((x, ~1), T)
   167       | NONE => I);
   168   in fold_rev decl (fixes_of ctxt) types end));
   169 
   170 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   171   let
   172     val types' = fold_aterms
   173       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   174         | Var v => Vartab.update v
   175         | _ => I) t types;
   176     val sorts' = fold_types (fold_atyps
   177       (fn TFree (x, S) => Vartab.update ((x, ~1), S)
   178         | TVar v => Vartab.update v
   179         | _ => I)) t sorts;
   180   in (types', sorts') end)
   181   #> declare_type_names t
   182   #> redeclare_skolems;
   183 
   184 
   185 (* common declarations *)
   186 
   187 fun declare_internal t =
   188   declare_names t #>
   189   declare_type_occs t;
   190 
   191 fun declare_term t =
   192   declare_internal t #>
   193   declare_constraints t;
   194 
   195 fun declare_thm th = fold declare_internal (Thm.full_prop_of th :: Thm.hyps_of th);
   196 fun thm_context th = declare_thm th (Context.init_proof (Thm.theory_of_thm th));
   197 
   198 
   199 (* renaming term/type frees *)
   200 
   201 fun variant_frees ctxt ts frees =
   202   let
   203     val names = names_of (fold declare_names ts ctxt);
   204     val xs = fst (Name.variants (map #1 frees) names);
   205   in xs ~~ map snd frees end;
   206 
   207 
   208 
   209 (** fixes **)
   210 
   211 local
   212 
   213 fun no_dups [] = ()
   214   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   215 
   216 fun new_fixes names' xs xs' =
   217   map_names (K names') #>
   218   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   219   fold (declare_constraints o Syntax.free) xs' #>
   220   pair xs';
   221 
   222 in
   223 
   224 fun add_fixes xs ctxt =
   225   let
   226     val _ =
   227       (case filter (can Name.dest_skolem) xs of [] => ()
   228       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   229     val _ = no_dups (duplicates (op =) xs);
   230     val (ys, zs) = split_list (fixes_of ctxt);
   231     val names = names_of ctxt;
   232     val (xs', names') =
   233       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   234       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   235         (xs, fold Name.declare xs names));
   236   in ctxt |> new_fixes names' xs xs' end;
   237 
   238 fun fix_frees t ctxt =
   239   let
   240     val fixes = rev (fold_aterms (fn Free (x, _) =>
   241       if is_fixed ctxt x then I else insert (op =) x | _ => I) t []);
   242   in
   243     ctxt
   244     |> set_body false
   245     |> (snd o add_fixes fixes)
   246     |> restore_body ctxt
   247     |> declare_term t
   248   end;
   249 
   250 fun invent_fixes raw_xs ctxt =
   251   let
   252     val names = names_of ctxt;
   253     val xs = map Name.clean raw_xs;
   254     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   255   in ctxt |> new_fixes names' xs xs' end;
   256 
   257 end;
   258 
   259 fun invent_types Ss ctxt =
   260   let
   261     val tfrees = Name.invents (names_of ctxt) "'a" (length Ss) ~~ Ss;
   262     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   263   in (tfrees, ctxt') end;
   264 
   265 
   266 
   267 (** export -- generalize type/term variables **)
   268 
   269 fun export_inst inner outer =
   270   let
   271     val declared_outer = is_declared outer;
   272     val fixes_inner = fixes_of inner;
   273     val fixes_outer = fixes_of outer;
   274 
   275     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   276     val still_fixed = not o member (op =) gen_fixes;
   277     val gen_fixesT =
   278       Symtab.fold (fn (a, xs) =>
   279         if declared_outer a orelse exists still_fixed xs
   280         then I else cons a) (type_occs_of inner) [];
   281   in (gen_fixesT, gen_fixes) end;
   282 
   283 fun exportT_inst inner outer = #1 (export_inst inner outer);
   284 
   285 fun exportT_terms inner outer ts =
   286   map (Term.generalize (exportT_inst (fold declare_type_occs ts inner) outer, [])
   287     (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1)) ts;
   288 
   289 fun export_terms inner outer ts =
   290   map (Term.generalize (export_inst (fold declare_type_occs ts inner) outer)
   291     (fold Term.maxidx_term ts ~1 + 1)) ts;
   292 
   293 fun gen_export inst inner outer ths =
   294   let
   295     val ths' = map Thm.adjust_maxidx_thm ths;
   296     val inner' = fold (declare_type_occs o Thm.full_prop_of) ths' inner;
   297   in map (Thm.generalize (inst inner' outer) (fold Thm.maxidx_thm ths' ~1 + 1)) ths' end;
   298 
   299 val exportT = gen_export (rpair [] oo exportT_inst);
   300 val export = gen_export export_inst;
   301 
   302 
   303 
   304 (** import -- fix schematic type/term variables **)
   305 
   306 fun importT_inst ts ctxt =
   307   let
   308     val tvars = rev (fold Term.add_tvars ts []);
   309     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   310   in (tvars ~~ map TFree tfrees, ctxt') end;
   311 
   312 fun import_inst is_open ts ctxt =
   313   let
   314     val ren = if is_open then I else Name.internal;
   315     val (instT, ctxt') = importT_inst ts ctxt;
   316     val vars = map (apsnd (Term.instantiateT instT)) (rev (fold Term.add_vars ts []));
   317     val (xs, ctxt'') = invent_fixes (map (ren o #1 o #1) vars) ctxt';
   318     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   319   in ((instT, inst), ctxt'') end;
   320 
   321 fun importT_terms ts ctxt =
   322   let val (instT, ctxt') = importT_inst ts ctxt
   323   in (map (Term.instantiate (instT, [])) ts, ctxt') end;
   324 
   325 fun import_terms is_open ts ctxt =
   326   let val (inst, ctxt') = import_inst is_open ts ctxt
   327   in (map (Term.instantiate inst) ts, ctxt') end;
   328 
   329 fun importT ths ctxt =
   330   let
   331     val thy = Context.theory_of_proof ctxt;
   332     val certT = Thm.ctyp_of thy;
   333     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   334     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   335     val ths' = map (Thm.instantiate (instT', [])) ths;
   336   in ((map #2 instT', ths'), ctxt') end;
   337 
   338 fun import is_open ths ctxt =
   339   let
   340     val thy = Context.theory_of_proof ctxt;
   341     val cert = Thm.cterm_of thy;
   342     val certT = Thm.ctyp_of thy;
   343     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   344     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   345     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   346     val ths' = map (Thm.instantiate (instT', inst')) ths;
   347   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   348 
   349 
   350 (* import/export *)
   351 
   352 fun gen_trade imp exp ctxt f ths =
   353   let val ((_, ths'), ctxt') = imp ths ctxt
   354   in exp ctxt' ctxt (f ths') end;
   355 
   356 val tradeT = gen_trade importT exportT;
   357 val trade = gen_trade (import true) export;
   358 
   359 
   360 (* focus on outermost parameters *)
   361 
   362 fun forall_elim_prop t prop =
   363   Thm.beta_conversion false (Thm.capply (#2 (Thm.dest_comb prop)) t)
   364   |> Thm.cprop_of |> Thm.dest_comb |> #2;
   365 
   366 fun focus goal ctxt =
   367   let
   368     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   369     val t = Thm.term_of goal;
   370     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   371     val (xs, Ts) = split_list ps;
   372     val (xs', ctxt') = invent_fixes xs ctxt;
   373     val ps' = ListPair.map (cert o Free) (xs', Ts);
   374     val goal' = fold forall_elim_prop ps' goal;
   375   in ((ps', goal'), ctxt') end;
   376 
   377 
   378 (** implicit polymorphism **)
   379 
   380 (* warn_extra_tfrees *)
   381 
   382 fun warn_extra_tfrees ctxt1 ctxt2 =
   383   let
   384     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   385     fun occs_free a x =
   386       (case def_type ctxt1 false (x, ~1) of
   387         SOME T => if occs_typ a T then I else cons (a, x)
   388       | NONE => cons (a, x));
   389 
   390     val occs1 = type_occs_of ctxt1;
   391     val occs2 = type_occs_of ctxt2;
   392     val extras = Symtab.fold (fn (a, xs) =>
   393       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   394     val tfrees = map #1 extras |> sort_distinct string_ord;
   395     val frees = map #2 extras |> sort_distinct string_ord;
   396   in
   397     if null extras then ()
   398     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   399       space_implode " or " (map quote frees))
   400   end;
   401 
   402 
   403 (* polymorphic terms *)
   404 
   405 fun polymorphic ctxt ts =
   406   let
   407     val ctxt' = fold declare_term ts ctxt;
   408     val occs = type_occs_of ctxt;
   409     val occs' = type_occs_of ctxt';
   410     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   411     val idx = fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1;
   412   in map (Term.generalize (types, []) idx) ts end;
   413 
   414 fun hidden_polymorphism t T =
   415   let
   416     val tvarsT = Term.add_tvarsT T [];
   417     val extra_tvars = Term.fold_types (Term.fold_atyps
   418       (fn TVar v => if member (op =) tvarsT v then I else insert (op =) v | _ => I)) t [];
   419   in extra_tvars end;
   420 
   421 
   422 
   423 (** term bindings **)
   424 
   425 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   426   | add_bind ((x, i), SOME t) =
   427       let
   428         val T = Term.fastype_of t;
   429         val t' =
   430           if null (hidden_polymorphism t T) then t
   431           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   432       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   433 
   434 val add_binds = fold add_bind;
   435 
   436 fun expand_binds ctxt =
   437   let
   438     val binds = binds_of ctxt;
   439     fun expand (t as Var (xi, T)) =
   440           (case Vartab.lookup binds xi of
   441             SOME u => Envir.expand_atom T u
   442           | NONE => t)
   443       | expand t = t;
   444   in Envir.beta_norm o Term.map_aterms expand end;
   445 
   446 end;