src/Pure/theory.ML
author wenzelm
Tue Jul 19 17:21:55 2005 +0200 (2005-07-19)
changeset 16883 a89fafe1cbd8
parent 16803 014090d1e64b
child 16944 83ea7e3c6ec9
permissions -rw-r--r--
tuned defs interface;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   type theory
    11   type theory_ref
    12   val sign_of: theory -> theory    (*obsolete*)
    13   val rep_theory: theory ->
    14    {axioms: term NameSpace.table,
    15     defs: Defs.graph,
    16     oracles: ((theory * Object.T -> term) * stamp) NameSpace.table}
    17   val parents_of: theory -> theory list
    18   val ancestors_of: theory -> theory list
    19   val eq_thy: theory * theory -> bool
    20   val subthy: theory * theory -> bool
    21   val cert_axm: theory -> string * term -> string * term
    22   val read_def_axm: theory * (indexname -> typ option) * (indexname -> sort option) ->
    23     string list -> string * string -> string * term
    24   val read_axm: theory -> string * string -> string * term
    25   val inferT_axm: theory -> string * term -> string * term
    26 end
    27 
    28 signature THEORY =
    29 sig
    30   include BASIC_THEORY
    31   include SIGN_THEORY
    32   val begin_theory: string -> theory list -> theory
    33   val end_theory: theory -> theory
    34   val checkpoint: theory -> theory
    35   val copy: theory -> theory
    36   val init_data: theory -> theory
    37   val axiom_space: theory -> NameSpace.T
    38   val oracle_space: theory -> NameSpace.T
    39   val axioms_of: theory -> (string * term) list
    40   val all_axioms_of: theory -> (string * term) list
    41   val defs_of : theory -> Defs.graph
    42   val self_ref: theory -> theory_ref
    43   val deref: theory_ref -> theory
    44   val merge: theory * theory -> theory                     (*exception TERM*)
    45   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    46   val requires: theory -> string -> string -> unit
    47   val assert_super: theory -> theory -> theory
    48   val add_axioms: (bstring * string) list -> theory -> theory
    49   val add_axioms_i: (bstring * term) list -> theory -> theory
    50   val add_defs: bool -> (bstring * string) list -> theory -> theory
    51   val add_defs_i: bool -> (bstring * term) list -> theory -> theory
    52   val add_finals: bool -> string list -> theory -> theory
    53   val add_finals_i: bool -> term list -> theory -> theory
    54   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    55 end
    56 
    57 structure Theory: THEORY =
    58 struct
    59 
    60 (** type theory **)
    61 
    62 (* context operations *)
    63 
    64 type theory = Context.theory;
    65 type theory_ref = Context.theory_ref;
    66 
    67 val eq_thy = Context.eq_thy;
    68 val subthy = Context.subthy;
    69 
    70 val parents_of = Context.parents_of;
    71 val ancestors_of = Context.ancestors_of;
    72 
    73 val self_ref = Context.self_ref;
    74 val deref = Context.deref;
    75 val merge = Context.merge;
    76 val merge_refs = Context.merge_refs;
    77 
    78 val begin_theory = Sign.local_path oo Context.begin_thy Sign.pp;
    79 val end_theory = Context.finish_thy;
    80 val checkpoint = Context.checkpoint_thy;
    81 val copy = Context.copy_thy;
    82 
    83 
    84 (* signature operations *)
    85 
    86 val sign_of = I;
    87 
    88 structure SignTheory: SIGN_THEORY = Sign;
    89 open SignTheory;
    90 
    91 
    92 
    93 (** datatype thy **)
    94 
    95 datatype thy = Thy of
    96  {axioms: term NameSpace.table,
    97   defs: Defs.graph,
    98   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table};
    99 
   100 fun make_thy (axioms, defs, oracles) =
   101   Thy {axioms = axioms, defs = defs, oracles = oracles};
   102 
   103 fun err_dup_axms dups = error ("Duplicate axiom(s): " ^ commas_quote dups);
   104 fun err_dup_oras dups = error ("Duplicate oracle(s): " ^ commas_quote dups);
   105 
   106 structure ThyData = TheoryDataFun
   107 (struct
   108   val name = "Pure/theory";
   109   type T = thy;
   110   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table);
   111   val copy = I;
   112 
   113   fun extend (Thy {axioms, defs, oracles}) = make_thy (NameSpace.empty_table, defs, oracles);
   114 
   115   fun merge pp (thy1, thy2) =
   116     let
   117       val Thy {axioms = _, defs = defs1, oracles = oracles1} = thy1;
   118       val Thy {axioms = _, defs = defs2, oracles = oracles2} = thy2;
   119 
   120       val axioms = NameSpace.empty_table;
   121       val defs = Defs.merge pp defs1 defs2;
   122       val oracles = NameSpace.merge_tables eq_snd (oracles1, oracles2)
   123         handle Symtab.DUPS dups => err_dup_oras dups;
   124     in make_thy (axioms, defs, oracles) end;
   125 
   126   fun print _ _ = ();
   127 end);
   128 
   129 val init_data = ThyData.init;
   130 
   131 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   132 
   133 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles}) =>
   134   make_thy (f (axioms, defs, oracles)));
   135 
   136 fun map_axioms f = map_thy (fn (axioms, defs, oracles) => (f axioms, defs, oracles));
   137 fun map_defs f = map_thy (fn (axioms, defs, oracles) => (axioms, f defs, oracles));
   138 fun map_oracles f = map_thy (fn (axioms, defs, oracles) => (axioms, defs, f oracles));
   139 
   140 
   141 (* basic operations *)
   142 
   143 val axiom_space = #1 o #axioms o rep_theory;
   144 val oracle_space = #1 o #oracles o rep_theory;
   145 
   146 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   147 fun all_axioms_of thy = List.concat (map axioms_of (thy :: ancestors_of thy));
   148 
   149 val defs_of = #defs o rep_theory;
   150 
   151 fun requires thy name what =
   152   if Context.exists_name name thy then ()
   153   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   154 
   155 fun assert_super thy1 thy2 =
   156   if subthy (thy1, thy2) then thy2
   157   else raise THEORY ("Not a super theory", [thy1, thy2]);
   158 
   159 
   160 
   161 (** add axioms **)
   162 
   163 (* prepare axioms *)
   164 
   165 fun err_in_axm name =
   166   error ("The error(s) above occurred in axiom " ^ quote name);
   167 
   168 fun no_vars pp tm =
   169   (case (Term.term_vars tm, Term.term_tvars tm) of
   170     ([], []) => tm
   171   | (ts, ixns) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   172       (Pretty.str "Illegal schematic variable(s) in term:" ::
   173        map (Pretty.term pp) ts @ map (Pretty.typ pp o TVar) ixns)))));
   174 
   175 fun cert_axm thy (name, raw_tm) =
   176   let
   177     val pp = Sign.pp thy;
   178     val (t, T, _) = Sign.certify_term pp thy raw_tm
   179       handle TYPE (msg, _, _) => error msg
   180         | TERM (msg, _) => error msg;
   181   in
   182     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   183     assert (T = propT) "Term not of type prop";
   184     (name, no_vars pp t)
   185   end;
   186 
   187 fun read_def_axm (thy, types, sorts) used (name, str) =
   188   let
   189     val ts = Syntax.read thy (Sign.is_logtype thy) (Sign.syn_of thy) propT str;
   190     val (t, _) = Sign.infer_types (Sign.pp thy) thy types sorts used true (ts, propT);
   191   in cert_axm thy (name, t) end
   192   handle ERROR => err_in_axm name;
   193 
   194 fun read_axm thy name_str = read_def_axm (thy, K NONE, K NONE) [] name_str;
   195 
   196 fun inferT_axm thy (name, pre_tm) =
   197   let
   198     val pp = Sign.pp thy;
   199     val (t, _) = Sign.infer_types pp thy (K NONE) (K NONE) [] true ([pre_tm], propT);
   200   in (name, no_vars pp t) end
   201   handle ERROR => err_in_axm name;
   202 
   203 
   204 (* add_axioms(_i) *)
   205 
   206 local
   207 
   208 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   209   let
   210     val axms = map (apsnd (Term.compress_term o Logic.varify) o prep_axm thy) raw_axms;
   211     val axioms' = NameSpace.extend_table (Sign.naming_of thy) (axioms, axms)
   212       handle Symtab.DUPS dups => err_dup_axms dups;
   213   in axioms' end);
   214 
   215 in
   216 
   217 val add_axioms = gen_add_axioms read_axm;
   218 val add_axioms_i = gen_add_axioms cert_axm;
   219 
   220 end;
   221 
   222 
   223 
   224 (** add constant definitions **)
   225 
   226 (* overloading *)
   227 
   228 datatype overloading = Clean | Implicit | Useless;
   229 
   230 fun overloading thy overloaded declT defT =
   231   let
   232     val defT' = Logic.incr_tvar (maxidx_of_typ declT + 1) (Type.varifyT defT);
   233   in
   234     if Sign.typ_instance thy (declT, defT') then Clean
   235     else if Sign.typ_instance thy (Type.strip_sorts declT, Type.strip_sorts defT') then Useless
   236     else if overloaded then Clean
   237     else Implicit
   238   end;
   239 
   240 
   241 (* dest_def *)
   242 
   243 fun dest_def pp tm =
   244   let
   245     fun err msg = raise TERM (msg, [tm]);
   246 
   247     val (lhs, rhs) = Logic.dest_equals (Logic.strip_imp_concl tm)
   248       handle TERM _ => err "Not a meta-equality (==)";
   249     val (head, args) = Term.strip_comb lhs;
   250     val (c, T) = Term.dest_Const head
   251       handle TERM _ => err "Head of lhs not a constant";
   252 
   253     fun dest_free (Free (x, _)) = x
   254       | dest_free (Const ("TYPE", Type ("itself", [TFree (x, _)]))) = x
   255       | dest_free _ = raise Match;
   256 
   257     val show_terms = commas_quote o map (Pretty.string_of_term pp);
   258     val show_frees = commas_quote o map dest_free;
   259     val show_tfrees = commas_quote o map fst;
   260 
   261     val lhs_nofrees = filter (not o can dest_free) args;
   262     val lhs_dups = duplicates args;
   263     val rhs_extras = term_frees rhs |> fold (remove op =) args;
   264     val rhs_extrasT = term_tfrees rhs |> fold (remove op =) (typ_tfrees T);
   265   in
   266     if not (null lhs_nofrees) then
   267       err ("Non-variables as arguments on lhs: " ^ show_terms lhs_nofrees)
   268     else if not (null lhs_dups) then
   269       err ("Duplicate variables on lhs: " ^ show_frees lhs_dups)
   270     else if not (null rhs_extras) then
   271       err ("Extra variables on rhs: " ^ show_frees rhs_extras)
   272     else if not (null rhs_extrasT) then
   273       err ("Extra type variables on rhs: " ^ show_tfrees rhs_extrasT)
   274     else if exists_Const (equal (c, T)) rhs then
   275       err ("Constant to be defined occurs on rhs")
   276     else ((c, T), rhs)
   277   end;
   278 
   279 
   280 (* check_def *)
   281 
   282 fun pretty_const pp (c, T) =
   283  [Pretty.str c, Pretty.str " ::", Pretty.brk 1,
   284   Pretty.quote (Pretty.typ pp (Type.freeze_type T))];
   285 
   286 fun check_def thy overloaded (bname, tm) defs =
   287   let
   288     val pp = Sign.pp thy;
   289     fun prt_const (c, T) =
   290      [Pretty.str c, Pretty.str " ::", Pretty.brk 1,
   291       Pretty.quote (Pretty.typ pp (Type.freeze_type T))];
   292     fun string_of_def const txt =
   293       [Pretty.block (Pretty.str "Definition of " :: pretty_const pp const), Pretty.str txt]
   294       |> Pretty.chunks |> Pretty.string_of;
   295 
   296     fun typed_const c = (c, Sign.the_const_type thy c);
   297 
   298     val ((c, defT), rhs) = dest_def pp tm handle TERM (msg, _) => error msg;
   299     val rhs_consts = Term.term_constsT rhs;
   300     val declT = Sign.the_const_type thy c;
   301     val _ =
   302       (case overloading thy overloaded declT defT of
   303         Clean => ()
   304       | Implicit => warning (string_of_def (c, defT)
   305           ("is strictly less general than the declared type (see " ^ quote bname ^ ")"))
   306       | Useless => error (Library.setmp show_sorts true (string_of_def (c, defT))
   307           "imposes additional sort constraints on the declared type of the constant"));
   308   in
   309     defs |> Defs.declare (typed_const c) |> fold (Defs.declare o typed_const o #1) rhs_consts
   310     |> Defs.define pp (c, defT) (Sign.full_name thy bname) rhs_consts
   311   end
   312   handle ERROR => error (Pretty.string_of (Pretty.block
   313    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   314     Pretty.fbrk, Pretty.quote (Pretty.term (Sign.pp thy) tm)]));
   315 
   316 
   317 (* add_defs(_i) *)
   318 
   319 local
   320 
   321 fun gen_add_defs prep_axm overloaded raw_axms thy =
   322   let val axms = map (prep_axm thy) raw_axms in
   323     thy
   324     |> map_defs (fold (check_def thy overloaded) axms)
   325     |> add_axioms_i axms
   326   end;
   327 
   328 in
   329 
   330 val add_defs_i = gen_add_defs cert_axm;
   331 val add_defs = gen_add_defs read_axm;
   332 
   333 end;
   334 
   335 
   336 (* add_finals(_i) *)
   337 
   338 local
   339 
   340 fun gen_add_finals prep_term overloaded raw_terms thy =
   341   let
   342     fun finalize tm finals =
   343       let
   344         fun err msg = raise TERM (msg, [tm]);    (* FIXME error!? *)
   345         val (c, defT) =
   346           (case tm of Const x => x
   347           | Free _ => err "Attempt to finalize variable (or undeclared constant)"
   348           | _ => err "Attempt to finalize non-constant term");
   349         val declT = Sign.the_const_type thy c
   350           handle TYPE (msg, _, _) => err msg;
   351         val _ =    (* FIXME unify messages with defs *)
   352           (case overloading thy overloaded declT defT of
   353             Clean => ()
   354           | Implicit => warning ("Finalizing " ^ quote c ^
   355               " at a strictly less general type than declared")
   356           | Useless => err "Sort constraints stronger than declared");
   357       in finals |> Defs.declare (c, declT) |> Defs.finalize (c, defT) end;
   358   in thy |> map_defs (fold finalize (map (prep_term thy) raw_terms)) end;
   359 
   360 fun read_term thy = Sign.simple_read_term thy TypeInfer.logicT;
   361 fun cert_term thy = #1 o Sign.certify_term (Sign.pp thy) thy;
   362 
   363 in
   364 
   365 val add_finals = gen_add_finals read_term;
   366 val add_finals_i = gen_add_finals cert_term;
   367 
   368 end;
   369 
   370 
   371 
   372 (** add oracle **)
   373 
   374 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   375   NameSpace.extend_table (Sign.naming_of thy) (oracles, [(bname, (oracle, stamp ()))])
   376     handle Symtab.DUPS dups => err_dup_oras dups);
   377 
   378 end;
   379 
   380 structure BasicTheory: BASIC_THEORY = Theory;
   381 open BasicTheory;