src/Pure/variable.ML
author wenzelm
Tue Dec 12 20:49:26 2006 +0100 (2006-12-12)
changeset 21799 a85e3bbc76fb
parent 21683 b90fa6c8e062
child 22568 ed7aa5a350ef
permissions -rw-r--r--
tuned expand_binds;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Proof.context -> string -> bool
    18   val is_fixed: Proof.context -> string -> bool
    19   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    20   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    21   val default_type: Proof.context -> string -> typ option
    22   val def_type: Proof.context -> bool -> indexname -> typ option
    23   val def_sort: Proof.context -> indexname -> sort option
    24   val declare_constraints: term -> Proof.context -> Proof.context
    25   val declare_internal: term -> Proof.context -> Proof.context
    26   val declare_term: term -> Proof.context -> Proof.context
    27   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    28   val declare_thm: thm -> Proof.context -> Proof.context
    29   val thm_context: thm -> Proof.context
    30   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    31   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    32   val expand_binds: Proof.context -> term -> term
    33   val add_fixes: string list -> Proof.context -> string list * Proof.context
    34   val add_fixes_direct: string list -> Proof.context -> Proof.context
    35   val auto_fixes: term -> Proof.context -> Proof.context
    36   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    37   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    38   val export_inst: Proof.context -> Proof.context -> string list * string list
    39   val exportT_inst: Proof.context -> Proof.context -> string list
    40   val export_terms: Proof.context -> Proof.context -> term list -> term list
    41   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    42   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    43   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    44   val export: Proof.context -> Proof.context -> thm list -> thm list
    45   val export_morphism: Proof.context -> Proof.context -> morphism
    46   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    47   val import_inst: bool -> term list -> Proof.context ->
    48     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    49   val importT_terms: term list -> Proof.context -> term list * Proof.context
    50   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    51   val importT: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    52   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    53   val import: bool -> thm list -> Proof.context ->
    54     ((ctyp list * cterm list) * thm list) * Proof.context
    55   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    56   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    57   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    58   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    59   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    60   val polymorphic: Proof.context -> term list -> term list
    61 end;
    62 
    63 structure Variable: VARIABLE =
    64 struct
    65 
    66 (** local context data **)
    67 
    68 datatype data = Data of
    69  {is_body: bool,                        (*inner body mode*)
    70   names: Name.context,                  (*type/term variable names*)
    71   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    72   binds: (typ * term) Vartab.table,     (*term bindings*)
    73   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    74   constraints:
    75     typ Vartab.table *                  (*type constraints*)
    76     sort Vartab.table};                 (*default sorts*)
    77 
    78 fun make_data (is_body, names, fixes, binds, type_occs, constraints) =
    79   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    80     type_occs = type_occs, constraints = constraints};
    81 
    82 structure Data = ProofDataFun
    83 (
    84   val name = "Pure/variable";
    85   type T = data;
    86   fun init thy =
    87     make_data (false, Name.context, [], Vartab.empty, Symtab.empty, (Vartab.empty, Vartab.empty));
    88   fun print _ _ = ();
    89 );
    90 
    91 val _ = Context.add_setup Data.init;
    92 
    93 fun map_data f =
    94   Data.map (fn Data {is_body, names, fixes, binds, type_occs, constraints} =>
    95     make_data (f (is_body, names, fixes, binds, type_occs, constraints)));
    96 
    97 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    98   (is_body, f names, fixes, binds, type_occs, constraints));
    99 
   100 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   101   (is_body, names, f fixes, binds, type_occs, constraints));
   102 
   103 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   104   (is_body, names, fixes, f binds, type_occs, constraints));
   105 
   106 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   107   (is_body, names, fixes, binds, f type_occs, constraints));
   108 
   109 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   110   (is_body, names, fixes, binds, type_occs, f constraints));
   111 
   112 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   113 
   114 val is_body = #is_body o rep_data;
   115 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, constraints) =>
   116   (b, names, fixes, binds, type_occs, constraints));
   117 fun restore_body ctxt = set_body (is_body ctxt);
   118 
   119 val names_of = #names o rep_data;
   120 val fixes_of = #fixes o rep_data;
   121 val binds_of = #binds o rep_data;
   122 val type_occs_of = #type_occs o rep_data;
   123 val constraints_of = #constraints o rep_data;
   124 
   125 val is_declared = Name.is_declared o names_of;
   126 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   127 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   128 
   129 fun add_fixed ctxt = Term.fold_aterms
   130   (fn Free (x, T) => if is_fixed ctxt x then insert (op =) (x, T) else I | _ => I);
   131 
   132 
   133 
   134 (** declarations **)
   135 
   136 (* default sorts and types *)
   137 
   138 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   139 
   140 fun def_type ctxt pattern xi =
   141   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   142     (case Vartab.lookup types xi of
   143       NONE =>
   144         if pattern then NONE
   145         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   146     | some => some)
   147   end;
   148 
   149 val def_sort = Vartab.lookup o #2 o constraints_of;
   150 
   151 
   152 (* names *)
   153 
   154 val declare_type_names = map_names o
   155   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I));
   156 
   157 fun declare_names t =
   158   declare_type_names t #>
   159   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t);
   160 
   161 
   162 (* type occurrences *)
   163 
   164 val declare_type_occs = map_type_occs o fold_term_types
   165   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   166     | _ => fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I));
   167 
   168 
   169 (* constraints *)
   170 
   171 fun redeclare_skolems ctxt = ctxt |> map_constraints (apfst (fn types =>
   172   let
   173     fun decl (x, x') =
   174       (case default_type ctxt x' of
   175         SOME T => Vartab.update ((x, ~1), T)
   176       | NONE => I);
   177   in fold_rev decl (fixes_of ctxt) types end));
   178 
   179 fun constrain_tvar (xi, S) =
   180   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   181 
   182 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   183   let
   184     val types' = fold_aterms
   185       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   186         | Var v => Vartab.update v
   187         | _ => I) t types;
   188     val sorts' = fold_types (fold_atyps
   189       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   190         | TVar v => constrain_tvar v
   191         | _ => I)) t sorts;
   192   in (types', sorts') end)
   193   #> declare_type_names t
   194   #> redeclare_skolems;
   195 
   196 
   197 (* common declarations *)
   198 
   199 fun declare_internal t =
   200   declare_names t #>
   201   declare_type_occs t;
   202 
   203 fun declare_term t =
   204   declare_internal t #>
   205   declare_constraints t;
   206 
   207 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   208 
   209 val declare_thm = Drule.fold_terms declare_internal;
   210 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   211 
   212 
   213 (* renaming term/type frees *)
   214 
   215 fun variant_frees ctxt ts frees =
   216   let
   217     val names = names_of (fold declare_names ts ctxt);
   218     val xs = fst (Name.variants (map #1 frees) names);
   219   in xs ~~ map snd frees end;
   220 
   221 
   222 
   223 (** term bindings **)
   224 
   225 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   226   | add_bind ((x, i), SOME t) =
   227       let
   228         val T = Term.fastype_of t;
   229         val t' =
   230           if null (Term.hidden_polymorphism t T) then t
   231           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   232       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   233 
   234 val add_binds = fold add_bind;
   235 
   236 fun expand_binds ctxt =
   237   let
   238     val binds = binds_of ctxt;
   239     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   240   in Envir.beta_norm o Envir.expand_term get end;
   241 
   242 
   243 
   244 (** fixes **)
   245 
   246 local
   247 
   248 fun no_dups [] = ()
   249   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   250 
   251 fun new_fixes names' xs xs' =
   252   map_names (K names') #>
   253   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   254   fold (declare_constraints o Syntax.free) xs' #>
   255   pair xs';
   256 
   257 in
   258 
   259 fun add_fixes xs ctxt =
   260   let
   261     val _ =
   262       (case filter (can Name.dest_skolem) xs of [] => ()
   263       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   264     val _ = no_dups (duplicates (op =) xs);
   265     val (ys, zs) = split_list (fixes_of ctxt);
   266     val names = names_of ctxt;
   267     val (xs', names') =
   268       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   269       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   270         (xs, fold Name.declare xs names));
   271   in ctxt |> new_fixes names' xs xs' end;
   272 
   273 fun variant_fixes raw_xs ctxt =
   274   let
   275     val names = names_of ctxt;
   276     val xs = map Name.clean raw_xs;
   277     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   278   in ctxt |> new_fixes names' xs xs' end;
   279 
   280 end;
   281 
   282 
   283 fun add_fixes_direct xs ctxt = ctxt
   284   |> set_body false
   285   |> (snd o add_fixes xs)
   286   |> restore_body ctxt;
   287 
   288 fun fix_frees t ctxt = ctxt
   289   |> add_fixes_direct
   290       (rev (fold_aterms (fn Free (x, _) =>
   291         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   292 
   293 fun auto_fixes t ctxt =
   294   (if is_body ctxt then ctxt else fix_frees t ctxt)
   295   |> declare_term t;
   296 
   297 fun invent_types Ss ctxt =
   298   let
   299     val tfrees = Name.invents (names_of ctxt) "'a" (length Ss) ~~ Ss;
   300     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   301   in (tfrees, ctxt') end;
   302 
   303 
   304 
   305 (** export -- generalize type/term variables **)
   306 
   307 fun export_inst inner outer =
   308   let
   309     val declared_outer = is_declared outer;
   310     val fixes_inner = fixes_of inner;
   311     val fixes_outer = fixes_of outer;
   312 
   313     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   314     val still_fixed = not o member (op =) gen_fixes;
   315     val gen_fixesT =
   316       Symtab.fold (fn (a, xs) =>
   317         if declared_outer a orelse exists still_fixed xs
   318         then I else cons a) (type_occs_of inner) [];
   319   in (gen_fixesT, gen_fixes) end;
   320 
   321 fun exportT_inst inner outer = #1 (export_inst inner outer);
   322 
   323 fun exportT_terms inner outer ts =
   324   map (TermSubst.generalize (exportT_inst (fold declare_type_occs ts inner) outer, [])
   325     (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1)) ts;
   326 
   327 fun export_terms inner outer ts =
   328   map (TermSubst.generalize (export_inst (fold declare_type_occs ts inner) outer)
   329     (fold Term.maxidx_term ts ~1 + 1)) ts;
   330 
   331 fun export_prf inner outer prf =
   332   let
   333     val insts = export_inst (declare_prf prf inner) outer;
   334     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   335     val gen_term = TermSubst.generalize_option insts idx;
   336     val gen_typ = TermSubst.generalizeT_option (#1 insts) idx;
   337   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   338 
   339 fun gen_export inst inner outer ths =
   340   let
   341     val inner' = fold (declare_type_occs o Thm.full_prop_of) ths inner;
   342   in map (Thm.generalize (inst inner' outer) (fold Thm.maxidx_thm ths ~1 + 1)) ths end;
   343 
   344 val exportT = gen_export (rpair [] oo exportT_inst);
   345 val export = gen_export export_inst;
   346 
   347 fun export_morphism inner outer =
   348   let
   349     val fact = export inner outer;
   350     val term = singleton (export_terms inner outer);
   351     val typ = Logic.type_map term;
   352   in Morphism.morphism {name = I, var = I, typ = typ, term = term, fact = fact} end;
   353 
   354 
   355 (** import -- fix schematic type/term variables **)
   356 
   357 fun importT_inst ts ctxt =
   358   let
   359     val tvars = rev (fold Term.add_tvars ts []);
   360     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   361   in (tvars ~~ map TFree tfrees, ctxt') end;
   362 
   363 fun import_inst is_open ts ctxt =
   364   let
   365     val ren = if is_open then I else Name.internal;
   366     val (instT, ctxt') = importT_inst ts ctxt;
   367     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   368     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   369     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   370   in ((instT, inst), ctxt'') end;
   371 
   372 fun importT_terms ts ctxt =
   373   let val (instT, ctxt') = importT_inst ts ctxt
   374   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   375 
   376 fun import_terms is_open ts ctxt =
   377   let val (inst, ctxt') = import_inst is_open ts ctxt
   378   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   379 
   380 fun importT ths ctxt =
   381   let
   382     val thy = ProofContext.theory_of ctxt;
   383     val certT = Thm.ctyp_of thy;
   384     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   385     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   386     val ths' = map (Thm.instantiate (instT', [])) ths;
   387   in ((map #2 instT', ths'), ctxt') end;
   388 
   389 fun import_prf is_open prf ctxt =
   390   let
   391     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   392     val (insts, ctxt') = import_inst is_open ts ctxt;
   393   in (Proofterm.instantiate insts prf, ctxt') end;
   394 
   395 fun import is_open ths ctxt =
   396   let
   397     val thy = ProofContext.theory_of ctxt;
   398     val cert = Thm.cterm_of thy;
   399     val certT = Thm.ctyp_of thy;
   400     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   401     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   402     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   403     val ths' = map (Thm.instantiate (instT', inst')) ths;
   404   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   405 
   406 
   407 (* import/export *)
   408 
   409 fun gen_trade imp exp f ctxt ths =
   410   let val ((_, ths'), ctxt') = imp ths ctxt
   411   in exp ctxt' ctxt (f ctxt' ths') end;
   412 
   413 val tradeT = gen_trade importT exportT;
   414 val trade = gen_trade (import true) export;
   415 
   416 
   417 (* focus on outermost parameters *)
   418 
   419 fun forall_elim_prop t prop =
   420   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   421   |> Thm.cprop_of |> Thm.dest_arg;
   422 
   423 fun focus goal ctxt =
   424   let
   425     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   426     val t = Thm.term_of goal;
   427     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   428     val (xs, Ts) = split_list ps;
   429     val (xs', ctxt') = variant_fixes xs ctxt;
   430     val ps' = ListPair.map (cert o Free) (xs', Ts);
   431     val goal' = fold forall_elim_prop ps' goal;
   432   in ((ps', goal'), ctxt') end;
   433 
   434 fun focus_subgoal i st =
   435   let
   436     val all_vars = Drule.fold_terms Term.add_vars st [];
   437     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   438   in
   439     add_binds no_binds #>
   440     fold (declare_constraints o Var) all_vars #>
   441     focus (Thm.cprem_of st i)
   442   end;
   443 
   444 
   445 
   446 (** implicit polymorphism **)
   447 
   448 (* warn_extra_tfrees *)
   449 
   450 fun warn_extra_tfrees ctxt1 ctxt2 =
   451   let
   452     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   453     fun occs_free a x =
   454       (case def_type ctxt1 false (x, ~1) of
   455         SOME T => if occs_typ a T then I else cons (a, x)
   456       | NONE => cons (a, x));
   457 
   458     val occs1 = type_occs_of ctxt1;
   459     val occs2 = type_occs_of ctxt2;
   460     val extras = Symtab.fold (fn (a, xs) =>
   461       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   462     val tfrees = map #1 extras |> sort_distinct string_ord;
   463     val frees = map #2 extras |> sort_distinct string_ord;
   464   in
   465     if null extras then ()
   466     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   467       space_implode " or " (map quote frees))
   468   end;
   469 
   470 
   471 (* polymorphic terms *)
   472 
   473 fun polymorphic ctxt ts =
   474   let
   475     val ctxt' = fold declare_term ts ctxt;
   476     val occs = type_occs_of ctxt;
   477     val occs' = type_occs_of ctxt';
   478     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   479     val idx = fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1;
   480   in map (TermSubst.generalize (types, []) idx) ts end;
   481 
   482 end;