src/Pure/library.ML
author wenzelm
Sun Apr 09 18:51:17 2006 +0200 (2006-04-09)
changeset 19383 a7c055012a8c
parent 19301 ce99525202fc
child 19424 b701ea590259
permissions -rw-r--r--
added coalesce;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix 1 |> |-> ||> ||>> |>> |>>> #> #->;
    12 infix 2 ?;
    13 infix 3 o oo ooo oooo;
    14 
    15 infix 4 ~~ upto downto;
    16 infix orf andf \ \\ ins ins_string ins_int mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string;
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    25   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    26   val |> : 'a * ('a -> 'b) -> 'b
    27   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    28   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    29   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    30   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    31   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    32   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    33   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    34   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    35   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    36   val tap: ('b -> 'a) -> 'b -> 'b
    37   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    38   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    39   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    40   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    41 
    42   (*old options -- invalidated*)
    43   datatype invalid = None of invalid
    44   exception OPTION of invalid
    45 
    46   (*options*)
    47   val the: 'a option -> 'a
    48   val these: 'a list option -> 'a list
    49   val the_default: 'a -> 'a option -> 'a
    50   val the_list: 'a option -> 'a list
    51   val if_none: 'a option -> 'a -> 'a
    52   val is_some: 'a option -> bool
    53   val is_none: 'a option -> bool
    54   val perhaps: ('a -> 'a option) -> 'a -> 'a
    55 
    56   (*exceptions*)
    57   val try: ('a -> 'b) -> 'a -> 'b option
    58   val can: ('a -> 'b) -> 'a -> bool
    59   exception EXCEPTION of exn * string
    60   val do_transform_failure: bool ref
    61   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    62   datatype 'a result = Result of 'a | Exn of exn
    63   val capture: ('a -> 'b) -> 'a -> 'b result
    64   val release: 'a result -> 'a
    65   val get_result: 'a result -> 'a option
    66   val get_exn: 'a result -> exn option
    67 
    68   (*errors*)
    69   exception ERROR of string
    70   val error: string -> 'a
    71   val cat_error: string -> string -> 'a
    72   val sys_error: string -> 'a
    73   val assert: bool -> string -> unit
    74   val deny: bool -> string -> unit
    75   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    76 
    77   (*pairs*)
    78   val pair: 'a -> 'b -> 'a * 'b
    79   val rpair: 'a -> 'b -> 'b * 'a
    80   val fst: 'a * 'b -> 'a
    81   val snd: 'a * 'b -> 'b
    82   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    83   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    84   val swap: 'a * 'b -> 'b * 'a
    85   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    86   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    87   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    88 
    89   (*booleans*)
    90   val equal: ''a -> ''a -> bool
    91   val not_equal: ''a -> ''a -> bool
    92   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    93   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    94   val exists: ('a -> bool) -> 'a list -> bool
    95   val forall: ('a -> bool) -> 'a list -> bool
    96   val set: bool ref -> bool
    97   val reset: bool ref -> bool
    98   val toggle: bool ref -> bool
    99   val change: 'a ref -> ('a -> 'a) -> unit
   100   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
   101   val conditional: bool -> (unit -> unit) -> unit
   102 
   103   (*lists*)
   104   exception UnequalLengths
   105   val cons: 'a -> 'a list -> 'a list
   106   val single: 'a -> 'a list
   107   val singleton: ('a list -> 'b list) -> 'a -> 'b
   108   val append: 'a list -> 'a list -> 'a list
   109   val apply: ('a -> 'a) list -> 'a -> 'a
   110   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   111   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   112   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   113   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   114   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   115   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
   116   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
   117   val chop: int -> 'a list -> 'a list * 'a list
   118   val splitAt: int * 'a list -> 'a list * 'a list
   119   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   120   val nth: 'a list -> int -> 'a
   121   val nth_update: int * 'a -> 'a list -> 'a list
   122   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
   123   val nth_list: 'a list list -> int -> 'a list
   124   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
   125   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   126   val split_last: 'a list -> 'a list * 'a
   127   val find_index: ('a -> bool) -> 'a list -> int
   128   val find_index_eq: ''a -> ''a list -> int
   129   val find_first: ('a -> bool) -> 'a list -> 'a option
   130   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   131   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   132   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   133   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   134   val ~~ : 'a list * 'b list -> ('a * 'b) list
   135   val split_list: ('a * 'b) list -> 'a list * 'b list
   136   val separate: 'a -> 'a list -> 'a list
   137   val replicate: int -> 'a -> 'a list
   138   val multiply: 'a list -> 'a list list -> 'a list list
   139   val product: 'a list -> 'b list -> ('a * 'b) list
   140   val coalesce: ('a * 'a -> bool) -> ('a * 'b) list -> ('a * 'b list) list
   141   val filter: ('a -> bool) -> 'a list -> 'a list
   142   val filter_out: ('a -> bool) -> 'a list -> 'a list
   143   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   144   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   145   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   146   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   147   val prefixes1: 'a list -> 'a list list
   148   val prefixes: 'a list -> 'a list list
   149   val suffixes1: 'a list -> 'a list list
   150   val suffixes: 'a list -> 'a list list
   151 
   152   (*integers*)
   153   val gcd: IntInf.int * IntInf.int -> IntInf.int
   154   val lcm: IntInf.int * IntInf.int -> IntInf.int
   155   val inc: int ref -> int
   156   val dec: int ref -> int
   157   val upto: int * int -> int list
   158   val downto: int * int -> int list
   159   val downto0: int list * int -> bool
   160   val radixpand: int * int -> int list
   161   val radixstring: int * string * int -> string
   162   val string_of_int: int -> string
   163   val string_of_indexname: string * int -> string
   164   val read_radixint: int * string list -> int * string list
   165   val read_int: string list -> int * string list
   166   val oct_char: string -> string
   167 
   168   (*strings*)
   169   val nth_string: string -> int -> string
   170   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   171   val exists_string: (string -> bool) -> string -> bool
   172   val forall_string: (string -> bool) -> string -> bool
   173   val enclose: string -> string -> string -> string
   174   val unenclose: string -> string
   175   val quote: string -> string
   176   val space_implode: string -> string list -> string
   177   val commas: string list -> string
   178   val commas_quote: string list -> string
   179   val cat_lines: string list -> string
   180   val space_explode: string -> string -> string list
   181   val split_lines: string -> string list
   182   val prefix_lines: string -> string -> string
   183   val untabify: string list -> string list
   184   val prefix: string -> string -> string
   185   val suffix: string -> string -> string
   186   val unprefix: string -> string -> string
   187   val unsuffix: string -> string -> string
   188   val replicate_string: int -> string -> string
   189   val translate_string: (string -> string) -> string -> string
   190 
   191   (*lists as sets -- see also Pure/General/ord_list.ML*)
   192   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   193   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   194   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   195   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   196   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   197   val mem: ''a * ''a list -> bool
   198   val mem_int: int * int list -> bool
   199   val mem_string: string * string list -> bool
   200   val ins: ''a * ''a list -> ''a list
   201   val ins_int: int * int list -> int list
   202   val ins_string: string * string list -> string list
   203   val union: ''a list * ''a list -> ''a list
   204   val union_int: int list * int list -> int list
   205   val union_string: string list * string list -> string list
   206   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   207   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   208   val inter: ''a list * ''a list -> ''a list
   209   val inter_int: int list * int list -> int list
   210   val inter_string: string list * string list -> string list
   211   val subset: ''a list * ''a list -> bool
   212   val subset_int: int list * int list -> bool
   213   val subset_string: string list * string list -> bool
   214   val eq_set: ''a list * ''a list -> bool
   215   val eq_set_string: string list * string list -> bool
   216   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   217   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   218   val \ : ''a list * ''a -> ''a list
   219   val \\ : ''a list * ''a list -> ''a list
   220   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   221   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   222   val findrep: ''a list -> ''a list
   223   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   224   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   225   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   226 
   227   (*lists as tables -- see also Pure/General/alist.ML*)
   228   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   229   val merge_lists: ''a list -> ''a list -> ''a list
   230   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   231 
   232   (*balanced trees*)
   233   exception Balance
   234   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   235   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   236   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   237 
   238   (*orders*)
   239   val is_equal: order -> bool
   240   val rev_order: order -> order
   241   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   242   val eq_ord: ('a -> order) -> 'a -> bool
   243   val int_ord: int * int -> order
   244   val string_ord: string * string -> order
   245   val fast_string_ord: string * string -> order
   246   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   247   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   248   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   249   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   250   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   251   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   252   val sort_strings: string list -> string list
   253   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   254 
   255   (*random numbers*)
   256   exception RANDOM
   257   val random: unit -> real
   258   val random_range: int -> int -> int
   259   val one_of: 'a list -> 'a
   260   val frequency: (int * 'a) list -> 'a
   261 
   262   (*current directory*)
   263   val cd: string -> unit
   264   val pwd: unit -> string
   265 
   266   (*misc*)
   267   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   268   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   269   val gensym: string -> string
   270   val scanwords: (string -> bool) -> string list -> string list
   271   type stamp
   272   val stamp: unit -> stamp
   273   type serial
   274   val serial: unit -> serial
   275   structure Object: sig type T end
   276 end;
   277 
   278 signature LIBRARY =
   279 sig
   280   include BASIC_LIBRARY
   281   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   282   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   283   val take: int * 'a list -> 'a list
   284   val drop: int * 'a list -> 'a list
   285   val last_elem: 'a list -> 'a
   286   val flat: 'a list list -> 'a list
   287   val seq: ('a -> unit) -> 'a list -> unit
   288   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   289   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   290 end;
   291 
   292 structure Library: LIBRARY =
   293 struct
   294 
   295 
   296 (** functions **)
   297 
   298 fun I x = x;
   299 fun K x = fn _ => x;
   300 fun curry f x y = f (x, y);
   301 fun uncurry f (x, y) = f x y;
   302 
   303 (*reverse application and structured results*)
   304 fun x |> f = f x;
   305 fun (x, y) |-> f = f x y;
   306 fun (x, y) |>> f = (f x, y);
   307 fun (x, y) ||> f = (x, f y);
   308 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   309 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   310 
   311 (*reverse composition*)
   312 fun f #> g = g o f;
   313 fun f #-> g = uncurry g o f;
   314 
   315 (*conditional application*)
   316 fun b ? f = fn x => if b x then f x else x;
   317 
   318 (*view results*)
   319 fun `f = fn x => (f x, x);
   320 fun tap f = fn x => (f x; x);
   321 
   322 (*composition with multiple args*)
   323 fun (f oo g) x y = f (g x y);
   324 fun (f ooo g) x y z = f (g x y z);
   325 fun (f oooo g) x y z w = f (g x y z w);
   326 
   327 (*function exponentiation: f(...(f x)...) with n applications of f*)
   328 fun funpow n f x =
   329   let fun rep (0, x) = x
   330         | rep (n, x) = rep (n - 1, f x)
   331   in rep (n, x) end;
   332 
   333 
   334 (** options **)
   335 
   336 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   337 datatype invalid = None of invalid;
   338 exception OPTION of invalid;
   339 
   340 val the = Option.valOf;
   341 
   342 fun these (SOME x) = x
   343   | these _ = [];
   344 
   345 fun the_default x (SOME y) = y
   346   | the_default x _ = x;
   347 
   348 fun the_list (SOME x) = [x]
   349   | the_list _ = []
   350 
   351 (*strict!*)
   352 fun if_none NONE y = y
   353   | if_none (SOME x) _ = x;
   354 
   355 fun is_some (SOME _) = true
   356   | is_some NONE = false;
   357 
   358 fun is_none (SOME _) = false
   359   | is_none NONE = true;
   360 
   361 fun perhaps f x = the_default x (f x);
   362 
   363 
   364 (* exceptions *)
   365 
   366 val do_transform_failure = ref true;
   367 
   368 fun transform_failure exn f x =
   369   if ! do_transform_failure then
   370     f x handle Interrupt => raise Interrupt | e => raise exn e
   371   else f x;
   372 
   373 exception EXCEPTION of exn * string;
   374 
   375 
   376 fun try f x = SOME (f x)
   377   handle Interrupt => raise Interrupt | _ => NONE;
   378 
   379 fun can f x = is_some (try f x);
   380 
   381 
   382 datatype 'a result =
   383   Result of 'a |
   384   Exn of exn;
   385 
   386 fun capture f x = Result (f x) handle e => Exn e;
   387 
   388 fun release (Result y) = y
   389   | release (Exn e) = raise e;
   390 
   391 fun get_result (Result x) = SOME x
   392   | get_result _ = NONE;
   393 
   394 fun get_exn (Exn exn) = SOME exn
   395   | get_exn _ = NONE;
   396 
   397 
   398 (* errors *)
   399 
   400 exception ERROR of string;
   401 
   402 fun error msg = raise ERROR msg;
   403 
   404 fun cat_error "" msg = error msg
   405   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   406 
   407 fun sys_error msg = error ("## SYSTEM ERROR ##\n" ^ msg);
   408 
   409 fun assert p msg = if p then () else error msg;
   410 fun deny p msg = if p then error msg else ();
   411 
   412 fun assert_all pred list msg =
   413   let
   414     fun ass [] = ()
   415       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   416   in ass list end;
   417 
   418 
   419 
   420 (** pairs **)
   421 
   422 fun pair x y = (x, y);
   423 fun rpair x y = (y, x);
   424 
   425 fun fst (x, y) = x;
   426 fun snd (x, y) = y;
   427 
   428 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   429 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   430 
   431 fun swap (x, y) = (y, x);
   432 
   433 (*apply function to components*)
   434 fun apfst f (x, y) = (f x, y);
   435 fun apsnd f (x, y) = (x, f y);
   436 fun pairself f (x, y) = (f x, f y);
   437 
   438 
   439 
   440 (** booleans **)
   441 
   442 (* equality *)
   443 
   444 fun equal x y = x = y;
   445 fun not_equal x y = x <> y;
   446 
   447 
   448 (* operators for combining predicates *)
   449 
   450 fun p orf q = fn x => p x orelse q x;
   451 fun p andf q = fn x => p x andalso q x;
   452 
   453 
   454 (* predicates on lists *)
   455 
   456 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   457 fun exists (pred: 'a -> bool) : 'a list -> bool =
   458   let fun boolf [] = false
   459         | boolf (x :: xs) = pred x orelse boolf xs
   460   in boolf end;
   461 
   462 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   463 fun forall (pred: 'a -> bool) : 'a list -> bool =
   464   let fun boolf [] = true
   465         | boolf (x :: xs) = pred x andalso boolf xs
   466   in boolf end;
   467 
   468 
   469 (* flags *)
   470 
   471 fun set flag = (flag := true; true);
   472 fun reset flag = (flag := false; false);
   473 fun toggle flag = (flag := not (! flag); ! flag);
   474 
   475 fun change r f = r := f (! r);
   476 
   477 (*temporarily set flag during execution*)
   478 fun setmp flag value f x =
   479   let
   480     val orig_value = ! flag;
   481     val _ = flag := value;
   482     val result = capture f x;
   483     val _ = flag := orig_value;
   484   in release result end;
   485 
   486 
   487 (* conditional execution *)
   488 
   489 fun conditional b f = if b then f () else ();
   490 
   491 
   492 
   493 (** lists **)
   494 
   495 exception UnequalLengths;
   496 
   497 fun cons x xs = x :: xs;
   498 fun single x = [x];
   499 
   500 fun singleton f x = (case f [x] of [y] => y | _ => raise Empty);
   501 
   502 fun append xs ys = xs @ ys;
   503 
   504 fun apply [] x = x
   505   | apply (f :: fs) x = apply fs (f x);
   506 
   507 
   508 (* fold *)
   509 
   510 fun fold f =
   511   let
   512     fun fold_aux [] y = y
   513       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   514   in fold_aux end;
   515 
   516 fun fold_rev f =
   517   let
   518     fun fold_aux [] y = y
   519       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   520   in fold_aux end;
   521 
   522 fun fold_map f =
   523   let
   524     fun fold_aux [] y = ([], y)
   525       | fold_aux (x :: xs) y =
   526           let
   527             val (x', y') = f x y;
   528             val (xs', y'') = fold_aux xs y';
   529           in (x' :: xs', y'') end;
   530   in fold_aux end;
   531 
   532 (*the following versions of fold are designed to fit nicely with infixes*)
   533 
   534 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   535     for operators that associate to the left (TAIL RECURSIVE)*)
   536 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   537   let fun itl (e, [])  = e
   538         | itl (e, a::l) = itl (f(e, a), l)
   539   in  itl end;
   540 
   541 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   542     for operators that associate to the right (not tail recursive)*)
   543 fun foldr f (l, e) =
   544   let fun itr [] = e
   545         | itr (a::l) = f(a, itr l)
   546   in  itr l  end;
   547 
   548 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   549     for n > 0, operators that associate to the right (not tail recursive)*)
   550 fun foldr1 f l =
   551   let fun itr [x] = x
   552         | itr (x::l) = f(x, itr l)
   553   in  itr l  end;
   554 
   555 fun fold_index f =
   556   let
   557     fun fold_aux _ [] y = y
   558       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   559   in fold_aux 0 end;
   560 
   561 fun foldl_map f =
   562   let
   563     fun fold_aux (x, []) = (x, [])
   564       | fold_aux (x, y :: ys) =
   565           let
   566             val (x', y') = f (x, y);
   567             val (x'', ys') = fold_aux (x', ys);
   568           in (x'', y' :: ys') end;
   569   in fold_aux end;
   570 
   571 
   572 (* basic list functions *)
   573 
   574 fun chop 0 xs = ([], xs)
   575   | chop _ [] = ([], [])
   576   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   577 
   578 fun splitAt (n, xs) = chop n xs;
   579 
   580 (*take the first n elements from a list*)
   581 fun take (n, []) = []
   582   | take (n, x :: xs) =
   583       if n > 0 then x :: take (n - 1, xs) else [];
   584 
   585 (*drop the first n elements from a list*)
   586 fun drop (n, []) = []
   587   | drop (n, x :: xs) =
   588       if n > 0 then drop (n - 1, xs) else x :: xs;
   589 
   590 fun dropwhile P [] = []
   591   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   592 
   593 (*return nth element of a list, where 0 designates the first element;
   594   raise Subscript if list too short*)
   595 fun nth xs i = List.nth (xs, i);
   596 
   597 fun nth_list xss i = nth xss i handle Subscript => [];
   598 
   599 (*update nth element*)
   600 fun nth_update (n, x) xs =
   601     (case splitAt (n, xs) of
   602       (_, []) => raise Subscript
   603     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   604 
   605 fun nth_map 0 f (x :: xs) = f x :: xs
   606   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   607   | nth_map _ _ [] = raise Subscript;
   608 
   609 fun map_index f =
   610   let
   611     fun mapp _ [] = []
   612       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   613   in mapp 0 end;
   614 
   615 val last_elem = List.last;
   616 
   617 (*rear decomposition*)
   618 fun split_last [] = raise Empty
   619   | split_last [x] = ([], x)
   620   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   621 
   622 (*find the position of an element in a list*)
   623 fun find_index pred =
   624   let fun find _ [] = ~1
   625         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   626   in find 0 end;
   627 
   628 fun find_index_eq x = find_index (equal x);
   629 
   630 (*find first element satisfying predicate*)
   631 fun find_first _ [] = NONE
   632   | find_first pred (x :: xs) =
   633       if pred x then SOME x else find_first pred xs;
   634 
   635 (*get first element by lookup function*)
   636 fun get_first _ [] = NONE
   637   | get_first f (x :: xs) =
   638       (case f x of
   639         NONE => get_first f xs
   640       | some => some);
   641 
   642 fun get_index f =
   643   let
   644     fun get _ [] = NONE
   645       | get i (x::xs) = 
   646           case f x
   647            of NONE => get (i+1) xs
   648             | SOME y => SOME (i, y)
   649   in get 0 end;
   650 
   651 (*flatten a list of lists to a list*)
   652 val flat = List.concat;
   653 
   654 fun unflat (xs :: xss) ys =
   655       let val (ps,qs) = splitAt(length xs,ys)
   656       in ps :: unflat xss qs end
   657   | unflat [] [] = []
   658   | unflat _ _ = raise UnequalLengths;
   659 
   660 fun burrow f xss =
   661   unflat xss ((f o flat) xss);
   662 
   663 fun fold_burrow f xss s =
   664   apfst (unflat xss) (f (flat xss) s);
   665 
   666 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   667   (proc x1; ...; proc xn) for side effects*)
   668 val seq = List.app;
   669 
   670 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   671 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   672   | separate _ xs = xs;
   673 
   674 (*make the list [x, x, ..., x] of length n*)
   675 fun replicate n (x: 'a) : 'a list =
   676   let fun rep (0, xs) = xs
   677         | rep (n, xs) = rep (n - 1, x :: xs)
   678   in
   679     if n < 0 then raise Subscript
   680     else rep (n, [])
   681   end;
   682 
   683 fun translate_string f = String.translate (f o String.str);
   684 
   685 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   686 fun multiply [] _ = []
   687   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   688 
   689 (*direct product*)
   690 fun product _ [] = []
   691   | product [] _ = []
   692   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   693 
   694 (*coalesce ranges of equal keys*)
   695 fun coalesce eq =
   696   let
   697     fun vals _ [] = ([], [])
   698       | vals x (lst as (y, b) :: ps) =
   699           if eq (x, y) then vals x ps |>> cons b
   700           else ([], lst);
   701     fun coal [] = []
   702       | coal ((x, a) :: ps) =
   703           let val (bs, qs) = vals x ps
   704           in (x, a :: bs) :: coal qs end;
   705   in coal end;
   706 
   707 
   708 (* filter *)
   709 
   710 (*copy the list preserving elements that satisfy the predicate*)
   711 val filter = List.filter;
   712 fun filter_out f = filter (not o f);
   713 val mapfilter = List.mapPartial;
   714 
   715 
   716 (* lists of pairs *)
   717 
   718 exception UnequalLengths;
   719 
   720 fun map2 _ [] [] = []
   721   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   722   | map2 _ _ _ = raise UnequalLengths;
   723 
   724 fun fold2 f =
   725   let
   726     fun fold_aux [] [] z = z
   727       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   728       | fold_aux _ _ _ = raise UnequalLengths;
   729   in fold_aux end;
   730 
   731 
   732 (*combine two lists forming a list of pairs:
   733   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   734 fun [] ~~ [] = []
   735   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   736   | _ ~~ _ = raise UnequalLengths;
   737 
   738 (*inverse of ~~; the old 'split':
   739   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   740 val split_list = ListPair.unzip;
   741 
   742 fun equal_lists eq (xs, ys) =
   743   let
   744     fun eq' [] [] = true
   745       | eq' (x :: xs) (y :: ys) = eq (x, y) andalso eq' xs ys
   746   in length xs = length ys andalso eq' xs ys end;
   747 
   748 
   749 (* prefixes, suffixes *)
   750 
   751 fun is_prefix _ [] _ = true
   752   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   753   | is_prefix eq _ _ = false;
   754 
   755 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   756    where xi is the first element that does not satisfy the predicate*)
   757 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   758   let fun take (rxs, []) = (rev rxs, [])
   759         | take (rxs, x :: xs) =
   760             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   761   in  take([], xs)  end;
   762 
   763 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   764    where xi is the last element that does not satisfy the predicate*)
   765 fun take_suffix _ [] = ([], [])
   766   | take_suffix pred (x :: xs) =
   767       (case take_suffix pred xs of
   768         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   769       | (prfx, sffx) => (x :: prfx, sffx));
   770 
   771 fun prefixes1 [] = []
   772   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   773 
   774 fun prefixes xs = [] :: prefixes1 xs;
   775 
   776 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   777 fun suffixes xs = [] :: suffixes1 xs;
   778 
   779 
   780 (** integers **)
   781 
   782 fun gcd (x, y) =
   783   let fun gxd x y : IntInf.int =
   784     if y = 0 then x else gxd y (x mod y)
   785   in if x < y then gxd y x else gxd x y end;
   786 
   787 fun lcm (x, y) = (x * y) div gcd (x, y);
   788 
   789 fun inc i = (i := ! i + 1; ! i);
   790 fun dec i = (i := ! i - 1; ! i);
   791 
   792 
   793 (* lists of integers *)
   794 
   795 (*make the list [from, from + 1, ..., to]*)
   796 fun (from upto to) =
   797   if from > to then [] else from :: ((from + 1) upto to);
   798 
   799 (*make the list [from, from - 1, ..., to]*)
   800 fun (from downto to) =
   801   if from < to then [] else from :: ((from - 1) downto to);
   802 
   803 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   804 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   805   | downto0 ([], n) = n = ~1;
   806 
   807 
   808 (* convert integers to strings *)
   809 
   810 (*expand the number in the given base;
   811   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   812 fun radixpand (base, num) : int list =
   813   let
   814     fun radix (n, tail) =
   815       if n < base then n :: tail
   816       else radix (n div base, (n mod base) :: tail)
   817   in radix (num, []) end;
   818 
   819 (*expands a number into a string of characters starting from "zerochar";
   820   example: radixstring (2, "0", 8) gives "1000"*)
   821 fun radixstring (base, zerochar, num) =
   822   let val offset = ord zerochar;
   823       fun chrof n = chr (offset + n)
   824   in implode (map chrof (radixpand (base, num))) end;
   825 
   826 
   827 val string_of_int = Int.toString;
   828 
   829 fun string_of_indexname (a,0) = a
   830   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   831 
   832 
   833 (* read integers *)
   834 
   835 fun read_radixint (radix: int, cs) : int * string list =
   836   let val zero = ord"0"
   837       val limit = zero+radix
   838       fun scan (num,[]) = (num,[])
   839         | scan (num, c::cs) =
   840               if  zero <= ord c  andalso  ord c < limit
   841               then scan(radix*num + ord c - zero, cs)
   842               else (num, c::cs)
   843   in  scan(0,cs)  end;
   844 
   845 fun read_int cs = read_radixint (10, cs);
   846 
   847 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   848 
   849 
   850 
   851 (** strings **)
   852 
   853 (* functions tuned for strings, avoiding explode *)
   854 
   855 fun nth_string str i =
   856   (case try String.substring (str, i, 1) of
   857     SOME s => s
   858   | NONE => raise Subscript);
   859 
   860 fun fold_string f str x0 =
   861   let
   862     val n = size str;
   863     fun iter (x, i) =
   864       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   865   in iter (x0, 0) end;
   866 
   867 fun exists_string pred str =
   868   let
   869     val n = size str;
   870     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   871   in ex 0 end;
   872 
   873 fun forall_string pred = not o exists_string (not o pred);
   874 
   875 (*enclose in brackets*)
   876 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   877 fun unenclose str = String.substring (str, 1, size str - 2);
   878 
   879 (*simple quoting (does not escape special chars)*)
   880 val quote = enclose "\"" "\"";
   881 
   882 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   883 fun space_implode a bs = implode (separate a bs);
   884 
   885 val commas = space_implode ", ";
   886 val commas_quote = commas o map quote;
   887 
   888 (*concatenate messages, one per line, into a string*)
   889 val cat_lines = space_implode "\n";
   890 
   891 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   892 fun space_explode _ "" = []
   893   | space_explode sep str =
   894       let
   895         fun expl chs =
   896           (case take_prefix (fn s => s <> sep) chs of
   897             (cs, []) => [implode cs]
   898           | (cs, _ :: cs') => implode cs :: expl cs');
   899       in expl (explode str) end;
   900 
   901 val split_lines = space_explode "\n";
   902 
   903 fun prefix_lines "" txt = txt
   904   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   905 
   906 fun untabify chs =
   907   let
   908     val tab_width = 8;
   909 
   910     fun untab (_, "\n") = (0, ["\n"])
   911       | untab (pos, "\t") =
   912           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   913       | untab (pos, c) = (pos + 1, [c]);
   914   in
   915     if not (exists (fn c => c = "\t") chs) then chs
   916     else flat (#2 (foldl_map untab (0, chs)))
   917   end;
   918 
   919 fun prefix prfx s = prfx ^ s;
   920 fun suffix sffx s = s ^ sffx;
   921 
   922 fun unprefix prfx s =
   923   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   924   else raise Fail "unprefix";
   925 
   926 fun unsuffix sffx s =
   927   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   928   else raise Fail "unsuffix";
   929 
   930 fun replicate_string 0 _ = ""
   931   | replicate_string 1 a = a
   932   | replicate_string k a =
   933       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   934       else replicate_string (k div 2) (a ^ a) ^ a;
   935 
   936 
   937 
   938 (** lists as sets -- see also Pure/General/ord_list.ML **)
   939 
   940 (*canonical member, insert, remove*)
   941 fun member eq list x =
   942   let
   943     fun memb [] = false
   944       | memb (y :: ys) = eq (x, y) orelse memb ys;
   945   in memb list end;
   946 
   947 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   948 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   949 
   950 fun subtract eq = fold (remove eq);
   951 
   952 fun merge _ ([], ys) = ys
   953   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   954 
   955 (*old-style infixes*)
   956 fun x mem xs = member (op =) xs x;
   957 fun (x: int) mem_int xs = member (op =) xs x;
   958 fun (x: string) mem_string xs = member (op =) xs x;
   959 
   960 fun x ins xs = insert (op =) x xs;
   961 fun (x: int) ins_int xs = insert (op =) x xs;
   962 fun (x: string) ins_string xs = insert (op =) x xs;
   963 
   964 
   965 (*union of sets represented as lists: no repetitions*)
   966 fun xs union [] = xs
   967   | [] union ys = ys
   968   | (x :: xs) union ys = xs union (x ins ys);
   969 
   970 (*union of sets, optimized version for ints*)
   971 fun (xs:int list) union_int [] = xs
   972   | [] union_int ys = ys
   973   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   974 
   975 (*union of sets, optimized version for strings*)
   976 fun (xs:string list) union_string [] = xs
   977   | [] union_string ys = ys
   978   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   979 
   980 (*generalized union*)
   981 fun gen_union eq (xs, []) = xs
   982   | gen_union eq ([], ys) = ys
   983   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   984 
   985 
   986 (*intersection*)
   987 fun [] inter ys = []
   988   | (x :: xs) inter ys =
   989       if x mem ys then x :: (xs inter ys) else xs inter ys;
   990 
   991 (*intersection, optimized version for ints*)
   992 fun ([]:int list) inter_int ys = []
   993   | (x :: xs) inter_int ys =
   994       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   995 
   996 (*intersection, optimized version for strings *)
   997 fun ([]:string list) inter_string ys = []
   998   | (x :: xs) inter_string ys =
   999       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
  1000 
  1001 (*generalized intersection*)
  1002 fun gen_inter eq ([], ys) = []
  1003   | gen_inter eq (x::xs, ys) =
  1004       if member eq ys x then x :: gen_inter eq (xs, ys)
  1005       else gen_inter eq (xs, ys);
  1006 
  1007 
  1008 (*subset*)
  1009 fun [] subset ys = true
  1010   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
  1011 
  1012 (*subset, optimized version for ints*)
  1013 fun ([]: int list) subset_int ys = true
  1014   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
  1015 
  1016 (*subset, optimized version for strings*)
  1017 fun ([]: string list) subset_string ys = true
  1018   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
  1019 
  1020 (*set equality*)
  1021 fun eq_set (xs, ys) =
  1022   xs = ys orelse (xs subset ys andalso ys subset xs);
  1023 
  1024 (*set equality for strings*)
  1025 fun eq_set_string ((xs: string list), ys) =
  1026   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
  1027 
  1028 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
  1029 
  1030 fun gen_eq_set eq (xs, ys) =
  1031   equal_lists eq (xs, ys) orelse
  1032     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
  1033 
  1034 
  1035 (*removing an element from a list WITHOUT duplicates*)
  1036 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
  1037   | [] \ x = [];
  1038 
  1039 fun ys \\ xs = foldl (op \) (ys,xs);
  1040 
  1041 (*removing an element from a list -- possibly WITH duplicates*)
  1042 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
  1043 fun gen_rems eq (xs, ys) = filter_out (member eq ys) xs;
  1044 
  1045 (*returns the tail beginning with the first repeated element, or []*)
  1046 fun findrep [] = []
  1047   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
  1048 
  1049 
  1050 (*makes a list of the distinct members of the input; preserves order, takes
  1051   first of equal elements*)
  1052 fun distinct eq lst =
  1053   let
  1054     fun dist (rev_seen, []) = rev rev_seen
  1055       | dist (rev_seen, x :: xs) =
  1056           if member eq rev_seen x then dist (rev_seen, xs)
  1057           else dist (x :: rev_seen, xs);
  1058   in dist ([], lst) end;
  1059 
  1060 (*returns a list containing all repeated elements exactly once; preserves
  1061   order, takes first of equal elements*)
  1062 fun duplicates eq lst =
  1063   let
  1064     fun dups (rev_dups, []) = rev rev_dups
  1065       | dups (rev_dups, x :: xs) =
  1066           if member eq rev_dups x orelse not (member eq xs x) then
  1067             dups (rev_dups, xs)
  1068           else dups (x :: rev_dups, xs);
  1069   in dups ([], lst) end;
  1070 
  1071 fun has_duplicates eq =
  1072   let
  1073     fun dups [] = false
  1074       | dups (x :: xs) = member eq xs x orelse dups xs;
  1075   in dups end;
  1076 
  1077 
  1078 (** association lists -- legacy operations **)
  1079 
  1080 fun gen_merge_lists _ xs [] = xs
  1081   | gen_merge_lists _ [] ys = ys
  1082   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1083 
  1084 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1085 fun merge_alists al = gen_merge_lists (eq_fst (op =)) al;
  1086 
  1087 
  1088 (** balanced trees **)
  1089 
  1090 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1091 
  1092 (*balanced folding; avoids deep nesting*)
  1093 fun fold_bal f [x] = x
  1094   | fold_bal f [] = raise Balance
  1095   | fold_bal f xs =
  1096       let val (ps,qs) = splitAt(length xs div 2, xs)
  1097       in  f (fold_bal f ps, fold_bal f qs)  end;
  1098 
  1099 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1100 fun access_bal (f, g, x) n i =
  1101   let fun acc n i =     (*1<=i<=n*)
  1102           if n=1 then x else
  1103           let val n2 = n div 2
  1104           in  if i<=n2 then f (acc n2 i)
  1105                        else g (acc (n-n2) (i-n2))
  1106           end
  1107   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1108 
  1109 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1110 fun accesses_bal (f, g, x) n =
  1111   let fun acc n =
  1112           if n=1 then [x] else
  1113           let val n2 = n div 2
  1114               val acc2 = acc n2
  1115           in  if n-n2=n2 then map f acc2 @ map g acc2
  1116                          else map f acc2 @ map g (acc (n-n2)) end
  1117   in  if 1<=n then acc n else raise Balance  end;
  1118 
  1119 
  1120 
  1121 (** orders **)
  1122 
  1123 fun is_equal EQUAL = true
  1124   | is_equal _ = false;
  1125 
  1126 fun rev_order LESS = GREATER
  1127   | rev_order EQUAL = EQUAL
  1128   | rev_order GREATER = LESS;
  1129 
  1130 (*assume rel is a linear strict order*)
  1131 fun make_ord rel (x, y) =
  1132   if rel (x, y) then LESS
  1133   else if rel (y, x) then GREATER
  1134   else EQUAL;
  1135 
  1136 fun eq_ord ord xy =
  1137   case ord xy
  1138    of EQUAL => true
  1139     | _ => false;
  1140 
  1141 val int_ord = Int.compare;
  1142 val string_ord = String.compare;
  1143 
  1144 fun fast_string_ord (s1, s2) =
  1145   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1146 
  1147 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1148   | option_ord _ (NONE, NONE) = EQUAL
  1149   | option_ord _ (NONE, SOME _) = LESS
  1150   | option_ord _ (SOME _, NONE) = GREATER;
  1151 
  1152 (*lexicographic product*)
  1153 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1154   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1155 
  1156 (*dictionary order -- in general NOT well-founded!*)
  1157 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1158       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1159   | dict_ord _ ([], []) = EQUAL
  1160   | dict_ord _ ([], _ :: _) = LESS
  1161   | dict_ord _ (_ :: _, []) = GREATER;
  1162 
  1163 (*lexicographic product of lists*)
  1164 fun list_ord elem_ord (xs, ys) =
  1165   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1166 
  1167 
  1168 (* sorting *)
  1169 
  1170 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1171 fun quicksort unique ord =
  1172   let
  1173     fun qsort [] = []
  1174       | qsort (xs as [_]) = xs
  1175       | qsort (xs as [x, y]) =
  1176           (case ord (x, y) of
  1177             LESS => xs
  1178           | EQUAL => if unique then [x] else xs
  1179           | GREATER => [y, x])
  1180       | qsort xs =
  1181           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1182           in qsort lts @ eqs @ qsort gts end
  1183     and part _ [] = ([], [], [])
  1184       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1185     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1186       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1187       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1188       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1189   in qsort end;
  1190 
  1191 fun sort ord = quicksort false ord;
  1192 fun sort_distinct ord = quicksort true ord;
  1193 
  1194 val sort_strings = sort string_ord;
  1195 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1196 
  1197 
  1198 
  1199 (** random numbers **)
  1200 
  1201 exception RANDOM;
  1202 
  1203 fun rmod x y = x - y * Real.realFloor (x / y);
  1204 
  1205 local
  1206   val a = 16807.0;
  1207   val m = 2147483647.0;
  1208   val random_seed = ref 1.0;
  1209 in
  1210 
  1211 fun random () =
  1212   let val r = rmod (a * !random_seed) m
  1213   in (random_seed := r; r) end;
  1214 
  1215 end;
  1216 
  1217 fun random_range l h =
  1218   if h < l orelse l < 0 then raise RANDOM
  1219   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1220 
  1221 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1222 
  1223 fun frequency xs =
  1224   let
  1225     val sum = foldl op + (0, map fst xs);
  1226     fun pick n ((k: int, x) :: xs) =
  1227       if n <= k then x else pick (n - k) xs
  1228   in pick (random_range 1 sum) xs end;
  1229 
  1230 
  1231 (** current directory **)
  1232 
  1233 val cd = OS.FileSys.chDir;
  1234 val pwd = OS.FileSys.getDir;
  1235 
  1236 
  1237 (** misc **)
  1238 
  1239 (*Partition list into elements that satisfy predicate and those that don't.
  1240   Preserves order of elements in both lists.*)
  1241 val partition = List.partition;
  1242 
  1243 fun partition_eq (eq:'a * 'a -> bool) =
  1244   let
  1245     fun part [] = []
  1246       | part (x :: ys) =
  1247           let val (xs, xs') = partition (fn y => eq (x, y)) ys
  1248           in (x::xs)::(part xs') end
  1249   in part end;
  1250 
  1251 
  1252 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1253    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1254 fun partition_list p i j =
  1255   let fun part k xs =
  1256             if k>j then
  1257               (case xs of [] => []
  1258                          | _ => raise Fail "partition_list")
  1259             else
  1260             let val (ns, rest) = partition (p k) xs;
  1261             in  ns :: part(k+1)rest  end
  1262   in  part i end;
  1263 
  1264 
  1265 (* generating identifiers *)
  1266 
  1267 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1268 local
  1269 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1270 fun char i =      if i<26 then chr (ord "A" + i)
  1271              else if i<52 then chr (ord "a" + i - 26)
  1272              else if i<62 then chr (ord"0" + i - 52)
  1273              else if i=62 then "_"
  1274              else  (*i=63*)    "'";
  1275 
  1276 val charVec = Vector.tabulate (64, char);
  1277 
  1278 fun newid n =
  1279   let
  1280   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1281 
  1282 val seedr = ref 0;
  1283 
  1284 in
  1285 
  1286 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1287 
  1288 end;
  1289 
  1290 
  1291 (* lexical scanning *)
  1292 
  1293 (*scan a list of characters into "words" composed of "letters" (recognized by
  1294   is_let) and separated by any number of non-"letters"*)
  1295 fun scanwords is_let cs =
  1296   let fun scan1 [] = []
  1297         | scan1 cs =
  1298             let val (lets, rest) = take_prefix is_let cs
  1299             in implode lets :: scanwords is_let rest end;
  1300   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1301 
  1302 
  1303 (* stamps and serial numbers *)
  1304 
  1305 type stamp = unit ref;
  1306 val stamp: unit -> stamp = ref;
  1307 
  1308 type serial = int;
  1309 local val count = ref 0
  1310 in fun serial () = inc count end;
  1311 
  1312 
  1313 (* generic objects *)
  1314 
  1315 (*note that the builtin exception datatype may be extended by new
  1316   constructors at any time*)
  1317 structure Object = struct type T = exn end;
  1318 
  1319 end;
  1320 
  1321 structure BasicLibrary: BASIC_LIBRARY = Library;
  1322 open BasicLibrary;