src/Pure/PIDE/command.ML
author wenzelm
Mon Apr 07 23:02:29 2014 +0200 (2014-04-07)
changeset 56458 a8d960baa5c2
parent 56447 1e77ed11f2f7
child 56504 d71f4be7e287
permissions -rw-r--r--
simplified blob again (amending 1e77ed11f2f7): only store file node name, i.e. the raw editor file name;
more liberal hyperlink to files, allow hyperlinks within editor files independently of the (POSIX) file-system;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   type blob = (string * (SHA1.digest * string list) option) Exn.result
    10   val read_file: Path.T -> Position.T -> Path.T -> Token.file
    11   val read: (unit -> theory) -> Path.T -> blob list -> Token.T list -> Toplevel.transition
    12   type eval
    13   val eval_eq: eval * eval -> bool
    14   val eval_running: eval -> bool
    15   val eval_finished: eval -> bool
    16   val eval_result_state: eval -> Toplevel.state
    17   val eval: (unit -> theory) -> Path.T -> blob list -> Token.T list -> eval -> eval
    18   type print
    19   val print: bool -> (string * string list) list -> string ->
    20     eval -> print list -> print list option
    21   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    22   type print_function =
    23     {command_name: string, args: string list, exec_id: Document_ID.exec} ->
    24       {delay: Time.time option, pri: int, persistent: bool, strict: bool, print_fn: print_fn} option
    25   val print_function: string -> print_function -> unit
    26   val no_print_function: string -> unit
    27   type exec = eval * print list
    28   val no_exec: exec
    29   val exec_ids: exec option -> Document_ID.exec list
    30   val exec: Document_ID.execution -> exec -> unit
    31 end;
    32 
    33 structure Command: COMMAND =
    34 struct
    35 
    36 (** memo results **)
    37 
    38 datatype 'a expr =
    39   Expr of Document_ID.exec * (unit -> 'a) |
    40   Result of 'a Exn.result;
    41 
    42 abstype 'a memo = Memo of 'a expr Synchronized.var
    43 with
    44 
    45 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    46 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    47 
    48 fun memo_result (Memo v) =
    49   (case Synchronized.value v of
    50     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    51   | Result res => Exn.release res);
    52 
    53 fun memo_finished (Memo v) =
    54   (case Synchronized.value v of Expr _ => false | Result _ => true);
    55 
    56 fun memo_exec execution_id (Memo v) =
    57   Synchronized.timed_access v (K (SOME Time.zeroTime))
    58     (fn expr =>
    59       (case expr of
    60         Expr (exec_id, body) =>
    61           uninterruptible (fn restore_attributes => fn () =>
    62             let val group = Future.worker_subgroup () in
    63               if Execution.running execution_id exec_id [group] then
    64                 let
    65                   val res =
    66                     (body
    67                       |> restore_attributes
    68                       |> Future.task_context "Command.memo_exec" group
    69                       |> Exn.interruptible_capture) ();
    70                 in SOME ((), Result res) end
    71               else SOME ((), expr)
    72             end) ()
    73       | Result _ => SOME ((), expr)))
    74   |> (fn NONE => error "Conflicting command execution" | _ => ());
    75 
    76 fun memo_fork params execution_id (Memo v) =
    77   (case Synchronized.value v of
    78     Result _ => ()
    79   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    80 
    81 end;
    82 
    83 
    84 
    85 (** main phases of execution **)
    86 
    87 (* read *)
    88 
    89 type blob =
    90   (string * (SHA1.digest * string list) option) Exn.result;  (*file node name, digest, lines*)
    91 
    92 fun read_file master_dir pos src_path =
    93   let
    94     val _ = Position.report pos Markup.language_path;
    95     val full_path = File.check_file (File.full_path master_dir src_path);
    96     val _ = Position.report pos (Markup.path (Path.implode full_path));
    97     val text = File.read full_path;
    98     val lines = split_lines text;
    99     val digest = SHA1.digest text;
   100   in {src_path = src_path, lines = lines, digest = digest, pos = Path.position full_path} end;
   101 
   102 local
   103 
   104 fun blob_file src_path lines digest file_node =
   105   let
   106     val file_pos =
   107       Position.file file_node |>
   108       (case Position.get_id (Position.thread_data ()) of
   109         NONE => I
   110       | SOME exec_id => Position.put_id exec_id);
   111   in {src_path = src_path, lines = lines, digest = digest, pos = file_pos} end
   112 
   113 fun resolve_files master_dir blobs toks =
   114   (case Thy_Syntax.parse_spans toks of
   115     [span] => span
   116       |> Thy_Syntax.resolve_files (fn cmd => fn (path, pos) =>
   117         let
   118           fun make_file src_path (Exn.Res (_, NONE)) =
   119                 Exn.interruptible_capture (fn () => read_file master_dir pos src_path) ()
   120             | make_file src_path (Exn.Res (file_node, SOME (digest, lines))) =
   121                (Position.reports [(pos, Markup.language_path), (pos, Markup.path file_node)];
   122                 Exn.Res (blob_file src_path lines digest file_node))
   123             | make_file _ (Exn.Exn e) = Exn.Exn e;
   124           val src_paths = Keyword.command_files cmd path;
   125         in
   126           if null blobs then
   127             map2 make_file src_paths (map (K (Exn.Res ("", NONE))) src_paths)
   128           else if length src_paths = length blobs then
   129             map2 make_file src_paths blobs
   130           else error ("Misalignment of inlined files" ^ Position.here pos)
   131         end)
   132       |> Thy_Syntax.span_content
   133   | _ => toks);
   134 
   135 in
   136 
   137 fun read init master_dir blobs span =
   138   let
   139     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
   140     val command_reports = Outer_Syntax.command_reports outer_syntax;
   141 
   142     val proper_range = Token.range_of (#1 (take_suffix Token.is_improper span));
   143     val pos =
   144       (case find_first Token.is_command span of
   145         SOME tok => Token.pos_of tok
   146       | NONE => #1 proper_range);
   147 
   148     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
   149     val _ = Position.reports_text (token_reports @ maps command_reports span);
   150   in
   151     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
   152     else
   153       (case Outer_Syntax.read_spans outer_syntax (resolve_files master_dir blobs span) of
   154         [tr] =>
   155           if Keyword.is_control (Toplevel.name_of tr) then
   156             Toplevel.malformed pos "Illegal control command"
   157           else Toplevel.modify_init init tr
   158       | [] => Toplevel.ignored (#1 (Token.range_of span))
   159       | _ => Toplevel.malformed (#1 proper_range) "Exactly one command expected")
   160       handle ERROR msg => Toplevel.malformed (#1 proper_range) msg
   161   end;
   162 
   163 end;
   164 
   165 
   166 (* eval *)
   167 
   168 type eval_state =
   169   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   170 val init_eval_state =
   171   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   172 
   173 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   174 
   175 fun eval_exec_id (Eval {exec_id, ...}) = exec_id;
   176 val eval_eq = op = o pairself eval_exec_id;
   177 
   178 val eval_running = Execution.is_running_exec o eval_exec_id;
   179 fun eval_finished (Eval {eval_process, ...}) = memo_finished eval_process;
   180 
   181 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   182 val eval_result_state = #state o eval_result;
   183 
   184 local
   185 
   186 fun run int tr st =
   187   if Goal.future_enabled 1 andalso Keyword.is_diag (Toplevel.name_of tr) then
   188     (Execution.fork {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   189       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   190   else Toplevel.command_errors int tr st;
   191 
   192 fun check_cmts span tr st' =
   193   Toplevel.setmp_thread_position tr
   194     (fn () =>
   195       Outer_Syntax.side_comments span |> maps (fn cmt =>
   196         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   197           handle exn =>
   198             if Exn.is_interrupt exn then reraise exn
   199             else Runtime.exn_messages_ids exn)) ();
   200 
   201 fun report tr m =
   202   Toplevel.setmp_thread_position tr (fn () => Output.report [Markup.markup_only m]) ();
   203 
   204 fun status tr m =
   205   Toplevel.setmp_thread_position tr (fn () => Output.status (Markup.markup_only m)) ();
   206 
   207 fun proof_status tr st =
   208   (case try Toplevel.proof_of st of
   209     SOME prf => status tr (Proof.status_markup prf)
   210   | NONE => ());
   211 
   212 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   213   if malformed then
   214     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   215   else
   216     let
   217       val malformed' = Toplevel.is_malformed tr;
   218       val is_init = Toplevel.is_init tr;
   219       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   220 
   221       val _ = Multithreading.interrupted ();
   222       val _ = status tr Markup.running;
   223       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   224       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   225       val errs = errs1 @ errs2;
   226       val _ = List.app (Future.error_message (Toplevel.pos_of tr)) errs;
   227     in
   228       (case result of
   229         NONE =>
   230           let
   231             val _ = status tr Markup.failed;
   232             val _ = status tr Markup.finished;
   233             val _ = if null errs then (report tr Markup.bad; Exn.interrupt ()) else ();
   234           in {failed = true, malformed = malformed', command = tr, state = st} end
   235       | SOME st' =>
   236           let
   237             val _ = proof_status tr st';
   238             val _ = status tr Markup.finished;
   239           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   240     end;
   241 
   242 in
   243 
   244 fun eval init master_dir blobs span eval0 =
   245   let
   246     val exec_id = Document_ID.make ();
   247     fun process () =
   248       let
   249         val tr =
   250           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   251             (fn () => read init master_dir blobs span |> Toplevel.exec_id exec_id) ();
   252       in eval_state span tr (eval_result eval0) end;
   253   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   254 
   255 end;
   256 
   257 
   258 (* print *)
   259 
   260 datatype print = Print of
   261  {name: string, args: string list, delay: Time.time option, pri: int, persistent: bool,
   262   exec_id: Document_ID.exec, print_process: unit memo};
   263 
   264 fun print_exec_id (Print {exec_id, ...}) = exec_id;
   265 val print_eq = op = o pairself print_exec_id;
   266 
   267 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   268 
   269 type print_function =
   270   {command_name: string, args: string list, exec_id: Document_ID.exec} ->
   271     {delay: Time.time option, pri: int, persistent: bool, strict: bool, print_fn: print_fn} option;
   272 
   273 local
   274 
   275 val print_functions =
   276   Synchronized.var "Command.print_functions" ([]: (string * print_function) list);
   277 
   278 fun print_error tr opt_context e =
   279   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution opt_context) e ()
   280     handle exn =>
   281       if Exn.is_interrupt exn then reraise exn
   282       else List.app (Future.error_message (Toplevel.pos_of tr)) (Runtime.exn_messages_ids exn);
   283 
   284 fun print_finished (Print {print_process, ...}) = memo_finished print_process;
   285 
   286 fun print_persistent (Print {persistent, ...}) = persistent;
   287 
   288 val overlay_ord = prod_ord string_ord (list_ord string_ord);
   289 
   290 in
   291 
   292 fun print command_visible command_overlays command_name eval old_prints =
   293   let
   294     val print_functions = Synchronized.value print_functions;
   295 
   296     fun make_print name args {delay, pri, persistent, strict, print_fn} =
   297       let
   298         val exec_id = Document_ID.make ();
   299         fun process () =
   300           let
   301             val {failed, command, state = st', ...} = eval_result eval;
   302             val tr = Toplevel.exec_id exec_id command;
   303             val opt_context = try Toplevel.generic_theory_of st';
   304           in
   305             if failed andalso strict then ()
   306             else print_error tr opt_context (fn () => print_fn tr st')
   307           end;
   308       in
   309         Print {
   310           name = name, args = args, delay = delay, pri = pri, persistent = persistent,
   311           exec_id = exec_id, print_process = memo exec_id process}
   312       end;
   313 
   314     fun bad_print name args exn =
   315       make_print name args {delay = NONE, pri = 0, persistent = false,
   316         strict = false, print_fn = fn _ => fn _ => reraise exn};
   317 
   318     fun new_print name args get_pr =
   319       let
   320         val params = {command_name = command_name, args = args, exec_id = eval_exec_id eval};
   321       in
   322         (case Exn.capture (Runtime.controlled_execution NONE get_pr) params of
   323           Exn.Res NONE => NONE
   324         | Exn.Res (SOME pr) => SOME (make_print name args pr)
   325         | Exn.Exn exn => SOME (bad_print name args exn))
   326       end;
   327 
   328     fun get_print (a, b) =
   329       (case find_first (fn Print {name, args, ...} => name = a andalso args = b) old_prints of
   330         NONE =>
   331           (case AList.lookup (op =) print_functions a of
   332             NONE => SOME (bad_print a b (ERROR ("Missing print function " ^ quote a)))
   333           | SOME get_pr => new_print a b get_pr)
   334       | some => some);
   335 
   336     val new_prints =
   337       if command_visible then
   338         fold (fn (a, _) => cons (a, [])) print_functions command_overlays
   339         |> sort_distinct overlay_ord
   340         |> map_filter get_print
   341       else filter (fn print => print_finished print andalso print_persistent print) old_prints;
   342   in
   343     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   344   end;
   345 
   346 fun print_function name f =
   347   Synchronized.change print_functions (fn funs =>
   348    (if not (AList.defined (op =) funs name) then ()
   349     else warning ("Redefining command print function: " ^ quote name);
   350     AList.update (op =) (name, f) funs));
   351 
   352 fun no_print_function name =
   353   Synchronized.change print_functions (filter_out (equal name o #1));
   354 
   355 end;
   356 
   357 val _ =
   358   print_function "Execution.print"
   359     (fn {args, exec_id, ...} =>
   360       if null args then
   361         SOME {delay = NONE, pri = 1, persistent = false, strict = true,
   362           print_fn = fn _ => fn _ => Execution.fork_prints exec_id}
   363       else NONE);
   364 
   365 val _ =
   366   print_function "print_state"
   367     (fn {command_name, ...} =>
   368       SOME {delay = NONE, pri = 1, persistent = false, strict = true,
   369         print_fn = fn tr => fn st' =>
   370           let
   371             val is_init = Keyword.is_theory_begin command_name;
   372             val is_proof = Keyword.is_proof command_name;
   373             val do_print =
   374               not is_init andalso
   375                 (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   376           in if do_print then Toplevel.print_state false st' else () end});
   377 
   378 
   379 (* combined execution *)
   380 
   381 type exec = eval * print list;
   382 val no_exec: exec =
   383   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   384 
   385 fun exec_ids NONE = []
   386   | exec_ids (SOME (eval, prints)) = eval_exec_id eval :: map print_exec_id prints;
   387 
   388 local
   389 
   390 fun run_print execution_id (Print {name, delay, pri, print_process, ...}) =
   391   if Multithreading.enabled () orelse pri <= 0 then
   392     let
   393       val group = Future.worker_subgroup ();
   394       fun fork () =
   395         memo_fork {name = name, group = SOME group, deps = [], pri = pri, interrupts = true}
   396           execution_id print_process;
   397     in
   398       (case delay of
   399         NONE => fork ()
   400       | SOME d => ignore (Event_Timer.request (Time.+ (Time.now (), d)) fork))
   401     end
   402   else memo_exec execution_id print_process;
   403 
   404 in
   405 
   406 fun exec execution_id (Eval {eval_process, ...}, prints) =
   407   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   408 
   409 end;
   410 
   411 end;
   412