src/Pure/Isar/proof.ML
author wenzelm
Tue Feb 25 14:34:18 2014 +0100 (2014-02-25)
changeset 55742 a989bdaf8121
parent 55709 4e5a83a46ded
child 55765 ec7ca5388dea
permissions -rw-r--r--
modernized Method.check_name/check_source (with reports) vs. strict Method.the_method (without interning nor reports), e.g. relevant for semantic completion;
removed obsolete Method.Source_i;
proper context for global data;
tuned messages;
     1 (*  Title:      Pure/Isar/proof.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The Isar/VM proof language interpreter: maintains a structured flow of
     5 context elements, goals, refinements, and facts.
     6 *)
     7 
     8 signature PROOF =
     9 sig
    10   type context = Proof.context
    11   type method = Method.method
    12   type state
    13   val init: context -> state
    14   val level: state -> int
    15   val assert_bottom: bool -> state -> state
    16   val context_of: state -> context
    17   val theory_of: state -> theory
    18   val map_context: (context -> context) -> state -> state
    19   val map_context_result : (context -> 'a * context) -> state -> 'a * state
    20   val map_contexts: (context -> context) -> state -> state
    21   val propagate_ml_env: state -> state
    22   val bind_terms: (indexname * term option) list -> state -> state
    23   val put_thms: bool -> string * thm list option -> state -> state
    24   val the_facts: state -> thm list
    25   val the_fact: state -> thm
    26   val set_facts: thm list -> state -> state
    27   val reset_facts: state -> state
    28   val assert_forward: state -> state
    29   val assert_chain: state -> state
    30   val assert_forward_or_chain: state -> state
    31   val assert_backward: state -> state
    32   val assert_no_chain: state -> state
    33   val enter_forward: state -> state
    34   val goal_message: (unit -> Pretty.T) -> state -> state
    35   val pretty_goal_messages: state -> Pretty.T list
    36   val pretty_state: int -> state -> Pretty.T list
    37   val refine: Method.text -> state -> state Seq.seq
    38   val refine_end: Method.text -> state -> state Seq.seq
    39   val refine_insert: thm list -> state -> state
    40   val refine_goals: (context -> thm -> unit) -> context -> thm list -> state -> state Seq.seq
    41   val raw_goal: state -> {context: context, facts: thm list, goal: thm}
    42   val goal: state -> {context: context, facts: thm list, goal: thm}
    43   val simple_goal: state -> {context: context, goal: thm}
    44   val status_markup: state -> Markup.T
    45   val let_bind: (term list * term) list -> state -> state
    46   val let_bind_cmd: (string list * string) list -> state -> state
    47   val write: Syntax.mode -> (term * mixfix) list -> state -> state
    48   val write_cmd: Syntax.mode -> (string * mixfix) list -> state -> state
    49   val fix: (binding * typ option * mixfix) list -> state -> state
    50   val fix_cmd: (binding * string option * mixfix) list -> state -> state
    51   val assm: Assumption.export ->
    52     (Thm.binding * (term * term list) list) list -> state -> state
    53   val assm_cmd: Assumption.export ->
    54     (Attrib.binding * (string * string list) list) list -> state -> state
    55   val assume: (Thm.binding * (term * term list) list) list -> state -> state
    56   val assume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    57   val presume: (Thm.binding * (term * term list) list) list -> state -> state
    58   val presume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    59   val def: (Thm.binding * ((binding * mixfix) * (term * term list))) list -> state -> state
    60   val def_cmd: (Attrib.binding * ((binding * mixfix) * (string * string list))) list -> state -> state
    61   val chain: state -> state
    62   val chain_facts: thm list -> state -> state
    63   val note_thmss: (Thm.binding * (thm list * attribute list) list) list -> state -> state
    64   val note_thmss_cmd: (Attrib.binding * (Facts.ref * Attrib.src list) list) list -> state -> state
    65   val from_thmss: ((thm list * attribute list) list) list -> state -> state
    66   val from_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    67   val with_thmss: ((thm list * attribute list) list) list -> state -> state
    68   val with_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    69   val using: ((thm list * attribute list) list) list -> state -> state
    70   val using_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    71   val unfolding: ((thm list * attribute list) list) list -> state -> state
    72   val unfolding_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    73   val invoke_case: (string * Position.T) * binding option list * attribute list ->
    74     state -> state
    75   val invoke_case_cmd: (string * Position.T) * binding option list * Attrib.src list ->
    76     state -> state
    77   val begin_block: state -> state
    78   val next_block: state -> state
    79   val end_block: state -> state
    80   val begin_notepad: context -> state
    81   val end_notepad: state -> context
    82   val proof: Method.text option -> state -> state Seq.seq
    83   val proof_results: Method.text_range option -> state -> state Seq.result Seq.seq
    84   val defer: int -> state -> state
    85   val prefer: int -> state -> state
    86   val apply: Method.text -> state -> state Seq.seq
    87   val apply_end: Method.text -> state -> state Seq.seq
    88   val apply_results: Method.text_range -> state -> state Seq.result Seq.seq
    89   val apply_end_results: Method.text_range -> state -> state Seq.result Seq.seq
    90   val local_goal: (context -> ((string * string) * (string * thm list) list) -> unit) ->
    91     (context -> 'a -> attribute) ->
    92     ('b list -> context -> (term list list * (context -> context)) * context) ->
    93     string -> Method.text option -> (thm list list -> state -> state) ->
    94     ((binding * 'a list) * 'b) list -> state -> state
    95   val local_qed: Method.text_range option * bool -> state -> state
    96   val theorem: Method.text option -> (thm list list -> context -> context) ->
    97     (term * term list) list list -> context -> state
    98   val theorem_cmd: Method.text option -> (thm list list -> context -> context) ->
    99     (string * string list) list list -> context -> state
   100   val global_qed: Method.text_range option * bool -> state -> context
   101   val local_terminal_proof: Method.text_range * Method.text_range option -> state -> state
   102   val local_default_proof: state -> state
   103   val local_immediate_proof: state -> state
   104   val local_skip_proof: bool -> state -> state
   105   val local_done_proof: state -> state
   106   val global_terminal_proof: Method.text_range * Method.text_range option -> state -> context
   107   val global_default_proof: state -> context
   108   val global_immediate_proof: state -> context
   109   val global_skip_proof: bool -> state -> context
   110   val global_done_proof: state -> context
   111   val have: Method.text option -> (thm list list -> state -> state) ->
   112     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   113   val have_cmd: Method.text option -> (thm list list -> state -> state) ->
   114     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   115   val show: Method.text option -> (thm list list -> state -> state) ->
   116     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   117   val show_cmd: Method.text option -> (thm list list -> state -> state) ->
   118     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   119   val schematic_goal: state -> bool
   120   val is_relevant: state -> bool
   121   val future_proof: (state -> ('a * context) future) -> state -> 'a future * state
   122   val local_future_terminal_proof: Method.text_range * Method.text_range option -> bool ->
   123     state -> state
   124   val global_future_terminal_proof: Method.text_range * Method.text_range option -> bool ->
   125     state -> context
   126 end;
   127 
   128 structure Proof: PROOF =
   129 struct
   130 
   131 type context = Proof.context;
   132 type method = Method.method;
   133 
   134 
   135 (** proof state **)
   136 
   137 (* datatype state *)
   138 
   139 datatype mode = Forward | Chain | Backward;
   140 
   141 datatype state =
   142   State of node Stack.T
   143 and node =
   144   Node of
   145    {context: context,
   146     facts: thm list option,
   147     mode: mode,
   148     goal: goal option}
   149 and goal =
   150   Goal of
   151    {statement: (string * Position.T) * term list list * term,
   152       (*goal kind and statement (starting with vars), initial proposition*)
   153     messages: (unit -> Pretty.T) list,    (*persistent messages (hints etc.)*)
   154     using: thm list,                      (*goal facts*)
   155     goal: thm,                            (*subgoals ==> statement*)
   156     before_qed: Method.text option,
   157     after_qed:
   158       (thm list list -> state -> state) *
   159       (thm list list -> context -> context)};
   160 
   161 fun make_goal (statement, messages, using, goal, before_qed, after_qed) =
   162   Goal {statement = statement, messages = messages, using = using, goal = goal,
   163     before_qed = before_qed, after_qed = after_qed};
   164 
   165 fun make_node (context, facts, mode, goal) =
   166   Node {context = context, facts = facts, mode = mode, goal = goal};
   167 
   168 fun map_node f (Node {context, facts, mode, goal}) =
   169   make_node (f (context, facts, mode, goal));
   170 
   171 val init_context =
   172   Proof_Context.set_stmt true #>
   173   Proof_Context.map_naming (K Name_Space.local_naming);
   174 
   175 fun init ctxt =
   176   State (Stack.init (make_node (init_context ctxt, NONE, Forward, NONE)));
   177 
   178 fun top (State st) = Stack.top st |> (fn Node node => node);
   179 fun map_top f (State st) = State (Stack.map_top (map_node f) st);
   180 fun map_all f (State st) = State (Stack.map_all (map_node f) st);
   181 
   182 
   183 
   184 (** basic proof state operations **)
   185 
   186 (* block structure *)
   187 
   188 fun open_block (State st) = State (Stack.push st);
   189 
   190 fun close_block (State st) = State (Stack.pop st)
   191   handle List.Empty => error "Unbalanced block parentheses";
   192 
   193 fun level (State st) = Stack.level st;
   194 
   195 fun assert_bottom b state =
   196   let val b' = level state <= 2 in
   197     if b andalso not b' then error "Not at bottom of proof"
   198     else if not b andalso b' then error "Already at bottom of proof"
   199     else state
   200   end;
   201 
   202 
   203 (* context *)
   204 
   205 val context_of = #context o top;
   206 val theory_of = Proof_Context.theory_of o context_of;
   207 
   208 fun map_node_context f =
   209   map_node (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   210 
   211 fun map_context f =
   212   map_top (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   213 
   214 fun map_context_result f state =
   215   f (context_of state) ||> (fn ctxt => map_context (K ctxt) state);
   216 
   217 fun map_contexts f = map_all (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   218 
   219 fun propagate_ml_env state = map_contexts
   220   (Context.proof_map (ML_Env.inherit (Context.Proof (context_of state)))) state;
   221 
   222 val bind_terms = map_context o Proof_Context.bind_terms;
   223 val put_thms = map_context oo Proof_Context.put_thms;
   224 
   225 
   226 (* facts *)
   227 
   228 val get_facts = #facts o top;
   229 
   230 fun the_facts state =
   231   (case get_facts state of SOME facts => facts
   232   | NONE => error "No current facts available");
   233 
   234 fun the_fact state =
   235   (case the_facts state of [thm] => thm
   236   | _ => error "Single theorem expected");
   237 
   238 fun put_facts facts =
   239   map_top (fn (ctxt, _, mode, goal) => (ctxt, facts, mode, goal)) #>
   240   put_thms true (Auto_Bind.thisN, facts);
   241 
   242 val set_facts = put_facts o SOME;
   243 val reset_facts = put_facts NONE;
   244 
   245 fun these_factss more_facts (named_factss, state) =
   246   (named_factss, state |> set_facts (maps snd named_factss @ more_facts));
   247 
   248 fun export_facts inner outer =
   249   (case get_facts inner of
   250     NONE => reset_facts outer
   251   | SOME thms =>
   252       thms
   253       |> Proof_Context.export (context_of inner) (context_of outer)
   254       |> (fn ths => set_facts ths outer));
   255 
   256 
   257 (* mode *)
   258 
   259 val get_mode = #mode o top;
   260 fun put_mode mode = map_top (fn (ctxt, facts, _, goal) => (ctxt, facts, mode, goal));
   261 
   262 val mode_name = (fn Forward => "state" | Chain => "chain" | Backward => "prove");
   263 
   264 fun assert_mode pred state =
   265   let val mode = get_mode state in
   266     if pred mode then state
   267     else error ("Illegal application of proof command in " ^ quote (mode_name mode) ^ " mode")
   268   end;
   269 
   270 val assert_forward = assert_mode (fn mode => mode = Forward);
   271 val assert_chain = assert_mode (fn mode => mode = Chain);
   272 val assert_forward_or_chain = assert_mode (fn mode => mode = Forward orelse mode = Chain);
   273 val assert_backward = assert_mode (fn mode => mode = Backward);
   274 val assert_no_chain = assert_mode (fn mode => mode <> Chain);
   275 
   276 val enter_forward = put_mode Forward;
   277 val enter_chain = put_mode Chain;
   278 val enter_backward = put_mode Backward;
   279 
   280 
   281 (* current goal *)
   282 
   283 fun current_goal state =
   284   (case top state of
   285     {context, goal = SOME (Goal goal), ...} => (context, goal)
   286   | _ => error "No current goal");
   287 
   288 fun assert_current_goal g state =
   289   let val g' = can current_goal state in
   290     if g andalso not g' then error "No goal in this block"
   291     else if not g andalso g' then error "Goal present in this block"
   292     else state
   293   end;
   294 
   295 fun put_goal goal = map_top (fn (ctxt, using, mode, _) => (ctxt, using, mode, goal));
   296 
   297 val set_goal = put_goal o SOME;
   298 val reset_goal = put_goal NONE;
   299 
   300 val before_qed = #before_qed o #2 o current_goal;
   301 
   302 
   303 (* nested goal *)
   304 
   305 fun map_goal f g h (State (Node {context, facts, mode, goal = SOME goal}, node :: nodes)) =
   306       let
   307         val Goal {statement, messages, using, goal, before_qed, after_qed} = goal;
   308         val goal' = make_goal (g (statement, messages, using, goal, before_qed, after_qed));
   309         val node' = map_node_context h node;
   310       in State (make_node (f context, facts, mode, SOME goal'), node' :: nodes) end
   311   | map_goal f g h (State (nd, node :: nodes)) =
   312       let
   313         val nd' = map_node_context f nd;
   314         val State (node', nodes') = map_goal f g h (State (node, nodes));
   315       in State (nd', node' :: nodes') end
   316   | map_goal _ _ _ state = state;
   317 
   318 fun provide_goal goal = map_goal I (fn (statement, _, using, _, before_qed, after_qed) =>
   319   (statement, [], using, goal, before_qed, after_qed)) I;
   320 
   321 fun goal_message msg = map_goal I (fn (statement, messages, using, goal, before_qed, after_qed) =>
   322   (statement, msg :: messages, using, goal, before_qed, after_qed)) I;
   323 
   324 fun using_facts using = map_goal I (fn (statement, _, _, goal, before_qed, after_qed) =>
   325   (statement, [], using, goal, before_qed, after_qed)) I;
   326 
   327 local
   328   fun find i state =
   329     (case try current_goal state of
   330       SOME (ctxt, goal) => (ctxt, (i, goal))
   331     | NONE => find (i + 1) (close_block state handle ERROR _ => error "No goal present"));
   332 in val find_goal = find 0 end;
   333 
   334 fun get_goal state =
   335   let val (ctxt, (_, {using, goal, ...})) = find_goal state
   336   in (ctxt, (using, goal)) end;
   337 
   338 
   339 
   340 (** pretty_state **)
   341 
   342 fun pretty_goal_messages state =
   343   (case try find_goal state of
   344     SOME (_, (_, {messages, ...})) => map (fn msg => msg ()) (rev messages)
   345   | NONE => []);
   346 
   347 fun pretty_facts _ _ NONE = []
   348   | pretty_facts ctxt s (SOME ths) = [Proof_Display.pretty_goal_facts ctxt s ths, Pretty.str ""];
   349 
   350 fun pretty_state nr state =
   351   let
   352     val {context = ctxt, facts, mode, goal = _} = top state;
   353     val verbose = Config.get ctxt Proof_Context.verbose;
   354 
   355     fun prt_goal (SOME (_, (_,
   356       {statement = ((_, pos), _, _), messages, using, goal, before_qed = _, after_qed = _}))) =
   357           pretty_facts ctxt "using"
   358             (if mode <> Backward orelse null using then NONE else SOME using) @
   359           [Proof_Display.pretty_goal_header goal] @ Goal_Display.pretty_goals ctxt goal @
   360           (map (fn msg => Position.setmp_thread_data pos msg ()) (rev messages))
   361       | prt_goal NONE = [];
   362 
   363     val prt_ctxt =
   364       if verbose orelse mode = Forward then Proof_Context.pretty_context ctxt
   365       else if mode = Backward then Proof_Context.pretty_ctxt ctxt
   366       else [];
   367   in
   368     [Pretty.str ("proof (" ^ mode_name mode ^ "): step " ^ string_of_int nr ^
   369       (if verbose then ", depth " ^ string_of_int (level state div 2 - 1) else "")),
   370       Pretty.str ""] @
   371     (if null prt_ctxt then [] else prt_ctxt @ [Pretty.str ""]) @
   372     (if verbose orelse mode = Forward then
   373        pretty_facts ctxt "" facts @ prt_goal (try find_goal state)
   374      else if mode = Chain then pretty_facts ctxt "picking" facts
   375      else prt_goal (try find_goal state))
   376   end;
   377 
   378 
   379 
   380 (** proof steps **)
   381 
   382 (* refine via method *)
   383 
   384 local
   385 
   386 fun goalN i = "goal" ^ string_of_int i;
   387 fun goals st = map goalN (1 upto Thm.nprems_of st);
   388 
   389 fun no_goal_cases st = map (rpair NONE) (goals st);
   390 
   391 fun goal_cases st =
   392   Rule_Cases.make_common
   393     (Thm.theory_of_thm st, Thm.prop_of st) (map (rpair [] o rpair []) (goals st));
   394 
   395 fun apply_method current_context method state =
   396   let
   397     val (goal_ctxt, (_, {statement, messages = _, using, goal, before_qed, after_qed})) =
   398       find_goal state;
   399     val ctxt = if current_context then context_of state else goal_ctxt;
   400   in
   401     Method.apply method ctxt using goal |> Seq.map (fn (meth_cases, goal') =>
   402       state
   403       |> map_goal
   404           (Proof_Context.update_cases false (no_goal_cases goal @ goal_cases goal') #>
   405            Proof_Context.update_cases true meth_cases)
   406           (K (statement, [], using, goal', before_qed, after_qed)) I)
   407   end;
   408 
   409 fun select_goals n meth state =
   410   ALLGOALS Goal.conjunction_tac (#2 (#2 (get_goal state)))
   411   |> Seq.maps (fn goal =>
   412     state
   413     |> Seq.lift provide_goal ((PRIMITIVE (Goal.restrict 1 n) THEN Goal.conjunction_tac 1) goal)
   414     |> Seq.maps meth
   415     |> Seq.maps (fn state' => state'
   416       |> Seq.lift provide_goal (PRIMITIVE (Goal.unrestrict 1) (#2 (#2 (get_goal state')))))
   417     |> Seq.maps (apply_method true (K Method.succeed)));
   418 
   419 fun apply_text current_context text state =
   420   let
   421     val ctxt = context_of state;
   422 
   423     fun eval (Method.Basic m) = apply_method current_context m
   424       | eval (Method.Source src) =
   425           apply_method current_context (Method.the_method ctxt (Method.check_source ctxt src))
   426       | eval (Method.Then txts) = Seq.EVERY (map eval txts)
   427       | eval (Method.Orelse txts) = Seq.FIRST (map eval txts)
   428       | eval (Method.Try txt) = Seq.TRY (eval txt)
   429       | eval (Method.Repeat1 txt) = Seq.REPEAT1 (eval txt)
   430       | eval (Method.Select_Goals (n, txt)) = select_goals n (eval txt);
   431   in eval text state end;
   432 
   433 in
   434 
   435 val refine = apply_text true;
   436 val refine_end = apply_text false;
   437 fun refine_insert ths = Seq.hd o refine (Method.Basic (K (Method.insert ths)));
   438 
   439 end;
   440 
   441 
   442 (* refine via sub-proof *)
   443 
   444 local
   445 
   446 fun finish_tac _ 0 = K all_tac
   447   | finish_tac ctxt n =
   448       Goal.norm_hhf_tac ctxt THEN'
   449       SUBGOAL (fn (goal, i) =>
   450         if can Logic.unprotect (Logic.strip_assums_concl goal) then
   451           etac Drule.protectI i THEN finish_tac ctxt (n - 1) i
   452         else finish_tac ctxt (n - 1) (i + 1));
   453 
   454 fun goal_tac ctxt rule =
   455   Goal.norm_hhf_tac ctxt THEN'
   456   rtac rule THEN'
   457   finish_tac ctxt (Thm.nprems_of rule);
   458 
   459 fun FINDGOAL tac st =
   460   let fun find i n = if i > n then Seq.fail else Seq.APPEND (tac i, find (i + 1) n)
   461   in find 1 (Thm.nprems_of st) st end;
   462 
   463 in
   464 
   465 fun refine_goals print_rule inner raw_rules state =
   466   let
   467     val (outer, (_, goal)) = get_goal state;
   468     fun refine rule st = (print_rule outer rule; FINDGOAL (goal_tac outer rule) st);
   469   in
   470     raw_rules
   471     |> Proof_Context.goal_export inner outer
   472     |> (fn rules => Seq.lift provide_goal (EVERY (map refine rules) goal) state)
   473   end;
   474 
   475 end;
   476 
   477 
   478 (* conclude goal *)
   479 
   480 fun conclude_goal ctxt goal propss =
   481   let
   482     val thy = Proof_Context.theory_of ctxt;
   483 
   484     val _ =
   485       Theory.subthy (theory_of_thm goal, thy) orelse error "Bad background theory of goal state";
   486     val _ = Thm.no_prems goal orelse error (Proof_Display.string_of_goal ctxt goal);
   487 
   488     fun lost_structure () = error ("Lost goal structure:\n" ^ Display.string_of_thm ctxt goal);
   489 
   490     val th =
   491       (Goal.conclude (if length (flat propss) > 1 then Thm.norm_proof goal else goal)
   492         handle THM _ => lost_structure ())
   493       |> Drule.flexflex_unique
   494       |> Thm.check_shyps (Variable.sorts_of ctxt)
   495       |> Thm.check_hyps (Context.Proof ctxt);
   496 
   497     val goal_propss = filter_out null propss;
   498     val results =
   499       Conjunction.elim_balanced (length goal_propss) th
   500       |> map2 Conjunction.elim_balanced (map length goal_propss)
   501       handle THM _ => lost_structure ();
   502     val _ = Unify.matches_list thy (flat goal_propss) (map Thm.prop_of (flat results)) orelse
   503       error ("Proved a different theorem:\n" ^ Display.string_of_thm ctxt th);
   504 
   505     fun recover_result ([] :: pss) thss = [] :: recover_result pss thss
   506       | recover_result (_ :: pss) (ths :: thss) = ths :: recover_result pss thss
   507       | recover_result [] [] = []
   508       | recover_result _ _ = lost_structure ();
   509   in recover_result propss results end;
   510 
   511 val finished_goal_error = "Failed to finish proof";
   512 
   513 fun finished_goal pos state =
   514   let val (ctxt, (_, goal)) = get_goal state in
   515     if Thm.no_prems goal then Seq.Result state
   516     else
   517       Seq.Error (fn () =>
   518         finished_goal_error ^ Position.here pos ^ ":\n" ^
   519           Proof_Display.string_of_goal ctxt goal)
   520   end;
   521 
   522 
   523 (* goal views -- corresponding to methods *)
   524 
   525 fun raw_goal state =
   526   let val (ctxt, (facts, goal)) = get_goal state
   527   in {context = ctxt, facts = facts, goal = goal} end;
   528 
   529 val goal = raw_goal o refine_insert [];
   530 
   531 fun simple_goal state =
   532   let
   533     val (_, (facts, _)) = get_goal state;
   534     val (ctxt, (_, goal)) = get_goal (refine_insert facts state);
   535   in {context = ctxt, goal = goal} end;
   536 
   537 fun status_markup state =
   538   (case try goal state of
   539     SOME {goal, ...} => Markup.proof_state (Thm.nprems_of goal)
   540   | NONE => Markup.empty);
   541 
   542 fun method_error kind pos state =
   543   Seq.single (Proof_Display.method_error kind pos (raw_goal state));
   544 
   545 
   546 
   547 (*** structured proof commands ***)
   548 
   549 (** context elements **)
   550 
   551 (* let bindings *)
   552 
   553 local
   554 
   555 fun gen_bind bind args state =
   556   state
   557   |> assert_forward
   558   |> map_context (bind true args #> snd)
   559   |> reset_facts;
   560 
   561 in
   562 
   563 val let_bind = gen_bind Proof_Context.match_bind_i;
   564 val let_bind_cmd = gen_bind Proof_Context.match_bind;
   565 
   566 end;
   567 
   568 
   569 (* concrete syntax *)
   570 
   571 local
   572 
   573 fun gen_write prep_arg mode args =
   574   assert_forward
   575   #> map_context (fn ctxt => ctxt |> Proof_Context.notation true mode (map (prep_arg ctxt) args))
   576   #> reset_facts;
   577 
   578 in
   579 
   580 val write = gen_write (K I);
   581 
   582 val write_cmd =
   583   gen_write (fn ctxt => fn (c, mx) =>
   584     (Proof_Context.read_const ctxt false (Mixfix.mixfixT mx) c, mx));
   585 
   586 end;
   587 
   588 
   589 (* fix *)
   590 
   591 local
   592 
   593 fun gen_fix prep_vars args =
   594   assert_forward
   595   #> map_context (fn ctxt => snd (Proof_Context.add_fixes (fst (prep_vars args ctxt)) ctxt))
   596   #> reset_facts;
   597 
   598 in
   599 
   600 val fix = gen_fix Proof_Context.cert_vars;
   601 val fix_cmd = gen_fix Proof_Context.read_vars;
   602 
   603 end;
   604 
   605 
   606 (* assume etc. *)
   607 
   608 local
   609 
   610 fun gen_assume asm prep_att exp args state =
   611   state
   612   |> assert_forward
   613   |> map_context_result (asm exp (Attrib.map_specs (map (prep_att (context_of state))) args))
   614   |> these_factss [] |> #2;
   615 
   616 in
   617 
   618 val assm = gen_assume Proof_Context.add_assms_i (K I);
   619 val assm_cmd = gen_assume Proof_Context.add_assms Attrib.attribute_cmd;
   620 val assume = assm Assumption.assume_export;
   621 val assume_cmd = assm_cmd Assumption.assume_export;
   622 val presume = assm Assumption.presume_export;
   623 val presume_cmd = assm_cmd Assumption.presume_export;
   624 
   625 end;
   626 
   627 
   628 (* def *)
   629 
   630 local
   631 
   632 fun gen_def prep_att prep_vars prep_binds args state =
   633   let
   634     val _ = assert_forward state;
   635     val (raw_name_atts, (raw_vars, raw_rhss)) = args |> split_list ||> split_list;
   636     val name_atts = map (apsnd (map (prep_att (context_of state)))) raw_name_atts;
   637   in
   638     state
   639     |> map_context_result (prep_vars (map (fn (x, mx) => (x, NONE, mx)) raw_vars))
   640     |>> map (fn (x, _, mx) => (x, mx))
   641     |-> (fn vars =>
   642       map_context_result (prep_binds false (map swap raw_rhss))
   643       #-> (fn rhss =>
   644         let
   645           val defs = (vars ~~ (name_atts ~~ rhss)) |> map (fn ((x, mx), ((a, atts), rhs)) =>
   646             ((x, mx), ((Thm.def_binding_optional x a, atts), rhs)));
   647         in map_context_result (Local_Defs.add_defs defs) end))
   648     |-> (set_facts o map (#2 o #2))
   649   end;
   650 
   651 in
   652 
   653 val def = gen_def (K I) Proof_Context.cert_vars Proof_Context.match_bind_i;
   654 val def_cmd = gen_def Attrib.attribute_cmd Proof_Context.read_vars Proof_Context.match_bind;
   655 
   656 end;
   657 
   658 
   659 
   660 (** facts **)
   661 
   662 (* chain *)
   663 
   664 fun clean_facts ctxt =
   665   set_facts (filter_out Thm.is_dummy (the_facts ctxt)) ctxt;
   666 
   667 val chain =
   668   assert_forward
   669   #> clean_facts
   670   #> enter_chain;
   671 
   672 fun chain_facts facts =
   673   set_facts facts
   674   #> chain;
   675 
   676 
   677 (* note etc. *)
   678 
   679 fun no_binding args = map (pair (Binding.empty, [])) args;
   680 
   681 local
   682 
   683 fun gen_thmss more_facts opt_chain opt_result prep_atts prep_fact args state =
   684   state
   685   |> assert_forward
   686   |> map_context_result (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   687     (Attrib.map_facts_refs (map (prep_atts ctxt)) (prep_fact ctxt) args))
   688   |> these_factss (more_facts state)
   689   ||> opt_chain
   690   |> opt_result;
   691 
   692 in
   693 
   694 val note_thmss = gen_thmss (K []) I #2 (K I) (K I);
   695 val note_thmss_cmd = gen_thmss (K []) I #2 Attrib.attribute_cmd Proof_Context.get_fact;
   696 
   697 val from_thmss = gen_thmss (K []) chain #2 (K I) (K I) o no_binding;
   698 val from_thmss_cmd =
   699   gen_thmss (K []) chain #2 Attrib.attribute_cmd Proof_Context.get_fact o no_binding;
   700 
   701 val with_thmss = gen_thmss the_facts chain #2 (K I) (K I) o no_binding;
   702 val with_thmss_cmd =
   703   gen_thmss the_facts chain #2 Attrib.attribute_cmd Proof_Context.get_fact o no_binding;
   704 
   705 val local_results = gen_thmss (K []) I I (K I) (K I) o map (apsnd Thm.simple_fact);
   706 
   707 end;
   708 
   709 
   710 (* using/unfolding *)
   711 
   712 local
   713 
   714 fun gen_using f g prep_att prep_fact args state =
   715   state
   716   |> assert_backward
   717   |> map_context_result
   718     (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   719       (Attrib.map_facts_refs (map (prep_att ctxt)) (prep_fact ctxt) (no_binding args)))
   720   |> (fn (named_facts, state') =>
   721     state' |> map_goal I (fn (statement, _, using, goal, before_qed, after_qed) =>
   722       let
   723         val ctxt = context_of state';
   724         val ths = maps snd named_facts;
   725       in (statement, [], f ctxt ths using, g ctxt ths goal, before_qed, after_qed) end) I);
   726 
   727 fun append_using _ ths using = using @ filter_out Thm.is_dummy ths;
   728 fun unfold_using ctxt ths = map (Local_Defs.unfold ctxt ths);
   729 val unfold_goals = Local_Defs.unfold_goals;
   730 
   731 in
   732 
   733 val using = gen_using append_using (K (K I)) (K I) (K I);
   734 val using_cmd = gen_using append_using (K (K I)) Attrib.attribute_cmd Proof_Context.get_fact;
   735 val unfolding = gen_using unfold_using unfold_goals (K I) (K I);
   736 val unfolding_cmd = gen_using unfold_using unfold_goals Attrib.attribute_cmd Proof_Context.get_fact;
   737 
   738 end;
   739 
   740 
   741 (* case *)
   742 
   743 local
   744 
   745 fun gen_invoke_case prep_att ((name, pos), xs, raw_atts) state =
   746   let
   747     val atts = map (prep_att (context_of state)) raw_atts;
   748     val (asms, state') = state |> map_context_result (fn ctxt =>
   749       ctxt |> Proof_Context.apply_case (Proof_Context.check_case ctxt (name, pos) xs));
   750     val assumptions =
   751       asms |> map (fn (b, ts) => ((Binding.set_pos pos b, atts), map (rpair []) ts));
   752   in
   753     state'
   754     |> assume assumptions
   755     |> bind_terms Auto_Bind.no_facts
   756     |> `the_facts |-> (fn thms => note_thmss [((Binding.make (name, pos), []), [(thms, [])])])
   757   end;
   758 
   759 in
   760 
   761 val invoke_case = gen_invoke_case (K I);
   762 val invoke_case_cmd = gen_invoke_case Attrib.attribute_cmd;
   763 
   764 end;
   765 
   766 
   767 
   768 (** proof structure **)
   769 
   770 (* blocks *)
   771 
   772 val begin_block =
   773   assert_forward
   774   #> open_block
   775   #> reset_goal
   776   #> open_block;
   777 
   778 val next_block =
   779   assert_forward
   780   #> close_block
   781   #> open_block
   782   #> reset_goal
   783   #> reset_facts;
   784 
   785 fun end_block state =
   786   state
   787   |> assert_forward
   788   |> assert_bottom false
   789   |> close_block
   790   |> assert_current_goal false
   791   |> close_block
   792   |> export_facts state;
   793 
   794 
   795 (* global notepad *)
   796 
   797 val begin_notepad =
   798   init
   799   #> open_block
   800   #> map_context (Variable.set_body true)
   801   #> open_block;
   802 
   803 val end_notepad =
   804   assert_forward
   805   #> assert_bottom true
   806   #> close_block
   807   #> assert_current_goal false
   808   #> close_block
   809   #> context_of;
   810 
   811 
   812 (* sub-proofs *)
   813 
   814 fun proof opt_text =
   815   assert_backward
   816   #> refine (the_default Method.default_text opt_text)
   817   #> Seq.map (using_facts [] #> enter_forward);
   818 
   819 fun proof_results arg =
   820   Seq.APPEND (proof (Method.text arg) #> Seq.make_results,
   821     method_error "initial" (Method.position arg));
   822 
   823 fun end_proof bot (prev_pos, (opt_text, immed)) =
   824   let
   825     val (finish_text, terminal_pos, finished_pos) =
   826       (case opt_text of
   827         NONE => (Method.finish_text (NONE, immed), Position.none, prev_pos)
   828       | SOME (text, (pos, end_pos)) => (Method.finish_text (SOME text, immed), pos, end_pos));
   829   in
   830     Seq.APPEND (fn state =>
   831       state
   832       |> assert_forward
   833       |> assert_bottom bot
   834       |> close_block
   835       |> assert_current_goal true
   836       |> using_facts []
   837       |> `before_qed |-> (refine o the_default Method.succeed_text)
   838       |> Seq.maps (refine finish_text)
   839       |> Seq.make_results, method_error "terminal" terminal_pos)
   840     #> Seq.maps_results (Seq.single o finished_goal finished_pos)
   841   end;
   842 
   843 fun check_result msg sq =
   844   (case Seq.pull sq of
   845     NONE => error msg
   846   | SOME (s, _) => s);
   847 
   848 
   849 (* unstructured refinement *)
   850 
   851 fun defer i =
   852   assert_no_chain #>
   853   refine (Method.Basic (fn _ => METHOD (fn _ => ASSERT_SUBGOAL defer_tac i))) #> Seq.hd;
   854 
   855 fun prefer i =
   856   assert_no_chain #>
   857   refine (Method.Basic (fn _ => METHOD (fn _ => ASSERT_SUBGOAL prefer_tac i))) #> Seq.hd;
   858 
   859 fun apply text = assert_backward #> refine text #> Seq.map (using_facts []);
   860 
   861 fun apply_end text = assert_forward #> refine_end text;
   862 
   863 fun apply_results (text, (pos, _)) =
   864   Seq.APPEND (apply text #> Seq.make_results, method_error "" pos);
   865 
   866 fun apply_end_results (text, (pos, _)) =
   867   Seq.APPEND (apply_end text #> Seq.make_results, method_error "" pos);
   868 
   869 
   870 
   871 (** goals **)
   872 
   873 (* generic goals *)
   874 
   875 local
   876 
   877 val is_var =
   878   can (dest_TVar o Logic.dest_type o Logic.dest_term) orf
   879   can (dest_Var o Logic.dest_term);
   880 
   881 fun implicit_vars props =
   882   let
   883     val (var_props, _) = take_prefix is_var props;
   884     val explicit_vars = fold Term.add_vars var_props [];
   885     val vars = filter_out (member (op =) explicit_vars) (fold Term.add_vars props []);
   886   in map (Logic.mk_term o Var) vars end;
   887 
   888 fun refine_terms n =
   889   refine (Method.Basic (K (RAW_METHOD
   890     (K (HEADGOAL (PRECISE_CONJUNCTS n
   891       (HEADGOAL (CONJUNCTS (ALLGOALS (rtac Drule.termI))))))))))
   892   #> Seq.hd;
   893 
   894 in
   895 
   896 fun generic_goal prepp kind before_qed after_qed raw_propp state =
   897   let
   898     val thy = theory_of state;
   899     val cert = Thm.cterm_of thy;
   900     val chaining = can assert_chain state;
   901     val pos = Position.thread_data ();
   902 
   903     val ((propss, after_ctxt), goal_state) =
   904       state
   905       |> assert_forward_or_chain
   906       |> enter_forward
   907       |> open_block
   908       |> map_context_result (prepp raw_propp);
   909     val props = flat propss;
   910 
   911     val vars = implicit_vars props;
   912     val propss' = vars :: propss;
   913     val goal_propss = filter_out null propss';
   914     val goal =
   915       cert (Logic.mk_conjunction_balanced (map Logic.mk_conjunction_balanced goal_propss))
   916       |> Thm.weaken_sorts (Variable.sorts_of (context_of goal_state));
   917     val statement = ((kind, pos), propss', Thm.term_of goal);
   918     val after_qed' = after_qed |>> (fn after_local =>
   919       fn results => map_context after_ctxt #> after_local results);
   920   in
   921     goal_state
   922     |> map_context (init_context #> Variable.set_body true)
   923     |> set_goal (make_goal (statement, [], [], Goal.init goal, before_qed, after_qed'))
   924     |> map_context (Proof_Context.auto_bind_goal props)
   925     |> chaining ? (`the_facts #-> using_facts)
   926     |> reset_facts
   927     |> open_block
   928     |> reset_goal
   929     |> enter_backward
   930     |> not (null vars) ? refine_terms (length goal_propss)
   931     |> null props ? (refine (Method.Basic Method.assumption) #> Seq.hd)
   932   end;
   933 
   934 fun generic_qed after_ctxt state =
   935   let
   936     val (goal_ctxt, {statement = (_, stmt, _), goal, after_qed, ...}) = current_goal state;
   937     val outer_state = state |> close_block;
   938     val outer_ctxt = context_of outer_state;
   939 
   940     val props =
   941       flat (tl stmt)
   942       |> Variable.exportT_terms goal_ctxt outer_ctxt;
   943     val results =
   944       tl (conclude_goal goal_ctxt goal stmt)
   945       |> burrow (Proof_Context.export goal_ctxt outer_ctxt);
   946   in
   947     outer_state
   948     |> map_context (after_ctxt props)
   949     |> pair (after_qed, results)
   950   end;
   951 
   952 end;
   953 
   954 
   955 (* local goals *)
   956 
   957 fun local_goal print_results prep_att prepp kind before_qed after_qed stmt state =
   958   let
   959     val ((names, attss), propp) =
   960       Attrib.map_specs (map (prep_att (context_of state))) stmt |> split_list |>> split_list;
   961 
   962     fun after_qed' results =
   963       local_results ((names ~~ attss) ~~ results)
   964       #-> (fn res => tap (fn st => print_results (context_of st) ((kind, ""), res) : unit))
   965       #> after_qed results;
   966   in
   967     state
   968     |> generic_goal prepp kind before_qed (after_qed', K I) propp
   969     |> tap (Variable.warn_extra_tfrees (context_of state) o context_of)
   970   end;
   971 
   972 fun local_qeds arg =
   973   end_proof false arg
   974   #> Seq.map_result (generic_qed Proof_Context.auto_bind_facts #->
   975     (fn ((after_qed, _), results) => after_qed results));
   976 
   977 fun local_qed arg =
   978   local_qeds (Position.none, arg) #> Seq.the_result finished_goal_error;
   979 
   980 
   981 (* global goals *)
   982 
   983 fun prepp_auto_fixes prepp args =
   984   prepp args #>
   985   (fn ((propss, a), ctxt) => ((propss, a), (fold o fold) Variable.auto_fixes propss ctxt));
   986 
   987 fun global_goal prepp before_qed after_qed propp =
   988   init #>
   989   generic_goal (prepp_auto_fixes prepp) "" before_qed (K I, after_qed) propp;
   990 
   991 val theorem = global_goal Proof_Context.bind_propp_schematic_i;
   992 val theorem_cmd = global_goal Proof_Context.bind_propp_schematic;
   993 
   994 fun global_qeds arg =
   995   end_proof true arg
   996   #> Seq.map_result (generic_qed (K I) #> (fn (((_, after_qed), results), state) =>
   997     after_qed results (context_of state)));
   998 
   999 fun global_qed arg =
  1000   global_qeds (Position.none, arg) #> Seq.the_result finished_goal_error;
  1001 
  1002 
  1003 (* terminal proof steps *)
  1004 
  1005 local
  1006 
  1007 fun terminal_proof qeds initial terminal =
  1008   proof_results (SOME initial) #> Seq.maps_results (qeds (#2 (#2 initial), terminal))
  1009   #> Seq.the_result "";
  1010 
  1011 in
  1012 
  1013 fun local_terminal_proof (text, opt_text) = terminal_proof local_qeds text (opt_text, true);
  1014 val local_default_proof = local_terminal_proof ((Method.default_text, Position.no_range), NONE);
  1015 val local_immediate_proof = local_terminal_proof ((Method.this_text, Position.no_range), NONE);
  1016 val local_done_proof = terminal_proof local_qeds (Method.done_text, Position.no_range) (NONE, false);
  1017 
  1018 fun global_terminal_proof (text, opt_text) = terminal_proof global_qeds text (opt_text, true);
  1019 val global_default_proof = global_terminal_proof ((Method.default_text, Position.no_range), NONE);
  1020 val global_immediate_proof = global_terminal_proof ((Method.this_text, Position.no_range), NONE);
  1021 val global_done_proof = terminal_proof global_qeds (Method.done_text, Position.no_range) (NONE, false);
  1022 
  1023 end;
  1024 
  1025 
  1026 (* skip proofs *)
  1027 
  1028 fun local_skip_proof int state =
  1029   local_terminal_proof ((Method.sorry_text int, Position.no_range), NONE) state before
  1030   Skip_Proof.report (context_of state);
  1031 
  1032 fun global_skip_proof int state =
  1033   global_terminal_proof ((Method.sorry_text int, Position.no_range), NONE) state before
  1034   Skip_Proof.report (context_of state);
  1035 
  1036 
  1037 (* common goal statements *)
  1038 
  1039 local
  1040 
  1041 fun gen_have prep_att prepp before_qed after_qed stmt int =
  1042   local_goal (Proof_Display.print_results Markup.state int)
  1043     prep_att prepp "have" before_qed after_qed stmt;
  1044 
  1045 fun gen_show prep_att prepp before_qed after_qed stmt int state =
  1046   let
  1047     val testing = Unsynchronized.ref false;
  1048     val rule = Unsynchronized.ref (NONE: thm option);
  1049     fun fail_msg ctxt =
  1050       "Local statement fails to refine any pending goal" ::
  1051       (case ! rule of NONE => [] | SOME th => [Proof_Display.string_of_rule ctxt "Failed" th])
  1052       |> cat_lines;
  1053 
  1054     fun print_results ctxt res =
  1055       if ! testing then ()
  1056       else Proof_Display.print_results Markup.state int ctxt res;
  1057     fun print_rule ctxt th =
  1058       if ! testing then rule := SOME th
  1059       else if int then
  1060         writeln (Markup.markup Markup.state (Proof_Display.string_of_rule ctxt "Successful" th))
  1061       else ();
  1062     val test_proof =
  1063       local_skip_proof true
  1064       |> Unsynchronized.setmp testing true
  1065       |> Exn.interruptible_capture;
  1066 
  1067     fun after_qed' results =
  1068       refine_goals print_rule (context_of state) (flat results)
  1069       #> check_result "Failed to refine any pending goal"
  1070       #> after_qed results;
  1071   in
  1072     state
  1073     |> local_goal print_results prep_att prepp "show" before_qed after_qed' stmt
  1074     |> int ? (fn goal_state =>
  1075       (case test_proof (map_context (Context_Position.set_visible false) goal_state) of
  1076         Exn.Res _ => goal_state
  1077       | Exn.Exn exn => raise Exn.EXCEPTIONS ([exn, ERROR (fail_msg (context_of goal_state))])))
  1078   end;
  1079 
  1080 in
  1081 
  1082 val have = gen_have (K I) Proof_Context.bind_propp_i;
  1083 val have_cmd = gen_have Attrib.attribute_cmd Proof_Context.bind_propp;
  1084 val show = gen_show (K I) Proof_Context.bind_propp_i;
  1085 val show_cmd = gen_show Attrib.attribute_cmd Proof_Context.bind_propp;
  1086 
  1087 end;
  1088 
  1089 
  1090 
  1091 (** future proofs **)
  1092 
  1093 (* relevant proof states *)
  1094 
  1095 fun schematic_goal state =
  1096   let val (_, (_, {statement = (_, _, prop), ...})) = find_goal state
  1097   in Goal.is_schematic prop end;
  1098 
  1099 fun is_relevant state =
  1100   (case try find_goal state of
  1101     NONE => true
  1102   | SOME (_, (_, {statement = (_, _, prop), goal, ...})) =>
  1103       Goal.is_schematic prop orelse not (Logic.protect prop aconv Thm.concl_of goal));
  1104 
  1105 
  1106 (* full proofs *)
  1107 
  1108 local
  1109 
  1110 structure Result = Proof_Data
  1111 (
  1112   type T = thm option;
  1113   val empty = NONE;
  1114   fun init _ = empty;
  1115 );
  1116 
  1117 fun the_result ctxt =
  1118   (case Result.get ctxt of
  1119     NONE => error "No result of forked proof"
  1120   | SOME th => th);
  1121 
  1122 val set_result = Result.put o SOME;
  1123 val reset_result = Result.put NONE;
  1124 
  1125 in
  1126 
  1127 fun future_proof fork_proof state =
  1128   let
  1129     val _ = assert_backward state;
  1130     val (goal_ctxt, (_, goal)) = find_goal state;
  1131     val {statement as (kind, _, prop), messages, using, goal, before_qed, after_qed} = goal;
  1132     val goal_tfrees =
  1133       fold Term.add_tfrees
  1134         (prop :: map Thm.term_of (Assumption.all_assms_of goal_ctxt)) [];
  1135 
  1136     val _ = is_relevant state andalso error "Cannot fork relevant proof";
  1137 
  1138     val prop' = Logic.protect prop;
  1139     val statement' = (kind, [[], [prop']], prop');
  1140     val goal' = Thm.adjust_maxidx_thm (Thm.maxidx_of goal) (Goal.protect (Thm.nprems_of goal) goal);
  1141     val after_qed' = (fn [[th]] => map_context (set_result th), fn [[th]] => set_result th);
  1142 
  1143     val result_ctxt =
  1144       state
  1145       |> map_context reset_result
  1146       |> map_goal I (K (statement', messages, using, goal', before_qed, after_qed'))
  1147         (fold (Variable.declare_typ o TFree) goal_tfrees)
  1148       |> fork_proof;
  1149 
  1150     val future_thm = Future.map (the_result o snd) result_ctxt;
  1151     val finished_goal = Goal.future_result goal_ctxt future_thm prop';
  1152     val state' =
  1153       state
  1154       |> map_goal I (K (statement, messages, using, finished_goal, NONE, after_qed)) I;
  1155   in (Future.map fst result_ctxt, state') end;
  1156 
  1157 end;
  1158 
  1159 
  1160 (* terminal proofs *)  (* FIXME avoid toplevel imitation -- include in PIDE/document *)
  1161 
  1162 local
  1163 
  1164 fun future_terminal_proof proof1 proof2 done int state =
  1165   if Goal.future_enabled 3 andalso not (is_relevant state) then
  1166     state |> future_proof (fn state' =>
  1167       let
  1168         val pos = Position.thread_data ();
  1169         val props = Markup.command_timing :: (Markup.nameN, "by") :: Position.properties_of pos;
  1170       in
  1171         Execution.fork {name = "Proof.future_terminal_proof", pos = pos, pri = ~1}
  1172           (fn () => ((), Timing.protocol props proof2 state'))
  1173       end) |> snd |> done
  1174   else proof1 state;
  1175 
  1176 in
  1177 
  1178 fun local_future_terminal_proof meths =
  1179   future_terminal_proof
  1180     (local_terminal_proof meths)
  1181     (local_terminal_proof meths #> context_of) local_done_proof;
  1182 
  1183 fun global_future_terminal_proof meths =
  1184   future_terminal_proof
  1185     (global_terminal_proof meths)
  1186     (global_terminal_proof meths) global_done_proof;
  1187 
  1188 end;
  1189 
  1190 end;
  1191