src/HOL/Set.thy
author nipkow
Sat May 16 11:28:02 2009 +0200 (2009-05-16)
changeset 31166 a90fe83f58ea
parent 30814 10dc9bc264b7
child 31197 c1c163ec6c44
permissions -rw-r--r--
"{x. P x & x=t & Q x}" is now rewritten to "if P t & Q t then {t} else {}"
by the new simproc defColl_regroup. More precisely, the simproc pulls an
equation x=t (or t=x) out of a nest of conjunctions to the front where the
simp rule singleton_conj_conv(2) converts to "if".
     1 (*  Title:      HOL/Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3 *)
     4 
     5 header {* Set theory for higher-order logic *}
     6 
     7 theory Set
     8 imports Lattices
     9 begin
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 types 'a set = "'a => bool"
    19 
    20 consts
    21   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    22   "op :"        :: "'a => 'a set => bool"                -- "membership"
    23   insert        :: "'a => 'a set => 'a set"
    24   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    25   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    26   Bex1          :: "'a set => ('a => bool) => bool"      -- "bounded unique existential quantifiers"
    27   Pow           :: "'a set => 'a set set"                -- "powerset"
    28   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    29 
    30 local
    31 
    32 notation
    33   "op :"  ("op :") and
    34   "op :"  ("(_/ : _)" [50, 51] 50)
    35 
    36 abbreviation
    37   "not_mem x A == ~ (x : A)" -- "non-membership"
    38 
    39 notation
    40   not_mem  ("op ~:") and
    41   not_mem  ("(_/ ~: _)" [50, 51] 50)
    42 
    43 notation (xsymbols)
    44   "op :"  ("op \<in>") and
    45   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    46   not_mem  ("op \<notin>") and
    47   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    48 
    49 notation (HTML output)
    50   "op :"  ("op \<in>") and
    51   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    52   not_mem  ("op \<notin>") and
    53   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    54 
    55 syntax
    56   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    57 
    58 translations
    59   "{x. P}"      == "Collect (%x. P)"
    60 
    61 definition empty :: "'a set" ("{}") where
    62   "empty \<equiv> {x. False}"
    63 
    64 definition UNIV :: "'a set" where
    65   "UNIV \<equiv> {x. True}"
    66 
    67 syntax
    68   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    69 
    70 translations
    71   "{x, xs}"     == "insert x {xs}"
    72   "{x}"         == "insert x {}"
    73 
    74 definition Int :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Int" 70) where
    75   "A Int B \<equiv> {x. x \<in> A \<and> x \<in> B}"
    76 
    77 definition Un :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Un" 65) where
    78   "A Un B \<equiv> {x. x \<in> A \<or> x \<in> B}"
    79 
    80 notation (xsymbols)
    81   "Int"  (infixl "\<inter>" 70) and
    82   "Un"  (infixl "\<union>" 65)
    83 
    84 notation (HTML output)
    85   "Int"  (infixl "\<inter>" 70) and
    86   "Un"  (infixl "\<union>" 65)
    87 
    88 syntax
    89   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    90   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    91   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3EX! _:_./ _)" [0, 0, 10] 10)
    92   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST _:_./ _)" [0, 0, 10] 10)
    93 
    94 syntax (HOL)
    95   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    96   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    97   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3?! _:_./ _)" [0, 0, 10] 10)
    98 
    99 syntax (xsymbols)
   100   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   101   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   102   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   103   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST_\<in>_./ _)" [0, 0, 10] 10)
   104 
   105 syntax (HTML output)
   106   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   107   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   108   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   109 
   110 translations
   111   "ALL x:A. P"  == "Ball A (%x. P)"
   112   "EX x:A. P"   == "Bex A (%x. P)"
   113   "EX! x:A. P"  == "Bex1 A (%x. P)"
   114   "LEAST x:A. P" => "LEAST x. x:A & P"
   115 
   116 definition INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   117   "INTER A B \<equiv> {y. \<forall>x\<in>A. y \<in> B x}"
   118 
   119 definition UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   120   "UNION A B \<equiv> {y. \<exists>x\<in>A. y \<in> B x}"
   121 
   122 definition Inter :: "'a set set \<Rightarrow> 'a set" where
   123   "Inter S \<equiv> INTER S (\<lambda>x. x)"
   124 
   125 definition Union :: "'a set set \<Rightarrow> 'a set" where
   126   "Union S \<equiv> UNION S (\<lambda>x. x)"
   127 
   128 notation (xsymbols)
   129   Inter  ("\<Inter>_" [90] 90) and
   130   Union  ("\<Union>_" [90] 90)
   131 
   132 
   133 subsection {* Additional concrete syntax *}
   134 
   135 syntax
   136   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
   137   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ :/ _./ _})")
   138   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   139   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   140   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 10] 10)
   141   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 10] 10)
   142 
   143 syntax (xsymbols)
   144   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ \<in>/ _./ _})")
   145   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   146   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   147   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 10] 10)
   148   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 10] 10)
   149 
   150 syntax (latex output)
   151   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   152   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   153   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   154   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   155 
   156 translations
   157   "{x:A. P}"    => "{x. x:A & P}"
   158   "INT x y. B"  == "INT x. INT y. B"
   159   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   160   "INT x. B"    == "INT x:CONST UNIV. B"
   161   "INT x:A. B"  == "CONST INTER A (%x. B)"
   162   "UN x y. B"   == "UN x. UN y. B"
   163   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   164   "UN x. B"     == "UN x:CONST UNIV. B"
   165   "UN x:A. B"   == "CONST UNION A (%x. B)"
   166 
   167 text {*
   168   Note the difference between ordinary xsymbol syntax of indexed
   169   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   170   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   171   former does not make the index expression a subscript of the
   172   union/intersection symbol because this leads to problems with nested
   173   subscripts in Proof General.
   174 *}
   175 
   176 abbreviation
   177   subset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   178   "subset \<equiv> less"
   179 
   180 abbreviation
   181   subset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   182   "subset_eq \<equiv> less_eq"
   183 
   184 notation (output)
   185   subset  ("op <") and
   186   subset  ("(_/ < _)" [50, 51] 50) and
   187   subset_eq  ("op <=") and
   188   subset_eq  ("(_/ <= _)" [50, 51] 50)
   189 
   190 notation (xsymbols)
   191   subset  ("op \<subset>") and
   192   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   193   subset_eq  ("op \<subseteq>") and
   194   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   195 
   196 notation (HTML output)
   197   subset  ("op \<subset>") and
   198   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   199   subset_eq  ("op \<subseteq>") and
   200   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   201 
   202 abbreviation (input)
   203   supset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   204   "supset \<equiv> greater"
   205 
   206 abbreviation (input)
   207   supset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   208   "supset_eq \<equiv> greater_eq"
   209 
   210 notation (xsymbols)
   211   supset  ("op \<supset>") and
   212   supset  ("(_/ \<supset> _)" [50, 51] 50) and
   213   supset_eq  ("op \<supseteq>") and
   214   supset_eq  ("(_/ \<supseteq> _)" [50, 51] 50)
   215 
   216 abbreviation
   217   range :: "('a => 'b) => 'b set" where -- "of function"
   218   "range f == f ` UNIV"
   219 
   220 
   221 subsubsection "Bounded quantifiers"
   222 
   223 syntax (output)
   224   "_setlessAll" :: "[idt, 'a, bool] => bool"  ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   225   "_setlessEx"  :: "[idt, 'a, bool] => bool"  ("(3EX _<_./ _)"  [0, 0, 10] 10)
   226   "_setleAll"   :: "[idt, 'a, bool] => bool"  ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   227   "_setleEx"    :: "[idt, 'a, bool] => bool"  ("(3EX _<=_./ _)" [0, 0, 10] 10)
   228   "_setleEx1"   :: "[idt, 'a, bool] => bool"  ("(3EX! _<=_./ _)" [0, 0, 10] 10)
   229 
   230 syntax (xsymbols)
   231   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   232   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   233   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   234   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   235   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   236 
   237 syntax (HOL output)
   238   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   239   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   240   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   241   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   242   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3?! _<=_./ _)" [0, 0, 10] 10)
   243 
   244 syntax (HTML output)
   245   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   246   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   247   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   248   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   249   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   250 
   251 translations
   252  "\<forall>A\<subset>B. P"   =>  "ALL A. A \<subset> B --> P"
   253  "\<exists>A\<subset>B. P"   =>  "EX A. A \<subset> B & P"
   254  "\<forall>A\<subseteq>B. P"   =>  "ALL A. A \<subseteq> B --> P"
   255  "\<exists>A\<subseteq>B. P"   =>  "EX A. A \<subseteq> B & P"
   256  "\<exists>!A\<subseteq>B. P"  =>  "EX! A. A \<subseteq> B & P"
   257 
   258 print_translation {*
   259 let
   260   val Type (set_type, _) = @{typ "'a set"};
   261   val All_binder = Syntax.binder_name @{const_syntax "All"};
   262   val Ex_binder = Syntax.binder_name @{const_syntax "Ex"};
   263   val impl = @{const_syntax "op -->"};
   264   val conj = @{const_syntax "op &"};
   265   val sbset = @{const_syntax "subset"};
   266   val sbset_eq = @{const_syntax "subset_eq"};
   267 
   268   val trans =
   269    [((All_binder, impl, sbset), "_setlessAll"),
   270     ((All_binder, impl, sbset_eq), "_setleAll"),
   271     ((Ex_binder, conj, sbset), "_setlessEx"),
   272     ((Ex_binder, conj, sbset_eq), "_setleEx")];
   273 
   274   fun mk v v' c n P =
   275     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   276     then Syntax.const c $ Syntax.mark_bound v' $ n $ P else raise Match;
   277 
   278   fun tr' q = (q,
   279     fn [Const ("_bound", _) $ Free (v, Type (T, _)), Const (c, _) $ (Const (d, _) $ (Const ("_bound", _) $ Free (v', _)) $ n) $ P] =>
   280          if T = (set_type) then case AList.lookup (op =) trans (q, c, d)
   281           of NONE => raise Match
   282            | SOME l => mk v v' l n P
   283          else raise Match
   284      | _ => raise Match);
   285 in
   286   [tr' All_binder, tr' Ex_binder]
   287 end
   288 *}
   289 
   290 
   291 text {*
   292   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   293   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   294   only translated if @{text "[0..n] subset bvs(e)"}.
   295 *}
   296 
   297 parse_translation {*
   298   let
   299     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   300 
   301     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   302       | nvars _ = 1;
   303 
   304     fun setcompr_tr [e, idts, b] =
   305       let
   306         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   307         val P = Syntax.const "op &" $ eq $ b;
   308         val exP = ex_tr [idts, P];
   309       in Syntax.const "Collect" $ Term.absdummy (dummyT, exP) end;
   310 
   311   in [("@SetCompr", setcompr_tr)] end;
   312 *}
   313 
   314 (* To avoid eta-contraction of body: *)
   315 print_translation {*
   316 let
   317   fun btr' syn [A, Abs abs] =
   318     let val (x, t) = atomic_abs_tr' abs
   319     in Syntax.const syn $ x $ A $ t end
   320 in
   321 [(@{const_syntax Ball}, btr' "_Ball"), (@{const_syntax Bex}, btr' "_Bex"),
   322  (@{const_syntax UNION}, btr' "@UNION"),(@{const_syntax INTER}, btr' "@INTER")]
   323 end
   324 *}
   325 
   326 print_translation {*
   327 let
   328   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   329 
   330   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   331     let
   332       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   333         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   334             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   335             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   336         | check _ = false
   337 
   338         fun tr' (_ $ abs) =
   339           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   340           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   341     in if check (P, 0) then tr' P
   342        else let val (x as _ $ Free(xN,_), t) = atomic_abs_tr' abs
   343                 val M = Syntax.const "@Coll" $ x $ t
   344             in case t of
   345                  Const("op &",_)
   346                    $ (Const("op :",_) $ (Const("_bound",_) $ Free(yN,_)) $ A)
   347                    $ P =>
   348                    if xN=yN then Syntax.const "@Collect" $ x $ A $ P else M
   349                | _ => M
   350             end
   351     end;
   352   in [("Collect", setcompr_tr')] end;
   353 *}
   354 
   355 
   356 subsection {* Rules and definitions *}
   357 
   358 text {* Isomorphisms between predicates and sets. *}
   359 
   360 defs
   361   mem_def [code]: "x : S == S x"
   362   Collect_def [code]: "Collect P == P"
   363 
   364 defs
   365   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   366   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   367   Bex1_def:     "Bex1 A P       == EX! x. x:A & P(x)"
   368 
   369 instantiation "fun" :: (type, minus) minus
   370 begin
   371 
   372 definition
   373   fun_diff_def: "A - B = (%x. A x - B x)"
   374 
   375 instance ..
   376 
   377 end
   378 
   379 instantiation bool :: minus
   380 begin
   381 
   382 definition
   383   bool_diff_def: "A - B = (A & ~ B)"
   384 
   385 instance ..
   386 
   387 end
   388 
   389 instantiation "fun" :: (type, uminus) uminus
   390 begin
   391 
   392 definition
   393   fun_Compl_def: "- A = (%x. - A x)"
   394 
   395 instance ..
   396 
   397 end
   398 
   399 instantiation bool :: uminus
   400 begin
   401 
   402 definition
   403   bool_Compl_def: "- A = (~ A)"
   404 
   405 instance ..
   406 
   407 end
   408 
   409 defs
   410   Pow_def:      "Pow A          == {B. B <= A}"
   411   insert_def:   "insert a B     == {x. x=a} Un B"
   412   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   413 
   414 
   415 subsection {* Lemmas and proof tool setup *}
   416 
   417 subsubsection {* Relating predicates and sets *}
   418 
   419 lemma mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   420   by (simp add: Collect_def mem_def)
   421 
   422 lemma Collect_mem_eq [simp]: "{x. x:A} = A"
   423   by (simp add: Collect_def mem_def)
   424 
   425 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   426   by simp
   427 
   428 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   429   by simp
   430 
   431 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   432   by simp
   433 
   434 lemmas CollectE = CollectD [elim_format]
   435 
   436 
   437 subsubsection {* Bounded quantifiers *}
   438 
   439 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   440   by (simp add: Ball_def)
   441 
   442 lemmas strip = impI allI ballI
   443 
   444 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   445   by (simp add: Ball_def)
   446 
   447 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   448   by (unfold Ball_def) blast
   449 
   450 ML {* bind_thm ("rev_ballE", permute_prems 1 1 @{thm ballE}) *}
   451 
   452 text {*
   453   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   454   @{prop "a:A"}; creates assumption @{prop "P a"}.
   455 *}
   456 
   457 ML {*
   458   fun ball_tac i = etac @{thm ballE} i THEN contr_tac (i + 1)
   459 *}
   460 
   461 text {*
   462   Gives better instantiation for bound:
   463 *}
   464 
   465 declaration {* fn _ =>
   466   Classical.map_cs (fn cs => cs addbefore ("bspec", datac @{thm bspec} 1))
   467 *}
   468 
   469 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   470   -- {* Normally the best argument order: @{prop "P x"} constrains the
   471     choice of @{prop "x:A"}. *}
   472   by (unfold Bex_def) blast
   473 
   474 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   475   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   476   by (unfold Bex_def) blast
   477 
   478 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   479   by (unfold Bex_def) blast
   480 
   481 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   482   by (unfold Bex_def) blast
   483 
   484 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   485   -- {* Trival rewrite rule. *}
   486   by (simp add: Ball_def)
   487 
   488 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   489   -- {* Dual form for existentials. *}
   490   by (simp add: Bex_def)
   491 
   492 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   493   by blast
   494 
   495 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   496   by blast
   497 
   498 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   499   by blast
   500 
   501 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   502   by blast
   503 
   504 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   505   by blast
   506 
   507 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   508   by blast
   509 
   510 ML {*
   511   local
   512     val unfold_bex_tac = unfold_tac @{thms "Bex_def"};
   513     fun prove_bex_tac ss = unfold_bex_tac ss THEN Quantifier1.prove_one_point_ex_tac;
   514     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   515 
   516     val unfold_ball_tac = unfold_tac @{thms "Ball_def"};
   517     fun prove_ball_tac ss = unfold_ball_tac ss THEN Quantifier1.prove_one_point_all_tac;
   518     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   519   in
   520     val defBEX_regroup = Simplifier.simproc (the_context ())
   521       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   522     val defBALL_regroup = Simplifier.simproc (the_context ())
   523       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   524   end;
   525 
   526   Addsimprocs [defBALL_regroup, defBEX_regroup];
   527 *}
   528 
   529 
   530 subsubsection {* Congruence rules *}
   531 
   532 lemma ball_cong:
   533   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   534     (ALL x:A. P x) = (ALL x:B. Q x)"
   535   by (simp add: Ball_def)
   536 
   537 lemma strong_ball_cong [cong]:
   538   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   539     (ALL x:A. P x) = (ALL x:B. Q x)"
   540   by (simp add: simp_implies_def Ball_def)
   541 
   542 lemma bex_cong:
   543   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   544     (EX x:A. P x) = (EX x:B. Q x)"
   545   by (simp add: Bex_def cong: conj_cong)
   546 
   547 lemma strong_bex_cong [cong]:
   548   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   549     (EX x:A. P x) = (EX x:B. Q x)"
   550   by (simp add: simp_implies_def Bex_def cong: conj_cong)
   551 
   552 
   553 subsubsection {* Subsets *}
   554 
   555 lemma subsetI [atp,intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   556   by (auto simp add: mem_def intro: predicate1I)
   557 
   558 text {*
   559   \medskip Map the type @{text "'a set => anything"} to just @{typ
   560   'a}; for overloading constants whose first argument has type @{typ
   561   "'a set"}.
   562 *}
   563 
   564 lemma subsetD [elim, intro?]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   565   -- {* Rule in Modus Ponens style. *}
   566   by (unfold mem_def) blast
   567 
   568 lemma rev_subsetD [intro?]: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   569   -- {* The same, with reversed premises for use with @{text erule} --
   570       cf @{text rev_mp}. *}
   571   by (rule subsetD)
   572 
   573 text {*
   574   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   575 *}
   576 
   577 ML {*
   578   fun impOfSubs th = th RSN (2, @{thm rev_subsetD})
   579 *}
   580 
   581 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   582   -- {* Classical elimination rule. *}
   583   by (unfold mem_def) blast
   584 
   585 lemma subset_eq: "A \<le> B = (\<forall>x\<in>A. x \<in> B)" by blast
   586 
   587 text {*
   588   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   589   creates the assumption @{prop "c \<in> B"}.
   590 *}
   591 
   592 ML {*
   593   fun set_mp_tac i = etac @{thm subsetCE} i THEN mp_tac i
   594 *}
   595 
   596 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   597   by blast
   598 
   599 lemma subset_refl [simp,atp]: "A \<subseteq> A"
   600   by fast
   601 
   602 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   603   by blast
   604 
   605 
   606 subsubsection {* Equality *}
   607 
   608 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   609   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   610    apply (rule Collect_mem_eq)
   611   apply (rule Collect_mem_eq)
   612   done
   613 
   614 (* Due to Brian Huffman *)
   615 lemma expand_set_eq: "(A = B) = (ALL x. (x:A) = (x:B))"
   616 by(auto intro:set_ext)
   617 
   618 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   619   -- {* Anti-symmetry of the subset relation. *}
   620   by (iprover intro: set_ext subsetD)
   621 
   622 text {*
   623   \medskip Equality rules from ZF set theory -- are they appropriate
   624   here?
   625 *}
   626 
   627 lemma equalityD1: "A = B ==> A \<subseteq> B"
   628   by (simp add: subset_refl)
   629 
   630 lemma equalityD2: "A = B ==> B \<subseteq> A"
   631   by (simp add: subset_refl)
   632 
   633 text {*
   634   \medskip Be careful when adding this to the claset as @{text
   635   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   636   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   637 *}
   638 
   639 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   640   by (simp add: subset_refl)
   641 
   642 lemma equalityCE [elim]:
   643     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   644   by blast
   645 
   646 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   647   by simp
   648 
   649 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   650   by simp
   651 
   652 
   653 subsubsection {* The universal set -- UNIV *}
   654 
   655 lemma UNIV_I [simp]: "x : UNIV"
   656   by (simp add: UNIV_def)
   657 
   658 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   659 
   660 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   661   by simp
   662 
   663 lemma subset_UNIV [simp]: "A \<subseteq> UNIV"
   664   by (rule subsetI) (rule UNIV_I)
   665 
   666 text {*
   667   \medskip Eta-contracting these two rules (to remove @{text P})
   668   causes them to be ignored because of their interaction with
   669   congruence rules.
   670 *}
   671 
   672 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   673   by (simp add: Ball_def)
   674 
   675 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   676   by (simp add: Bex_def)
   677 
   678 lemma UNIV_eq_I: "(\<And>x. x \<in> A) \<Longrightarrow> UNIV = A"
   679   by auto
   680 
   681 
   682 subsubsection {* The empty set *}
   683 
   684 lemma empty_iff [simp]: "(c : {}) = False"
   685   by (simp add: empty_def)
   686 
   687 lemma emptyE [elim!]: "a : {} ==> P"
   688   by simp
   689 
   690 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   691     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   692   by blast
   693 
   694 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   695   by blast
   696 
   697 lemma equals0D: "A = {} ==> a \<notin> A"
   698     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   699   by blast
   700 
   701 lemma ball_empty [simp]: "Ball {} P = True"
   702   by (simp add: Ball_def)
   703 
   704 lemma bex_empty [simp]: "Bex {} P = False"
   705   by (simp add: Bex_def)
   706 
   707 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   708   by (blast elim: equalityE)
   709 
   710 
   711 subsubsection {* The Powerset operator -- Pow *}
   712 
   713 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   714   by (simp add: Pow_def)
   715 
   716 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   717   by (simp add: Pow_def)
   718 
   719 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   720   by (simp add: Pow_def)
   721 
   722 lemma Pow_bottom: "{} \<in> Pow B"
   723   by simp
   724 
   725 lemma Pow_top: "A \<in> Pow A"
   726   by (simp add: subset_refl)
   727 
   728 
   729 subsubsection {* Set complement *}
   730 
   731 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   732   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   733 
   734 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   735   by (unfold mem_def fun_Compl_def bool_Compl_def) blast
   736 
   737 text {*
   738   \medskip This form, with negated conclusion, works well with the
   739   Classical prover.  Negated assumptions behave like formulae on the
   740   right side of the notional turnstile ... *}
   741 
   742 lemma ComplD [dest!]: "c : -A ==> c~:A"
   743   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   744 
   745 lemmas ComplE = ComplD [elim_format]
   746 
   747 lemma Compl_eq: "- A = {x. ~ x : A}" by blast
   748 
   749 
   750 subsubsection {* Binary union -- Un *}
   751 
   752 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   753   by (unfold Un_def) blast
   754 
   755 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   756   by simp
   757 
   758 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   759   by simp
   760 
   761 text {*
   762   \medskip Classical introduction rule: no commitment to @{prop A} vs
   763   @{prop B}.
   764 *}
   765 
   766 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   767   by auto
   768 
   769 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   770   by (unfold Un_def) blast
   771 
   772 
   773 subsubsection {* Binary intersection -- Int *}
   774 
   775 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   776   by (unfold Int_def) blast
   777 
   778 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   779   by simp
   780 
   781 lemma IntD1: "c : A Int B ==> c:A"
   782   by simp
   783 
   784 lemma IntD2: "c : A Int B ==> c:B"
   785   by simp
   786 
   787 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   788   by simp
   789 
   790 
   791 subsubsection {* Set difference *}
   792 
   793 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   794   by (simp add: mem_def fun_diff_def bool_diff_def)
   795 
   796 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   797   by simp
   798 
   799 lemma DiffD1: "c : A - B ==> c : A"
   800   by simp
   801 
   802 lemma DiffD2: "c : A - B ==> c : B ==> P"
   803   by simp
   804 
   805 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   806   by simp
   807 
   808 lemma set_diff_eq: "A - B = {x. x : A & ~ x : B}" by blast
   809 
   810 lemma Compl_eq_Diff_UNIV: "-A = (UNIV - A)"
   811 by blast
   812 
   813 
   814 subsubsection {* Augmenting a set -- insert *}
   815 
   816 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   817   by (unfold insert_def) blast
   818 
   819 lemma insertI1: "a : insert a B"
   820   by simp
   821 
   822 lemma insertI2: "a : B ==> a : insert b B"
   823   by simp
   824 
   825 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   826   by (unfold insert_def) blast
   827 
   828 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   829   -- {* Classical introduction rule. *}
   830   by auto
   831 
   832 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   833   by auto
   834 
   835 lemma set_insert:
   836   assumes "x \<in> A"
   837   obtains B where "A = insert x B" and "x \<notin> B"
   838 proof
   839   from assms show "A = insert x (A - {x})" by blast
   840 next
   841   show "x \<notin> A - {x}" by blast
   842 qed
   843 
   844 lemma insert_ident: "x ~: A ==> x ~: B ==> (insert x A = insert x B) = (A = B)"
   845 by auto
   846 
   847 subsubsection {* Singletons, using insert *}
   848 
   849 lemma singletonI [intro!,noatp]: "a : {a}"
   850     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   851   by (rule insertI1)
   852 
   853 lemma singletonD [dest!,noatp]: "b : {a} ==> b = a"
   854   by blast
   855 
   856 lemmas singletonE = singletonD [elim_format]
   857 
   858 lemma singleton_iff: "(b : {a}) = (b = a)"
   859   by blast
   860 
   861 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   862   by blast
   863 
   864 lemma singleton_insert_inj_eq [iff,noatp]:
   865      "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   866   by blast
   867 
   868 lemma singleton_insert_inj_eq' [iff,noatp]:
   869      "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   870   by blast
   871 
   872 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   873   by fast
   874 
   875 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   876   by blast
   877 
   878 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   879   by blast
   880 
   881 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   882   by blast
   883 
   884 lemma doubleton_eq_iff: "({a,b} = {c,d}) = (a=c & b=d | a=d & b=c)"
   885   by (blast elim: equalityE)
   886 
   887 
   888 subsubsection {* Unions of families *}
   889 
   890 text {*
   891   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   892 *}
   893 
   894 declare UNION_def [noatp]
   895 
   896 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   897   by (unfold UNION_def) blast
   898 
   899 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   900   -- {* The order of the premises presupposes that @{term A} is rigid;
   901     @{term b} may be flexible. *}
   902   by auto
   903 
   904 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   905   by (unfold UNION_def) blast
   906 
   907 lemma UN_cong [cong]:
   908     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   909   by (simp add: UNION_def)
   910 
   911 lemma strong_UN_cong:
   912     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   913   by (simp add: UNION_def simp_implies_def)
   914 
   915 
   916 subsubsection {* Intersections of families *}
   917 
   918 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   919 
   920 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   921   by (unfold INTER_def) blast
   922 
   923 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   924   by (unfold INTER_def) blast
   925 
   926 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   927   by auto
   928 
   929 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   930   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   931   by (unfold INTER_def) blast
   932 
   933 lemma INT_cong [cong]:
   934     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   935   by (simp add: INTER_def)
   936 
   937 
   938 subsubsection {* Union *}
   939 
   940 lemma Union_iff [simp,noatp]: "(A : Union C) = (EX X:C. A:X)"
   941   by (unfold Union_def) blast
   942 
   943 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   944   -- {* The order of the premises presupposes that @{term C} is rigid;
   945     @{term A} may be flexible. *}
   946   by auto
   947 
   948 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   949   by (unfold Union_def) blast
   950 
   951 
   952 subsubsection {* Inter *}
   953 
   954 lemma Inter_iff [simp,noatp]: "(A : Inter C) = (ALL X:C. A:X)"
   955   by (unfold Inter_def) blast
   956 
   957 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   958   by (simp add: Inter_def)
   959 
   960 text {*
   961   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   962   contains @{term A} as an element, but @{prop "A:X"} can hold when
   963   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   964 *}
   965 
   966 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   967   by auto
   968 
   969 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   970   -- {* ``Classical'' elimination rule -- does not require proving
   971     @{prop "X:C"}. *}
   972   by (unfold Inter_def) blast
   973 
   974 text {*
   975   \medskip Image of a set under a function.  Frequently @{term b} does
   976   not have the syntactic form of @{term "f x"}.
   977 *}
   978 
   979 declare image_def [noatp]
   980 
   981 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   982   by (unfold image_def) blast
   983 
   984 lemma imageI: "x : A ==> f x : f ` A"
   985   by (rule image_eqI) (rule refl)
   986 
   987 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   988   -- {* This version's more effective when we already have the
   989     required @{term x}. *}
   990   by (unfold image_def) blast
   991 
   992 lemma imageE [elim!]:
   993   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   994   -- {* The eta-expansion gives variable-name preservation. *}
   995   by (unfold image_def) blast
   996 
   997 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   998   by blast
   999 
  1000 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
  1001   by blast
  1002 
  1003 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
  1004   by blast
  1005 
  1006 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
  1007   -- {* This rewrite rule would confuse users if made default. *}
  1008   by blast
  1009 
  1010 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
  1011   apply safe
  1012    prefer 2 apply fast
  1013   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
  1014   done
  1015 
  1016 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
  1017   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
  1018     @{text hypsubst}, but breaks too many existing proofs. *}
  1019   by blast
  1020 
  1021 text {*
  1022   \medskip Range of a function -- just a translation for image!
  1023 *}
  1024 
  1025 lemma range_eqI: "b = f x ==> b \<in> range f"
  1026   by simp
  1027 
  1028 lemma rangeI: "f x \<in> range f"
  1029   by simp
  1030 
  1031 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
  1032   by blast
  1033 
  1034 
  1035 subsubsection {* Set reasoning tools *}
  1036 
  1037 text{* Elimination of @{text"{x. \<dots> & x=t & \<dots>}"}. *}
  1038 
  1039 lemma singleton_conj_conv[simp]: "{x. x=a & P x} = (if P a then {a} else {})"
  1040 by auto
  1041 
  1042 lemma singleton_conj_conv2[simp]: "{x. a=x & P x} = (if P a then {a} else {})"
  1043 by auto
  1044 
  1045 ML{*
  1046   local
  1047     val Coll_perm_tac = rtac @{thm Collect_cong} 1 THEN rtac @{thm iffI} 1 THEN
  1048     ALLGOALS(EVERY'[REPEAT_DETERM o (etac @{thm conjE}),
  1049                     DEPTH_SOLVE_1 o (ares_tac [@{thm conjI}])])
  1050   in
  1051     val defColl_regroup = Simplifier.simproc (the_context ())
  1052       "defined Collect" ["{x. P x & Q x}"]
  1053       (Quantifier1.rearrange_Coll Coll_perm_tac)
  1054   end;
  1055 
  1056   Addsimprocs [defColl_regroup];
  1057 
  1058 *}
  1059 
  1060 text {*
  1061   Rewrite rules for boolean case-splitting: faster than @{text
  1062   "split_if [split]"}.
  1063 *}
  1064 
  1065 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
  1066   by (rule split_if)
  1067 
  1068 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
  1069   by (rule split_if)
  1070 
  1071 text {*
  1072   Split ifs on either side of the membership relation.  Not for @{text
  1073   "[simp]"} -- can cause goals to blow up!
  1074 *}
  1075 
  1076 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
  1077   by (rule split_if)
  1078 
  1079 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
  1080   by (rule split_if [where P="%S. a : S"])
  1081 
  1082 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
  1083 
  1084 (*Would like to add these, but the existing code only searches for the
  1085   outer-level constant, which in this case is just "op :"; we instead need
  1086   to use term-nets to associate patterns with rules.  Also, if a rule fails to
  1087   apply, then the formula should be kept.
  1088   [("HOL.uminus", Compl_iff RS iffD1), ("HOL.minus", [Diff_iff RS iffD1]),
  1089    ("Int", [IntD1,IntD2]),
  1090    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
  1091  *)
  1092 
  1093 ML {*
  1094   val mksimps_pairs = [(@{const_name Ball}, @{thms bspec})] @ mksimps_pairs;
  1095 *}
  1096 declaration {* fn _ =>
  1097   Simplifier.map_ss (fn ss => ss setmksimps (mksimps mksimps_pairs))
  1098 *}
  1099 
  1100 
  1101 subsubsection {* The ``proper subset'' relation *}
  1102 
  1103 lemma psubsetI [intro!,noatp]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
  1104   by (unfold less_le) blast
  1105 
  1106 lemma psubsetE [elim!,noatp]: 
  1107     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
  1108   by (unfold less_le) blast
  1109 
  1110 lemma psubset_insert_iff:
  1111   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
  1112   by (auto simp add: less_le subset_insert_iff)
  1113 
  1114 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
  1115   by (simp only: less_le)
  1116 
  1117 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
  1118   by (simp add: psubset_eq)
  1119 
  1120 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
  1121 apply (unfold less_le)
  1122 apply (auto dest: subset_antisym)
  1123 done
  1124 
  1125 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
  1126 apply (unfold less_le)
  1127 apply (auto dest: subsetD)
  1128 done
  1129 
  1130 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
  1131   by (auto simp add: psubset_eq)
  1132 
  1133 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
  1134   by (auto simp add: psubset_eq)
  1135 
  1136 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
  1137   by (unfold less_le) blast
  1138 
  1139 lemma atomize_ball:
  1140     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
  1141   by (simp only: Ball_def atomize_all atomize_imp)
  1142 
  1143 lemmas [symmetric, rulify] = atomize_ball
  1144   and [symmetric, defn] = atomize_ball
  1145 
  1146 
  1147 subsection {* Further set-theory lemmas *}
  1148 
  1149 subsubsection {* Derived rules involving subsets. *}
  1150 
  1151 text {* @{text insert}. *}
  1152 
  1153 lemma subset_insertI: "B \<subseteq> insert a B"
  1154   by (rule subsetI) (erule insertI2)
  1155 
  1156 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
  1157   by blast
  1158 
  1159 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
  1160   by blast
  1161 
  1162 
  1163 text {* \medskip Big Union -- least upper bound of a set. *}
  1164 
  1165 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
  1166   by (iprover intro: subsetI UnionI)
  1167 
  1168 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
  1169   by (iprover intro: subsetI elim: UnionE dest: subsetD)
  1170 
  1171 
  1172 text {* \medskip General union. *}
  1173 
  1174 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1175   by blast
  1176 
  1177 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
  1178   by (iprover intro: subsetI elim: UN_E dest: subsetD)
  1179 
  1180 
  1181 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
  1182 
  1183 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
  1184   by blast
  1185 
  1186 lemma Inter_subset:
  1187   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
  1188   by blast
  1189 
  1190 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
  1191   by (iprover intro: InterI subsetI dest: subsetD)
  1192 
  1193 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
  1194   by blast
  1195 
  1196 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
  1197   by (iprover intro: INT_I subsetI dest: subsetD)
  1198 
  1199 
  1200 text {* \medskip Finite Union -- the least upper bound of two sets. *}
  1201 
  1202 lemma Un_upper1: "A \<subseteq> A \<union> B"
  1203   by blast
  1204 
  1205 lemma Un_upper2: "B \<subseteq> A \<union> B"
  1206   by blast
  1207 
  1208 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
  1209   by blast
  1210 
  1211 
  1212 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
  1213 
  1214 lemma Int_lower1: "A \<inter> B \<subseteq> A"
  1215   by blast
  1216 
  1217 lemma Int_lower2: "A \<inter> B \<subseteq> B"
  1218   by blast
  1219 
  1220 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
  1221   by blast
  1222 
  1223 
  1224 text {* \medskip Set difference. *}
  1225 
  1226 lemma Diff_subset: "A - B \<subseteq> A"
  1227   by blast
  1228 
  1229 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
  1230 by blast
  1231 
  1232 
  1233 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1234 
  1235 text {* @{text "{}"}. *}
  1236 
  1237 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1238   -- {* supersedes @{text "Collect_False_empty"} *}
  1239   by auto
  1240 
  1241 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1242   by blast
  1243 
  1244 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1245   by (unfold less_le) blast
  1246 
  1247 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1248 by blast
  1249 
  1250 lemma empty_Collect_eq [simp]: "({} = Collect P) = (\<forall>x. \<not> P x)"
  1251 by blast
  1252 
  1253 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1254   by blast
  1255 
  1256 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1257   by blast
  1258 
  1259 lemma Collect_imp_eq: "{x. P x --> Q x} = -{x. P x} \<union> {x. Q x}"
  1260   by blast
  1261 
  1262 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1263   by blast
  1264 
  1265 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1266   by blast
  1267 
  1268 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1269   by blast
  1270 
  1271 lemma Collect_ex_eq [noatp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1272   by blast
  1273 
  1274 lemma Collect_bex_eq [noatp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1275   by blast
  1276 
  1277 
  1278 text {* \medskip @{text insert}. *}
  1279 
  1280 lemma insert_is_Un: "insert a A = {a} Un A"
  1281   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1282   by blast
  1283 
  1284 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1285   by blast
  1286 
  1287 lemmas empty_not_insert = insert_not_empty [symmetric, standard]
  1288 declare empty_not_insert [simp]
  1289 
  1290 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1291   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1292   -- {* with \emph{quadratic} running time *}
  1293   by blast
  1294 
  1295 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1296   by blast
  1297 
  1298 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1299   by blast
  1300 
  1301 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1302   by blast
  1303 
  1304 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1305   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1306   apply (rule_tac x = "A - {a}" in exI, blast)
  1307   done
  1308 
  1309 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1310   by auto
  1311 
  1312 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1313   by blast
  1314 
  1315 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1316   by blast
  1317 
  1318 lemma insert_disjoint [simp,noatp]:
  1319  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1320  "({} = insert a A \<inter> B) = (a \<notin> B \<and> {} = A \<inter> B)"
  1321   by auto
  1322 
  1323 lemma disjoint_insert [simp,noatp]:
  1324  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1325  "({} = A \<inter> insert b B) = (b \<notin> A \<and> {} = A \<inter> B)"
  1326   by auto
  1327 
  1328 text {* \medskip @{text image}. *}
  1329 
  1330 lemma image_empty [simp]: "f`{} = {}"
  1331   by blast
  1332 
  1333 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1334   by blast
  1335 
  1336 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1337   by auto
  1338 
  1339 lemma image_constant_conv: "(%x. c) ` A = (if A = {} then {} else {c})"
  1340 by auto
  1341 
  1342 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1343   by blast
  1344 
  1345 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1346   by blast
  1347 
  1348 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1349   by blast
  1350 
  1351 
  1352 lemma image_Collect [noatp]: "f ` {x. P x} = {f x | x. P x}"
  1353   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS,
  1354       with its implicit quantifier and conjunction.  Also image enjoys better
  1355       equational properties than does the RHS. *}
  1356   by blast
  1357 
  1358 lemma if_image_distrib [simp]:
  1359   "(\<lambda>x. if P x then f x else g x) ` S
  1360     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1361   by (auto simp add: image_def)
  1362 
  1363 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1364   by (simp add: image_def)
  1365 
  1366 
  1367 text {* \medskip @{text range}. *}
  1368 
  1369 lemma full_SetCompr_eq [noatp]: "{u. \<exists>x. u = f x} = range f"
  1370   by auto
  1371 
  1372 lemma range_composition: "range (\<lambda>x. f (g x)) = f`range g"
  1373 by (subst image_image, simp)
  1374 
  1375 
  1376 text {* \medskip @{text Int} *}
  1377 
  1378 lemma Int_absorb [simp]: "A \<inter> A = A"
  1379   by blast
  1380 
  1381 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1382   by blast
  1383 
  1384 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1385   by blast
  1386 
  1387 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1388   by blast
  1389 
  1390 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1391   by blast
  1392 
  1393 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1394   -- {* Intersection is an AC-operator *}
  1395 
  1396 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1397   by blast
  1398 
  1399 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1400   by blast
  1401 
  1402 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1403   by blast
  1404 
  1405 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1406   by blast
  1407 
  1408 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1409   by blast
  1410 
  1411 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1412   by blast
  1413 
  1414 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1415   by blast
  1416 
  1417 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1418   by blast
  1419 
  1420 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1421   by blast
  1422 
  1423 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1424   by blast
  1425 
  1426 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1427   by blast
  1428 
  1429 lemma Int_UNIV [simp,noatp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1430   by blast
  1431 
  1432 lemma Int_subset_iff [simp]: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1433   by blast
  1434 
  1435 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1436   by blast
  1437 
  1438 
  1439 text {* \medskip @{text Un}. *}
  1440 
  1441 lemma Un_absorb [simp]: "A \<union> A = A"
  1442   by blast
  1443 
  1444 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1445   by blast
  1446 
  1447 lemma Un_commute: "A \<union> B = B \<union> A"
  1448   by blast
  1449 
  1450 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1451   by blast
  1452 
  1453 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1454   by blast
  1455 
  1456 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1457   -- {* Union is an AC-operator *}
  1458 
  1459 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1460   by blast
  1461 
  1462 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1463   by blast
  1464 
  1465 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1466   by blast
  1467 
  1468 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1469   by blast
  1470 
  1471 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1472   by blast
  1473 
  1474 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1475   by blast
  1476 
  1477 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1478   by blast
  1479 
  1480 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1481   by blast
  1482 
  1483 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1484   by blast
  1485 
  1486 lemma Int_insert_left:
  1487     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1488   by auto
  1489 
  1490 lemma Int_insert_right:
  1491     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1492   by auto
  1493 
  1494 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1495   by blast
  1496 
  1497 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1498   by blast
  1499 
  1500 lemma Un_Int_crazy:
  1501     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1502   by blast
  1503 
  1504 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1505   by blast
  1506 
  1507 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1508   by blast
  1509 
  1510 lemma Un_subset_iff [simp]: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1511   by blast
  1512 
  1513 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1514   by blast
  1515 
  1516 lemma Diff_Int2: "A \<inter> C - B \<inter> C = A \<inter> C - B"
  1517   by blast
  1518 
  1519 
  1520 text {* \medskip Set complement *}
  1521 
  1522 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1523   by blast
  1524 
  1525 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1526   by blast
  1527 
  1528 lemma Compl_partition: "A \<union> -A = UNIV"
  1529   by blast
  1530 
  1531 lemma Compl_partition2: "-A \<union> A = UNIV"
  1532   by blast
  1533 
  1534 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1535   by blast
  1536 
  1537 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1538   by blast
  1539 
  1540 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1541   by blast
  1542 
  1543 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1544   by blast
  1545 
  1546 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1547   by blast
  1548 
  1549 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1550   by blast
  1551 
  1552 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1553   -- {* Halmos, Naive Set Theory, page 16. *}
  1554   by blast
  1555 
  1556 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1557   by blast
  1558 
  1559 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1560   by blast
  1561 
  1562 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1563   by blast
  1564 
  1565 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1566   by blast
  1567 
  1568 
  1569 text {* \medskip @{text Union}. *}
  1570 
  1571 lemma Union_empty [simp]: "Union({}) = {}"
  1572   by blast
  1573 
  1574 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1575   by blast
  1576 
  1577 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1578   by blast
  1579 
  1580 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1581   by blast
  1582 
  1583 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1584   by blast
  1585 
  1586 lemma Union_empty_conv [simp,noatp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1587   by blast
  1588 
  1589 lemma empty_Union_conv [simp,noatp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1590   by blast
  1591 
  1592 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1593   by blast
  1594 
  1595 
  1596 text {* \medskip @{text Inter}. *}
  1597 
  1598 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1599   by blast
  1600 
  1601 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1602   by blast
  1603 
  1604 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1605   by blast
  1606 
  1607 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1608   by blast
  1609 
  1610 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1611   by blast
  1612 
  1613 lemma Inter_UNIV_conv [simp,noatp]:
  1614   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1615   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1616   by blast+
  1617 
  1618 
  1619 text {*
  1620   \medskip @{text UN} and @{text INT}.
  1621 
  1622   Basic identities: *}
  1623 
  1624 lemma UN_empty [simp,noatp]: "(\<Union>x\<in>{}. B x) = {}"
  1625   by blast
  1626 
  1627 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1628   by blast
  1629 
  1630 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1631   by blast
  1632 
  1633 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1634   by auto
  1635 
  1636 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1637   by blast
  1638 
  1639 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1640   by blast
  1641 
  1642 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1643   by blast
  1644 
  1645 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1646   by blast
  1647 
  1648 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1649   by blast
  1650 
  1651 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1652   by blast
  1653 
  1654 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1655   by blast
  1656 
  1657 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1658   by blast
  1659 
  1660 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1661   by blast
  1662 
  1663 lemma INT_insert_distrib:
  1664     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1665   by blast
  1666 
  1667 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1668   by blast
  1669 
  1670 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1671   by blast
  1672 
  1673 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1674   by blast
  1675 
  1676 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1677   by auto
  1678 
  1679 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1680   by auto
  1681 
  1682 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1683   by blast
  1684 
  1685 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1686   -- {* Look: it has an \emph{existential} quantifier *}
  1687   by blast
  1688 
  1689 lemma UNION_empty_conv[simp]:
  1690   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1691   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1692 by blast+
  1693 
  1694 lemma INTER_UNIV_conv[simp]:
  1695  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1696  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1697 by blast+
  1698 
  1699 
  1700 text {* \medskip Distributive laws: *}
  1701 
  1702 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1703   by blast
  1704 
  1705 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1706   by blast
  1707 
  1708 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1709   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1710   -- {* Union of a family of unions *}
  1711   by blast
  1712 
  1713 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1714   -- {* Equivalent version *}
  1715   by blast
  1716 
  1717 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1718   by blast
  1719 
  1720 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1721   by blast
  1722 
  1723 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1724   -- {* Equivalent version *}
  1725   by blast
  1726 
  1727 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1728   -- {* Halmos, Naive Set Theory, page 35. *}
  1729   by blast
  1730 
  1731 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1732   by blast
  1733 
  1734 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1735   by blast
  1736 
  1737 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1738   by blast
  1739 
  1740 
  1741 text {* \medskip Bounded quantifiers.
  1742 
  1743   The following are not added to the default simpset because
  1744   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1745 
  1746 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1747   by blast
  1748 
  1749 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1750   by blast
  1751 
  1752 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1753   by blast
  1754 
  1755 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1756   by blast
  1757 
  1758 
  1759 text {* \medskip Set difference. *}
  1760 
  1761 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1762   by blast
  1763 
  1764 lemma Diff_eq_empty_iff [simp,noatp]: "(A - B = {}) = (A \<subseteq> B)"
  1765   by blast
  1766 
  1767 lemma Diff_cancel [simp]: "A - A = {}"
  1768   by blast
  1769 
  1770 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1771 by blast
  1772 
  1773 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1774   by (blast elim: equalityE)
  1775 
  1776 lemma empty_Diff [simp]: "{} - A = {}"
  1777   by blast
  1778 
  1779 lemma Diff_empty [simp]: "A - {} = A"
  1780   by blast
  1781 
  1782 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1783   by blast
  1784 
  1785 lemma Diff_insert0 [simp,noatp]: "x \<notin> A ==> A - insert x B = A - B"
  1786   by blast
  1787 
  1788 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1789   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1790   by blast
  1791 
  1792 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1793   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1794   by blast
  1795 
  1796 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1797   by auto
  1798 
  1799 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1800   by blast
  1801 
  1802 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1803 by blast
  1804 
  1805 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1806   by blast
  1807 
  1808 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1809   by auto
  1810 
  1811 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1812   by blast
  1813 
  1814 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1815   by blast
  1816 
  1817 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1818   by blast
  1819 
  1820 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1821   by blast
  1822 
  1823 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1824   by blast
  1825 
  1826 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1827   by blast
  1828 
  1829 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1830   by blast
  1831 
  1832 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1833   by blast
  1834 
  1835 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1836   by blast
  1837 
  1838 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1839   by blast
  1840 
  1841 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1842   by blast
  1843 
  1844 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1845   by auto
  1846 
  1847 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1848   by blast
  1849 
  1850 
  1851 text {* \medskip Quantification over type @{typ bool}. *}
  1852 
  1853 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1854   by (cases x) auto
  1855 
  1856 lemma all_bool_eq: "(\<forall>b. P b) \<longleftrightarrow> P True \<and> P False"
  1857   by (auto intro: bool_induct)
  1858 
  1859 lemma bool_contrapos: "P x \<Longrightarrow> \<not> P False \<Longrightarrow> P True"
  1860   by (cases x) auto
  1861 
  1862 lemma ex_bool_eq: "(\<exists>b. P b) \<longleftrightarrow> P True \<or> P False"
  1863   by (auto intro: bool_contrapos)
  1864 
  1865 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1866   by (auto simp add: split_if_mem2)
  1867 
  1868 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1869   by (auto intro: bool_contrapos)
  1870 
  1871 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1872   by (auto intro: bool_induct)
  1873 
  1874 text {* \medskip @{text Pow} *}
  1875 
  1876 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1877   by (auto simp add: Pow_def)
  1878 
  1879 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1880   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1881 
  1882 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1883   by (blast intro: exI [where ?x = "- u", standard])
  1884 
  1885 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1886   by blast
  1887 
  1888 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1889   by blast
  1890 
  1891 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1892   by blast
  1893 
  1894 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1895   by blast
  1896 
  1897 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1898   by blast
  1899 
  1900 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1901   by blast
  1902 
  1903 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1904   by blast
  1905 
  1906 
  1907 text {* \medskip Miscellany. *}
  1908 
  1909 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1910   by blast
  1911 
  1912 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1913   by blast
  1914 
  1915 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1916   by (unfold less_le) blast
  1917 
  1918 lemma all_not_in_conv [simp]: "(\<forall>x. x \<notin> A) = (A = {})"
  1919   by blast
  1920 
  1921 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1922   by blast
  1923 
  1924 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1925   by iprover
  1926 
  1927 
  1928 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1929            and Intersections. *}
  1930 
  1931 lemma UN_simps [simp]:
  1932   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1933   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1934   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1935   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1936   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1937   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1938   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1939   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1940   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1941   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1942   by auto
  1943 
  1944 lemma INT_simps [simp]:
  1945   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1946   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1947   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1948   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1949   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1950   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1951   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1952   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1953   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1954   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1955   by auto
  1956 
  1957 lemma ball_simps [simp,noatp]:
  1958   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1959   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1960   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1961   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1962   "!!P. (ALL x:{}. P x) = True"
  1963   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1964   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1965   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1966   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1967   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1968   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1969   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1970   by auto
  1971 
  1972 lemma bex_simps [simp,noatp]:
  1973   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1974   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1975   "!!P. (EX x:{}. P x) = False"
  1976   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1977   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1978   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1979   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1980   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1981   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1982   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1983   by auto
  1984 
  1985 lemma ball_conj_distrib:
  1986   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1987   by blast
  1988 
  1989 lemma bex_disj_distrib:
  1990   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1991   by blast
  1992 
  1993 
  1994 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1995 
  1996 lemma UN_extend_simps:
  1997   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1998   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1999   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  2000   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  2001   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  2002   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  2003   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  2004   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  2005   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  2006   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  2007   by auto
  2008 
  2009 lemma INT_extend_simps:
  2010   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  2011   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  2012   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  2013   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  2014   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  2015   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  2016   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  2017   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  2018   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  2019   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  2020   by auto
  2021 
  2022 
  2023 subsubsection {* Monotonicity of various operations *}
  2024 
  2025 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  2026   by blast
  2027 
  2028 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  2029   by blast
  2030 
  2031 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  2032   by blast
  2033 
  2034 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  2035   by blast
  2036 
  2037 lemma UN_mono:
  2038   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  2039     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  2040   by (blast dest: subsetD)
  2041 
  2042 lemma INT_anti_mono:
  2043   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  2044     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  2045   -- {* The last inclusion is POSITIVE! *}
  2046   by (blast dest: subsetD)
  2047 
  2048 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  2049   by blast
  2050 
  2051 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  2052   by blast
  2053 
  2054 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  2055   by blast
  2056 
  2057 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  2058   by blast
  2059 
  2060 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  2061   by blast
  2062 
  2063 text {* \medskip Monotonicity of implications. *}
  2064 
  2065 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  2066   apply (rule impI)
  2067   apply (erule subsetD, assumption)
  2068   done
  2069 
  2070 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  2071   by iprover
  2072 
  2073 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  2074   by iprover
  2075 
  2076 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  2077   by iprover
  2078 
  2079 lemma imp_refl: "P --> P" ..
  2080 
  2081 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  2082   by iprover
  2083 
  2084 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  2085   by iprover
  2086 
  2087 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  2088   by blast
  2089 
  2090 lemma Int_Collect_mono:
  2091     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  2092   by blast
  2093 
  2094 lemmas basic_monos =
  2095   subset_refl imp_refl disj_mono conj_mono
  2096   ex_mono Collect_mono in_mono
  2097 
  2098 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  2099   by iprover
  2100 
  2101 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  2102   by iprover
  2103 
  2104 
  2105 subsection {* Inverse image of a function *}
  2106 
  2107 constdefs
  2108   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  2109   [code del]: "f -` B == {x. f x : B}"
  2110 
  2111 
  2112 subsubsection {* Basic rules *}
  2113 
  2114 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  2115   by (unfold vimage_def) blast
  2116 
  2117 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  2118   by simp
  2119 
  2120 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  2121   by (unfold vimage_def) blast
  2122 
  2123 lemma vimageI2: "f a : A ==> a : f -` A"
  2124   by (unfold vimage_def) fast
  2125 
  2126 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  2127   by (unfold vimage_def) blast
  2128 
  2129 lemma vimageD: "a : f -` A ==> f a : A"
  2130   by (unfold vimage_def) fast
  2131 
  2132 
  2133 subsubsection {* Equations *}
  2134 
  2135 lemma vimage_empty [simp]: "f -` {} = {}"
  2136   by blast
  2137 
  2138 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  2139   by blast
  2140 
  2141 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  2142   by blast
  2143 
  2144 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  2145   by fast
  2146 
  2147 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  2148   by blast
  2149 
  2150 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  2151   by blast
  2152 
  2153 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  2154   by blast
  2155 
  2156 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  2157   by blast
  2158 
  2159 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  2160   by blast
  2161 
  2162 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  2163   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  2164   by blast
  2165 
  2166 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  2167   by blast
  2168 
  2169 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  2170   by blast
  2171 
  2172 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  2173   -- {* NOT suitable for rewriting *}
  2174   by blast
  2175 
  2176 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  2177   -- {* monotonicity *}
  2178   by blast
  2179 
  2180 lemma vimage_image_eq [noatp]: "f -` (f ` A) = {y. EX x:A. f x = f y}"
  2181 by (blast intro: sym)
  2182 
  2183 lemma image_vimage_subset: "f ` (f -` A) <= A"
  2184 by blast
  2185 
  2186 lemma image_vimage_eq [simp]: "f ` (f -` A) = A Int range f"
  2187 by blast
  2188 
  2189 lemma image_Int_subset: "f`(A Int B) <= f`A Int f`B"
  2190 by blast
  2191 
  2192 lemma image_diff_subset: "f`A - f`B <= f`(A - B)"
  2193 by blast
  2194 
  2195 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
  2196 by blast
  2197 
  2198 
  2199 subsection {* Getting the Contents of a Singleton Set *}
  2200 
  2201 definition contents :: "'a set \<Rightarrow> 'a" where
  2202   [code del]: "contents X = (THE x. X = {x})"
  2203 
  2204 lemma contents_eq [simp]: "contents {x} = x"
  2205   by (simp add: contents_def)
  2206 
  2207 
  2208 subsection {* Transitivity rules for calculational reasoning *}
  2209 
  2210 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  2211   by (rule subsetD)
  2212 
  2213 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  2214   by (rule subsetD)
  2215 
  2216 lemmas basic_trans_rules [trans] =
  2217   order_trans_rules set_rev_mp set_mp
  2218 
  2219 
  2220 subsection {* Least value operator *}
  2221 
  2222 lemma Least_mono:
  2223   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  2224     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  2225     -- {* Courtesy of Stephan Merz *}
  2226   apply clarify
  2227   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  2228   apply (rule LeastI2_order)
  2229   apply (auto elim: monoD intro!: order_antisym)
  2230   done
  2231 
  2232 
  2233 subsection {* Rudimentary code generation *}
  2234 
  2235 lemma empty_code [code]: "{} x \<longleftrightarrow> False"
  2236   unfolding empty_def Collect_def ..
  2237 
  2238 lemma UNIV_code [code]: "UNIV x \<longleftrightarrow> True"
  2239   unfolding UNIV_def Collect_def ..
  2240 
  2241 lemma insert_code [code]: "insert y A x \<longleftrightarrow> y = x \<or> A x"
  2242   unfolding insert_def Collect_def mem_def Un_def by auto
  2243 
  2244 lemma inter_code [code]: "(A \<inter> B) x \<longleftrightarrow> A x \<and> B x"
  2245   unfolding Int_def Collect_def mem_def ..
  2246 
  2247 lemma union_code [code]: "(A \<union> B) x \<longleftrightarrow> A x \<or> B x"
  2248   unfolding Un_def Collect_def mem_def ..
  2249 
  2250 lemma vimage_code [code]: "(f -` A) x = A (f x)"
  2251   unfolding vimage_def Collect_def mem_def ..
  2252 
  2253 
  2254 subsection {* Complete lattices *}
  2255 
  2256 notation
  2257   less_eq  (infix "\<sqsubseteq>" 50) and
  2258   less (infix "\<sqsubset>" 50) and
  2259   inf  (infixl "\<sqinter>" 70) and
  2260   sup  (infixl "\<squnion>" 65)
  2261 
  2262 class complete_lattice = lattice + bot + top +
  2263   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
  2264     and Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
  2265   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
  2266      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
  2267   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
  2268      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
  2269 begin
  2270 
  2271 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<le> a}"
  2272   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
  2273 
  2274 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<le> b}"
  2275   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
  2276 
  2277 lemma Inf_Univ: "\<Sqinter>UNIV = \<Squnion>{}"
  2278   unfolding Sup_Inf by auto
  2279 
  2280 lemma Sup_Univ: "\<Squnion>UNIV = \<Sqinter>{}"
  2281   unfolding Inf_Sup by auto
  2282 
  2283 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
  2284   by (auto intro: antisym Inf_greatest Inf_lower)
  2285 
  2286 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
  2287   by (auto intro: antisym Sup_least Sup_upper)
  2288 
  2289 lemma Inf_singleton [simp]:
  2290   "\<Sqinter>{a} = a"
  2291   by (auto intro: antisym Inf_lower Inf_greatest)
  2292 
  2293 lemma Sup_singleton [simp]:
  2294   "\<Squnion>{a} = a"
  2295   by (auto intro: antisym Sup_upper Sup_least)
  2296 
  2297 lemma Inf_insert_simp:
  2298   "\<Sqinter>insert a A = (if A = {} then a else a \<sqinter> \<Sqinter>A)"
  2299   by (cases "A = {}") (simp_all, simp add: Inf_insert)
  2300 
  2301 lemma Sup_insert_simp:
  2302   "\<Squnion>insert a A = (if A = {} then a else a \<squnion> \<Squnion>A)"
  2303   by (cases "A = {}") (simp_all, simp add: Sup_insert)
  2304 
  2305 lemma Inf_binary:
  2306   "\<Sqinter>{a, b} = a \<sqinter> b"
  2307   by (simp add: Inf_insert_simp)
  2308 
  2309 lemma Sup_binary:
  2310   "\<Squnion>{a, b} = a \<squnion> b"
  2311   by (simp add: Sup_insert_simp)
  2312 
  2313 lemma bot_def:
  2314   "bot = \<Squnion>{}"
  2315   by (auto intro: antisym Sup_least)
  2316 
  2317 lemma top_def:
  2318   "top = \<Sqinter>{}"
  2319   by (auto intro: antisym Inf_greatest)
  2320 
  2321 lemma sup_bot [simp]:
  2322   "x \<squnion> bot = x"
  2323   using bot_least [of x] by (simp add: le_iff_sup sup_commute)
  2324 
  2325 lemma inf_top [simp]:
  2326   "x \<sqinter> top = x"
  2327   using top_greatest [of x] by (simp add: le_iff_inf inf_commute)
  2328 
  2329 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
  2330   "SUPR A f == \<Squnion> (f ` A)"
  2331 
  2332 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
  2333   "INFI A f == \<Sqinter> (f ` A)"
  2334 
  2335 end
  2336 
  2337 syntax
  2338   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
  2339   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 10] 10)
  2340   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
  2341   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 10] 10)
  2342 
  2343 translations
  2344   "SUP x y. B"   == "SUP x. SUP y. B"
  2345   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
  2346   "SUP x. B"     == "SUP x:CONST UNIV. B"
  2347   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
  2348   "INF x y. B"   == "INF x. INF y. B"
  2349   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
  2350   "INF x. B"     == "INF x:CONST UNIV. B"
  2351   "INF x:A. B"   == "CONST INFI A (%x. B)"
  2352 
  2353 (* To avoid eta-contraction of body: *)
  2354 print_translation {*
  2355 let
  2356   fun btr' syn (A :: Abs abs :: ts) =
  2357     let val (x,t) = atomic_abs_tr' abs
  2358     in list_comb (Syntax.const syn $ x $ A $ t, ts) end
  2359   val const_syntax_name = Sign.const_syntax_name @{theory} o fst o dest_Const
  2360 in
  2361 [(const_syntax_name @{term SUPR}, btr' "_SUP"),(const_syntax_name @{term "INFI"}, btr' "_INF")]
  2362 end
  2363 *}
  2364 
  2365 context complete_lattice
  2366 begin
  2367 
  2368 lemma le_SUPI: "i : A \<Longrightarrow> M i \<le> (SUP i:A. M i)"
  2369   by (auto simp add: SUPR_def intro: Sup_upper)
  2370 
  2371 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<le> u) \<Longrightarrow> (SUP i:A. M i) \<le> u"
  2372   by (auto simp add: SUPR_def intro: Sup_least)
  2373 
  2374 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<le> M i"
  2375   by (auto simp add: INFI_def intro: Inf_lower)
  2376 
  2377 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<le> M i) \<Longrightarrow> u \<le> (INF i:A. M i)"
  2378   by (auto simp add: INFI_def intro: Inf_greatest)
  2379 
  2380 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
  2381   by (auto intro: antisym SUP_leI le_SUPI)
  2382 
  2383 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
  2384   by (auto intro: antisym INF_leI le_INFI)
  2385 
  2386 end
  2387 
  2388 
  2389 subsection {* Bool as complete lattice *}
  2390 
  2391 instantiation bool :: complete_lattice
  2392 begin
  2393 
  2394 definition
  2395   Inf_bool_def: "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
  2396 
  2397 definition
  2398   Sup_bool_def: "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
  2399 
  2400 instance
  2401   by intro_classes (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
  2402 
  2403 end
  2404 
  2405 lemma Inf_empty_bool [simp]:
  2406   "\<Sqinter>{}"
  2407   unfolding Inf_bool_def by auto
  2408 
  2409 lemma not_Sup_empty_bool [simp]:
  2410   "\<not> \<Squnion>{}"
  2411   unfolding Sup_bool_def by auto
  2412 
  2413 
  2414 subsection {* Fun as complete lattice *}
  2415 
  2416 instantiation "fun" :: (type, complete_lattice) complete_lattice
  2417 begin
  2418 
  2419 definition
  2420   Inf_fun_def [code del]: "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
  2421 
  2422 definition
  2423   Sup_fun_def [code del]: "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
  2424 
  2425 instance
  2426   by intro_classes
  2427     (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
  2428       intro: Inf_lower Sup_upper Inf_greatest Sup_least)
  2429 
  2430 end
  2431 
  2432 lemma Inf_empty_fun:
  2433   "\<Sqinter>{} = (\<lambda>_. \<Sqinter>{})"
  2434   by rule (auto simp add: Inf_fun_def)
  2435 
  2436 lemma Sup_empty_fun:
  2437   "\<Squnion>{} = (\<lambda>_. \<Squnion>{})"
  2438   by rule (auto simp add: Sup_fun_def)
  2439 
  2440 
  2441 subsection {* Set as lattice *}
  2442 
  2443 lemma inf_set_eq: "A \<sqinter> B = A \<inter> B"
  2444   apply (rule subset_antisym)
  2445   apply (rule Int_greatest)
  2446   apply (rule inf_le1)
  2447   apply (rule inf_le2)
  2448   apply (rule inf_greatest)
  2449   apply (rule Int_lower1)
  2450   apply (rule Int_lower2)
  2451   done
  2452 
  2453 lemma sup_set_eq: "A \<squnion> B = A \<union> B"
  2454   apply (rule subset_antisym)
  2455   apply (rule sup_least)
  2456   apply (rule Un_upper1)
  2457   apply (rule Un_upper2)
  2458   apply (rule Un_least)
  2459   apply (rule sup_ge1)
  2460   apply (rule sup_ge2)
  2461   done
  2462 
  2463 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
  2464   apply (fold inf_set_eq sup_set_eq)
  2465   apply (erule mono_inf)
  2466   done
  2467 
  2468 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
  2469   apply (fold inf_set_eq sup_set_eq)
  2470   apply (erule mono_sup)
  2471   done
  2472 
  2473 lemma Inf_set_eq: "\<Sqinter>S = \<Inter>S"
  2474   apply (rule subset_antisym)
  2475   apply (rule Inter_greatest)
  2476   apply (erule Inf_lower)
  2477   apply (rule Inf_greatest)
  2478   apply (erule Inter_lower)
  2479   done
  2480 
  2481 lemma Sup_set_eq: "\<Squnion>S = \<Union>S"
  2482   apply (rule subset_antisym)
  2483   apply (rule Sup_least)
  2484   apply (erule Union_upper)
  2485   apply (rule Union_least)
  2486   apply (erule Sup_upper)
  2487   done
  2488   
  2489 lemma top_set_eq: "top = UNIV"
  2490   by (iprover intro!: subset_antisym subset_UNIV top_greatest)
  2491 
  2492 lemma bot_set_eq: "bot = {}"
  2493   by (iprover intro!: subset_antisym empty_subsetI bot_least)
  2494 
  2495 no_notation
  2496   less_eq  (infix "\<sqsubseteq>" 50) and
  2497   less (infix "\<sqsubset>" 50) and
  2498   inf  (infixl "\<sqinter>" 70) and
  2499   sup  (infixl "\<squnion>" 65) and
  2500   Inf  ("\<Sqinter>_" [900] 900) and
  2501   Sup  ("\<Squnion>_" [900] 900)
  2502 
  2503 
  2504 subsection {* Misc theorem and ML bindings *}
  2505 
  2506 lemmas equalityI = subset_antisym
  2507 lemmas mem_simps =
  2508   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  2509   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  2510   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  2511 
  2512 ML {*
  2513 val Ball_def = @{thm Ball_def}
  2514 val Bex_def = @{thm Bex_def}
  2515 val CollectD = @{thm CollectD}
  2516 val CollectE = @{thm CollectE}
  2517 val CollectI = @{thm CollectI}
  2518 val Collect_conj_eq = @{thm Collect_conj_eq}
  2519 val Collect_mem_eq = @{thm Collect_mem_eq}
  2520 val IntD1 = @{thm IntD1}
  2521 val IntD2 = @{thm IntD2}
  2522 val IntE = @{thm IntE}
  2523 val IntI = @{thm IntI}
  2524 val Int_Collect = @{thm Int_Collect}
  2525 val UNIV_I = @{thm UNIV_I}
  2526 val UNIV_witness = @{thm UNIV_witness}
  2527 val UnE = @{thm UnE}
  2528 val UnI1 = @{thm UnI1}
  2529 val UnI2 = @{thm UnI2}
  2530 val ballE = @{thm ballE}
  2531 val ballI = @{thm ballI}
  2532 val bexCI = @{thm bexCI}
  2533 val bexE = @{thm bexE}
  2534 val bexI = @{thm bexI}
  2535 val bex_triv = @{thm bex_triv}
  2536 val bspec = @{thm bspec}
  2537 val contra_subsetD = @{thm contra_subsetD}
  2538 val distinct_lemma = @{thm distinct_lemma}
  2539 val eq_to_mono = @{thm eq_to_mono}
  2540 val eq_to_mono2 = @{thm eq_to_mono2}
  2541 val equalityCE = @{thm equalityCE}
  2542 val equalityD1 = @{thm equalityD1}
  2543 val equalityD2 = @{thm equalityD2}
  2544 val equalityE = @{thm equalityE}
  2545 val equalityI = @{thm equalityI}
  2546 val imageE = @{thm imageE}
  2547 val imageI = @{thm imageI}
  2548 val image_Un = @{thm image_Un}
  2549 val image_insert = @{thm image_insert}
  2550 val insert_commute = @{thm insert_commute}
  2551 val insert_iff = @{thm insert_iff}
  2552 val mem_Collect_eq = @{thm mem_Collect_eq}
  2553 val rangeE = @{thm rangeE}
  2554 val rangeI = @{thm rangeI}
  2555 val range_eqI = @{thm range_eqI}
  2556 val subsetCE = @{thm subsetCE}
  2557 val subsetD = @{thm subsetD}
  2558 val subsetI = @{thm subsetI}
  2559 val subset_refl = @{thm subset_refl}
  2560 val subset_trans = @{thm subset_trans}
  2561 val vimageD = @{thm vimageD}
  2562 val vimageE = @{thm vimageE}
  2563 val vimageI = @{thm vimageI}
  2564 val vimageI2 = @{thm vimageI2}
  2565 val vimage_Collect = @{thm vimage_Collect}
  2566 val vimage_Int = @{thm vimage_Int}
  2567 val vimage_Un = @{thm vimage_Un}
  2568 *}
  2569 
  2570 end