src/HOL/SMT.thy
author boehmes
Sun Dec 19 17:55:56 2010 +0100 (2010-12-19)
changeset 41280 a7de9d36f4f2
parent 41174 10eb369f8c01
child 41281 679118e35378
permissions -rw-r--r--
only linear occurrences of multiplication are treated as built-in (SMT solvers only support linear arithmetic in general);
hide internal constants z3div and z3mod;
rewrite div/mod to z3div/z3mod instead of adding extra rules characterizing div/mod in terms of z3div/z3mod
     1 (*  Title:      HOL/SMT.thy
     2     Author:     Sascha Boehme, TU Muenchen
     3 *)
     4 
     5 header {* Bindings to Satisfiability Modulo Theories (SMT) solvers *}
     6 
     7 theory SMT
     8 imports List
     9 uses
    10   "Tools/Datatype/datatype_selectors.ML"
    11   "Tools/SMT/smt_utils.ML"
    12   "Tools/SMT/smt_failure.ML"
    13   "Tools/SMT/smt_config.ML"
    14   ("Tools/SMT/smt_monomorph.ML")
    15   ("Tools/SMT/smt_builtin.ML")
    16   ("Tools/SMT/smt_normalize.ML")
    17   ("Tools/SMT/smt_translate.ML")
    18   ("Tools/SMT/smt_solver.ML")
    19   ("Tools/SMT/smtlib_interface.ML")
    20   ("Tools/SMT/z3_proof_parser.ML")
    21   ("Tools/SMT/z3_proof_tools.ML")
    22   ("Tools/SMT/z3_proof_literals.ML")
    23   ("Tools/SMT/z3_proof_methods.ML")
    24   ("Tools/SMT/z3_proof_reconstruction.ML")
    25   ("Tools/SMT/z3_model.ML")
    26   ("Tools/SMT/z3_interface.ML")
    27   ("Tools/SMT/smt_setup_solvers.ML")
    28 begin
    29 
    30 
    31 
    32 subsection {* Triggers for quantifier instantiation *}
    33 
    34 text {*
    35 Some SMT solvers support patterns as a quantifier instantiation
    36 heuristics.  Patterns may either be positive terms (tagged by "pat")
    37 triggering quantifier instantiations -- when the solver finds a
    38 term matching a positive pattern, it instantiates the corresponding
    39 quantifier accordingly -- or negative terms (tagged by "nopat")
    40 inhibiting quantifier instantiations.  A list of patterns
    41 of the same kind is called a multipattern, and all patterns in a
    42 multipattern are considered conjunctively for quantifier instantiation.
    43 A list of multipatterns is called a trigger, and their multipatterns
    44 act disjunctively during quantifier instantiation.  Each multipattern
    45 should mention at least all quantified variables of the preceding
    46 quantifier block.
    47 *}
    48 
    49 datatype pattern = Pattern
    50 
    51 definition pat :: "'a \<Rightarrow> pattern" where "pat _ = Pattern"
    52 definition nopat :: "'a \<Rightarrow> pattern" where "nopat _ = Pattern"
    53 
    54 definition trigger :: "pattern list list \<Rightarrow> bool \<Rightarrow> bool"
    55 where "trigger _ P = P"
    56 
    57 
    58 
    59 subsection {* Quantifier weights *}
    60 
    61 text {*
    62 Weight annotations to quantifiers influence the priority of quantifier
    63 instantiations.  They should be handled with care for solvers, which support
    64 them, because incorrect choices of weights might render a problem unsolvable.
    65 *}
    66 
    67 definition weight :: "int \<Rightarrow> bool \<Rightarrow> bool" where "weight _ P = P"
    68 
    69 text {*
    70 Weights must be non-negative.  The value @{text 0} is equivalent to providing
    71 no weight at all.
    72 
    73 Weights should only be used at quantifiers and only inside triggers (if the
    74 quantifier has triggers).  Valid usages of weights are as follows:
    75 
    76 \begin{itemize}
    77 \item
    78 @{term "\<forall>x. trigger [[pat (P x)]] (weight 2 (P x))"}
    79 \item
    80 @{term "\<forall>x. weight 3 (P x)"}
    81 \end{itemize}
    82 *}
    83 
    84 
    85 
    86 subsection {* Higher-order encoding *}
    87 
    88 text {*
    89 Application is made explicit for constants occurring with varying
    90 numbers of arguments.  This is achieved by the introduction of the
    91 following constant.
    92 *}
    93 
    94 definition fun_app where "fun_app f = f"
    95 
    96 text {*
    97 Some solvers support a theory of arrays which can be used to encode
    98 higher-order functions.  The following set of lemmas specifies the
    99 properties of such (extensional) arrays.
   100 *}
   101 
   102 lemmas array_rules = ext fun_upd_apply fun_upd_same fun_upd_other
   103   fun_upd_upd fun_app_def
   104 
   105 
   106 
   107 subsection {* First-order logic *}
   108 
   109 text {*
   110 Some SMT solvers only accept problems in first-order logic, i.e.,
   111 where formulas and terms are syntactically separated. When
   112 translating higher-order into first-order problems, all
   113 uninterpreted constants (those not built-in in the target solver)
   114 are treated as function symbols in the first-order sense.  Their
   115 occurrences as head symbols in atoms (i.e., as predicate symbols) are
   116 turned into terms by equating such atoms with @{term True}.
   117 Whenever the boolean type occurs in first-order terms, it is replaced
   118 by the following type.
   119 *}
   120 
   121 typedecl term_bool
   122 
   123 
   124 
   125 subsection {* Integer division and modulo for Z3 *}
   126 
   127 definition z3div :: "int \<Rightarrow> int \<Rightarrow> int" where
   128   "z3div k l = (if 0 \<le> l then k div l else -(k div (-l)))"
   129 
   130 definition z3mod :: "int \<Rightarrow> int \<Rightarrow> int" where
   131   "z3mod k l = (if 0 \<le> l then k mod l else k mod (-l))"
   132 
   133 
   134 
   135 subsection {* Setup *}
   136 
   137 use "Tools/SMT/smt_monomorph.ML"
   138 use "Tools/SMT/smt_builtin.ML"
   139 use "Tools/SMT/smt_normalize.ML"
   140 use "Tools/SMT/smt_translate.ML"
   141 use "Tools/SMT/smt_solver.ML"
   142 use "Tools/SMT/smtlib_interface.ML"
   143 use "Tools/SMT/z3_interface.ML"
   144 use "Tools/SMT/z3_proof_parser.ML"
   145 use "Tools/SMT/z3_proof_tools.ML"
   146 use "Tools/SMT/z3_proof_literals.ML"
   147 use "Tools/SMT/z3_proof_methods.ML"
   148 use "Tools/SMT/z3_proof_reconstruction.ML"
   149 use "Tools/SMT/z3_model.ML"
   150 use "Tools/SMT/smt_setup_solvers.ML"
   151 
   152 setup {*
   153   SMT_Config.setup #>
   154   SMT_Normalize.setup #>
   155   SMT_Solver.setup #>
   156   SMTLIB_Interface.setup #>
   157   Z3_Interface.setup #>
   158   Z3_Proof_Reconstruction.setup #>
   159   SMT_Setup_Solvers.setup
   160 *}
   161 
   162 
   163 
   164 subsection {* Configuration *}
   165 
   166 text {*
   167 The current configuration can be printed by the command
   168 @{text smt_status}, which shows the values of most options.
   169 *}
   170 
   171 
   172 
   173 subsection {* General configuration options *}
   174 
   175 text {*
   176 The option @{text smt_solver} can be used to change the target SMT
   177 solver.  The possible values are @{text cvc3}, @{text yices}, and
   178 @{text z3}.  It is advisable to locally install the selected solver,
   179 although this is not necessary for @{text cvc3} and @{text z3}, which
   180 can also be used over an Internet-based service.
   181 
   182 When using local SMT solvers, the path to their binaries should be
   183 declared by setting the following environment variables:
   184 @{text CVC3_SOLVER}, @{text YICES_SOLVER}, and @{text Z3_SOLVER}.
   185 *}
   186 
   187 declare [[ smt_solver = z3 ]]
   188 
   189 text {*
   190 Since SMT solvers are potentially non-terminating, there is a timeout
   191 (given in seconds) to restrict their runtime.  A value greater than
   192 120 (seconds) is in most cases not advisable.
   193 *}
   194 
   195 declare [[ smt_timeout = 20 ]]
   196 
   197 text {*
   198 SMT solvers apply randomized heuristics.  In case a problem is not
   199 solvable by an SMT solver, changing the following option might help.
   200 *}
   201 
   202 declare [[ smt_random_seed = 1 ]]
   203 
   204 text {*
   205 In general, the binding to SMT solvers runs as an oracle, i.e, the SMT
   206 solvers are fully trusted without additional checks.  The following
   207 option can cause the SMT solver to run in proof-producing mode, giving
   208 a checkable certificate.  This is currently only implemented for Z3.
   209 *}
   210 
   211 declare [[ smt_oracle = false ]]
   212 
   213 text {*
   214 Each SMT solver provides several commandline options to tweak its
   215 behaviour.  They can be passed to the solver by setting the following
   216 options.
   217 *}
   218 
   219 declare [[ cvc3_options = "", yices_options = "", z3_options = "" ]]
   220 
   221 text {*
   222 Enable the following option to use built-in support for datatypes and
   223 records.  Currently, this is only implemented for Z3 running in oracle
   224 mode.
   225 *}
   226 
   227 declare [[ smt_datatypes = false ]]
   228 
   229 text {*
   230 The SMT method provides an inference mechanism to detect simple triggers
   231 in quantified formulas, which might increase the number of problems
   232 solvable by SMT solvers (note: triggers guide quantifier instantiations
   233 in the SMT solver).  To turn it on, set the following option.
   234 *}
   235 
   236 declare [[ smt_infer_triggers = false ]]
   237 
   238 text {*
   239 The SMT method monomorphizes the given facts, that is, it tries to
   240 instantiate all schematic type variables with fixed types occurring
   241 in the problem.  This is a (possibly nonterminating) fixed-point
   242 construction whose cycles are limited by the following option.
   243 *}
   244 
   245 declare [[ smt_monomorph_limit = 10 ]]
   246 
   247 
   248 
   249 subsection {* Certificates *}
   250 
   251 text {*
   252 By setting the option @{text smt_certificates} to the name of a file,
   253 all following applications of an SMT solver a cached in that file.
   254 Any further application of the same SMT solver (using the very same
   255 configuration) re-uses the cached certificate instead of invoking the
   256 solver.  An empty string disables caching certificates.
   257 
   258 The filename should be given as an explicit path.  It is good
   259 practice to use the name of the current theory (with ending
   260 @{text ".certs"} instead of @{text ".thy"}) as the certificates file.
   261 *}
   262 
   263 declare [[ smt_certificates = "" ]]
   264 
   265 text {*
   266 The option @{text smt_fixed} controls whether only stored
   267 certificates are should be used or invocation of an SMT solver is
   268 allowed.  When set to @{text true}, no SMT solver will ever be
   269 invoked and only the existing certificates found in the configured
   270 cache are used;  when set to @{text false} and there is no cached
   271 certificate for some proposition, then the configured SMT solver is
   272 invoked.
   273 *}
   274 
   275 declare [[ smt_fixed = false ]]
   276 
   277 
   278 
   279 subsection {* Tracing *}
   280 
   281 text {*
   282 The SMT method, when applied, traces important information.  To
   283 make it entirely silent, set the following option to @{text false}.
   284 *}
   285 
   286 declare [[ smt_verbose = true ]]
   287 
   288 text {*
   289 For tracing the generated problem file given to the SMT solver as
   290 well as the returned result of the solver, the option
   291 @{text smt_trace} should be set to @{text true}.
   292 *}
   293 
   294 declare [[ smt_trace = false ]]
   295 
   296 text {*
   297 From the set of assumptions given to the SMT solver, those assumptions
   298 used in the proof are traced when the following option is set to
   299 @{term true}.  This only works for Z3 when it runs in non-oracle mode
   300 (see options @{text smt_solver} and @{text smt_oracle} above).
   301 *}
   302 
   303 declare [[ smt_trace_used_facts = false ]]
   304 
   305 
   306 
   307 subsection {* Schematic rules for Z3 proof reconstruction *}
   308 
   309 text {*
   310 Several prof rules of Z3 are not very well documented.  There are two
   311 lemma groups which can turn failing Z3 proof reconstruction attempts
   312 into succeeding ones: the facts in @{text z3_rule} are tried prior to
   313 any implemented reconstruction procedure for all uncertain Z3 proof
   314 rules;  the facts in @{text z3_simp} are only fed to invocations of
   315 the simplifier when reconstructing theory-specific proof steps.
   316 *}
   317 
   318 lemmas [z3_rule] =
   319   refl eq_commute conj_commute disj_commute simp_thms nnf_simps
   320   ring_distribs field_simps times_divide_eq_right times_divide_eq_left
   321   if_True if_False not_not
   322 
   323 lemma [z3_rule]:
   324   "(P \<longrightarrow> Q) = (Q \<or> \<not>P)"
   325   "(\<not>P \<longrightarrow> Q) = (P \<or> Q)"
   326   "(\<not>P \<longrightarrow> Q) = (Q \<or> P)"
   327   by auto
   328 
   329 lemma [z3_rule]:
   330   "((P = Q) \<longrightarrow> R) = (R | (Q = (\<not>P)))"
   331   by auto
   332 
   333 lemma [z3_rule]:
   334   "((\<not>P) = P) = False"
   335   "(P = (\<not>P)) = False"
   336   "(P \<noteq> Q) = (Q = (\<not>P))"
   337   "(P = Q) = ((\<not>P \<or> Q) \<and> (P \<or> \<not>Q))"
   338   "(P \<noteq> Q) = ((\<not>P \<or> \<not>Q) \<and> (P \<or> Q))"
   339   by auto
   340 
   341 lemma [z3_rule]:
   342   "(if P then P else \<not>P) = True"
   343   "(if \<not>P then \<not>P else P) = True"
   344   "(if P then True else False) = P"
   345   "(if P then False else True) = (\<not>P)"
   346   "(if \<not>P then x else y) = (if P then y else x)"
   347   "f (if P then x else y) = (if P then f x else f y)"
   348   by auto
   349 
   350 lemma [z3_rule]:
   351   "P = Q \<or> P \<or> Q"
   352   "P = Q \<or> \<not>P \<or> \<not>Q"
   353   "(\<not>P) = Q \<or> \<not>P \<or> Q"
   354   "(\<not>P) = Q \<or> P \<or> \<not>Q"
   355   "P = (\<not>Q) \<or> \<not>P \<or> Q"
   356   "P = (\<not>Q) \<or> P \<or> \<not>Q"
   357   "P \<noteq> Q \<or> P \<or> \<not>Q"
   358   "P \<noteq> Q \<or> \<not>P \<or> Q"
   359   "P \<noteq> (\<not>Q) \<or> P \<or> Q"
   360   "(\<not>P) \<noteq> Q \<or> P \<or> Q"
   361   "P \<or> Q \<or> P \<noteq> (\<not>Q)"
   362   "P \<or> Q \<or> (\<not>P) \<noteq> Q"
   363   "P \<or> \<not>Q \<or> P \<noteq> Q"
   364   "\<not>P \<or> Q \<or> P \<noteq> Q"
   365   by auto
   366 
   367 lemma [z3_rule]:
   368   "0 + (x::int) = x"
   369   "x + 0 = x"
   370   "0 * x = 0"
   371   "1 * x = x"
   372   "x + y = y + x"
   373   by auto
   374 
   375 
   376 
   377 hide_type term_bool
   378 hide_type (open) pattern
   379 hide_const Pattern fun_app z3div z3mod
   380 hide_const (open) trigger pat nopat weight
   381 
   382 
   383 
   384 subsection {* Selectors for datatypes *}
   385 
   386 setup {* Datatype_Selectors.setup *}
   387 
   388 declare [[ selector Pair 1 = fst, selector Pair 2 = snd ]]
   389 declare [[ selector Cons 1 = hd, selector Cons 2 = tl ]]
   390 
   391 end