src/HOL/Complete_Lattices.thy
author haftmann
Thu Oct 18 09:19:37 2012 +0200 (2012-10-18)
changeset 49905 a81f95693c68
parent 46884 154dc6ec0041
child 51328 d63ec23c9125
permissions -rw-r--r--
simp results for simplification results of Inf/Sup expressions on bool;
tuned proofs
     1  (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices *}
     4 
     5 theory Complete_Lattices
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50)
    12 
    13 
    14 subsection {* Syntactic infimum and supremum operations *}
    15 
    16 class Inf =
    17   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    18 
    19 class Sup =
    20   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    21 
    22 
    23 subsection {* Abstract complete lattices *}
    24 
    25 class complete_lattice = bounded_lattice + Inf + Sup +
    26   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    27      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    28   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    29      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    30 begin
    31 
    32 lemma dual_complete_lattice:
    33   "class.complete_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
    34   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    35     (unfold_locales, (fact bot_least top_greatest
    36         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    37 
    38 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    39   INF_def: "INFI A f = \<Sqinter>(f ` A)"
    40 
    41 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    42   SUP_def: "SUPR A f = \<Squnion>(f ` A)"
    43 
    44 text {*
    45   Note: must use names @{const INFI} and @{const SUPR} here instead of
    46   @{text INF} and @{text SUP} to allow the following syntax coexist
    47   with the plain constant names.
    48 *}
    49 
    50 end
    51 
    52 syntax
    53   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    54   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    55   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    56   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    57 
    58 syntax (xsymbols)
    59   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
    60   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
    61   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
    62   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
    63 
    64 translations
    65   "INF x y. B"   == "INF x. INF y. B"
    66   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
    67   "INF x. B"     == "INF x:CONST UNIV. B"
    68   "INF x:A. B"   == "CONST INFI A (%x. B)"
    69   "SUP x y. B"   == "SUP x. SUP y. B"
    70   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
    71   "SUP x. B"     == "SUP x:CONST UNIV. B"
    72   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
    73 
    74 print_translation {*
    75   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
    76     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
    77 *} -- {* to avoid eta-contraction of body *}
    78 
    79 context complete_lattice
    80 begin
    81 
    82 lemma INF_foundation_dual [no_atp]:
    83   "complete_lattice.SUPR Inf = INFI"
    84   by (simp add: fun_eq_iff INF_def
    85     complete_lattice.SUP_def [OF dual_complete_lattice])
    86 
    87 lemma SUP_foundation_dual [no_atp]:
    88   "complete_lattice.INFI Sup = SUPR"
    89   by (simp add: fun_eq_iff SUP_def
    90     complete_lattice.INF_def [OF dual_complete_lattice])
    91 
    92 lemma INF_lower: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
    93   by (auto simp add: INF_def intro: Inf_lower)
    94 
    95 lemma INF_greatest: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
    96   by (auto simp add: INF_def intro: Inf_greatest)
    97 
    98 lemma SUP_upper: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
    99   by (auto simp add: SUP_def intro: Sup_upper)
   100 
   101 lemma SUP_least: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   102   by (auto simp add: SUP_def intro: Sup_least)
   103 
   104 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   105   using Inf_lower [of u A] by auto
   106 
   107 lemma INF_lower2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   108   using INF_lower [of i A f] by auto
   109 
   110 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   111   using Sup_upper [of u A] by auto
   112 
   113 lemma SUP_upper2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   114   using SUP_upper [of i A f] by auto
   115 
   116 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
   117   by (auto intro: Inf_greatest dest: Inf_lower)
   118 
   119 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i\<in>A. u \<sqsubseteq> f i)"
   120   by (auto simp add: INF_def le_Inf_iff)
   121 
   122 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
   123   by (auto intro: Sup_least dest: Sup_upper)
   124 
   125 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i\<in>A. f i \<sqsubseteq> u)"
   126   by (auto simp add: SUP_def Sup_le_iff)
   127 
   128 lemma Inf_empty [simp]:
   129   "\<Sqinter>{} = \<top>"
   130   by (auto intro: antisym Inf_greatest)
   131 
   132 lemma INF_empty [simp]: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   133   by (simp add: INF_def)
   134 
   135 lemma Sup_empty [simp]:
   136   "\<Squnion>{} = \<bottom>"
   137   by (auto intro: antisym Sup_least)
   138 
   139 lemma SUP_empty [simp]: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   140   by (simp add: SUP_def)
   141 
   142 lemma Inf_UNIV [simp]:
   143   "\<Sqinter>UNIV = \<bottom>"
   144   by (auto intro!: antisym Inf_lower)
   145 
   146 lemma Sup_UNIV [simp]:
   147   "\<Squnion>UNIV = \<top>"
   148   by (auto intro!: antisym Sup_upper)
   149 
   150 lemma Inf_insert [simp]: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   151   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
   152 
   153 lemma INF_insert: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFI A f"
   154   by (simp add: INF_def)
   155 
   156 lemma Sup_insert [simp]: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   157   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
   158 
   159 lemma SUP_insert: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPR A f"
   160   by (simp add: SUP_def)
   161 
   162 lemma INF_image [simp]: "(\<Sqinter>x\<in>f`A. g x) = (\<Sqinter>x\<in>A. g (f x))"
   163   by (simp add: INF_def image_image)
   164 
   165 lemma SUP_image [simp]: "(\<Squnion>x\<in>f`A. g x) = (\<Squnion>x\<in>A. g (f x))"
   166   by (simp add: SUP_def image_image)
   167 
   168 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
   169   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   170 
   171 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
   172   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   173 
   174 lemma Inf_superset_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   175   by (auto intro: Inf_greatest Inf_lower)
   176 
   177 lemma Sup_subset_mono: "A \<subseteq> B \<Longrightarrow> \<Squnion>A \<sqsubseteq> \<Squnion>B"
   178   by (auto intro: Sup_least Sup_upper)
   179 
   180 lemma INF_cong:
   181   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Sqinter>x\<in>A. C x) = (\<Sqinter>x\<in>B. D x)"
   182   by (simp add: INF_def image_def)
   183 
   184 lemma SUP_cong:
   185   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Squnion>x\<in>A. C x) = (\<Squnion>x\<in>B. D x)"
   186   by (simp add: SUP_def image_def)
   187 
   188 lemma Inf_mono:
   189   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   190   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   191 proof (rule Inf_greatest)
   192   fix b assume "b \<in> B"
   193   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   194   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   195   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
   196 qed
   197 
   198 lemma INF_mono:
   199   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   200   unfolding INF_def by (rule Inf_mono) fast
   201 
   202 lemma Sup_mono:
   203   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   204   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   205 proof (rule Sup_least)
   206   fix a assume "a \<in> A"
   207   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   208   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   209   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   210 qed
   211 
   212 lemma SUP_mono:
   213   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   214   unfolding SUP_def by (rule Sup_mono) fast
   215 
   216 lemma INF_superset_mono:
   217   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Sqinter>x\<in>A. f x) \<sqsubseteq> (\<Sqinter>x\<in>B. g x)"
   218   -- {* The last inclusion is POSITIVE! *}
   219   by (blast intro: INF_mono dest: subsetD)
   220 
   221 lemma SUP_subset_mono:
   222   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Squnion>x\<in>A. f x) \<sqsubseteq> (\<Squnion>x\<in>B. g x)"
   223   by (blast intro: SUP_mono dest: subsetD)
   224 
   225 lemma Inf_less_eq:
   226   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   227     and "A \<noteq> {}"
   228   shows "\<Sqinter>A \<sqsubseteq> u"
   229 proof -
   230   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   231   moreover with assms have "v \<sqsubseteq> u" by blast
   232   ultimately show ?thesis by (rule Inf_lower2)
   233 qed
   234 
   235 lemma less_eq_Sup:
   236   assumes "\<And>v. v \<in> A \<Longrightarrow> u \<sqsubseteq> v"
   237     and "A \<noteq> {}"
   238   shows "u \<sqsubseteq> \<Squnion>A"
   239 proof -
   240   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   241   moreover with assms have "u \<sqsubseteq> v" by blast
   242   ultimately show ?thesis by (rule Sup_upper2)
   243 qed
   244 
   245 lemma less_eq_Inf_inter: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   246   by (auto intro: Inf_greatest Inf_lower)
   247 
   248 lemma Sup_inter_less_eq: "\<Squnion>(A \<inter> B) \<sqsubseteq> \<Squnion>A \<sqinter> \<Squnion>B "
   249   by (auto intro: Sup_least Sup_upper)
   250 
   251 lemma Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   252   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   253 
   254 lemma INF_union:
   255   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   256   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 INF_greatest INF_lower)
   257 
   258 lemma Sup_union_distrib: "\<Squnion>(A \<union> B) = \<Squnion>A \<squnion> \<Squnion>B"
   259   by (rule antisym) (auto intro: Sup_least Sup_upper le_supI1 le_supI2)
   260 
   261 lemma SUP_union:
   262   "(\<Squnion>i \<in> A \<union> B. M i) = (\<Squnion>i \<in> A. M i) \<squnion> (\<Squnion>i\<in>B. M i)"
   263   by (auto intro!: antisym SUP_mono intro: le_supI1 le_supI2 SUP_least SUP_upper)
   264 
   265 lemma INF_inf_distrib: "(\<Sqinter>a\<in>A. f a) \<sqinter> (\<Sqinter>a\<in>A. g a) = (\<Sqinter>a\<in>A. f a \<sqinter> g a)"
   266   by (rule antisym) (rule INF_greatest, auto intro: le_infI1 le_infI2 INF_lower INF_mono)
   267 
   268 lemma SUP_sup_distrib: "(\<Squnion>a\<in>A. f a) \<squnion> (\<Squnion>a\<in>A. g a) = (\<Squnion>a\<in>A. f a \<squnion> g a)" (is "?L = ?R")
   269 proof (rule antisym)
   270   show "?L \<le> ?R" by (auto intro: le_supI1 le_supI2 SUP_upper SUP_mono)
   271 next
   272   show "?R \<le> ?L" by (rule SUP_least) (auto intro: le_supI1 le_supI2 SUP_upper)
   273 qed
   274 
   275 lemma Inf_top_conv [simp, no_atp]:
   276   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   277   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   278 proof -
   279   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   280   proof
   281     assume "\<forall>x\<in>A. x = \<top>"
   282     then have "A = {} \<or> A = {\<top>}" by auto
   283     then show "\<Sqinter>A = \<top>" by auto
   284   next
   285     assume "\<Sqinter>A = \<top>"
   286     show "\<forall>x\<in>A. x = \<top>"
   287     proof (rule ccontr)
   288       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   289       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   290       then obtain B where "A = insert x B" by blast
   291       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by simp
   292     qed
   293   qed
   294   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   295 qed
   296 
   297 lemma INF_top_conv [simp]:
   298  "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   299  "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   300   by (auto simp add: INF_def)
   301 
   302 lemma Sup_bot_conv [simp, no_atp]:
   303   "\<Squnion>A = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?P)
   304   "\<bottom> = \<Squnion>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?Q)
   305   using dual_complete_lattice
   306   by (rule complete_lattice.Inf_top_conv)+
   307 
   308 lemma SUP_bot_conv [simp]:
   309  "(\<Squnion>x\<in>A. B x) = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   310  "\<bottom> = (\<Squnion>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   311   by (auto simp add: SUP_def)
   312 
   313 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   314   by (auto intro: antisym INF_lower INF_greatest)
   315 
   316 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   317   by (auto intro: antisym SUP_upper SUP_least)
   318 
   319 lemma INF_top [simp]: "(\<Sqinter>x\<in>A. \<top>) = \<top>"
   320   by (cases "A = {}") simp_all
   321 
   322 lemma SUP_bot [simp]: "(\<Squnion>x\<in>A. \<bottom>) = \<bottom>"
   323   by (cases "A = {}") simp_all
   324 
   325 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   326   by (iprover intro: INF_lower INF_greatest order_trans antisym)
   327 
   328 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   329   by (iprover intro: SUP_upper SUP_least order_trans antisym)
   330 
   331 lemma INF_absorb:
   332   assumes "k \<in> I"
   333   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   334 proof -
   335   from assms obtain J where "I = insert k J" by blast
   336   then show ?thesis by (simp add: INF_insert)
   337 qed
   338 
   339 lemma SUP_absorb:
   340   assumes "k \<in> I"
   341   shows "A k \<squnion> (\<Squnion>i\<in>I. A i) = (\<Squnion>i\<in>I. A i)"
   342 proof -
   343   from assms obtain J where "I = insert k J" by blast
   344   then show ?thesis by (simp add: SUP_insert)
   345 qed
   346 
   347 lemma INF_constant:
   348   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   349   by simp
   350 
   351 lemma SUP_constant:
   352   "(\<Squnion>y\<in>A. c) = (if A = {} then \<bottom> else c)"
   353   by simp
   354 
   355 lemma less_INF_D:
   356   assumes "y < (\<Sqinter>i\<in>A. f i)" "i \<in> A" shows "y < f i"
   357 proof -
   358   note `y < (\<Sqinter>i\<in>A. f i)`
   359   also have "(\<Sqinter>i\<in>A. f i) \<le> f i" using `i \<in> A`
   360     by (rule INF_lower)
   361   finally show "y < f i" .
   362 qed
   363 
   364 lemma SUP_lessD:
   365   assumes "(\<Squnion>i\<in>A. f i) < y" "i \<in> A" shows "f i < y"
   366 proof -
   367   have "f i \<le> (\<Squnion>i\<in>A. f i)" using `i \<in> A`
   368     by (rule SUP_upper)
   369   also note `(\<Squnion>i\<in>A. f i) < y`
   370   finally show "f i < y" .
   371 qed
   372 
   373 lemma INF_UNIV_bool_expand:
   374   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   375   by (simp add: UNIV_bool INF_insert inf_commute)
   376 
   377 lemma SUP_UNIV_bool_expand:
   378   "(\<Squnion>b. A b) = A True \<squnion> A False"
   379   by (simp add: UNIV_bool SUP_insert sup_commute)
   380 
   381 end
   382 
   383 class complete_distrib_lattice = complete_lattice +
   384   assumes sup_Inf: "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   385   assumes inf_Sup: "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   386 begin
   387 
   388 lemma sup_INF:
   389   "a \<squnion> (\<Sqinter>b\<in>B. f b) = (\<Sqinter>b\<in>B. a \<squnion> f b)"
   390   by (simp add: INF_def sup_Inf image_image)
   391 
   392 lemma inf_SUP:
   393   "a \<sqinter> (\<Squnion>b\<in>B. f b) = (\<Squnion>b\<in>B. a \<sqinter> f b)"
   394   by (simp add: SUP_def inf_Sup image_image)
   395 
   396 lemma dual_complete_distrib_lattice:
   397   "class.complete_distrib_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   398   apply (rule class.complete_distrib_lattice.intro)
   399   apply (fact dual_complete_lattice)
   400   apply (rule class.complete_distrib_lattice_axioms.intro)
   401   apply (simp_all only: INF_foundation_dual SUP_foundation_dual inf_Sup sup_Inf)
   402   done
   403 
   404 subclass distrib_lattice proof
   405   fix a b c
   406   from sup_Inf have "a \<squnion> \<Sqinter>{b, c} = (\<Sqinter>d\<in>{b, c}. a \<squnion> d)" .
   407   then show "a \<squnion> b \<sqinter> c = (a \<squnion> b) \<sqinter> (a \<squnion> c)" by (simp add: INF_def)
   408 qed
   409 
   410 lemma Inf_sup:
   411   "\<Sqinter>B \<squnion> a = (\<Sqinter>b\<in>B. b \<squnion> a)"
   412   by (simp add: sup_Inf sup_commute)
   413 
   414 lemma Sup_inf:
   415   "\<Squnion>B \<sqinter> a = (\<Squnion>b\<in>B. b \<sqinter> a)"
   416   by (simp add: inf_Sup inf_commute)
   417 
   418 lemma INF_sup: 
   419   "(\<Sqinter>b\<in>B. f b) \<squnion> a = (\<Sqinter>b\<in>B. f b \<squnion> a)"
   420   by (simp add: sup_INF sup_commute)
   421 
   422 lemma SUP_inf:
   423   "(\<Squnion>b\<in>B. f b) \<sqinter> a = (\<Squnion>b\<in>B. f b \<sqinter> a)"
   424   by (simp add: inf_SUP inf_commute)
   425 
   426 lemma Inf_sup_eq_top_iff:
   427   "(\<Sqinter>B \<squnion> a = \<top>) \<longleftrightarrow> (\<forall>b\<in>B. b \<squnion> a = \<top>)"
   428   by (simp only: Inf_sup INF_top_conv)
   429 
   430 lemma Sup_inf_eq_bot_iff:
   431   "(\<Squnion>B \<sqinter> a = \<bottom>) \<longleftrightarrow> (\<forall>b\<in>B. b \<sqinter> a = \<bottom>)"
   432   by (simp only: Sup_inf SUP_bot_conv)
   433 
   434 lemma INF_sup_distrib2:
   435   "(\<Sqinter>a\<in>A. f a) \<squnion> (\<Sqinter>b\<in>B. g b) = (\<Sqinter>a\<in>A. \<Sqinter>b\<in>B. f a \<squnion> g b)"
   436   by (subst INF_commute) (simp add: sup_INF INF_sup)
   437 
   438 lemma SUP_inf_distrib2:
   439   "(\<Squnion>a\<in>A. f a) \<sqinter> (\<Squnion>b\<in>B. g b) = (\<Squnion>a\<in>A. \<Squnion>b\<in>B. f a \<sqinter> g b)"
   440   by (subst SUP_commute) (simp add: inf_SUP SUP_inf)
   441 
   442 end
   443 
   444 class complete_boolean_algebra = boolean_algebra + complete_distrib_lattice
   445 begin
   446 
   447 lemma dual_complete_boolean_algebra:
   448   "class.complete_boolean_algebra Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom> (\<lambda>x y. x \<squnion> - y) uminus"
   449   by (rule class.complete_boolean_algebra.intro, rule dual_complete_distrib_lattice, rule dual_boolean_algebra)
   450 
   451 lemma uminus_Inf:
   452   "- (\<Sqinter>A) = \<Squnion>(uminus ` A)"
   453 proof (rule antisym)
   454   show "- \<Sqinter>A \<le> \<Squnion>(uminus ` A)"
   455     by (rule compl_le_swap2, rule Inf_greatest, rule compl_le_swap2, rule Sup_upper) simp
   456   show "\<Squnion>(uminus ` A) \<le> - \<Sqinter>A"
   457     by (rule Sup_least, rule compl_le_swap1, rule Inf_lower) auto
   458 qed
   459 
   460 lemma uminus_INF: "- (\<Sqinter>x\<in>A. B x) = (\<Squnion>x\<in>A. - B x)"
   461   by (simp add: INF_def SUP_def uminus_Inf image_image)
   462 
   463 lemma uminus_Sup:
   464   "- (\<Squnion>A) = \<Sqinter>(uminus ` A)"
   465 proof -
   466   have "\<Squnion>A = - \<Sqinter>(uminus ` A)" by (simp add: image_image uminus_Inf)
   467   then show ?thesis by simp
   468 qed
   469   
   470 lemma uminus_SUP: "- (\<Squnion>x\<in>A. B x) = (\<Sqinter>x\<in>A. - B x)"
   471   by (simp add: INF_def SUP_def uminus_Sup image_image)
   472 
   473 end
   474 
   475 class complete_linorder = linorder + complete_lattice
   476 begin
   477 
   478 lemma dual_complete_linorder:
   479   "class.complete_linorder Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   480   by (rule class.complete_linorder.intro, rule dual_complete_lattice, rule dual_linorder)
   481 
   482 lemma Inf_less_iff:
   483   "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   484   unfolding not_le [symmetric] le_Inf_iff by auto
   485 
   486 lemma INF_less_iff:
   487   "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   488   unfolding INF_def Inf_less_iff by auto
   489 
   490 lemma less_Sup_iff:
   491   "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   492   unfolding not_le [symmetric] Sup_le_iff by auto
   493 
   494 lemma less_SUP_iff:
   495   "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   496   unfolding SUP_def less_Sup_iff by auto
   497 
   498 lemma Sup_eq_top_iff [simp]:
   499   "\<Squnion>A = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < i)"
   500 proof
   501   assume *: "\<Squnion>A = \<top>"
   502   show "(\<forall>x<\<top>. \<exists>i\<in>A. x < i)" unfolding * [symmetric]
   503   proof (intro allI impI)
   504     fix x assume "x < \<Squnion>A" then show "\<exists>i\<in>A. x < i"
   505       unfolding less_Sup_iff by auto
   506   qed
   507 next
   508   assume *: "\<forall>x<\<top>. \<exists>i\<in>A. x < i"
   509   show "\<Squnion>A = \<top>"
   510   proof (rule ccontr)
   511     assume "\<Squnion>A \<noteq> \<top>"
   512     with top_greatest [of "\<Squnion>A"]
   513     have "\<Squnion>A < \<top>" unfolding le_less by auto
   514     then have "\<Squnion>A < \<Squnion>A"
   515       using * unfolding less_Sup_iff by auto
   516     then show False by auto
   517   qed
   518 qed
   519 
   520 lemma SUP_eq_top_iff [simp]:
   521   "(\<Squnion>i\<in>A. f i) = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < f i)"
   522   unfolding SUP_def by auto
   523 
   524 lemma Inf_eq_bot_iff [simp]:
   525   "\<Sqinter>A = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. i < x)"
   526   using dual_complete_linorder
   527   by (rule complete_linorder.Sup_eq_top_iff)
   528 
   529 lemma INF_eq_bot_iff [simp]:
   530   "(\<Sqinter>i\<in>A. f i) = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. f i < x)"
   531   unfolding INF_def by auto
   532 
   533 end
   534 
   535 
   536 subsection {* Complete lattice on @{typ bool} *}
   537 
   538 instantiation bool :: complete_lattice
   539 begin
   540 
   541 definition
   542   [simp, code]: "\<Sqinter>A \<longleftrightarrow> False \<notin> A"
   543 
   544 definition
   545   [simp, code]: "\<Squnion>A \<longleftrightarrow> True \<in> A"
   546 
   547 instance proof
   548 qed (auto intro: bool_induct)
   549 
   550 end
   551 
   552 lemma not_False_in_image_Ball [simp]:
   553   "False \<notin> P ` A \<longleftrightarrow> Ball A P"
   554   by auto
   555 
   556 lemma True_in_image_Bex [simp]:
   557   "True \<in> P ` A \<longleftrightarrow> Bex A P"
   558   by auto
   559 
   560 lemma INF_bool_eq [simp]:
   561   "INFI = Ball"
   562   by (simp add: fun_eq_iff INF_def)
   563 
   564 lemma SUP_bool_eq [simp]:
   565   "SUPR = Bex"
   566   by (simp add: fun_eq_iff SUP_def)
   567 
   568 instance bool :: complete_boolean_algebra proof
   569 qed (auto intro: bool_induct)
   570 
   571 
   572 subsection {* Complete lattice on @{typ "_ \<Rightarrow> _"} *}
   573 
   574 instantiation "fun" :: (type, complete_lattice) complete_lattice
   575 begin
   576 
   577 definition
   578   "\<Sqinter>A = (\<lambda>x. \<Sqinter>f\<in>A. f x)"
   579 
   580 lemma Inf_apply [simp, code]:
   581   "(\<Sqinter>A) x = (\<Sqinter>f\<in>A. f x)"
   582   by (simp add: Inf_fun_def)
   583 
   584 definition
   585   "\<Squnion>A = (\<lambda>x. \<Squnion>f\<in>A. f x)"
   586 
   587 lemma Sup_apply [simp, code]:
   588   "(\<Squnion>A) x = (\<Squnion>f\<in>A. f x)"
   589   by (simp add: Sup_fun_def)
   590 
   591 instance proof
   592 qed (auto simp add: le_fun_def intro: INF_lower INF_greatest SUP_upper SUP_least)
   593 
   594 end
   595 
   596 lemma INF_apply [simp]:
   597   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   598   by (auto intro: arg_cong [of _ _ Inf] simp add: INF_def)
   599 
   600 lemma SUP_apply [simp]:
   601   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   602   by (auto intro: arg_cong [of _ _ Sup] simp add: SUP_def)
   603 
   604 instance "fun" :: (type, complete_distrib_lattice) complete_distrib_lattice proof
   605 qed (auto simp add: INF_def SUP_def inf_Sup sup_Inf image_image)
   606 
   607 instance "fun" :: (type, complete_boolean_algebra) complete_boolean_algebra ..
   608 
   609 
   610 subsection {* Complete lattice on unary and binary predicates *}
   611 
   612 lemma INF1_iff: "(\<Sqinter>x\<in>A. B x) b = (\<forall>x\<in>A. B x b)"
   613   by simp
   614 
   615 lemma INF2_iff: "(\<Sqinter>x\<in>A. B x) b c = (\<forall>x\<in>A. B x b c)"
   616   by simp
   617 
   618 lemma INF1_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b"
   619   by auto
   620 
   621 lemma INF2_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b c) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b c"
   622   by auto
   623 
   624 lemma INF1_D: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> a \<in> A \<Longrightarrow> B a b"
   625   by auto
   626 
   627 lemma INF2_D: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> a \<in> A \<Longrightarrow> B a b c"
   628   by auto
   629 
   630 lemma INF1_E: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> (B a b \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   631   by auto
   632 
   633 lemma INF2_E: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> (B a b c \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   634   by auto
   635 
   636 lemma SUP1_iff: "(\<Squnion>x\<in>A. B x) b = (\<exists>x\<in>A. B x b)"
   637   by simp
   638 
   639 lemma SUP2_iff: "(\<Squnion>x\<in>A. B x) b c = (\<exists>x\<in>A. B x b c)"
   640   by simp
   641 
   642 lemma SUP1_I: "a \<in> A \<Longrightarrow> B a b \<Longrightarrow> (\<Squnion>x\<in>A. B x) b"
   643   by auto
   644 
   645 lemma SUP2_I: "a \<in> A \<Longrightarrow> B a b c \<Longrightarrow> (\<Squnion>x\<in>A. B x) b c"
   646   by auto
   647 
   648 lemma SUP1_E: "(\<Squnion>x\<in>A. B x) b \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b \<Longrightarrow> R) \<Longrightarrow> R"
   649   by auto
   650 
   651 lemma SUP2_E: "(\<Squnion>x\<in>A. B x) b c \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b c \<Longrightarrow> R) \<Longrightarrow> R"
   652   by auto
   653 
   654 
   655 subsection {* Complete lattice on @{typ "_ set"} *}
   656 
   657 instantiation "set" :: (type) complete_lattice
   658 begin
   659 
   660 definition
   661   "\<Sqinter>A = {x. \<Sqinter>((\<lambda>B. x \<in> B) ` A)}"
   662 
   663 definition
   664   "\<Squnion>A = {x. \<Squnion>((\<lambda>B. x \<in> B) ` A)}"
   665 
   666 instance proof
   667 qed (auto simp add: less_eq_set_def Inf_set_def Sup_set_def Inf_bool_def Sup_bool_def le_fun_def)
   668 
   669 end
   670 
   671 instance "set" :: (type) complete_boolean_algebra
   672 proof
   673 qed (auto simp add: INF_def SUP_def Inf_set_def Sup_set_def image_def)
   674   
   675 
   676 subsubsection {* Inter *}
   677 
   678 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   679   "Inter S \<equiv> \<Sqinter>S"
   680   
   681 notation (xsymbols)
   682   Inter  ("\<Inter>_" [90] 90)
   683 
   684 lemma Inter_eq:
   685   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   686 proof (rule set_eqI)
   687   fix x
   688   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   689     by auto
   690   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   691     by (simp add: Inf_set_def image_def)
   692 qed
   693 
   694 lemma Inter_iff [simp,no_atp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   695   by (unfold Inter_eq) blast
   696 
   697 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   698   by (simp add: Inter_eq)
   699 
   700 text {*
   701   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   702   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   703   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   704 *}
   705 
   706 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   707   by auto
   708 
   709 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   710   -- {* ``Classical'' elimination rule -- does not require proving
   711     @{prop "X \<in> C"}. *}
   712   by (unfold Inter_eq) blast
   713 
   714 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   715   by (fact Inf_lower)
   716 
   717 lemma Inter_subset:
   718   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   719   by (fact Inf_less_eq)
   720 
   721 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   722   by (fact Inf_greatest)
   723 
   724 lemma Inter_empty: "\<Inter>{} = UNIV"
   725   by (fact Inf_empty) (* already simp *)
   726 
   727 lemma Inter_UNIV: "\<Inter>UNIV = {}"
   728   by (fact Inf_UNIV) (* already simp *)
   729 
   730 lemma Inter_insert: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   731   by (fact Inf_insert) (* already simp *)
   732 
   733 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   734   by (fact less_eq_Inf_inter)
   735 
   736 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   737   by (fact Inf_union_distrib)
   738 
   739 lemma Inter_UNIV_conv [simp, no_atp]:
   740   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   741   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   742   by (fact Inf_top_conv)+
   743 
   744 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   745   by (fact Inf_superset_mono)
   746 
   747 
   748 subsubsection {* Intersections of families *}
   749 
   750 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   751   "INTER \<equiv> INFI"
   752 
   753 text {*
   754   Note: must use name @{const INTER} here instead of @{text INT}
   755   to allow the following syntax coexist with the plain constant name.
   756 *}
   757 
   758 syntax
   759   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   760   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   761 
   762 syntax (xsymbols)
   763   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   764   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   765 
   766 syntax (latex output)
   767   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   768   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   769 
   770 translations
   771   "INT x y. B"  == "INT x. INT y. B"
   772   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   773   "INT x. B"    == "INT x:CONST UNIV. B"
   774   "INT x:A. B"  == "CONST INTER A (%x. B)"
   775 
   776 print_translation {*
   777   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   778 *} -- {* to avoid eta-contraction of body *}
   779 
   780 lemma INTER_eq:
   781   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   782   by (auto simp add: INF_def)
   783 
   784 lemma Inter_image_eq [simp]:
   785   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   786   by (rule sym) (fact INF_def)
   787 
   788 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   789   by (auto simp add: INF_def image_def)
   790 
   791 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   792   by (auto simp add: INF_def image_def)
   793 
   794 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   795   by auto
   796 
   797 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   798   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   799   by (auto simp add: INF_def image_def)
   800 
   801 lemma INT_cong [cong]:
   802   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   803   by (fact INF_cong)
   804 
   805 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   806   by blast
   807 
   808 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   809   by blast
   810 
   811 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   812   by (fact INF_lower)
   813 
   814 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   815   by (fact INF_greatest)
   816 
   817 lemma INT_empty: "(\<Inter>x\<in>{}. B x) = UNIV"
   818   by (fact INF_empty)
   819 
   820 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   821   by (fact INF_absorb)
   822 
   823 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
   824   by (fact le_INF_iff)
   825 
   826 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   827   by (fact INF_insert)
   828 
   829 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   830   by (fact INF_union)
   831 
   832 lemma INT_insert_distrib:
   833   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   834   by blast
   835 
   836 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   837   by (fact INF_constant)
   838 
   839 lemma INTER_UNIV_conv:
   840  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   841  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   842   by (fact INF_top_conv)+ (* already simp *)
   843 
   844 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
   845   by (fact INF_UNIV_bool_expand)
   846 
   847 lemma INT_anti_mono:
   848   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>B. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   849   -- {* The last inclusion is POSITIVE! *}
   850   by (fact INF_superset_mono)
   851 
   852 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   853   by blast
   854 
   855 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   856   by blast
   857 
   858 
   859 subsubsection {* Union *}
   860 
   861 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   862   "Union S \<equiv> \<Squnion>S"
   863 
   864 notation (xsymbols)
   865   Union  ("\<Union>_" [90] 90)
   866 
   867 lemma Union_eq:
   868   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   869 proof (rule set_eqI)
   870   fix x
   871   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   872     by auto
   873   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   874     by (simp add: Sup_set_def image_def)
   875 qed
   876 
   877 lemma Union_iff [simp, no_atp]:
   878   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   879   by (unfold Union_eq) blast
   880 
   881 lemma UnionI [intro]:
   882   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   883   -- {* The order of the premises presupposes that @{term C} is rigid;
   884     @{term A} may be flexible. *}
   885   by auto
   886 
   887 lemma UnionE [elim!]:
   888   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
   889   by auto
   890 
   891 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
   892   by (fact Sup_upper)
   893 
   894 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
   895   by (fact Sup_least)
   896 
   897 lemma Union_empty: "\<Union>{} = {}"
   898   by (fact Sup_empty) (* already simp *)
   899 
   900 lemma Union_UNIV: "\<Union>UNIV = UNIV"
   901   by (fact Sup_UNIV) (* already simp *)
   902 
   903 lemma Union_insert: "\<Union>insert a B = a \<union> \<Union>B"
   904   by (fact Sup_insert) (* already simp *)
   905 
   906 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
   907   by (fact Sup_union_distrib)
   908 
   909 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   910   by (fact Sup_inter_less_eq)
   911 
   912 lemma Union_empty_conv [no_atp]: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   913   by (fact Sup_bot_conv) (* already simp *)
   914 
   915 lemma empty_Union_conv [no_atp]: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   916   by (fact Sup_bot_conv) (* already simp *)
   917 
   918 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   919   by blast
   920 
   921 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   922   by blast
   923 
   924 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
   925   by (fact Sup_subset_mono)
   926 
   927 
   928 subsubsection {* Unions of families *}
   929 
   930 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   931   "UNION \<equiv> SUPR"
   932 
   933 text {*
   934   Note: must use name @{const UNION} here instead of @{text UN}
   935   to allow the following syntax coexist with the plain constant name.
   936 *}
   937 
   938 syntax
   939   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   940   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   941 
   942 syntax (xsymbols)
   943   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   944   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   945 
   946 syntax (latex output)
   947   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   948   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   949 
   950 translations
   951   "UN x y. B"   == "UN x. UN y. B"
   952   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   953   "UN x. B"     == "UN x:CONST UNIV. B"
   954   "UN x:A. B"   == "CONST UNION A (%x. B)"
   955 
   956 text {*
   957   Note the difference between ordinary xsymbol syntax of indexed
   958   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   959   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   960   former does not make the index expression a subscript of the
   961   union/intersection symbol because this leads to problems with nested
   962   subscripts in Proof General.
   963 *}
   964 
   965 print_translation {*
   966   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   967 *} -- {* to avoid eta-contraction of body *}
   968 
   969 lemma UNION_eq [no_atp]:
   970   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   971   by (auto simp add: SUP_def)
   972 
   973 lemma bind_UNION [code]:
   974   "Set.bind A f = UNION A f"
   975   by (simp add: bind_def UNION_eq)
   976 
   977 lemma member_bind [simp]:
   978   "x \<in> Set.bind P f \<longleftrightarrow> x \<in> UNION P f "
   979   by (simp add: bind_UNION)
   980 
   981 lemma Union_image_eq [simp]:
   982   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
   983   by (rule sym) (fact SUP_def)
   984 
   985 lemma UN_iff [simp]: "b \<in> (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<exists>x\<in>A. b \<in> B x)"
   986   by (auto simp add: SUP_def image_def)
   987 
   988 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
   989   -- {* The order of the premises presupposes that @{term A} is rigid;
   990     @{term b} may be flexible. *}
   991   by auto
   992 
   993 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
   994   by (auto simp add: SUP_def image_def)
   995 
   996 lemma UN_cong [cong]:
   997   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   998   by (fact SUP_cong)
   999 
  1000 lemma strong_UN_cong:
  1001   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1002   by (unfold simp_implies_def) (fact UN_cong)
  1003 
  1004 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
  1005   by blast
  1006 
  1007 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1008   by (fact SUP_upper)
  1009 
  1010 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
  1011   by (fact SUP_least)
  1012 
  1013 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1014   by blast
  1015 
  1016 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1017   by blast
  1018 
  1019 lemma UN_empty [no_atp]: "(\<Union>x\<in>{}. B x) = {}"
  1020   by (fact SUP_empty)
  1021 
  1022 lemma UN_empty2: "(\<Union>x\<in>A. {}) = {}"
  1023   by (fact SUP_bot) (* already simp *)
  1024 
  1025 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1026   by (fact SUP_absorb)
  1027 
  1028 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1029   by (fact SUP_insert)
  1030 
  1031 lemma UN_Un [simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1032   by (fact SUP_union)
  1033 
  1034 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1035   by blast
  1036 
  1037 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1038   by (fact SUP_le_iff)
  1039 
  1040 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1041   by (fact SUP_constant)
  1042 
  1043 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1044   by blast
  1045 
  1046 lemma UNION_empty_conv:
  1047   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1048   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1049   by (fact SUP_bot_conv)+ (* already simp *)
  1050 
  1051 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1052   by blast
  1053 
  1054 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) \<longleftrightarrow> (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1055   by blast
  1056 
  1057 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) \<longleftrightarrow> (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1058   by blast
  1059 
  1060 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1061   by (auto simp add: split_if_mem2)
  1062 
  1063 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
  1064   by (fact SUP_UNIV_bool_expand)
  1065 
  1066 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1067   by blast
  1068 
  1069 lemma UN_mono:
  1070   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
  1071     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1072   by (fact SUP_subset_mono)
  1073 
  1074 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
  1075   by blast
  1076 
  1077 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
  1078   by blast
  1079 
  1080 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
  1081   -- {* NOT suitable for rewriting *}
  1082   by blast
  1083 
  1084 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
  1085   by blast
  1086 
  1087 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1088   by blast
  1089 
  1090 
  1091 subsubsection {* Distributive laws *}
  1092 
  1093 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1094   by (fact inf_Sup)
  1095 
  1096 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1097   by (fact sup_Inf)
  1098 
  1099 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1100   by (fact Sup_inf)
  1101 
  1102 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1103   by (rule sym) (rule INF_inf_distrib)
  1104 
  1105 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1106   by (rule sym) (rule SUP_sup_distrib)
  1107 
  1108 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)"
  1109   by (simp only: INT_Int_distrib INF_def)
  1110 
  1111 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)"
  1112   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1113   -- {* Union of a family of unions *}
  1114   by (simp only: UN_Un_distrib SUP_def)
  1115 
  1116 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1117   by (fact sup_INF)
  1118 
  1119 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1120   -- {* Halmos, Naive Set Theory, page 35. *}
  1121   by (fact inf_SUP)
  1122 
  1123 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1124   by (fact SUP_inf_distrib2)
  1125 
  1126 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1127   by (fact INF_sup_distrib2)
  1128 
  1129 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
  1130   by (fact Sup_inf_eq_bot_iff)
  1131 
  1132 
  1133 subsubsection {* Complement *}
  1134 
  1135 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1136   by (fact uminus_INF)
  1137 
  1138 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1139   by (fact uminus_SUP)
  1140 
  1141 
  1142 subsubsection {* Miniscoping and maxiscoping *}
  1143 
  1144 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1145            and Intersections. *}
  1146 
  1147 lemma UN_simps [simp]:
  1148   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
  1149   "\<And>A B C. (\<Union>x\<in>C. A x \<union> B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
  1150   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
  1151   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter> B)"
  1152   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
  1153   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
  1154   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
  1155   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
  1156   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
  1157   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
  1158   by auto
  1159 
  1160 lemma INT_simps [simp]:
  1161   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter> B)"
  1162   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
  1163   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
  1164   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
  1165   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
  1166   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
  1167   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
  1168   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
  1169   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
  1170   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
  1171   by auto
  1172 
  1173 lemma UN_ball_bex_simps [simp, no_atp]:
  1174   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
  1175   "\<And>A B P. (\<forall>x\<in>UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
  1176   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
  1177   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
  1178   by auto
  1179 
  1180 
  1181 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1182 
  1183 lemma UN_extend_simps:
  1184   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
  1185   "\<And>A B C. (\<Union>x\<in>C. A x) \<union> B = (if C={} then B else (\<Union>x\<in>C. A x \<union> B))"
  1186   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
  1187   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
  1188   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
  1189   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
  1190   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
  1191   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
  1192   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
  1193   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
  1194   by auto
  1195 
  1196 lemma INT_extend_simps:
  1197   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
  1198   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
  1199   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
  1200   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
  1201   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
  1202   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
  1203   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
  1204   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
  1205   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
  1206   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
  1207   by auto
  1208 
  1209 text {* Finally *}
  1210 
  1211 no_notation
  1212   less_eq (infix "\<sqsubseteq>" 50) and
  1213   less (infix "\<sqsubset>" 50)
  1214 
  1215 lemmas mem_simps =
  1216   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1217   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1218   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  1219 
  1220 end
  1221